configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012
   3 #   Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/cloog.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 # This is a hack to get around the mis-configuring of libintl.a
 112 # support in GNUPro 05r1.  In theory this should not be necessary
 113 # but test building native toolchains under Solaris and Cygwin
 114 # before permanently removing it.
 115 case "$ac_configure_args" in
 116   *--with-included-gettext=* )
 117       ;;
 118   *--disable-nls* )
 119       ;;
 120   * )
 121       ac_configure_args="$ac_configure_args --with-included-gettext"
 122       ;;
 123 esac
 124
 125 ### To add a new directory to the tree, first choose whether it is a target
 126 ### or a host dependent tool.  Then put it into the appropriate list
 127 ### (library or tools, host or target), doing a dependency sort.
 128
 129 # Subdirs will be configured in the order listed in build_configdirs,
 130 # configdirs, or target_configdirs; see the serialization section below.
 131
 132 # Dependency sorting is only needed when *configuration* must be done in
 133 # a particular order.  In all cases a dependency should be specified in
 134 # the Makefile, whether or not it's implicitly specified here.
 135
 136 # Double entries in build_configdirs, configdirs, or target_configdirs may
 137 # cause circular dependencies and break everything horribly.
 138
 139 # these library is used by various programs built for the build
 140 # environment
 141 #
 142 build_libs="build-libiberty build-intl"
 143
 144 # these tools are built for the build environment
 145 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 146
 147 # these libraries are used by various programs built for the host environment
 148 #
 149 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libcpp libdecnumber gmp mpfr mpc ppl cloog libelf libiconv"
 150
 151 # these tools are built for the host environment
 152 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 153 # know that we are building the simulator.
 154 # binutils, gas and ld appear in that order because it makes sense to run
 155 # "make check" in that particular order.
 156 # If --enable-gold is used, "gold" may replace "ld".
 157 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools"
 158
 159 # libgcj represents the runtime libraries only used by gcj.
 160 libgcj="target-libffi \
 161         target-zlib \
 162         target-libjava"
 163
 164 # these libraries are built for the target environment, and are built after
 165 # the host libraries and the host tools (which may be a cross compiler)
 166 # Note that libiberty is not a target library.
 167 target_libraries="target-libgcc \
 168                 target-libgloss \
 169                 target-newlib \
 170                 target-libgomp \
 171                 target-libitm \
 172                 target-libstdc++-v3 \
 173                 target-libmudflap \
 174                 target-libssp \
 175                 target-libquadmath \
 176                 target-libgfortran \
 177                 target-boehm-gc \
 178                 ${libgcj} \
 179                 target-libobjc \
 180                 target-libada \
 181                 target-libgo"
 182
 183 # these tools are built using the target libraries, and are intended to
 184 # run only in the target environment
 185 #
 186 # note: any program that *uses* libraries that are in the "target_libraries"
 187 # list belongs in this list.
 188 #
 189 target_tools="target-rda"
 190
 191 ################################################################################
 192
 193 ## All tools belong in one of the four categories, and are assigned above
 194 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 195 ## is important because configure will choke if they ever get through.
 196 ## ${configdirs} is directories we build using the host tools.
 197 ## ${target_configdirs} is directories we build using the target tools.
 198 configdirs=`echo ${host_libs} ${host_tools}`
 199 target_configdirs=`echo ${target_libraries} ${target_tools}`
 200 build_configdirs=`echo ${build_libs} ${build_tools}`
 201
 202 m4_divert_text([PARSE_ARGS],
 203 [case $srcdir in
 204   *" "*)
 205 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 206     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 207 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 208     ;;
 209 esac
 210 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 211 ])
 212
 213 ################################################################################
 214
 215 srcname="gnu development package"
 216
 217 # This gets set non-empty for some net releases of packages.
 218 appdirs=""
 219
 220 # Define is_cross_compiler to save on calls to 'test'.
 221 is_cross_compiler=
 222 if test x"${host}" = x"${target}" ; then
 223   is_cross_compiler=no
 224 else
 225   is_cross_compiler=yes
 226 fi
 227
 228 # Find the build and target subdir names.
 229 GCC_TOPLEV_SUBDIRS
 230 # Be sure to cover against remnants of an in-tree build.
 231 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 232   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 233 Use a pristine source tree when building in a separate tree])
 234 fi
 235
 236 # Skipdirs are removed silently.
 237 skipdirs=
 238 # Noconfigdirs are removed loudly.
 239 noconfigdirs=""
 240
 241 use_gnu_ld=
 242 # Make sure we don't let GNU ld be added if we didn't want it.
 243 if test x$with_gnu_ld = xno ; then
 244   use_gnu_ld=no
 245   noconfigdirs="$noconfigdirs ld gold"
 246 fi
 247
 248 use_gnu_as=
 249 # Make sure we don't let GNU as be added if we didn't want it.
 250 if test x$with_gnu_as = xno ; then
 251   use_gnu_as=no
 252   noconfigdirs="$noconfigdirs gas"
 253 fi
 254
 255 use_included_zlib=
 256 # Make sure we don't let ZLIB be added if we didn't want it.
 257 if test x$with_system_zlib = xyes ; then
 258   use_included_zlib=no
 259   noconfigdirs="$noconfigdirs zlib"
 260 fi
 261
 262 # some tools are so dependent upon X11 that if we're not building with X,
 263 # it's not even worth trying to configure, much less build, that tool.
 264
 265 case ${with_x} in
 266   yes | "") ;; # the default value for this tree is that X11 is available
 267   no)
 268     skipdirs="${skipdirs} tk itcl libgui"
 269     # We won't be able to build gdbtk without X.
 270     enable_gdbtk=no
 271     ;;
 272   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 273 esac
 274
 275 # Some are only suitable for cross toolchains.
 276 # Remove these if host=target.
 277 cross_only="target-libgloss target-newlib target-opcodes"
 278
 279 case $is_cross_compiler in
 280   no) skipdirs="${skipdirs} ${cross_only}" ;;
 281 esac
 282
 283 # If both --with-headers and --with-libs are specified, default to
 284 # --without-newlib.
 285 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 286    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 287   if test x"${with_newlib}" = x ; then
 288     with_newlib=no
 289   fi
 290 fi
 291
 292 # Recognize --with-newlib/--without-newlib.
 293 case ${with_newlib} in
 294   no) skipdirs="${skipdirs} target-newlib" ;;
 295   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 296 esac
 297
 298 # Handle --enable-gold, --enable-ld.
 299 # --disable-gold [--enable-ld]
 300 #     Build only ld.  Default option.
 301 # --enable-gold [--enable-ld]
 302 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 303 #     as "ld.bfd" and "ld".
 304 # --enable-gold=default [--enable-ld]
 305 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 306 #     install ld as "ld.bfd".
 307 # --enable-gold[=default] --disable-ld
 308 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 309 # --enable-gold --enable-ld=default
 310 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 311 #     and ld.bfd).
 312 #     In other words, ld is default
 313 # --enable-gold=default --enable-ld=default
 314 #     Error.
 315
 316 default_ld=
 317 AC_ARG_ENABLE(gold,
 318 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 319                 [build gold @<:@ARG={default,yes,no}@:>@])],
 320 ENABLE_GOLD=$enableval,
 321 ENABLE_GOLD=no)
 322 case "${ENABLE_GOLD}" in
 323   yes|default|both)
 324     # Check for ELF target.
 325     is_elf=no
 326     case "${target}" in
 327       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 328       | *-*-linux* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 329       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 330       | *-*-solaris2* | *-*-nto*)
 331         case "${target}" in
 332           *-*-linux*aout* | *-*-linux*oldld*)
 333             ;;
 334           *)
 335             is_elf=yes
 336             ;;
 337         esac
 338     esac
 339
 340     if test "$is_elf" = "yes"; then
 341       # Check for target supported by gold.
 342       case "${target}" in
 343         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-*)
 344           configdirs="$configdirs gold"
 345           if test x${ENABLE_GOLD} = xdefault; then
 346             default_ld=gold
 347           fi
 348           ENABLE_GOLD=yes
 349           ;;
 350       esac
 351     fi
 352     ;;
 353   no)
 354     ;;
 355   *)
 356     AC_MSG_ERROR([invalid --enable-gold argument])
 357     ;;
 358 esac
 359
 360 AC_ARG_ENABLE(ld,
 361 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 362                 [build ld @<:@ARG={default,yes,no}@:>@])],
 363 ENABLE_LD=$enableval,
 364 ENABLE_LD=yes)
 365
 366 case "${ENABLE_LD}" in
 367   default)
 368     if test x${default_ld} != x; then
 369       AC_MSG_ERROR([either gold or ld can be the default ld])
 370     fi
 371     ;;
 372   yes|both)
 373     ;;
 374   no)
 375     if test x${ENABLE_GOLD} != xyes; then
 376       AC_MSG_WARN([neither ld nor gold are enabled])
 377     fi
 378     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 379     ;;
 380   *)
 381     AC_MSG_ERROR([invalid --enable-ld argument])
 382     ;;
 383 esac
 384
 385 # Configure extra directories which are host specific
 386
 387 case "${host}" in
 388   *-cygwin*)
 389     configdirs="$configdirs libtermcap" ;;
 390 esac
 391
 392 # A target can indicate whether a language isn't supported for some reason.
 393 # Only spaces may be used in this macro; not newlines or tabs.
 394 unsupported_languages=
 395
 396 # Remove more programs from consideration, based on the host or
 397 # target this usually means that a port of the program doesn't
 398 # exist yet.
 399
 400 case "${host}" in
 401   i[[3456789]]86-*-msdosdjgpp*)
 402     noconfigdirs="$noconfigdirs tcl tk itcl"
 403     ;;
 404 esac
 405
 406
 407 AC_ARG_ENABLE(libquadmath,
 408 AS_HELP_STRING([--disable-libquadmath],
 409   [do not build libquadmath directory]),
 410 ENABLE_LIBQUADMATH=$enableval,
 411 ENABLE_LIBQUADMATH=yes)
 412 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 413   noconfigdirs="$noconfigdirs target-libquadmath"
 414 fi
 415
 416
 417 AC_ARG_ENABLE(libquadmath-support,
 418 AS_HELP_STRING([--disable-libquadmath-support],
 419   [disable libquadmath support for Fortran]),
 420 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 421 ENABLE_LIBQUADMATH_SUPPORT=yes)
 422 enable_libquadmath_support=
 423 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 424   enable_libquadmath_support=no
 425 fi
 426
 427
 428 AC_ARG_ENABLE(libada,
 429 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 430 ENABLE_LIBADA=$enableval,
 431 ENABLE_LIBADA=yes)
 432 if test "${ENABLE_LIBADA}" != "yes" ; then
 433   noconfigdirs="$noconfigdirs gnattools"
 434 fi
 435
 436 AC_ARG_ENABLE(libssp,
 437 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 438 ENABLE_LIBSSP=$enableval,
 439 ENABLE_LIBSSP=yes)
 440
 441 # Save it here so that, even in case of --enable-libgcj, if the Java
 442 # front-end isn't enabled, we still get libgcj disabled.
 443 libgcj_saved=$libgcj
 444 case $enable_libgcj in
 445 yes)
 446   # If we reset it here, it won't get added to noconfigdirs in the
 447   # target-specific build rules, so it will be forcibly enabled
 448   # (unless the Java language itself isn't enabled).
 449   libgcj=
 450   ;;
 451 no)
 452   # Make sure we get it printed in the list of not supported target libs.
 453   # Don't disable libffi, though, other languages use it.
 454   noconfigdirs="$noconfigdirs `echo ${libgcj} | sed -e 's/target-libffi//'`"
 455   # Clear libgcj_saved so that even if java is enabled libffi won't be
 456   # built.
 457   libgcj_saved=
 458   ;;
 459 esac
 460
 461 AC_ARG_ENABLE(static-libjava,
 462 [AS_HELP_STRING([[--enable-static-libjava[=ARG]]],
 463                 [build static libjava @<:@default=no@:>@])],
 464 ENABLE_STATIC_LIBJAVA=$enableval,
 465 ENABLE_STATIC_LIBJAVA=no)
 466 enable_static_libjava=
 467 if test "${ENABLE_STATIC_LIBJAVA}" = "yes" ; then
 468   enable_static_libjava=yes
 469 fi
 470
 471 if test x$enable_static_libjava != xyes ; then
 472   EXTRA_CONFIGARGS_LIBJAVA=--disable-static
 473 fi
 474 AC_SUBST(EXTRA_CONFIGARGS_LIBJAVA)
 475
 476 # Disable libmudflap on some systems.
 477 if test x$enable_libmudflap = x ; then
 478     case "${target}" in
 479     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | bfin*-*-uclinux* | *-*-kopensolaris*-gnu)
 480         # Enable libmudflap by default in GNU and friends.
 481         ;;
 482     *-*-freebsd*)
 483         # Enable libmudflap by default in FreeBSD.
 484         ;;
 485     *)
 486         # Disable it by default everywhere else.
 487         noconfigdirs="$noconfigdirs target-libmudflap"
 488         ;;
 489     esac
 490 fi
 491
 492 # Disable libgomp on non POSIX hosted systems.
 493 if test x$enable_libgomp = x ; then
 494     # Enable libgomp by default on hosted POSIX systems.
 495     case "${target}" in
 496     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 497         ;;
 498     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 499         ;;
 500     *-*-solaris2* | *-*-irix6* | *-*-osf* | *-*-hpux11*)
 501         ;;
 502     *-*-darwin* | *-*-aix*)
 503         ;;
 504     *)
 505         noconfigdirs="$noconfigdirs target-libgomp"
 506         ;;
 507     esac
 508 fi
 509
 510 # Disable libitm on unsupported systems.
 511 if test -d ${srcdir}/libitm; then
 512     if test x$enable_libitm = x; then
 513         AC_MSG_CHECKING([for libitm support])
 514         if (srcdir=${srcdir}/libitm; \
 515                 . ${srcdir}/configure.tgt; \
 516                 test -n "$UNSUPPORTED")
 517         then
 518             AC_MSG_RESULT([no])
 519             noconfigdirs="$noconfigdirs target-libitm"
 520         else
 521             AC_MSG_RESULT([yes])
 522         fi
 523     fi
 524 fi
 525
 526 # Disable libssp for some systems.
 527 case "${target}" in
 528   avr-*-*)
 529     # No hosted I/O support.
 530     noconfigdirs="$noconfigdirs target-libssp"
 531     ;;
 532   powerpc-*-aix* | rs6000-*-aix*)
 533     noconfigdirs="$noconfigdirs target-libssp"
 534     ;;
 535   rl78-*-*)
 536     # libssp uses a misaligned load to trigger a fault, but the RL78
 537     # doesn't fault for those - instead, it gives a build-time error
 538     # for explicit misaligned loads.
 539     noconfigdirs="$noconfigdirs target-libssp"
 540     ;;
 541    *-*-tpf*)
 542     noconfigdirs="$noconfigdirs target-libssp"
 543     ;;
 544 esac
 545
 546 # Disable libstdc++-v3 for some systems.
 547 case "${target}" in
 548   *-*-vxworks*)
 549     # VxWorks uses the Dinkumware C++ library.
 550     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 551     ;;
 552   arm*-wince-pe*)
 553     # the C++ libraries don't build on top of CE's C libraries
 554     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 555     ;;
 556   avr-*-*)
 557     noconfigdirs="$noconfigdirs target-libstdc++-v3"
 558     ;;
 559 esac
 560
 561 # Disable Fortran for some systems.
 562 case "${target}" in
 563   mmix-*-*)
 564     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 565     unsupported_languages="$unsupported_languages fortran"
 566     ;;
 567 esac
 568
 569 # Disable Java if libffi is not supported.
 570 case "${target}" in
 571   alpha*-*-*)
 572     ;;
 573   arm*-*-*)
 574     ;;
 575   cris-*-*)
 576     ;;
 577   frv-*-*)
 578     ;;
 579   hppa*-*-linux*)
 580     ;;
 581   hppa*-*-hpux*)
 582     ;;
 583   i?86-*-*)
 584     ;;
 585   ia64*-*-*)
 586     ;;
 587   m32r*-*-*)
 588     ;;
 589   m68k-*-*)
 590     ;;
 591   mips-sgi-irix6.* | mips*-*-rtems*)
 592     ;;
 593   mips*-*-linux*)
 594     ;;
 595   powerpc*-*-linux*)
 596     ;;
 597   powerpc-*-darwin*)
 598     ;;
 599   powerpc-*-aix* | rs6000-*-aix*)
 600     ;;
 601   powerpc-*-freebsd*)
 602     ;;
 603   powerpc64-*-freebsd*)
 604     ;;
 605   powerpc*-*-rtems*)
 606     ;;
 607   s390-*-* | s390x-*-*)
 608     ;;
 609   sh-*-* | sh[[34]]*-*-*)
 610     ;;
 611   sh64-*-* | sh5*-*-*)
 612     ;;
 613   sparc*-*-*)
 614     ;;
 615   x86_64-*-*)
 616     ;;
 617   *-*-*)
 618     unsupported_languages="$unsupported_languages java"
 619     ;;
 620 esac
 621
 622 # Disable Java, libgcj or related libraries for some systems.
 623 case "${target}" in
 624   powerpc-*-darwin*)
 625     ;;
 626   i[[3456789]]86-*-darwin*)
 627     ;;
 628   x86_64-*-darwin[[912]]*)
 629     ;;
 630   *-*-darwin*)
 631     noconfigdirs="$noconfigdirs ${libgcj}"
 632     ;;
 633   *-*-netware*)
 634     noconfigdirs="$noconfigdirs ${libgcj}"
 635     ;;
 636   *-*-rtems*)
 637     noconfigdirs="$noconfigdirs ${libgcj}"
 638     ;;
 639   *-*-tpf*)
 640     noconfigdirs="$noconfigdirs ${libgcj}"
 641     ;;
 642   *-*-uclinux*)
 643     noconfigdirs="$noconfigdirs ${libgcj}"
 644     ;;
 645   *-*-vxworks*)
 646     noconfigdirs="$noconfigdirs ${libgcj}"
 647     ;;
 648   alpha*-*-*vms*)
 649     noconfigdirs="$noconfigdirs ${libgcj}"
 650     ;;
 651   arm-wince-pe)
 652     noconfigdirs="$noconfigdirs ${libgcj}"
 653     ;;
 654   arm*-*-symbianelf*)
 655     noconfigdirs="$noconfigdirs ${libgcj}"
 656     ;;
 657   bfin-*-*)
 658     noconfigdirs="$noconfigdirs target-boehm-gc"
 659     ;;
 660   cris-*-* | crisv32-*-*)
 661     unsupported_languages="$unsupported_languages java"
 662     case "${target}" in
 663       *-*-linux*)
 664         ;;
 665       *) # See PR46792 regarding target-libffi.
 666         noconfigdirs="$noconfigdirs target-libffi target-boehm-gc";;
 667     esac
 668     ;;
 669   hppa*64*-*-linux*)
 670     # In this case, it's because the hppa64-linux target is for
 671     # the kernel only at this point and has no libc, and thus no
 672     # headers, crt*.o, etc., all of which are needed by these.
 673     unsupported_languages="$unsupported_languages java"
 674     ;;
 675   hppa*64*-*-hpux*)
 676     noconfigdirs="$noconfigdirs ${libgcj}"
 677     ;;
 678   hppa*-hp-hpux11*)
 679     ;;
 680   hppa*-*-hpux*)
 681     # According to Alexandre Oliva <aoliva@redhat.com>, libjava won't
 682     # build on HP-UX 10.20.
 683     noconfigdirs="$noconfigdirs ${libgcj}"
 684     ;;
 685   ia64*-*-*vms*)
 686     noconfigdirs="$noconfigdirs ${libgcj}"
 687     ;;
 688   i[[3456789]]86-w64-mingw*)
 689     noconfigdirs="$noconfigdirs ${libgcj}"
 690     ;;
 691   i[[3456789]]86-*-mingw*)
 692     noconfigdirs="$noconfigdirs ${libgcj}"
 693     ;;
 694   x86_64-*-mingw*)
 695     noconfigdirs="$noconfigdirs ${libgcj}"
 696     ;;
 697   mmix-*-*)
 698     noconfigdirs="$noconfigdirs target-libffi target-boehm-gc"
 699     ;;
 700   powerpc-*-aix*)
 701     # copied from rs6000-*-* entry
 702     noconfigdirs="$noconfigdirs ${libgcj}"
 703     ;;
 704   rs6000-*-aix*)
 705     noconfigdirs="$noconfigdirs ${libgcj}"
 706     ;;
 707   mep-*-*)
 708     configdirs="$configdirs sid"
 709     ;;
 710   mips*-*-irix6*)
 711     # Linking libjava exceeds command-line length limits on at least
 712     # IRIX 6.2, but not on IRIX 6.5.
 713     # Also, boehm-gc won't build on IRIX 6.5, according to Jeffrey Oldham
 714     # <oldham@codesourcery.com>
 715     noconfigdirs="$noconfigdirs ${libgcj}"
 716     ;;
 717   mips*-*-*)
 718     noconfigdirs="$noconfigdirs ${libgcj} target-libssp"
 719     ;;
 720   xstormy16*-*-*)
 721     configdirs="$configdirs sid"
 722     ;;
 723   *-*-lynxos*)
 724     noconfigdirs="$noconfigdirs ${libgcj}"
 725     ;;
 726 esac
 727
 728 # Default libgloss CPU subdirectory.
 729 libgloss_dir="$target_cpu"
 730
 731 case "${target}" in
 732   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 733     libgloss_dir=wince
 734     ;;
 735   arm*-*-*)
 736     libgloss_dir=arm
 737     ;;
 738   cris-*-* | crisv32-*-*)
 739     libgloss_dir=cris
 740     ;;
 741   hppa*-*-*)
 742     libgloss_dir=pa
 743     ;;
 744   i[[3456789]]86-*-*)
 745     libgloss_dir=i386
 746     ;;
 747   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 748     libgloss_dir=m68hc11
 749     ;;
 750   m68*-*-* | fido-*-*)
 751     libgloss_dir=m68k
 752     ;;
 753   mips*-*-*)
 754     libgloss_dir=mips
 755     ;;
 756   powerpc*-*-*)
 757     libgloss_dir=rs6000
 758     ;;
 759   sparc*-*-*)
 760     libgloss_dir=sparc
 761     ;;
 762 esac
 763
 764 # Disable newlib and libgloss for various target OSes.
 765 case "${target}" in
 766   alpha*-dec-osf*)
 767     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 768     ;;
 769   i[[3456789]]86-*-linux*)
 770     # This section makes it possible to build newlib natively on linux.
 771     # If we are using a cross compiler then don't configure newlib.
 772     if test x${is_cross_compiler} != xno ; then
 773       noconfigdirs="$noconfigdirs target-newlib"
 774     fi
 775     noconfigdirs="$noconfigdirs target-libgloss"
 776     # If we are not using a cross compiler, do configure newlib.
 777     # Note however, that newlib will only be configured in this situation
 778     # if the --with-newlib option has been given, because otherwise
 779     # 'target-newlib' will appear in skipdirs.
 780     ;;
 781   i[[3456789]]86-*-rdos*)
 782     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 783     ;;
 784   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 785     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 786     ;;
 787   sparc-*-sunos4*)
 788     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 789     ;;
 790   *-*-aix*)
 791     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 792     ;;
 793   *-*-beos*)
 794     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 795     ;;
 796   *-*-chorusos)
 797     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 798     ;;
 799   *-*-dragonfly*)
 800     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 801     ;;
 802   *-*-freebsd*)
 803     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 804     ;;
 805   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 806     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 807     ;;
 808   *-*-lynxos*)
 809     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 810     ;;
 811   *-*-mingw*)
 812     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 813     ;;
 814   *-*-netbsd*)
 815     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 816     ;;
 817   *-*-netware*)
 818     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 819     ;;
 820   *-*-tpf*)
 821     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 822     ;;
 823   *-*-uclinux*)
 824     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 825     ;;
 826   *-*-vxworks*)
 827     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 828     ;;
 829 esac
 830
 831 case "${target}" in
 832   *-*-chorusos)
 833     ;;
 834   powerpc-*-darwin*)
 835     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 836     noconfigdirs="$noconfigdirs sim target-rda"
 837     ;;
 838   i[[3456789]]86-*-darwin*)
 839     noconfigdirs="$noconfigdirs ld gprof"
 840     noconfigdirs="$noconfigdirs sim target-rda"
 841     ;;
 842   x86_64-*-darwin[[912]]*)
 843     noconfigdirs="$noconfigdirs ld gas gprof"
 844     noconfigdirs="$noconfigdirs sim target-rda"
 845     ;;
 846   *-*-darwin*)
 847     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 848     noconfigdirs="$noconfigdirs sim target-rda"
 849     ;;
 850   *-*-dragonfly*)
 851     ;;
 852   *-*-freebsd*)
 853     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 854         && test -f /usr/local/include/gmp.h; then
 855       with_gmp=/usr/local
 856     fi
 857     ;;
 858   *-*-kaos*)
 859     # Remove unsupported stuff on all kaOS configurations.
 860     noconfigdirs="$noconfigdirs target-libgloss"
 861     ;;
 862   *-*-netbsd*)
 863     ;;
 864   *-*-netware*)
 865     ;;
 866   *-*-rtems*)
 867     noconfigdirs="$noconfigdirs target-libgloss"
 868     ;;
 869     # The tpf target doesn't support gdb yet.
 870   *-*-tpf*)
 871     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 872     ;;
 873   *-*-uclinux*)
 874     noconfigdirs="$noconfigdirs target-rda"
 875     ;;
 876   *-*-vxworks*)
 877     ;;
 878   alpha*-dec-osf*)
 879     # ld works, but does not support shared libraries.
 880     # gas doesn't generate exception information.
 881     noconfigdirs="$noconfigdirs gas ld"
 882     ;;
 883   alpha*-*-*vms*)
 884     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 885     ;;
 886   alpha*-*-*)
 887     # newlib is not 64 bit ready
 888     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 889     ;;
 890   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 891     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 892     ;;
 893   arc-*-*)
 894     noconfigdirs="$noconfigdirs target-libgloss"
 895     ;;
 896   arm-*-pe*)
 897     noconfigdirs="$noconfigdirs target-libgloss"
 898     ;;
 899   arm-*-riscix*)
 900     noconfigdirs="$noconfigdirs ld target-libgloss"
 901     ;;
 902   c4x-*-* | tic4x-*-*)
 903     noconfigdirs="$noconfigdirs target-libgloss"
 904     ;;
 905   tic54x-*-*)
 906     noconfigdirs="$noconfigdirs target-libgloss gdb"
 907     ;;
 908   cr16-*-*)
 909     noconfigdirs="$noconfigdirs gdb"
 910     ;;
 911   d10v-*-*)
 912     noconfigdirs="$noconfigdirs target-libgloss"
 913     ;;
 914   d30v-*-*)
 915     noconfigdirs="$noconfigdirs gdb"
 916     ;;
 917   fr30-*-elf*)
 918     noconfigdirs="$noconfigdirs gdb"
 919     ;;
 920   moxie-*-*)
 921     noconfigdirs="$noconfigdirs gprof"
 922     ;;
 923   h8300*-*-*)
 924     noconfigdirs="$noconfigdirs target-libgloss"
 925     ;;
 926   h8500-*-*)
 927     noconfigdirs="$noconfigdirs target-libgloss"
 928     ;;
 929   hppa1.1-*-osf* | hppa1.1-*-bsd* )
 930     ;;
 931   hppa*64*-*-linux*)
 932     ;;
 933   hppa*-*-linux*)
 934     ;;
 935   hppa*-*-*elf* | \
 936   hppa*-*-lites* | \
 937   hppa*-*-openbsd* | \
 938   hppa*64*-*-*)
 939     ;;
 940   hppa*-hp-hpux11*)
 941     noconfigdirs="$noconfigdirs ld"
 942     ;;
 943   hppa*-*-pro*)
 944     ;;
 945   hppa*-*-*)
 946     noconfigdirs="$noconfigdirs ld"
 947     ;;
 948   i960-*-*)
 949     noconfigdirs="$noconfigdirs gdb"
 950     ;;
 951   ia64*-*-elf*)
 952     # No gdb support yet.
 953     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
 954     ;;
 955   ia64*-**-hpux*)
 956     # No ld support yet.
 957     noconfigdirs="$noconfigdirs libgui itcl ld"
 958     ;;
 959   ia64*-*-*vms*)
 960     # No gdb or ld support yet.
 961     noconfigdirs="$noconfigdirs readline libgui itcl gdb ld"
 962     ;;
 963   i[[3456789]]86-w64-mingw*)
 964     ;;
 965   i[[3456789]]86-*-mingw*)
 966     target_configdirs="$target_configdirs target-winsup"
 967     ;;
 968   *-*-cygwin*)
 969     target_configdirs="$target_configdirs target-libtermcap target-winsup"
 970     noconfigdirs="$noconfigdirs target-libgloss"
 971     # always build newlib if winsup directory is present.
 972     if test -d "$srcdir/winsup/cygwin"; then
 973       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
 974     elif test -d "$srcdir/newlib"; then
 975       echo "Warning: winsup/cygwin is missing so newlib can't be built."
 976     fi
 977     ;;
 978   i[[3456789]]86-*-pe)
 979     noconfigdirs="$noconfigdirs target-libgloss"
 980     ;;
 981   i[[3456789]]86-*-sco3.2v5*)
 982     # The linker does not yet know about weak symbols in COFF,
 983     # and is not configured to handle mixed ELF and COFF.
 984     noconfigdirs="$noconfigdirs ld target-libgloss"
 985     ;;
 986   i[[3456789]]86-*-sco*)
 987     noconfigdirs="$noconfigdirs gprof target-libgloss"
 988     ;;
 989   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 990     noconfigdirs="$noconfigdirs target-libgloss"
 991     ;;
 992   i[[3456789]]86-*-sysv4*)
 993     noconfigdirs="$noconfigdirs target-libgloss"
 994     ;;
 995   i[[3456789]]86-*-beos*)
 996     noconfigdirs="$noconfigdirs gdb"
 997     ;;
 998   i[[3456789]]86-*-rdos*)
 999     noconfigdirs="$noconfigdirs gdb"
