configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 dnl Set internal versions
  28 OSMESA_VERSION=8
  29 AC_SUBST([OSMESA_VERSION])
  30
  31 dnl Versions for external dependencies
  32 LIBDRM_REQUIRED=2.4.24
  33 LIBDRM_RADEON_REQUIRED=2.4.40
  34 LIBDRM_INTEL_REQUIRED=2.4.38
  35 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  36 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  37 DRI2PROTO_REQUIRED=2.6
  38 GLPROTO_REQUIRED=1.4.14
  39 LIBDRM_XORG_REQUIRED=2.4.24
  40 LIBKMS_XORG_REQUIRED=1.0.0
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AX_PROG_CC_FOR_BUILD
  46 AC_PROG_CXX
  47 AX_PROG_CXX_FOR_BUILD
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([disable-static])
  58
  59 if test "x$MKDEP" = "x"; then
  60     AC_MSG_ERROR([makedepend is required to build Mesa])
  61 fi
  62
  63 AC_PROG_YACC
  64 AC_PATH_PROG([YACC_INST], $YACC)
  65 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  66     if test -z "$YACC_INST"; then
  67         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  68     fi
  69 fi
  70 AC_PROG_LEX
  71
  72 AC_PATH_PROG([PERL], [perl])
  73
  74 AC_CHECK_PROG(INDENT, indent, indent, cat)
  75 if test "x$INDENT" != "xcat"; then
  76     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  77 fi
  78
  79 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  80 dnl configuration in that case.
  81 AC_PROG_INSTALL
  82 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  83
  84 dnl We need a POSIX shell for parts of the build. Assume we have one
  85 dnl in most cases.
  86 case "$host_os" in
  87 solaris*)
  88     # Solaris /bin/sh is too old/non-POSIX compliant
  89     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  90     SHELL="$POSIX_SHELL"
  91     ;;
  92 esac
  93
  94 dnl clang is mostly GCC-compatible, but its version is much lower,
  95 dnl so we have to check for it.
  96 AC_MSG_CHECKING([if compiling with clang])
  97
  98 AC_COMPILE_IFELSE(
  99 [AC_LANG_PROGRAM([], [[
 100 #ifndef __clang__
 101        not clang
 102 #endif
 103 ]])],
 104 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 105
 106 AC_MSG_RESULT([$acv_mesa_CLANG])
 107
 108 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 109 dnl versions are explictly not supported.
 110 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 111     AC_MSG_CHECKING([whether gcc version is sufficient])
 112     major=0
 113     minor=0
 114
 115     GCC_VERSION=`$CC -dumpversion`
 116     if test $? -eq 0; then
 117         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 118         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 119     fi
 120
 121     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 122         AC_MSG_RESULT([no])
 123         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 124     else
 125         AC_MSG_RESULT([yes])
 126     fi
 127 fi
 128
 129
 130 MKDEP_OPTIONS=-fdepend
 131 dnl Ask gcc where it's keeping its secret headers
 132 if test "x$GCC" = xyes; then
 133     for dir in include include-fixed; do
 134         GCC_INCLUDES=`$CC -print-file-name=$dir`
 135         if test "x$GCC_INCLUDES" != x && \
 136            test "$GCC_INCLUDES" != "$dir" && \
 137            test -d "$GCC_INCLUDES"; then
 138             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 139         fi
 140     done
 141 fi
 142 AC_SUBST([MKDEP_OPTIONS])
 143
 144 dnl Make sure the pkg-config macros are defined
 145 m4_ifndef([PKG_PROG_PKG_CONFIG],
 146     [m4_fatal([Could not locate the pkg-config autoconf macros.
 147   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 148   are in a different location, try setting the environment variable
 149   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 150 PKG_PROG_PKG_CONFIG()
 151
 152 dnl LIB_DIR - library basename
 153 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 154 AC_SUBST([LIB_DIR])
 155
 156 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 157 _SAVE_LDFLAGS="$LDFLAGS"
 158 _SAVE_CPPFLAGS="$CPPFLAGS"
 159
 160 dnl build host compiler macros
 161 DEFINES_FOR_BUILD=""
 162 AC_SUBST([DEFINES_FOR_BUILD])
 163 case "$build_os" in
 164 linux*|*-gnu*|gnu*)
 165     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 166     ;;
 167 solaris*)
 168     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 169     ;;
 170 cygwin*)
 171     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 172     ;;
 173 esac
 174
 175 dnl Compiler macros
 176 DEFINES=""
 177 AC_SUBST([DEFINES])
 178 case "$host_os" in
 179 linux*|*-gnu*|gnu*)
 180     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 181     ;;
 182 solaris*)
 183     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 184     ;;
 185 cygwin*)
 186     DEFINES="$DEFINES -DHAVE_PTHREAD"
 187     ;;
 188 esac
 189
 190 dnl Add flags for gcc and g++
 191 if test "x$GCC" = xyes; then
 192     case "$host_os" in
 193     cygwin*)
 194         CFLAGS="$CFLAGS -Wall -std=gnu99"
 195         ;;
 196     *)
 197         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 198         CFLAGS="$CFLAGS -Wall -std=c99"
 199         ;;
 200     esac
 201
 202     # Enable -Werror=implicit-function-declaration and
 203     # -Werror=missing-prototypes, if available, or otherwise, just
 204     # -Wmissing-prototypes.  This is particularly useful to avoid
 205     # generating a loadable driver module that has undefined symbols.
 206     save_CFLAGS="$CFLAGS"
 207     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 208     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 209     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 210     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 211                    AC_MSG_RESULT([yes]),
 212                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 213                     AC_MSG_RESULT([no])]);
 214
 215     # Enable -fvisibility=hidden if using a gcc that supports it
 216     save_CFLAGS="$CFLAGS"
 217     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 218     VISIBILITY_CFLAGS="-fvisibility=hidden"
 219     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 220     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 221                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 222
 223     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 224     CFLAGS=$save_CFLAGS
 225
 226     # Work around aliasing bugs - developers should comment this out
 227     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 228     CFLAGS="$CFLAGS -fno-strict-aliasing"
 229
 230     # gcc's builtin memcmp is slower than glibc's
 231     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 232     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 233     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 234 fi
 235 if test "x$GXX" = xyes; then
 236     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 237     CXXFLAGS="$CXXFLAGS -Wall"
 238
 239     # Enable -fvisibility=hidden if using a gcc that supports it
 240     save_CXXFLAGS="$CXXFLAGS"
 241     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 242     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 243     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 244     AC_LANG_PUSH([C++])
 245     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 246                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 247     AC_LANG_POP([C++])
 248
 249     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 250     CXXFLAGS=$save_CXXFLAGS
 251
 252     # Work around aliasing bugs - developers should comment this out
 253     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 254     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 255
 256     # gcc's builtin memcmp is slower than glibc's
 257     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 258     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 259     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 260 fi
 261
 262 dnl even if the compiler appears to support it, using visibility attributes isn't
 263 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 264 case "$host_os" in
 265 cygwin*)
 266     VISIBILITY_CFLAGS=""
 267     VISIBILITY_CXXFLAGS=""
 268     ;;
 269 esac
 270
 271 AC_SUBST([VISIBILITY_CFLAGS])
 272 AC_SUBST([VISIBILITY_CXXFLAGS])
 273
 274 dnl
 275 dnl Hacks to enable 32 or 64 bit build
 276 dnl
 277 AC_ARG_ENABLE([32-bit],
 278     [AS_HELP_STRING([--enable-32-bit],
 279         [build 32-bit libraries @<:@default=auto@:>@])],
 280     [enable_32bit="$enableval"],
 281     [enable_32bit=auto]
 282 )
 283 if test "x$enable_32bit" = xyes; then
 284     if test "x$GCC" = xyes; then
 285         CFLAGS="$CFLAGS -m32"
 286         CCASFLAGS="$CCASFLAGS -m32"
 287     fi
 288     if test "x$GXX" = xyes; then
 289         CXXFLAGS="$CXXFLAGS -m32"
 290     fi
 291 fi
 292 AC_ARG_ENABLE([64-bit],
 293     [AS_HELP_STRING([--enable-64-bit],
 294         [build 64-bit libraries @<:@default=auto@:>@])],
 295     [enable_64bit="$enableval"],
 296     [enable_64bit=auto]
 297 )
 298 if test "x$enable_64bit" = xyes; then
 299     if test "x$GCC" = xyes; then
 300         CFLAGS="$CFLAGS -m64"
 301     fi
 302     if test "x$GXX" = xyes; then
 303         CXXFLAGS="$CXXFLAGS -m64"
 304     fi
 305 fi
 306
 307 dnl Can't have static and shared libraries, default to static if user
 308 dnl explicitly requested. If both disabled, set to static since shared
 309 dnl was explicitly requested.
 310 case "x$enable_static$enable_shared" in
 311 xyesyes )
 312     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 313     enable_shared=no
 314     ;;
 315 xnono )
 316     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 317     enable_static=yes
 318     ;;
 319 esac
 320
 321 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 322
 323 dnl
 324 dnl mklib options
 325 dnl
 326 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 327 if test "$enable_static" = yes; then
 328     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 329 fi
 330 AC_SUBST([MKLIB_OPTIONS])
 331
 332 dnl
 333 dnl other compiler options
 334 dnl
 335 AC_ARG_ENABLE([debug],
 336     [AS_HELP_STRING([--enable-debug],
 337         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 338     [enable_debug="$enableval"],
 339     [enable_debug=no]
 340 )
 341 if test "x$enable_debug" = xyes; then
 342     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 343     if test "x$GCC_FOR_BUILD" = xyes; then
 344         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 345     fi
 346     if test "x$GXX_FOR_BUILD" = xyes; then
 347         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 348     fi
 349
 350     DEFINES="$DEFINES -DDEBUG"
 351     if test "x$GCC" = xyes; then
 352         CFLAGS="$CFLAGS -g -O0"
 353     fi
 354     if test "x$GXX" = xyes; then
 355         CXXFLAGS="$CXXFLAGS -g -O0"
 356     fi
 357 fi
 358
 359 dnl
 360 dnl library names
 361 dnl
 362 LIB_PREFIX_GLOB='lib'
 363 LIB_VERSION_SEPARATOR='.'
 364 if test "$enable_static" = yes; then
 365     LIB_EXTENSION='a'
 366 else
 367     case "$host_os" in
 368     darwin* )
 369         LIB_EXTENSION='dylib' ;;
 370     cygwin* )
 371         dnl prefix can be 'cyg' or 'lib'
 372         LIB_PREFIX_GLOB='???'
 373         LIB_VERSION_SEPARATOR='-'
 374         LIB_EXTENSION='dll' ;;
 375     aix* )
 376         LIB_EXTENSION='a' ;;
 377     * )
 378         LIB_EXTENSION='so' ;;
 379     esac
 380 fi
 381 AC_ARG_WITH([gl-lib-name],
 382   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 383     [specify GL library name @<:@default=GL@:>@])],
 384   [GL_LIB=$withval],
 385   [GL_LIB=GL])
 386 AC_ARG_WITH([osmesa-lib-name],
 387   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 388     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 389   [OSMESA_LIB=$withval],
 390   [OSMESA_LIB=OSMesa])
 391 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 392 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 393
 394 dnl
 395 dnl Mangled Mesa support
 396 dnl
 397 AC_ARG_ENABLE([mangling],
 398   [AS_HELP_STRING([--enable-mangling],
 399     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 400   [enable_mangling="${enableval}"],
 401   [enable_mangling=no]
 402 )
 403 if test "x${enable_mangling}" = "xyes" ; then
 404   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 405   GL_LIB="Mangled${GL_LIB}"
 406   OSMESA_LIB="Mangled${OSMESA_LIB}"
 407 fi
 408 AC_SUBST([GL_LIB])
 409 AC_SUBST([OSMESA_LIB])
 410
 411 dnl
 412 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 413 dnl
 414 AC_ARG_ENABLE([texture-float],
 415     [AS_HELP_STRING([--enable-texture-float],
 416         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 417     [enable_texture_float="$enableval"],
 418     [enable_texture_float=no]
 419 )
 420 if test "x$enable_texture_float" = xyes; then
 421     AC_MSG_WARN([Floating-point textures enabled.])
 422     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 423     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 424 fi
 425
 426 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 427 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 428 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 429 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 430 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 431 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 432 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 433
 434 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 435 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 436 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 437 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 438 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 439 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 440 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 441
 442 AC_SUBST([GL_LIB_NAME])
 443 AC_SUBST([OSMESA_LIB_NAME])
 444 AC_SUBST([EGL_LIB_NAME])
 445 AC_SUBST([GLESv1_CM_LIB_NAME])
 446 AC_SUBST([GLESv2_LIB_NAME])
 447 AC_SUBST([VG_LIB_NAME])
 448 AC_SUBST([GLAPI_LIB_NAME])
 449
 450 AC_SUBST([GL_LIB_GLOB])
 451 AC_SUBST([EGL_LIB_GLOB])
 452 AC_SUBST([GLESv1_CM_LIB_GLOB])
 453 AC_SUBST([GLESv2_LIB_GLOB])
 454 AC_SUBST([VG_LIB_GLOB])
 455 AC_SUBST([GLAPI_LIB_GLOB])
 456
 457 dnl
 458 dnl Arch/platform-specific settings
 459 dnl
 460 AC_ARG_ENABLE([asm],
 461     [AS_HELP_STRING([--disable-asm],
 462         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 463     [enable_asm="$enableval"],
 464     [enable_asm=yes]
 465 )
 466 asm_arch=""
 467 MESA_ASM_FILES=""
 468 AC_MSG_CHECKING([whether to enable assembly])
 469 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 470 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 471 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 472     case "$host_cpu" in
 473     i?86 | x86_64)
 474         enable_asm=no
 475         AC_MSG_RESULT([no, cross compiling])
 476         ;;
 477     esac
 478 fi
 479 # check for supported arches
 480 if test "x$enable_asm" = xyes; then
 481     case "$host_cpu" in
 482     i?86)
 483         case "$host_os" in
 484         linux* | *freebsd* | dragonfly* | *netbsd*)
 485             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 486             ;;
 487         esac
 488         ;;
 489     x86_64)
 490         case "$host_os" in
 491         linux* | *freebsd* | dragonfly* | *netbsd*)
 492             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 493             ;;
 494         esac
 495         ;;
 496     sparc*)
 497         case "$host_os" in
 498         linux*)
 499             asm_arch=sparc
 500             ;;
 501         esac
 502         ;;
 503     esac
 504
 505     case "$asm_arch" in
 506     x86)
 507         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 508         MESA_ASM_FILES='$(X86_FILES)'
 509         AC_MSG_RESULT([yes, x86])
 510         ;;
 511     x86_64)
 512         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 513         MESA_ASM_FILES='$(X86_64_FILES)'
 514         AC_MSG_RESULT([yes, x86_64])
 515         ;;
 516     sparc)
 517         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 518         MESA_ASM_FILES='$(SPARC_FILES)'
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526 AC_SUBST([MESA_ASM_FILES])
 527
 528 dnl PIC code macro
 529 MESA_PIC_FLAGS
 530
 531 dnl Check to see if dlopen is in default libraries (like Solaris, which
 532 dnl has it in libc), or if libdl is needed to get it.
 533 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 534     [AC_CHECK_LIB([dl], [dlopen],
 535        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 536 AC_SUBST([DLOPEN_LIBS])
 537
 538 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 539                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 540                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 541 AC_SUBST([CLOCK_LIB])
 542
 543 dnl See if posix_memalign is available
 544 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 545
 546 dnl Check for pthreads
 547 AX_PTHREAD
 548 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 549 dnl to -pthread, which causes problems if we need -lpthread to appear in
 550 dnl pkgconfig files.
 551 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 552
 553 dnl SELinux awareness.
 554 AC_ARG_ENABLE([selinux],
 555     [AS_HELP_STRING([--enable-selinux],
 556         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 557     [MESA_SELINUX="$enableval"],
 558     [MESA_SELINUX=no])
 559 if test "x$enable_selinux" = "xyes"; then
 560     AC_CHECK_HEADER([selinux/selinux.h],[],
 561                     [AC_MSG_ERROR([SELinux headers not found])])
 562     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 563                  [AC_MSG_ERROR([SELinux library not found])])
 564     SELINUX_LIBS="-lselinux"
 565     DEFINES="$DEFINES -DMESA_SELINUX"
 566 fi
 567 AC_SUBST([SELINUX_LIBS])
 568
 569 dnl Options for APIs
 570 AC_ARG_ENABLE([opengl],
 571     [AS_HELP_STRING([--disable-opengl],
 572         [disable support for standard OpenGL API @<:@default=no@:>@])],
 573     [enable_opengl="$enableval"],
 574     [enable_opengl=yes])
 575 AC_ARG_ENABLE([gles1],
 576     [AS_HELP_STRING([--enable-gles1],
 577         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 578     [enable_gles1="$enableval"],
 579     [enable_gles1=no])
 580 AC_ARG_ENABLE([gles2],
 581     [AS_HELP_STRING([--enable-gles2],
 582         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 583     [enable_gles2="$enableval"],
 584     [enable_gles2=no])
 585 AC_ARG_ENABLE([openvg],
 586     [AS_HELP_STRING([--enable-openvg],
 587         [enable support for OpenVG API @<:@default=no@:>@])],
 588     [enable_openvg="$enableval"],
 589     [enable_openvg=no])
 590
 591 AC_ARG_ENABLE([dri],
 592     [AS_HELP_STRING([--enable-dri],
 593         [enable DRI modules @<:@default=enabled@:>@])],
 594     [enable_dri="$enableval"],
 595     [enable_dri=yes])
 596 AC_ARG_ENABLE([glx],
 597     [AS_HELP_STRING([--enable-glx],
 598         [enable GLX library @<:@default=enabled@:>@])],
 599     [enable_glx="$enableval"],
 600     [enable_glx=yes])
 601 AC_ARG_ENABLE([osmesa],
 602     [AS_HELP_STRING([--enable-osmesa],
 603         [enable OSMesa library @<:@default=disabled@:>@])],
 604     [enable_osmesa="$enableval"],
 605     [enable_osmesa=no])
 606 AC_ARG_ENABLE([egl],
 607     [AS_HELP_STRING([--disable-egl],
 608         [disable EGL library @<:@default=enabled@:>@])],
 609     [enable_egl="$enableval"],
 610     [enable_egl=yes])
 611
 612 AC_ARG_ENABLE([xorg],
 613     [AS_HELP_STRING([--enable-xorg],
 614         [enable support for X.Org DDX API @<:@default=no@:>@])],
 615     [enable_xorg="$enableval"],
 616     [enable_xorg=no])
 617 AC_ARG_ENABLE([xa],
 618     [AS_HELP_STRING([--enable-xa],
 619         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 620     [enable_xa="$enableval"],
 621     [enable_xa=no])
 622 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 623 enable_d3d1x=no
 624 dnl AC_ARG_ENABLE([d3d1x],
 625 dnl     [AS_HELP_STRING([--enable-d3d1x],
 626 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 627 dnl     [enable_d3d1x="$enableval"],
 628 dnl     [enable_d3d1x=no])
 629 AC_ARG_ENABLE([gbm],
 630    [AS_HELP_STRING([--enable-gbm],
 631          [enable gbm library @<:@default=auto@:>@])],
 632    [enable_gbm="$enableval"],
 633    [enable_gbm=auto])
 634
 635 AC_ARG_ENABLE([xvmc],
 636    [AS_HELP_STRING([--enable-xvmc],
 637          [enable xvmc library @<:@default=auto@:>@])],
 638    [enable_xvmc="$enableval"],
 639    [enable_xvmc=auto])
 640 AC_ARG_ENABLE([vdpau],
 641    [AS_HELP_STRING([--enable-vdpau],
 642          [enable vdpau library @<:@default=auto@:>@])],
 643    [enable_vdpau="$enableval"],
 644    [enable_vdpau=auto])
 645 AC_ARG_ENABLE([opencl],
 646    [AS_HELP_STRING([--enable-opencl],
 647          [enable OpenCL library @<:@default=no@:>@])],
 648    [enable_opencl="$enableval"],
 649    [enable_opencl=no])
 650 AC_ARG_ENABLE([xlib_glx],
 651     [AS_HELP_STRING([--enable-xlib-glx],
 652         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 653     [enable_xlib_glx="$enableval"],
 654     [enable_xlib_glx=no])
 655 AC_ARG_ENABLE([gallium_egl],
 656     [AS_HELP_STRING([--enable-gallium-egl],
 657         [enable optional EGL state tracker (not required
 658          for EGL support in Gallium with OpenGL and OpenGL ES)
 659          @<:@default=disable@:>@])],
 660     [enable_gallium_egl="$enableval"],
 661     [enable_gallium_egl=no])
 662 AC_ARG_ENABLE([gallium_gbm],
 663     [AS_HELP_STRING([--enable-gallium-gbm],
 664         [enable optional gbm state tracker (not required for
 665          gbm support in Gallium)
 666          @<:@default=auto@:>@])],
 667     [enable_gallium_gbm="$enableval"],
 668     [enable_gallium_gbm=auto])
 669
 670 AC_ARG_ENABLE([r600-llvm-compiler],
 671     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 672         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 673     [enable_r600_llvm="$enableval"],
 674     [enable_r600_llvm=no])
 675
 676 AC_ARG_ENABLE([gallium_tests],
 677     [AS_HELP_STRING([--enable-gallium-tests],
 678         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 679     [enable_gallium_tests="$enableval"],
 680     [enable_gallium_tests=no])
 681
 682 # Option for Gallium drivers
 683 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 684
 685 AC_ARG_WITH([gallium-drivers],
 686     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 687         [comma delimited Gallium drivers list, e.g.
 688         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 689         @<:@default=r300,r600,swrast@:>@])],
 690     [with_gallium_drivers="$withval"],
 691     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 692
 693 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 694 # here so that the script doesn't choke on an unknown driver name later.
 695 case "$with_gallium_drivers" in
 696     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 697     no) with_gallium_drivers='' ;;
 698 esac
 699
 700 if test "x$enable_opengl" = xno -a \
 701         "x$enable_gles1" = xno -a \
 702         "x$enable_gles2" = xno -a \
 703         "x$enable_openvg" = xno -a \
 704         "x$enable_xorg" = xno -a \
 705         "x$enable_xa" = xno -a \
 706         "x$enable_d3d1x" = xno -a \
 707         "x$enable_xvmc" = xno -a \
 708         "x$enable_vdpau" = xno -a \
 709         "x$enable_opencl" = xno; then
 710     AC_MSG_ERROR([at least one API should be enabled])
 711 fi
 712
 713 API_DEFINES=""
 714 if test "x$enable_opengl" = xno; then
 715     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 716 else
 717     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 718 fi
 719 if test "x$enable_gles1" = xyes; then
 720     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 721 fi
 722 if test "x$enable_gles2" = xyes; then
 723     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 724 fi
 725 AC_SUBST([API_DEFINES])
 726
 727 if test "x$enable_glx" = xno; then
 728     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 729     enable_xlib_glx=no
 730 fi
 731
 732 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 733     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 734 fi
 735
 736 # Disable GLX if DRI and Xlib-GLX are not enabled
 737 if test "x$enable_glx" = xyes -a \
 738         "x$enable_dri" = xno -a \
 739         "x$enable_xlib_glx" = xno; then
 740     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 741     enable_glx=no
 742 fi
 743
 744 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 745 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 746                                   "x$enable_osmesa" = xyes)
 747
 748 AC_ARG_ENABLE([shared-glapi],
 749     [AS_HELP_STRING([--enable-shared-glapi],
 750         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 751     [enable_shared_glapi="$enableval"],
 752     [enable_shared_glapi="$enable_dri"])
 753
 754 # Shared GLAPI is only useful for DRI
 755 if test "x$enable_dri" = xno; then
 756     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 757     enable_shared_glapi=no
 758 fi
 759
 760 # TODO: Get rid of SHARED_GLAPI variable
 761 SHARED_GLAPI="0"
 762 if test "x$enable_shared_glapi" = xyes; then
 763     SHARED_GLAPI="1"
 764     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 765     # the remap table)
 766     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 767     CORE_DIRS="mapi/shared-glapi"
 768 fi
 769 AC_SUBST([SHARED_GLAPI])
 770 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 771
 772 dnl
 773 dnl Driver specific build directories
 774 dnl
 775 SRC_DIRS="gtest"
 776 GALLIUM_DIRS="auxiliary drivers state_trackers"
 777 GALLIUM_TARGET_DIRS=""
 778 GALLIUM_WINSYS_DIRS="sw"
 779 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 780 GALLIUM_STATE_TRACKERS_DIRS=""
 781
 782 # build glapi if OpenGL is enabled
 783 if test "x$enable_opengl" = xyes; then
 784     CORE_DIRS="$CORE_DIRS mapi/glapi"
 785 fi
 786
 787 # build es1api if OpenGL ES 1.x is enabled
 788 if test "x$enable_gles1" = xyes; then
 789     CORE_DIRS="$CORE_DIRS mapi/es1api"
 790 fi
 791
 792 # build es2api if OpenGL ES 2.x is enabled
 793 if test "x$enable_gles2" = xyes; then
 794     CORE_DIRS="$CORE_DIRS mapi/es2api"
 795 fi
 796
 797 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 798 case "x$enable_opengl$enable_gles1$enable_gles2" in
 799 x*yes*)
 800     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 801     ;;
 802 esac
 803
 804 case "x$enable_glx$enable_xlib_glx" in
 805 xyesyes)
 806     DRIVER_DIRS="$DRIVER_DIRS x11"
 807     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 808     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 809     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 810     HAVE_WINSYS_XLIB="yes"
 811     ;;
 812 xyesno)
 813     # DRI-based GLX
 814     SRC_DIRS="$SRC_DIRS glx"
 815     ;;
 816 esac
 817
 818 if test "x$enable_dri" = xyes; then
 819     DRIVER_DIRS="$DRIVER_DIRS dri"
 820
 821     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 822     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 823     HAVE_ST_DRI="yes"
 824 fi
 825
 826 if test "x$enable_osmesa" = xyes; then
 827     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 828 fi
 829
 830 AC_SUBST([SRC_DIRS])
 831 AC_SUBST([DRIVER_DIRS])
 832 AC_SUBST([GALLIUM_DIRS])
 833 AC_SUBST([GALLIUM_TARGET_DIRS])
 834 AC_SUBST([GALLIUM_WINSYS_DIRS])
 835 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 836 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 837 AC_SUBST([MESA_LLVM])
 838
 839 # Check for libdrm
 840 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 841                   [have_libdrm=yes], [have_libdrm=no])
 842
 843 if test "x$enable_dri" = xyes; then
 844     # DRI must be shared, I think
 845     if test "$enable_static" = yes; then
 846         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 847     fi
 848
 849     # not a hard requirement as swrast does not depend on it
 850     if test "x$have_libdrm" = xyes; then
 851         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 852     fi
 853 fi
 854
 855 dnl Find out if X is available.
 856 PKG_CHECK_MODULES([X11], [x11], [no_x=no], [no_x=yes])
 857
 858 dnl Try to tell the user that the --x-* options are only used when
 859 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 860 m4_divert_once([HELP_BEGIN],
 861 [These options are only used when the X libraries cannot be found by the
 862 pkg-config utility.])
 863
 864 dnl We need X for xlib and dri, so bomb now if it's not found
 865 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 866     AC_MSG_ERROR([X11 development libraries needed for GLX])
 867 fi
 868
 869 dnl Direct rendering or just indirect rendering
 870 case "$host_os" in
 871 gnu*)
 872     dnl Disable by default on GNU/Hurd
 873     driglx_direct_default="no"
 874     ;;
 875 cygwin*)
 876     dnl Disable by default on cygwin
 877     driglx_direct_default="no"
 878     ;;
 879 *)
 880     driglx_direct_default="yes"
 881     ;;
 882 esac
 883 AC_ARG_ENABLE([driglx-direct],
 884     [AS_HELP_STRING([--disable-driglx-direct],
 885         [disable direct rendering in GLX and EGL for DRI \
 886             @<:@default=auto@:>@])],
 887     [driglx_direct="$enableval"],
 888     [driglx_direct="$driglx_direct_default"])
 889
 890 dnl
 891 dnl libGL configuration per driver
 892 dnl
 893 case "x$enable_glx$enable_xlib_glx" in
 894 xyesyes)
 895     # Xlib-based GLX
 896     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 897     GL_PC_REQ_PRIV="x11 xext"
 898     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 899     GL_LIB_DEPS="$XLIBGL_LIBS"
 900     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 901     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 902     ;;
 903 xyesno)
 904     # DRI-based GLX
 905     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 906     if test x"$driglx_direct" = xyes; then
 907         if test "x$have_libdrm" != xyes; then
 908             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 909         fi
 910         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 911         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 912     fi
 913
 914     # find the DRI deps for libGL
 915     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 916
 917     # add xf86vidmode if available
 918     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 919     if test "$HAVE_XF86VIDMODE" = yes ; then
 920         dri_modules="$dri_modules xxf86vm"
 921     fi
 922
 923     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 924     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 925     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 926     GL_LIB_DEPS="$DRIGL_LIBS"
 927
 928     # need DRM libs, $PTHREAD_LIBS, etc.
 929     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 930     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 931     ;;
 932 esac
 933
 934 # This is outside the case (above) so that it is invoked even for non-GLX
 935 # builds.
 936 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 937
 938 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 939 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 940 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 941 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 942
 943 AC_SUBST([X11_INCLUDES])
 944 AC_SUBST([GL_LIB_DEPS])
 945 AC_SUBST([GL_PC_REQ_PRIV])
 946 AC_SUBST([GL_PC_LIB_PRIV])
 947 AC_SUBST([GL_PC_CFLAGS])
 948 AC_SUBST([DRI_PC_REQ_PRIV])
 949 AC_SUBST([GLESv1_CM_LIB_DEPS])
 950 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 951 AC_SUBST([GLESv2_LIB_DEPS])
 952 AC_SUBST([GLESv2_PC_LIB_PRIV])
 953
 954 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 955
 956 AC_SUBST([HAVE_XF86VIDMODE])
 957
 958 dnl
 959 dnl More GLX setup
 960 dnl
 961 case "x$enable_glx$enable_xlib_glx" in
 962 xyesyes)
 963     DEFINES="$DEFINES -DUSE_XSHM"
 964     ;;
 965 xyesno)
 966     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 967     if test "x$driglx_direct" = xyes; then
 968         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 969     fi
 970     ;;
 971 esac
 972
 973 dnl
 974 dnl TLS detection
 975 dnl
 976
 977 AC_ARG_ENABLE([glx-tls],
 978     [AS_HELP_STRING([--enable-glx-tls],
 979         [enable TLS support in GLX @<:@default=disabled@:>@])],
 980     [GLX_USE_TLS="$enableval"],
 981     [GLX_USE_TLS=no])
 982 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 983
 984 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 985       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 986
 987 dnl
 988 dnl More DRI setup
 989 dnl
 990 dnl Directory for DRI drivers
 991 AC_ARG_WITH([dri-driverdir],
 992     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 993         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 994     [DRI_DRIVER_INSTALL_DIR="$withval"],
 995     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 996 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 997 dnl Extra search path for DRI drivers
 998 AC_ARG_WITH([dri-searchpath],
 999     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1000         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1001     [DRI_DRIVER_SEARCH_DIR="$withval"],
1002     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1003 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1004 dnl Which drivers to build - default is chosen by platform
1005 AC_ARG_WITH([dri-drivers],
1006     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1007         [comma delimited DRI drivers list, e.g.
1008         "swrast,i965,radeon" @<:@default=auto@:>@])],
1009     [with_dri_drivers="$withval"],
1010     [with_dri_drivers=yes])
1011 if test "x$with_dri_drivers" = x; then
1012     with_dri_drivers=no
1013 fi
1014
1015 dnl If $with_dri_drivers is yes, directories will be added through
1016 dnl platform checks
1017 DRI_DIRS=""
1018 case "$with_dri_drivers" in
1019 no) ;;
1020 yes)
1021     # classic DRI drivers require FEATURE_GL to build
1022     if test "x$enable_opengl" = xyes; then
1023         DRI_DIRS="yes"
1024     fi
1025     ;;
1026 *)
1027     # verify the requested driver directories exist
1028     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1029     for driver in $dri_drivers; do
1030         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1031             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1032     done
1033     DRI_DIRS="$dri_drivers"
1034     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1035         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1036     fi
1037     ;;
1038 esac
1039
1040 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1041 if test "x$enable_dri" = xyes; then
1042     # Platform specific settings and drivers to build
1043     case "$host_os" in
1044     linux*)
1045         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1046         DEFINES="$DEFINES -DHAVE_ALIAS"
1047
1048         case "$host_cpu" in
1049         x86_64)
1050             if test "x$DRI_DIRS" = "xyes"; then
1051                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1052             fi
1053             ;;
1054         powerpc*)
1055             # Build only the drivers for cards that exist on PowerPC.
1056             if test "x$DRI_DIRS" = "xyes"; then
1057                 DRI_DIRS="r200 radeon swrast"
1058             fi
1059             ;;
1060         sparc*)
1061             # Build only the drivers for cards that exist on sparc
1062             if test "x$DRI_DIRS" = "xyes"; then
1063                 DRI_DIRS="r200 radeon swrast"
1064             fi
1065             ;;
1066         esac
1067         ;;
1068     freebsd* | dragonfly* | *netbsd*)
1069         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1070         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1071
1072         if test "x$DRI_DIRS" = "xyes"; then
1073             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1074         fi
1075         ;;
1076     gnu*)
1077         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1078         DEFINES="$DEFINES -DHAVE_ALIAS"
1079         ;;
1080     solaris*)
1081         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1082         ;;
1083     cygwin*)
1084         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1085         if test "x$DRI_DIRS" = "xyes"; then
1086             DRI_DIRS="swrast"
1087         fi
1088         ;;
1089     esac
1090
1091     # default drivers
1092     if test "x$DRI_DIRS" = "xyes"; then
1093         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1094     fi
1095
1096     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1097
1098     # Check for expat
1099     if test "x$enable_dri" = xyes; then
1100         EXPAT_INCLUDES=""
1101         EXPAT_LIB=-lexpat
1102         AC_ARG_WITH([expat],
1103             [AS_HELP_STRING([--with-expat=DIR],
1104                 [expat install directory])],[
1105             EXPAT_INCLUDES="-I$withval/include"
1106             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1107             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1108             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1109             ])
1110         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1111         save_LIBS="$LIBS"
1112         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1113             [AC_MSG_ERROR([Expat required for DRI.])])
1114         LIBS="$save_LIBS"
1115     fi
1116
1117     # if we are building any dri driver other than swrast ...
1118     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1119         # ... libdrm is required
1120         if test "x$have_libdrm" != xyes; then
1121             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1122         fi
1123         # ... and build dricommon
1124         HAVE_COMMON_DRI=yes
1125     fi
1126
1127     # put all the necessary libs together
1128     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1129     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1130 fi
1131 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1132 AC_SUBST([DRI_DIRS])
1133 AC_SUBST([EXPAT_INCLUDES])
1134 AC_SUBST([DRI_LIB_DEPS])
1135 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1136
1137 case $DRI_DIRS in
1138 *i915*|*i965*)
1139     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1140
1141     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1142         case $d in
1143         i915)
1144             HAVE_I915_DRI=yes;
1145             ;;
1146         i965)
1147             HAVE_I965_DRI=yes;
1148             ;;
1149         esac
1150     done
1151
1152     ;;
1153 esac
1154
1155 case $DRI_DIRS in
1156 *nouveau*)
1157     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1158     HAVE_NOUVEAU_DRI=yes;
1159     ;;
1160 esac
1161
1162 case $DRI_DIRS in
1163 *radeon*|*r200*)
1164     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1165
1166     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1167         case $d in
1168         radeon)
1169             HAVE_RADEON_DRI=yes;
1170             ;;
1171         r200)
1172             HAVE_R200_DRI=yes;
1173             ;;
1174         esac
1175     done
1176
1177     ;;
1178 esac
1179
1180 case $DRI_DIRS in
1181 *swrast*)
1182     HAVE_SWRAST_DRI=yes;
1183     ;;
1184 esac
1185
1186 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1187 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1188 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1189 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1190 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1191 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1192 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1193
1194 dnl
1195 dnl OSMesa configuration
1196 dnl
1197
1198 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1199 AC_ARG_WITH([osmesa-bits],
1200     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1201         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1202     [osmesa_bits="$withval"],
1203     [osmesa_bits=8])
1204 if test "x$osmesa_bits" != x8; then
1205     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1206         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1207         osmesa_bits=8
1208     fi
1209 fi
1210 case "x$osmesa_bits" in
1211 x8)
1212     OSMESA_LIB="${OSMESA_LIB}"
1213     ;;
1214 x16|x32)
1215     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1216     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1217     ;;
1218 *)
1219     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1220     ;;
1221 esac
1222
1223 if test "x$enable_osmesa" = xyes; then
1224     # only link libraries with osmesa if shared
1225     if test "$enable_static" = no; then
1226         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1227     else
1228         OSMESA_LIB_DEPS=""
1229     fi
1230     OSMESA_MESA_DEPS=""
1231     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1232 fi
1233
1234 AC_SUBST([OSMESA_LIB_DEPS])
1235 AC_SUBST([OSMESA_MESA_DEPS])
1236 AC_SUBST([OSMESA_PC_REQ])
1237 AC_SUBST([OSMESA_PC_LIB_PRIV])
1238
1239 dnl
1240 dnl gbm configuration
1241 dnl
1242 if test "x$enable_gbm" = xauto; then
1243     case "$with_egl_platforms" in
1244         *drm*)
1245             enable_gbm=yes ;;
1246          *)
1247             enable_gbm=no ;;
1248     esac
1249 fi
1250 if test "x$enable_gbm" = xyes; then
1251     SRC_DIRS="$SRC_DIRS gbm"
1252
1253     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1254                       AC_MSG_ERROR([gbm needs udev]))
1255
1256     if test "x$enable_dri" = xyes; then
1257         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1258         if test "x$enable_shared_glapi" = xno; then
1259             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1260         fi
1261     fi
1262 fi
1263 GBM_PC_REQ_PRIV="libudev"
1264 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1265 AC_SUBST([GBM_PC_REQ_PRIV])
1266 AC_SUBST([GBM_PC_LIB_PRIV])
1267
1268 dnl
1269 dnl EGL configuration
1270 dnl
1271 EGL_CLIENT_APIS=""
1272
1273 if test "x$enable_egl" = xyes; then
1274     SRC_DIRS="$SRC_DIRS egl"
1275     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1276
1277     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1278
1279     if test "$enable_static" != yes; then
1280         # build egl_glx when libGL is built
1281         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1282                           [have_libudev=yes],[have_libudev=no])
1283         if test "$have_libudev" = yes; then
1284             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1285         fi
1286
1287         if test "x$enable_dri" = xyes; then
1288             HAVE_EGL_DRIVER_DRI2=1
1289         fi
1290
1291     fi
1292 fi
1293 AC_SUBST([EGL_LIB_DEPS])
1294
1295 dnl
1296 dnl EGL Gallium configuration
1297 dnl
1298 if test "x$enable_gallium_egl" = xyes; then
1299     if test "x$with_gallium_drivers" = x; then
1300         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1301     fi
1302     if test "x$enable_egl" = xno; then
1303         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1304     fi
1305     if test "x$have_libdrm" != xyes; then
1306         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1307     fi
1308
1309     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1310     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1311     HAVE_ST_EGL="yes"
1312 fi
1313
1314 dnl
1315 dnl gbm Gallium configuration
1316 dnl
1317 if test "x$enable_gallium_gbm" = xauto; then
1318     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1319         yesyesyes*drm*)
1320             enable_gallium_gbm=yes ;;
1321          *)
1322             enable_gallium_gbm=no ;;
1323     esac
1324 fi
1325 if test "x$enable_gallium_gbm" = xyes; then
1326     if test "x$with_gallium_drivers" = x; then
1327         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1328     fi
1329     if test "x$enable_gbm" = xno; then
1330         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1331     fi
1332     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1333     if test "x$enable_dri" = xno; then
1334         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1335     fi
1336
1337     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1338     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1339     HAVE_ST_GBM="yes"
1340     enable_gallium_loader=yes
1341 fi
1342
1343 dnl
1344 dnl X.Org DDX configuration
1345 dnl
1346 if test "x$enable_xorg" = xyes; then
1347     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1348     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1349     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1350     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1351         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1352         HAVE_XEXTPROTO_71="no")
1353     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1354     HAVE_ST_XORG=yes
1355 fi
1356
1357 dnl
1358 dnl XA configuration
1359 dnl
1360 if test "x$enable_xa" = xyes; then
1361 AC_PROG_AWK
1362 AC_PROG_GREP
1363 AC_CHECK_PROG(NM, nm, "nm")
1364 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1365 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1366 enable_xa=no
1367 fi
1368 fi
1369 if test "x$enable_xa" = xyes; then
1370     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1371     HAVE_ST_XA=yes
1372     AC_SUBST(AWK)
1373     AC_SUBST(GREP)
1374     AC_SUBST(NM)
1375 fi
1376
1377 dnl
1378 dnl OpenVG configuration
1379 dnl
1380 VG_LIB_DEPS=""
1381
1382 if test "x$enable_openvg" = xyes; then
1383     if test "x$enable_egl" = xno; then
1384         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1385     fi
1386     if test "x$with_gallium_drivers" = x; then
1387         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1388     fi
1389     if test "x$enable_gallium_egl" = xno; then
1390         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1391     fi
1392
1393     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1394     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1395     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1396     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1397     HAVE_ST_VEGA=yes
1398     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1399     AC_SUBST([VG_PC_LIB_PRIV])
1400 fi
1401 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1402
1403 dnl
1404 dnl D3D1X configuration
1405 dnl
1406
1407 if test "x$enable_d3d1x" = xyes; then
1408     if test "x$with_gallium_drivers" = x; then
1409         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1410     fi
1411
1412     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1413     HAVE_ST_D3D1X=yes
1414 fi
1415
1416 dnl
1417 dnl Gallium G3DVL configuration
1418 dnl
1419 AC_ARG_ENABLE([gallium-g3dvl],
1420     [AS_HELP_STRING([--enable-gallium-g3dvl],
1421         [build gallium g3dvl @<:@default=disabled@:>@])],
1422     [enable_gallium_g3dvl="$enableval"],
1423     [enable_gallium_g3dvl=no])
1424 if test "x$enable_gallium_g3dvl" = xyes; then
1425     if test "x$with_gallium_drivers" = x; then
1426         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1427     fi
1428
1429     if test "x$enable_xvmc" = xauto; then
1430         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1431     fi
1432
1433     if test "x$enable_vdpau" = xauto; then
1434         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1435     fi
1436 fi
1437
1438 if test "x$enable_xvmc" = xyes; then
1439     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1440     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1441     HAVE_ST_XVMC="yes"
1442 fi
1443
1444 if test "x$enable_vdpau" = xyes; then
1445     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1446     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1447     HAVE_ST_VDPAU="yes"
1448 fi
1449
1450 dnl
1451 dnl OpenCL configuration
1452 dnl
1453
1454 AC_ARG_WITH([libclc-path],
1455    [AS_HELP_STRING([--with-libclc-path],
1456          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1457    [LIBCLC_PATH="$withval"],
1458    [LIBCLC_PATH=""])
1459
1460 if test "x$LIBCLC_PATH" != x; then
1461    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1462                   Please review the updated build instructions for clover:
1463                   http://dri.freedesktop.org/wiki/GalliumCompute])
1464 fi
1465
1466
1467 AC_ARG_WITH([clang-libdir],
1468    [AS_HELP_STRING([--with-clang-libdir],
1469          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1470    [CLANG_LIBDIR="$withval"],
1471    [CLANG_LIBDIR=""])
1472
1473 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1474 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1475 AC_SUBST([LIBCLC_INCLUDEDIR])
1476 AC_SUBST([LIBCLC_LIBEXECDIR])
1477
1478 if test "x$enable_opencl" = xyes; then
1479     if test "x$with_gallium_drivers" = x; then
1480         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1481     fi
1482
1483     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1484         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1485     fi
1486
1487     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1488         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1489     fi
1490
1491     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1492     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1493     enable_gallium_loader=yes
1494 fi
1495
1496 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1497     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1498 fi
1499
1500 dnl
1501 dnl Gallium configuration
1502 dnl
1503 if test "x$with_gallium_drivers" != x; then
1504     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1505 fi
1506 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1507
1508 AC_SUBST([LLVM_BINDIR])
1509 AC_SUBST([LLVM_CFLAGS])
1510 AC_SUBST([LLVM_CPPFLAGS])
1511 AC_SUBST([LLVM_CXXFLAGS])
1512 AC_SUBST([LLVM_LIBDIR])
1513 AC_SUBST([LLVM_LIBS])
1514 AC_SUBST([LLVM_LDFLAGS])
1515 AC_SUBST([LLVM_INCLUDEDIR])
1516 AC_SUBST([LLVM_VERSION])
1517 AC_SUBST([CLANG_RESOURCE_DIR])
1518
1519 case "x$enable_opengl$enable_gles1$enable_gles2" in
1520 x*yes*)
1521     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1522     HAVE_OPENGL=yes
1523     ;;
1524 esac
1525 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1526
1527 AC_SUBST([VG_LIB_DEPS])
1528 AC_SUBST([EGL_CLIENT_APIS])
1529
1530 dnl
1531 dnl EGL Platforms configuration
1532 dnl
1533 AC_ARG_WITH([egl-platforms],
1534     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1535         [comma delimited native platforms libEGL supports, e.g.
1536         "x11,drm" @<:@default=auto@:>@])],
1537     [with_egl_platforms="$withval"],
1538     [if test "x$enable_egl" = xyes; then
1539         with_egl_platforms="x11"
1540     else
1541         with_egl_platforms=""
1542     fi])
1543
1544 EGL_PLATFORMS=""
1545
1546 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1547     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1548 fi
1549
1550 # Do per-EGL platform setups and checks
1551 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1552 for plat in $egl_platforms; do
1553         case "$plat" in
1554         fbdev|null)
1555                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1556                 ;;
1557
1558         wayland)
1559                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1560                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1561
1562                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1563                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1564                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1565                 ;;
1566
1567         x11)
1568                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1569
1570                 if test "x$enable_glx" = xyes; then
1571                         HAVE_EGL_DRIVER_GLX=1
1572                 fi
1573                 ;;
1574
1575         drm)
1576                 test "x$enable_gbm" = "xno" &&
1577                         AC_MSG_ERROR([EGL platform drm needs gbm])
1578                 ;;
1579
1580         android|gdi)
1581                 ;;
1582
1583         *)
1584                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1585                 ;;
1586         esac
1587
1588         case "$plat$have_libudev" in
1589                 waylandno|drmno)
1590                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1591         esac
1592 done
1593
1594 # libEGL wants to default to the first platform specified in
1595 # ./configure.  parse that here.
1596 if test "x$egl_platforms" != "x"; then
1597     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1598     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1599 else
1600     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1601 fi
1602
1603 EGL_PLATFORMS="$egl_platforms"
1604
1605 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1606 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1607 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1608 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1609 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1610
1611 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1612 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1613
1614 AC_SUBST([EGL_NATIVE_PLATFORM])
1615 AC_SUBST([EGL_PLATFORMS])
1616 AC_SUBST([EGL_CFLAGS])
1617
1618 AC_ARG_WITH([egl-driver-dir],
1619     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1620                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1621     [EGL_DRIVER_INSTALL_DIR="$withval"],
1622     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1623 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1624
1625 AC_ARG_WITH([xorg-driver-dir],
1626     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1627                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1628     [XORG_DRIVER_INSTALL_DIR="$withval"],
1629     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1630 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1631
1632 AC_ARG_WITH([max-width],
1633     [AS_HELP_STRING([--with-max-width=N],
1634                     [Maximum framebuffer width (4096)])],
1635     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1636      AS_IF([test "${withval}" -gt "4096"],
1637            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1638 )
1639 AC_ARG_WITH([max-height],
1640     [AS_HELP_STRING([--with-max-height=N],
1641                     [Maximum framebuffer height (4096)])],
1642     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1643      AS_IF([test "${withval}" -gt "4096"],
1644            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1645 )
1646
1647 dnl
1648 dnl Gallium LLVM
1649 dnl
1650 AC_ARG_ENABLE([gallium-llvm],
1651     [AS_HELP_STRING([--enable-gallium-llvm],
1652         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1653     [enable_gallium_llvm="$enableval"],
1654     [enable_gallium_llvm=auto])
1655
1656 AC_ARG_WITH([llvm-shared-libs],
1657     [AS_HELP_STRING([--with-llvm-shared-libs],
1658         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1659     [with_llvm_shared_libs=yes],
1660     [with_llvm_shared_libs=no])
1661
1662 AC_ARG_WITH([llvm-prefix],
1663     [AS_HELP_STRING([--with-llvm-prefix],
1664         [Prefix for LLVM installations in non-standard locations])],
1665     [llvm_prefix="$withval"],
1666     [llvm_prefix=""])
1667
1668
1669 # Call this inside ` ` to get the return value.
1670 # $1 is the llvm-config command with arguments.
1671 strip_unwanted_llvm_flags() {
1672     # Use \> (marks the end of the word)
1673     echo `$1` | sed \
1674         -e 's/-DNDEBUG\>//g' \
1675         -e 's/-pedantic\>//g' \
1676         -e 's/-Wcovered-switch-default\>//g' \
1677         -e 's/-O.\>//g' \
1678         -e 's/-g\>//g' \
1679         -e 's/-Wall\>//g' \
1680         -e 's/-fomit-frame-pointer\>//g'
1681 }
1682
1683
1684 if test "x$with_gallium_drivers" = x; then
1685     enable_gallium_llvm=no
1686 fi
1687 if test "x$enable_gallium_llvm" = xauto; then
1688     case "$host_cpu" in
1689     i*86|x86_64) enable_gallium_llvm=yes;;
1690     esac
1691 fi
1692 if test "x$enable_gallium_llvm" = xyes; then
1693     if test "x$llvm_prefix" != x; then
1694         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1695     else
1696         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1697     fi
1698
1699     if test "x$LLVM_CONFIG" != xno; then
1700         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1701         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1702         if test "x$with_llvm_shared_libs" = xyes; then
1703             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1704             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1705         else
1706             LLVM_COMPONENTS="engine bitwriter"
1707             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1708                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1709             fi
1710
1711             if test "x$enable_opencl" = xyes; then
1712                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1713             fi
1714             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1715         fi
1716         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1717         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1718         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1719         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1720         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1721         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1722         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1723         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1724         MESA_LLVM=1
1725
1726         dnl Check for Clang interanl headers
1727         if test "x$enable_opencl" = xyes; then
1728             if test "x$CLANG_LIBDIR" = x; then
1729                 CLANG_LIBDIR=${LLVM_LIBDIR}
1730             fi
1731             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1732             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1733                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1734         fi
1735     else
1736         MESA_LLVM=0
1737         LLVM_VERSION_INT=0
1738     fi
1739 else
1740     MESA_LLVM=0
1741     LLVM_VERSION_INT=0
1742 fi
1743
1744 dnl Directory for XVMC libs
1745 AC_ARG_WITH([xvmc-libdir],
1746     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1747         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1748     [XVMC_LIB_INSTALL_DIR="$withval"],
1749     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1750 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1751
1752 dnl
1753 dnl Gallium Tests
1754 dnl
1755 if test "x$enable_gallium_tests" = xyes; then
1756     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1757     enable_gallium_loader=yes
1758 fi
1759
1760 dnl Directory for VDPAU libs
1761 AC_ARG_WITH([vdpau-libdir],
1762     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1763         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1764     [VDPAU_LIB_INSTALL_DIR="$withval"],
1765     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1766 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1767
1768 dnl Directory for OpenCL libs
1769 AC_ARG_WITH([opencl-libdir],
1770     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1771         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1772     [OPENCL_LIB_INSTALL_DIR="$withval"],
1773     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1774 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1775
1776 dnl
1777 dnl Gallium helper functions
1778 dnl
1779 gallium_check_st() {
1780     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1781          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1782          test "x$HAVE_ST_VDPAU" = xyes; then
1783          if test "x$have_libdrm" != xyes; then
1784             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1785          fi
1786          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1787     fi
1788     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1789          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1790     fi
1791     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1792          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1793     fi
1794     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1795          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1796     fi
1797     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1798          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1799     fi
1800     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1801          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1802     fi
1803 }
1804
1805 gallium_require_llvm() {
1806     if test "x$MESA_LLVM" = x0; then
1807         case "$host_cpu" in
1808         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1809         esac
1810     fi
1811 }
1812
1813 gallium_require_drm_loader() {
1814     if test "x$enable_gallium_loader" = xyes; then
1815         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1816                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1817         if test "x$have_libdrm" != xyes; then
1818             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1819         fi
1820         enable_gallium_drm_loader=yes
1821     fi
1822 }
1823
1824 radeon_llvm_check() {
1825     LLVM_REQUIRED_VERSION_MAJOR="3"
1826     LLVM_REQUIRED_VERSION_MINOR="2"
1827     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1828         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1829                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1830                      git://people.freedesktop.org/~tstellar/llvm master
1831                      and build with --enable-experimental-targets=R600])
1832     fi
1833     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1834         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1835                       sources with the --enable-experimental-targets=R600
1836                       configure flag])
1837     fi
1838     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1839     LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --libs r600`"
1840 }
1841
1842 dnl Gallium drivers
1843 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1844 if test "x$with_gallium_drivers" != x; then
1845     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1846     for driver in $gallium_drivers; do
1847         case "x$driver" in
1848         xsvga)
1849             HAVE_GALLIUM_SVGA=yes
1850             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1851             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1852             ;;
1853         xi915)
1854             HAVE_GALLIUM_I915=yes
1855             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1856             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1857             if test "x$MESA_LLVM" = x1; then
1858                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1859             fi
1860             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1861             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1862             ;;
1863         xr300)
1864             HAVE_GALLIUM_R300=yes
1865             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1866             gallium_require_llvm "Gallium R300"
1867             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1868             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300"
1869             ;;
1870         xr600)
1871             HAVE_GALLIUM_R600=yes
1872             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1873             gallium_require_drm_loader
1874             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1875             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1876                 radeon_llvm_check
1877                 NEED_RADEON_GALLIUM=yes;
1878             fi
1879             if test "x$enable_r600_llvm" = xyes; then
1880                 USE_R600_LLVM_COMPILER=yes;
1881             fi
1882             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1883                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1884             fi
1885             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1886             ;;
1887         xradeonsi)
1888             HAVE_GALLIUM_RADEONSI=yes
1889             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1890             gallium_require_drm_loader
1891             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1892             radeon_llvm_check
1893             NEED_RADEON_GALLIUM=yes;
1894             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1895             ;;
1896         xnouveau)
1897             HAVE_GALLIUM_NOUVEAU=yes
1898             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1899             gallium_require_drm_loader
1900             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1901             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1902             ;;
1903         xswrast)
1904             HAVE_GALLIUM_SOFTPIPE=yes
1905             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1906             if test "x$MESA_LLVM" = x1; then
1907                 HAVE_GALLIUM_LLVMPIPE=yes
1908                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1909             fi
1910
1911             if test "x$HAVE_ST_DRI" = xyes; then
1912                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1913             fi
1914             if test "x$HAVE_ST_VDPAU" = xyes; then
1915                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1916             fi
1917             if test "x$HAVE_ST_XVMC" = xyes; then
1918                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1919             fi
1920             if test "x$HAVE_ST_VDPAU" = xyes ||
1921                test "x$HAVE_ST_XVMC" = xyes; then
1922                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1923                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1924                fi
1925             fi
1926             ;;
1927         *)
1928             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1929             ;;
1930         esac
1931     done
1932 fi
1933 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1934 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1935 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1936 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1937 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1938 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1939 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1940 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1941
1942 if test "x$enable_gallium_loader" = xyes; then
1943     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1944     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1945     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1946     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1947
1948     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1949         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1950         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1951     fi
1952
1953     if test "x$enable_gallium_drm_loader" = xyes; then
1954         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1955         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1956                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1957         if test "x$pipe_loader_have_xcb" = xyes; then
1958             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1959             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1960         fi
1961     fi
1962
1963     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1964     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1965 fi
1966
1967 dnl Tell Automake which drivers to build
1968 for driver in $GALLIUM_DRIVERS_DIRS; do
1969     case "x$driver" in
1970         xgalahad)
1971             HAVE_GALAHAD_GALLIUM=yes;
1972             ;;
1973         xidentity)
1974             HAVE_IDENTITY_GALLIUM=yes;
1975             ;;
1976         xnoop)
1977             HAVE_NOOP_GALLIUM=yes;
1978             ;;
1979         *)
1980             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1981             ;;
1982     esac
1983 done
1984
1985 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1986 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1987 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1988 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1989 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1990 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1991 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1992 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1993 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1994 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1995
1996 AC_SUBST([GALLIUM_MAKE_DIRS])
1997
1998 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
1999                                      "x$enable_xlib_glx" = xyes -o \
2000                                      "x$enable_osmesa" = xyes)
2001 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2002
2003 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2004 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2005 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2006
2007 AC_SUBST([VDPAU_MAJOR], 1)
2008 AC_SUBST([VDPAU_MINOR], 0)
2009
2010 AC_SUBST([XVMC_MAJOR], 1)
2011 AC_SUBST([XVMC_MINOR], 0)
2012
2013 AC_SUBST([XA_MAJOR], 1)
2014 AC_SUBST([XA_MINOR], 0)
2015 AC_SUBST([XA_TINY], 0)
2016 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2017
2018 dnl prepend CORE_DIRS to SRC_DIRS
2019 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2020
2021 dnl Restore LDFLAGS and CPPFLAGS
2022 LDFLAGS="$_SAVE_LDFLAGS"
2023 CPPFLAGS="$_SAVE_CPPFLAGS"
2024
2025 dnl Add user CFLAGS and CXXFLAGS
2026 CFLAGS="$CFLAGS $USER_CFLAGS"
2027 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2028
2029 dnl Substitute the config
2030 AC_CONFIG_FILES([configs/current
2031                 Makefile
2032                 src/Makefile
2033                 src/egl/Makefile
2034                 src/egl/drivers/Makefile
2035                 src/egl/drivers/dri2/Makefile
2036                 src/egl/drivers/glx/Makefile
2037                 src/egl/main/Makefile
2038                 src/egl/main/egl.pc
2039                 src/egl/wayland/Makefile
2040                 src/egl/wayland/wayland-drm/Makefile
2041                 src/egl/wayland/wayland-egl/Makefile
2042                 src/egl/wayland/wayland-egl/wayland-egl.pc
2043                 src/gallium/Makefile
2044                 src/gallium/auxiliary/Makefile
2045                 src/gallium/auxiliary/pipe-loader/Makefile
2046                 src/gallium/drivers/Makefile
2047                 src/gallium/drivers/i915/Makefile
2048                 src/gallium/drivers/llvmpipe/Makefile
2049                 src/gallium/drivers/nouveau/Makefile
2050                 src/gallium/drivers/nv30/Makefile
2051                 src/gallium/drivers/nv50/Makefile
2052                 src/gallium/drivers/nvc0/Makefile
2053                 src/gallium/drivers/r300/Makefile
2054                 src/gallium/drivers/r600/Makefile
2055                 src/gallium/drivers/radeon/Makefile
2056                 src/gallium/drivers/radeonsi/Makefile
2057                 src/gallium/drivers/rbug/Makefile
2058                 src/gallium/drivers/softpipe/Makefile
2059                 src/gallium/drivers/svga/Makefile
2060                 src/gallium/drivers/trace/Makefile
2061                 src/gallium/state_trackers/Makefile
2062                 src/gallium/state_trackers/clover/Makefile
2063                 src/gallium/state_trackers/dri/Makefile
2064                 src/gallium/state_trackers/dri/drm/Makefile
2065                 src/gallium/state_trackers/dri/sw/Makefile
2066                 src/gallium/state_trackers/egl/Makefile
2067                 src/gallium/state_trackers/gbm/Makefile
2068                 src/gallium/state_trackers/glx/Makefile
2069                 src/gallium/state_trackers/vdpau/Makefile
2070                 src/gallium/state_trackers/vega/Makefile
2071                 src/gallium/state_trackers/xa/Makefile
2072                 src/gallium/state_trackers/xorg/Makefile
2073                 src/gallium/state_trackers/xvmc/Makefile
2074                 src/gallium/targets/Makefile
2075                 src/gallium/targets/dri-i915/Makefile
2076                 src/gallium/targets/dri-nouveau/Makefile
2077                 src/gallium/targets/dri-r300/Makefile
2078                 src/gallium/targets/dri-r600/Makefile
2079                 src/gallium/targets/dri-radeonsi/Makefile
2080                 src/gallium/targets/dri-swrast/Makefile
2081                 src/gallium/targets/dri-vmwgfx/Makefile
2082                 src/gallium/targets/egl-static/Makefile
2083                 src/gallium/targets/gbm/Makefile
2084                 src/gallium/targets/opencl/Makefile
2085                 src/gallium/targets/pipe-loader/Makefile
2086                 src/gallium/targets/libgl-xlib/Makefile
2087                 src/gallium/targets/vdpau-nouveau/Makefile
2088                 src/gallium/targets/vdpau-r300/Makefile
2089                 src/gallium/targets/vdpau-r600/Makefile
2090                 src/gallium/targets/vdpau-radeonsi/Makefile
2091                 src/gallium/targets/vdpau-softpipe/Makefile
2092                 src/gallium/targets/xa-vmwgfx/Makefile
2093                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2094                 src/gallium/targets/xorg-i915/Makefile
2095                 src/gallium/targets/xorg-nouveau/Makefile
2096                 src/gallium/targets/xorg-r300/Makefile
2097                 src/gallium/targets/xorg-r600/Makefile
2098                 src/gallium/targets/xorg-radeonsi/Makefile
2099                 src/gallium/targets/xvmc-nouveau/Makefile
2100                 src/gallium/targets/xvmc-r300/Makefile
2101                 src/gallium/targets/xvmc-r600/Makefile
2102                 src/gallium/targets/xvmc-softpipe/Makefile
2103                 src/gallium/tests/trivial/Makefile
2104                 src/gallium/winsys/Makefile
2105                 src/gallium/winsys/i915/drm/Makefile
2106                 src/gallium/winsys/i915/sw/Makefile
2107                 src/gallium/winsys/nouveau/drm/Makefile
2108                 src/gallium/winsys/radeon/drm/Makefile
2109                 src/gallium/winsys/svga/drm/Makefile
2110                 src/gallium/winsys/sw/Makefile
2111                 src/gallium/winsys/sw/dri/Makefile
2112                 src/gallium/winsys/sw/fbdev/Makefile
2113                 src/gallium/winsys/sw/null/Makefile
2114                 src/gallium/winsys/sw/wayland/Makefile
2115                 src/gallium/winsys/sw/wrapper/Makefile
2116                 src/gallium/winsys/sw/xlib/Makefile
2117                 src/gbm/Makefile
2118                 src/gbm/main/gbm.pc
2119                 src/glsl/Makefile
2120                 src/glsl/builtin_compiler/Makefile
2121                 src/glsl/glcpp/Makefile
2122                 src/glsl/tests/Makefile
2123                 src/glx/Makefile
2124                 src/glx/tests/Makefile
2125                 src/gtest/Makefile
2126                 src/mapi/es1api/Makefile
2127                 src/mapi/es1api/glesv1_cm.pc
2128                 src/mapi/es2api/Makefile
2129                 src/mapi/es2api/glesv2.pc
2130                 src/mapi/glapi/Makefile
2131                 src/mapi/glapi/gen/Makefile
2132                 src/mapi/glapi/tests/Makefile
2133                 src/mapi/shared-glapi/Makefile
2134                 src/mapi/shared-glapi/tests/Makefile
2135                 src/mapi/vgapi/Makefile
2136                 src/mapi/vgapi/vg.pc
2137                 src/mesa/Makefile
2138                 src/mesa/gl.pc
2139                 src/mesa/drivers/Makefile
2140                 src/mesa/drivers/dri/dri.pc
2141                 src/mesa/drivers/dri/common/Makefile
2142                 src/mesa/drivers/dri/i915/Makefile
2143                 src/mesa/drivers/dri/i965/Makefile
2144                 src/mesa/drivers/dri/Makefile
2145                 src/mesa/drivers/dri/nouveau/Makefile
2146                 src/mesa/drivers/dri/r200/Makefile
2147                 src/mesa/drivers/dri/radeon/Makefile
2148                 src/mesa/drivers/dri/swrast/Makefile
2149                 src/mesa/drivers/osmesa/Makefile
2150                 src/mesa/drivers/osmesa/osmesa.pc
2151                 src/mesa/drivers/x11/Makefile
2152                 src/mesa/libdricore/Makefile
2153                 src/mesa/main/tests/Makefile
2154                 src/mesa/main/tests/hash_table/Makefile
2155                 src/mesa/program/Makefile
2156                 src/mesa/x86-64/Makefile
2157                 src/mesa/x86/Makefile])
2158
2159 dnl Sort the dirs alphabetically
2160 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2161 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2162 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2163 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2164 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2165
2166 AC_OUTPUT
2167
2168 dnl
2169 dnl Output some configuration info for the user
2170 dnl
2171 echo ""
2172 echo "        prefix:          $prefix"
2173 echo "        exec_prefix:     $exec_prefix"
2174 echo "        libdir:          $libdir"
2175 echo "        includedir:      $includedir"
2176
2177 dnl API info
2178 echo ""
2179 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2180 echo "        OpenVG:          $enable_openvg"
2181
2182 dnl Driver info
2183 echo ""
2184 if test "x$enable_osmesa" != xno; then
2185         echo "        OSMesa:          lib$OSMESA_LIB"
2186 else
2187         echo "        OSMesa:          no"
2188 fi
2189
2190 if test "x$enable_dri" != xno; then
2191         # cleanup the drivers var
2192         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2193         if test "x$DRI_DIRS" = x; then
2194             echo "        DRI drivers:     no"
2195         else
2196             echo "        DRI drivers:     $dri_dirs"
2197         fi
2198         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2199 fi
2200
2201 case "x$enable_glx$enable_xlib_glx" in
2202 xyesyes)
2203     echo "        GLX:             Xlib-based"
2204     ;;
2205 xyesno)
2206     echo "        GLX:             DRI-based"
2207     ;;
2208 *)
2209     echo "        GLX:             $enable_glx"
2210     ;;
2211 esac
2212
2213 dnl EGL
2214 echo ""
2215 echo "        EGL:             $enable_egl"
2216 if test "$enable_egl" = yes; then
2217     echo "        EGL platforms:   $EGL_PLATFORMS"
2218
2219     egl_drivers=""
2220     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2221         egl_drivers="$egl_drivers builtin:egl_glx"
2222     fi
2223     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2224         egl_drivers="$egl_drivers builtin:egl_dri2"
2225     fi
2226
2227     if test "x$HAVE_ST_EGL" = xyes; then
2228         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2229         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2230     else
2231         echo "        EGL drivers:    $egl_drivers"
2232     fi
2233 fi
2234
2235 echo ""
2236 if test "x$MESA_LLVM" = x1; then
2237     echo "        llvm:            yes"
2238     echo "        llvm-config:     $LLVM_CONFIG"
2239     echo "        llvm-version:    $LLVM_VERSION"
2240 else
2241     echo "        llvm:            no"
2242 fi
2243
2244 echo ""
2245 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2246     echo "        Gallium:         yes"
2247     echo "        Gallium dirs:    $GALLIUM_DIRS"
2248     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2249     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2250     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2251     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2252 else
2253     echo "        Gallium:         no"
2254 fi
2255
2256
2257 dnl Libraries
2258 echo ""
2259 echo "        Shared libs:     $enable_shared"
2260 echo "        Static libs:     $enable_static"
2261 echo "        Shared-glapi:    $enable_shared_glapi"
2262
2263 dnl Compiler options
2264 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2265 cflags=`echo $CFLAGS $PIC_FLAGS | \
2266     $SED 's/^ *//;s/  */ /;s/ *$//'`
2267 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2268     $SED 's/^ *//;s/  */ /;s/ *$//'`
2269 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2270 echo ""
2271 echo "        CFLAGS:          $cflags"
2272 echo "        CXXFLAGS:        $cxxflags"
2273 echo "        Macros:          $defines"
2274 echo ""
2275 if test "x$MESA_LLVM" = x1; then
2276     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2277     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2278     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2279     echo ""
2280 fi
2281 echo "        PYTHON2:         $PYTHON2"
2282
2283 echo ""
2284 echo "        Run '${MAKE-make}' to build Mesa"
2285 echo ""