configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT([LHa for UNIX], 1.14i-ac20020622, jca02266@nifty.ne.jp, lha)
   3 AC_CANONICAL_TARGET
   4 AM_INIT_AUTOMAKE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
   8                    [the type of system on which the package will run.])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_GCC_TRADITIONAL
  13 AC_PROG_INSTALL
  14 AC_PROG_MAKE_SET
  15 AC_MINIX
  16 AM_C_PROTOTYPES
  17
  18 # Checks for libraries.
  19
  20 # Checks for header files.
  21 AC_HEADER_DIRENT
  22 AC_HEADER_STDC
  23 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
  24 AC_CHECK_HEADERS(pwd.h grp.h)
  25
  26 # Checks for typedefs, structures, and compiler characteristics.
  27 AC_C_CONST
  28 AC_HEADER_TIME
  29 AC_STRUCT_TM
  30 AC_STRUCT_TIMEZONE
  31
  32 AC_CHECK_TYPES([uid_t, gid_t])
  33 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct stat.st_ino],,,
  34 [
  35 #if HAVE_SYS_TYPES_H
  36 # include <sys/types.h>
  37 #endif
  38 #if HAVE_SYS_STAT_H
  39 # include <sys/stat.h>
  40 #endif
  41 #if TIME_WITH_SYS_TIME
  42 # include <sys/time.h>
  43 # include <time.h>
  44 #else
  45 # if HAVE_SYS_TIME_H
  46 #  include <sys/time.h>
  47 # else
  48 #  include <time.h>
  49 # endif
  50 #endif
  51 ])
  52
  53 # Checks for library functions.
  54 AC_TYPE_SIGNAL
  55 AC_FUNC_FORK
  56 AC_FUNC_UTIME_NULL
  57 # checks readdir(). opendir() has been checked and cached by AC_HEADER_DIRENT.
  58 AC_SEARCH_LIBS(readdir, [mingwex])
  59 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove)
  60 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
  61 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp)
  62 AC_CHECK_FUNCS(strcasecmp link)
  63 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
  64
  65 if test $ac_header_dirent = no; then
  66   AC_LIBOBJ(lhdir)
  67 fi
  68
  69 # support kanji code conversion
  70 AC_SUBST(DEF_KCODE)
  71 AC_ARG_ENABLE(text_conv,
  72   AC_HELP_STRING([--enable-text-conv],
  73                  [support text code convert from/to EUC [[default=yes]]]),
  74   , enable_text_conv=yes)
  75
  76 if test $enable_text_conv = yes; then
  77   DEF_KCODE=-DEUC
  78 fi
  79
  80 # force support -lh7-
  81 AC_SUBST(SUPPORT_LZHUFF_METHOD)
  82 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
  83
  84 # whether use the -lh567- method
  85 AC_MSG_CHECKING(default archive method is )
  86 AC_ARG_WITH(default_method,
  87   AC_HELP_STRING([--with-default-method=[[567]]],
  88                  [create the -lh[[567]]- archive default [[default=5]]]),
  89   [case $withval in
  90    [567]) ;;
  91    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
  92    esac],
  93   with_default_method=5)
  94 AC_MSG_RESULT(-lh$with_default_method-)
  95 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
  96
  97 # decide temporary path names
  98 AC_MSG_CHECKING(template of the temporary file is )
  99 AC_ARG_WITH(tmp_file,
 100   AC_HELP_STRING([--with-tmp-file=TEMPLATE],
 101                  [temporary file template [[default=/tmp/lhXXXXXX]]]),
 102   [case $withval in
 103    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
 104    no)   ;;
 105    esac],
 106   with_tmp_file=/tmp/lhXXXXXX)
 107 AC_MSG_RESULT($with_tmp_file)
 108 if test x"$with_tmp_file" != xno; then
 109   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
 110     [temporary file template for mktemp/mkstemp])
 111 fi
 112
 113 # incremental indicator
 114 AC_ARG_ENABLE(indicator,
 115   AC_HELP_STRING([--enable-indicator],
 116                  [need incremental indicator [[default=yes]]]),
 117   ,
 118   # default
 119   enable_indicator=yes)
 120 if test "x$enable_indicator" = xyes; then
 121   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1,
 122             [Define to 1 if you want to use the incremental indicator])
 123 fi
 124
 125 # support multibyte filename
 126 AC_MSG_CHECKING(kanji code for filename is )
 127 AC_ARG_ENABLE(multibyte-filename,
 128   AC_HELP_STRING([--enable-multibyte-filename],
 129                  [support multibyte filename. specify kanji code (euc or sjis) [[default=auto]]]),,
 130   # default
 131   enable_multibyte_filename=auto)
 132
 133 case $enable_multibyte_filename in
 134 auto|yes)
 135   AC_EGREP_CPP(SJIS,[
 136 #if defined(__CYGWIN__) || defined(__MINGW32__) || defined(__hpux)
 137 SJIS
 138 #else
 139 EUC
 140 #endif], enable_multibyte_filename=CODE_SJIS,
 141          enable_multibyte_filename=CODE_EUC);;
 142 sjis)    enable_multibyte_filename=CODE_SJIS;;
 143 euc)     enable_multibyte_filename=CODE_EUC;;
 144 no)      ;;
 145 *)       AC_MSG_ERROR([you should specify auto, sjis or euc as your system filename code.]);;
 146 esac
 147
 148 AC_MSG_RESULT($enable_multibyte_filename)
 149 if test x$enable_multibyte_filename != xno; then
 150   AC_DEFINE_UNQUOTED(MULTIBYTE_FILENAME, $enable_multibyte_filename,
 151       [Define to CODE_EUC or CODE_SJIS if you want to use multibyte filename])
 152 fi
 153
 154 # make user/group name extented header
 155 AC_ARG_ENABLE(user-name-header,
 156   AC_HELP_STRING([--enable-user-name-header],
 157                  [make user/group name extended header [[default=no]]]),
 158   ,
 159   # default
 160   enable_user_name_header=no)
 161 if test "x$user_name_header" = xyes; then
 162   AC_DEFINE(INCLUDE_OWNER_NAME_IN_HEADER, 1,
 163             [Define to 1 if you want to use the user/group name extened header])
 164 fi
 165
 166 AC_CONFIG_FILES([Makefile src/Makefile man/Makefile])
 167 AC_CONFIG_FILES([tests/Makefile tests/lha-test])
 168 AC_OUTPUT