1000     ;;
1001   mmix-*-*)
1002     noconfigdirs="$noconfigdirs gdb"
1003     ;;
1004   mt-*-*)
1005     noconfigdirs="$noconfigdirs sim"
1006     ;;
1007   powerpc-*-aix*)
1008     # copied from rs6000-*-* entry
1009     noconfigdirs="$noconfigdirs gprof"
1010     ;;
1011   powerpc*-*-winnt* | powerpc*-*-pe*)
1012     target_configdirs="$target_configdirs target-winsup"
1013     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1014     # always build newlib.
1015     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1016     ;;
1017     # This is temporary until we can link against shared libraries
1018   powerpcle-*-solaris*)
1019     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1020     ;;
1021   powerpc-*-beos*)
1022     noconfigdirs="$noconfigdirs gdb"
1023     ;;
1024   rs6000-*-lynxos*)
1025     noconfigdirs="$noconfigdirs gprof"
1026     ;;
1027   rs6000-*-aix*)
1028     noconfigdirs="$noconfigdirs gprof"
1029     ;;
1030   rs6000-*-*)
1031     noconfigdirs="$noconfigdirs gprof"
1032     ;;
1033   m68k-apollo-*)
1034     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1035     ;;
1036   microblaze*)
1037     noconfigdirs="$noconfigdirs gprof"
1038     ;;
1039   mips*-sde-elf*)
1040     if test x$with_newlib = xyes; then
1041       noconfigdirs="$noconfigdirs gprof"
1042     fi
1043     ;;
1044   mips*-*-irix5*)
1045     noconfigdirs="$noconfigdirs gprof target-libgloss"
1046     ;;
1047   mips*-*-irix6*)
1048     noconfigdirs="$noconfigdirs gprof target-libgloss"
1049     ;;
1050   mips*-*-bsd*)
1051     noconfigdirs="$noconfigdirs gprof target-libgloss"
1052     ;;
1053   mips*-*-linux*)
1054     ;;
1055   mips*-*-*)
1056     noconfigdirs="$noconfigdirs gprof"
1057     ;;
1058   sh-*-* | sh64-*-*)
1059     case "${target}" in
1060       sh*-*-elf)
1061          ;;
1062       *)
1063          noconfigdirs="$noconfigdirs target-libgloss" ;;
1064     esac
1065     ;;
1066   sparc-*-sunos4*)
1067     if test x${is_cross_compiler} = xno ; then
1068            use_gnu_ld=no
1069     fi
1070     ;;
1071   tic6x-*-*)
1072     noconfigdirs="$noconfigdirs sim"
1073     ;;
1074   tilepro-*-* | tilegx-*-*)
1075     noconfigdirs="$noconfigdirs sim"
1076     ;;
1077   v810-*-*)
1078     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1079     ;;
1080   vax-*-*)
1081     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1082     ;;
1083 esac
1084
1085 # If we aren't building newlib, then don't build libgloss, since libgloss
1086 # depends upon some newlib header files.
1087 case "${noconfigdirs}" in
1088   *target-libgloss*) ;;
1089   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1090 esac
1091
1092 # Work in distributions that contain no compiler tools, like Autoconf.
1093 host_makefile_frag=/dev/null
1094 if test -d ${srcdir}/config ; then
1095 case "${host}" in
1096   i[[3456789]]86-*-msdosdjgpp*)
1097     host_makefile_frag="config/mh-djgpp"
1098     ;;
1099   *-cygwin*)
1100     ACX_CHECK_CYGWIN_CAT_WORKS
1101     host_makefile_frag="config/mh-cygwin"
1102     ;;
1103   *-mingw*)
1104     host_makefile_frag="config/mh-mingw"
1105     ;;
1106   *-interix*)
1107     host_makefile_frag="config/mh-interix"
1108     ;;
1109   hppa*-hp-hpux10*)
1110     host_makefile_frag="config/mh-pa-hpux10"
1111     ;;
1112   hppa*-hp-hpux*)
1113     host_makefile_frag="config/mh-pa"
1114     ;;
1115   hppa*-*)
1116     host_makefile_frag="config/mh-pa"
1117     ;;
1118   *-*-darwin*)
1119     host_makefile_frag="config/mh-darwin"
1120     ;;
1121   powerpc-*-aix*)
1122     host_makefile_frag="config/mh-ppc-aix"
1123     ;;
1124   rs6000-*-aix*)
1125     host_makefile_frag="config/mh-ppc-aix"
1126     ;;
1127 esac
1128 fi
1129
1130 if test "${build}" != "${host}" ; then
1131   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1132   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1133   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1134   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1135   GCJ_FOR_BUILD=${GCJ_FOR_BUILD-gcj}
1136   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1137   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1138   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1139   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1140   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1141   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1142   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1143   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1144 else
1145   AR_FOR_BUILD="\$(AR)"
1146   AS_FOR_BUILD="\$(AS)"
1147   CC_FOR_BUILD="\$(CC)"
1148   CXX_FOR_BUILD="\$(CXX)"
1149   GCJ_FOR_BUILD="\$(GCJ)"
1150   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1151   GOC_FOR_BUILD="\$(GOC)"
1152   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1153   LD_FOR_BUILD="\$(LD)"
1154   NM_FOR_BUILD="\$(NM)"
1155   RANLIB_FOR_BUILD="\$(RANLIB)"
1156   WINDRES_FOR_BUILD="\$(WINDRES)"
1157   WINDMC_FOR_BUILD="\$(WINDMC)"
1158 fi
1159
1160 AC_PROG_CC
1161 AC_PROG_CXX
1162
1163 # We must set the default linker to the linker used by gcc for the correct
1164 # operation of libtool.  If LD is not defined and we are using gcc, try to
1165 # set the LD default to the ld used by gcc.
1166 if test -z "$LD"; then
1167   if test "$GCC" = yes; then
1168     case $build in
1169     *-*-mingw*)
1170       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1171     *)
1172       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1173     esac
1174     case $gcc_prog_ld in
1175     # Accept absolute paths.
1176     [[\\/]* | [A-Za-z]:[\\/]*)]
1177       LD="$gcc_prog_ld" ;;
1178     esac
1179   fi
1180 fi
1181
1182 ACX_PROG_GNAT
1183 ACX_PROG_CMP_IGNORE_INITIAL
1184
1185 AC_ARG_ENABLE([bootstrap],
1186 [AS_HELP_STRING([--enable-bootstrap],
1187                 [enable bootstrapping @<:@yes if native build@:>@])],,
1188 enable_bootstrap=default)
1189
1190 # Issue errors and warnings for invalid/strange bootstrap combinations.
1191 if test -r $srcdir/gcc/configure; then
1192   have_compiler=yes
1193 else
1194   have_compiler=no
1195 fi
1196
1197 case "$have_compiler:$host:$target:$enable_bootstrap" in
1198   *:*:*:no) ;;
1199
1200   # Default behavior.  Enable bootstrap if we have a compiler
1201   # and we are in a native configuration.
1202   yes:$build:$build:default)
1203     enable_bootstrap=yes ;;
1204
1205   *:*:*:default)
1206     enable_bootstrap=no ;;
1207
1208   # We have a compiler and we are in a native configuration, bootstrap is ok
1209   yes:$build:$build:yes)
1210     ;;
1211
1212   # Other configurations, but we have a compiler.  Assume the user knows
1213   # what he's doing.
1214   yes:*:*:yes)
1215     AC_MSG_WARN([trying to bootstrap a cross compiler])
1216     ;;
1217
1218   # No compiler: if they passed --enable-bootstrap explicitly, fail
1219   no:*:*:yes)
1220     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1221
1222   # Fail if wrong command line
1223   *)
1224     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1225     ;;
1226 esac
1227
1228 # See if we are building gcc with C++.
1229 AC_ARG_ENABLE(build-with-cxx,
1230 [AS_HELP_STRING([--enable-build-with-cxx],
1231                 [build with C++ compiler instead of C compiler])],
1232 ENABLE_BUILD_WITH_CXX=$enableval,
1233 ENABLE_BUILD_WITH_CXX=no)
1234
1235 # Build stage1 with C and build stages 2 and 3 with C++.
1236 AC_ARG_ENABLE(build-poststage1-with-cxx,
1237 [AS_HELP_STRING([--enable-build-poststage1-with-cxx],
1238                 [build stages 2 and 3 with C++, not C])],
1239 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=$enableval,
1240 ENABLE_BUILD_POSTSTAGE1_WITH_CXX=yes)
1241
1242 # Used for setting $lt_cv_objdir
1243 _LT_CHECK_OBJDIR
1244
1245 # Check for GMP, MPFR and MPC
1246 gmplibs="-lmpc -lmpfr -lgmp"
1247 gmpinc=
1248 have_gmp=no
1249
1250 # Specify a location for mpc
1251 # check for this first so it ends up on the link line before mpfr.
1252 AC_ARG_WITH(mpc,
1253 [AS_HELP_STRING([--with-mpc=PATH],
1254                 [specify prefix directory for installed MPC package.
1255                  Equivalent to --with-mpc-include=PATH/include
1256                  plus --with-mpc-lib=PATH/lib])])
1257 AC_ARG_WITH(mpc-include,
1258 [AS_HELP_STRING([--with-mpc-include=PATH],
1259                 [specify directory for installed MPC include files])])
1260 AC_ARG_WITH(mpc-lib,
1261 [AS_HELP_STRING([--with-mpc-lib=PATH],
1262                 [specify directory for the installed MPC library])])
1263
1264 if test "x$with_mpc" != x; then
1265   gmplibs="-L$with_mpc/lib $gmplibs"
1266   gmpinc="-I$with_mpc/include $gmpinc"
1267 fi
1268 if test "x$with_mpc_include" != x; then
1269   gmpinc="-I$with_mpc_include $gmpinc"
1270 fi
1271 if test "x$with_mpc_lib" != x; then
1272   gmplibs="-L$with_mpc_lib $gmplibs"
1273 fi
1274 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1275   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1276   gmpinc='-I$$s/mpc/src '"$gmpinc"
1277   # Do not test the mpc version.  Assume that it is sufficient, since
1278   # it is in the source tree, and the library has not been built yet
1279   # but it would be included on the link line in the version check below
1280   # hence making the test fail.
1281   have_gmp=yes
1282 fi
1283
1284 # Specify a location for mpfr
1285 # check for this first so it ends up on the link line before gmp.
1286 AC_ARG_WITH(mpfr-dir,
1287 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1288 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1289 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1290
1291 AC_ARG_WITH(mpfr,
1292 [AS_HELP_STRING([--with-mpfr=PATH],
1293                 [specify prefix directory for installed MPFR package.
1294                  Equivalent to --with-mpfr-include=PATH/include
1295                  plus --with-mpfr-lib=PATH/lib])])
1296 AC_ARG_WITH(mpfr-include,
1297 [AS_HELP_STRING([--with-mpfr-include=PATH],
1298                 [specify directory for installed MPFR include files])])
1299 AC_ARG_WITH(mpfr-lib,
1300 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1301                 [specify directory for the installed MPFR library])])
1302
1303 if test "x$with_mpfr" != x; then
1304   gmplibs="-L$with_mpfr/lib $gmplibs"
1305   gmpinc="-I$with_mpfr/include $gmpinc"
1306 fi
1307 if test "x$with_mpfr_include" != x; then
1308   gmpinc="-I$with_mpfr_include $gmpinc"
1309 fi
1310 if test "x$with_mpfr_lib" != x; then
1311   gmplibs="-L$with_mpfr_lib $gmplibs"
1312 fi
1313 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1314   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1315   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1316   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1317   # Do not test the mpfr version.  Assume that it is sufficient, since
1318   # it is in the source tree, and the library has not been built yet
1319   # but it would be included on the link line in the version check below
1320   # hence making the test fail.
1321   have_gmp=yes
1322 fi
1323
1324 # Specify a location for gmp
1325 AC_ARG_WITH(gmp-dir,
1326 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1327 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1328 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1329
1330 AC_ARG_WITH(gmp,
1331 [AS_HELP_STRING([--with-gmp=PATH],
1332                 [specify prefix directory for the installed GMP package.
1333                  Equivalent to --with-gmp-include=PATH/include
1334                  plus --with-gmp-lib=PATH/lib])])
1335 AC_ARG_WITH(gmp-include,
1336 [AS_HELP_STRING([--with-gmp-include=PATH],
1337                 [specify directory for installed GMP include files])])
1338 AC_ARG_WITH(gmp-lib,
1339 [AS_HELP_STRING([--with-gmp-lib=PATH],
1340                 [specify directory for the installed GMP library])])
1341
1342
1343 if test "x$with_gmp" != x; then
1344   gmplibs="-L$with_gmp/lib $gmplibs"
1345   gmpinc="-I$with_gmp/include $gmpinc"
1346 fi
1347 if test "x$with_gmp_include" != x; then
1348   gmpinc="-I$with_gmp_include $gmpinc"
1349 fi
1350 if test "x$with_gmp_lib" != x; then
1351   gmplibs="-L$with_gmp_lib $gmplibs"
1352 fi
1353 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1354   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1355   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1356   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1357   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1358   # Do not test the gmp version.  Assume that it is sufficient, since
1359   # it is in the source tree, and the library has not been built yet
1360   # but it would be included on the link line in the version check below
1361   # hence making the test fail.
1362   have_gmp=yes
1363 fi
1364
1365 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1366   have_gmp=yes
1367   saved_CFLAGS="$CFLAGS"
1368   CFLAGS="$CFLAGS $gmpinc"
1369   # Check for the recommended and required versions of GMP.
1370   AC_MSG_CHECKING([for the correct version of gmp.h])
1371   AC_TRY_COMPILE([#include "gmp.h"],[
1372   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1373   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1374   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,0)
1375   choke me
1376   #endif
1377   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1378   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1379   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1380   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1381   choke me
1382   #endif
1383   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1384    [AC_MSG_RESULT([no]); have_gmp=no])
1385
1386   # If we have GMP, check the MPFR version.
1387   if test x"$have_gmp" = xyes; then
1388     # Check for the recommended and required versions of MPFR.
1389     AC_MSG_CHECKING([for the correct version of mpfr.h])
1390     AC_TRY_COMPILE([#include <gmp.h>
1391     #include <mpfr.h>],[
1392     #if MPFR_VERSION < MPFR_VERSION_NUM(2,3,1)
1393     choke me
1394     #endif
1395     ], [AC_TRY_COMPILE([#include <gmp.h>
1396     #include <mpfr.h>],[
1397     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1398     choke me
1399     #endif
1400     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1401      [AC_MSG_RESULT([no]); have_gmp=no])
1402   fi
1403
1404   # Check for the MPC header version.
1405   if test x"$have_gmp" = xyes ; then
1406     # Check for the recommended and required versions of MPC.
1407     AC_MSG_CHECKING([for the correct version of mpc.h])
1408     AC_TRY_COMPILE([#include <mpc.h>],[
1409     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1410     choke me
1411     #endif
1412     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1413     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1414     choke me
1415     #endif
1416     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1417      [AC_MSG_RESULT([no]); have_gmp=no])
1418   fi
1419
1420   # Now check the MPFR library.
1421   if test x"$have_gmp" = xyes; then
1422     saved_LIBS="$LIBS"
1423     LIBS="$LIBS $gmplibs"
1424     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1425     AC_TRY_LINK([#include <mpc.h>],[
1426     mpfr_t n;
1427     mpfr_t x;
1428     mpc_t c;
1429     int t;
1430     mpfr_init (n);
1431     mpfr_init (x);
1432     mpfr_atan2 (n, n, x, GMP_RNDN);
1433     mpfr_erfc (n, x, GMP_RNDN);
1434     mpfr_subnormalize (x, t, GMP_RNDN);
1435     mpfr_clear(n);
1436     mpfr_clear(x);
1437     mpc_init2 (c, 53);
1438     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1439     mpc_cosh (c, c, MPC_RNDNN);
1440     mpc_pow (c, c, c, MPC_RNDNN);
1441     mpc_acosh (c, c, MPC_RNDNN);
1442     mpc_clear (c);
1443     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1444     LIBS="$saved_LIBS"
1445   fi
1446
1447   CFLAGS="$saved_CFLAGS"
1448
1449 # The library versions listed in the error message below should match
1450 # the HARD-minimums enforced above.
1451   if test x$have_gmp != xyes; then
1452     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.3.1+ and MPC 0.8.0+.
1453 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1454 their locations.  Source code for these libraries can be found at
1455 their respective hosting sites as well as at
1456 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1457 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1458 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1459 make sure that you have installed both the libraries and the header
1460 files.  They may be located in separate packages.])
1461   fi
1462 fi
1463
1464 # Flags needed for both GMP, MPFR and/or MPC.
1465 AC_SUBST(gmplibs)
1466 AC_SUBST(gmpinc)
1467 AC_SUBST(extra_mpfr_configure_flags)
1468 AC_SUBST(extra_mpc_gmp_configure_flags)
1469 AC_SUBST(extra_mpc_mpfr_configure_flags)
1470
1471 # Allow host libstdc++ to be specified for static linking with PPL.
1472 AC_ARG_WITH(host-libstdcxx,
1473 [AS_HELP_STRING([--with-host-libstdcxx=L],
1474                 [use linker arguments L to link with libstdc++
1475                  when linking with PPL])])
1476
1477 case $with_host_libstdcxx in
1478   no|yes)
1479     AC_MSG_ERROR([-with-host-libstdcxx needs an argument])
1480     ;;
1481 esac
1482
1483 # Linker flags to use for stage1 or when not boostrapping.
1484 AC_ARG_WITH(stage1-ldflags,
1485 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1486 [if test "$withval" = "no" -o "$withval" = "yes"; then
1487    stage1_ldflags=
1488  else
1489    stage1_ldflags=$withval
1490  fi],
1491 [stage1_ldflags=])
1492 AC_SUBST(stage1_ldflags)
1493
1494 # Libraries to use for stage1 or when not bootstrapping.
1495 AC_ARG_WITH(stage1-libs,
1496 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1497 [if test "$withval" = "no" -o "$withval" = "yes"; then
1498    stage1_libs=
1499  else
1500    stage1_libs=$withval
1501  fi],
1502 [stage1_libs=$with_host_libstdcxx])
1503 AC_SUBST(stage1_libs)
1504
1505 # Libraries to use for stage2 and later builds.  This defaults to the
1506 # argument passed to --with-host-libstdcxx.
1507 AC_ARG_WITH(boot-libs,
1508 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1509 [if test "$withval" = "no" -o "$withval" = "yes"; then
1510    poststage1_libs=
1511  else
1512    poststage1_libs=$withval
1513  fi],
1514 [poststage1_libs=$with_host_libstdcxx])
1515 AC_SUBST(poststage1_libs)
1516
1517 # Linker flags to use for stage2 and later builds.
1518 AC_ARG_WITH(boot-ldflags,
1519 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1520                 [linker flags for stage2 and later])],
1521 [if test "$withval" = "no" -o "$withval" = "yes"; then
1522    poststage1_ldflags=
1523  else
1524    poststage1_ldflags=$withval
1525  fi],
1526 [poststage1_ldflags=
1527  # In stages 2 and 3, default to linking libstdc++ and libgcc
1528  # statically.  But if the user explicitly specified the libraries to
1529  # use, trust that they are doing what they want.
1530  if test "$poststage1_libs" = ""; then
1531    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1532  fi])
1533 AC_SUBST(poststage1_ldflags)
1534
1535 # Check for PPL
1536 ppllibs=
1537 pplinc=
1538 pwllib=
1539
1540 AC_ARG_WITH(ppl,
1541 [AS_HELP_STRING([--with-ppl=PATH],
1542                 [specify prefix directory for the installed PPL package.
1543                  Equivalent to --with-ppl-include=PATH/include
1544                  plus --with-ppl-lib=PATH/lib])])
1545 AC_ARG_WITH(ppl-include,
1546 [AS_HELP_STRING([--with-ppl-include=PATH],
1547                 [specify directory for installed PPL include files])])
1548 AC_ARG_WITH(ppl-lib,
1549 [AS_HELP_STRING([--with-ppl-lib=PATH],
1550                 [specify directory for the installed PPL library])])
1551
1552 AC_ARG_ENABLE(ppl-version-check,
1553 [AS_HELP_STRING([--disable-ppl-version-check],
1554                 [disable check for PPL version])])
1555
1556 case $with_ppl in
1557   yes | no | "")
1558     ;;
1559   *)
1560     ppllibs="-L$with_ppl/lib"
1561     pplinc="-I$with_ppl/include $pplinc"
1562     if test -d "$with_ppl/lib" && test -d "$with_ppl/include"; then
1563       with_ppl=yes
1564     else
1565       AC_MSG_ERROR([cannot find directories "$with_ppl/lib" or "$with_ppl/include"])
1566     fi
1567     ;;
1568 esac
1569
1570 if test x"$with_ppl_include" != x; then
1571   pplinc="-I$with_ppl_include $pplinc"
1572   with_ppl=yes
1573 fi
1574
1575 if test "x$with_ppl_lib" != x; then
1576   ppllibs="-L$with_ppl_lib"
1577   with_ppl=yes
1578 fi
1579
1580 if test x"$with_ppl$with_ppl_include$with_ppl_lib" = x && test -d ${srcdir}/ppl; then
1581   if test x"$enable_watchdog" = xyes; then
1582     pwllib="-lpwl"
1583   fi
1584   ppllibs='-L$$r/$(HOST_SUBDIR)/ppl/interfaces/C/'"$lt_cv_objdir"' -L$$r/$(HOST_SUBDIR)/ppl/src/'"$lt_cv_objdir"
1585   pplinc='-I$$r/$(HOST_SUBDIR)/ppl/src -I$$r/$(HOST_SUBDIR)/ppl/interfaces/C '
1586   enable_ppl_version_check=no
1587   with_ppl=yes
1588 fi
1589
1590 if test "x$with_ppl" != xno; then
1591   if test "x$pwllib" = x; then
1592     saved_LIBS="$LIBS"
1593     LIBS="$LIBS $ppllibs -lstdc++ -lm"
1594     AC_CHECK_LIB(pwl, PWL_handle_timeout, [pwllib="-lpwl"])
1595     LIBS="$saved_LIBS"
1596   fi
1597
1598   ppllibs="$ppllibs -lppl_c -lppl $pwllib -lgmpxx"
1599
1600   if test "$enable_ppl_version_check" != no; then
1601     saved_CFLAGS="$CFLAGS"
1602     CFLAGS="$CFLAGS $pplinc $gmpinc"
1603     AC_MSG_CHECKING([for version 0.11 (revision 0 or later) of PPL])
1604     AC_TRY_COMPILE([#include "ppl_c.h"],[
1605     #if PPL_VERSION_MAJOR != 0 || PPL_VERSION_MINOR < 11
1606     choke me
1607     #endif
1608     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); ppllibs= ; pplinc= ; with_ppl=no ])
1609     CFLAGS="$saved_CFLAGS"
1610   fi
1611 fi
1612
1613 # Flags needed for PPL
1614 AC_SUBST(ppllibs)
1615 AC_SUBST(pplinc)
1616
1617
1618 # Check for CLOOG
1619
1620 dnl Provide configure switches and initialize clooginc & clooglibs
1621 dnl with user input.
1622 CLOOG_INIT_FLAGS
1623 if test "x$with_ppl" = "xno"; then
1624   dnl Only execute fail-action, if CLooG has been requested.
1625   CLOOG_REQUESTED([graphite_requested=yes], [graphite_requested=no])
1626   if test "${graphite_requested}" = yes; then
1627     AC_MSG_ERROR([Unable to find a usable PPL.  See config.log for details.])
1628   fi
1629   with_cloog=no
1630 fi
1631 if test "x${with_cloog}" = x && test "x${with_cloog_include}" = x \
1632   && test "x${with_cloog_lib}" = x && test -d ${srcdir}/cloog; then
1633   clooglibs='-L$$r/$(HOST_SUBDIR)/cloog/'"$lt_cv_objdir"' '
1634   clooginc='-I$$r/$(HOST_SUBDIR)/cloog/include -I$$s/cloog/include '
1635 fi
1636 if test "x$with_cloog" != "xno"; then
1637   dnl The minimal version of CLooG required for Graphite.
1638   dnl
1639   dnl If we use CLooG-Legacy, the provided version information is
1640   dnl ignored.
1641   CLOOG_CHECK_VERSION(0,16,1)
1642
1643   dnl Only execute fail-action, if CLooG has been requested.
1644   CLOOG_IF_FAILED([
1645     AC_MSG_ERROR([Unable to find a usable CLooG.  See config.log for details.])])
1646 fi
1647
1648 # Check for LTO support.
1649 AC_ARG_ENABLE(lto,
1650 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1651 enable_lto=$enableval,
1652 enable_lto=yes; default_enable_lto=yes)
1653
1654 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1655   build_lto_plugin=yes
1656 ],[if test x"$default_enable_lto" = x"yes" ; then
1657     case $target in
1658       *-apple-darwin9* | *-cygwin* | *-mingw*) ;;
1659       # On other non-ELF platforms, LTO has yet to be validated.
1660       *) enable_lto=no ;;
1661     esac
1662   else
1663   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1664   # It would also be nice to check the binutils support, but we don't
1665   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1666   # warn during gcc/ subconfigure; unless you're bootstrapping with
1667   # -flto it won't be needed until after installation anyway.
1668     case $target in
1669       *-cygwin* | *-mingw* | *-apple-darwin*) ;;
1670       *) if test x"$enable_lto" = x"yes"; then
1671         AC_MSG_ERROR([LTO support is not enabled for this target.])
1672         fi
1673       ;;
1674     esac
1675   fi
1676   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1677   # Build it unless LTO was explicitly disabled.
1678   case $target in
1679     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1680     *) ;;
1681   esac
1682 ])
1683
1684
1685 # By default, C is the only stage 1 language.
1686 stage1_languages=,c,
1687
1688 # Target libraries that we bootstrap.
1689 bootstrap_target_libs=,target-libgcc,
1690
1691 # Figure out what language subdirectories are present.
1692 # Look if the user specified --enable-languages="..."; if not, use
1693 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1694 # go away some day.
1695 # NB:  embedded tabs in this IF block -- do not untabify
1696 if test -d ${srcdir}/gcc; then
1697   if test x"${enable_languages+set}" != xset; then
1698     if test x"${LANGUAGES+set}" = xset; then
1699       enable_languages="${LANGUAGES}"
1700         echo configure.in: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1701     else
1702       enable_languages=all
1703     fi
1704   else
1705     if test x"${enable_languages}" = x ||
1706        test x"${enable_languages}" = xyes;
1707        then
1708       echo configure.in: --enable-languages needs at least one language argument 1>&2
1709       exit 1
1710     fi
1711   fi
1712   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1713
1714   # 'f95' is the old name for the 'fortran' language. We issue a warning
1715   # and make the substitution.
1716   case ,${enable_languages}, in
1717     *,f95,*)
1718       echo configure.in: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1719       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1720       ;;
1721   esac
1722
1723   # If bootstrapping, then using --enable-build-with-cxx or
1724   # --enable-build-poststage1-with-cxx requires enabling C++.
1725   case ",$enable_languages,:,$ENABLE_BUILD_WITH_CXX,$ENABLE_BUILD_POSTSTAGE1_WITH_CXX,:$enable_bootstrap" in
1726     *,c++,*:*:*) ;;
1727     *:*,yes,*:yes)
1728       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1729         enable_languages="${enable_languages},c++"
1730       else
1731         AC_MSG_ERROR([bootstrapping with --enable-build-with-cxx or --enable-build-poststage1-with-cxx requires c++ sources])
1732       fi
1733       ;;
1734   esac
1735
1736   # First scan to see if an enabled language requires some other language.
1737   # We assume that a given config-lang.in will list all the language
1738   # front ends it requires, even if some are required indirectly.
1739   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1740     case ${lang_frag} in
1741       ..) ;;
1742       # The odd quoting in the next line works around
1743       # an apparent bug in bash 1.12 on linux.
1744       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1745       *)
1746         # From the config-lang.in, get $language, $lang_requires, and
1747         # $lang_requires_boot_languages.
1748         language=
1749         lang_requires=
1750         lang_requires_boot_languages=
1751         . ${lang_frag}
1752         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1753           case ,${enable_languages}, in
1754             *,$other,*) ;;
1755             *,all,*) ;;
1756             *,$language,*)
1757               echo " \`$other' language required by \`$language'; enabling" 1>&2
1758               enable_languages="${enable_languages},${other}"
1759               ;;
1760           esac
1761         done
1762         for other in ${lang_requires_boot_languages} ; do
1763           if test "$other" != "c"; then
1764             case ,${enable_stage1_languages}, in
1765               *,$other,*) ;;
1766               *,all,*) ;;
1767               *)
1768                 case ,${enable_languages}, in
1769                   *,$language,*)
1770                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1771                     enable_stage1_languages="$enable_stage1_languages,${other}"
1772                     ;;
1773                 esac
1774                 ;;
1775             esac
1776           fi
1777         done
1778         ;;
1779     esac
1780   done
1781
1782   new_enable_languages=,c,
1783
1784   # If LTO is enabled, add the LTO front end.
1785   extra_host_libiberty_configure_flags=
1786   if test "$enable_lto" = "yes" ; then
1787     case ,${enable_languages}, in
1788       *,lto,*) ;;
1789       *) enable_languages="${enable_languages},lto" ;;
1790     esac
1791     if test "${build_lto_plugin}" = "yes" ; then
1792       configdirs="$configdirs lto-plugin"
1793       extra_host_libiberty_configure_flags=--enable-shared
1794     fi
1795   fi
1796   AC_SUBST(extra_host_libiberty_configure_flags)
1797
1798   missing_languages=`echo ",$enable_languages," | sed -e s/,all,/,/ -e s/,c,/,/ `
1799   potential_languages=,c,
1800
1801   enabled_target_libs=
1802   disabled_target_libs=
1803
1804   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1805     case ${lang_frag} in
1806       ..) ;;
1807       # The odd quoting in the next line works around
1808       # an apparent bug in bash 1.12 on linux.
1809       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1810       *)
1811         # From the config-lang.in, get $language, $target_libs,
1812         # $lang_dirs, $boot_language, and $build_by_default
1813         language=
1814         target_libs=
1815         lang_dirs=
1816         subdir_requires=
1817         boot_language=no
1818         build_by_default=yes
1819         . ${lang_frag}
1820         if test x${language} = x; then
1821           echo "${lang_frag} doesn't set \$language." 1>&2
1822           exit 1
1823         fi
1824
1825         if test "$language" = "c++"; then
1826           if test "$ENABLE_BUILD_WITH_CXX" = "yes" \
1827              || test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
1828             boot_language=yes
1829           fi
1830         fi
1831
1832         case ,${enable_languages}, in
1833           *,${language},*)
1834             # Language was explicitly selected; include it.
1835             add_this_lang=yes
1836             ;;
1837           *,all,*)
1838             # 'all' was selected, select it if it is a default language
1839             add_this_lang=${build_by_default}
1840             ;;
1841           *)
1842             add_this_lang=no
1843             ;;
1844         esac
1845
1846         # Disable languages that need other directories if these aren't available.
1847         for i in $subdir_requires; do
1848           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1849           case ,${enable_languages}, in
1850             *,${language},*)
1851               # Specifically requested language; tell them.
1852               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1853               ;;
1854             *)
1855               # Silently disable.
1856               add_this_lang=unsupported
1857               ;;
1858           esac
1859         done
1860
1861         # Disable Ada if no preexisting GNAT is available.
1862         case ,${enable_languages},:${language}:${have_gnat} in
1863           *,${language},*:ada:no)
1864             # Specifically requested language; tell them.
1865             AC_MSG_ERROR([GNAT is required to build $language])
1866             ;;
1867           *:ada:no)
1868             # Silently disable.
1869             add_this_lang=unsupported
1870             ;;
1871         esac
1872
1873         # Disable a language that is unsupported by the target.
1874         case " $unsupported_languages " in
1875           *" $language "*)
1876             add_this_lang=unsupported
1877             ;;
1878         esac
1879
1880         case $add_this_lang in
1881           unsupported)
1882             # Remove language-dependent dirs.
1883             disabled_target_libs="$disabled_target_libs $target_libs"
1884             noconfigdirs="$noconfigdirs $lang_dirs"
1885             ;;
1886           no)
1887             # Remove language-dependent dirs; still show language as supported.
1888             disabled_target_libs="$disabled_target_libs $target_libs"
1889             noconfigdirs="$noconfigdirs $lang_dirs"
1890             potential_languages="${potential_languages}${language},"
1891             ;;
1892           yes)
1893             new_enable_languages="${new_enable_languages}${language},"
1894             potential_languages="${potential_languages}${language},"
1895             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
1896             enabled_target_libs="$enabled_target_libs $target_libs"
1897             case "${boot_language}:,$enable_stage1_languages," in
1898               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
1899                 # Add to (comma-separated) list of stage 1 languages.
1900                 case ",$stage1_languages," in
1901                   *,$language,* | ,yes, | ,all,) ;;
1902                   *) stage1_languages="${stage1_languages}${language}," ;;
1903                 esac
1904                 # We need to bootstrap any supporting libraries.
1905                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
1906                 ;;
1907             esac
1908             ;;
1909         esac
1910         ;;
1911     esac
1912   done
1913
1914   # Add target libraries which are only needed for disabled languages
1915   # to noconfigdirs.
1916   if test -n "$disabled_target_libs"; then
1917     for dir in $disabled_target_libs; do
1918       case " $enabled_target_libs " in
1919       *" ${dir} "*) ;;
1920       *) noconfigdirs="$noconfigdirs $dir" ;;
1921       esac
1922     done
1923   fi
1924
1925   AC_ARG_ENABLE(stage1-languages,
1926   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
1927                   [choose additional languages to build during
1928                   stage1.  Mostly useful for compiler development])],
1929   [case ,${enable_stage1_languages}, in
1930     ,no,|,,)
1931       # Set it to something that will have no effect in the loop below
1932       enable_stage1_languages=c ;;
1933     ,yes,)
1934       enable_stage1_languages=`echo $new_enable_languages | \
1935         sed -e "s/^,//" -e "s/,$//" ` ;;
1936     *,all,*)
1937       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
1938         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
1939   esac
1940
1941   # Add "good" languages from enable_stage1_languages to stage1_languages,
1942   # while "bad" languages go in missing_languages.  Leave no duplicates.
1943   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
1944     case $potential_languages in
1945       *,$i,*)
1946         case $stage1_languages in
1947           *,$i,*) ;;
1948           *) stage1_languages="$stage1_languages$i," ;;
1949         esac ;;
1950       *)
1951         case $missing_languages in
1952           *,$i,*) ;;
1953           *) missing_languages="$missing_languages$i," ;;
1954         esac ;;
1955      esac
1956   done])
1957
1958   # Remove leading/trailing commas that were added for simplicity
1959   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
1960   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
1961   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
1962   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
1963
1964   if test "x$missing_languages" != x; then
1965     AC_MSG_ERROR([
1966 The following requested languages could not be built: ${missing_languages}
1967 Supported languages are: ${potential_languages}])
1968   fi
1969   if test "x$new_enable_languages" != "x$enable_languages"; then
1970     echo The following languages will be built: ${new_enable_languages}
1971     enable_languages="$new_enable_languages"
1972   fi
1973
1974   AC_SUBST(stage1_languages)
1975   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
1976 fi
1977
1978 # Handle --disable-<component> generically.
1979 for dir in $configdirs $build_configdirs $target_configdirs ; do
1980   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
1981   varname=`echo $dirname | sed -e s/+/_/g`
1982   if eval test x\${enable_${varname}} "=" xno ; then
1983     noconfigdirs="$noconfigdirs $dir"
1984   fi
1985 done
1986
1987 # Check for Boehm's garbage collector
1988 AC_ARG_ENABLE(objc-gc,
1989 [AS_HELP_STRING([--enable-objc-gc],
1990                 [enable use of Boehm's garbage collector with the
1991                  GNU Objective-C runtime])],
1992 [case ,${enable_languages},:${enable_objc_gc}:${noconfigdirs} in
1993   *,objc,*:*:yes:*target-boehm-gc*)
1994     AC_MSG_ERROR([Boehm's garbage collector was requested yet not supported in this configuration])
1995     ;;
1996 esac])
1997
1998 # Make sure we only build Boehm's garbage collector if required.
1999 case ,${enable_languages},:${enable_objc_gc} in
2000   *,objc,*:yes)
2001     # Keep target-boehm-gc if requested for Objective-C.
2002     ;;
2003   *)
2004     # Otherwise remove target-boehm-gc depending on target-libjava.
2005     if echo " ${noconfigdirs} " | grep "target-libjava" >/dev/null 2>&1; then
2006       noconfigdirs="$noconfigdirs target-boehm-gc"
2007     fi
2008     ;;
2009 esac
2010
2011 # Disable libitm if we're not building C++
2012 case ,${enable_languages}, in
2013   *,c++,*) ;;
2014   *)
2015     noconfigdirs="$noconfigdirs target-libitm"
2016     ;;
2017 esac
2018
2019 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2020 # $build_configdirs and $target_configdirs.
2021 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2022
2023 notsupp=""
2024 for dir in . $skipdirs $noconfigdirs ; do
2025   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2026   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2027     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2028     if test -r $srcdir/$dirname/configure ; then
2029       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2030         true
2031       else
2032         notsupp="$notsupp $dir"
2033       fi
2034     fi
2035   fi
2036   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2037     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2038     if test -r $srcdir/$dirname/configure ; then
2039       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2040         true
2041       else
2042         notsupp="$notsupp $dir"
2043       fi
2044     fi
2045   fi
2046   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2047     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2048     if test -r $srcdir/$dirname/configure ; then
2049       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2050         true
2051       else
2052         notsupp="$notsupp $dir"
2053       fi
2054     fi
2055   fi
2056 done
2057
2058 # Quietly strip out all directories which aren't configurable in this tree.
2059 # This relies on all configurable subdirectories being autoconfiscated, which
2060 # is now the case.
2061 build_configdirs_all="$build_configdirs"
2062 build_configdirs=
2063 for i in ${build_configdirs_all} ; do
2064   j=`echo $i | sed -e s/build-//g`
2065   if test -f ${srcdir}/$j/configure ; then
2066     build_configdirs="${build_configdirs} $i"
2067   fi
2068 done
2069
2070 configdirs_all="$configdirs"
2071 configdirs=
2072 for i in ${configdirs_all} ; do
2073   if test -f ${srcdir}/$i/configure ; then
2074     configdirs="${configdirs} $i"
2075   fi
2076 done
2077
2078 target_configdirs_all="$target_configdirs"
2079 target_configdirs=
2080 for i in ${target_configdirs_all} ; do
2081   j=`echo $i | sed -e s/target-//g`
2082   if test -f ${srcdir}/$j/configure ; then
2083     target_configdirs="${target_configdirs} $i"
2084   fi
2085 done
2086
2087 # Produce a warning message for the subdirs we can't configure.
2088 # This isn't especially interesting in the Cygnus tree, but in the individual
2089 # FSF releases, it's important to let people know when their machine isn't
2090 # supported by the one or two programs in a package.
2091
2092 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2093   # If $appdirs is non-empty, at least one of those directories must still
2094   # be configured, or we error out.  (E.g., if the gas release supports a
2095   # specified target in some subdirs but not the gas subdir, we shouldn't
2096   # pretend that all is well.)
2097   if test -n "$appdirs" ; then
2098     for dir in $appdirs ; do
2099       if test -r $dir/Makefile.in ; then
2100         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2101           appdirs=""
2102           break
2103         fi
2104         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2105           appdirs=""
2106           break
2107         fi
2108       fi
2109     done
2110     if test -n "$appdirs" ; then
2111       echo "*** This configuration is not supported by this package." 1>&2
2112       exit 1
2113     fi
2114   fi
2115   # Okay, some application will build, or we don't care to check.  Still
2116   # notify of subdirs not getting built.
2117   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2118   echo "    ${notsupp}" 1>&2
2119   echo "    (Any other directories should still work fine.)" 1>&2
2120 fi
2121
2122 case "$host" in
2123   *msdosdjgpp*)
2124     enable_gdbtk=no ;;
2125 esac
2126
2127 # To find our prefix, in gcc_cv_tool_prefix.
2128 ACX_TOOL_DIRS
2129
2130 copy_dirs=
2131
2132 AC_ARG_WITH([build-sysroot],
2133   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2134                   [use sysroot as the system root during the build])],
2135   [if test x"$withval" != x ; then
2136      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2137    fi],
2138   [SYSROOT_CFLAGS_FOR_TARGET=])
2139 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2140
2141 AC_ARG_WITH([debug-prefix-map],
2142   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2143                   [map A to B, C to D ... in debug information])],
2144   [if test x"$withval" != x; then
2145      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2146      for debug_map in $withval; do
2147        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2148      done
2149    fi],
2150   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2151 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2152
2153 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2154 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2155 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2156 # We want to ensure that TARGET libraries (which we know are built with
2157 # gcc) are built with "-O2 -g", so include those options when setting
2158 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2159 if test "x$CFLAGS_FOR_TARGET" = x; then
2160   CFLAGS_FOR_TARGET=$CFLAGS
2161   case " $CFLAGS " in
2162     *" -O2 "*) ;;
2163     *) CFLAGS_FOR_TARGET="-O2 $CFLAGS" ;;
2164   esac
2165   case " $CFLAGS " in
2166     *" -g "* | *" -g3 "*) ;;
2167     *) CFLAGS_FOR_TARGET="-g $CFLAGS" ;;
2168   esac
2169 fi
2170 AC_SUBST(CFLAGS_FOR_TARGET)
2171
2172 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2173   CXXFLAGS_FOR_TARGET=$CXXFLAGS
2174   case " $CXXFLAGS " in
2175     *" -O2 "*) ;;
2176     *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS" ;;
2177   esac
2178   case " $CXXFLAGS " in
2179     *" -g "* | *" -g3 "*) ;;
2180     *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS" ;;
2181   esac
2182 fi
2183 AC_SUBST(CXXFLAGS_FOR_TARGET)
2184
2185 AC_SUBST(LDFLAGS_FOR_TARGET)
2186
2187 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2188 # the named directory are copied to $(tooldir)/sys-include.
2189 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2190   if test x${is_cross_compiler} = xno ; then
2191     echo 1>&2 '***' --with-headers is only supported when cross compiling
2192     exit 1
2193   fi
2194   if test x"${with_headers}" != xyes ; then
2195     x=${gcc_cv_tool_prefix}
2196     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2197   fi
2198 fi
2199
2200 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2201 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2202 # are permitted.
2203 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2204   if test x${is_cross_compiler} = xno ; then
2205     echo 1>&2 '***' --with-libs is only supported when cross compiling
2206     exit 1
2207   fi
2208   if test x"${with_libs}" != xyes ; then
2209     # Copy the libraries in reverse order, so that files in the first named
2210     # library override files in subsequent libraries.
2211     x=${gcc_cv_tool_prefix}
2212     for l in ${with_libs}; do
2213       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2214     done
2215   fi
2216 fi
2217
2218 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2219 #
2220 # This is done by determining whether or not the appropriate directory
2221 # is available, and by checking whether or not specific configurations
2222 # have requested that this magic not happen.
2223 #
2224 # The command line options always override the explicit settings in
2225 # configure.in, and the settings in configure.in override this magic.
2226 #
2227 # If the default for a toolchain is to use GNU as and ld, and you don't
2228 # want to do that, then you should use the --without-gnu-as and
2229 # --without-gnu-ld options for the configure script.  Similarly, if
2230 # the default is to use the included zlib and you don't want to do that,
2231 # you should use the --with-system-zlib option for the configure script.
2232
2233 if test x${use_gnu_as} = x &&
2234    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2235   with_gnu_as=yes
2236   extra_host_args="$extra_host_args --with-gnu-as"
2237 fi
2238
2239 if test x${use_gnu_ld} = x &&
2240    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2241   with_gnu_ld=yes
2242   extra_host_args="$extra_host_args --with-gnu-ld"
2243 fi
2244
2245 if test x${use_included_zlib} = x &&
2246    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2247   :
2248 else
2249   with_system_zlib=yes
2250   extra_host_args="$extra_host_args --with-system-zlib"
2251 fi
2252
2253 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2254 # can detect this case.
2255
2256 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2257   with_newlib=yes
2258   extra_host_args="$extra_host_args --with-newlib"
2259 fi
2260
2261 # Handle ${copy_dirs}
2262 set fnord ${copy_dirs}
2263 shift
2264 while test $# != 0 ; do
2265   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2266     :
2267   else
2268     echo Copying $1 to $2
2269
2270     # Use the install script to create the directory and all required
2271     # parent directories.
2272     if test -d $2 ; then
2273       :
2274     else
2275       echo >config.temp
2276       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2277     fi
2278
2279     # Copy the directory, assuming we have tar.
2280     # FIXME: Should we use B in the second tar?  Not all systems support it.
2281     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2282
2283     # It is the responsibility of the user to correctly adjust all
2284     # symlinks.  If somebody can figure out how to handle them correctly
2285     # here, feel free to add the code.
2286
2287     echo $1 > $2/COPIED
2288   fi
2289   shift; shift
2290 done
2291
2292 # Determine a target-dependent exec_prefix that the installed
2293 # gcc will search in.  Keep this list sorted by triplet, with
2294 # the *-*-osname triplets last.
2295 md_exec_prefix=
2296 case "${target}" in
2297   i[[34567]]86-pc-msdosdjgpp*)
2298     md_exec_prefix=/dev/env/DJDIR/bin
2299     ;;
2300   *-*-hpux* | \
2301   *-*-nto-qnx* | \
2302   *-*-solaris2*)
2303     md_exec_prefix=/usr/ccs/bin
2304     ;;
2305 esac
2306
2307 extra_arflags_for_target=
2308 extra_nmflags_for_target=
2309 extra_ranlibflags_for_target=
2310 target_makefile_frag=/dev/null
2311 case "${target}" in
2312   spu-*-*)
2313     target_makefile_frag="config/mt-spu"
2314     ;;
2315   mips*-sde-elf*)
2316     target_makefile_frag="config/mt-sde"
2317     ;;
2318   mipsisa*-*-elfoabi*)
2319     target_makefile_frag="config/mt-mips-elfoabi"
2320     ;;
2321   mips*-*-*linux* | mips*-*-gnu*)
2322     target_makefile_frag="config/mt-mips-gnu"
2323     ;;
2324   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2325     target_makefile_frag="config/mt-gnu"
2326     ;;
2327   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2328     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2329     # commands to handle both 32-bit and 64-bit objects.  These flags are
2330     # harmless if we're using GNU nm or ar.
2331     extra_arflags_for_target=" -X32_64"
2332     extra_nmflags_for_target=" -B -X32_64"
2333     ;;
2334   *-*-darwin[[3-9]]*)
2335     # ranlib before Darwin10 requires the -c flag to look at common symbols.
2336     extra_ranlibflags_for_target=" -c"
2337     ;;
2338 esac
2339
2340 alphaieee_frag=/dev/null
2341 case $target in
2342   alpha*-*-*)
2343     # This just makes sure to use the -mieee option to build target libs.
2344     # This should probably be set individually by each library.
2345     alphaieee_frag="config/mt-alphaieee"
2346     ;;
2347 esac
2348
2349 # If --enable-target-optspace always use -Os instead of -O2 to build
2350 # the target libraries, similarly if it is not specified, use -Os
2351 # on selected platforms.
2352 ospace_frag=/dev/null
2353 case "${enable_target_optspace}:${target}" in
2354   yes:*)
2355     ospace_frag="config/mt-ospace"
2356     ;;
2357   :d30v-*)
2358     ospace_frag="config/mt-d30v"
2359     ;;
2360   :m32r-* | :d10v-* | :fr30-*)
2361     ospace_frag="config/mt-ospace"
2362     ;;
2363   no:* | :*)
2364     ;;
2365   *)
2366     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2367     ;;
2368 esac
2369
2370 # Default to using --with-stabs for certain targets.
2371 if test x${with_stabs} = x ; then
2372   case "${target}" in
2373   mips*-*-irix[[56]]*)
2374     ;;
2375   mips*-*-* | alpha*-*-osf*)
2376     with_stabs=yes;
2377     extra_host_args="${extra_host_args} --with-stabs"
2378     ;;
2379   esac
2380 fi
2381
2382 # Some systems (e.g., one of the i386-aix systems the gas testers are
2383 # using) don't handle "\$" correctly, so don't use it here.
2384 tooldir='${exec_prefix}'/${target_noncanonical}
2385 build_tooldir=${tooldir}
2386
2387 # Create a .gdbinit file which runs the one in srcdir
2388 # and tells GDB to look there for source files.
2389
2390 if test -r ${srcdir}/.gdbinit ; then
2391   case ${srcdir} in
2392     .) ;;
2393     *) cat > ./.gdbinit <<EOF
2394 # ${NO_EDIT}
2395 dir ${srcdir}
2396 dir .
2397 source ${srcdir}/.gdbinit
2398 EOF
2399     ;;
2400   esac
2401 fi
2402
2403 # Make sure that the compiler is able to generate an executable.  If it
2404 # can't, we are probably in trouble.  We don't care whether we can run the
2405 # executable--we might be using a cross compiler--we only care whether it
2406 # can be created.  At this point the main configure script has set CC.
2407 we_are_ok=no
2408 echo "int main () { return 0; }" > conftest.c
2409 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2410 if test $? = 0 ; then
2411   if test -s conftest || test -s conftest.exe ; then
2412     we_are_ok=yes
2413   fi
2414 fi
2415 case $we_are_ok in
2416   no)
2417     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2418     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2419     rm -f conftest*
2420     exit 1
2421     ;;
2422 esac
2423 rm -f conftest*
2424
2425 # Decide which environment variable is used to find dynamic libraries.
2426 case "${host}" in
2427   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2428   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2429   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2430   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2431 esac
2432
2433 # On systems where the dynamic library environment variable is PATH,
2434 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2435 # built executables to PATH.
2436 if test "$RPATH_ENVVAR" = PATH; then
2437   GCC_SHLIB_SUBDIR=/shlib
2438 else
2439   GCC_SHLIB_SUBDIR=
2440 fi
2441
2442 # Record target_configdirs and the configure arguments for target and
2443 # build configuration in Makefile.
2444 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2445 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2446
2447 # If we are building libgomp, bootstrap it.
2448 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2449   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2450 fi
2451
2452 # Determine whether gdb needs tk/tcl or not.
2453 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2454 # and in that case we want gdb to be built without tk.  Ugh!
2455 # In fact I believe gdb is the *only* package directly dependent on tk,
2456 # so we should be able to put the 'maybe's in unconditionally and
2457 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2458 # 100% sure that that's safe though.
2459
2460 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2461 case "$enable_gdbtk" in
2462   no)
2463     GDB_TK="" ;;
2464   yes)
2465     GDB_TK="${gdb_tk}" ;;
2466   *)
2467     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2468     # distro.  Eventually someone will fix this and move Insight, nee
2469     # gdbtk to a separate directory.
2470     if test -d ${srcdir}/gdb/gdbtk ; then
2471       GDB_TK="${gdb_tk}"
2472     else
2473       GDB_TK=""
2474     fi
2475     ;;
2476 esac
2477 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2478 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2479
2480 # Strip out unwanted targets.
2481
2482 # While at that, we remove Makefiles if we were started for recursive
2483 # configuration, so that the top-level Makefile reconfigures them,
2484 # like we used to do when configure itself was recursive.
2485
2486 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2487 # but now we're fixing up the Makefile ourselves with the additional
2488 # commands passed to AC_CONFIG_FILES.  Use separate variables
2489 # extrasub-{build,host,target} not because there is any reason to split
2490 # the substitutions up that way, but only to remain below the limit of
2491 # 99 commands in a script, for HP-UX sed.
2492 # Do not nest @if/@endif pairs, because configure will not warn you at all.
2493
2494 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2495   yes:both:*\ gold\ *:*,c++,* | \
2496   yes:yes:*\ gold\ *:*,c++,*) ;;
2497   yes:both:*\ gold\ *:* | \
2498   yes:yes:*\ gold\ *:*)
2499     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2500     ;;
2501 esac
2502
2503 # Adjust the toplevel makefile according to whether bootstrap was selected.
2504 case $enable_bootstrap in
2505   yes)
2506     bootstrap_suffix=bootstrap
2507     BUILD_CONFIG=bootstrap-debug
2508     ;;
2509   no)
2510     bootstrap_suffix=no-bootstrap
2511     BUILD_CONFIG=
2512     ;;
2513 esac
2514
2515 AC_MSG_CHECKING(for default BUILD_CONFIG)
2516
2517 AC_ARG_WITH([build-config],
2518   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2519                   [use config/NAME.mk build configuration])],
2520   [case $with_build_config in
2521    yes) with_build_config= ;;
2522    no) with_build_config= BUILD_CONFIG= ;;
2523    esac])
2524
2525 if test "x${with_build_config}" != x; then
2526   BUILD_CONFIG=$with_build_config
2527 else
2528   case $BUILD_CONFIG in
2529   bootstrap-debug)
2530     if echo "int f (void) { return 0; }" > conftest.c &&
2531        ${CC} -c conftest.c &&
2532        mv conftest.o conftest.o.g0 &&
2533        ${CC} -c -g conftest.c &&
2534        mv conftest.o conftest.o.g &&
2535        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2536       :
2537     else
2538       BUILD_CONFIG=
2539     fi
2540     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2541     ;;
2542   esac
2543 fi
2544 AC_MSG_RESULT($BUILD_CONFIG)
2545 AC_SUBST(BUILD_CONFIG)
2546
2547 extrasub_build=
2548 for module in ${build_configdirs} ; do
2549   if test -z "${no_recursion}" \
2550      && test -f ${build_subdir}/${module}/Makefile; then
2551     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2552     rm -f ${build_subdir}/${module}/Makefile
2553   fi
2554   extrasub_build="$extrasub_build
2555 /^@if build-$module\$/d
2556 /^@endif build-$module\$/d
2557 /^@if build-$module-$bootstrap_suffix\$/d
2558 /^@endif build-$module-$bootstrap_suffix\$/d"
2559 done
2560 extrasub_host=
2561 for module in ${configdirs} ; do
2562   if test -z "${no_recursion}"; then
2563     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2564       if test -f ${file}; then
2565         echo 1>&2 "*** removing ${file} to force reconfigure"
2566         rm -f ${file}
2567       fi
2568     done
2569   fi
2570   extrasub_host="$extrasub_host
2571 /^@if $module\$/d
2572 /^@endif $module\$/d
2573 /^@if $module-$bootstrap_suffix\$/d
2574 /^@endif $module-$bootstrap_suffix\$/d"
2575 done
2576 extrasub_target=
2577 for module in ${target_configdirs} ; do
2578   if test -z "${no_recursion}" \
2579      && test -f ${target_subdir}/${module}/Makefile; then
2580     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2581     rm -f ${target_subdir}/${module}/Makefile
2582   fi
2583
2584   # We only bootstrap target libraries listed in bootstrap_target_libs.
2585   case $bootstrap_target_libs in
2586     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2587     *) target_bootstrap_suffix=no-bootstrap ;;
2588   esac
2589
2590   extrasub_target="$extrasub_target
2591 /^@if target-$module\$/d
2592 /^@endif target-$module\$/d
2593 /^@if target-$module-$target_bootstrap_suffix\$/d
2594 /^@endif target-$module-$target_bootstrap_suffix\$/d"
2595 done
2596
2597 # Do the final fixup along with target modules.
2598 extrasub_target="$extrasub_target
2599 /^@if /,/^@endif /d"
2600
2601 # Create the serialization dependencies.  This uses a temporary file.
2602
2603 AC_ARG_ENABLE([serial-configure],
2604 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2605                 [force sequential configuration of
2606                  sub-packages for the host, target or build
2607                  machine, or all sub-packages])])
2608
2609 case ${enable_serial_configure} in
2610   yes)
2611     enable_serial_build_configure=yes
2612     enable_serial_host_configure=yes
2613     enable_serial_target_configure=yes
2614     ;;
2615 esac
2616
2617 # These force 'configure's to be done one at a time, to avoid problems
2618 # with contention over a shared config.cache.
2619 rm -f serdep.tmp
2620 echo '# serdep.tmp' > serdep.tmp
2621 olditem=
2622 test "x${enable_serial_build_configure}" = xyes &&
2623 for item in ${build_configdirs} ; do
2624   case ${olditem} in
2625     "") ;;
2626     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2627   esac
2628   olditem=${item}
2629 done
2630 olditem=
2631 test "x${enable_serial_host_configure}" = xyes &&
2632 for item in ${configdirs} ; do
2633   case ${olditem} in
2634     "") ;;
2635     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2636   esac
2637   olditem=${item}
2638 done
2639 olditem=
2640 test "x${enable_serial_target_configure}" = xyes &&
2641 for item in ${target_configdirs} ; do
2642   case ${olditem} in
2643     "") ;;
2644     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2645   esac
2646   olditem=${item}
2647 done
2648 serialization_dependencies=serdep.tmp
2649 AC_SUBST_FILE(serialization_dependencies)
2650
2651 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2652 # target, nonopt, and variable assignments.  These are the ones we
2653 # might not want to pass down to subconfigures.  The exception being
2654 # --cache-file=/dev/null, which is used to turn off the use of cache
2655 # files altogether, and which should be passed on to subconfigures.
2656 # Also strip program-prefix, program-suffix, and program-transform-name,
2657 # so that we can pass down a consistent program-transform-name.
2658 baseargs=
2659 tbaseargs=
2660 keep_next=no
2661 skip_next=no
2662 eval "set -- $ac_configure_args"
2663 for ac_arg
2664 do
2665   if test X"$skip_next" = X"yes"; then
2666     skip_next=no
2667     continue
2668   fi
2669   if test X"$keep_next" = X"yes"; then
2670     case $ac_arg in
2671       *\'*)
2672         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2673     esac
2674     baseargs="$baseargs '$ac_arg'"
2675     tbaseargs="$tbaseargs '$ac_arg'"
2676     keep_next=no
2677     continue
2678   fi
2679
2680   # Handle separated arguments.  Based on the logic generated by
2681   # autoconf 2.59.
2682   case $ac_arg in
2683     *=* | --config-cache | -C | -disable-* | --disable-* \
2684       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2685       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2686       | -with-* | --with-* | -without-* | --without-* | --x)
2687       separate_arg=no
2688       ;;
2689     -*)
2690       separate_arg=yes
2691       ;;
2692     *)
2693       separate_arg=no
2694       ;;
2695   esac
2696
2697   skip_targ=no
2698   case $ac_arg in
2699 changequote(,)
2700   --with-* | --without-*)
2701     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2702
2703     case $libopt in
2704     *[-_]include)
2705       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2706       ;;
2707     *[-_]lib)
2708       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2709       ;;
2710     *)
2711       lib=$libopt
2712       ;;
2713     esac
2714 changequote([,])
2715
2716     case $lib in
2717     mpc | mpfr | gmp | ppl | cloog)
2718       # If we're processing --with-$lib, --with-$lib-include or
2719       # --with-$lib-lib, for one of the libs above, and target is
2720       # different from host, don't pass the current argument to any
2721       # target library's configure.
2722       if test x$is_cross_compiler = xyes; then
2723         skip_targ=yes
2724       fi
2725       ;;
2726     esac
2727     ;;
2728   esac
2729
2730   case "$ac_arg" in
2731     --cache-file=/dev/null | \
2732     -cache-file=/dev/null )
2733       # Handled here to avoid the test to skip args below.
2734       baseargs="$baseargs '$ac_arg'"
2735       tbaseargs="$tbaseargs '$ac_arg'"
2736       # Assert: $separate_arg should always be no.
2737       keep_next=$separate_arg
2738       ;;
2739     --no*)
2740       continue
2741       ;;
2742     --c* | \
2743     --sr* | \
2744     --ho* | \
2745     --bu* | \
2746     --t* | \
2747     --program-* | \
2748     -cache_file* | \
2749     -srcdir* | \
2750     -host* | \
2751     -build* | \
2752     -target* | \
2753     -program-prefix* | \
2754     -program-suffix* | \
2755     -program-transform-name* )
2756       skip_next=$separate_arg
2757       continue
2758       ;;
2759     -*)
2760       # An option.  Add it.
2761       case $ac_arg in
2762         *\'*)
2763           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2764       esac
2765       baseargs="$baseargs '$ac_arg'"
2766       if test X"$skip_targ" = Xno; then
2767         tbaseargs="$tbaseargs '$ac_arg'"
2768       fi
2769       keep_next=$separate_arg
2770       ;;
2771     *)
2772       # Either a variable assignment, or a nonopt (triplet).  Don't
2773       # pass it down; let the Makefile handle this.
2774       continue
2775       ;;
2776   esac
2777 done
2778 # Remove the initial space we just introduced and, as these will be
2779 # expanded by make, quote '$'.
2780 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2781
2782 # Add in --program-transform-name, after --program-prefix and
2783 # --program-suffix have been applied to it.  Autoconf has already
2784 # doubled dollar signs and backslashes in program_transform_name; we want
2785 # the backslashes un-doubled, and then the entire thing wrapped in single
2786 # quotes, because this will be expanded first by make and then by the shell.
2787 # Also, because we want to override the logic in subdir configure scripts to
2788 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2789 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2790 ${program_transform_name}
2791 EOF_SED
2792 gcc_transform_name=`cat conftestsed.out`
2793 rm -f conftestsed.out
2794 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2795 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2796 if test "$silent" = yes; then
2797   baseargs="$baseargs --silent"
2798   tbaseargs="$tbaseargs --silent"
2799 fi
2800 baseargs="$baseargs --disable-option-checking"
2801 tbaseargs="$tbaseargs --disable-option-checking"
2802
2803 # Record and document user additions to sub configure arguments.
2804 AC_ARG_VAR([build_configargs],
2805            [additional configure arguments for build directories])
2806 AC_ARG_VAR([host_configargs],
2807            [additional configure arguments for host directories])
2808 AC_ARG_VAR([target_configargs],
2809            [additional configure arguments for target directories])
2810
2811 # For the build-side libraries, we just need to pretend we're native,
2812 # and not use the same cache file.  Multilibs are neither needed nor
2813 # desired.
2814 build_configargs="$build_configargs --cache-file=../config.cache ${baseargs}"
2815
2816 # For host modules, accept cache file option, or specification as blank.
2817 case "${cache_file}" in
2818 "") # empty
2819   cache_file_option="" ;;
2820 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
2821   cache_file_option="--cache-file=${cache_file}" ;;
2822 *) # relative path
2823   cache_file_option="--cache-file=../${cache_file}" ;;
2824 esac
2825
2826 # Host dirs don't like to share a cache file either, horribly enough.
2827 # This seems to be due to autoconf 2.5x stupidity.
2828 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
2829
2830 target_configargs="$target_configargs ${tbaseargs}"
2831
2832 # Passing a --with-cross-host argument lets the target libraries know
2833 # whether they are being built with a cross-compiler or being built
2834 # native.  However, it would be better to use other mechanisms to make the
2835 # sorts of decisions they want to make on this basis.  Please consider
2836 # this option to be deprecated.  FIXME.
2837 if test x${is_cross_compiler} = xyes ; then
2838   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
2839 fi
2840
2841 # Default to --enable-multilib.
2842 if test x${enable_multilib} = x ; then
2843   target_configargs="--enable-multilib ${target_configargs}"
2844 fi
2845
2846 # Pass --with-newlib if appropriate.  Note that target_configdirs has
2847 # changed from the earlier setting of with_newlib.
2848 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
2849   target_configargs="--with-newlib ${target_configargs}"
2850 fi
2851
2852 # Different target subdirs use different values of certain variables
2853 # (notably CXX).  Worse, multilibs use *lots* of different values.
2854 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
2855 # it doesn't automatically accept command-line overrides of them.
2856 # This means it's not safe for target subdirs to share a cache file,
2857 # which is disgusting, but there you have it.  Hopefully this can be
2858 # fixed in future.  It's still worthwhile to use a cache file for each
2859 # directory.  I think.
2860
2861 # Pass the appropriate --build, --host, --target and --cache-file arguments.
2862 # We need to pass --target, as newer autoconf's requires consistency
2863 # for target_alias and gcc doesn't manage it consistently.
2864 target_configargs="--cache-file=./config.cache ${target_configargs}"
2865
2866 FLAGS_FOR_TARGET=
2867 case " $target_configdirs " in
2868  *" newlib "*)
2869   case " $target_configargs " in
2870   *" --with-newlib "*)
2871    case "$target" in
2872     *-cygwin*)
2873       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/include -isystem $$s/winsup/cygwin/include -isystem $$s/winsup/w32api/include'
2874       ;;
2875    esac
2876
2877    # If we're not building GCC, don't discard standard headers.
2878    if test -d ${srcdir}/gcc; then
2879      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
2880
2881      if test "${build}" != "${host}"; then
2882        # On Canadian crosses, CC_FOR_TARGET will have already been set
2883        # by `configure', so we won't have an opportunity to add -Bgcc/
2884        # to it.  This is right: we don't want to search that directory
2885        # for binaries, but we want the header files in there, so add
2886        # them explicitly.
2887        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
2888
2889        # Someone might think of using the pre-installed headers on
2890        # Canadian crosses, in case the installed compiler is not fully
2891        # compatible with the compiler being built.  In this case, it
2892        # would be better to flag an error than risking having
2893        # incompatible object files being constructed.  We can't
2894        # guarantee that an error will be flagged, but let's hope the
2895        # compiler will do it, when presented with incompatible header
2896        # files.
2897      fi
2898    fi
2899
2900    case "${target}-${is_cross_compiler}" in
2901    i[[3456789]]86-*-linux*-no)
2902       # Here host == target, so we don't need to build gcc,
2903       # so we don't want to discard standard headers.
2904       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
2905       ;;
2906    *)
2907       # If we're building newlib, use its generic headers last, but search
2908       # for any libc-related directories first (so make it the last -B
2909       # switch).
2910       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
2911
2912       # If we're building libgloss, find the startup file, simulator library
2913       # and linker script.
2914       case " $target_configdirs " in
2915         *" libgloss "*)
2916         # Look for startup file, simulator library and maybe linker script.
2917         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
2918         # Look for libnosys.a in case the target needs it.
2919         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
2920         # Most targets have the linker script in the source directory.
2921         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
2922         ;;
2923       esac
2924       ;;
2925    esac
2926    ;;
2927   esac
2928   ;;
2929 esac
2930
2931 case "$target" in
2932   x86_64-*mingw* | *-w64-mingw*)
2933   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
2934   # however, use a symlink named 'mingw' in ${prefix} .
2935     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
2936     ;;
2937   *-mingw*)
2938   # MinGW can't be handled as Cygwin above since it does not use newlib.
2939     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
2940     ;;
2941 esac
2942
2943 # Allow the user to override the flags for
2944 # our build compiler if desired.
2945 if test x"${build}" = x"${host}" ; then
2946   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
2947   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
2948   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
2949 fi
2950
2951 # On Canadian crosses, we'll be searching the right directories for
2952 # the previously-installed cross compiler, so don't bother to add
2953 # flags for directories within the install tree of the compiler
2954 # being built; programs in there won't even run.
2955 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
2956   # Search for pre-installed headers if nothing else fits.
2957   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
2958 fi
2959
2960 if test "x${use_gnu_ld}" = x &&
2961    echo " ${configdirs} " | grep " ld " > /dev/null ; then
2962   # Arrange for us to find uninstalled linker scripts.
2963   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
2964 fi
2965
2966 # Search for other target-specific linker scripts and such.
2967 case "${target}" in
2968   mep*)
2969     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
2970     ;;
2971 esac
2972
2973 # Makefile fragments.
2974 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
2975 do
2976   eval fragval=\$$frag
2977   if test $fragval != /dev/null; then
2978     eval $frag=${srcdir}/$fragval
2979   fi
2980 done
2981 AC_SUBST_FILE(host_makefile_frag)
2982 AC_SUBST_FILE(target_makefile_frag)
2983 AC_SUBST_FILE(alphaieee_frag)
2984 AC_SUBST_FILE(ospace_frag)
2985
2986 # Miscellanea: directories, flags, etc.
2987 AC_SUBST(RPATH_ENVVAR)
2988 AC_SUBST(GCC_SHLIB_SUBDIR)
2989 AC_SUBST(tooldir)
2990 AC_SUBST(build_tooldir)
2991 AC_SUBST(CONFIGURE_GDB_TK)
2992 AC_SUBST(GDB_TK)
2993 AC_SUBST(INSTALL_GDB_TK)
2994
2995 # Build module lists & subconfigure args.
2996 AC_SUBST(build_configargs)
2997 AC_SUBST(build_configdirs)
2998
2999 # Host module lists & subconfigure args.
3000 AC_SUBST(host_configargs)
3001 AC_SUBST(configdirs)
3002 AC_SUBST(target_configdirs)
3003
3004 # Target module lists & subconfigure args.
3005 AC_SUBST(target_configargs)
3006
3007
3008 # Build tools.
3009 AC_SUBST(AR_FOR_BUILD)
3010 AC_SUBST(AS_FOR_BUILD)
3011 AC_SUBST(CC_FOR_BUILD)
3012 AC_SUBST(CFLAGS_FOR_BUILD)
3013 AC_SUBST(CXXFLAGS_FOR_BUILD)
3014 AC_SUBST(CXX_FOR_BUILD)
3015 AC_SUBST(DLLTOOL_FOR_BUILD)
3016 AC_SUBST(GCJ_FOR_BUILD)
3017 AC_SUBST(GFORTRAN_FOR_BUILD)
3018 AC_SUBST(GOC_FOR_BUILD)
3019 AC_SUBST(LDFLAGS_FOR_BUILD)
3020 AC_SUBST(LD_FOR_BUILD)
3021 AC_SUBST(NM_FOR_BUILD)
3022 AC_SUBST(RANLIB_FOR_BUILD)
3023 AC_SUBST(WINDMC_FOR_BUILD)
3024 AC_SUBST(WINDRES_FOR_BUILD)
3025
3026 # Generate default definitions for YACC, M4, LEX and other programs that run
3027 # on the build machine.  These are used if the Makefile can't locate these
3028 # programs in objdir.
3029 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3030
3031 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3032
3033 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3034
3035 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3036
3037 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3038
3039 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3040
3041 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3042 case " $build_configdirs " in
3043   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3044   *)
3045 changequote(,)
3046     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3047     # higher, else we use the "missing" dummy.
3048     if ${MAKEINFO} --version \
3049        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3050       :
3051     else
3052       MAKEINFO="$MISSING makeinfo"
3053     fi
3054     ;;
3055 changequote([,])
3056 esac
3057
3058 # FIXME: expect and dejagnu may become build tools?
3059
3060 AC_CHECK_PROGS(EXPECT, expect, expect)
3061 case " $configdirs " in
3062   *" expect "*)
3063     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3064     ;;
3065 esac
3066
3067 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3068 case " $configdirs " in
3069   *" dejagnu "*)
3070     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3071     ;;
3072 esac
3073
3074
3075 # Host tools.
3076 NCN_STRICT_CHECK_TOOLS(AR, ar)
3077 NCN_STRICT_CHECK_TOOLS(AS, as)
3078 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3079 NCN_STRICT_CHECK_TOOLS(LD, ld)
3080 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3081 NCN_STRICT_CHECK_TOOLS(NM, nm)
3082 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3083 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3084 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3085 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3086 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3087 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3088 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3089 AC_SUBST(CC)
3090 AC_SUBST(CXX)
3091 AC_SUBST(CFLAGS)
3092 AC_SUBST(CXXFLAGS)
3093
3094 # Target tools.
3095 AC_ARG_WITH([build-time-tools],
3096   [AS_HELP_STRING([--with-build-time-tools=PATH],
3097                   [use given path to find target tools during the build])],
3098   [case x"$withval" in
3099      x/*) ;;
3100      *)
3101        with_build_time_tools=
3102        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3103        ;;
3104    esac],
3105   [with_build_time_tools=])
3106
3107 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3108 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3109 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3110 NCN_STRICT_CHECK_TARGET_TOOLS(GCJ_FOR_TARGET, gcj)
3111 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3112 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3113
3114 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3115 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3116 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3117 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3118 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3119 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3120 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3121 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3122 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3123 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3124 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3125 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3126
3127 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3128
3129 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3130 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3131 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3132 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3133 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3134                 [gcc/g++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3135                 c++)
3136 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3137                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs],
3138                 c++)
3139 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3140 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3141 GCC_TARGET_TOOL(gcj, GCJ_FOR_TARGET, GCJ,
3142                 [gcc/gcj -B$$r/$(HOST_SUBDIR)/gcc/], java)
3143 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3144                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3145 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3146                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3147 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3148 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3149 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3150 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3151 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3152 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3153 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3154 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3155 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3156
3157 AC_SUBST(FLAGS_FOR_TARGET)
3158 AC_SUBST(RAW_CXX_FOR_TARGET)
3159
3160 # Certain tools may need extra flags.
3161 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3162 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3163 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3164
3165 # When building target libraries, except in a Canadian cross, we use
3166 # the same toolchain as the compiler we just built.
3167 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3168 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3169 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3170 if test $host = $build; then
3171   case " $configdirs " in
3172     *" gcc "*)
3173       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3174       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3175       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3176       ;;
3177   esac
3178 fi
3179
3180 AC_SUBST(COMPILER_AS_FOR_TARGET)
3181 AC_SUBST(COMPILER_LD_FOR_TARGET)
3182 AC_SUBST(COMPILER_NM_FOR_TARGET)
3183
3184 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3185 AC_ARG_ENABLE(maintainer-mode,
3186 [AS_HELP_STRING([--enable-maintainer-mode],
3187                 [enable make rules and dependencies not useful
3188                  (and sometimes confusing) to the casual installer])],
3189       USE_MAINTAINER_MODE=$enableval,
3190       USE_MAINTAINER_MODE=no)
3191 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3192 AC_SUBST(MAINTAINER_MODE_TRUE)
3193 AC_SUBST(MAINTAINER_MODE_FALSE)
3194 if test "$USE_MAINTAINER_MODE" = yes; then
3195   MAINTAINER_MODE_TRUE=
3196   MAINTAINER_MODE_FALSE='#'
3197 else
3198   MAINTAINER_MODE_TRUE='#'
3199   MAINTAINER_MODE_FALSE=
3200 fi
3201 MAINT=$MAINTAINER_MODE_TRUE
3202 AC_SUBST(MAINT)dnl
3203
3204 # ---------------------
3205 # GCC bootstrap support
3206 # ---------------------
3207
3208 # Stage specific cflags for build.
3209 stage1_cflags="-g"
3210 case $build in
3211   vax-*-*)
3212     case ${GCC} in
3213       yes) stage1_cflags="-g -Wa,-J" ;;
3214       *) stage1_cflags="-g -J" ;;
3215     esac ;;
3216 esac
3217
3218 # This is aimed to mimic bootstrap with a non-GCC compiler to catch problems.
3219 if test "$GCC" = yes -a "$ENABLE_BUILD_WITH_CXX" != yes; then
3220   saved_CFLAGS="$CFLAGS"
3221
3222   # Pass -fkeep-inline-functions for stage 1 if the GCC version supports it.
3223   CFLAGS="$CFLAGS -fkeep-inline-functions"
3224   AC_MSG_CHECKING([whether -fkeep-inline-functions is supported])
3225   AC_TRY_COMPILE([
3226 #if (__GNUC__ < 3) \
3227     || (__GNUC__ == 3 && (__GNUC_MINOR__ < 3 \
3228                           || (__GNUC_MINOR__ == 3 && __GNUC_PATCHLEVEL__ < 1)))
3229 #error http://gcc.gnu.org/PR29382
3230 #endif
3231     ],,
3232     [AC_MSG_RESULT([yes]); stage1_cflags="$stage1_cflags -fkeep-inline-functions"],
3233     [AC_MSG_RESULT([no])])
3234
3235   CFLAGS="$saved_CFLAGS"
3236 fi
3237
3238 AC_SUBST(stage1_cflags)
3239
3240 # Enable --enable-checking in stage1 of the compiler.
3241 AC_ARG_ENABLE(stage1-checking,
3242 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3243                 [choose additional checking for stage1 of the compiler])],
3244 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3245 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3246   stage1_checking=--enable-checking=yes,types
3247 else
3248   stage1_checking=--enable-checking=$enable_checking,types
3249 fi])
3250 AC_SUBST(stage1_checking)
3251
3252 # Enable -Werror in bootstrap stage2 and later.
3253 AC_ARG_ENABLE(werror,
3254 [AS_HELP_STRING([--enable-werror],
3255                 [enable -Werror in bootstrap stage2 and later])], [],
3256 [if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3257   enable_werror=yes
3258 else
3259   enable_werror=no
3260 fi])
3261 case ${enable_werror} in
3262   yes) stage2_werror_flag="--enable-werror-always" ;;
3263   *) stage2_werror_flag="" ;;
3264 esac
3265 AC_SUBST(stage2_werror_flag)
3266
3267 # If using ENABLE_BUILD_POSTSTAGE1_WITH_CXX, pass
3268 # --enable-build-with-cxx after stage1.
3269 if test "$ENABLE_BUILD_POSTSTAGE1_WITH_CXX" = "yes"; then
3270   POSTSTAGE1_CONFIGURE_FLAGS=--enable-build-with-cxx
3271 else
3272   POSTSTAGE1_CONFIGURE_FLAGS=
3273 fi
3274 AC_SUBST(POSTSTAGE1_CONFIGURE_FLAGS)
3275
3276 # Specify what files to not compare during bootstrap.
3277
3278 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3279 case "$target" in
3280   hppa*64*-*-hpux*) ;;
3281   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/*" ;;
3282 esac
3283 case " $configdirs " in
3284 *" ppl "*) compare_exclusions="$compare_exclusions | ppl/src/ppl-config.o" ;;
3285 esac
3286 AC_SUBST(compare_exclusions)
3287
3288 AC_CONFIG_FILES([Makefile],
3289   [sed "$extrasub_build" Makefile |
3290    sed "$extrasub_host" |
3291    sed "$extrasub_target" > mf$$
3292    mv -f mf$$ Makefile],
3293   [extrasub_build="$extrasub_build"
3294    extrasub_host="$extrasub_host"
3295    extrasub_target="$extrasub_target"])
3296 AC_OUTPUT