config/docbook.m4

   1 # $Header: /cvsroot/pgsql/config/docbook.m4,v 1.1 2000/11/05 21:04:06 petere Exp $
   2
   3 # PGAC_PROG_JADE
   4 # --------------
   5 AC_DEFUN([PGAC_PROG_JADE],
   6 [AC_CHECK_PROGS([JADE], [openjade jade])])
   7
   8
   9 # PGAC_PROG_NSGMLS
  10 # ----------------
  11 AC_DEFUN([PGAC_PROG_NSGMLS],
  12 [AC_CHECK_PROGS([NSGMLS], [onsgmls nsgmls])])
  13
  14
  15 # PGAC_CHECK_DOCBOOK(VERSION)
  16 # ---------------------------
  17 AC_DEFUN([PGAC_CHECK_DOCBOOK],
  18 [AC_REQUIRE([PGAC_PROG_NSGMLS])
  19 AC_CACHE_CHECK([for DocBook V$1], [pgac_cv_check_docbook],
  20 [cat >conftest.sgml <<EOF
  21 <!doctype book PUBLIC "-//OASIS//DTD DocBook V$1//EN">
  22 <book>
  23  <title>test</title>
  24  <chapter>
  25   <title>random</title>
  26    <sect1>
  27     <title>testsect</title>
  28     <para>text</para>
  29   </sect1>
  30  </chapter>
  31 </book>
  32 EOF
  33
  34 ${NSGMLS-false} -s conftest.sgml 1>&5 2>&1
  35 if test $? -eq 0; then
  36   pgac_cv_check_docbook=yes
  37 else
  38   pgac_cv_check_docbook=no
  39 fi
  40 rm -f conftest.sgml])
  41
  42 have_docbook=$pgac_cv_check_docbook
  43 AC_SUBST([have_docbook])
  44 ])# PGAC_CHECK_DOCBOOK
  45
  46
  47 # PGAC_PATH_DOCBOOK_STYLESHEETS
  48 # -----------------------------
  49 AC_DEFUN([PGAC_PATH_DOCBOOK_STYLESHEETS],
  50 [AC_MSG_CHECKING([for DocBook stylesheets])
  51 AC_CACHE_VAL([pgac_cv_path_stylesheets],
  52 [if test -n "$DOCBOOKSTYLE"; then
  53   pgac_cv_path_stylesheets=$DOCBOOKSTYLE
  54 else
  55   for pgac_prefix in /usr /usr/local /opt; do
  56     for pgac_infix in share lib; do
  57       for pgac_postfix in \
  58         sgml/stylesheets/nwalsh-modular \
  59         sgml/stylesheets/docbook \
  60         sgml/docbook/dsssl/modular
  61       do
  62         pgac_candidate=$pgac_prefix/$pgac_infix/$pgac_postfix
  63         if test -r "$pgac_candidate/html/docbook.dsl" \
  64            && test -r "$pgac_candidate/print/docbook.dsl"
  65         then
  66           pgac_cv_path_stylesheets=$pgac_candidate
  67           break 3
  68         fi
  69       done
  70     done
  71   done
  72 fi])
  73 DOCBOOKSTYLE=$pgac_cv_path_stylesheets
  74 AC_SUBST([DOCBOOKSTYLE])
  75 if test -n "$DOCBOOKSTYLE"; then
  76   AC_MSG_RESULT([$DOCBOOKSTYLE])
  77 else
  78   AC_MSG_RESULT(no)
  79 fi])# PGAC_PATH_DOCBOOK_STYLESHEETS