bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55
  56 AM_CONFIG_HEADER(config.h:config.in)
  57
  58 if test -z "$target" ; then
  59     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  60 fi
  61
  62 AM_MAINTAINER_MODE
  63 AM_INSTALL_LIBBFD
  64 AC_EXEEXT
  65
  66 host64=false
  67 target64=false
  68 bfd_default_target_size=32
  69
  70 # host stuff:
  71
  72 AC_PROG_CC
  73
  74 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw"
  75 CY_GNU_GETTEXT
  76
  77 # Permit host specific settings.
  78 . ${srcdir}/configure.host
  79
  80 AC_SUBST(HDEFINES)
  81 AC_PROG_INSTALL
  82
  83 BFD_HOST_64BIT_LONG=0
  84 BFD_HOST_LONG_LONG=0
  85 BFD_HOST_64_BIT_DEFINED=0
  86 BFD_HOST_64_BIT=
  87 BFD_HOST_U_64_BIT=
  88
  89 AC_MSG_CHECKING([for long long])
  90 AC_CACHE_VAL(bfd_cv_has_long_long,
  91 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
  92 AC_MSG_RESULT($bfd_cv_has_long_long)
  93 if test $bfd_cv_has_long_long = yes; then
  94   BFD_HOST_LONG_LONG=1
  95   AC_COMPILE_CHECK_SIZEOF(long long)
  96 fi
  97
  98 AC_COMPILE_CHECK_SIZEOF(long)
  99 if test "x${ac_cv_sizeof_long}" = "x8"; then
 100   host64=true
 101   BFD_HOST_64BIT_LONG=1
 102   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 103   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 104 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 105   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 106   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 107 fi
 108
 109 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 110   BFD_HOST_64_BIT_DEFINED=1
 111   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 112   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 113 fi
 114
 115 AC_SUBST(BFD_HOST_64BIT_LONG)
 116 AC_SUBST(BFD_HOST_LONG_LONG)
 117 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 118 AC_SUBST(BFD_HOST_64_BIT)
 119 AC_SUBST(BFD_HOST_U_64_BIT)
 120
 121 BFD_CC_FOR_BUILD
 122
 123 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 124 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 125 AC_HEADER_TIME
 126 AC_HEADER_DIRENT
 127 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 128 AC_CHECK_FUNCS(strtoull)
 129
 130 AC_CHECK_DECLS(basename, , , [#include "sysdep.h"])
 131
 132 BFD_BINARY_FOPEN
 133
 134 BFD_NEED_DECLARATION(ffs)
 135 BFD_NEED_DECLARATION(free)
 136 BFD_NEED_DECLARATION(getenv)
 137 BFD_NEED_DECLARATION(malloc)
 138 BFD_NEED_DECLARATION(realloc)
 139 BFD_NEED_DECLARATION(strstr)
 140
 141 # If we are configured native, pick a core file support file.
 142 COREFILE=
 143 COREFLAG=
 144 TRAD_HEADER=
 145 if test "${target}" = "${host}"; then
 146   case "${host}" in
 147   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 148         COREFILE=''
 149         ;;
 150   alpha*-*-linux-*)
 151         COREFILE=trad-core.lo
 152         TRAD_HEADER='"hosts/alphalinux.h"'
 153         ;;
 154   alpha*-*-netbsd* | alpha*-*-openbsd*)
 155         COREFILE=netbsd-core.lo
 156         ;;
 157   alpha*-*-*)           COREFILE=osf-core.lo ;;
 158   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 159                         COREFILE='' ;;
 160   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 161   arm-*-riscix)         COREFILE=trad-core.lo ;;
 162   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 163   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 164   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 165   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 166                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 167   hppa*-*-netbsd* | hppa*-*-openbsd*)
 168         COREFILE=netbsd-core.lo
 169         ;;
 170
 171   i370-*-*)
 172         COREFILE=trad-core.lo
 173         TRAD_HEADER='"hosts/i370linux.h"'
 174         ;;
 175
 176 changequote(,)dnl
 177   i[3-7]86-sequent-bsd*)
 178 changequote([,])dnl
 179         COREFILE=trad-core.lo
 180         TRAD_HEADER='"hosts/symmetry.h"'
 181         ;;
 182 changequote(,)dnl
 183   i[3-7]86-sequent-sysv4*) ;;
 184   i[3-7]86-sequent-sysv*)
 185 changequote([,])dnl
 186         COREFILE=trad-core.lo
 187         TRAD_HEADER='"hosts/symmetry.h"'
 188         ;;
 189 changequote(,)dnl
 190   i[3-7]86-*-bsdi)
 191 changequote([,])dnl
 192         COREFILE=
 193         ;;
 194 changequote(,)dnl
 195   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 196 changequote([,])dnl
 197         COREFILE=trad-core.lo
 198         TRAD_HEADER='"hosts/i386bsd.h"'
 199         ;;
 200 changequote(,)dnl
 201   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 202 changequote([,])dnl
 203         COREFILE=''
 204         TRAD_HEADER='"hosts/i386bsd.h"'
 205         ;;
 206 changequote(,)dnl
 207   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 208 changequote([,])dnl
 209         COREFILE=netbsd-core.lo
 210         ;;
 211 changequote(,)dnl
 212   i[3-7]86-esix-sysv3*)
 213 changequote([,])dnl
 214         COREFILE=trad-core.lo
 215         TRAD_HEADER='"hosts/esix.h"'
 216         ;;
 217 changequote(,)dnl
 218   i[3-7]86-*-sco3.2v5*)
 219 changequote([,])dnl
 220         COREFILE=sco5-core.lo
 221         ;;
 222 changequote(,)dnl
 223   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 224 changequote([,])dnl
 225         COREFILE=trad-core.lo
 226         TRAD_HEADER='"hosts/i386sco.h"'
 227         ;;
 228 changequote(,)dnl
 229   i[3-7]86-*-mach3*)
 230 changequote([,])dnl
 231         COREFILE=trad-core.lo
 232         TRAD_HEADER='"hosts/i386mach3.h"'
 233         ;;
 234 changequote(,)dnl
 235   i[3-7]86-*-linux-*)
 236 changequote([,])dnl
 237         COREFILE=trad-core.lo
 238         TRAD_HEADER='"hosts/i386linux.h"'
 239         ;;
 240 changequote(,)dnl
 241   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 242   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 243 changequote([,])dnl
 244   i860-*-mach3* | i860-*-osf1*)
 245         COREFILE=trad-core.lo
 246         TRAD_HEADER='"hosts/i860mach3.h"'
 247         ;;
 248   mips-*-netbsd* | mips*-*-openbsd*)
 249         COREFILE=netbsd-core.lo
 250         ;;
 251   mips-dec-*)
 252         COREFILE=trad-core.lo
 253         TRAD_HEADER='"hosts/decstation.h"'
 254         ;;
 255   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 256   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 257   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 258   mips-*-sysv4*)        ;;
 259   mips-*-sysv* | mips-*-riscos*)
 260         COREFILE=trad-core.lo
 261         TRAD_HEADER='"hosts/riscos.h"'
 262         ;;
 263   mips-sony-bsd*)
 264         COREFILE=trad-core.lo
 265         TRAD_HEADER='"hosts/news-mips.h"'
 266         ;;
 267   m68*-bull*-sysv*)
 268         COREFILE=trad-core.lo
 269         TRAD_HEADER='"hosts/dpx2.h"'
 270         ;;
 271   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 272   m68*-hp-bsd*)
 273         COREFILE=trad-core.lo
 274         TRAD_HEADER='"hosts/hp300bsd.h"'
 275         ;;
 276   m68*-*-linux-*)
 277         COREFILE=trad-core.lo
 278         TRAD_HEADER='"hosts/m68klinux.h"'
 279         ;;
 280   m68*-motorola-sysv*)
 281         COREFILE=trad-core.lo
 282         TRAD_HEADER='"hosts/delta68.h"'
 283         ;;
 284   m68*-sony-*)
 285         COREFILE=trad-core.lo
 286         TRAD_HEADER='"hosts/news.h"'
 287         ;;
 288   m68*-*-netbsd* | m68*-*-openbsd*)
 289         COREFILE=netbsd-core.lo
 290         ;;
 291   m68*-apple-aux*)
 292         COREFILE=trad-core.lo
 293         TRAD_HEADER='"hosts/m68kaux.h"'
 294         ;;
 295   m88*-*-sysv4*)
 296         ;;
 297   m88*-motorola-sysv*)
 298         COREFILE=ptrace-core.lo
 299         ;;
 300   m88*-*-mach3*)
 301         COREFILE=trad-core.lo
 302         TRAD_HEADER='"hosts/m88kmach3.h"'
 303         ;;
 304   m88*-*-openbsd*)
 305         COREFILE=netbsd-core.lo
 306         ;;
 307   ns32k-pc532-mach)
 308         COREFILE=trad-core.lo
 309         TRAD_HEADER='"hosts/pc532mach.h"'
 310         ;;
 311   ns32k-*-netbsd* | ns32k-*-openbsd*)
 312         COREFILE=netbsd-core.lo
 313         ;;
 314   rs6000-*-lynx*)
 315         COREFILE=lynx-core.lo
 316         ;;
 317   rs6000-*-aix5.* | powerpc-*-aix5.*)
 318         COREFILE=rs6000-core.lo
 319         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 320         ;;
 321 changequote(,)dnl
 322   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 323 changequote([,])dnl
 324         COREFILE=rs6000-core.lo
 325         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 326         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 327         # have c_impl as a member of struct core_dumpx
 328         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 329         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 330             [Define if struct core_dumpx has member c_impl])
 331           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 332         ;;
 333   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 334   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 335   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 336   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 337   powerpc-*-beos*)      ;;
 338   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 339                         COREFILE='' ;;
 340   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 341   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 342   s390*-*-*)            COREFILE=trad-core.lo ;;
 343   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 344   sparc-*-netbsd* | sparc*-*-openbsd*)
 345         COREFILE=netbsd-core.lo
 346         ;;
 347   tahoe-*-*)
 348         COREFILE=trad-core.lo
 349         TRAD_HEADER='"hosts/tahoe.h"'
 350         ;;
 351   vax-*-netbsd* | vax-*-openbsd*)
 352         COREFILE=netbsd-core.lo
 353         ;;
 354   vax-*-ultrix2*)
 355         COREFILE=trad-core.lo
 356         TRAD_HEADER='"hosts/vaxult2.h"'
 357         ;;
 358   vax-*-ultrix*)
 359         COREFILE=trad-core.lo
 360         TRAD_HEADER='"hosts/vaxult2.h"'
 361         ;;
 362   vax-*-linux-*)
 363         COREFILE=trad-core.lo
 364         TRAD_HEADER='"hosts/vaxlinux.h"'
 365         ;;
 366   vax-*-*)
 367         COREFILE=trad-core.lo
 368         TRAD_HEADER='"hosts/vaxbsd.h"'
 369         ;;
 370   x86_64-*-netbsd* | x86_64-*-openbsd*)
 371         COREFILE=netbsd-core.lo
 372         ;;
 373   esac
 374
 375   case "$COREFILE" in
 376   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 377   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 378   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 379   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 380   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 381   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 382   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 383   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 384   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 385   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 386   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 387   esac
 388
 389   # ELF corefile support has several flavors, but all of
 390   # them use something called <sys/procfs.h>
 391   AC_CHECK_HEADERS(sys/procfs.h)
 392   if test "$ac_cv_header_sys_procfs_h" = yes; then
 393     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 394     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 395     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 396     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 397     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 398     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 399     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 400     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 401     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 402     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 403     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 404     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 407     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 408     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 409   fi
 410 fi
 411 AC_SUBST(COREFILE)
 412 AC_SUBST(COREFLAG)
 413 if test -n "$TRAD_HEADER"; then
 414   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 415     [Name of host specific header file to include in trad-core.c.])
 416 fi
 417
 418 # Horrible hacks to build DLLs on Windows.
 419 WIN32LDFLAGS=
 420 WIN32LIBADD=
 421 case "${host}" in
 422 *-*-cygwin*)
 423   if test "$enable_shared" = "yes"; then
 424     WIN32LDFLAGS="-no-undefined"
 425     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 426   fi
 427   ;;
 428 *-*-linux*)
 429   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 430   # libiberty.a.
 431   case "${host}" in
 432   mips*-*-linux*)
 433     # Linux/MIPS uses PIC by default.
 434     if test "$enable_shared" = "yes"; then
 435       WIN32LIBADD="-L../libiberty -liberty"
 436     fi
 437     ;;
 438   *)
 439 changequote(,)dnl
 440     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 441 changequote([,])dnl
 442     if test -n "$x"; then
 443       WIN32LIBADD="-L../libiberty/pic -liberty"
 444     fi
 445   ;;
 446   esac
 447   ;;
 448 esac
 449 AC_SUBST(WIN32LDFLAGS)
 450 AC_SUBST(WIN32LIBADD)
 451
 452 # target stuff:
 453
 454 # Canonicalize the secondary target names.
 455 if test -n "$enable_targets" ; then
 456     for targ in `echo $enable_targets | sed 's/,/ /g'`
 457     do
 458         result=`$ac_config_sub $targ 2>/dev/null`
 459         if test -n "$result" ; then
 460             canon_targets="$canon_targets $result"
 461         else
 462             # Allow targets that config.sub doesn't recognize, like "all".
 463             canon_targets="$canon_targets $targ"
 464         fi
 465     done
 466 fi
 467
 468 all_targets=false
 469 defvec=
 470 selvecs=
 471 assocvecs=
 472 selarchs=
 473 TDEFINES=
 474 for targ in $target $canon_targets
 475 do
 476     if test "x$targ" = "xall"; then
 477         all_targets=true
 478         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 479     else
 480         . $srcdir/config.bfd
 481         if test "x$targ" = "x$target"; then
 482             defvec=$targ_defvec
 483         fi
 484         selvecs="$selvecs $targ_defvec $targ_selvecs"
 485         selarchs="$selarchs $targ_archs"
 486         TDEFINES="$TDEFINES $targ_cflags"
 487     fi
 488 done
 489 AC_SUBST(TDEFINES)
 490
 491 # This processing still needs to be done if we're to decide properly whether
 492 # 64-bit support needs to be compiled in.  Currently, it will be included if
 493 # the default or any other explicitly requested target requires it; it
 494 # will not be included on a 32-bit host if no 64-bit target is requested, and
 495 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 496 # used.
 497
 498 # uniq the default and selected vectors in all the configured targets.
 499 f=""
 500 for i in $selvecs ; do
 501     case " $f " in
 502     *" $i "*) ;;
 503     *) f="$f $i" ;;
 504     esac
 505 done
 506 selvecs="$f"
 507
 508
 509 # uniq the associated vectors in all the configured targets.
 510 f=""
 511 for i in $assocvecs ; do
 512     case " $f " in
 513     *" $i "*) ;;
 514     *) f="$f $i" ;;
 515     esac
 516 done
 517 assocvecs="$f"
 518
 519
 520 # uniq the architectures in all the configured targets.
 521 f=""
 522 for i in $selarchs ; do
 523     case " $f " in
 524     *" $i "*) ;;
 525     *) f="$f $i" ;;
 526     esac
 527 done
 528 selarchs="$f"
 529
 530 # Target backend .o files.
 531 tb=
 532
 533 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 534
 535 for vec in $selvecs
 536 do
 537     target_size=32
 538     case "$vec" in
 539     # This list is alphabetized to make it easy to compare
 540     # with the two vector lists in targets.c.  For the same reason,
 541     # use one entry per line, even though this leads to long lines.
 542     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 543     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 544     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 545     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 546     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 547     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 548     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 549     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 550     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 551     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 552     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 553     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 554     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 555     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 556     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 557     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 558     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 559     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 560     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 561     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 562     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 563     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 564     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 565     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 566     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 567     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 568     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 569     bfd_elf32_bigarm_symbian_vec)
 570                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 571     bfd_elf32_bigarm_vxworks_vec)
 572                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 573     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 574     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 575     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 576     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 577     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 578     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 579     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 580     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 581     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 582     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 583     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 584     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 585     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 586     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 587     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 588     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 589     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf32.lo $elf" ;;
 590     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 591     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 592     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 593     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 594     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 595     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 596     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 597     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 598     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 599     bfd_elf32_littlearm_symbian_vec)
 600                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 601     bfd_elf32_littlearm_vxworks_vec)
 602                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 603     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 604     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 605     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 606     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 607     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 608     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 609     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 610     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 611     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 612     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 613     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 614     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 615     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 616     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 617     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 618     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 619     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 620     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 621     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 622     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 623     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 624     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 625     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 626     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 627     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 628     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 629     # FIXME: We include cofflink.lo not because it's needed for
 630     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 631     # which needs it but does not list it.  Should be fixed in right place.
 632     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 633     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 634     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 635     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 636     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 637     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 638     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 639     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 640     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 641     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 642     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 643     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 644     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 645     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
 646     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 647     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 648     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 649     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 650     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 651     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 652     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 653     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 654     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 655     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 656     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 657     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 658     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 659     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 660     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 661     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 662     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 663     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 664     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 665     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 666     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 667     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 668     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 669     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 670     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 671     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 672     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 673     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 674     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 675     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
 676     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 677     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 678     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 679     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 680     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 681     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 682     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 683     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 684     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 685     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 686     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 687     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 688     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 689     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 690     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 691     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 692     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 693     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 694     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 695     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 696     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 697     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 698     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 699     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 700     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 701     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 702     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 703     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 704     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 705     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 706     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 707     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 708     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 709     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 710     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 711     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 712     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 713     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 714     ieee_vec)                   tb="$tb ieee.lo" ;;
 715     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 716     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 717     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 718     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 719     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 720     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 721     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 722     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 723     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 724     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 725     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 726     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 727     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 728     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 729     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 730     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 731     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 732     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 733     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 734     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 735     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 736     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 737     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 738     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 739     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 740     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 741     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 742     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 743     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 744     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 745     pef_vec)                    tb="$tb pef.lo" ;;
 746     pef_xlib_vec)               tb="$tb pef.lo" ;;
 747     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 748     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 749     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 750     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 751     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 752     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 753     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 754     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 755     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 756     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 757     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 758     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 759     som_vec)                    tb="$tb som.lo" ;;
 760     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 761     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 762     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 763     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 764     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 765     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 766     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 767     sym_vec)                    tb="$tb xsym.lo" ;;
 768     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 769     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 770     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 771     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 772     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 773     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 774     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 775     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 776     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 777     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 778     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 779     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 780     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 781     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 782     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 783     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 784     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 785     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 786     versados_vec)               tb="$tb versados.lo" ;;
 787     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 788     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 789     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 790     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 791     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 792
 793     # These appear out of order in targets.c
 794     srec_vec)                   tb="$tb srec.lo" ;;
 795     symbolsrec_vec)             tb="$tb srec.lo" ;;
 796     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 797     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 798     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 799
 800     "")                 ;;
 801     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 802     esac
 803
 804     if test ${target_size} = 64; then
 805         target64=true
 806     fi
 807     if test x"${vec}" = x"${defvec}"; then
 808         bfd_default_target_size=${target_size}
 809     fi
 810 done
 811
 812 # Target architecture .o files.
 813 # A couple of CPUs use shorter file names to avoid problems on DOS
 814 # filesystems.
 815 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 816
 817 # Weed out duplicate .o files.
 818 f=""
 819 for i in $tb ; do
 820     case " $f " in
 821     *" $i "*) ;;
 822     *) f="$f $i" ;;
 823     esac
 824 done
 825 tb="$f"
 826
 827 f=""
 828 for i in $ta ; do
 829     case " $f " in
 830     *" $i "*) ;;
 831     *) f="$f $i" ;;
 832     esac
 833 done
 834 ta="$f"
 835
 836 bfd_backends="$tb"
 837 bfd_machines="$ta"
 838
 839 if test x${all_targets} = xtrue ; then
 840   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 841   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 842   selvecs=
 843   havevecs=
 844   selarchs=
 845   test -n "$assocvecs" &&
 846     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 847 else    # all_targets is true
 848   # Only set these if they will be nonempty, for the clever echo.
 849   havevecs=
 850   assocvecs=
 851   test -n "$selvecs" &&
 852     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 853   test -n "$selvecs" &&
 854     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 855   test -n "$selarchs" &&
 856     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 857 fi      # all_targets is true
 858
 859 case ${host64}-${target64}-${want64} in
 860   *true*)
 861     wordsize=64
 862     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 863     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 864     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 865       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 866       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 867     fi
 868     if test -n "$GCC" ; then
 869        bad_64bit_gcc=no;
 870        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 871        # Add more tests for gcc versions with non-working 64-bit support here.
 872        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 873                     bad_64bit_gcc=yes;
 874                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 875                     AC_MSG_RESULT(no))
 876        if test $bad_64bit_gcc = yes ; then
 877          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 878        fi
 879     fi
 880     ;;
 881   false-false-false)
 882     wordsize=32
 883     bfd_libs='$(BFD32_LIBS)'
 884     all_backends='$(BFD32_BACKENDS)'
 885     ;;
 886 esac
 887
 888 AC_SUBST(wordsize)
 889 AC_SUBST(bfd_libs)
 890 AC_SUBST(all_backends)
 891 AC_SUBST(bfd_backends)
 892 AC_SUBST(bfd_machines)
 893 AC_SUBST(bfd_default_target_size)
 894
 895 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 896 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 897 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 898 # Hopefully a reasonable assumption since fseeko et.al. should be
 899 # upward compatible.
 900 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 901 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 902     AC_COMPILE_CHECK_SIZEOF(off_t)
 903 fi
 904 AC_MSG_CHECKING([file_ptr type])
 905 bfd_file_ptr="long"
 906 bfd_ufile_ptr="unsigned long"
 907 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 908         -o x"${ac_cv_sizeof_off_t}" = x8; then
 909     bfd_file_ptr=BFD_HOST_64_BIT
 910     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 911 fi
 912 AC_MSG_RESULT($bfd_file_ptr)
 913 AC_SUBST(bfd_file_ptr)
 914 AC_SUBST(bfd_ufile_ptr)
 915
 916
 917 tdefaults=""
 918 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 919 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 920 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 921 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 922 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 923 AC_SUBST(tdefaults)
 924
 925 dnl AC_CHECK_HEADERS(sys/mman.h)
 926 AC_FUNC_MMAP
 927 AC_CHECK_FUNCS(madvise mprotect)
 928 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 929   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 930 esac
 931
 932 rm -f doc/config.status
 933 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 934 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 935 AC_OUTPUT
 936