# $Id$
PortSystem	1.0

name				macvim
version				20090417
revision			0
categories			editors
platforms			darwin
maintainers			nomaintainer
description			MacVim is a port of the text editor Vim to Mac OS X.
long_description	MacVim supports multiple windows with tabbed editing and a host of other features. \
					MacVim brings you the full power of Vim to Mac OS X.
homepage			http://code.google.com/p/macvim-kaoriya/

set gittag			${version}
distname			KaoriYa-${gittag}
use_zip				yes
checksums			\
	${distname}.zip sha1 24885fa750ed51625e6de5705bcc212a688c2767
master_sites		\
	"http://repo.or.cz/w/MacVim/KaoriYa.git?a=snapshot;h=${gittag};sf=zip&"
worksrcdir			KaoriYa/src
extract.only		${distname}.zip

depends_lib			port:cmigemo \
					port:gettext \
					port:libiconv \
					port:ncurses

configure.pre_args	--prefix=${applications_dir}
configure.args		--enable-gui=macvim \
					--without-x \
					--disable-gpm \
					--with-features=huge \
					--enable-multibyte \
					--with-tlib=ncurses
configure.cppflags	-I${prefix}/include
configure.ldflags	-L${prefix}/lib

if {[variant_isset universal]} {
	configure.universal_target	10.4
	configure.args-append		--with-mac-arch=both
	set xcodeconfig Universal
} else {
	set xcodeconfig Release
}

use_parallel_build	yes

variant perl description {Enable Perl scripting} {
	configure.args-append	--enable-perlinterp
	depends_lib-append		bin:perl:perl5.8
}
variant python description {Enable Python scripting} {
	configure.args-append	--enable-pythoninterp
	depends_lib-append		bin:python:python25
}
variant ruby description {Enable Ruby scripting} {
	configure.args-append	--enable-rubyinterp
	configure.env-append	ARCHFLAGS="-L${prefix}/lib"
	depends_lib-append		bin:ruby:ruby
}
variant tcl description {Enable Tcl scripting} {
	configure.args-append	--enable-tclinterp
	depends_lib-append		bin:tclsh:tcl
}
variant cscope description {Enable source code browsing with cscope} {
	configure.args-append	--enable-cscope
}

post-patch {
	reinplace \
		"s|^# VIM_APP_DIR=/Applications$|VIM_APP_DIR=${applications_dir}|" \
		${worksrcpath}/MacVim/mvim
}

post-build {
	system "cd ${worksrcpath}/po; make ja_JP.UTF-8.mo"
	system "cd ${worksrcpath}/MacVim; xcodebuild -configuration ${xcodeconfig}"
}

# Can be removed once MacPorts 1.7.1 is released
pre-destroot {
	xinstall -d ${destroot}${applications_dir}
}

set appPath "${destroot}${applications_dir}/MacVim.app/Contents"
set runtimePath "${appPath}/Resources/vim/runtime"

destroot {
	file copy ${worksrcpath}/MacVim/build/${xcodeconfig}/MacVim.app ${destroot}${applications_dir}
	xinstall -m 755 ${worksrcpath}/MacVim/mvim ${destroot}${prefix}/bin
	xinstall -d 755 ${runtimePath}/lang/ja_JP.UTF-8/LC_MESSAGES
	xinstall -m 644 ${worksrcpath}/po/ja_JP.UTF-8.mo \
		${runtimePath}/lang/ja_JP.UTF-8/LC_MESSAGES/vim.mo
	file copy ${prefix}/share/migemo/tools/migemo.vim \
		${runtimePath}/plugin/migemo.vim
}

test.run			yes

variant standalone description {Enable standalonize} {
	configure.env-append	PATH="/usr/bin:${env(PATH)}"
	configure.cppflags-append	-DDYNAMIC_PERL -DDYNAMIC_PYTHON -DDYNAMIC_RUBY
	post-configure {
		reinplace "s|^PERL_LIBS|#PERL_LIBS|" ${worksrcpath}/auto/config.mk
		reinplace "s|^PYTHON_LIBS|#PYTHON_LIBS|" ${worksrcpath}/auto/config.mk
		reinplace "s|^RUBY_LIBS|#RUBY_LIBS|" ${worksrcpath}/auto/config.mk
	}
	post-destroot {
		foreach dylib {intl.8 iconv.2 migemo.1 ncurses.5} {
			set libname [lindex [split ${dylib} .] 0]
			set instname "@executable_path/../Frameworks/lib${libname}.dylib"
			set origname "${prefix}/lib/lib${dylib}.dylib"
			system "install_name_tool \
				-change ${origname} ${instname} ${appPath}/MacOS/Vim"
			if {[file type ${origname}] == "link"} {
				set realpath "${prefix}/lib/"
				append realpath [file readlink ${origname}]
			} else {
				set realpath ${origname}
			}
			xinstall -m 755 ${realpath} \
				${appPath}/Frameworks/lib${libname}.dylib
		}
		system "install_name_tool \
			-change ${prefix}/lib/libiconv.2.dylib \
			@executable_path/../Frameworks/libiconv.dylib \
			${appPath}/Frameworks/libintl.dylib"

		xinstall -d 755 ${runtimePath}/dict
		foreach mdict {han2zen.dat hira2kata.dat \
				migemo-dict roma2hira.dat zen2han.dat} {
			xinstall -m 644 ${prefix}/share/migemo/utf-8/${mdict} \
				${runtimePath}/dict
		}
	}
}

include gdb