configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [9.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CONFIG_MACRO_DIR([m4])
  13 AC_CANONICAL_SYSTEM
  14 AM_INIT_AUTOMAKE([foreign])
  15
  16 dnl http://people.gnome.org/~walters/docs/build-api.txt
  17 dnl We don't support srcdir != builddir.
  18 echo \#buildapi-variable-no-builddir >/dev/null
  19
  20 # Support silent build rules, requires at least automake-1.11. Disable
  21 # by either passing --disable-silent-rules to configure or passing V=1
  22 # to make
  23 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  24
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 dnl Set internal versions
  28 OSMESA_VERSION=8
  29 AC_SUBST([OSMESA_VERSION])
  30
  31 dnl Versions for external dependencies
  32 LIBDRM_REQUIRED=2.4.24
  33 LIBDRM_RADEON_REQUIRED=2.4.40
  34 LIBDRM_INTEL_REQUIRED=2.4.38
  35 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  36 LIBDRM_NOUVEAU_REQUIRED="2.4.33 libdrm >= 2.4.41"
  37 DRI2PROTO_REQUIRED=2.6
  38 GLPROTO_REQUIRED=1.4.14
  39 LIBDRM_XORG_REQUIRED=2.4.24
  40 LIBKMS_XORG_REQUIRED=1.0.0
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AX_PROG_CC_FOR_BUILD
  46 AC_PROG_CXX
  47 AX_PROG_CXX_FOR_BUILD
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AX_PYTHON_MODULE([libxml2], [needed])
  53 AC_PROG_SED
  54 AC_PROG_MKDIR_P
  55
  56 LT_PREREQ([2.2])
  57 LT_INIT([disable-static])
  58
  59 AX_PROG_BISON([],
  60               AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"]
  61                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
  62 AX_PROG_FLEX([],
  63              AS_IF([test ! -f "$srcdir/src/glsl/glcpp/glcpp-lex.c"]
  64                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
  65
  66 AC_PATH_PROG([PERL], [perl])
  67
  68 AC_CHECK_PROG(INDENT, indent, indent, cat)
  69 if test "x$INDENT" != "xcat"; then
  70     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
  71 fi
  72
  73 AC_PROG_INSTALL
  74
  75 dnl We need a POSIX shell for parts of the build. Assume we have one
  76 dnl in most cases.
  77 case "$host_os" in
  78 solaris*)
  79     # Solaris /bin/sh is too old/non-POSIX compliant
  80     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  81     SHELL="$POSIX_SHELL"
  82     ;;
  83 esac
  84
  85 dnl clang is mostly GCC-compatible, but its version is much lower,
  86 dnl so we have to check for it.
  87 AC_MSG_CHECKING([if compiling with clang])
  88
  89 AC_COMPILE_IFELSE(
  90 [AC_LANG_PROGRAM([], [[
  91 #ifndef __clang__
  92        not clang
  93 #endif
  94 ]])],
  95 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  96
  97 AC_MSG_RESULT([$acv_mesa_CLANG])
  98
  99 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 100 dnl versions are explictly not supported.
 101 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 102     AC_MSG_CHECKING([whether gcc version is sufficient])
 103     major=0
 104     minor=0
 105
 106     GCC_VERSION=`$CC -dumpversion`
 107     if test $? -eq 0; then
 108         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 109         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 110     fi
 111
 112     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 113         AC_MSG_RESULT([no])
 114         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 115     else
 116         AC_MSG_RESULT([yes])
 117     fi
 118 fi
 119
 120 dnl Make sure the pkg-config macros are defined
 121 m4_ifndef([PKG_PROG_PKG_CONFIG],
 122     [m4_fatal([Could not locate the pkg-config autoconf macros.
 123   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 124   are in a different location, try setting the environment variable
 125   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 126 PKG_PROG_PKG_CONFIG()
 127
 128 dnl LIB_DIR - library basename
 129 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 130 AC_SUBST([LIB_DIR])
 131
 132 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 133 _SAVE_LDFLAGS="$LDFLAGS"
 134 _SAVE_CPPFLAGS="$CPPFLAGS"
 135
 136 dnl build host compiler macros
 137 DEFINES_FOR_BUILD=""
 138 AC_SUBST([DEFINES_FOR_BUILD])
 139 case "$build_os" in
 140 linux*|*-gnu*|gnu*)
 141     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -D_GNU_SOURCE"
 142     ;;
 143 solaris*)
 144     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DSVR4"
 145     ;;
 146 cygwin*)
 147     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD"
 148     ;;
 149 esac
 150
 151 dnl Compiler macros
 152 DEFINES=""
 153 AC_SUBST([DEFINES])
 154 case "$host_os" in
 155 linux*|*-gnu*|gnu*)
 156     DEFINES="$DEFINES -D_GNU_SOURCE -DHAVE_PTHREAD"
 157     ;;
 158 solaris*)
 159     DEFINES="$DEFINES -DHAVE_PTHREAD -DSVR4"
 160     ;;
 161 cygwin*)
 162     DEFINES="$DEFINES -DHAVE_PTHREAD"
 163     ;;
 164 esac
 165
 166 dnl Add flags for gcc and g++
 167 if test "x$GCC" = xyes; then
 168     case "$host_os" in
 169     cygwin*)
 170         CFLAGS="$CFLAGS -Wall -std=gnu99"
 171         ;;
 172     *)
 173         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -Wall -std=c99"
 174         CFLAGS="$CFLAGS -Wall -std=c99"
 175         ;;
 176     esac
 177
 178     # Enable -Werror=implicit-function-declaration and
 179     # -Werror=missing-prototypes, if available, or otherwise, just
 180     # -Wmissing-prototypes.  This is particularly useful to avoid
 181     # generating a loadable driver module that has undefined symbols.
 182     save_CFLAGS="$CFLAGS"
 183     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 184     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 185     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 186     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 187                    AC_MSG_RESULT([yes]),
 188                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 189                     AC_MSG_RESULT([no])]);
 190
 191     # Enable -fvisibility=hidden if using a gcc that supports it
 192     save_CFLAGS="$CFLAGS"
 193     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 194     VISIBILITY_CFLAGS="-fvisibility=hidden"
 195     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 196     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 197                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 198
 199     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 200     CFLAGS=$save_CFLAGS
 201
 202     # Work around aliasing bugs - developers should comment this out
 203     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-strict-aliasing"
 204     CFLAGS="$CFLAGS -fno-strict-aliasing"
 205
 206     # gcc's builtin memcmp is slower than glibc's
 207     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 208     CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -fno-builtin-memcmp"
 209     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 210 fi
 211 if test "x$GXX" = xyes; then
 212     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -Wall"
 213     CXXFLAGS="$CXXFLAGS -Wall"
 214
 215     # Enable -fvisibility=hidden if using a gcc that supports it
 216     save_CXXFLAGS="$CXXFLAGS"
 217     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 218     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 219     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 220     AC_LANG_PUSH([C++])
 221     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 222                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 223     AC_LANG_POP([C++])
 224
 225     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 226     CXXFLAGS=$save_CXXFLAGS
 227
 228     # Work around aliasing bugs - developers should comment this out
 229     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-strict-aliasing"
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -fno-builtin-memcmp"
 235     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 236 fi
 237
 238 dnl even if the compiler appears to support it, using visibility attributes isn't
 239 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 240 case "$host_os" in
 241 cygwin*)
 242     VISIBILITY_CFLAGS=""
 243     VISIBILITY_CXXFLAGS=""
 244     ;;
 245 esac
 246
 247 AC_SUBST([VISIBILITY_CFLAGS])
 248 AC_SUBST([VISIBILITY_CXXFLAGS])
 249
 250 dnl
 251 dnl Hacks to enable 32 or 64 bit build
 252 dnl
 253 AC_ARG_ENABLE([32-bit],
 254     [AS_HELP_STRING([--enable-32-bit],
 255         [build 32-bit libraries @<:@default=auto@:>@])],
 256     [enable_32bit="$enableval"],
 257     [enable_32bit=auto]
 258 )
 259 if test "x$enable_32bit" = xyes; then
 260     if test "x$GCC" = xyes; then
 261         CFLAGS="$CFLAGS -m32"
 262         CCASFLAGS="$CCASFLAGS -m32"
 263     fi
 264     if test "x$GXX" = xyes; then
 265         CXXFLAGS="$CXXFLAGS -m32"
 266     fi
 267 fi
 268 AC_ARG_ENABLE([64-bit],
 269     [AS_HELP_STRING([--enable-64-bit],
 270         [build 64-bit libraries @<:@default=auto@:>@])],
 271     [enable_64bit="$enableval"],
 272     [enable_64bit=auto]
 273 )
 274 if test "x$enable_64bit" = xyes; then
 275     if test "x$GCC" = xyes; then
 276         CFLAGS="$CFLAGS -m64"
 277     fi
 278     if test "x$GXX" = xyes; then
 279         CXXFLAGS="$CXXFLAGS -m64"
 280     fi
 281 fi
 282
 283 dnl Can't have static and shared libraries, default to static if user
 284 dnl explicitly requested. If both disabled, set to static since shared
 285 dnl was explicitly requested.
 286 case "x$enable_static$enable_shared" in
 287 xyesyes )
 288     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 289     enable_shared=no
 290     ;;
 291 xnono )
 292     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 293     enable_static=yes
 294     ;;
 295 esac
 296
 297 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 298
 299 dnl
 300 dnl other compiler options
 301 dnl
 302 AC_ARG_ENABLE([debug],
 303     [AS_HELP_STRING([--enable-debug],
 304         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 305     [enable_debug="$enableval"],
 306     [enable_debug=no]
 307 )
 308 if test "x$enable_debug" = xyes; then
 309     DEFINES_FOR_BUILD="$DEFINES_FOR_BUILD -DDEBUG"
 310     if test "x$GCC_FOR_BUILD" = xyes; then
 311         CFLAGS_FOR_BUILD="$CFLAGS_FOR_BUILD -g -O0"
 312     fi
 313     if test "x$GXX_FOR_BUILD" = xyes; then
 314         CXXFLAGS_FOR_BUILD="$CXXFLAGS_FOR_BUILD -g -O0"
 315     fi
 316
 317     DEFINES="$DEFINES -DDEBUG"
 318     if test "x$GCC" = xyes; then
 319         CFLAGS="$CFLAGS -g -O0"
 320     fi
 321     if test "x$GXX" = xyes; then
 322         CXXFLAGS="$CXXFLAGS -g -O0"
 323     fi
 324 fi
 325
 326 dnl
 327 dnl library names
 328 dnl
 329 LIB_PREFIX_GLOB='lib'
 330 LIB_VERSION_SEPARATOR='.'
 331 if test "$enable_static" = yes; then
 332     LIB_EXTENSION='a'
 333 else
 334     case "$host_os" in
 335     darwin* )
 336         LIB_EXTENSION='dylib' ;;
 337     cygwin* )
 338         dnl prefix can be 'cyg' or 'lib'
 339         LIB_PREFIX_GLOB='???'
 340         LIB_VERSION_SEPARATOR='-'
 341         LIB_EXTENSION='dll' ;;
 342     aix* )
 343         LIB_EXTENSION='a' ;;
 344     * )
 345         LIB_EXTENSION='so' ;;
 346     esac
 347 fi
 348 AC_ARG_WITH([gl-lib-name],
 349   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 350     [specify GL library name @<:@default=GL@:>@])],
 351   [GL_LIB=$withval],
 352   [GL_LIB=GL])
 353 AC_ARG_WITH([osmesa-lib-name],
 354   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 355     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 356   [OSMESA_LIB=$withval],
 357   [OSMESA_LIB=OSMesa])
 358 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 359 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 360
 361 dnl
 362 dnl Mangled Mesa support
 363 dnl
 364 AC_ARG_ENABLE([mangling],
 365   [AS_HELP_STRING([--enable-mangling],
 366     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 367   [enable_mangling="${enableval}"],
 368   [enable_mangling=no]
 369 )
 370 if test "x${enable_mangling}" = "xyes" ; then
 371   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 372   GL_LIB="Mangled${GL_LIB}"
 373   OSMESA_LIB="Mangled${OSMESA_LIB}"
 374 fi
 375 AC_SUBST([GL_LIB])
 376 AC_SUBST([OSMESA_LIB])
 377
 378 dnl
 379 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 380 dnl
 381 AC_ARG_ENABLE([texture-float],
 382     [AS_HELP_STRING([--enable-texture-float],
 383         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 384     [enable_texture_float="$enableval"],
 385     [enable_texture_float=no]
 386 )
 387 if test "x$enable_texture_float" = xyes; then
 388     AC_MSG_WARN([Floating-point textures enabled.])
 389     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 390     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 391 fi
 392
 393 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 394 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 395 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 396 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 397 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 398 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 399 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 400
 401 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408
 409 AC_SUBST([GL_LIB_NAME])
 410 AC_SUBST([OSMESA_LIB_NAME])
 411 AC_SUBST([EGL_LIB_NAME])
 412 AC_SUBST([GLESv1_CM_LIB_NAME])
 413 AC_SUBST([GLESv2_LIB_NAME])
 414 AC_SUBST([VG_LIB_NAME])
 415 AC_SUBST([GLAPI_LIB_NAME])
 416
 417 AC_SUBST([GL_LIB_GLOB])
 418 AC_SUBST([EGL_LIB_GLOB])
 419 AC_SUBST([GLESv1_CM_LIB_GLOB])
 420 AC_SUBST([GLESv2_LIB_GLOB])
 421 AC_SUBST([VG_LIB_GLOB])
 422 AC_SUBST([GLAPI_LIB_GLOB])
 423
 424 dnl
 425 dnl Arch/platform-specific settings
 426 dnl
 427 AC_ARG_ENABLE([asm],
 428     [AS_HELP_STRING([--disable-asm],
 429         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 430     [enable_asm="$enableval"],
 431     [enable_asm=yes]
 432 )
 433 asm_arch=""
 434 MESA_ASM_FILES=""
 435 AC_MSG_CHECKING([whether to enable assembly])
 436 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 437 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 438 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 439     case "$host_cpu" in
 440     i?86 | x86_64)
 441         enable_asm=no
 442         AC_MSG_RESULT([no, cross compiling])
 443         ;;
 444     esac
 445 fi
 446 # check for supported arches
 447 if test "x$enable_asm" = xyes; then
 448     case "$host_cpu" in
 449     i?86)
 450         case "$host_os" in
 451         linux* | *freebsd* | dragonfly* | *netbsd*)
 452             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 453             ;;
 454         esac
 455         ;;
 456     x86_64)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 460             ;;
 461         esac
 462         ;;
 463     sparc*)
 464         case "$host_os" in
 465         linux*)
 466             asm_arch=sparc
 467             ;;
 468         esac
 469         ;;
 470     esac
 471
 472     case "$asm_arch" in
 473     x86)
 474         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 475         MESA_ASM_FILES='$(X86_FILES)'
 476         AC_MSG_RESULT([yes, x86])
 477         ;;
 478     x86_64)
 479         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 480         MESA_ASM_FILES='$(X86_64_FILES)'
 481         AC_MSG_RESULT([yes, x86_64])
 482         ;;
 483     sparc)
 484         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 485         MESA_ASM_FILES='$(SPARC_FILES)'
 486         AC_MSG_RESULT([yes, sparc])
 487         ;;
 488     *)
 489         AC_MSG_RESULT([no, platform not supported])
 490         ;;
 491     esac
 492 fi
 493 AC_SUBST([MESA_ASM_FILES])
 494
 495 dnl Check to see if dlopen is in default libraries (like Solaris, which
 496 dnl has it in libc), or if libdl is needed to get it.
 497 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 498     [AC_CHECK_LIB([dl], [dlopen],
 499        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 500 AC_SUBST([DLOPEN_LIBS])
 501
 502 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 503                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 504                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 505 AC_SUBST([CLOCK_LIB])
 506
 507 dnl See if posix_memalign is available
 508 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 509
 510 dnl Check for pthreads
 511 AX_PTHREAD
 512 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 513 dnl to -pthread, which causes problems if we need -lpthread to appear in
 514 dnl pkgconfig files.
 515 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 516
 517 dnl SELinux awareness.
 518 AC_ARG_ENABLE([selinux],
 519     [AS_HELP_STRING([--enable-selinux],
 520         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 521     [MESA_SELINUX="$enableval"],
 522     [MESA_SELINUX=no])
 523 if test "x$enable_selinux" = "xyes"; then
 524     AC_CHECK_HEADER([selinux/selinux.h],[],
 525                     [AC_MSG_ERROR([SELinux headers not found])])
 526     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 527                  [AC_MSG_ERROR([SELinux library not found])])
 528     SELINUX_LIBS="-lselinux"
 529     DEFINES="$DEFINES -DMESA_SELINUX"
 530 fi
 531 AC_SUBST([SELINUX_LIBS])
 532
 533 dnl Options for APIs
 534 AC_ARG_ENABLE([opengl],
 535     [AS_HELP_STRING([--disable-opengl],
 536         [disable support for standard OpenGL API @<:@default=no@:>@])],
 537     [enable_opengl="$enableval"],
 538     [enable_opengl=yes])
 539 AC_ARG_ENABLE([gles1],
 540     [AS_HELP_STRING([--enable-gles1],
 541         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 542     [enable_gles1="$enableval"],
 543     [enable_gles1=no])
 544 AC_ARG_ENABLE([gles2],
 545     [AS_HELP_STRING([--enable-gles2],
 546         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 547     [enable_gles2="$enableval"],
 548     [enable_gles2=no])
 549 AC_ARG_ENABLE([openvg],
 550     [AS_HELP_STRING([--enable-openvg],
 551         [enable support for OpenVG API @<:@default=no@:>@])],
 552     [enable_openvg="$enableval"],
 553     [enable_openvg=no])
 554
 555 AC_ARG_ENABLE([dri],
 556     [AS_HELP_STRING([--enable-dri],
 557         [enable DRI modules @<:@default=enabled@:>@])],
 558     [enable_dri="$enableval"],
 559     [enable_dri=yes])
 560 AC_ARG_ENABLE([glx],
 561     [AS_HELP_STRING([--enable-glx],
 562         [enable GLX library @<:@default=enabled@:>@])],
 563     [enable_glx="$enableval"],
 564     [enable_glx=yes])
 565 AC_ARG_ENABLE([osmesa],
 566     [AS_HELP_STRING([--enable-osmesa],
 567         [enable OSMesa library @<:@default=disabled@:>@])],
 568     [enable_osmesa="$enableval"],
 569     [enable_osmesa=no])
 570 AC_ARG_ENABLE([egl],
 571     [AS_HELP_STRING([--disable-egl],
 572         [disable EGL library @<:@default=enabled@:>@])],
 573     [enable_egl="$enableval"],
 574     [enable_egl=yes])
 575
 576 AC_ARG_ENABLE([xorg],
 577     [AS_HELP_STRING([--enable-xorg],
 578         [enable support for X.Org DDX API @<:@default=no@:>@])],
 579     [enable_xorg="$enableval"],
 580     [enable_xorg=no])
 581 AC_ARG_ENABLE([xa],
 582     [AS_HELP_STRING([--enable-xa],
 583         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 584     [enable_xa="$enableval"],
 585     [enable_xa=no])
 586 dnl Broken, unmaintained. Don't want to see bug reports about it without patches.
 587 enable_d3d1x=no
 588 dnl AC_ARG_ENABLE([d3d1x],
 589 dnl     [AS_HELP_STRING([--enable-d3d1x],
 590 dnl         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 591 dnl     [enable_d3d1x="$enableval"],
 592 dnl     [enable_d3d1x=no])
 593 AC_ARG_ENABLE([gbm],
 594    [AS_HELP_STRING([--enable-gbm],
 595          [enable gbm library @<:@default=auto@:>@])],
 596    [enable_gbm="$enableval"],
 597    [enable_gbm=auto])
 598
 599 AC_ARG_ENABLE([xvmc],
 600    [AS_HELP_STRING([--enable-xvmc],
 601          [enable xvmc library @<:@default=auto@:>@])],
 602    [enable_xvmc="$enableval"],
 603    [enable_xvmc=auto])
 604 AC_ARG_ENABLE([vdpau],
 605    [AS_HELP_STRING([--enable-vdpau],
 606          [enable vdpau library @<:@default=auto@:>@])],
 607    [enable_vdpau="$enableval"],
 608    [enable_vdpau=auto])
 609 AC_ARG_ENABLE([opencl],
 610    [AS_HELP_STRING([--enable-opencl],
 611          [enable OpenCL library NOTE: Enabling this option will also enable
 612           --with-llvm-shared-libs
 613           @<:@default=no@:>@])],
 614    [enable_opencl="$enableval" with_llvm_shared_libs="$enableval"],
 615    [enable_opencl=no])
 616 AC_ARG_ENABLE([xlib_glx],
 617     [AS_HELP_STRING([--enable-xlib-glx],
 618         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 619     [enable_xlib_glx="$enableval"],
 620     [enable_xlib_glx=no])
 621 AC_ARG_ENABLE([gallium_egl],
 622     [AS_HELP_STRING([--enable-gallium-egl],
 623         [enable optional EGL state tracker (not required
 624          for EGL support in Gallium with OpenGL and OpenGL ES)
 625          @<:@default=disable@:>@])],
 626     [enable_gallium_egl="$enableval"],
 627     [enable_gallium_egl=no])
 628 AC_ARG_ENABLE([gallium_gbm],
 629     [AS_HELP_STRING([--enable-gallium-gbm],
 630         [enable optional gbm state tracker (not required for
 631          gbm support in Gallium)
 632          @<:@default=auto@:>@])],
 633     [enable_gallium_gbm="$enableval"],
 634     [enable_gallium_gbm=auto])
 635
 636 AC_ARG_ENABLE([r600-llvm-compiler],
 637     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 638         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 639     [enable_r600_llvm="$enableval"],
 640     [enable_r600_llvm=no])
 641
 642 AC_ARG_ENABLE([gallium_tests],
 643     [AS_HELP_STRING([--enable-gallium-tests],
 644         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 645     [enable_gallium_tests="$enableval"],
 646     [enable_gallium_tests=no])
 647
 648 # Option for Gallium drivers
 649
 650 # Keep this in sync with the --with-gallium-drivers help string default value
 651 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 652
 653 AC_ARG_WITH([gallium-drivers],
 654     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 655         [comma delimited Gallium drivers list, e.g.
 656         "i915,nouveau,r300,r600,radeonsi,svga,swrast"
 657         @<:@default=r300,r600,svga,swrast@:>@])],
 658     [with_gallium_drivers="$withval"],
 659     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 660
 661 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 662 # here so that the script doesn't choke on an unknown driver name later.
 663 case "$with_gallium_drivers" in
 664     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 665     no) with_gallium_drivers='' ;;
 666 esac
 667
 668 if test "x$enable_opengl" = xno -a \
 669         "x$enable_gles1" = xno -a \
 670         "x$enable_gles2" = xno -a \
 671         "x$enable_openvg" = xno -a \
 672         "x$enable_xorg" = xno -a \
 673         "x$enable_xa" = xno -a \
 674         "x$enable_d3d1x" = xno -a \
 675         "x$enable_xvmc" = xno -a \
 676         "x$enable_vdpau" = xno -a \
 677         "x$enable_opencl" = xno; then
 678     AC_MSG_ERROR([at least one API should be enabled])
 679 fi
 680
 681 API_DEFINES=""
 682 if test "x$enable_opengl" = xno; then
 683     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 684 else
 685     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 686 fi
 687 if test "x$enable_gles1" = xyes; then
 688     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 689 fi
 690 if test "x$enable_gles2" = xyes; then
 691     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 692 fi
 693 AC_SUBST([API_DEFINES])
 694
 695 if test "x$enable_glx" = xno; then
 696     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 697     enable_xlib_glx=no
 698 fi
 699
 700 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 701     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 702 fi
 703
 704 # Disable GLX if DRI and Xlib-GLX are not enabled
 705 if test "x$enable_glx" = xyes -a \
 706         "x$enable_dri" = xno -a \
 707         "x$enable_xlib_glx" = xno; then
 708     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 709     enable_glx=no
 710 fi
 711
 712 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 713 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 714                                   "x$enable_osmesa" = xyes)
 715
 716 AC_ARG_ENABLE([shared-glapi],
 717     [AS_HELP_STRING([--enable-shared-glapi],
 718         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 719     [enable_shared_glapi="$enableval"],
 720     [enable_shared_glapi="$enable_dri"])
 721
 722 # Shared GLAPI is only useful for DRI
 723 if test "x$enable_dri" = xno; then
 724     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 725     enable_shared_glapi=no
 726 fi
 727
 728 if test "x$enable_shared_glapi" = xyes; then
 729     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 730     # the remap table)
 731     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 732     CORE_DIRS="mapi/shared-glapi"
 733 fi
 734 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 735
 736 dnl
 737 dnl Driver specific build directories
 738 dnl
 739 GALLIUM_DIRS="auxiliary drivers state_trackers"
 740 GALLIUM_TARGET_DIRS=""
 741 GALLIUM_WINSYS_DIRS="sw"
 742 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 743 GALLIUM_STATE_TRACKERS_DIRS=""
 744
 745 # build glapi if OpenGL is enabled
 746 if test "x$enable_opengl" = xyes; then
 747     CORE_DIRS="$CORE_DIRS mapi/glapi"
 748 fi
 749
 750 # build es1api if OpenGL ES 1.x is enabled
 751 if test "x$enable_gles1" = xyes; then
 752     CORE_DIRS="$CORE_DIRS mapi/es1api"
 753 fi
 754
 755 # build es2api if OpenGL ES 2.x is enabled
 756 if test "x$enable_gles2" = xyes; then
 757     CORE_DIRS="$CORE_DIRS mapi/es2api"
 758 fi
 759
 760 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 761 case "x$enable_opengl$enable_gles1$enable_gles2" in
 762 x*yes*)
 763     CORE_DIRS="mapi/glapi/gen $CORE_DIRS gtest glsl mesa"
 764     ;;
 765 esac
 766
 767 case "x$enable_glx$enable_xlib_glx" in
 768 xyesyes)
 769     DRIVER_DIRS="$DRIVER_DIRS x11"
 770     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 771     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 772     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 773     HAVE_WINSYS_XLIB="yes"
 774     ;;
 775 xyesno)
 776     # DRI-based GLX
 777     SRC_DIRS="$SRC_DIRS glx"
 778     ;;
 779 esac
 780
 781 if test "x$enable_dri" = xyes; then
 782     DRIVER_DIRS="$DRIVER_DIRS dri"
 783
 784     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 785     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 786     HAVE_ST_DRI="yes"
 787 fi
 788
 789 if test "x$enable_osmesa" = xyes; then
 790     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 791 fi
 792
 793 AC_SUBST([SRC_DIRS])
 794 AC_SUBST([DRIVER_DIRS])
 795 AC_SUBST([GALLIUM_DIRS])
 796 AC_SUBST([GALLIUM_TARGET_DIRS])
 797 AC_SUBST([GALLIUM_WINSYS_DIRS])
 798 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 799 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 800 AC_SUBST([MESA_LLVM])
 801
 802 # Check for libdrm
 803 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 804                   [have_libdrm=yes], [have_libdrm=no])
 805
 806 if test "x$enable_dri" = xyes; then
 807     # DRI must be shared, I think
 808     if test "$enable_static" = yes; then
 809         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 810     fi
 811
 812     # not a hard requirement as swrast does not depend on it
 813     if test "x$have_libdrm" = xyes; then
 814         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 815     fi
 816 fi
 817
 818 dnl Find out if X is available.
 819 PKG_CHECK_MODULES([X11], [x11], [no_x=no], [no_x=yes])
 820
 821 dnl Try to tell the user that the --x-* options are only used when
 822 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 823 m4_divert_once([HELP_BEGIN],
 824 [These options are only used when the X libraries cannot be found by the
 825 pkg-config utility.])
 826
 827 dnl We need X for xlib and dri, so bomb now if it's not found
 828 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 829     AC_MSG_ERROR([X11 development libraries needed for GLX])
 830 fi
 831
 832 dnl Direct rendering or just indirect rendering
 833 case "$host_os" in
 834 gnu*)
 835     dnl Disable by default on GNU/Hurd
 836     driglx_direct_default="no"
 837     ;;
 838 cygwin*)
 839     dnl Disable by default on cygwin
 840     driglx_direct_default="no"
 841     ;;
 842 *)
 843     driglx_direct_default="yes"
 844     ;;
 845 esac
 846 AC_ARG_ENABLE([driglx-direct],
 847     [AS_HELP_STRING([--disable-driglx-direct],
 848         [disable direct rendering in GLX and EGL for DRI \
 849             @<:@default=auto@:>@])],
 850     [driglx_direct="$enableval"],
 851     [driglx_direct="$driglx_direct_default"])
 852
 853 dnl
 854 dnl libGL configuration per driver
 855 dnl
 856 case "x$enable_glx$enable_xlib_glx" in
 857 xyesyes)
 858     # Xlib-based GLX
 859     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 860     GL_PC_REQ_PRIV="x11 xext"
 861     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 862     GL_LIB_DEPS="$XLIBGL_LIBS"
 863     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 864     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
 865     ;;
 866 xyesno)
 867     # DRI-based GLX
 868     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 869     if test x"$driglx_direct" = xyes; then
 870         if test "x$have_libdrm" != xyes; then
 871             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 872         fi
 873         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 874         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
 875     fi
 876
 877     # find the DRI deps for libGL
 878     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1 xcb-dri2 >= 1.8"
 879
 880     # add xf86vidmode if available
 881     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 882     if test "$HAVE_XF86VIDMODE" = yes ; then
 883         dri_modules="$dri_modules xxf86vm"
 884     fi
 885
 886     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 887     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 888     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 889     GL_LIB_DEPS="$DRIGL_LIBS"
 890
 891     # need DRM libs, $PTHREAD_LIBS, etc.
 892     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 893     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 894     ;;
 895 esac
 896
 897 # This is outside the case (above) so that it is invoked even for non-GLX
 898 # builds.
 899 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 900
 901 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 902 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 903 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
 904 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
 905
 906 AC_SUBST([X11_INCLUDES])
 907 AC_SUBST([GL_LIB_DEPS])
 908 AC_SUBST([GL_PC_REQ_PRIV])
 909 AC_SUBST([GL_PC_LIB_PRIV])
 910 AC_SUBST([GL_PC_CFLAGS])
 911 AC_SUBST([DRI_PC_REQ_PRIV])
 912 AC_SUBST([GLESv1_CM_LIB_DEPS])
 913 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 914 AC_SUBST([GLESv2_LIB_DEPS])
 915 AC_SUBST([GLESv2_PC_LIB_PRIV])
 916
 917 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 918
 919 AC_SUBST([HAVE_XF86VIDMODE])
 920
 921 dnl
 922 dnl More GLX setup
 923 dnl
 924 case "x$enable_glx$enable_xlib_glx" in
 925 xyesyes)
 926     DEFINES="$DEFINES -DUSE_XSHM"
 927     ;;
 928 xyesno)
 929     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 930     if test "x$driglx_direct" = xyes; then
 931         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 932     fi
 933     ;;
 934 esac
 935
 936 dnl
 937 dnl TLS detection
 938 dnl
 939
 940 AC_ARG_ENABLE([glx-tls],
 941     [AS_HELP_STRING([--enable-glx-tls],
 942         [enable TLS support in GLX @<:@default=disabled@:>@])],
 943     [GLX_USE_TLS="$enableval"],
 944     [GLX_USE_TLS=no])
 945 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 946
 947 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
 948       [DEFINES="${DEFINES} -DGLX_USE_TLS -DHAVE_PTHREAD"])
 949
 950 dnl
 951 dnl More DRI setup
 952 dnl
 953 dnl Directory for DRI drivers
 954 AC_ARG_WITH([dri-driverdir],
 955     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 956         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 957     [DRI_DRIVER_INSTALL_DIR="$withval"],
 958     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 959 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 960 dnl Extra search path for DRI drivers
 961 AC_ARG_WITH([dri-searchpath],
 962     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 963         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 964     [DRI_DRIVER_SEARCH_DIR="$withval"],
 965     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 966 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 967 dnl Which drivers to build - default is chosen by platform
 968 AC_ARG_WITH([dri-drivers],
 969     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 970         [comma delimited DRI drivers list, e.g.
 971         "swrast,i965,radeon" @<:@default=auto@:>@])],
 972     [with_dri_drivers="$withval"],
 973     [with_dri_drivers=yes])
 974 if test "x$with_dri_drivers" = x; then
 975     with_dri_drivers=no
 976 fi
 977
 978 dnl If $with_dri_drivers is yes, directories will be added through
 979 dnl platform checks
 980 DRI_DIRS=""
 981 case "$with_dri_drivers" in
 982 no) ;;
 983 yes)
 984     # classic DRI drivers require FEATURE_GL to build
 985     if test "x$enable_opengl" = xyes; then
 986         DRI_DIRS="yes"
 987     fi
 988     ;;
 989 *)
 990     # verify the requested driver directories exist
 991     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 992     for driver in $dri_drivers; do
 993         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 994             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
 995     done
 996     DRI_DIRS="$dri_drivers"
 997     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
 998         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
 999     fi
