configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.2.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  24     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  25
  26 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  27
  28 dnl Set internal versions
  29 OSMESA_VERSION=8
  30 AC_SUBST([OSMESA_VERSION])
  31
  32 dnl Versions for external dependencies
  33 LIBDRM_REQUIRED=2.4.24
  34 LIBDRM_RADEON_REQUIRED=2.4.44
  35 LIBDRM_INTEL_REQUIRED=2.4.38
  36 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  37 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  38 LIBDRM_FREEDRENO_REQUIRED=2.4.39
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AX_PROG_CC_FOR_BUILD
  48 AC_PROG_CXX
  49 AX_PROG_CXX_FOR_BUILD
  50 AM_PROG_CC_C_O
  51 AM_PROG_AS
  52 AC_CHECK_PROGS([MAKE], [gmake make])
  53 AC_CHECK_PROGS([PYTHON2], [python2 python])
  54 AX_PYTHON_MODULE([libxml2], [needed])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57
  58 LT_PREREQ([2.2])
  59 LT_INIT([disable-static])
  60
  61 AX_PROG_BISON([],
  62               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"],
  63                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  64 AX_PROG_FLEX([],
  65              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"],
  66                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  67
  68 AC_PATH_PROG([PERL], [perl])
  69
  70 AC_CHECK_PROG(INDENT, indent, indent, cat)
  71 if test "x$INDENT" != "xcat"; then
  72     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  73 fi
  74
  75 AC_PROG_INSTALL
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122 dnl Make sure the pkg-config macros are defined
 123 m4_ifndef([PKG_PROG_PKG_CONFIG],
 124     [m4_fatal([Could not locate the pkg-config autoconf macros.
 125   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 126   are in a different location, try setting the environment variable
 127   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 128 PKG_PROG_PKG_CONFIG()
 129
 130 dnl LIB_DIR - library basename
 131 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 132 AC_SUBST([LIB_DIR])
 133
 134 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 135 _SAVE_LDFLAGS="$LDFLAGS"
 136 _SAVE_CPPFLAGS="$CPPFLAGS"
 137
 138 dnl build host compiler macros
 139 DEFINES_FOR_BUILD=""
 140 AC_SUBST([DEFINES_FOR_BUILD])
 141 case "$build_os" in
 142 linux*|*-gnu*|gnu*)
 143     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 144     ;;
 145 solaris*)
 146     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 147     ;;
 148 cygwin*)
 149     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 150     ;;
 151 esac
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DHAVE_PTHREAD"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     case "$host_os" in
 171     cygwin*)
 172         CFLAGS="$CFLAGS -Wall -std=gnu99"
 173         ;;
 174     *)
 175         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 176         CFLAGS="$CFLAGS -Wall -std=c99"
 177         ;;
 178     esac
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 206     CFLAGS="$CFLAGS -fno-strict-aliasing"
 207
 208     # gcc's builtin memcmp is slower than glibc's
 209     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 210     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 215     CXXFLAGS="$CXXFLAGS -Wall"
 216
 217     # Enable -fvisibility=hidden if using a gcc that supports it
 218     save_CXXFLAGS="$CXXFLAGS"
 219     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 220     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 221     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 222     AC_LANG_PUSH([C++])
 223     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 224                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 225     AC_LANG_POP([C++])
 226
 227     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 228     CXXFLAGS=$save_CXXFLAGS
 229
 230     # Work around aliasing bugs - developers should comment this out
 231     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 232     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 233
 234     # gcc's builtin memcmp is slower than glibc's
 235     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 236     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 237     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 238 fi
 239
 240 dnl even if the compiler appears to support it, using visibility attributes isn't
 241 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 242 case "$host_os" in
 243 cygwin*)
 244     VISIBILITY_CFLAGS=""
 245     VISIBILITY_CXXFLAGS=""
 246     ;;
 247 esac
 248
 249 AC_SUBST([VISIBILITY_CFLAGS])
 250 AC_SUBST([VISIBILITY_CXXFLAGS])
 251
 252 dnl
 253 dnl Hacks to enable 32 or 64 bit build
 254 dnl
 255 AC_ARG_ENABLE([32-bit],
 256     [AS_HELP_STRING([--enable-32-bit],
 257         [build 32-bit libraries @<:@default=auto@:>@])],
 258     [enable_32bit="$enableval"],
 259     [enable_32bit=auto]
 260 )
 261 if test "x$enable_32bit" = xyes; then
 262     if test "x$GCC" = xyes; then
 263         CFLAGS="$CFLAGS -m32"
 264         CCASFLAGS="$CCASFLAGS -m32"
 265     fi
 266     if test "x$GXX" = xyes; then
 267         CXXFLAGS="$CXXFLAGS -m32"
 268     fi
 269 fi
 270 AC_ARG_ENABLE([64-bit],
 271     [AS_HELP_STRING([--enable-64-bit],
 272         [build 64-bit libraries @<:@default=auto@:>@])],
 273     [enable_64bit="$enableval"],
 274     [enable_64bit=auto]
 275 )
 276 if test "x$enable_64bit" = xyes; then
 277     if test "x$GCC" = xyes; then
 278         CFLAGS="$CFLAGS -m64"
 279     fi
 280     if test "x$GXX" = xyes; then
 281         CXXFLAGS="$CXXFLAGS -m64"
 282     fi
 283 fi
 284
 285 dnl Can't have static and shared libraries, default to static if user
 286 dnl explicitly requested. If both disabled, set to static since shared
 287 dnl was explicitly requested.
 288 case "x$enable_static$enable_shared" in
 289 xyesyes )
 290     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 291     enable_shared=no
 292     ;;
 293 xnono )
 294     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 295     enable_static=yes
 296     ;;
 297 esac
 298
 299 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 300
 301 dnl
 302 dnl other compiler options
 303 dnl
 304 AC_ARG_ENABLE([debug],
 305     [AS_HELP_STRING([--enable-debug],
 306         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 307     [enable_debug="$enableval"],
 308     [enable_debug=no]
 309 )
 310 if test "x$enable_debug" = xyes; then
 311     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 312     if test "x$GCC_FOR_BUILD" = xyes; then
 313         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 314     fi
 315     if test "x$GXX_FOR_BUILD" = xyes; then
 316         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 317     fi
 318
 319     DEFINES="$DEFINES -DDEBUG"
 320     if test "x$GCC" = xyes; then
 321         CFLAGS="$CFLAGS -g -O0"
 322     fi
 323     if test "x$GXX" = xyes; then
 324         CXXFLAGS="$CXXFLAGS -g -O0"
 325     fi
 326 fi
 327
 328 dnl
 329 dnl library names
 330 dnl
 331 LIB_PREFIX_GLOB='lib'
 332 LIB_VERSION_SEPARATOR='.'
 333 if test "$enable_static" = yes; then
 334     LIB_EXTENSION='a'
 335 else
 336     case "$host_os" in
 337     darwin* )
 338         LIB_EXTENSION='dylib' ;;
 339     cygwin* )
 340         dnl prefix can be 'cyg' or 'lib'
 341         LIB_PREFIX_GLOB='???'
 342         LIB_VERSION_SEPARATOR='-'
 343         LIB_EXTENSION='dll' ;;
 344     aix* )
 345         LIB_EXTENSION='a' ;;
 346     * )
 347         LIB_EXTENSION='so' ;;
 348     esac
 349 fi
 350 AC_ARG_WITH([gl-lib-name],
 351   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 352     [specify GL library name @<:@default=GL@:>@])],
 353   [GL_LIB=$withval],
 354   [GL_LIB=GL])
 355 AC_ARG_WITH([osmesa-lib-name],
 356   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 357     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 358   [OSMESA_LIB=$withval],
 359   [OSMESA_LIB=OSMesa])
 360 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 361 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 362
 363 dnl
 364 dnl Mangled Mesa support
 365 dnl
 366 AC_ARG_ENABLE([mangling],
 367   [AS_HELP_STRING([--enable-mangling],
 368     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 369   [enable_mangling="${enableval}"],
 370   [enable_mangling=no]
 371 )
 372 if test "x${enable_mangling}" = "xyes" ; then
 373   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 374   GL_LIB="Mangled${GL_LIB}"
 375   OSMESA_LIB="Mangled${OSMESA_LIB}"
 376 fi
 377 AC_SUBST([GL_LIB])
 378 AC_SUBST([OSMESA_LIB])
 379
 380 dnl
 381 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 382 dnl
 383 AC_ARG_ENABLE([texture-float],
 384     [AS_HELP_STRING([--enable-texture-float],
 385         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 386     [enable_texture_float="$enableval"],
 387     [enable_texture_float=no]
 388 )
 389 if test "x$enable_texture_float" = xyes; then
 390     AC_MSG_WARN([Floating-point textures enabled.])
 391     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 392     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 393 fi
 394
 395 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 396 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 397 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 398 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 399 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 400 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 401 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 402
 403 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410
 411 AC_SUBST([GL_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([EGL_LIB_GLOB])
 421 AC_SUBST([GLESv1_CM_LIB_GLOB])
 422 AC_SUBST([GLESv2_LIB_GLOB])
 423 AC_SUBST([VG_LIB_GLOB])
 424 AC_SUBST([GLAPI_LIB_GLOB])
 425
 426 dnl
 427 dnl Arch/platform-specific settings
 428 dnl
 429 AC_ARG_ENABLE([asm],
 430     [AS_HELP_STRING([--disable-asm],
 431         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 432     [enable_asm="$enableval"],
 433     [enable_asm=yes]
 434 )
 435 asm_arch=""
 436 AC_MSG_CHECKING([whether to enable assembly])
 437 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 438 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 439 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 440     case "$host_cpu" in
 441     i?86 | x86_64)
 442         enable_asm=no
 443         AC_MSG_RESULT([no, cross compiling])
 444         ;;
 445     esac
 446 fi
 447 # check for supported arches
 448 if test "x$enable_asm" = xyes; then
 449     case "$host_cpu" in
 450     i?86)
 451         case "$host_os" in
 452         linux* | *freebsd* | dragonfly* | *netbsd*)
 453             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 454             ;;
 455         gnu*)
 456             asm_arch=x86
 457             ;;
 458         esac
 459         ;;
 460     x86_64)
 461         case "$host_os" in
 462         linux* | *freebsd* | dragonfly* | *netbsd*)
 463             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 464             ;;
 465         esac
 466         ;;
 467     sparc*)
 468         case "$host_os" in
 469         linux*)
 470             asm_arch=sparc
 471             ;;
 472         esac
 473         ;;
 474     esac
 475
 476     case "$asm_arch" in
 477     x86)
 478         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 479         AC_MSG_RESULT([yes, x86])
 480         ;;
 481     x86_64)
 482         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 483         AC_MSG_RESULT([yes, x86_64])
 484         ;;
 485     sparc)
 486         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 487         AC_MSG_RESULT([yes, sparc])
 488         ;;
 489     *)
 490         AC_MSG_RESULT([no, platform not supported])
 491         ;;
 492     esac
 493 fi
 494
 495 dnl Check to see if dlopen is in default libraries (like Solaris, which
 496 dnl has it in libc), or if libdl is needed to get it.
 497 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 498     [AC_CHECK_LIB([dl], [dlopen],
 499        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 500 AC_SUBST([DLOPEN_LIBS])
 501
 502 case "$host_os" in
 503 darwin*|mingw*)
 504     ;;
 505 *)
 506     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 507                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 508                                  [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 509     AC_SUBST([CLOCK_LIB])
 510     ;;
 511 esac
 512
 513 dnl See if posix_memalign is available
 514 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 515
 516 dnl Check for pthreads
 517 AX_PTHREAD
 518 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 519 dnl to -pthread, which causes problems if we need -lpthread to appear in
 520 dnl pkgconfig files.
 521 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 522
 523 dnl SELinux awareness.
 524 AC_ARG_ENABLE([selinux],
 525     [AS_HELP_STRING([--enable-selinux],
 526         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 527     [MESA_SELINUX="$enableval"],
 528     [MESA_SELINUX=no])
 529 if test "x$enable_selinux" = "xyes"; then
 530     AC_CHECK_HEADER([selinux/selinux.h],[],
 531                     [AC_MSG_ERROR([SELinux headers not found])])
 532     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 533                  [AC_MSG_ERROR([SELinux library not found])])
 534     SELINUX_LIBS="-lselinux"
 535     DEFINES="$DEFINES -DMESA_SELINUX"
 536 fi
 537 AC_SUBST([SELINUX_LIBS])
 538
 539 dnl Options for APIs
 540 AC_ARG_ENABLE([opengl],
 541     [AS_HELP_STRING([--disable-opengl],
 542         [disable support for standard OpenGL API @<:@default=no@:>@])],
 543     [enable_opengl="$enableval"],
 544     [enable_opengl=yes])
 545 AC_ARG_ENABLE([gles1],
 546     [AS_HELP_STRING([--enable-gles1],
 547         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 548     [enable_gles1="$enableval"],
 549     [enable_gles1=no])
 550 AC_ARG_ENABLE([gles2],
 551     [AS_HELP_STRING([--enable-gles2],
 552         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 553     [enable_gles2="$enableval"],
 554     [enable_gles2=no])
 555 AC_ARG_ENABLE([openvg],
 556     [AS_HELP_STRING([--enable-openvg],
 557         [enable support for OpenVG API @<:@default=no@:>@])],
 558     [enable_openvg="$enableval"],
 559     [enable_openvg=no])
 560
 561 AC_ARG_ENABLE([dri],
 562     [AS_HELP_STRING([--enable-dri],
 563         [enable DRI modules @<:@default=enabled@:>@])],
 564     [enable_dri="$enableval"],
 565     [enable_dri=yes])
 566 AC_ARG_ENABLE([glx],
 567     [AS_HELP_STRING([--enable-glx],
 568         [enable GLX library @<:@default=enabled@:>@])],
 569     [enable_glx="$enableval"],
 570     [enable_glx=yes])
 571 AC_ARG_ENABLE([osmesa],
 572     [AS_HELP_STRING([--enable-osmesa],
 573         [enable OSMesa library @<:@default=disabled@:>@])],
 574     [enable_osmesa="$enableval"],
 575     [enable_osmesa=no])
 576 AC_ARG_ENABLE([egl],
 577     [AS_HELP_STRING([--disable-egl],
 578         [disable EGL library @<:@default=enabled@:>@])],
 579     [enable_egl="$enableval"],
 580     [enable_egl=yes])
 581
 582 AC_ARG_ENABLE([xorg],
 583     [AS_HELP_STRING([--enable-xorg],
 584         [enable support for X.Org DDX API @<:@default=no@:>@])],
 585     [enable_xorg="$enableval"],
 586     [enable_xorg=no])
 587 AC_ARG_ENABLE([xa],
 588     [AS_HELP_STRING([--enable-xa],
 589         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 590     [enable_xa="$enableval"],
 591     [enable_xa=no])
 592 AC_ARG_ENABLE([gbm],
 593    [AS_HELP_STRING([--enable-gbm],
 594          [enable gbm library @<:@default=auto@:>@])],
 595    [enable_gbm="$enableval"],
 596    [enable_gbm=auto])
 597
 598 AC_ARG_ENABLE([xvmc],
 599    [AS_HELP_STRING([--enable-xvmc],
 600          [enable xvmc library @<:@default=auto@:>@])],
 601    [enable_xvmc="$enableval"],
 602    [enable_xvmc=auto])
 603 AC_ARG_ENABLE([vdpau],
 604    [AS_HELP_STRING([--enable-vdpau],
 605          [enable vdpau library @<:@default=auto@:>@])],
 606    [enable_vdpau="$enableval"],
 607    [enable_vdpau=auto])
 608 AC_ARG_ENABLE([opencl],
 609    [AS_HELP_STRING([--enable-opencl],
 610          [enable OpenCL library NOTE: Enabling this option will also enable
 611           --with-llvm-shared-libs
 612           @<:@default=no@:>@])],
 613    [],
 614    [enable_opencl=no])
 615 AC_ARG_ENABLE([xlib_glx],
 616     [AS_HELP_STRING([--enable-xlib-glx],
 617         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 618     [enable_xlib_glx="$enableval"],
 619     [enable_xlib_glx=no])
 620 AC_ARG_ENABLE([gallium_egl],
 621     [AS_HELP_STRING([--enable-gallium-egl],
 622         [enable optional EGL state tracker (not required
 623          for EGL support in Gallium with OpenGL and OpenGL ES)
 624          @<:@default=disable@:>@])],
 625     [enable_gallium_egl="$enableval"],
 626     [enable_gallium_egl=no])
 627 AC_ARG_ENABLE([gallium_gbm],
 628     [AS_HELP_STRING([--enable-gallium-gbm],
 629         [enable optional gbm state tracker (not required for
 630          gbm support in Gallium)
 631          @<:@default=auto@:>@])],
 632     [enable_gallium_gbm="$enableval"],
 633     [enable_gallium_gbm=auto])
 634
 635 AC_ARG_ENABLE([r600-llvm-compiler],
 636     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 637         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 638     [enable_r600_llvm="$enableval"],
 639     [enable_r600_llvm=no])
 640
 641 AC_ARG_ENABLE([gallium_tests],
 642     [AS_HELP_STRING([--enable-gallium-tests],
 643         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 644     [enable_gallium_tests="$enableval"],
 645     [enable_gallium_tests=no])
 646
 647 # Option for Gallium drivers
 648
 649 # Keep this in sync with the --with-gallium-drivers help string default value
 650 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 651
 652 AC_ARG_WITH([gallium-drivers],
 653     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 654         [comma delimited Gallium drivers list, e.g.
 655         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast"
 656         @<:@default=r300,r600,svga,swrast@:>@])],
 657     [with_gallium_drivers="$withval"],
 658     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 659
 660 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 661 # here so that the script doesn't choke on an unknown driver name later.
 662 case "$with_gallium_drivers" in
 663     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 664     no) with_gallium_drivers='' ;;
 665 esac
 666
 667 if test "x$enable_opengl" = xno -a \
 668         "x$enable_gles1" = xno -a \
 669         "x$enable_gles2" = xno -a \
 670         "x$enable_openvg" = xno -a \
 671         "x$enable_xorg" = xno -a \
 672         "x$enable_xa" = xno -a \
 673         "x$enable_xvmc" = xno -a \
 674         "x$enable_vdpau" = xno -a \
 675         "x$enable_opencl" = xno; then
 676     AC_MSG_ERROR([at least one API should be enabled])
 677 fi
 678
 679 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
 680 if test "x$enable_opengl" = xno -a \
 681         "x$enable_gles1" = xyes; then
 682     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
 683 fi
 684
 685 if test "x$enable_opengl" = xno -a \
 686         "x$enable_gles2" = xyes; then
 687     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
 688 fi
 689
 690 API_DEFINES=""
 691 AC_SUBST([API_DEFINES])
 692
 693 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
 694 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
 695 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
 696 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
 697                                         "x$enable_gles1" = xyes -o \
 698                                         "x$enable_gles2" = xyes)
 699
 700 if test "x$enable_glx" = xno; then
 701     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 702     enable_xlib_glx=no
 703 fi
 704
 705 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 706     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 707 fi
 708
 709 if test "x$enable_opengl$enable_xlib_glx" = xnoyes; then
 710     AC_MSG_ERROR([Xlib-GLX cannot be built without OpenGL])
 711 fi
 712
 713 # Disable GLX if OpenGL is not enabled
 714 if test "x$enable_glx$enable_opengl" = xyesno; then
 715     AC_MSG_WARN([OpenGL not enabled, disabling GLX])
 716     enable_glx=no
 717 fi
 718
 719 # Disable GLX if DRI and Xlib-GLX are not enabled
 720 if test "x$enable_glx" = xyes -a \
 721         "x$enable_dri" = xno -a \
 722         "x$enable_xlib_glx" = xno; then
 723     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 724     enable_glx=no
 725 fi
 726
 727 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xyes -a \
 728                                   "x$enable_dri" = xyes)
 729 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 730 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 731                                   "x$enable_osmesa" = xyes)
 732
 733 AC_ARG_ENABLE([shared-glapi],
 734     [AS_HELP_STRING([--enable-shared-glapi],
 735         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 736     [enable_shared_glapi="$enableval"],
 737     [enable_shared_glapi="$enable_dri"])
 738
 739 # Shared GLAPI is only useful for DRI
 740 if test "x$enable_dri" = xno; then
 741     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 742     enable_shared_glapi=no
 743 fi
 744
 745 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 746
 747 dnl
 748 dnl Driver specific build directories
 749 dnl
 750 GALLIUM_TARGET_DIRS=""
 751 GALLIUM_WINSYS_DIRS="sw"
 752 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 753 GALLIUM_STATE_TRACKERS_DIRS=""
 754
 755 case "x$enable_glx$enable_xlib_glx" in
 756 xyesyes)
 757     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 758     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 759     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 760     NEED_WINSYS_XLIB="yes"
 761     ;;
 762 esac
 763
 764 if test "x$enable_dri" = xyes; then
 765     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 766     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 767 fi
 768
 769 if test "x$enable_osmesa" = xyes; then
 770     GALLIUM_STATE_TRACKERS_DIRS="osmesa $GALLIUM_STATE_TRACKERS_DIRS"
 771     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS osmesa"
 772 fi
 773
 774 AC_SUBST([MESA_LLVM])
 775
 776 # Check for libdrm
 777 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 778                   [have_libdrm=yes], [have_libdrm=no])
 779
 780 if test "x$enable_dri" = xyes; then
 781     # DRI must be shared, I think
 782     if test "$enable_static" = yes; then
 783         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 784     fi
 785
 786     # not a hard requirement as swrast does not depend on it
 787     if test "x$have_libdrm" = xyes; then
 788         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 789     fi
 790 fi
 791
 792 dnl Direct rendering or just indirect rendering
 793 case "$host_os" in
 794 gnu*)
 795     dnl Disable by default on GNU/Hurd
 796     driglx_direct_default="no"
 797     ;;
 798 cygwin*)
 799     dnl Disable by default on cygwin
 800     driglx_direct_default="no"
 801     ;;
 802 *)
 803     driglx_direct_default="yes"
 804     ;;
 805 esac
 806 AC_ARG_ENABLE([driglx-direct],
 807     [AS_HELP_STRING([--disable-driglx-direct],
 808         [disable direct rendering in GLX and EGL for DRI \
 809             @<:@default=auto@:>@])],
 810     [driglx_direct="$enableval"],
 811     [driglx_direct="$driglx_direct_default"])
 812
 813 dnl
 814 dnl libGL configuration per driver
 815 dnl
 816 case "x$enable_glx$enable_xlib_glx" in
 817 xyesyes)
 818     # Xlib-based GLX
 819     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 820     GL_PC_REQ_PRIV="x11 xext"
 821     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 822     GL_LIB_DEPS="$XLIBGL_LIBS"
 823     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 824     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 825     ;;
 826 xyesno)
 827     # DRI-based GLX
 828     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 829     if test x"$driglx_direct" = xyes; then
 830         if test "x$have_libdrm" != xyes; then
 831             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 832         fi
 833         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 834         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 835     fi
 836
 837     # find the DRI deps for libGL
 838     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 839
 840     # add xf86vidmode if available
 841     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 842     if test "$HAVE_XF86VIDMODE" = yes ; then
 843         dri_modules="$dri_modules xxf86vm"
 844     fi
 845
 846     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 847     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 848     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 849     GL_LIB_DEPS="$DRIGL_LIBS"
 850
 851     # need DRM libs, $PTHREAD_LIBS, etc.
 852     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 853     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 854     ;;
 855 esac
 856
 857 # This is outside the case (above) so that it is invoked even for non-GLX
 858 # builds.
 859 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 860
 861 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 862 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 863 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 864 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 865
 866 AC_SUBST([X11_INCLUDES])
 867 AC_SUBST([GL_LIB_DEPS])
 868 AC_SUBST([GL_PC_REQ_PRIV])
 869 AC_SUBST([GL_PC_LIB_PRIV])
 870 AC_SUBST([GL_PC_CFLAGS])
 871 AC_SUBST([DRI_PC_REQ_PRIV])
 872 AC_SUBST([GLESv1_CM_LIB_DEPS])
 873 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 874 AC_SUBST([GLESv2_LIB_DEPS])
 875 AC_SUBST([GLESv2_PC_LIB_PRIV])
 876
 877 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 878
 879 AC_SUBST([HAVE_XF86VIDMODE])
 880
 881 dnl
 882 dnl More GLX setup
 883 dnl
 884 case "x$enable_glx$enable_xlib_glx" in
 885 xyesyes)
 886     DEFINES="$DEFINES -DUSE_XSHM"
 887     ;;
 888 xyesno)
 889     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 890     if test "x$driglx_direct" = xyes; then
 891         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 892     fi
 893     ;;
 894 esac
 895
 896 dnl
 897 dnl TLS detection
 898 dnl
 899
 900 AC_ARG_ENABLE([glx-tls],
 901     [AS_HELP_STRING([--enable-glx-tls],
 902         [enable TLS support in GLX @<:@default=disabled@:>@])],
 903     [GLX_USE_TLS="$enableval"],
 904     [GLX_USE_TLS=no])
 905 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 906
 907 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 908       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 909
 910 dnl
 911 dnl More DRI setup
 912 dnl
 913 dnl Directory for DRI drivers
 914 AC_ARG_WITH([dri-driverdir],
 915     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 916         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 917     [DRI_DRIVER_INSTALL_DIR="$withval"],
 918     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 919 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 920 dnl Extra search path for DRI drivers
 921 AC_ARG_WITH([dri-searchpath],
 922     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 923         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 924     [DRI_DRIVER_SEARCH_DIR="$withval"],
 925     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 926 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 927 dnl Which drivers to build - default is chosen by platform
 928 AC_ARG_WITH([dri-drivers],
 929     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 930         [comma delimited DRI drivers list, e.g.
 931         "swrast,i965,radeon" @<:@default=auto@:>@])],
 932     [with_dri_drivers="$withval"],
 933     [with_dri_drivers=yes])
 934 if test "x$with_dri_drivers" = x; then
 935     with_dri_drivers=no
 936 fi
 937
 938 dnl If $with_dri_drivers is yes, directories will be added through
 939 dnl platform checks
 940 DRI_DIRS=""
 941 case "$with_dri_drivers" in
 942 no) ;;
 943 yes)
 944     # classic DRI drivers
 945     if test "x$enable_opengl" = xyes; then
 946         DRI_DIRS="yes"
 947     fi
 948     ;;
 949 *)
 950     # verify the requested driver directories exist
 951     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 952     for driver in $dri_drivers; do
 953         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 954             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 955     done
 956     DRI_DIRS="$dri_drivers"
 957     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 958         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 959     fi
 960     ;;
 961 esac
 962
 963 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 964 if test "x$enable_dri" = xyes; then
 965     # Platform specific settings and drivers to build
 966     case "$host_os" in
 967     linux*)
 968         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
 969         DEFINES="$DEFINES -DHAVE_ALIAS"
 970
 971         case "$host_cpu" in
 972         x86_64)
 973             if test "x$DRI_DIRS" = "xyes"; then
 974                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 975             fi
 976             ;;
 977         powerpc*)
 978             # Build only the drivers for cards that exist on PowerPC.
 979             if test "x$DRI_DIRS" = "xyes"; then
 980                 DRI_DIRS="r200 radeon swrast"
 981             fi
 982             ;;
 983         sparc*)
 984             # Build only the drivers for cards that exist on sparc
 985             if test "x$DRI_DIRS" = "xyes"; then
 986                 DRI_DIRS="r200 radeon swrast"
 987             fi
 988             ;;
 989         esac
 990         ;;
 991     freebsd* | dragonfly* | *netbsd*)
 992         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
 993         DEFINES="$DEFINES -DHAVE_ALIAS"
 994
 995         if test "x$DRI_DIRS" = "xyes"; then
 996             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
 997         fi
 998         ;;
 999     gnu*)
