libstdc++-v3/testsuite/lib/libstdc++.exp

   1 # libstdc++ "tool init file" for DejaGNU
   2
   3 # Copyright (C) 2001, 2002, 2003, 2004 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  18
  19
  20 # Define callbacks and load other libraries.  This file is loaded relatively
  21 # early, and before any other file we write ourselves.  "load_lib" will
  22 # find anything in the DejaGNU installation tree, or in our lib directory.
  23 # "load_gcc_lib" will search the core compiler's .exp collection instead.
  24 #
  25 # The naming rule is that dg.exp looks for "tool-" and runtest.exp looks
  26 # for "tool_" when finding callbacks.  Utility routines we define for
  27 # our callbacks begin with "v3-".
  28 #
  29 # libstdc++_* callbacks we don't define, but could:
  30 # ..._option_help           prints additional --help output
  31 # ..._option_proc (--foo)   process our own options
  32 # ..._init (normal.exp)     called once per test file
  33 # ..._finish                bracketing function for libstdc++_init
  34 # ...-dg-prune              removing output text, see top of system dg.exp
  35 #
  36 # Useful hook:  if ${hostname}_init exists, it will be called, almost
  37 # the last thing before testing begins.  This can be defined in, e.g.,
  38 # ~/.dejagnurc or $DEJAGNU.
  39
  40 proc load_gcc_lib { filename } {
  41     global srcdir
  42     load_file $srcdir/../../gcc/testsuite/lib/$filename
  43 }
  44
  45 # system routines
  46 load_lib dg.exp
  47 load_lib libgloss.exp
  48 # compiler routines, then ours
  49 load_gcc_lib target-supports.exp
  50 load_lib prune.exp
  51 load_lib dg-options.exp
  52 load_gcc_lib wrapper.exp
  53
  54 # Useful for debugging.  Pass the name of a variable and the verbosity
  55 # threshold (number of -v's on the command line).
  56 proc v3track { var n } {
  57     upvar $var val
  58     verbose "++ $var is $val" $n
  59 }
  60
  61 # Called by v3-init below.  "Static" to this file.
  62 proc v3-copy-files {srcfiles} {
  63     foreach f $srcfiles {
  64         if { [catch { set symlink [file readlink $f] } x] } then {
  65             remote_download target $f
  66         } else {
  67             if { [regexp "^/" "$symlink"] } then {
  68                 remote_download target $symlink
  69             } else {
  70                 set dirname [file dirname $f]
  71                 remote_download target $dirname/$symlink
  72             }
  73         }
  74     }
  75 }
  76
  77 # Called once, during runtest.exp setup.
  78 proc libstdc++_init { testfile } {
  79     global env
  80     global srcdir blddir objdir tool_root_dir
  81     global cxx cxxflags
  82     global includes
  83     global gluefile wrap_flags
  84     global original_ld_library_path
  85     global target_triplet
  86
  87     # We set LC_ALL and LANG to C so that we get the same error messages as expected.
  88     setenv LC_ALL C
  89     setenv LANG C
  90
  91     set blddir [lookfor_file [get_multilibs] libstdc++-v3]
  92     set flags_file "${blddir}/scripts/testsuite_flags"
  93     v3track flags_file 2
  94
  95     # If a test doesn't have special options, use DEFAULT_CXXFLAGS.
  96     # Use this variable if the behavior
  97     #   1) only applies to libstdc++ testing
  98     #   2) might need to be negated
  99     # In particular, some tests have to be run without precompiled
 100     # headers, or without assertions.
 101     global DEFAULT_CXXFLAGS
 102     if ![info exists DEFAULT_CXXFLAGS] then {
 103         # Set up includes for stdc++.h.gch, the precompiled header file.
 104         if { [file exists $flags_file] } {
 105             set cxxpchflags [exec sh $flags_file --cxxpchflags]
 106         } else {
 107             set cxxpchflags ""
 108         }
 109         set DEFAULT_CXXFLAGS " ${cxxpchflags}"
 110
 111         # Host specific goo here.
 112         if { [string match "powerpc-*-darwin*" $target_triplet] } {
 113             append DEFAULT_CXXFLAGS " -multiply_defined suppress"
 114         }
 115     }
 116     v3track DEFAULT_CXXFLAGS 2
 117
 118     # By default, we assume we want to run program images.
 119     global dg-do-what-default
 120     set dg-do-what-default run
 121
 122     # Copy any required data files.
 123     v3-copy-files [glob -nocomplain "$srcdir/data/*.tst"]
 124     v3-copy-files [glob -nocomplain "$srcdir/data/*.txt"]
 125
 126     # Setup LD_LIBRARY_PATH so that libgcc_s, libstdc++ binaries can be found.
 127     # Find the existing LD_LIBRARY_PATH.
 128     if [info exists env(LD_LIBRARY_PATH)] {
 129         set original_ld_library_path $env(LD_LIBRARY_PATH)
 130         # For HP-UX
 131     } elseif [info exists env(SHLIB_PATH)] {
 132         set original_ld_library_path $env(SHLIB_PATH)
 133         # For Darwin:
 134     } elseif [info exists env(DYLD_LIBRARY_PATH)] {
 135         set original_ld_library_path $env(DYLD_LIBRARY_PATH)
 136         # For Solaris 32 bit:
 137     } elseif [info exists env(LD_LIBRARY_PATH_32)] {
 138         set original_ld_library_path $env(LD_LIBRARY_PATH_32)
 139         # For Solaris 64 bit:
 140     } elseif [info exists env(LD_LIBRARY_PATH_64)] {
 141         set original_ld_library_path $env(LD_LIBRARY_PATH_64)
 142     } else {
 143         set original_ld_library_path ""
 144     }
 145
 146     # Locate libgcc.a so we don't need to account for different values of
 147     # SHLIB_EXT on different platforms
 148     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
 149     if {$gccdir != ""} {
 150         set gccdir [file dirname $gccdir]
 151     }
 152     v3track gccdir 3
 153
 154     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
 155     set ld_library_path ""
 156     append ld_library_path ":${gccdir}"
 157     set compiler ${gccdir}/g++
 158     if { [is_remote host] == 0 && [which $compiler] != 0 } {
 159       foreach i "[exec $compiler --print-multi-lib]" {
 160         set mldir ""
 161         regexp -- "\[a-z0-9=/\.-\]*;" $i mldir
 162         set mldir [string trimright $mldir "\;@"]
 163         if { "$mldir" == "." } {
 164           continue
 165         }
 166         if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
 167           append ld_library_path ":${gccdir}/${mldir}"
 168         }
 169       }
 170     }
 171     append ld_library_path ":${blddir}/src/.libs"
 172
 173     # On IRIX 6, we have to set variables akin to LD_LIBRARY_PATH, but
 174     # called LD_LIBRARYN32_PATH (for the N32 ABI) and LD_LIBRARY64_PATH
 175     # (for the 64-bit ABI).  The right way to do this would be to modify
 176     # unix.exp -- but that's not an option since it's part of DejaGNU
 177     # proper, so we do it here.
 178     # The same applies to darwin (DYLD_LIBRARY_PATH), solaris 32 bit
 179     # (LD_LIBRARY_PATH_32), solaris 64 bit (LD_LIBRARY_PATH_64), and HP-UX
 180     # (SHLIB_PATH).
 181     setenv  LD_LIBRARY_PATH     "$ld_library_path:$original_ld_library_path"
 182     setenv  SHLIB_PATH          "$ld_library_path:$original_ld_library_path"
 183     setenv  LD_LIBRARYN32_PATH  "$ld_library_path:$original_ld_library_path"
 184     setenv  LD_LIBRARY64_PATH   "$ld_library_path:$original_ld_library_path"
 185     setenv  LD_RUN_PATH         "$ld_library_path:$original_ld_library_path"
 186     setenv  LD_LIBRARY_PATH_32  "$ld_library_path:$original_ld_library_path"
 187     setenv  LD_LIBRARY_PATH_64  "$ld_library_path:$original_ld_library_path"
 188     setenv  DYLD_LIBRARY_PATH   "$ld_library_path:$original_ld_library_path"
 189     verbose -log "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
 190
 191     # Do a bunch of handstands and backflips for cross compiling and
 192     # finding simulators...
 193     if [is_remote host] {
 194         set header [remote_download host ${blddir}/testsuite/testsuite_hooks.h]
 195         if { $header == "" } {
 196             verbose -log "Unable to download ${blddir}/testsuite/testsuite_hooks.h to host."
 197             return "untested"
 198         }
 199       set cxx [transform "g++"]
 200       set cxxflags "-ggdb3"
 201       set includes "-I./"
 202     } else {
 203         # If we find a testsuite_flags file, we're testing in the build dir.
 204         if { [file exists $flags_file] } {
 205             set cxx [exec sh $flags_file --build-cxx]
 206             set cxxflags [exec sh $flags_file --cxxflags]
 207             set includes [exec sh $flags_file --build-includes]
 208         } else {
 209             set cxx [transform "g++"]
 210             set cxxflags "-ggdb3"
 211             set includes "-I${srcdir}"
 212         }
 213     }
 214
 215     libstdc++_maybe_build_wrapper "${objdir}/testglue.o"
 216 }
 217
 218 # Callback for cleanup routines.
 219 proc libstdc++_exit { } {
 220     global gluefile;
 221
 222     if [info exists gluefile] {
 223         file_on_build delete $gluefile;
 224         unset gluefile;
 225     }
 226 }
 227
 228 # Callback from system dg-test.
 229 proc libstdc++-dg-test { prog do_what extra_tool_flags } {
 230     # Set up the compiler flags, based on what we're going to do.
 231     switch $do_what {
 232         "preprocess" {
 233             set compile_type "preprocess"
 234             set output_file "[file rootname [file tail $prog]].i"
 235         }
 236         "compile" {
 237             set compile_type "assembly"
 238             set output_file "[file rootname [file tail $prog]].s"
 239         }
 240         "assemble" {
 241             set compile_type "object"
 242             set output_file "[file rootname [file tail $prog]].o"
 243         }
 244         "link" {
 245             set compile_type "executable"
 246             set output_file "./[file rootname [file tail $prog]].exe"
 247         }
 248         "run" {
 249             set compile_type "executable"
 250             # FIXME: "./" is to cope with "." not being in $PATH.
 251             # Should this be handled elsewhere?
 252             # YES.
 253             set output_file "./[file rootname [file tail $prog]].exe"
 254             # This is the only place where we care if an executable was
 255             # created or not.  If it was, dg.exp will try to run it.
 256             remote_file build delete $output_file;
 257         }
 258         default {
 259             perror "$do_what: not a valid dg-do keyword"
 260             return ""
 261         }
 262     }
 263     set options ""
 264     if { $extra_tool_flags != "" } {
 265         lappend options "additional_flags=$extra_tool_flags"
 266     }
 267
 268     # There is a libstdc++_compile made for us by default (via the tool-
 269     # and-target file), but the defaults are lacking in goodness.
 270     set comp_output [v3_target_compile "$prog" "$output_file" "$compile_type" $options];
 271     set comp_output [ prune_g++_output $comp_output ];
 272
 273     return [list $comp_output $output_file]
 274 }
 275
 276 # Called from libstdc++-dg-test above.  Calls back into system's
 277 # target_compile to actually do the work.
 278 proc v3_target_compile { source dest type options } {
 279     global gluefile
 280     global wrap_flags
 281     global cxx
 282     global cxxflags
 283     global includes
 284     global blddir
 285
 286     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
 287         lappend options "libs=${gluefile}"
 288         lappend options "ldflags=${wrap_flags}"
 289     }
 290
 291     set cxx_final $cxx
 292     set cxxlibglossflags  [libgloss_link_flags]
 293     set cxx_final [concat $cxx_final $cxxlibglossflags]
 294     set cxx_final [concat $cxx_final $cxxflags]
 295     set cxx_final [concat $cxx_final $includes]
 296
 297     lappend options "compiler=$cxx_final"
 298
 299     # Picks up the freshly-built testsuite library corresponding to the
 300     # multilib under test.
 301     lappend options "ldflags=-L${blddir}/testsuite"
 302     lappend options "libs=-lv3test"
 303
 304     return [target_compile $source $dest $type $options]
 305 }
 306
 307
 308 # Called once, from libstdc++/normal.exp.
 309 proc v3-list-tests { filename } {
 310     global srcdir
 311     global blddir
 312
 313     set tests_file "${blddir}/testsuite/${filename}"
 314     set sfiles ""
 315
 316     verbose -log "In v3-list-tests"
 317     verbose -log "blddir = ${blddir}"
 318     verbose -log "tests_file = $tests_file"
 319
 320     # If there is a testsuite_file, use it.
 321     if { [file exists $tests_file] } {
 322         set f [open $tests_file]
 323         while { ! [eof $f] } {
 324             set t [gets $f]
 325             if { [string length "$t"] != 0 } {
 326                 lappend sfiles  ${srcdir}/${t}
 327             }
 328         }
 329         close $f
 330     } else {
 331         verbose "cannot open $tests_file"
 332     }
 333     return $sfiles
 334 }