1000     ;;
1001 esac
1002
1003 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1004 if test "x$enable_dri" = xyes; then
1005     # Platform specific settings and drivers to build
1006     case "$host_os" in
1007     linux*)
1008         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1009         DEFINES="$DEFINES -DHAVE_ALIAS"
1010
1011         case "$host_cpu" in
1012         x86_64)
1013             if test "x$DRI_DIRS" = "xyes"; then
1014                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1015             fi
1016             ;;
1017         powerpc*)
1018             # Build only the drivers for cards that exist on PowerPC.
1019             if test "x$DRI_DIRS" = "xyes"; then
1020                 DRI_DIRS="r200 radeon swrast"
1021             fi
1022             ;;
1023         sparc*)
1024             # Build only the drivers for cards that exist on sparc
1025             if test "x$DRI_DIRS" = "xyes"; then
1026                 DRI_DIRS="r200 radeon swrast"
1027             fi
1028             ;;
1029         esac
1030         ;;
1031     freebsd* | dragonfly* | *netbsd*)
1032         DEFINES="$DEFINES -DHAVE_PTHREAD -DUSE_EXTERNAL_DXTN_LIB=1"
1033         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1034
1035         if test "x$DRI_DIRS" = "xyes"; then
1036             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1037         fi
1038         ;;
1039     gnu*)
1040         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1041         DEFINES="$DEFINES -DHAVE_ALIAS"
1042         ;;
1043     solaris*)
1044         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1045         ;;
1046     cygwin*)
1047         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1048         if test "x$DRI_DIRS" = "xyes"; then
1049             DRI_DIRS="swrast"
1050         fi
1051         ;;
1052     esac
1053
1054     # default drivers
1055     if test "x$DRI_DIRS" = "xyes"; then
1056         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1057     fi
1058
1059     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1060
1061     # Check for expat
1062     if test "x$enable_dri" = xyes; then
1063         EXPAT_INCLUDES=""
1064         EXPAT_LIB=-lexpat
1065         AC_ARG_WITH([expat],
1066             [AS_HELP_STRING([--with-expat=DIR],
1067                 [expat install directory])],[
1068             EXPAT_INCLUDES="-I$withval/include"
1069             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1070             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1071             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1072             ])
1073         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1074         save_LIBS="$LIBS"
1075         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1076             [AC_MSG_ERROR([Expat required for DRI.])])
1077         LIBS="$save_LIBS"
1078     fi
1079
1080     # if we are building any dri driver other than swrast or using the dri state tracker ...
1081     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast || test "x$enable_dri" = xyes; then
1082         # ... libdrm is required
1083         if test "x$have_libdrm" != xyes; then
1084             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1085         fi
1086         # ... and build dricommon
1087         HAVE_COMMON_DRI=yes
1088     fi
1089
1090     # put all the necessary libs together
1091     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1092     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1093 fi
1094 AM_CONDITIONAL(NEED_LIBDRICORE, test -n "$DRI_DIRS")
1095 AC_SUBST([DRI_DIRS])
1096 AC_SUBST([EXPAT_INCLUDES])
1097 AC_SUBST([DRI_LIB_DEPS])
1098 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1099
1100 case $DRI_DIRS in
1101 *i915*|*i965*)
1102     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1103
1104     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1105         case $d in
1106         i915)
1107             HAVE_I915_DRI=yes;
1108             ;;
1109         i965)
1110             HAVE_I965_DRI=yes;
1111             ;;
1112         esac
1113     done
1114
1115     ;;
1116 esac
1117
1118 case $DRI_DIRS in
1119 *nouveau*)
1120     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1121     HAVE_NOUVEAU_DRI=yes;
1122     ;;
1123 esac
1124
1125 case $DRI_DIRS in
1126 *radeon*|*r200*)
1127     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1128
1129     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1130         case $d in
1131         radeon)
1132             HAVE_RADEON_DRI=yes;
1133             ;;
1134         r200)
1135             HAVE_R200_DRI=yes;
1136             ;;
1137         esac
1138     done
1139
1140     ;;
1141 esac
1142
1143 case $DRI_DIRS in
1144 *swrast*)
1145     HAVE_SWRAST_DRI=yes;
1146     ;;
1147 esac
1148
1149 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1150 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1151 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1152 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1153 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1154 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1156
1157 dnl
1158 dnl OSMesa configuration
1159 dnl
1160
1161 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1162 AC_ARG_WITH([osmesa-bits],
1163     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1164         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1165     [osmesa_bits="$withval"],
1166     [osmesa_bits=8])
1167 if test "x$osmesa_bits" != x8; then
1168     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1169         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1170         osmesa_bits=8
1171     fi
1172 fi
1173 case "x$osmesa_bits" in
1174 x8)
1175     OSMESA_LIB="${OSMESA_LIB}"
1176     ;;
1177 x16|x32)
1178     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1179     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1180     ;;
1181 *)
1182     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1183     ;;
1184 esac
1185
1186 if test "x$enable_osmesa" = xyes; then
1187     # only link libraries with osmesa if shared
1188     if test "$enable_static" = no; then
1189         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1190     else
1191         OSMESA_LIB_DEPS=""
1192     fi
1193     OSMESA_MESA_DEPS=""
1194     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1195 fi
1196
1197 AC_SUBST([OSMESA_LIB_DEPS])
1198 AC_SUBST([OSMESA_MESA_DEPS])
1199 AC_SUBST([OSMESA_PC_REQ])
1200 AC_SUBST([OSMESA_PC_LIB_PRIV])
1201
1202 dnl
1203 dnl gbm configuration
1204 dnl
1205 if test "x$enable_gbm" = xauto; then
1206     case "$with_egl_platforms" in
1207         *drm*)
1208             enable_gbm=yes ;;
1209          *)
1210             enable_gbm=no ;;
1211     esac
1212 fi
1213 if test "x$enable_gbm" = xyes; then
1214     SRC_DIRS="$SRC_DIRS gbm"
1215
1216     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1217                       AC_MSG_ERROR([gbm needs udev]))
1218
1219     if test "x$enable_dri" = xyes; then
1220         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1221         if test "x$enable_shared_glapi" = xno; then
1222             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1223         fi
1224     fi
1225 fi
1226 GBM_PC_REQ_PRIV="libudev"
1227 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1228 AC_SUBST([GBM_PC_REQ_PRIV])
1229 AC_SUBST([GBM_PC_LIB_PRIV])
1230
1231 dnl
1232 dnl EGL configuration
1233 dnl
1234 EGL_CLIENT_APIS=""
1235
1236 if test "x$enable_egl" = xyes; then
1237     SRC_DIRS="$SRC_DIRS egl"
1238     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1239
1240     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1241
1242     if test "$enable_static" != yes; then
1243         # build egl_glx when libGL is built
1244         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1245                           [have_libudev=yes],[have_libudev=no])
1246         if test "$have_libudev" = yes; then
1247             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1248         fi
1249
1250         if test "x$enable_dri" = xyes; then
1251             HAVE_EGL_DRIVER_DRI2=1
1252         fi
1253
1254     fi
1255 fi
1256 AC_SUBST([EGL_LIB_DEPS])
1257
1258 dnl
1259 dnl EGL Gallium configuration
1260 dnl
1261 if test "x$enable_gallium_egl" = xyes; then
1262     if test "x$with_gallium_drivers" = x; then
1263         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1264     fi
1265     if test "x$enable_egl" = xno; then
1266         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1267     fi
1268     if test "x$have_libdrm" != xyes; then
1269         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1270     fi
1271
1272     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1273     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1274     HAVE_ST_EGL="yes"
1275 fi
1276
1277 dnl
1278 dnl gbm Gallium configuration
1279 dnl
1280 if test "x$enable_gallium_gbm" = xauto; then
1281     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1282         yesyesyes*drm*)
1283             enable_gallium_gbm=yes ;;
1284          *)
1285             enable_gallium_gbm=no ;;
1286     esac
1287 fi
1288 if test "x$enable_gallium_gbm" = xyes; then
1289     if test "x$with_gallium_drivers" = x; then
1290         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1291     fi
1292     if test "x$enable_gbm" = xno; then
1293         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1294     fi
1295     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1296     if test "x$enable_dri" = xno; then
1297         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1298     fi
1299
1300     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1301     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1302     HAVE_ST_GBM="yes"
1303     enable_gallium_loader=yes
1304 fi
1305
1306 dnl
1307 dnl X.Org DDX configuration
1308 dnl
1309 if test "x$enable_xorg" = xyes; then
1310     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1311     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1312     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1313     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1314         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1315         HAVE_XEXTPROTO_71="no")
1316     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1317     HAVE_ST_XORG=yes
1318 fi
1319
1320 dnl
1321 dnl XA configuration
1322 dnl
1323 if test "x$enable_xa" = xyes; then
1324 AC_PROG_AWK
1325 AC_PROG_GREP
1326 AC_CHECK_PROG(NM, nm, "nm")
1327 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1328 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1329 enable_xa=no
1330 fi
1331 fi
1332 if test "x$enable_xa" = xyes; then
1333     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1334     HAVE_ST_XA=yes
1335     AC_SUBST(AWK)
1336     AC_SUBST(GREP)
1337     AC_SUBST(NM)
1338 fi
1339
1340 dnl
1341 dnl OpenVG configuration
1342 dnl
1343 VG_LIB_DEPS=""
1344
1345 if test "x$enable_openvg" = xyes; then
1346     if test "x$enable_egl" = xno; then
1347         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1348     fi
1349     if test "x$with_gallium_drivers" = x; then
1350         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1351     fi
1352     if test "x$enable_gallium_egl" = xno; then
1353         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1354     fi
1355
1356     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1357     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS $PTHREAD_LIBS"
1358     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1359     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1360     HAVE_ST_VEGA=yes
1361     VG_PC_LIB_PRIV="-lm $CLOCK_LIB $PTHREAD_LIBS $DLOPEN_LIBS"
1362     AC_SUBST([VG_PC_LIB_PRIV])
1363 fi
1364 AM_CONDITIONAL(HAVE_OPENVG, test "x$enable_openvg" = xyes)
1365
1366 dnl
1367 dnl D3D1X configuration
1368 dnl
1369
1370 if test "x$enable_d3d1x" = xyes; then
1371     if test "x$with_gallium_drivers" = x; then
1372         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1373     fi
1374
1375     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1376     HAVE_ST_D3D1X=yes
1377 fi
1378
1379 dnl
1380 dnl Gallium G3DVL configuration
1381 dnl
1382 AC_ARG_ENABLE([gallium-g3dvl],
1383     [AS_HELP_STRING([--enable-gallium-g3dvl],
1384         [build gallium g3dvl @<:@default=disabled@:>@])],
1385     [enable_gallium_g3dvl="$enableval"],
1386     [enable_gallium_g3dvl=no])
1387 if test "x$enable_gallium_g3dvl" = xyes; then
1388     if test "x$with_gallium_drivers" = x; then
1389         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1390     fi
1391
1392     if test "x$enable_xvmc" = xauto; then
1393         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1394     fi
1395
1396     if test "x$enable_vdpau" = xauto; then
1397         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1398     fi
1399 fi
1400
1401 if test "x$enable_xvmc" = xyes; then
1402     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1403     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1404     HAVE_ST_XVMC="yes"
1405 fi
1406
1407 if test "x$enable_vdpau" = xyes; then
1408     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1409     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1410     HAVE_ST_VDPAU="yes"
1411 fi
1412
1413 dnl
1414 dnl OpenCL configuration
1415 dnl
1416
1417 AC_ARG_WITH([libclc-path],
1418    [AS_HELP_STRING([--with-libclc-path],
1419          [DEPRECATED: See http://dri.freedesktop.org/wiki/GalliumCompute#How_to_Install])],
1420    [LIBCLC_PATH="$withval"],
1421    [LIBCLC_PATH=""])
1422
1423 if test "x$LIBCLC_PATH" != x; then
1424    AC_MSG_ERROR([The --with-libclc-path option has been deprecated.
1425                   Please review the updated build instructions for clover:
1426                   http://dri.freedesktop.org/wiki/GalliumCompute])
1427 fi
1428
1429
1430 AC_ARG_WITH([clang-libdir],
1431    [AS_HELP_STRING([--with-clang-libdir],
1432          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1433    [CLANG_LIBDIR="$withval"],
1434    [CLANG_LIBDIR=""])
1435
1436 LIBCLC_INCLUDEDIR=`pkg-config --variable=includedir libclc`
1437 LIBCLC_LIBEXECDIR=`pkg-config --variable=libexecdir libclc`
1438 AC_SUBST([LIBCLC_INCLUDEDIR])
1439 AC_SUBST([LIBCLC_LIBEXECDIR])
1440
1441 if test "x$enable_opencl" = xyes; then
1442     if test "x$with_gallium_drivers" = x; then
1443         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1444     fi
1445
1446     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1447         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1448     fi
1449
1450     if test "x$LIBCLC_INCLUDEDIR" == x || test "x$LIBCLC_LIBEXECDIR" == x; then
1451         AC_MSG_ERROR([pkg-config cannot use libclc.pc which is required to build clover])
1452     fi
1453
1454     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1455     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1456     enable_gallium_loader=yes
1457 fi
1458
1459 if test "x$enable_gallium_gbm" = xyes || test "x$enable_opencl" = xyes; then
1460     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS pipe-loader"
1461 fi
1462
1463 dnl
1464 dnl Gallium configuration
1465 dnl
1466 if test "x$with_gallium_drivers" != x; then
1467     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1468 fi
1469 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1470
1471 AC_SUBST([LLVM_BINDIR])
1472 AC_SUBST([LLVM_CFLAGS])
1473 AC_SUBST([LLVM_CPPFLAGS])
1474 AC_SUBST([LLVM_CXXFLAGS])
1475 AC_SUBST([LLVM_LIBDIR])
1476 AC_SUBST([LLVM_LIBS])
1477 AC_SUBST([LLVM_LDFLAGS])
1478 AC_SUBST([LLVM_INCLUDEDIR])
1479 AC_SUBST([LLVM_VERSION])
1480 AC_SUBST([CLANG_RESOURCE_DIR])
1481
1482 case "x$enable_opengl$enable_gles1$enable_gles2" in
1483 x*yes*)
1484     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1485     HAVE_OPENGL=yes
1486     ;;
1487 esac
1488 AM_CONDITIONAL(HAVE_OPENGL, test "x$HAVE_OPENGL" = xyes)
1489
1490 AC_SUBST([VG_LIB_DEPS])
1491 AC_SUBST([EGL_CLIENT_APIS])
1492
1493 dnl
1494 dnl EGL Platforms configuration
1495 dnl
1496 AC_ARG_WITH([egl-platforms],
1497     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1498         [comma delimited native platforms libEGL supports, e.g.
1499         "x11,drm" @<:@default=auto@:>@])],
1500     [with_egl_platforms="$withval"],
1501     [if test "x$enable_egl" = xyes; then
1502         with_egl_platforms="x11"
1503     else
1504         with_egl_platforms=""
1505     fi])
1506
1507 EGL_PLATFORMS=""
1508
1509 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1510     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1511 fi
1512
1513 # Do per-EGL platform setups and checks
1514 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1515 for plat in $egl_platforms; do
1516         case "$plat" in
1517         fbdev|null)
1518                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1519                 ;;
1520
1521         wayland)
1522                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= 1.0.2 wayland-server >= 1.0.2])
1523                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1524
1525                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1526                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1527                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1528                 ;;
1529
1530         x11)
1531                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 >= 1.8 xcb-xfixes])
1532
1533                 if test "x$enable_glx" = xyes; then
1534                         HAVE_EGL_DRIVER_GLX=1
1535                 fi
1536                 ;;
1537
1538         drm)
1539                 test "x$enable_gbm" = "xno" &&
1540                         AC_MSG_ERROR([EGL platform drm needs gbm])
1541                 ;;
1542
1543         android|gdi)
1544                 ;;
1545
1546         *)
1547                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1548                 ;;
1549         esac
1550
1551         case "$plat$have_libudev" in
1552                 waylandno|drmno)
1553                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1554         esac
1555 done
1556
1557 # libEGL wants to default to the first platform specified in
1558 # ./configure.  parse that here.
1559 if test "x$egl_platforms" != "x"; then
1560     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1561     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1562 else
1563     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1564 fi
1565
1566 EGL_PLATFORMS="$egl_platforms"
1567
1568 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1569 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1570 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1571 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1572 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1573
1574 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1575 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1576
1577 AC_SUBST([EGL_NATIVE_PLATFORM])
1578 AC_SUBST([EGL_PLATFORMS])
1579 AC_SUBST([EGL_CFLAGS])
1580
1581 AC_ARG_WITH([egl-driver-dir],
1582     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1583                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1584     [EGL_DRIVER_INSTALL_DIR="$withval"],
1585     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1586 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1587
1588 AC_ARG_WITH([xorg-driver-dir],
1589     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1590                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1591     [XORG_DRIVER_INSTALL_DIR="$withval"],
1592     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1593 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1594
1595 AC_ARG_WITH([max-width],
1596     [AS_HELP_STRING([--with-max-width=N],
1597                     [Maximum framebuffer width (4096)])],
1598     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1599      AS_IF([test "${withval}" -gt "4096"],
1600            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1601 )
1602 AC_ARG_WITH([max-height],
1603     [AS_HELP_STRING([--with-max-height=N],
1604                     [Maximum framebuffer height (4096)])],
1605     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1606      AS_IF([test "${withval}" -gt "4096"],
1607            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1608 )
1609
1610 dnl
1611 dnl Gallium LLVM
1612 dnl
1613 AC_ARG_ENABLE([gallium-llvm],
1614     [AS_HELP_STRING([--enable-gallium-llvm],
1615         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1616     [enable_gallium_llvm="$enableval"],
1617     [enable_gallium_llvm=auto])
1618
1619 AC_ARG_WITH([llvm-shared-libs],
1620     [AS_HELP_STRING([--with-llvm-shared-libs],
1621         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1622     [with_llvm_shared_libs=yes],
1623     [with_llvm_shared_libs=no])
1624
1625 AC_ARG_WITH([llvm-prefix],
1626     [AS_HELP_STRING([--with-llvm-prefix],
1627         [Prefix for LLVM installations in non-standard locations])],
1628     [llvm_prefix="$withval"],
1629     [llvm_prefix=""])
1630
1631
1632 # Call this inside ` ` to get the return value.
1633 # $1 is the llvm-config command with arguments.
1634 strip_unwanted_llvm_flags() {
1635     # Use \> (marks the end of the word)
1636     echo `$1` | sed \
1637         -e 's/-DNDEBUG\>//g' \
1638         -e 's/-pedantic\>//g' \
1639         -e 's/-Wcovered-switch-default\>//g' \
1640         -e 's/-O.\>//g' \
1641         -e 's/-g\>//g' \
1642         -e 's/-Wall\>//g' \
1643         -e 's/-fomit-frame-pointer\>//g'
1644 }
1645
1646
1647 if test "x$with_gallium_drivers" = x; then
1648     enable_gallium_llvm=no
1649 fi
1650 if test "x$enable_gallium_llvm" = xauto; then
1651     case "$host_cpu" in
1652     i*86|x86_64) enable_gallium_llvm=yes;;
1653     esac
1654 fi
1655 if test "x$enable_gallium_llvm" = xyes; then
1656     if test "x$llvm_prefix" != x; then
1657         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1658     else
1659         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1660     fi
1661
1662     if test "x$LLVM_CONFIG" != xno; then
1663         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1664         LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
1665         if test "x$with_llvm_shared_libs" != xyes; then
1666             LLVM_COMPONENTS="engine bitwriter"
1667             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1668                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1669             fi
1670
1671             if test "x$enable_opencl" = xyes; then
1672                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1673             fi
1674         fi
1675         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1676         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1677         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
1678         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
1679         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
1680         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1681         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1682         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT"
1683         MESA_LLVM=1
1684
1685         dnl Check for Clang interanl headers
1686         if test "x$enable_opencl" = xyes; then
1687             if test "x$CLANG_LIBDIR" = x; then
1688                 CLANG_LIBDIR=${LLVM_LIBDIR}
1689             fi
1690             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1691             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1692                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1693         fi
1694     else
1695         MESA_LLVM=0
1696         LLVM_VERSION_INT=0
1697     fi
1698 else
1699     MESA_LLVM=0
1700     LLVM_VERSION_INT=0
1701 fi
1702
1703 dnl Directory for XVMC libs
1704 AC_ARG_WITH([xvmc-libdir],
1705     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1706         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1707     [XVMC_LIB_INSTALL_DIR="$withval"],
1708     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1709 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1710
1711 dnl
1712 dnl Gallium Tests
1713 dnl
1714 if test "x$enable_gallium_tests" = xyes; then
1715     SRC_DIRS="$SRC_DIRS gallium/tests/trivial gallium/tests/unit"
1716     enable_gallium_loader=yes
1717 fi
1718
1719 dnl Directory for VDPAU libs
1720 AC_ARG_WITH([vdpau-libdir],
1721     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1722         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1723     [VDPAU_LIB_INSTALL_DIR="$withval"],
1724     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1725 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1726
1727 dnl Directory for OpenCL libs
1728 AC_ARG_WITH([opencl-libdir],
1729     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1730         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1731     [OPENCL_LIB_INSTALL_DIR="$withval"],
1732     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1733 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1734
1735 dnl
1736 dnl Gallium helper functions
1737 dnl
1738 gallium_check_st() {
1739     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1740          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1741          test "x$HAVE_ST_VDPAU" = xyes; then
1742          if test "x$have_libdrm" != xyes; then
1743             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1744          fi
1745          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1746     fi
1747     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1748          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1749     fi
1750     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1751          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1752     fi
1753     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1754          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1755     fi
1756     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1757          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1758     fi
1759     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1760          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1761     fi
1762 }
1763
1764 gallium_require_llvm() {
1765     if test "x$MESA_LLVM" = x0; then
1766         case "$host_cpu" in
1767         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1768         esac
1769     fi
1770 }
1771
1772 gallium_require_drm_loader() {
1773     if test "x$enable_gallium_loader" = xyes; then
1774         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1775                           AC_MSG_ERROR([Gallium drm loader requires libudev]))
1776         if test "x$have_libdrm" != xyes; then
1777             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1778         fi
1779         enable_gallium_drm_loader=yes
1780     fi
1781 }
1782
1783 radeon_llvm_check() {
1784     LLVM_REQUIRED_VERSION_MAJOR="3"
1785     LLVM_REQUIRED_VERSION_MINOR="2"
1786     if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
1787         AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer with R600 target enabled is required.
1788                      To use the r600/radeonsi LLVM backend, you need to fetch the LLVM source from:
1789                      git://people.freedesktop.org/~tstellar/llvm master
1790                      and build with --enable-experimental-targets=R600])
1791     fi
1792     if test true && $LLVM_CONFIG --targets-built | grep -qv '\<R600\>' ; then
1793         AC_MSG_ERROR([LLVM R600 Target not enabled.  You can enable it when building the LLVM
1794                       sources with the --enable-experimental-targets=R600
1795                       configure flag])
1796     fi
1797     AC_MSG_WARN([Please ensure you use the latest llvm tree from git://people.freedesktop.org/~tstellar/llvm master before submitting a bug])
1798     LLVM_COMPONENTS="${LLVM_COMPONENTS} r600"
1799 }
1800
1801 dnl Gallium drivers
1802 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1803 if test "x$with_gallium_drivers" != x; then
1804     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1805     for driver in $gallium_drivers; do
1806         case "x$driver" in
1807         xsvga)
1808             HAVE_GALLIUM_SVGA=yes
1809             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1810             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1811             ;;
1812         xi915)
1813             HAVE_GALLIUM_I915=yes
1814             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1815             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1816             if test "x$MESA_LLVM" = x1; then
1817                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1818             fi
1819             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1820             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1821             ;;
1822         xr300)
1823             HAVE_GALLIUM_R300=yes
1824             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1825             gallium_require_llvm "Gallium R300"
1826             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1827             gallium_check_st "radeon/drm" "dri-r300" "" "" "xvmc-r300" "vdpau-r300"
1828             ;;
1829         xr600)
1830             HAVE_GALLIUM_R600=yes
1831             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1832             gallium_require_drm_loader
1833             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1834             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1835                 radeon_llvm_check
1836                 NEED_RADEON_GALLIUM=yes;
1837                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo"
1838             fi
1839             if test "x$enable_r600_llvm" = xyes; then
1840                 USE_R600_LLVM_COMPILER=yes;
1841             fi
1842             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1843                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
1844             fi
1845             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600"
1846             ;;
1847         xradeonsi)
1848             HAVE_GALLIUM_RADEONSI=yes
1849             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1850             gallium_require_drm_loader
1851             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1852             radeon_llvm_check
1853             NEED_RADEON_GALLIUM=yes;
1854             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1855             ;;
1856         xnouveau)
1857             HAVE_GALLIUM_NOUVEAU=yes
1858             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1859             gallium_require_drm_loader
1860             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1861             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1862             ;;
1863         xswrast)
1864             HAVE_GALLIUM_SOFTPIPE=yes
1865             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1866             if test "x$MESA_LLVM" = x1; then
1867                 HAVE_GALLIUM_LLVMPIPE=yes
1868                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1869             fi
1870
1871             if test "x$HAVE_ST_DRI" = xyes; then
1872                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1873             fi
1874             if test "x$HAVE_ST_VDPAU" = xyes; then
1875                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1876             fi
1877             if test "x$HAVE_ST_XVMC" = xyes; then
1878                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1879             fi
1880             if test "x$HAVE_ST_VDPAU" = xyes ||
1881                test "x$HAVE_ST_XVMC" = xyes; then
1882                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1883                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1884                fi
1885             fi
1886             ;;
1887         *)
1888             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1889             ;;
1890         esac
1891     done
1892 fi
1893
1894 dnl Set LLVM_LIBS - This is done after the driver configuration so
1895 dnl that drivers can add additonal components to LLVM_COMPONENTS.
1896 dnl Previously, gallium drivers were updating LLVM_LIBS directly
1897 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
1898 dnl this was causing the same libraries to be appear multiple times
1899 dnl in LLVM_LIBS.
1900
1901 LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1902
1903 if test "x$with_llvm_shared_libs" = xyes; then
1904     dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1905     LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
1906     AC_CHECK_FILE("$LLVM_LIBDIR/lib$LLVM_SO_NAME.so", llvm_have_one_so=yes,)
1907
1908     if test "x$llvm_have_one_so" = xyes; then
1909         dnl LLVM was built using auto*, so there is only one shared object.
1910         LLVM_LIBS="-l$LLVM_SO_NAME"
1911     else
1912         dnl If LLVM was built with CMake, there will be one shared object per
1913         dnl component.
1914         AC_CHECK_FILE("$LLVM_LIBDIR/libLLVMTarget.so",,
1915                 AC_MSG_ERROR([Could not find llvm shared libraries:
1916         Please make sure you have built llvm with the --enable-shared option
1917         and that your llvm libraries are installed in $LLVM_LIBDIR
1918         If you have installed your llvm libraries to a different directory you
1919         can use the --with-llvm-prefix= configure flag to specify this directory.
1920         NOTE: Mesa is attempting to use llvm shared libraries because you have
1921         passed one of the following options to configure:
1922                 --with-llvm-shared-libs
1923                 --enable-opencl
1924         If you do not want to build with llvm shared libraries and instead want to
1925         use llvm static libraries then remove these options from your configure
1926         invocation and reconfigure.]))
1927
1928        dnl We don't need to update LLVM_LIBS in this case because the LLVM
1929        dnl install uses a shared object for each compoenent and we have
1930        dnl already added all of these objects to LLVM_LIBS.
1931     fi
1932 fi
1933
1934 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
1935 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
1936 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
1937 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
1938 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
1939 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
1940 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
1941 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
1942
1943 if test "x$enable_gallium_loader" = xyes; then
1944     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1945     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1946     GALLIUM_PIPE_LOADER_LIBS="\$(top_builddir)/src/gallium/auxiliary/pipe-loader/libpipe_loader.la"
1947     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/null/libws_null.la"
1948
1949     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1950         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1951         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(top_builddir)/src/gallium/winsys/sw/xlib/libws_xlib.la"
1952     fi
1953
1954     if test "x$enable_gallium_drm_loader" = xyes; then
1955         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1956         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1957                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1958         if test "x$pipe_loader_have_xcb" = xyes; then
1959             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1960             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1961         fi
1962     fi
1963
1964     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1965     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1966 fi
1967
1968 dnl Tell Automake which drivers to build
1969 for driver in $GALLIUM_DRIVERS_DIRS; do
1970     case "x$driver" in
1971         xgalahad)
1972             HAVE_GALAHAD_GALLIUM=yes;
1973             ;;
1974         xidentity)
1975             HAVE_IDENTITY_GALLIUM=yes;
1976             ;;
1977         xnoop)
1978             HAVE_NOOP_GALLIUM=yes;
1979             ;;
1980         *)
1981             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1982             ;;
1983     esac
1984 done
1985
1986 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1987 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1988 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1989 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1990 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1991 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1992 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1993 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1994 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
1995 AM_CONDITIONAL(LLVM_NEEDS_FNORTTI, test $LLVM_VERSION_INT -ge 302)
1996
1997 AC_SUBST([GALLIUM_MAKE_DIRS])
1998
1999 AM_CONDITIONAL(NEED_LIBPROGRAM, test "x$with_gallium_drivers" != x -o \
2000                                      "x$enable_xlib_glx" = xyes -o \
2001                                      "x$enable_osmesa" = xyes)
2002 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2003
2004 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2005 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2006 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2007
2008 AM_CONDITIONAL(CROSS_COMPILING, test "x$cross_compiling" = xyes)
2009
2010 AC_SUBST([VDPAU_MAJOR], 1)
2011 AC_SUBST([VDPAU_MINOR], 0)
2012
2013 AC_SUBST([XVMC_MAJOR], 1)
2014 AC_SUBST([XVMC_MINOR], 0)
2015
2016 AC_SUBST([XA_MAJOR], 1)
2017 AC_SUBST([XA_MINOR], 0)
2018 AC_SUBST([XA_TINY], 0)
2019 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2020
2021 dnl prepend CORE_DIRS to SRC_DIRS
2022 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2023
2024 dnl Restore LDFLAGS and CPPFLAGS
2025 LDFLAGS="$_SAVE_LDFLAGS"
2026 CPPFLAGS="$_SAVE_CPPFLAGS"
2027
2028 dnl Add user CFLAGS and CXXFLAGS
2029 CFLAGS="$CFLAGS $USER_CFLAGS"
2030 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2031
2032 dnl Substitute the config
2033 AC_CONFIG_FILES([Makefile
2034                 src/Makefile
2035                 src/egl/Makefile
2036                 src/egl/drivers/Makefile
2037                 src/egl/drivers/dri2/Makefile
2038                 src/egl/drivers/glx/Makefile
2039                 src/egl/main/Makefile
2040                 src/egl/main/egl.pc
2041                 src/egl/wayland/Makefile
2042                 src/egl/wayland/wayland-drm/Makefile
2043                 src/egl/wayland/wayland-egl/Makefile
2044                 src/egl/wayland/wayland-egl/wayland-egl.pc
2045                 src/gallium/Makefile
2046                 src/gallium/auxiliary/Makefile
2047                 src/gallium/auxiliary/pipe-loader/Makefile
2048                 src/gallium/drivers/Makefile
2049                 src/gallium/drivers/i915/Makefile
2050                 src/gallium/drivers/llvmpipe/Makefile
2051                 src/gallium/drivers/nouveau/Makefile
2052                 src/gallium/drivers/nv30/Makefile
2053                 src/gallium/drivers/nv50/Makefile
2054                 src/gallium/drivers/nvc0/Makefile
2055                 src/gallium/drivers/r300/Makefile
2056                 src/gallium/drivers/r600/Makefile
2057                 src/gallium/drivers/radeon/Makefile
2058                 src/gallium/drivers/radeonsi/Makefile
2059                 src/gallium/drivers/rbug/Makefile
2060                 src/gallium/drivers/softpipe/Makefile
2061                 src/gallium/drivers/svga/Makefile
2062                 src/gallium/drivers/trace/Makefile
2063                 src/gallium/state_trackers/Makefile
2064                 src/gallium/state_trackers/clover/Makefile
2065                 src/gallium/state_trackers/dri/Makefile
2066                 src/gallium/state_trackers/dri/drm/Makefile
2067                 src/gallium/state_trackers/dri/sw/Makefile
2068                 src/gallium/state_trackers/egl/Makefile
2069                 src/gallium/state_trackers/gbm/Makefile
2070                 src/gallium/state_trackers/glx/Makefile
2071                 src/gallium/state_trackers/vdpau/Makefile
2072                 src/gallium/state_trackers/vega/Makefile
2073                 src/gallium/state_trackers/xa/Makefile
2074                 src/gallium/state_trackers/xorg/Makefile
2075                 src/gallium/state_trackers/xvmc/Makefile
2076                 src/gallium/targets/Makefile
2077                 src/gallium/targets/dri-i915/Makefile
2078                 src/gallium/targets/dri-nouveau/Makefile
2079                 src/gallium/targets/dri-r300/Makefile
2080                 src/gallium/targets/dri-r600/Makefile
2081                 src/gallium/targets/dri-radeonsi/Makefile
2082                 src/gallium/targets/dri-swrast/Makefile
2083                 src/gallium/targets/dri-vmwgfx/Makefile
2084                 src/gallium/targets/egl-static/Makefile
2085                 src/gallium/targets/gbm/Makefile
2086                 src/gallium/targets/opencl/Makefile
2087                 src/gallium/targets/pipe-loader/Makefile
2088                 src/gallium/targets/libgl-xlib/Makefile
2089                 src/gallium/targets/vdpau-nouveau/Makefile
2090                 src/gallium/targets/vdpau-r300/Makefile
2091                 src/gallium/targets/vdpau-r600/Makefile
2092                 src/gallium/targets/vdpau-radeonsi/Makefile
2093                 src/gallium/targets/vdpau-softpipe/Makefile
2094                 src/gallium/targets/xa-vmwgfx/Makefile
2095                 src/gallium/targets/xa-vmwgfx/xatracker.pc
2096                 src/gallium/targets/xorg-i915/Makefile
2097                 src/gallium/targets/xorg-nouveau/Makefile
2098                 src/gallium/targets/xorg-r600/Makefile
2099                 src/gallium/targets/xorg-radeonsi/Makefile
2100                 src/gallium/targets/xvmc-nouveau/Makefile
2101                 src/gallium/targets/xvmc-r300/Makefile
2102                 src/gallium/targets/xvmc-r600/Makefile
2103                 src/gallium/targets/xvmc-softpipe/Makefile
2104                 src/gallium/tests/trivial/Makefile
2105                 src/gallium/tests/unit/Makefile
2106                 src/gallium/winsys/Makefile
2107                 src/gallium/winsys/i915/drm/Makefile
2108                 src/gallium/winsys/i915/sw/Makefile
2109                 src/gallium/winsys/nouveau/drm/Makefile
2110                 src/gallium/winsys/radeon/drm/Makefile
2111                 src/gallium/winsys/svga/drm/Makefile
2112                 src/gallium/winsys/sw/Makefile
2113                 src/gallium/winsys/sw/dri/Makefile
2114                 src/gallium/winsys/sw/fbdev/Makefile
2115                 src/gallium/winsys/sw/null/Makefile
2116                 src/gallium/winsys/sw/wayland/Makefile
2117                 src/gallium/winsys/sw/wrapper/Makefile
2118                 src/gallium/winsys/sw/xlib/Makefile
2119                 src/gbm/Makefile
2120                 src/gbm/main/gbm.pc
2121                 src/glsl/Makefile
2122                 src/glsl/builtin_compiler/Makefile
2123                 src/glx/Makefile
2124                 src/glx/tests/Makefile
2125                 src/gtest/Makefile
2126                 src/mapi/es1api/Makefile
2127                 src/mapi/es1api/glesv1_cm.pc
2128                 src/mapi/es2api/Makefile
2129                 src/mapi/es2api/glesv2.pc
2130                 src/mapi/glapi/Makefile
2131                 src/mapi/glapi/gen/Makefile
2132                 src/mapi/glapi/tests/Makefile
2133                 src/mapi/shared-glapi/Makefile
2134                 src/mapi/shared-glapi/tests/Makefile
2135                 src/mapi/vgapi/Makefile
2136                 src/mapi/vgapi/vg.pc
2137                 src/mesa/Makefile
2138                 src/mesa/gl.pc
2139                 src/mesa/drivers/Makefile
2140                 src/mesa/drivers/dri/dri.pc
2141                 src/mesa/drivers/dri/common/Makefile
2142                 src/mesa/drivers/dri/common/xmlpool/Makefile
2143                 src/mesa/drivers/dri/i915/Makefile
2144                 src/mesa/drivers/dri/i965/Makefile
2145                 src/mesa/drivers/dri/Makefile
2146                 src/mesa/drivers/dri/nouveau/Makefile
2147                 src/mesa/drivers/dri/r200/Makefile
2148                 src/mesa/drivers/dri/radeon/Makefile
2149                 src/mesa/drivers/dri/swrast/Makefile
2150                 src/mesa/drivers/osmesa/Makefile
2151                 src/mesa/drivers/osmesa/osmesa.pc
2152                 src/mesa/drivers/x11/Makefile
2153                 src/mesa/libdricore/Makefile
2154                 src/mesa/main/tests/Makefile
2155                 src/mesa/main/tests/hash_table/Makefile
2156                 src/mesa/program/Makefile
2157                 src/mesa/x86-64/Makefile
2158                 src/mesa/x86/Makefile])
2159
2160 dnl Sort the dirs alphabetically
2161 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2162 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2163 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2164 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2165 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2166
2167 AC_OUTPUT
2168
2169 dnl
2170 dnl Output some configuration info for the user
2171 dnl
2172 echo ""
2173 echo "        prefix:          $prefix"
2174 echo "        exec_prefix:     $exec_prefix"
2175 echo "        libdir:          $libdir"
2176 echo "        includedir:      $includedir"
2177
2178 dnl API info
2179 echo ""
2180 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2181 echo "        OpenVG:          $enable_openvg"
2182
2183 dnl Driver info
2184 echo ""
2185 if test "x$enable_osmesa" != xno; then
2186         echo "        OSMesa:          lib$OSMESA_LIB"
2187 else
2188         echo "        OSMesa:          no"
2189 fi
2190
2191 if test "x$enable_dri" != xno; then
2192         # cleanup the drivers var
2193         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2194         if test "x$DRI_DIRS" = x; then
2195             echo "        DRI drivers:     no"
2196         else
2197             echo "        DRI drivers:     $dri_dirs"
2198         fi
2199         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2200 fi
2201
2202 case "x$enable_glx$enable_xlib_glx" in
2203 xyesyes)
2204     echo "        GLX:             Xlib-based"
2205     ;;
2206 xyesno)
2207     echo "        GLX:             DRI-based"
2208     ;;
2209 *)
2210     echo "        GLX:             $enable_glx"
2211     ;;
2212 esac
2213
2214 dnl EGL
2215 echo ""
2216 echo "        EGL:             $enable_egl"
2217 if test "$enable_egl" = yes; then
2218     echo "        EGL platforms:   $EGL_PLATFORMS"
2219
2220     egl_drivers=""
2221     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2222         egl_drivers="$egl_drivers builtin:egl_glx"
2223     fi
2224     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2225         egl_drivers="$egl_drivers builtin:egl_dri2"
2226     fi
2227
2228     if test "x$HAVE_ST_EGL" = xyes; then
2229         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2230         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2231     else
2232         echo "        EGL drivers:    $egl_drivers"
2233     fi
2234 fi
2235
2236 echo ""
2237 if test "x$MESA_LLVM" = x1; then
2238     echo "        llvm:            yes"
2239     echo "        llvm-config:     $LLVM_CONFIG"
2240     echo "        llvm-version:    $LLVM_VERSION"
2241 else
2242     echo "        llvm:            no"
2243 fi
2244
2245 echo ""
2246 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2247     echo "        Gallium:         yes"
2248     echo "        Gallium dirs:    $GALLIUM_DIRS"
2249     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2250     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2251     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2252     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2253 else
2254     echo "        Gallium:         no"
2255 fi
2256
2257
2258 dnl Libraries
2259 echo ""
2260 echo "        Shared libs:     $enable_shared"
2261 echo "        Static libs:     $enable_static"
2262 echo "        Shared-glapi:    $enable_shared_glapi"
2263
2264 dnl Compiler options
2265 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2266 cflags=`echo $CFLAGS | \
2267     $SED 's/^ *//;s/  */ /;s/ *$//'`
2268 cxxflags=`echo $CXXFLAGS | \
2269     $SED 's/^ *//;s/  */ /;s/ *$//'`
2270 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2271 echo ""
2272 echo "        CFLAGS:          $cflags"
2273 echo "        CXXFLAGS:        $cxxflags"
2274 echo "        Macros:          $defines"
2275 echo ""
2276 if test "x$MESA_LLVM" = x1; then
2277     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2278     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2279     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2280     echo ""
2281 fi
2282 echo "        PYTHON2:         $PYTHON2"
2283
2284 echo ""
2285 echo "        Run '${MAKE-make}' to build Mesa"
2286 echo ""