1000         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1001         DEFINES="$DEFINES -DHAVE_ALIAS"
1002         ;;
1003     solaris*)
1004         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1005         ;;
1006     cygwin*)
1007         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1"
1008         if test "x$DRI_DIRS" = "xyes"; then
1009             DRI_DIRS="swrast"
1010         fi
1011         ;;
1012     esac
1013
1014     # default drivers
1015     if test "x$DRI_DIRS" = "xyes"; then
1016         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1017     fi
1018
1019     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1020
1021     # Check for expat
1022     EXPAT_INCLUDES=""
1023     EXPAT_LIB=-lexpat
1024     AC_ARG_WITH([expat],
1025         [AS_HELP_STRING([--with-expat=DIR],
1026             [expat install directory])],[
1027         EXPAT_INCLUDES="-I$withval/include"
1028         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1029         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1030         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1031         ])
1032     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1033     save_LIBS="$LIBS"
1034     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1035         [AC_MSG_ERROR([Expat required for DRI.])])
1036     LIBS="$save_LIBS"
1037
1038     # If we are building any DRI driver other than swrast.
1039     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1040         # ... libdrm is required
1041         if test "x$have_libdrm" != xyes; then
1042             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1043         fi
1044         # ... and build dricommon
1045         HAVE_COMMON_DRI=yes
1046     fi
1047
1048     # put all the necessary libs together
1049     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1050     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1051 fi
1052 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1053 AC_SUBST([EXPAT_INCLUDES])
1054 AC_SUBST([DRI_LIB_DEPS])
1055 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1056
1057 case $DRI_DIRS in
1058 *i915*|*i965*)
1059     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1060
1061     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1062         case $d in
1063         i915)
1064             HAVE_I915_DRI=yes;
1065             ;;
1066         i965)
1067             HAVE_I965_DRI=yes;
1068             ;;
1069         esac
1070     done
1071
1072     ;;
1073 esac
1074
1075 case $DRI_DIRS in
1076 *nouveau*)
1077     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1078     HAVE_NOUVEAU_DRI=yes;
1079     ;;
1080 esac
1081
1082 case $DRI_DIRS in
1083 *radeon*|*r200*)
1084     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1085
1086     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1087         case $d in
1088         radeon)
1089             HAVE_RADEON_DRI=yes;
1090             ;;
1091         r200)
1092             HAVE_R200_DRI=yes;
1093             ;;
1094         esac
1095     done
1096
1097     ;;
1098 esac
1099
1100 case $DRI_DIRS in
1101 *swrast*)
1102     HAVE_SWRAST_DRI=yes;
1103     ;;
1104 esac
1105
1106 dnl
1107 dnl OSMesa configuration
1108 dnl
1109
1110 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1111 AC_ARG_WITH([osmesa-bits],
1112     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1113         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1114     [osmesa_bits="$withval"],
1115     [osmesa_bits=8])
1116 if test "x$osmesa_bits" != x8; then
1117     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1118         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1119         osmesa_bits=8
1120     fi
1121 fi
1122 case "x$osmesa_bits" in
1123 x8)
1124     OSMESA_LIB="${OSMESA_LIB}"
1125     ;;
1126 x16|x32)
1127     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1128     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1129     ;;
1130 *)
1131     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1132     ;;
1133 esac
1134
1135 if test "x$enable_osmesa" = xyes; then
1136     # only link libraries with osmesa if shared
1137     if test "$enable_static" = no; then
1138         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1139     else
1140         OSMESA_LIB_DEPS=""
1141     fi
1142     OSMESA_MESA_DEPS=""
1143     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1144 fi
1145
1146 AC_SUBST([OSMESA_LIB_DEPS])
1147 AC_SUBST([OSMESA_MESA_DEPS])
1148 AC_SUBST([OSMESA_PC_REQ])
1149 AC_SUBST([OSMESA_PC_LIB_PRIV])
1150
1151 dnl
1152 dnl gbm configuration
1153 dnl
1154 if test "x$enable_gbm" = xauto; then
1155     case "$with_egl_platforms" in
1156         *drm*)
1157             enable_gbm=yes ;;
1158          *)
1159             enable_gbm=no ;;
1160     esac
1161 fi
1162 if test "x$enable_gbm" = xyes; then
1163     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1164                       AC_MSG_ERROR([gbm needs udev]))
1165
1166     if test "x$enable_dri" = xyes; then
1167         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1168         if test "x$enable_shared_glapi" = xno; then
1169             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1170         fi
1171     fi
1172 fi
1173 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1174 GBM_PC_REQ_PRIV="libudev"
1175 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1176 AC_SUBST([GBM_PC_REQ_PRIV])
1177 AC_SUBST([GBM_PC_LIB_PRIV])
1178
1179 dnl
1180 dnl EGL configuration
1181 dnl
1182 EGL_CLIENT_APIS=""
1183
1184 if test "x$enable_egl" = xyes; then
1185     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1186
1187     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1188
1189     if test "$enable_static" != yes; then
1190         # build egl_glx when libGL is built
1191         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1192                           [have_libudev=yes],[have_libudev=no])
1193         if test "$have_libudev" = yes; then
1194             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1195         fi
1196
1197         if test "x$enable_dri" = xyes; then
1198             HAVE_EGL_DRIVER_DRI2=1
1199         fi
1200
1201     fi
1202 fi
1203 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1204 AC_SUBST([EGL_LIB_DEPS])
1205
1206 dnl
1207 dnl EGL Gallium configuration
1208 dnl
1209 if test "x$enable_gallium_egl" = xyes; then
1210     if test "x$with_gallium_drivers" = x; then
1211         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1212     fi
1213     if test "x$enable_egl" = xno; then
1214         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1215     fi
1216     if test "x$have_libdrm" != xyes; then
1217         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1218     fi
1219
1220     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1221     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1222 fi
1223 AM_CONDITIONAL(HAVE_GALLIUM_EGL, test "x$enable_gallium_egl" = xyes)
1224
1225 dnl
1226 dnl gbm Gallium configuration
1227 dnl
1228 if test "x$enable_gallium_gbm" = xauto; then
1229     case "$enable_gbm$enable_gallium_egl$enable_dri$with_egl_platforms" in
1230         yesyesyes*drm*)
1231             enable_gallium_gbm=yes ;;
1232          *)
1233             enable_gallium_gbm=no ;;
1234     esac
1235 fi
1236 if test "x$enable_gallium_gbm" = xyes; then
1237     if test "x$with_gallium_drivers" = x; then
1238         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1239     fi
1240     if test "x$enable_gbm" = xno; then
1241         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1242     fi
1243     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1244     if test "x$enable_dri" = xno; then
1245         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1246     fi
1247
1248     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1249     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1250     enable_gallium_loader=yes
1251 fi
1252 AM_CONDITIONAL(HAVE_GALLIUM_GBM, test "x$enable_gallium_gbm" = xyes)
1253
1254 dnl
1255 dnl X.Org DDX configuration
1256 dnl
1257 if test "x$enable_xorg" = xyes; then
1258     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1259     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1260     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1261     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1262         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1263         HAVE_XEXTPROTO_71="no")
1264     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1265 fi
1266 AM_CONDITIONAL(HAVE_ST_XORG, test "x$enable_xorg" = xyes)
1267
1268 dnl
1269 dnl XA configuration
1270 dnl
1271 if test "x$enable_xa" = xyes; then
1272 AC_PROG_AWK
1273 AC_PROG_GREP
1274 AC_CHECK_PROG(NM, nm, "nm")
1275 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1276 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1277 enable_xa=no
1278 fi
1279 fi
1280 if test "x$enable_xa" = xyes; then
1281     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1282     AC_SUBST(AWK)
1283     AC_SUBST(GREP)
1284     AC_SUBST(NM)
1285 fi
1286 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1287
1288 dnl
1289 dnl OpenVG configuration
1290 dnl
1291 VG_LIB_DEPS=""
1292
1293 if test "x$enable_openvg" = xyes; then
1294     if test "x$enable_egl" = xno; then
1295         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1296     fi
1297     if test "x$with_gallium_drivers" = x; then
1298         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1299     fi
1300     if test "x$enable_gallium_egl" = xno; then
1301         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1302     fi
1303
1304     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1305     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1306     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1307     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1308     AC_SUBST([VG_PC_LIB_PRIV])
1309 fi
1310 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1311
1312 dnl
1313 dnl Gallium G3DVL configuration
1314 dnl
1315 if test -n "$with_gallium_drivers"; then
1316     if test "x$enable_xvmc" = xauto; then
1317         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1318     fi
1319
1320     if test "x$enable_vdpau" = xauto; then
1321         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1322     fi
1323 fi
1324
1325 if test "x$enable_xvmc" = xyes; then
1326     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1327     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1328 fi
1329 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1330
1331 if test "x$enable_vdpau" = xyes; then
1332     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1333     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1334 fi
1335 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1336
1337 dnl
1338 dnl OpenCL configuration
1339 dnl
1340
1341 AC_ARG_WITH([libclc-path],
1342    [AS_HELP_STRING([--with-libclc-path],
1343          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1344    [LIBCLC_PATH="$withval"],
1345    [LIBCLC_PATH=""])
1346
1347 if test "x$LIBCLC_PATH" != x; then
1348    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1349                   Please review the updated build instructions for clover:
1350                   http://dri.freedesktop.org/wiki/GalliumCompute])
1351 fi
1352
1353
1354 AC_ARG_WITH([clang-libdir],
1355    [AS_HELP_STRING([--with-clang-libdir],
1356          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1357    [CLANG_LIBDIR="$withval"],
1358    [CLANG_LIBDIR=""])
1359
1360 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1361 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1362 AC_SUBST([LIBCLC_INCLUDEDIR])
1363 AC_SUBST([LIBCLC_LIBEXECDIR])
1364
1365 if test "x$enable_opencl" = xyes; then
1366     if test "x$with_gallium_drivers" = x; then
1367         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1368     fi
1369
1370     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1371         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1372     fi
1373
1374     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1375         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1376     fi
1377
1378     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1379     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1380     enable_gallium_loader=yes
1381 fi
1382 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1383
1384 dnl
1385 dnl Gallium configuration
1386 dnl
1387 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1388
1389 AC_SUBST([LLVM_BINDIR])
1390 AC_SUBST([LLVM_CFLAGS])
1391 AC_SUBST([LLVM_CPPFLAGS])
1392 AC_SUBST([LLVM_CXXFLAGS])
1393 AC_SUBST([LLVM_LIBDIR])
1394 AC_SUBST([LLVM_LIBS])
1395 AC_SUBST([LLVM_LDFLAGS])
1396 AC_SUBST([LLVM_INCLUDEDIR])
1397 AC_SUBST([LLVM_VERSION])
1398 AC_SUBST([CLANG_RESOURCE_DIR])
1399
1400 case "x$enable_opengl$enable_gles1$enable_gles2" in
1401 x*yes*)
1402     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1403     ;;
1404 esac
1405
1406 AC_SUBST([VG_LIB_DEPS])
1407 AC_SUBST([EGL_CLIENT_APIS])
1408
1409 dnl
1410 dnl EGL Platforms configuration
1411 dnl
1412 AC_ARG_WITH([egl-platforms],
1413     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1414         [comma delimited native platforms libEGL supports, e.g.
1415         "x11,drm" @<:@default=auto@:>@])],
1416     [with_egl_platforms="$withval"],
1417     [if test "x$enable_egl" = xyes; then
1418         with_egl_platforms="x11"
1419     else
1420         with_egl_platforms=""
1421     fi])
1422
1423 EGL_PLATFORMS=""
1424
1425 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1426     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1427 fi
1428
1429 # Do per-EGL platform setups and checks
1430 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1431 for plat in $egl_platforms; do
1432         case "$plat" in
1433         wayland)
1434                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1435                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1436
1437                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1438                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1439                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1440                 ;;
1441
1442         x11)
1443                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1444
1445                 if test "x$enable_glx" = xyes; then
1446                         HAVE_EGL_DRIVER_GLX=1
1447                 fi
1448                 ;;
1449
1450         drm)
1451                 test "x$enable_gbm" = "xno" &&
1452                         AC_MSG_ERROR([EGL platform drm needs gbm])
1453                 ;;
1454
1455         android|fbdev|gdi|null)
1456                 ;;
1457
1458         *)
1459                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1460                 ;;
1461         esac
1462
1463         case "$plat$have_libudev" in
1464                 waylandno|drmno)
1465                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1466         esac
1467 done
1468
1469 # libEGL wants to default to the first platform specified in
1470 # ./configure.  parse that here.
1471 if test "x$egl_platforms" != "x"; then
1472     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1473     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1474 else
1475     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1476 fi
1477
1478 EGL_PLATFORMS="$egl_platforms"
1479
1480 if echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1; then
1481     NEED_WINSYS_XLIB=yes
1482 fi
1483 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1484 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1485 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1486 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1487 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1488
1489 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1490 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1491
1492 AC_SUBST([EGL_NATIVE_PLATFORM])
1493 AC_SUBST([EGL_PLATFORMS])
1494 AC_SUBST([EGL_CFLAGS])
1495
1496 AC_ARG_WITH([egl-driver-dir],
1497     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1498                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1499     [EGL_DRIVER_INSTALL_DIR="$withval"],
1500     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1501 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1502
1503 AC_ARG_WITH([xorg-driver-dir],
1504     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1505                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1506     [XORG_DRIVER_INSTALL_DIR="$withval"],
1507     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1508 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1509
1510 AC_ARG_WITH([max-width],
1511     [AS_HELP_STRING([--with-max-width=N],
1512                     [Maximum framebuffer width (4096)])],
1513     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1514      AS_IF([test "${withval}" -gt "4096"],
1515            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1516 )
1517 AC_ARG_WITH([max-height],
1518     [AS_HELP_STRING([--with-max-height=N],
1519                     [Maximum framebuffer height (4096)])],
1520     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1521      AS_IF([test "${withval}" -gt "4096"],
1522            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1523 )
1524
1525 dnl
1526 dnl Gallium LLVM
1527 dnl
1528 AC_ARG_ENABLE([gallium-llvm],
1529     [AS_HELP_STRING([--enable-gallium-llvm],
1530         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1531     [enable_gallium_llvm="$enableval"],
1532     [enable_gallium_llvm=auto])
1533
1534 AC_ARG_WITH([llvm-shared-libs],
1535     [AS_HELP_STRING([--with-llvm-shared-libs],
1536         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1537     [],
1538     [with_llvm_shared_libs=no])
1539 AS_IF([test x$enable_opencl = xyes],
1540     [
1541         AC_MSG_WARN([OpenCL required, forcing LLVM shared libraries])
1542         with_llvm_shared_libs=yes
1543     ])
1544
1545 AC_ARG_WITH([llvm-prefix],
1546     [AS_HELP_STRING([--with-llvm-prefix],
1547         [Prefix for LLVM installations in non-standard locations])],
1548     [llvm_prefix="$withval"],
1549     [llvm_prefix=""])
1550
1551
1552 # Call this inside ` ` to get the return value.
1553 # $1 is the llvm-config command with arguments.
1554 strip_unwanted_llvm_flags() {
1555     # Use \> (marks the end of the word)
1556     echo `$1` | sed \
1557         -e 's/-DNDEBUG\>//g' \
1558         -e 's/-pedantic\>//g' \
1559         -e 's/-Wcovered-switch-default\>//g' \
1560         -e 's/-O.\>//g' \
1561         -e 's/-g\>//g' \
1562         -e 's/-Wall\>//g' \
1563         -e 's/-fomit-frame-pointer\>//g'
1564 }
1565
1566
1567 if test "x$with_gallium_drivers" = x; then
1568     enable_gallium_llvm=no
1569 fi
1570 if test "x$enable_gallium_llvm" = xauto; then
1571     case "$host_cpu" in
1572     i*86|x86_64) enable_gallium_llvm=yes;;
1573     esac
1574 fi
1575 if test "x$enable_gallium_llvm" = xyes; then
1576     if test "x$llvm_prefix" != x; then
1577         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1578     else
1579         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1580     fi
1581
1582     if test "x$LLVM_CONFIG" != xno; then
1583         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1584         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1585         LLVM_COMPONENTS="engine bitwriter"
1586         if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1587             LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1588         fi
1589
1590         if test "x$enable_opencl" = xyes; then
1591             LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1592             # LLVM 3.3 >= 177971 requires IRReader
1593             if $LLVM_CONFIG --components | grep -q '\<irreader\>'; then
1594                 LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader"
1595             fi
1596         fi
1597         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1598         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1599         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1600         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1601         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1602         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1603         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1604         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1605         MESA_LLVM=1
1606
1607         dnl Check for Clang interanl headers
1608         if test "x$enable_opencl" = xyes; then
1609             if test "x$CLANG_LIBDIR" = x; then
1610                 CLANG_LIBDIR=${LLVM_LIBDIR}
1611             fi
1612             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1613             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1614                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1615         fi
1616     else
1617         MESA_LLVM=0
1618         LLVM_VERSION_INT=0
1619     fi
1620 else
1621     MESA_LLVM=0
1622     LLVM_VERSION_INT=0
1623 fi
1624
1625 dnl Directory for XVMC libs
1626 AC_ARG_WITH([xvmc-libdir],
1627     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1628         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1629     [XVMC_LIB_INSTALL_DIR="$withval"],
1630     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1631 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1632
1633 dnl
1634 dnl Gallium Tests
1635 dnl
1636 if test "x$enable_gallium_tests" = xyes; then
1637     enable_gallium_loader=yes
1638 fi
1639 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
1640
1641 if test "x$enable_gallium_loader" = xyes; then
1642     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1643 fi
1644 AM_CONDITIONAL(NEED_GALLIUM_LOADER, test "x$enable_gallium_loader" = xyes)
1645
1646 dnl Directory for VDPAU libs
1647 AC_ARG_WITH([vdpau-libdir],
1648     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1649         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1650     [VDPAU_LIB_INSTALL_DIR="$withval"],
1651     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1652 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1653
1654 dnl Directory for OpenCL libs
1655 AC_ARG_WITH([opencl-libdir],
1656     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1657         [directory for auxiliary libraries used by the OpenCL implementation @<:@default=${libdir}/opencl@:>@])],
1658     [OPENCL_LIB_INSTALL_DIR="$withval"],
1659     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1660 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1661
1662 dnl
1663 dnl Gallium helper functions
1664 dnl
1665 gallium_check_st() {
1666     if test "x$NEED_NONNULL_WINSYS" = xyes; then
1667          if test "x$have_libdrm" != xyes; then
1668             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1669          fi
1670          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1671     fi
1672     if test "x$enable_dri" = xyes && test "x$2" != x; then
1673          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1674          HAVE_COMMON_DRI=yes
1675     fi
1676     if test "x$enable_xorg" = xyes && test "x$3" != x; then
1677          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1678     fi
1679     if test "x$enable_xa" = xyes && test "x$4" != x; then
1680          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1681     fi
1682     if test "x$enable_xvmc" = xyes && test "x$5" != x; then
1683          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1684     fi
1685     if test "x$enable_vdpau" = xyes && test "x$6" != x; then
1686          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1687     fi
1688 }
1689
1690 gallium_require_llvm() {
1691     if test "x$MESA_LLVM" = x0; then
1692         case "$host_cpu" in
1693         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1694         esac
1695     fi
1696 }
1697
1698 gallium_require_drm_loader() {
1699     if test "x$enable_gallium_loader" = xyes; then
1700         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1701                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1702         if test "x$have_libdrm" != xyes; then
1703             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1704         fi
1705         enable_gallium_drm_loader=yes
1706     fi
1707 }
1708
1709 radeon_llvm_check() {
1710     LLVM_REQUIRED_VERSION_MAJOR="3"
1711     LLVM_REQUIRED_VERSION_MINOR="3"
1712     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1713         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required for r600g and radeonsi.])
1714     fi
1715     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1716         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1717                       sources with the --enable-experimental-targets=R600
1718                       configure flag])
1719     fi
1720     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600 bitreader"
1721     NEED_RADEON_LLVM=yes
1722     AC_CHECK_LIB([elf], [elf_memory], [ELF_LIB=-lelf],
1723                                  [AC_MSG_ERROR([radeonsi and r600g require libelf when using LLVM])])
1724 }
1725
1726 dnl Gallium drivers
1727 if test "x$enable_dri" = xyes -o "x$enable_xorg" = xyes -o \
1728         "x$enable_xa" = xyes -o "x$enable_xvmc" = xyes -o \
1729         "x$enable_vdpau" = xyes; then
1730     NEED_NONNULL_WINSYS=yes
1731 fi
1732 AM_CONDITIONAL(NEED_NONNULL_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes)
1733
1734 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1735 if test "x$with_gallium_drivers" != x; then
1736     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1737     for driver in $gallium_drivers; do
1738         case "x$driver" in
1739         xsvga)
1740             HAVE_GALLIUM_SVGA=yes
1741             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1742             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1743             ;;
1744         xi915)
1745             HAVE_GALLIUM_I915=yes
1746             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1747             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1748             if test "x$MESA_LLVM" = x1; then
1749                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1750             fi
1751             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1752             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1753             ;;
1754         xilo)
1755             HAVE_GALLIUM_ILO=yes
1756             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1757             gallium_require_drm_loader
1758             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS ilo"
1759             gallium_check_st "intel/drm" "dri-ilo"
1760             ;;
1761         xr300)
1762             HAVE_GALLIUM_R300=yes
1763             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1764             gallium_require_llvm "Gallium R300"
1765             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1766             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1767             ;;
1768         xr600)
1769             HAVE_GALLIUM_R600=yes
1770             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1771             gallium_require_drm_loader
1772             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1773             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1774                 radeon_llvm_check
1775                 R600_NEED_RADEON_GALLIUM=yes;
1776                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo bitreader asmparser"
1777             fi
1778             if test "x$enable_r600_llvm" = xyes; then
1779                 USE_R600_LLVM_COMPILER=yes;
1780             fi
1781             if test "x$enable_opencl" = xyes; then
1782                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1783             fi
1784             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1785             ;;
1786         xradeonsi)
1787             HAVE_GALLIUM_RADEONSI=yes
1788             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1789             gallium_require_drm_loader
1790             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1791             radeon_llvm_check
1792             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1793             ;;
1794         xnouveau)
1795             HAVE_GALLIUM_NOUVEAU=yes
1796             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1797             gallium_require_drm_loader
1798             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1799             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1800             ;;
1801         xfreedreno)
1802             HAVE_GALLIUM_FREEDRENO=yes
1803             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
1804             gallium_require_drm_loader
1805             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS freedreno"
1806             gallium_check_st "freedreno/drm" "dri-freedreno" "" "" "" ""
1807             ;;
1808         xswrast)
1809             HAVE_GALLIUM_SOFTPIPE=yes
1810             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1811             if test "x$MESA_LLVM" = x1; then
1812                 HAVE_GALLIUM_LLVMPIPE=yes
1813                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1814             fi
1815
1816             if test "x$enable_dri" = xyes; then
1817                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1818             fi
1819             if test "x$enable_vdpau" = xyes; then
1820                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1821             fi
1822             if test "x$enable_xvmc" = xyes; then
1823                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1824             fi
1825             if test "x$enable_vdpau" = xyes -o "x$enable_xvmc" = xyes; then
1826                 NEED_WINSYS_XLIB=yes
1827                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1828             fi
1829             ;;
1830         *)
1831             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1832             ;;
1833         esac
1834     done
1835 fi
1836
1837 dnl Set LLVM_LIBS - This is done after the driver configuration so
1838 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1839 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1840 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1841 dnl this was causing the same libraries to be appear multiple times
1842 dnl in LLVM_LIBS.
1843
1844 if test "x$MESA_LLVM" != x0; then
1845
1846     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1847
1848     if test "x$with_llvm_shared_libs" = xyes; then
1849         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1850         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1851         AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1852
1853         if test "x$llvm_have_one_so" = xyes; then
1854             dnl LLVM was built using auto*, so there is only one shared object.
1855             LLVM_LIBS="-l$LLVM_SO_NAME"
1856         else
1857             dnl If LLVM was built with CMake, there will be one shared object per
1858             dnl component.
1859             AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1860                     AC_MSG_ERROR([Could not find llvm shared libraries:
1861         Please make sure you have built llvm with the --enable-shared option
1862         and that your llvm libraries are installed in $LLVM_LIBDIR
1863         If you have installed your llvm libraries to a different directory you
1864         can use the --with-llvm-prefix= configure flag to specify this directory.
1865         NOTE: Mesa is attempting to use llvm shared libraries because you have
1866         passed one of the following options to configure:
1867                 --with-llvm-shared-libs
1868                 --enable-opencl
1869         If you do not want to build with llvm shared libraries and instead want to
1870         use llvm static libraries then remove these options from your configure
1871         invocation and reconfigure.]))
1872
1873            dnl We don't need to update LLVM_LIBS in this case because the LLVM
1874            dnl install uses a shared object for each compoenent and we have
1875            dnl already added all of these objects to LLVM_LIBS.
1876         fi
1877     fi
1878 fi
1879
1880 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1881 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1882 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
1883 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1884 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1885 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1886 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1887 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
1888 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1889 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1890
1891 AM_CONDITIONAL(NEED_GALLIUM_SOFTPIPE_DRIVER, test "x$HAVE_GALLIUM_SVGA" = xyes -o \
1892                                                   "x$HAVE_GALLIUM_I915" = xyes -o \
1893                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1894 AM_CONDITIONAL(NEED_GALLIUM_LLVMPIPE_DRIVER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1895                                                   "x$HAVE_GALLIUM_SOFTPIPE" = xyes -a \
1896                                                   "x$MESA_LLVM" = x1)
1897
1898 if test "x$enable_gallium_loader" = xyes; then
1899     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1900
1901     if test "x$enable_gallium_drm_loader" = xyes; then
1902         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1903         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1904                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1905         if test "x$pipe_loader_have_xcb" = xyes; then
1906             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XCB"
1907             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1908         fi
1909     fi
1910
1911     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1912     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1913 fi
1914
1915 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1916 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1917 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1918 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1919 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1920 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1921 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1922
1923 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$NEED_NONNULL_WINSYS" = xyes -a \
1924                                             "x$HAVE_GALLIUM_R300" = xyes -o \
1925                                             "x$HAVE_GALLIUM_R600" = xyes -o \
1926                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
1927 AM_CONDITIONAL(NEED_WINSYS_WRAPPER, test "x$HAVE_GALLIUM_I915" = xyes -o \
1928                                          "x$HAVE_GALLIUM_SVGA" = xyes)
1929 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$NEED_WINSYS_XLIB" = xyes)
1930 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
1931 AM_CONDITIONAL(R600_NEED_RADEON_GALLIUM, test x$R600_NEED_RADEON_GALLIUM = xyes)
1932 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1933 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1934 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1935 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1936 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1937 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1938
1939 AC_SUBST([ELF_LIB])
1940
1941 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1942                                      "x$enable_xlib_glx" = xyes -o \
1943                                      "x$enable_osmesa" = xyes)
1944 AM_CONDITIONAL(HAVE_X11_DRIVER, test "x$enable_xlib_glx" = xyes)
1945 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
1946
1947 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1948 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1949 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1950
1951 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
1952
1953 AC_SUBST([VDPAU_MAJOR], 1)
1954 AC_SUBST([VDPAU_MINOR], 0)
1955
1956 AC_SUBST([XVMC_MAJOR], 1)
1957 AC_SUBST([XVMC_MINOR], 0)
1958
1959 AC_SUBST([XA_MAJOR], 1)
1960 AC_SUBST([XA_MINOR], 0)
1961 AC_SUBST([XA_TINY], 0)
1962 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
1963
1964 dnl Restore LDFLAGS and CPPFLAGS
1965 LDFLAGS="$_SAVE_LDFLAGS"
1966 CPPFLAGS="$_SAVE_CPPFLAGS"
1967
1968 dnl Add user CFLAGS and CXXFLAGS
1969 CFLAGS="$CFLAGS $USER_CFLAGS"
1970 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
1971
1972 dnl Substitute the config
1973 AC_CONFIG_FILES([Makefile
1974                 src/Makefile
1975                 src/egl/Makefile
1976                 src/egl/drivers/Makefile
1977                 src/egl/drivers/dri2/Makefile
1978                 src/egl/drivers/glx/Makefile
1979                 src/egl/main/Makefile
1980                 src/egl/main/egl.pc
1981                 src/egl/wayland/Makefile
1982                 src/egl/wayland/wayland-drm/Makefile
1983                 src/egl/wayland/wayland-egl/Makefile
1984                 src/egl/wayland/wayland-egl/wayland-egl.pc
1985                 src/gallium/auxiliary/Makefile
1986                 src/gallium/auxiliary/pipe-loader/Makefile
1987                 src/gallium/drivers/Makefile
1988                 src/gallium/drivers/freedreno/Makefile
1989                 src/gallium/drivers/i915/Makefile
1990                 src/gallium/drivers/ilo/Makefile
1991                 src/gallium/drivers/llvmpipe/Makefile
1992                 src/gallium/drivers/nouveau/Makefile
1993                 src/gallium/drivers/nv30/Makefile
1994                 src/gallium/drivers/nv50/Makefile
1995                 src/gallium/drivers/nvc0/Makefile
1996                 src/gallium/drivers/r300/Makefile
1997                 src/gallium/drivers/r600/Makefile
1998                 src/gallium/drivers/radeon/Makefile
1999                 src/gallium/drivers/radeonsi/Makefile
2000                 src/gallium/drivers/rbug/Makefile
2001                 src/gallium/drivers/softpipe/Makefile
2002                 src/gallium/drivers/svga/Makefile
2003                 src/gallium/drivers/trace/Makefile
2004                 src/gallium/state_trackers/Makefile
2005                 src/gallium/state_trackers/clover/Makefile
2006                 src/gallium/state_trackers/dri/Makefile
2007                 src/gallium/state_trackers/dri/drm/Makefile
2008                 src/gallium/state_trackers/dri/sw/Makefile
2009                 src/gallium/state_trackers/egl/Makefile
2010                 src/gallium/state_trackers/gbm/Makefile
2011                 src/gallium/state_trackers/glx/Makefile
2012                 src/gallium/state_trackers/osmesa/Makefile
2013                 src/gallium/state_trackers/vdpau/Makefile
2014                 src/gallium/state_trackers/vega/Makefile
2015                 src/gallium/state_trackers/xa/Makefile
2016                 src/gallium/state_trackers/xorg/Makefile
2017                 src/gallium/state_trackers/xvmc/Makefile
2018                 src/gallium/targets/Makefile
2019                 src/gallium/targets/dri-freedreno/Makefile
2020                 src/gallium/targets/dri-i915/Makefile
2021                 src/gallium/targets/dri-ilo/Makefile
2022                 src/gallium/targets/dri-nouveau/Makefile
2023                 src/gallium/targets/dri-r300/Makefile
2024                 src/gallium/targets/dri-r600/Makefile
2025                 src/gallium/targets/dri-radeonsi/Makefile
2026                 src/gallium/targets/dri-swrast/Makefile
2027                 src/gallium/targets/dri-vmwgfx/Makefile
2028                 src/gallium/targets/egl-static/Makefile
2029                 src/gallium/targets/gbm/Makefile
2030                 src/gallium/targets/opencl/Makefile
2031                 src/gallium/targets/osmesa/Makefile
2032                 src/gallium/targets/pipe-loader/Makefile
2033                 src/gallium/targets/libgl-xlib/Makefile
2034                 src/gallium/targets/vdpau-nouveau/Makefile
2035                 src/gallium/targets/vdpau-r300/Makefile
2036                 src/gallium/targets/vdpau-r600/Makefile
2037                 src/gallium/targets/vdpau-radeonsi/Makefile
2038                 src/gallium/targets/vdpau-softpipe/Makefile
2039                 src/gallium/targets/xa-vmwgfx/Makefile
2040                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2041                 src/gallium/targets/xorg-i915/Makefile
2042                 src/gallium/targets/xorg-nouveau/Makefile
2043                 src/gallium/targets/xorg-r600/Makefile
2044                 src/gallium/targets/xorg-radeonsi/Makefile
2045                 src/gallium/targets/xvmc-nouveau/Makefile
2046                 src/gallium/targets/xvmc-r300/Makefile
2047                 src/gallium/targets/xvmc-r600/Makefile
2048                 src/gallium/targets/xvmc-softpipe/Makefile
2049                 src/gallium/tests/trivial/Makefile
2050                 src/gallium/tests/unit/Makefile
2051                 src/gallium/winsys/Makefile
2052                 src/gallium/winsys/freedreno/drm/Makefile
2053                 src/gallium/winsys/i915/drm/Makefile
2054                 src/gallium/winsys/i915/sw/Makefile
2055                 src/gallium/winsys/intel/drm/Makefile
2056                 src/gallium/winsys/nouveau/drm/Makefile
2057                 src/gallium/winsys/radeon/drm/Makefile
2058                 src/gallium/winsys/svga/drm/Makefile
2059                 src/gallium/winsys/sw/dri/Makefile
2060                 src/gallium/winsys/sw/fbdev/Makefile
2061                 src/gallium/winsys/sw/null/Makefile
2062                 src/gallium/winsys/sw/wayland/Makefile
2063                 src/gallium/winsys/sw/wrapper/Makefile
2064                 src/gallium/winsys/sw/xlib/Makefile
2065                 src/gbm/Makefile
2066                 src/gbm/main/gbm.pc
2067                 src/glsl/Makefile
2068                 src/glsl/builtin_compiler/Makefile
2069                 src/glx/Makefile
2070                 src/glx/tests/Makefile
2071                 src/gtest/Makefile
2072                 src/mapi/Makefile
2073                 src/mapi/es1api/Makefile
2074                 src/mapi/es1api/glesv1_cm.pc
2075                 src/mapi/es2api/Makefile
2076                 src/mapi/es2api/glesv2.pc
2077                 src/mapi/glapi/Makefile
2078                 src/mapi/glapi/gen/Makefile
2079                 src/mapi/glapi/tests/Makefile
2080                 src/mapi/shared-glapi/Makefile
2081                 src/mapi/shared-glapi/tests/Makefile
2082                 src/mapi/vgapi/Makefile
2083                 src/mapi/vgapi/vg.pc
2084                 src/mesa/Makefile
2085                 src/mesa/gl.pc
2086                 src/mesa/drivers/dri/dri.pc
2087                 src/mesa/drivers/dri/common/Makefile
2088                 src/mesa/drivers/dri/common/xmlpool/Makefile
2089                 src/mesa/drivers/dri/i915/Makefile
2090                 src/mesa/drivers/dri/i965/Makefile
2091                 src/mesa/drivers/dri/Makefile
2092                 src/mesa/drivers/dri/nouveau/Makefile
2093                 src/mesa/drivers/dri/r200/Makefile
2094                 src/mesa/drivers/dri/radeon/Makefile
2095                 src/mesa/drivers/dri/swrast/Makefile
2096                 src/mesa/drivers/osmesa/Makefile
2097                 src/mesa/drivers/osmesa/osmesa.pc
2098                 src/mesa/drivers/x11/Makefile
2099                 src/mesa/libdricore/Makefile
2100                 src/mesa/main/tests/Makefile
2101                 src/mesa/main/tests/hash_table/Makefile
2102                 src/mesa/program/Makefile
2103                 src/mesa/x86-64/Makefile
2104                 src/mesa/x86/Makefile])
2105
2106 dnl Sort the dirs alphabetically
2107 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2108 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2109 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2110 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2111
2112 AC_OUTPUT
2113
2114 dnl
2115 dnl Output some configuration info for the user
2116 dnl
2117 echo ""
2118 echo "        prefix:          $prefix"
2119 echo "        exec_prefix:     $exec_prefix"
2120 echo "        libdir:          $libdir"
2121 echo "        includedir:      $includedir"
2122
2123 dnl API info
2124 echo ""
2125 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2126 echo "        OpenVG:          $enable_openvg"
2127
2128 dnl Driver info
2129 echo ""
2130 if test "x$enable_osmesa" != xno; then
2131         echo "        OSMesa:          lib$OSMESA_LIB"
2132 else
2133         echo "        OSMesa:          no"
2134 fi
2135
2136 if test "x$enable_dri" != xno; then
2137         # cleanup the drivers var
2138         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2139         if test "x$DRI_DIRS" = x; then
2140             echo "        DRI drivers:     no"
2141         else
2142             echo "        DRI drivers:     $dri_dirs"
2143         fi
2144         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2145 fi
2146
2147 case "x$enable_glx$enable_xlib_glx" in
2148 xyesyes)
2149     echo "        GLX:             Xlib-based"
2150     ;;
2151 xyesno)
2152     echo "        GLX:             DRI-based"
2153     ;;
2154 *)
2155     echo "        GLX:             $enable_glx"
2156     ;;
2157 esac
2158
2159 dnl EGL
2160 echo ""
2161 echo "        EGL:             $enable_egl"
2162 if test "$enable_egl" = yes; then
2163     echo "        EGL platforms:   $EGL_PLATFORMS"
2164
2165     egl_drivers=""
2166     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2167         egl_drivers="$egl_drivers builtin:egl_glx"
2168     fi
2169     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2170         egl_drivers="$egl_drivers builtin:egl_dri2"
2171     fi
2172
2173     if test "x$enable_gallium_egl" = xyes; then
2174         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2175         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2176     else
2177         echo "        EGL drivers:    $egl_drivers"
2178     fi
2179 fi
2180
2181 echo ""
2182 if test "x$MESA_LLVM" = x1; then
2183     echo "        llvm:            yes"
2184     echo "        llvm-config:     $LLVM_CONFIG"
2185     echo "        llvm-version:    $LLVM_VERSION"
2186 else
2187     echo "        llvm:            no"
2188 fi
2189
2190 echo ""
2191 if test -n "$with_gallium_drivers"; then
2192     echo "        Gallium:         yes"
2193     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2194     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2195     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2196     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2197 else
2198     echo "        Gallium:         no"
2199 fi
2200
2201
2202 dnl Libraries
2203 echo ""
2204 echo "        Shared libs:     $enable_shared"
2205 echo "        Static libs:     $enable_static"
2206 echo "        Shared-glapi:    $enable_shared_glapi"
2207
2208 dnl Compiler options
2209 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2210 cflags=`echo $CFLAGS | \
2211     $SED 's/^ *//;s/  */ /;s/ *$//'`
2212 cxxflags=`echo $CXXFLAGS | \
2213     $SED 's/^ *//;s/  */ /;s/ *$//'`
2214 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2215 echo ""
2216 echo "        CFLAGS:          $cflags"
2217 echo "        CXXFLAGS:        $cxxflags"
2218 echo "        Macros:          $defines"
2219 echo ""
2220 if test "x$MESA_LLVM" = x1; then
2221     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2222     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2223     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2224     echo ""
2225 fi
2226 echo "        PYTHON2:         $PYTHON2"
2227
2228 echo ""
2229 echo "        Run '${MAKE-make}' to build Mesa"
2230 echo ""