libstdc++-v3/testsuite/lib/libstdc++.exp

   1 # libstdc++ "tool init file" for DejaGNU
   2
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007
   4 # Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21
  22 # Define callbacks and load other libraries.  This file is loaded relatively
  23 # early, and before any other file we write ourselves.  "load_lib" will
  24 # find anything in the DejaGNU installation tree, or in our lib directory.
  25 # "load_gcc_lib" will search the core compiler's .exp collection instead.
  26 #
  27 # The naming rule is that dg.exp looks for "tool-" and runtest.exp looks
  28 # for "tool_" when finding callbacks.  Utility routines we define for
  29 # our callbacks begin with "v3-".
  30 #
  31 # libstdc++_* callbacks we don't define, but could:
  32 # ..._option_help           prints additional --help output
  33 # ..._option_proc (--foo)   process our own options
  34 # ..._init (normal.exp)     called once per test file
  35 # ..._finish                bracketing function for libstdc++_init
  36 # ...-dg-prune              removing output text, see top of system dg.exp
  37 #
  38 # Useful hook:  if ${hostname}_init exists, it will be called, almost
  39 # the last thing before testing begins.  This can be defined in, e.g.,
  40 # ~/.dejagnurc or $DEJAGNU.
  41
  42 proc load_gcc_lib { filename } {
  43     global srcdir
  44     load_file $srcdir/../../gcc/testsuite/lib/$filename
  45 }
  46
  47 # system routines
  48 load_lib dg.exp
  49 load_lib libgloss.exp
  50 # compiler routines, then ours
  51 load_gcc_lib target-supports.exp
  52 load_gcc_lib target-supports-dg.exp
  53 load_lib prune.exp
  54 load_lib dg-options.exp
  55 load_gcc_lib target-libpath.exp
  56 load_gcc_lib wrapper.exp
  57
  58 # Useful for debugging.  Pass the name of a variable and the verbosity
  59 # threshold (number of -v's on the command line).
  60 proc v3track { var n } {
  61     upvar $var val
  62     verbose "++ $var is $val" $n
  63 }
  64
  65 # Called by v3-init below.  "Static" to this file.
  66 proc v3-copy-files {srcfiles} {
  67     foreach f $srcfiles {
  68         if { [catch { set symlink [file readlink $f] } x] } then {
  69             remote_download target $f
  70         } else {
  71             if { [regexp "^/" "$symlink"] } then {
  72                 remote_download target $symlink
  73             } else {
  74                 set dirname [file dirname $f]
  75                 remote_download target $dirname/$symlink
  76             }
  77         }
  78     }
  79 }
  80
  81 # Called once, during runtest.exp setup.
  82 proc libstdc++_init { testfile } {
  83     global env
  84     global v3-sharedlib
  85     global srcdir blddir objdir tool_root_dir
  86     global cxx cxxflags cxxldflags
  87     global includes
  88     global gluefile wrap_flags
  89     global ld_library_path
  90     global target_triplet
  91     global flags_file
  92
  93     # We set LC_ALL and LANG to C so that we get the same error
  94     # messages as expected.
  95     setenv LC_ALL C
  96     setenv LANG C
  97
  98     set blddir [lookfor_file [get_multilibs] libstdc++-v3]
  99     set flags_file "${blddir}/scripts/testsuite_flags"
 100     v3track flags_file 2
 101
 102     # If a test doesn't have special options, use DEFAULT_CXXFLAGS.
 103     # Use this variable if the behavior
 104     #   1) only applies to libstdc++ testing
 105     #   2) might need to be negated
 106     # In particular, some tests have to be run without precompiled
 107     # headers, or without assertions.
 108     global DEFAULT_CXXFLAGS
 109     if ![info exists DEFAULT_CXXFLAGS] then {
 110         set DEFAULT_CXXFLAGS ""
 111         # Host specific goo here.
 112         if { [string match "powerpc-*-darwin*" $target_triplet] } {
 113             append DEFAULT_CXXFLAGS " -multiply_defined suppress"
 114         }
 115     }
 116     v3track DEFAULT_CXXFLAGS 2
 117
 118     # By default, we assume we want to run program images.
 119     global dg-do-what-default
 120     set dg-do-what-default run
 121
 122     # Copy any required data files.
 123     v3-copy-files [glob -nocomplain "$srcdir/data/*.tst"]
 124     v3-copy-files [glob -nocomplain "$srcdir/data/*.txt"]
 125
 126     # Locate libgcc.a so we don't need to account for different values of
 127     # SHLIB_EXT on different platforms
 128     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 129     if {$gccdir != ""} {
 130         set gccdir [file dirname $gccdir]
 131     }
 132     v3track gccdir 3
 133
 134     # Look for shared library. (ie libstdc++.so.)
 135     set v3-sharedlib 0
 136     set sharedlibdir [lookfor_file $blddir src/.libs/libstdc++.so]
 137     if {$sharedlibdir != ""} {
 138         if { [string match "*-*-linux*" $target_triplet] && [isnative] } {
 139             set v3-sharedlib 1
 140             verbose -log "shared library support detected"
 141         }
 142     }
 143     v3track v3-sharedlib 3
 144
 145     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 146     if {$gccdir != ""} {
 147         set ld_library_path ""
 148         append ld_library_path ":${gccdir}"
 149         set compiler ${gccdir}/g++
 150         append ld_library_path ":${blddir}/src/.libs"
 151
 152         if { [is_remote host] == 0 && [which $compiler] != 0 } {
 153           foreach i "[exec $compiler --print-multi-lib]" {
 154             set mldir ""
 155             regexp -- "\[a-z0-9=_/\.-\]*;" $i mldir
 156             set mldir [string trimright $mldir "\;@"]
 157             if { "$mldir" == "." } {
 158               continue
 159             }
 160             if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 161               append ld_library_path ":${gccdir}/${mldir}"
 162             }
 163           }
 164         }
 165
 166         set_ld_library_path_env_vars
 167         if [info exists env(LD_LIBRARY_PATH)] {
 168           verbose -log "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
 169         }
 170     } else {
 171         set compiler [transform "g++"]
 172     }
 173
 174     # Do a bunch of handstands and backflips for cross compiling and
 175     # finding simulators...
 176     if [is_remote host] {
 177         set header [remote_download host ${blddir}/testsuite/util/testsuite_hooks.h]
 178         if { $header == "" } {
 179             verbose -log "Unable to download ${blddir}/testsuite/util/testsuite_hooks.h to host."
 180             return "untested"
 181         }
 182       set cxx [transform "g++"]
 183       set cxxflags "-ggdb3"
 184       set cxxldflags ""
 185       set includes "-I./"
 186     } else {
 187         # If we find a testsuite_flags file, we're testing in the build dir.
 188         if { [file exists $flags_file] } {
 189             set cxx [exec sh $flags_file --build-cxx]
 190             set cxxflags [exec sh $flags_file --cxxflags]
 191             set cxxldflags [exec sh $flags_file --cxxldflags]
 192             set includes [exec sh $flags_file --build-includes]
 193         } else {
 194             set cxx [transform "g++"]
 195             set cxxldflags ""
 196             set cxxflags "-g -O2 -D_GLIBCXX_ASSERT -fmessage-length=0"
 197             set includes "-I${srcdir}/util"
 198         }
 199     }
 200
 201     # Always use MO files built by this test harness.
 202     set cxxflags "$cxxflags -DLOCALEDIR=\".\""
 203
 204     # If a PCH file is available, use it.  We must delay performing
 205     # this check until $cxx and such have been initialized because we
 206     # perform a test compilation.  (Ideally, gcc --print-file-name would
 207     # list PCH files, but it does not.)
 208     global PCH_CXXFLAGS
 209     if ![info exists PCH_CXXFLAGS] then {
 210         set src "config[pid].cc"
 211         set f [open $src "w"]
 212         puts $f "int main () {}"
 213         close $f
 214
 215         set lines [v3_target_compile $src "config[pid].o" object \
 216                  "additional_flags=-include additional_flags=bits/stdtr1c++.h"]
 217         if {$lines == "" } {
 218 #           set PCH_CXXFLAGS "-include bits/extc++.h"
 219 #           set PCH_CXXFLAGS "-include bits/stdtr1c++.h"
 220             set PCH_CXXFLAGS "-include bits/stdc++.h"
 221         } else {
 222             set PCH_CXXFLAGS ""
 223         }
 224         file delete $src
 225         v3track PCH_CXXFLAGS 2
 226     }
 227
 228     libstdc++_maybe_build_wrapper "${objdir}/testglue.o"
 229 }
 230
 231 # Callback for cleanup routines.
 232 proc libstdc++_exit { } {
 233     global gluefile;
 234
 235     if [info exists gluefile] {
 236         file_on_build delete $gluefile;
 237         unset gluefile;
 238     }
 239 }
 240
 241 # Callback from system dg-test.
 242 proc libstdc++-dg-test { prog do_what extra_tool_flags } {
 243     # Set up the compiler flags, based on what we're going to do.
 244     switch $do_what {
 245         "preprocess" {
 246             set compile_type "preprocess"
 247             set output_file "[file rootname [file tail $prog]].i"
 248         }
 249         "compile" {
 250             set compile_type "assembly"
 251             set output_file "[file rootname [file tail $prog]].s"
 252         }
 253         "assemble" {
 254             set compile_type "object"
 255             set output_file "[file rootname [file tail $prog]].o"
 256         }
 257         "link" {
 258             set compile_type "executable"
 259             set output_file "./[file rootname [file tail $prog]].exe"
 260         }
 261         "run" {
 262             set compile_type "executable"
 263             # FIXME: "./" is to cope with "." not being in $PATH.
 264             # Should this be handled elsewhere?
 265             # YES.
 266             set output_file "./[file rootname [file tail $prog]].exe"
 267             # This is the only place where we care if an executable was
 268             # created or not.  If it was, dg.exp will try to run it.
 269             catch { remote_file build delete $output_file }
 270         }
 271         default {
 272             perror "$do_what: not a valid dg-do keyword"
 273             return ""
 274         }
 275     }
 276
 277     # Short-circut a bunch of complicated goo here for the special
 278     # case of compiling a test file as a "C" file, not as C++. Why? So
 279     # -nostdc++ doesn't trip us up. So all the extra object files
 280     # don't trip us up. So automatically linking in libstdc++ doesn't
 281     # happen. So CXXFLAGS don't error.
 282     set select_compile "v3_target_compile"
 283     set options ""
 284     if { $extra_tool_flags != "" } {
 285         verbose -log "extra_tool_flags are:"
 286         verbose -log $extra_tool_flags
 287         if { [string first "-x c" $extra_tool_flags ] != -1 } {
 288             verbose -log "compiling and executing as C, not C++"
 289             set edit_tool_flags $extra_tool_flags
 290             regsub -all ".x c" $edit_tool_flags "" edit_tool_flags
 291             lappend options "additional_flags=$edit_tool_flags"
 292             set select_compile "v3_target_compile_as_c"
 293         } else {
 294             lappend options "additional_flags=$extra_tool_flags"
 295         }
 296     }
 297
 298     # There is a libstdc++_compile made for us by default (via the tool-
 299     # and-target file), but the defaults are lacking in goodness.
 300     set comp_output [$select_compile "$prog" "$output_file" "$compile_type" $options];
 301     set comp_output [ prune_g++_output $comp_output ];
 302
 303     return [list $comp_output $output_file]
 304 }
 305
 306 # True if the library supports wchar_t.
 307 set v3-wchar_t 0
 308
 309 # True if the library supports threads.
 310 set v3-threads 0
 311
 312 # True if the library supports symbol versioning.
 313 set v3-symver 0
 314
 315 # Called from libstdc++-dg-test above.  Calls back into system's
 316 # target_compile to actually do the work.
 317 proc v3_target_compile { source dest type options } {
 318     global gluefile
 319     global wrap_flags
 320     global cxx
 321     global cxxflags
 322     global cxxldflags
 323     global includes
 324
 325     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 326         lappend options "libs=${gluefile}"
 327         lappend options "ldflags=${wrap_flags}"
 328     }
 329
 330     set cxx_final $cxx
 331     set cxxlibglossflags  [libgloss_link_flags]
 332     set cxx_final [concat $cxx_final $cxxlibglossflags]
 333     set cxx_final [concat $cxx_final $cxxflags]
 334     set cxx_final [concat $cxx_final $includes]
 335
 336     # Flag setting based on type argument.
 337     if { $type == "executable" } {
 338         # Link the support objects into executables.
 339         set cxx_final [concat $cxx_final $cxxldflags]
 340         lappend options "additional_flags=./libtestc++.a"
 341     } else {
 342         if { $type == "sharedlib" } {
 343             # Don't link in anything.
 344             set type "executable"
 345         }
 346     }
 347
 348     lappend options "compiler=$cxx_final"
 349     lappend options "timeout=600"
 350
 351     return [target_compile $source $dest $type $options]
 352 }
 353
 354
 355 # Called from libstdc++-dg-test above, but only for "C" compilation.
 356 # Calls back into system's target_compile to actually do the work.
 357 proc v3_target_compile_as_c { source dest type options } {
 358     global gluefile
 359     global wrap_flags
 360     global includes
 361     global flags_file
 362     global blddir
 363
 364     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 365         lappend options "libs=${gluefile}"
 366         lappend options "ldflags=${wrap_flags}"
 367     }
 368
 369     set tname [target_info name]
 370     set cc [board_info $tname compiler]
 371     set cc_final $cc
 372     set cxxlibglossflags [libgloss_link_flags]
 373     set cc_final [concat $cc_final $cxxlibglossflags]
 374     set cc_final [concat $cc_final $includes]
 375     regsub -all ".nostdinc.." $cc_final "" cc_final
 376
 377     # This is needed for "C" tests, as this type of test may need the
 378     # C++ includes. And if we're not testing in the build directory,
 379     # the includes variable is not likely to include the necessary info.
 380     if { ![file exists $flags_file] } {
 381         set version [exec ${cc} -dumpversion]
 382         set machine [exec ${cc} -dumpmachine]
 383         set comp_base_dir [file dirname [file dirname [file dirname [file dirname [file dirname [exec ${cc} --print-prog-name=cc1]]]]]]
 384         set includesbase "${comp_base_dir}/include/c++/${version}"
 385         set includestarget "${includesbase}/${machine}"
 386         set cc_final [concat $cc_final "-I$includesbase -I$includestarget"]
 387
 388         set libsup "${comp_base_dir}/lib"
 389     } else {
 390         set libsup "${blddir}/libsupc++/.libs"
 391     }
 392
 393     set cc_final [concat $cc_final "-L$libsup"]
 394
 395     lappend options "compiler=$cc_final"
 396     lappend options "timeout=600"
 397
 398     return [target_compile $source $dest $type $options]
 399 }
 400
 401 # Build the support objects linked in with the libstdc++ tests.  In
 402 # addition, set v3-wchar_t, v3-threads, and v3-symver appropriately.
 403 proc v3-build_support { } {
 404     global srcdir
 405     global v3-wchar_t
 406     global v3-threads
 407     global v3-symver
 408     global v3-sharedlib
 409
 410     # Figure out whether or not the library supports certain features.
 411     set v3-wchar_t 0
 412     set v3-threads 0
 413     set v3-symver 0
 414     set libtest_objs ""
 415
 416     set config_src "config.cc"
 417     set f [open $config_src "w"]
 418     puts $f "#include <bits/c++config.h>"
 419     puts $f "#include <bits/gthr.h>"
 420     close $f
 421     set preprocessed [v3_target_compile $config_src "" \
 422                        preprocess "additional_flags=-dN"]
 423     if { [string first "_GLIBCXX_USE_WCHAR_T" $preprocessed] != -1 } {
 424         verbose -log "wchar_t support detected"
 425         set v3-wchar_t 1
 426     }
 427     if { [string first "_GLIBCXX_SYMVER" $preprocessed] != -1 } {
 428         verbose -log "symbol versioning support detected"
 429         set v3-symver 1
 430     }
 431     if { [string first "__GTHREADS" $preprocessed] != -1 } {
 432         verbose -log "thread support detected"
 433         set v3-threads 1
 434     }
 435
 436     # Try to build the MO files that are used by some of the locale
 437     # tests.  If we can't build them, that's OK; it just means that
 438     # those tests will fail.
 439     foreach lang [list "fr" "de"] {
 440         catch {
 441             file mkdir "$lang/LC_MESSAGES"
 442             remote_exec "build" "msgfmt" "-o $lang/LC_MESSAGES/libstdc++.mo $srcdir/../po/$lang.po"
 443             if [is_remote host] {
 444                 remote_exec "host" "mkdir" "-p $lang/LC_MESSAGES"
 445                 remote_download "host" "$lang/LC_MESSAGES/libstdc++.mo" "$lang/LC_MESSAGES/libstdc++.mo"
 446             }
 447         }
 448     }
 449
 450     # Build the support objects.
 451     set source_files [list testsuite_abi.cc testsuite_allocator.cc \
 452                           testsuite_character.cc testsuite_hooks.cc \
 453                  rng/twister_rand_gen.cc io/verified_cmd_line_input.cc \
 454                           io/prog_bar.cc performance/time/elapsed_timer.cc ]
 455     foreach f $source_files {
 456         set obj [file rootname $f].o
 457         set object_file [file tail $obj]
 458         # Compile with "-w" so that warnings issued by the compiler
 459         # do not prevent compilation.
 460         if { [v3_target_compile $srcdir/util/$f $object_file "object" \
 461                   [list "incdir=$srcdir" "additional_flags=-w"]]
 462              != "" } {
 463             error "could not compile $f"
 464         }
 465         append libtest_objs "$object_file "
 466     }
 467
 468     # Collect into libtestc++.a
 469     set arcommand "ar -rc ./libtestc++.a ${libtest_objs}"
 470     set result [lindex [local_exec "$arcommand" "" "" 300] 0]
 471     verbose "link result is $result"
 472     if { $result == 0 } {
 473         set ranlibcommand "ranlib ./libtestc++.a"
 474         set result [lindex [local_exec "$ranlibcommand" "" "" 300] 0]
 475         if { $result != 0 } {
 476             error "could not link libtestc++.a"
 477         }
 478     }
 479
 480     # Build any shared objects needed for regression testing.
 481     if { ${v3-sharedlib} == 1 } {
 482         set source_files [list testsuite_shared.cc]
 483         foreach f $source_files {
 484             set object_file [file rootname $f].so
 485             # Compile with "-w" so that warnings issued by the compiler
 486             # do not prevent compilation.
 487             if { [v3_target_compile $srcdir/util/$f $object_file "sharedlib" \
 488              [list "incdir=$srcdir" "additional_flags=-w -shared -fPIC -DPIC"]]
 489                  != "" } {
 490                 error "could not compile $f"
 491             }
 492         }
 493     }
 494 }
 495
 496 proc check_v3_target_sharedlib { } {
 497     global v3-sharedlib
 498     return ${v3-sharedlib}
 499 }
 500
 501 proc check_v3_target_namedlocale { } {
 502     global et_namedlocale_saved
 503     global et_namedlocale_target_name
 504     global tool
 505
 506     if { ![info exists et_namedlocale_target_name] } {
 507         set et_namedlocale_target_name ""
 508     }
 509
 510     # If the target has changed since we set the cached value, clear it.
 511     set current_target [current_target_name]
 512     if { $current_target != $et_namedlocale_target_name } {
 513         verbose "check_v3_target_namedlocale: `$et_namedlocale_target_name'" 2
 514         set et_namedlocale_target_name $current_target
 515         if [info exists et_namedlocale_saved] {
 516             verbose "check_v3_target_namedlocale: removing cached result" 2
 517             unset et_namedlocale_saved
 518         }
 519     }
 520
 521     if [info exists et_namedlocale_saved] {
 522         verbose "check_v3_target_namedlocale: using cached result" 2
 523     } else {
 524         set et_namedlocale_saved 0
 525
 526         # Set up, compile, and execute a C++ test program that tries to use
 527         # all the required named locales.
 528         set src nlocale[pid].cc
 529         set exe nlocale[pid].x
 530
 531         set f [open $src "w"]
 532         puts $f "#include <locale>"
 533         puts $f "using namespace std;"
 534         puts $f "int main ()"
 535         puts $f "{"
 536         puts $f "  try"
 537         puts $f "  {"
 538         puts $f "     locale(\"\");"
 539         puts $f "     locale(\"de_DE\");"
 540         puts $f "     locale(\"de_DE.ISO-8859-15@euro\");"
 541         puts $f "     locale(\"de_DE@euro\");"
 542         puts $f "     locale(\"en_HK\");"
 543         puts $f "     locale(\"en_PH\");"
 544         puts $f "     locale(\"en_US\");"
 545         puts $f "     locale(\"en_US.ISO-8859-1\");"
 546         puts $f "     locale(\"en_US.ISO-8859-15\");"
 547         puts $f "     locale(\"en_US.UTF-8\");"
 548         puts $f "     locale(\"es_ES\");"
 549         puts $f "     locale(\"es_MX\");"
 550         puts $f "     locale(\"fr_FR\");"
 551         puts $f "     locale(\"fr_FR@euro\");"
 552         puts $f "     locale(\"is_IS\");"
 553         puts $f "     locale(\"is_IS.UTF-8\");"
 554         puts $f "     locale(\"it_IT\");"
 555         puts $f "     locale(\"ja_JP.eucjp\");"
 556         puts $f "     locale(\"se_NO.UTF-8\");"
 557         puts $f "     locale(\"ta_IN\");"
 558         puts $f "     locale(\"zh_TW\");"
 559         puts $f "     return 0;"
 560         puts $f "  }"
 561         puts $f "  catch(...)"
 562         puts $f "  {"
 563         puts $f "     return 1;"
 564         puts $f "  }"
 565         puts $f "}"
 566         close $f
 567
 568         set lines [v3_target_compile $src $exe executable ""]
 569         file delete $src
 570
 571         if [string match "" $lines] {
 572             # No error message, compilation succeeded.
 573             set result [${tool}_load "./$exe" "" ""]
 574             set status [lindex $result 0]
 575             remote_file build delete $exe
 576
 577             verbose "check_v3_target_namedlocale: status is <$status>" 2
 578
 579             if { $status == "pass" } {
 580                 set et_namedlocale_saved 1
 581             }
 582         } else {
 583             verbose "check_v3_target_namedlocale: compilation failed" 2
 584         }
 585     }
 586     return $et_namedlocale_saved
 587 }
 588
 589 proc check_v3_target_debug_mode { } {
 590     global cxxflags
 591     global et_debug_mode
 592
 593     global tool
 594
 595     if { ![info exists et_debug_mode_target_name] } {
 596         set et_debug_mode_target_name ""
 597     }
 598
 599     # If the target has changed since we set the cached value, clear it.
 600     set current_target [current_target_name]
 601     if { $current_target != $et_debug_mode_target_name } {
 602         verbose "check_v3_target_debug_mode: `$et_debug_mode_target_name'" 2
 603         set et_debug_mode_target_name $current_target
 604         if [info exists et_debug_mode] {
 605             verbose "check_v3_target_debug_mode: removing cached result" 2
 606             unset et_debug_mode
 607         }
 608     }
 609
 610     if [info exists et_debug_mode] {
 611         verbose "check_v3_target_debug_mode: using cached result" 2
 612     } else {
 613         set et_debug_mode 0
 614
 615         # Set up, compile, and execute a C++ test program that depends
 616         # on debug mode working.
 617         set src debug_mode[pid].cc
 618         set exe debug_mode[pid].exe
 619
 620         set f [open $src "w"]
 621         puts $f "#include <string>"
 622         puts $f "using namespace std;"
 623         puts $f "int main()"
 624         puts $f "{ return 0; }"
 625         close $f
 626
 627         set cxxflags_saved $cxxflags
 628         set cxxflags "$cxxflags -Werror -O0 -D_GLIBCXX_DEBUG"
 629         set lines [v3_target_compile $src $exe executable ""]
 630         set cxxflags $cxxflags_saved
 631         file delete $src
 632
 633         if [string match "" $lines] {
 634             # No error message, compilation succeeded.
 635             set et_debug_mode 1
 636         }
 637     }
 638     verbose "check_v3_target_debug_mode: $et_debug_mode" 2
 639     return $et_debug_mode
 640 }