configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT([LHa for UNIX], 1.14i-ac20020729, jca02266@nifty.ne.jp, lha)
   3 AC_CANONICAL_TARGET
   4 AM_INIT_AUTOMAKE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
   8                    [the type of system on which the package will run.])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_GCC_TRADITIONAL
  13 AC_PROG_INSTALL
  14 AC_PROG_MAKE_SET
  15 AC_MINIX
  16 AM_C_PROTOTYPES
  17
  18 # Checks for libraries.
  19 AC_SEARCH_LIBS(opendir, [mingwex])
  20
  21 # Checks for header files.
  22 AC_HEADER_DIRENT
  23 AC_HEADER_STDC
  24 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
  25 AC_CHECK_HEADERS(pwd.h grp.h utime.h)
  26
  27 # Checks for typedefs, structures, and compiler characteristics.
  28 AC_C_CONST
  29 AC_HEADER_TIME
  30 AC_STRUCT_TM
  31 AC_STRUCT_TIMEZONE
  32
  33 AC_CHECK_TYPES([uid_t, gid_t])
  34 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct stat.st_ino],,,
  35 [
  36 #if HAVE_SYS_TYPES_H
  37 # include <sys/types.h>
  38 #endif
  39 #if HAVE_SYS_STAT_H
  40 # include <sys/stat.h>
  41 #endif
  42 #if TIME_WITH_SYS_TIME
  43 # include <sys/time.h>
  44 # include <time.h>
  45 #else
  46 # if HAVE_SYS_TIME_H
  47 #  include <sys/time.h>
  48 # else
  49 #  include <time.h>
  50 # endif
  51 #endif
  52 ])
  53
  54 # Checks for library functions.
  55 AC_TYPE_SIGNAL
  56 AC_FUNC_FORK
  57 AC_FUNC_UTIME_NULL
  58 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove strcasecmp)
  59 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
  60 AC_CHECK_FUNCS(mkdir rmdir ftruncate lchown mkstemp link)
  61 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
  62 AC_CHECK_FUNCS(iconv)
  63 AC_REPLACE_FUNCS(vsnprintf)
  64
  65 if test $ac_header_dirent = no; then
  66   AC_LIBOBJ(lhdir)
  67 fi
  68
  69 # checking whether 8 bit clean or not
  70 AC_CACHE_CHECK([whether strchr()/strrchr() is 8bit clean],
  71   [lha_cv_strchr_8bit_clean],
  72   AC_TRY_RUN([
  73 #if STDC_HEADERS
  74 # include <string.h>
  75 #else
  76 # if !HAVE_STRCHR
  77 #  define strchr index
  78 #  define strrchr rindex
  79 # endif
  80 char *strchr (), *strrchr ();
  81 #endif
  82
  83 main()
  84 {
  85   char *s = "\377";
  86   if (strchr(s, 0xff) != s) return 1;
  87   if (strchr(s, '\377') != s) return 1;
  88   if (strrchr(s, 0xff) != s) return 1;
  89   if (strrchr(s, '\377') != s) return 1;
  90   return 0; /* ok */
  91 }
  92 ], lha_cv_strchr_8bit_clean=yes,
  93    lha_cv_strchr_8bit_clean=no,
  94    lha_cv_strchr_8bit_clean=no))
  95
  96 if test x$lha_cv_strchr_8bit_clean = xyes; then
  97   AC_DEFINE(STRCHR_8BIT_CLEAN, 1,
  98             [Define to 1 if strchr()/strrchr() works correctly.])
  99 fi
 100
 101 # support kanji code conversion
 102 AC_SUBST(DEF_KCODE)
 103 AC_ARG_ENABLE(text_conv,
 104   AC_HELP_STRING([--enable-text-conv],
 105                  [support text code convert from/to EUC [[default=yes]]]),
 106   , enable_text_conv=yes)
 107
 108 if test $enable_text_conv = yes; then
 109   DEF_KCODE=-DEUC
 110 fi
 111
 112 # force support -lh7-
 113 AC_SUBST(SUPPORT_LZHUFF_METHOD)
 114 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
 115
 116 # whether use the -lh567- method
 117 AC_MSG_CHECKING(default archive method is )
 118 AC_ARG_WITH(default_method,
 119   AC_HELP_STRING([--with-default-method=[[567]]],
 120                  [create the -lh[[567]]- archive default [[default=5]]]),
 121   [case $withval in
 122    [567]) ;;
 123    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
 124    esac],
 125   with_default_method=5)
 126 AC_MSG_RESULT(-lh$with_default_method-)
 127 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
 128
 129 # decide temporary path names
 130 AC_MSG_CHECKING(template of the temporary file is )
 131 AC_ARG_WITH(tmp_file,
 132   AC_HELP_STRING([--with-tmp-file=TEMPLATE],
 133                  [temporary file template [[default=/tmp/lhXXXXXX]]]),
 134   [case $withval in
 135    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
 136    no)   ;;
 137    esac],
 138   with_tmp_file=/tmp/lhXXXXXX)
 139 AC_MSG_RESULT($with_tmp_file)
 140 if test x"$with_tmp_file" != xno; then
 141   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
 142     [temporary file template for mktemp/mkstemp])
 143 fi
 144
 145 # incremental indicator
 146 AC_ARG_ENABLE(indicator,
 147   AC_HELP_STRING([--enable-indicator],
 148                  [need incremental indicator [[default=yes]]]),
 149   ,
 150   # default
 151   enable_indicator=yes)
 152 if test "x$enable_indicator" = xyes; then
 153   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1,
 154             [Define to 1 if you want to use the incremental indicator])
 155 fi
 156
 157 # support multibyte filename
 158 AC_MSG_CHECKING(kanji code for filename is )
 159 AC_ARG_ENABLE(multibyte-filename,
 160   AC_HELP_STRING([--enable-multibyte-filename],
 161                  [support multibyte filename. specify kanji code (euc, sjis, utf8 or auto) [[default=auto]]]),,
 162   # default
 163   enable_multibyte_filename=auto)
 164
 165 case $enable_multibyte_filename in
 166 auto|yes)
 167   AC_EGREP_CPP(SJIS,[
 168 #if defined(__CYGWIN__) || defined(__MINGW32__) || defined(__hpux)
 169 SJIS
 170 #endif], enable_multibyte_filename=CODE_SJIS,
 171   AC_EGREP_CPP(UTF8,[
 172 #if defined(__APPLE__)  /* for Mac OS X */
 173 UTF8
 174 #endif], enable_multibyte_filename=CODE_UTF8,
 175          enable_multibyte_filename=CODE_EUC));;
 176 sjis)    enable_multibyte_filename=CODE_SJIS;;
 177 euc)     enable_multibyte_filename=CODE_EUC;;
 178 utf8)    enable_multibyte_filename=CODE_UTF8;;
 179 no)      ;;
 180 *)       AC_MSG_ERROR([you should specify auto, sjis or euc as your system filename code.]);;
 181 esac
 182
 183 AC_MSG_RESULT($enable_multibyte_filename)
 184 if test x$enable_multibyte_filename != xno; then
 185   AC_DEFINE_UNQUOTED(MULTIBYTE_FILENAME, $enable_multibyte_filename,
 186       [Define to CODE_EUC or CODE_SJIS if you want to use multibyte filename])
 187
 188   case $target_os in
 189   darwin*)
 190         # for multibyte filename
 191         LDFLAGS="$LDFLAGS -framework CoreFoundation"
 192         ;;
 193   esac
 194 fi
 195
 196 # make user/group name extented header
 197 AC_ARG_ENABLE(user-name-header,
 198   AC_HELP_STRING([--enable-user-name-header],
 199                  [make user/group name extended header [[default=no]]]),
 200   ,
 201   # default
 202   enable_user_name_header=no)
 203 if test "x$user_name_header" = xyes; then
 204   AC_DEFINE(INCLUDE_OWNER_NAME_IN_HEADER, 1,
 205             [Define to 1 if you want to use the user/group name extened header])
 206 fi
 207
 208 # backup old archive file
 209 AC_ARG_ENABLE(backup_archive,
 210   AC_HELP_STRING([--enable-backup-archive],
 211                  [backup old archive [[default=no]]]),
 212   ,
 213   # default
 214   enable_backup_archive=no)
 215 if test "x$enable_backup_archive" = xyes; then
 216   AC_DEFINE(BACKUP_OLD_ARCHIVE, 1,
 217             [Define to 1 if you want to leave an old archive])
 218 fi
 219
 220 AC_CONFIG_FILES([Makefile src/Makefile man/Makefile])
 221 AC_CONFIG_FILES([tests/Makefile tests/lha-test])
 222 AC_OUTPUT