OSDN Git Service

2008-03-16 Ralf Wildenhues <Ralf.Wildenhues@gmx.de>
[pf3gnuchains/gcc-fork.git] / ltsugar.m4
1 # ltsugar.m4 -- libtool m4 base layer.                         -*-Autoconf-*-
2 #
3 # Copyright (C) 2004, 2005, 2007 Free Software Foundation, Inc.
4 # Written by Gary V. Vaughan.
5 #
6 # This file is free software; the Free Software Foundation gives
7 # unlimited permission to copy and/or distribute it, with or without
8 # modifications, as long as this notice is preserved.
9
10 # serial 4 ltsugar.m4
11
12 # This is to help aclocal find these macros, as it can't see m4_define.
13 AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
14
15
16 # lt_join(SEP, ARG1, [ARG2...])
17 # -----------------------------
18 # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
19 # associated separator.
20 m4_define([lt_join],
21 [m4_case([$#],
22          [0], [m4_fatal([$0: too few arguments: $#])],
23          [1], [],
24          [2], [[$2]],
25          [m4_ifval([$2],
26                    [[$2][]m4_foreach(_lt_Arg, lt_car([m4_shiftn(2, $@)]),
27                            [_$0([$1], _lt_Arg)])],
28                    [$0([$1], m4_shiftn(2, $@))])])[]dnl
29 ])
30 m4_define([_lt_join],
31 [m4_ifval([$2],[$1][$2])[]dnl
32 ])
33
34
35 # lt_car(LIST)
36 # lt_cdr(LIST)
37 # ------------
38 # Manipulate m4 lists.
39 # These macros are necessary as long as will still need to support
40 # Autoconf-2.59 which quotes differently.
41 m4_define([lt_car], [[$1]])
42 m4_define([lt_cdr],
43 [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
44        [$#], 1, [],
45        [m4_dquote(m4_shift($@))])])
46 m4_define([lt_unquote], $1)
47
48
49 # lt_append(MACRO-NAME, STRING, [SEPARATOR])
50 # ------------------------------------------
51 # Redefine MACRO-NAME to hold its former content plus `SEPARATOR'`STRING'.
52 # Note that neither SEPARATOR nor STRING are expanded.  No SEPARATOR is
53 # output if MACRO-NAME was previously undefined (different than defined
54 # and empty).
55 # This macro is needed until we can rely on Autoconf 2.62, since earlier
56 # versions of m4 mistakenly expanded SEPARATOR.
57 m4_define([lt_append],
58 [m4_define([$1],
59            m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
60
61
62
63 # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
64 # ----------------------------------------------------------
65 # Produce a SEP delimited list of all paired combinations of elements of
66 # PREFIX-LIST with SUFFIX1 through SUFFIXn.  Each element of the list
67 # has the form PREFIXmINFIXSUFFIXn.
68 m4_define([lt_combine],
69 [m4_if([$2], [], [],
70   [m4_if([$4], [], [],
71     [lt_join(m4_quote(m4_default([$1], [[, ]])),
72       lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_prefix, [$2],
73                    [m4_foreach(_Lt_suffix, lt_car([m4_shiftn(3, $@)]),
74                                [_Lt_prefix[]$3[]_Lt_suffix ])])))))])])dnl
75 ])
76
77
78 # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
79 # -----------------------------------------------------------------------
80 # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
81 # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
82 m4_define([lt_if_append_uniq],
83 [m4_ifdef([$1],
84           [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
85                  [lt_append([$1], [$2], [$3])$4],
86                  [$5])],
87     [lt_append([$1], [$2], [$3])$4])])
88
89
90 # lt_dict_add(DICT, KEY, VALUE)
91 # -----------------------------
92 m4_define([lt_dict_add],
93 [m4_define([$1($2)], [$4])])
94
95
96 # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
97 # --------------------------------------------
98 m4_define([lt_dict_add_subkey],
99 [m4_define([$1($2:$3)], [$4])])
100
101
102 # lt_dict_fetch(DICT, KEY, [SUBKEY])
103 # ----------------------------------
104 m4_define([lt_dict_fetch],
105 [m4_ifval([$3],
106         m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
107     m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
108
109
110 # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
111 # -----------------------------------------------------------------
112 m4_define([lt_if_dict_fetch],
113 [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
114         [$5],
115     [$6])])
116
117
118 # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
119 # --------------------------------------------------------------
120 m4_define([lt_dict_filter],
121 [m4_if([$5], [], [],
122   [lt_join(m4_quote(m4_default([$4], [[, ]])),
123            lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
124                       [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
125 ])