OSDN Git Service

* acx.m4 (ACX_PKGVERSION, ACX_BUGURL): Define.
authorjsm28 <jsm28@138bc75d-0d04-0410-961f-82ee72b054a4>
Fri, 23 Mar 2007 02:51:56 +0000 (02:51 +0000)
committerjsm28 <jsm28@138bc75d-0d04-0410-961f-82ee72b054a4>
Fri, 23 Mar 2007 02:51:56 +0000 (02:51 +0000)
git-svn-id: svn+ssh://gcc.gnu.org/svn/gcc/trunk@123147 138bc75d-0d04-0410-961f-82ee72b054a4

config/ChangeLog
config/acx.m4

index f0cda7a..250c3ff 100644 (file)
@@ -1,3 +1,7 @@
+2007-03-23  Joseph Myers  <joseph@codesourcery.com>
+
+       * acx.m4 (ACX_PKGVERSION, ACX_BUGURL): Define.
+
 2007-03-07  Andreas Schwab  <schwab@suse.de>
 
        * acx.m4 (GCC_TARGET_TOOL): Expand backquotes outside
index a897075..73afe8d 100644 (file)
@@ -552,3 +552,41 @@ AC_DEFUN([ACX_CHECK_PROG_VER],[
     $1="${CONFIG_SHELL-/bin/sh} $ac_aux_dir/missing $2"
   fi
 ])
+
+dnl Support the --with-pkgversion configure option.
+dnl ACX_PKGVERSION(default-pkgversion)
+AC_DEFUN([ACX_PKGVERSION],[
+  AC_ARG_WITH(pkgversion,
+    AS_HELP_STRING([--with-pkgversion=PKG],
+                   [Use PKG in the version string in place of "$1"]),
+    [case "$withval" in
+      yes) AC_MSG_ERROR([package version not specified]) ;;
+      no)  PKGVERSION= ;;
+      *)   PKGVERSION="($withval) " ;;
+     esac],
+    PKGVERSION="($1) "
+  )
+  AC_SUBST(PKGVERSION)
+])
+
+dnl Support the --with-bugurl configure option.
+dnl ACX_BUGURL(default-bugurl)
+AC_DEFUN([ACX_BUGURL],[
+  AC_ARG_WITH(bugurl,
+    AS_HELP_STRING([--with-bugurl=URL],
+                   [Direct users to URL to report a bug]),
+    [case "$withval" in
+      yes) AC_MSG_ERROR([bug URL not specified]) ;;
+      no)  REPORT_BUGS_TO="";
+          REPORT_BUGS_TEXI=""
+          ;;
+      *)   REPORT_BUGS_TO="<$withval>"
+          REPORT_BUGS_TEXI="@uref{`echo $withval | sed 's/@/@@/g'`}"
+          ;;
+     esac],
+     REPORT_BUGS_TO="<$1>"
+     REPORT_BUGS_TEXI="@uref{$1}"
+  )
+  AC_SUBST(REPORT_BUGS_TO)
+  AC_SUBST(REPORT_BUGS_TEXI)
+])