configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_INIT([LHa for UNIX], 1.14i-ac20021115, jca02266@nifty.ne.jp, lha)
   3 AC_CANONICAL_TARGET
   4 AM_INIT_AUTOMAKE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_DEFINE_UNQUOTED(PLATFORM, "$ac_cv_host",
   8                    [the type of system on which the package will run.])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_GCC_TRADITIONAL
  13 AC_PROG_INSTALL
  14 AC_PROG_MAKE_SET
  15 AC_MINIX
  16 AM_C_PROTOTYPES
  17
  18 # Checks for libraries.
  19 AC_SEARCH_LIBS(opendir, [mingwex])
  20
  21 # Checks for header files.
  22 AC_HEADER_DIRENT
  23 AC_HEADER_STDC
  24 AC_CHECK_HEADERS(fcntl.h limits.h sys/file.h sys/param.h sys/time.h)
  25 AC_CHECK_HEADERS(pwd.h grp.h utime.h inttypes.h stdint.h)
  26
  27 # Checks for typedefs, structures, and compiler characteristics.
  28 AC_C_CONST
  29 AC_HEADER_TIME
  30 AC_STRUCT_TM
  31 AC_STRUCT_TIMEZONE
  32
  33 AC_CHECK_SIZEOF(long)
  34 AC_CHECK_TYPES([uid_t, gid_t, long long, uint64_t])
  35 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct stat.st_ino],,,
  36 [
  37 #if HAVE_SYS_TYPES_H
  38 # include <sys/types.h>
  39 #endif
  40 #if HAVE_SYS_STAT_H
  41 # include <sys/stat.h>
  42 #endif
  43 #if TIME_WITH_SYS_TIME
  44 # include <sys/time.h>
  45 # include <time.h>
  46 #else
  47 # if HAVE_SYS_TIME_H
  48 #  include <sys/time.h>
  49 # else
  50 #  include <time.h>
  51 # endif
  52 #endif
  53 ])
  54
  55 # Checks for library functions.
  56 AC_TYPE_SIGNAL
  57 AC_FUNC_FORK
  58 AC_FUNC_UTIME_NULL
  59 AC_CHECK_FUNCS(strchr strdup memcpy memset memmove strcasecmp)
  60 AC_CHECK_FUNCS(mktime timelocal tzset ftime gettimeofday utime)
  61 AC_CHECK_FUNCS(mkdir rmdir ftruncate chsize lchown mkstemp link)
  62 AC_CHECK_FUNCS(getpwuid getgrgid getpwnam getgrnam)
  63 AC_CHECK_FUNCS(iconv)
  64 AC_REPLACE_FUNCS(vsnprintf)
  65
  66 if test $ac_header_dirent = no; then
  67   AC_LIBOBJ(lhdir)
  68 fi
  69
  70 # checking whether 8 bit clean or not
  71 AC_CACHE_CHECK([whether strchr()/strrchr() is 8bit clean],
  72   [lha_cv_func_strchr_8bit_clean],
  73   AC_TRY_RUN([
  74 #if STDC_HEADERS
  75 # include <string.h>
  76 #else
  77 # if !HAVE_STRCHR
  78 #  define strchr index
  79 #  define strrchr rindex
  80 # endif
  81 char *strchr (), *strrchr ();
  82 #endif
  83
  84 main()
  85 {
  86   char *s = "\377";
  87   if (strchr(s, 0xff) != s) exit(1);
  88   if (strchr(s, '\377') != s) exit(1);
  89   if (strrchr(s, 0xff) != s) exit(1);
  90   if (strrchr(s, '\377') != s) exit(1);
  91   exit(0); /* ok */
  92 }
  93 ], lha_cv_func_strchr_8bit_clean=yes,
  94    lha_cv_func_strchr_8bit_clean=no,
  95    lha_cv_func_strchr_8bit_clean=no))
  96
  97 if test x$lha_cv_func_strchr_8bit_clean = xyes; then
  98   AC_DEFINE(STRCHR_8BIT_CLEAN, 1,
  99             [Define to 1 if strchr()/strrchr() works correctly.])
 100 fi
 101
 102 # checking whether the 2nd argument of gettimeofday() is effective or not.
 103 # note that this timezone argument is obsolete.
 104 AC_CACHE_CHECK([whether the 2nd argument of gettimeofday() is effective],
 105   [lha_cv_func_gettimeofday_2nd_arg],
 106   AC_TRY_RUN([
 107 #if TIME_WITH_SYS_TIME
 108 # include <sys/time.h>
 109 # include <time.h>
 110 #else
 111 # if HAVE_SYS_TIME_H
 112 #  include <sys/time.h>
 113 # else
 114 #  include <time.h>
 115 # endif
 116 #endif
 117
 118 main()
 119 {
 120     struct timeval tv;
 121     struct timezone tz;
 122
 123     tz.tz_minuteswest = -1;
 124     if (gettimeofday(&tv, &tz) == -1)
 125         exit(1);
 126
 127     if (tz.tz_minuteswest == -1)
 128         exit(1);        /* the timezone information is no given */
 129
 130     exit(0);
 131 }], lha_cv_func_gettimeofday_2nd_arg=yes,
 132    lha_cv_func_gettimeofday_2nd_arg=no,
 133    lha_cv_func_gettimeofday_2nd_arg=no))
 134
 135 if test x$lha_cv_func_gettimeofday_2nd_arg = xyes; then
 136   AC_DEFINE(GETTIMEOFDAY_HAS_2ND_ARG, 1,
 137             [Define to 1 if the 2nd argument of gettimeofday() is effective.])
 138 fi
 139
 140 # support kanji code conversion
 141 AC_SUBST(DEF_KCODE)
 142 AC_MSG_CHECKING(kanji code conversion on text file)
 143 AC_ARG_ENABLE(text-conv,
 144   AC_HELP_STRING([--enable-text-conv],
 145                  [support text code convert from/to EUC [[default=yes]]]),
 146   , enable_text_conv=yes)
 147
 148 AC_MSG_RESULT($enable_text_conv)
 149 if test $enable_text_conv = yes; then
 150   DEF_KCODE=-DEUC
 151 fi
 152
 153 # force support -lh7-
 154 AC_SUBST(SUPPORT_LZHUFF_METHOD)
 155 SUPPORT_LZHUFF_METHOD=-DSUPPORT_LH7
 156
 157 # whether use the -lh567- method
 158 AC_MSG_CHECKING(default archive method)
 159 AC_ARG_WITH(default-method,
 160   AC_HELP_STRING([--with-default-method=[[567]]],
 161                  [create the -lh[[567]]- archive default [[default=5]]]),
 162   [case $withval in
 163    [567]) ;;
 164    *) AC_MSG_ERROR(you should have specified 5, 6 or 7);;
 165    esac],
 166   with_default_method=5)
 167 AC_MSG_RESULT(-lh$with_default_method-)
 168 AC_DEFINE_UNQUOTED(DEFAULT_LZHUFF_METHOD, LZHUFF${with_default_method}_METHOD_NUM, [Define it to 5, 6 or 7 which you want to use -lhX- method, default])
 169
 170 # decide temporary path names
 171 AC_MSG_CHECKING(template of the temporary file)
 172 AC_ARG_WITH(tmp-file,
 173   AC_HELP_STRING([--with-tmp-file=TEMPLATE],
 174                  [temporary file template [[default=/tmp/lhXXXXXX]]]),
 175   [case $withval in
 176    yes)  with_tmp_file=/tmp/lhXXXXXX ;;
 177    no)   ;;
 178    esac],
 179   with_tmp_file=/tmp/lhXXXXXX)
 180
 181 AC_MSG_RESULT($with_tmp_file)
 182 if test x"$with_tmp_file" != xno; then
 183   AC_DEFINE_UNQUOTED(TMP_FILENAME_TEMPLATE, "$with_tmp_file",
 184     [temporary file template for mktemp/mkstemp])
 185 fi
 186
 187 # incremental indicator
 188 AC_MSG_CHECKING(whether incremental indicator is needed)
 189 AC_ARG_ENABLE(indicator,
 190   AC_HELP_STRING([--enable-indicator],
 191                  [need incremental indicator [[default=yes]]]),
 192   ,
 193   # default
 194   enable_indicator=yes)
 195
 196 AC_MSG_RESULT($enable_indicator)
 197 if test "x$enable_indicator" = xyes; then
 198   AC_DEFINE(NEED_INCREMENTAL_INDICATOR, 1,
 199             [Define to 1 if you want to use the incremental indicator])
 200 fi
 201
 202 # support multibyte filename
 203 AC_MSG_CHECKING(kanji code of filename)
 204 AC_ARG_ENABLE(multibyte-filename,
 205   AC_HELP_STRING([--enable-multibyte-filename],
 206                  [support multibyte filename. specify kanji code (euc, sjis, utf8 or auto) [[default=auto]]]),,
 207   # default
 208   enable_multibyte_filename=auto)
 209
 210 case $enable_multibyte_filename in
 211 auto|yes)
 212   AC_EGREP_CPP(SJIS,[
 213 #if defined(__CYGWIN__) || defined(__MINGW32__) || defined(__hpux)
 214 SJIS
 215 #endif], enable_multibyte_filename=CODE_SJIS,
 216   AC_EGREP_CPP(UTF8,[
 217 #if defined(__APPLE__)  /* for Mac OS X */
 218 UTF8
 219 #endif], enable_multibyte_filename=CODE_UTF8,
 220          enable_multibyte_filename=CODE_EUC));;
 221 sjis)    enable_multibyte_filename=CODE_SJIS;;
 222 euc)     enable_multibyte_filename=CODE_EUC;;
 223 utf8)    enable_multibyte_filename=CODE_UTF8;;
 224 no)      ;;
 225 *)       AC_MSG_ERROR([you should specify auto, sjis or euc as your system filename code.]);;
 226 esac
 227
 228 AC_MSG_RESULT($enable_multibyte_filename)
 229 if test x$enable_multibyte_filename != xno; then
 230   AC_DEFINE_UNQUOTED(MULTIBYTE_FILENAME, $enable_multibyte_filename,
 231       [Define to CODE_EUC or CODE_SJIS if you want to use multibyte filename])
 232
 233   case $target_os in
 234   darwin*)
 235         # for multibyte filename
 236         LDFLAGS="$LDFLAGS -framework CoreFoundation"
 237         ;;
 238   esac
 239 fi
 240
 241 # make user/group name extented header
 242 AC_MSG_CHECKING(whether user/group name extended header is needed)
 243 AC_ARG_ENABLE(user-name-header,
 244   AC_HELP_STRING([--enable-user-name-header],
 245                  [make user/group name extended header [[default=no]]]),
 246   ,
 247   # default
 248   enable_user_name_header=no)
 249
 250 AC_MSG_RESULT($enable_user_name_header)
 251 if test "x$enable_user_name_header" = xyes; then
 252   AC_DEFINE(INCLUDE_OWNER_NAME_IN_HEADER, 1,
 253             [Define to 1 if you want to use the user/group name extened header])
 254 fi
 255
 256 # backup old archive file
 257 AC_MSG_CHECKING(whether backup file for old archive is left)
 258 AC_ARG_ENABLE(backup-archive,
 259   AC_HELP_STRING([--enable-backup-archive],
 260                  [backup old archive [[default=no]]]),
 261   ,
 262   # default
 263   enable_backup_archive=no)
 264
 265 AC_MSG_RESULT($enable_backup_archive)
 266 if test "x$enable_backup_archive" = xyes; then
 267   AC_DEFINE(BACKUP_OLD_ARCHIVE, 1,
 268             [Define to 1 if you want to leave an old archive])
 269 fi
 270
 271 AC_CONFIG_FILES([Makefile src/Makefile man/Makefile])
 272 AC_CONFIG_FILES([tests/Makefile tests/lha-test])
 273 AC_OUTPUT