configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(src/lha.h)
   3 AM_INIT_AUTOMAKE(lha, 1.14i-ac20020527a)
   4 AM_CONFIG_HEADER(config.h)
   5
   6 AC_CANONICAL_HOST
   7
   8 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
   9                    [the type of system on which the package will run.])
  10
  11 dnl Checks for programs.
  12 AC_PROG_CC
  13 AC_PROG_GCC_TRADITIONAL
  14 AC_PROG_INSTALL
  15 AC_PROG_MAKE_SET
  16 AC_MINIX
  17 AM_C_PROTOTYPES
  18 AC_EXEEXT
  19 AC_OBJEXT
  20
  21 dnl Checks for libraries.
  22
  23 dnl Checks for header files.
  24 AC_HEADER_DIRENT
  25 AC_HEADER_STDC
  26 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
  27 AC_CHECK_HEADERS(pwd.h grp.h)
  28
  29 dnl Checks for typedefs, structures, and compiler characteristics.
  30 AC_C_CONST
  31 AC_HEADER_TIME
  32 AC_STRUCT_TM
  33 AC_STRUCT_TIMEZONE
  34
  35 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_member_struct_tm_tm_gmtoff,
  36 [AC_TRY_COMPILE([
  37 #if TM_IN_SYS_TIME
  38 #include <sys/time.h>
  39 #else
  40 #include <time.h>
  41 #endif
  42   ], [struct tm t; t.tm_gmtoff;],
  43   ac_cv_member_struct_tm_tm_gmtoff=yes,
  44   ac_cv_member_struct_tm_tm_gmtoff=no)
  45 ])
  46
  47 if test "x$ac_cv_member_struct_tm_tm_gmtoff" = xyes; then
  48   AC_DEFINE(HAVE_STRUCT_TM_TM_GMTOFF, 1,
  49             [Define if your struct tm has tm_gmtoff])
  50 fi
  51
  52 AC_CACHE_CHECK([for st_ino in struct stat], ac_cv_member_struct_stat_st_ino,
  53 [AC_TRY_COMPILE([
  54 #include <sys/types.h>
  55 #include <sys/stat.h>
  56   ], [struct stat s; s.st_ino;],
  57   ac_cv_member_struct_stat_st_ino=yes,
  58   ac_cv_member_struct_stat_st_ino=no)
  59 ])
  60
  61 if test "x$ac_cv_member_struct_stat_st_ino" = xyes; then
  62   AC_DEFINE(HAVE_STRUCT_STAT_ST_INO, 1,
  63             [Define if your struct stat has st_ino])
  64 fi
  65
  66 dnl Checks for library functions.
  67 AC_TYPE_SIGNAL
  68 AC_FUNC_FORK
  69 AC_FUNC_UTIME_NULL
  70 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove)
  71 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
  72 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp)
  73 AC_CHECK_FUNCS(strcasecmp link)
  74 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
  75
  76 AC_SUBST(LIBOBJS)
  77 if test $ac_header_dirent = no; then
  78   LIBOBJS="$LIBOBJS lhdir.o"
  79 fi
  80
  81 dnl support kanji code conversion
  82 AC_SUBST(DEF_KCODE)
  83 AC_ARG_ENABLE(text_conv,
  84   [  --enable-text-conv      support text code convert from/to EUC [default=yes]],
  85   , enable_text_conv=yes)
  86
  87 if test $enable_text_conv = yes; then
  88   DEF_KCODE=-DEUC
  89 fi
  90
  91 # force support -lh7-
  92 AC_SUBST(SUPPORT_LZHUFF_METHOD)
  93 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
  94
  95 dnl whether use the -lh567- method
  96 AC_MSG_CHECKING(default archive method is )
  97 AC_ARG_WITH(default_method,
  98   [  --with-default-method=[567]  create the -lh[567]- archive default [default=5]],
  99   [case $withval in
 100    [567]) ;;
 101    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
 102    esac],
 103   with_default_method=5)
 104
 105 AC_MSG_RESULT(-lh$with_default_method-)
 106 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
 107
 108 dnl decide temporary path names
 109 AC_MSG_CHECKING(template of the temporary file is )
 110 AC_ARG_WITH(tmp_file,
 111   [  --with-tmp-file=TEMPLATE temporary file template [default=/tmp/lhXXXXXX]],
 112   [case $withval in
 113    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
 114    no)   ;;
 115    esac],
 116   with_tmp_file=/tmp/lhXXXXXX)
 117
 118 AC_MSG_RESULT($with_tmp_file)
 119 if test x"$with_tmp_file" != xno; then
 120   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
 121     [temporary file template for mktemp/mkstemp])
 122 fi
 123
 124 dnl incremental indicator
 125 AC_ARG_ENABLE(indicator,
 126   [  --enable-indicator      need incremental indicator [default=yes]],
 127   ,
 128   # default
 129   enable_indicator=yes)
 130
 131 if test "x$enable_indicator" = xyes; then
 132   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1, [Define you want to use the incremental indicator])
 133 fi
 134
 135 dnl support multibyte filename
 136 AC_ARG_ENABLE(multibyte-char,
 137   [  --enable-multibyte-char support multibyte filename [default=yes]],
 138   ,
 139   # default
 140   enable_multibyte_char=yes)
 141
 142 if test "x$enable_multibyte_char" = xyes; then
 143   AC_DEFINE(MULTIBYTE_CHAR, 1, [Define you want to use multibyte filename])
 144 fi
 145
 146 AC_OUTPUT([Makefile src/Makefile man/Makefile tests/Makefile tests/lha-test])