OSDN Git Service

b482bf58d2054bcad008b695672f4fedc19e6f43
[pf3gnuchains/gcc-fork.git] / libstdc++-v3 / testsuite / lib / libstdc++.exp
1 # libstdc++ "tool init file" for DejaGNU
2
3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007
4 # Free Software Foundation, Inc.
5 #
6 # This program is free software; you can redistribute it and/or modify
7 # it under the terms of the GNU General Public License as published by
8 # the Free Software Foundation; either version 2 of the License, or
9 # (at your option) any later version.
10
11 # This program is distributed in the hope that it will be useful,
12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
14 # GNU General Public License for more details.
15
16 # You should have received a copy of the GNU General Public License
17 # along with this program; if not, write to the Free Software
18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
19 # 02110-1301, USA.
20
21
22 # Define callbacks and load other libraries.  This file is loaded relatively
23 # early, and before any other file we write ourselves.  "load_lib" will
24 # find anything in the DejaGNU installation tree, or in our lib directory.
25 # "load_gcc_lib" will search the core compiler's .exp collection instead.
26 #
27 # The naming rule is that dg.exp looks for "tool-" and runtest.exp looks
28 # for "tool_" when finding callbacks.  Utility routines we define for
29 # our callbacks begin with "v3-".
30 #
31 # libstdc++_* callbacks we don't define, but could:
32 # ..._option_help           prints additional --help output
33 # ..._option_proc (--foo)   process our own options
34 # ..._init (normal.exp)     called once per test file
35 # ..._finish                bracketing function for libstdc++_init
36 # ...-dg-prune              removing output text, see top of system dg.exp
37 #
38 # Useful hook:  if ${hostname}_init exists, it will be called, almost
39 # the last thing before testing begins.  This can be defined in, e.g.,
40 # ~/.dejagnurc or $DEJAGNU.
41
42 proc load_gcc_lib { filename } {
43     global srcdir
44     load_file $srcdir/../../gcc/testsuite/lib/$filename
45 }
46
47 # system routines
48 load_lib dg.exp
49 load_lib libgloss.exp
50 # compiler routines, then ours
51 load_gcc_lib target-supports.exp
52 load_gcc_lib target-supports-dg.exp
53 load_lib prune.exp
54 load_lib dg-options.exp
55 load_gcc_lib target-libpath.exp
56 load_gcc_lib wrapper.exp
57
58 # Useful for debugging.  Pass the name of a variable and the verbosity
59 # threshold (number of -v's on the command line).
60 proc v3track { var n } {
61     upvar $var val
62     verbose "++ $var is $val" $n
63 }
64
65 # Called by v3-init below.  "Static" to this file.
66 proc v3-copy-files {srcfiles} {
67     foreach f $srcfiles {
68         if { [catch { set symlink [file readlink $f] } x] } then {
69             remote_download target $f
70         } else {
71             if { [regexp "^/" "$symlink"] } then {
72                 remote_download target $symlink
73             } else {
74                 set dirname [file dirname $f]
75                 remote_download target $dirname/$symlink
76             }
77         }
78     }
79 }
80
81 # Called once, during runtest.exp setup.
82 proc libstdc++_init { testfile } {
83     global env
84     global v3-sharedlib 
85     global srcdir blddir objdir tool_root_dir
86     global cc cxx cxxflags cxxpchflags cxxldflags
87     global includes
88     global gluefile wrap_flags
89     global ld_library_path
90     global target_triplet
91     global flags_file
92
93     # We set LC_ALL and LANG to C so that we get the same error
94     # messages as expected.
95     setenv LC_ALL C
96     setenv LANG C
97
98     set blddir [lookfor_file [get_multilibs] libstdc++-v3]
99     set flags_file "${blddir}/scripts/testsuite_flags"
100     v3track flags_file 2
101
102     # If a test doesn't have special options, use DEFAULT_CXXFLAGS.
103     # Use this variable if the behavior
104     #   1) only applies to libstdc++ testing
105     #   2) might need to be negated 
106     # In particular, some tests have to be run without precompiled
107     # headers, or without assertions.
108     global DEFAULT_CXXFLAGS
109     if ![info exists DEFAULT_CXXFLAGS] then {
110         set DEFAULT_CXXFLAGS ""
111         # Host specific goo here.
112         if { [string match "powerpc-*-darwin*" $target_triplet] } {
113             append DEFAULT_CXXFLAGS " -multiply_defined suppress"
114         } 
115     }
116     v3track DEFAULT_CXXFLAGS 2
117
118     # By default, we assume we want to run program images.
119     global dg-do-what-default
120     set dg-do-what-default run
121
122     # Copy any required data files.
123     v3-copy-files [glob -nocomplain "$srcdir/data/*.tst"]
124     v3-copy-files [glob -nocomplain "$srcdir/data/*.txt"]
125
126     set ld_library_path_tmp ""
127
128     # Locate libgcc.a so we don't need to account for different values of
129     # SHLIB_EXT on different platforms
130     set gccdir [lookfor_file $tool_root_dir gcc/libgcc.a]
131     if {$gccdir != ""} {
132         set gccdir [file dirname $gccdir]
133         append ld_library_path_tmp ":${gccdir}"
134     }
135     v3track gccdir 3
136
137     # Locate libgomp. This is only required for parallel mode.
138     set libgompdir [lookfor_file $blddir/../libgomp .libs/libgomp.so]
139     if {$libgompdir != ""} {
140         set libgompdir [file dirname $libgompdir]
141         append ld_library_path_tmp ":${libgompdir}"
142     }
143     v3track libgompdir 3
144
145     # Locate libstdc++ shared library. (ie libstdc++.so.)
146     set v3-sharedlib 0
147     set sharedlibdir [lookfor_file $blddir src/.libs/libstdc++.so]
148     if {$sharedlibdir != ""} {
149         if { [string match "*-*-linux*" $target_triplet] && [isnative] } {
150             set v3-sharedlib 1
151             verbose -log "shared library support detected"
152         } 
153     }
154     v3track v3-sharedlib 3
155
156     # Compute what needs to be added to the existing LD_LIBRARY_PATH.
157     if {$gccdir != ""} {
158         set compiler ${gccdir}/g++
159         set ld_library_path ${ld_library_path_tmp}
160         append ld_library_path ":${blddir}/src/.libs"
161
162         if { [is_remote host] == 0 && [which $compiler] != 0 } {
163           foreach i "[exec $compiler --print-multi-lib]" {
164             set mldir ""
165             regexp -- "\[a-z0-9=_/\.-\]*;" $i mldir
166             set mldir [string trimright $mldir "\;@"]
167             if { "$mldir" == "." } {
168               continue
169             }
170             if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.so.*]] >= 1 } {
171               append ld_library_path ":${gccdir}/${mldir}"
172             }
173           }
174         }
175
176         set_ld_library_path_env_vars
177         if [info exists env(LD_LIBRARY_PATH)] {
178           verbose -log "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
179         }
180     } else {
181         set compiler [transform "g++"]
182     }
183
184     # Default settings.
185     set cxx [transform "g++"]
186     set cxxflags "-g -O2 -D_GLIBCXX_ASSERT -fmessage-length=0"
187     set cxxpchflags ""
188     set cxxldflags ""
189     set cc [transform "gcc"]
190     # Locate testsuite_hooks.h and other testsuite headers.
191     set includes "-I${srcdir}/util"
192     # Adapt the defaults for special circumstances.
193     if [is_remote host] {
194         # A remote host does not, in general, have access to the
195         # $srcdir so we copy the testsuite headers into the current
196         # directory, and then add that to the search path.
197         foreach src [glob "${srcdir}/util/*.h" \
198                           "${srcdir}/util/*.cc" \
199                           "${srcdir}/util/*/*.hpp" \
200                           "${srcdir}/util/*/*.cc" \
201                           "${srcdir}/util/*/*.hpp" \
202                           "${srcdir}/util/*/*/*.cc" \
203                           "${srcdir}/util/*/*/*.hpp" \
204                           "${srcdir}/util/*/*/*/*.cc" \
205                           "${srcdir}/util/*/*/*/*.hpp" \
206                           "${srcdir}/util/*/*/*/*/*.cc" \
207                           "${srcdir}/util/*/*/*/*/*.hpp" ] {
208             # Remove everything up to "util/..."
209             set dst [string range $src [string length "${srcdir}/"] end]
210             # Create the directory containing the file.
211             set dir [file dirname $dst]
212             remote_exec host "mkdir" [list "-p" "$dir"]
213             # Download the file.
214             set result [remote_download host $src $dst]
215             if { $result == "" } {
216                 verbose -log "Unable to download ${srcdir}/${src} to host."
217                 return "untested"
218             }
219         }
220         set includes "-Iutil"
221     } elseif { [file exists $flags_file] } {
222         # If we find a testsuite_flags file, we're testing in the build dir.
223         set cxx [exec sh $flags_file --build-cxx]
224         set cxxflags [exec sh $flags_file --cxxflags]
225         set cxxpchflags [exec sh $flags_file --cxxpchflags]
226         set cxxldflags [exec sh $flags_file --cxxldflags]
227         set cc [exec sh $flags_file --build-cc]
228         set includes [exec sh $flags_file --build-includes]
229     }
230     append cxxflags " "
231     append cxxflags [getenv CXXFLAGS]
232     v3track cxxflags 2
233
234     # Always use MO files built by this test harness.
235     set cxxflags "$cxxflags -DLOCALEDIR=\".\""
236     set ccflags "$cxxflags -DLOCALEDIR=\".\""
237
238     # If a PCH file is available, use it.  We must delay performing
239     # this check until $cxx and such have been initialized because we
240     # perform a test compilation.  (Ideally, gcc --print-file-name would
241     # list PCH files, but it does not.)
242     if { $cxxpchflags != "" } {
243         set src "config[pid].cc"
244         set f [open $src "w"]
245         puts $f "int main () {}"
246         close $f
247
248         # Fixme: "additional_flags=$cxxpchflags" fails, but would be
249         # useful as then the requested variant of the pre-build PCH
250         # files could be tested to see if it works.
251         set lines [v3_target_compile $src "config[pid].o" object \
252                    "additional_flags=-include additional_flags=bits/stdc++.h"]
253         if { $lines != "" } {
254             verbose -log "Requested PCH file: $cxxpchflags"
255             verbose -log "is not working, and will not be used."
256             set cxxpchflags ""
257         } 
258         file delete $src
259      } 
260     v3track cxxpchflags 2
261
262     global PCH_CXXFLAGS
263     if ![info exists PCH_CXXFLAGS] then {
264         set PCH_CXXFLAGS $cxxpchflags
265         v3track PCH_CXXFLAGS 2
266     }
267
268     libstdc++_maybe_build_wrapper "${objdir}/testglue.o" "-fexceptions"
269 }
270
271 # Callback for cleanup routines.
272 proc libstdc++_exit { } {
273     global gluefile;
274
275     if [info exists gluefile] {
276         file_on_build delete $gluefile;
277         unset gluefile;
278     }
279 }
280
281 # Callback from system dg-test.
282 proc libstdc++-dg-test { prog do_what extra_tool_flags } {
283     # Set up the compiler flags, based on what we're going to do.
284     switch $do_what {
285         "preprocess" {
286             set compile_type "preprocess"
287             set output_file "[file rootname [file tail $prog]].i"
288         }
289         "compile" {
290             set compile_type "assembly"
291             set output_file "[file rootname [file tail $prog]].s"
292         }
293         "assemble" {
294             set compile_type "object"
295             set output_file "[file rootname [file tail $prog]].o"
296         }
297         "link" {
298             set compile_type "executable"
299             set output_file "./[file rootname [file tail $prog]].exe"
300         }
301         "run" {
302             set compile_type "executable"
303             # FIXME: "./" is to cope with "." not being in $PATH.
304             # Should this be handled elsewhere?
305             # YES.
306             set output_file "./[file rootname [file tail $prog]].exe"
307             # This is the only place where we care if an executable was
308             # created or not.  If it was, dg.exp will try to run it.
309             catch { remote_file build delete $output_file }
310         }
311         default {
312             perror "$do_what: not a valid dg-do keyword"
313             return ""
314         }
315     }
316
317     # Short-circut a bunch of complicated goo here for the special
318     # case of compiling a test file as a "C" file, not as C++. Why? So
319     # -nostdc++ doesn't trip us up. So all the extra object files
320     # don't trip us up. So automatically linking in libstdc++ doesn't
321     # happen. So CXXFLAGS don't error.
322     set select_compile "v3_target_compile"
323     set options ""
324     if { $extra_tool_flags != "" } {
325         verbose -log "extra_tool_flags are:"
326         verbose -log $extra_tool_flags
327         if { [string first "-x c" $extra_tool_flags ] != -1 } {
328             verbose -log "compiling and executing as C, not C++"
329             set edit_tool_flags $extra_tool_flags
330             regsub -all ".x c" $edit_tool_flags "" edit_tool_flags
331             lappend options "additional_flags=$edit_tool_flags"
332             set select_compile "v3_target_compile_as_c"
333         } else {
334             lappend options "additional_flags=$extra_tool_flags"
335         }
336     }
337
338     # There is a libstdc++_compile made for us by default (via the tool-
339     # and-target file), but the defaults are lacking in goodness.
340     set comp_output [$select_compile "$prog" "$output_file" "$compile_type" $options];
341     set comp_output [ prune_g++_output $comp_output ];
342
343     return [list $comp_output $output_file]
344 }
345
346 # True if the library supports wchar_t.
347 set v3-wchar_t 0
348
349 # True if the library supports threads.
350 set v3-threads 0
351
352 # True if the library supports symbol versioning.
353 set v3-symver 0
354
355 # Called from libstdc++-dg-test above.  Calls back into system's
356 # target_compile to actually do the work.
357 proc v3_target_compile { source dest type options } {
358     global gluefile 
359     global wrap_flags
360     global cxx
361     global cxxflags
362     global cxxldflags
363     global includes
364
365     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
366         lappend options "libs=${gluefile}"
367         lappend options "ldflags=${wrap_flags}"
368     }
369
370     set cxx_final $cxx
371     set cxxlibglossflags  [libgloss_link_flags]
372     set cxx_final [concat $cxx_final $cxxlibglossflags]
373     set cxx_final [concat $cxx_final $cxxflags]
374     set cxx_final [concat $cxx_final $includes]
375
376     # Flag setting based on type argument.
377     if { $type == "executable" } {
378         # Link the support objects into executables.
379         set cxx_final [concat $cxx_final $cxxldflags]
380         lappend options "additional_flags=./libtestc++.a"
381     } else {
382         if { $type == "sharedlib" } {
383             # Don't link in anything.
384             set type "executable"
385         }
386     }
387
388     lappend options "compiler=$cxx_final"
389     lappend options "timeout=600"
390
391     return [target_compile $source $dest $type $options]
392 }
393
394
395 # Called from libstdc++-dg-test above, but only for "C" compilation.
396 # Calls back into system's target_compile to actually do the work.
397 proc v3_target_compile_as_c { source dest type options } {
398     global gluefile 
399     global wrap_flags
400     global includes
401     global flags_file
402     global blddir
403     global cc
404     global cxxflags
405
406     if { [target_info needs_status_wrapper] != "" && [info exists gluefile] } {
407         lappend options "libs=${gluefile}"
408         lappend options "ldflags=${wrap_flags}"
409     }
410
411     set tname [target_info name]
412     set cc_final $cc
413     set cxxlibglossflags [libgloss_link_flags]
414     set cc_final [concat $cc_final $cxxlibglossflags]
415     set cc_final [concat $cc_final $cxxflags]
416     set cc_final [concat $cc_final $includes]
417     regsub -all {\s[-]nostdinc[+][+]} $cc_final "" cc_final
418
419     # This is needed for "C" tests, as this type of test may need the
420     # C++ includes. And if we're not testing in the build directory,
421     # the includes variable is not likely to include the necessary
422     # info.
423     if { ![file exists $flags_file] } {
424         # ??? We need a --print-include-dirs option to GCC, so that
425         # we can avoid these hacks.  The heuristics here will not
426         # work with non-standard --with-includedir= options.
427         set version [remote_exec host ${cc} -dumpversion]
428         # Remove the trailing newline from the output.
429         set version [string trimright [lindex $version 1]]
430         set machine [remote_exec host ${cc} -dumpmachine]
431         set machine [string trimright [lindex $machine 1]]
432         set comp_base_dir [remote_exec host ${cc} --print-prog-name=cc1]
433         set comp_base_dir [lindex $comp_base_dir 1]
434         set comp_base_dir [file dirname [file dirname [file dirname [file dirname [file dirname $comp_base_dir]]]]]
435         # For a cross compiler, the header files will be located in a
436         # machine-specific subdirectory.
437         set crossbase "${comp_base_dir}/${machine}/include/c++/${version}"
438         set crosstarget "${crossbase}/${machine}"
439         set cc_final [concat $cc_final "-I$crossbase -I$crosstarget"]
440         # For a native compiler, the header files will be located at 
441         # the top level.
442         set includesbase "${comp_base_dir}/include/c++/${version}"
443         set includestarget "${includesbase}/${machine}"
444         set cc_final [concat $cc_final "-I$includesbase -I$includestarget"]
445
446         set libsup "${comp_base_dir}/lib"
447     } else {
448         set libsup "${blddir}/libsupc++/.libs"
449     }
450
451     set cc_final [concat $cc_final "-L$libsup"]
452
453     lappend options "compiler=$cc_final"
454     lappend options "timeout=600"
455
456     return [target_compile $source $dest $type $options]
457 }
458
459 # Build the support objects linked in with the libstdc++ tests.  In
460 # addition, set v3-wchar_t, v3-threads, and v3-symver appropriately.
461 proc v3-build_support { } {
462     global env
463     global srcdir
464     global v3-wchar_t
465     global v3-threads
466     global v3-symver
467     global v3-sharedlib
468
469     # Figure out whether or not the library supports certain features.
470     set v3-wchar_t 0
471     set v3-threads 0
472     set v3-symver 0
473     set libtest_objs ""
474
475     set config_src "config.cc"
476     set config_out "config.ii"
477     set f [open $config_src "w"]
478     puts $f "#include <bits/c++config.h>"
479     puts $f "#include <bits/gthr.h>"
480     close $f
481     v3_target_compile $config_src $config_out preprocess "additional_flags=-dN"
482     set file [open $config_out r]
483     set preprocessed [read $file]
484     close $file
485     if { [string first "_GLIBCXX_USE_WCHAR_T" $preprocessed] != -1 } {
486         verbose -log "wchar_t support detected"
487         set v3-wchar_t 1
488     }
489     if { [string first "_GLIBCXX_SYMVER" $preprocessed] != -1 } {
490         verbose -log "symbol versioning support detected"
491         set v3-symver 1
492     }
493     if { [string first "__GTHREADS" $preprocessed] != -1 } {
494         verbose -log "thread support detected"
495         set v3-threads 1
496     }
497
498     # Try to build the MO files that are used by some of the locale
499     # tests.  If we can't build them, that's OK; it just means that
500     # those tests will fail.
501     foreach lang [list "fr" "de"] {
502         catch {
503             file mkdir "$lang/LC_MESSAGES"
504             remote_exec "build" "msgfmt" "-o $lang/LC_MESSAGES/libstdc++.mo $srcdir/../po/$lang.po"
505             if [is_remote host] {
506                 remote_exec "host" "mkdir" "-p $lang/LC_MESSAGES"
507                 remote_download "host" "$lang/LC_MESSAGES/libstdc++.mo" "$lang/LC_MESSAGES/libstdc++.mo"
508             }
509         }
510     }
511
512     # Build the support objects.
513     set source_files [list testsuite_abi.cc testsuite_allocator.cc \
514                           testsuite_character.cc testsuite_hooks.cc \
515                  rng/twister_rand_gen.cc io/verified_cmd_line_input.cc \
516                           io/prog_bar.cc performance/time/elapsed_timer.cc ]
517     foreach f $source_files {
518         set obj [file rootname $f].o
519         set object_file [file tail $obj]
520         # Compile with "-w" so that warnings issued by the compiler
521         # do not prevent compilation.
522         if { [v3_target_compile $srcdir/util/$f $object_file "object" \
523                   [list "incdir=$srcdir" "additional_flags=-w"]]
524              != "" } {
525             error "could not compile $f"
526         }
527         append libtest_objs "$object_file "
528     }
529
530     # Collect into libtestc++.a
531     if  [info exists env(AR)] {
532         set ar $env(AR)
533     } else {
534         set ar [transform "ar"]
535     }
536     set arargs "-rc ./libtestc++.a ${libtest_objs}"
537     verbose -log "$ar $arargs"
538     set result [lindex [remote_exec host "$ar" "$arargs"] 0]
539     verbose "link result is $result"
540     if { $result == 0 } {
541         if  [info exists env(RANLIB)] {
542             set ranlib $env(RANLIB)
543         } else {
544             set ranlib [transform "ranlib"]
545         }
546         set ranlibargs "./libtestc++.a"
547         verbose -log "$ranlib $ranlibargs"
548         set result [lindex [remote_exec host "$ranlib" "$ranlibargs"] 0]
549         if { $result != 0 } {
550             error "could not link libtestc++.a"
551         }
552     }
553
554     # Build any shared objects needed for regression testing.
555     if { ${v3-sharedlib} == 1 } {
556         set source_files [list testsuite_shared.cc]
557         foreach f $source_files {
558             set object_file [file rootname $f].so
559             # Compile with "-w" so that warnings issued by the compiler
560             # do not prevent compilation.
561             if { [v3_target_compile $srcdir/util/$f $object_file "sharedlib" \
562              [list "incdir=$srcdir" "additional_flags=-w -shared -fPIC -DPIC"]]
563                  != "" } {
564                 error "could not compile $f"
565             }
566         }
567     }
568 }
569
570 proc check_v3_target_fileio { } {
571     global et_fileio_saved
572     global et_fileio_target_name
573     global tool 
574
575     if { ![info exists et_fileio_target_name] } {
576         set et_fileio_target_name ""
577     }
578
579     # If the target has changed since we set the cached value, clear it.
580     set current_target [current_target_name]
581     if { $current_target != $et_fileio_target_name } {
582         verbose "check_v3_target_fileio: `$et_fileio_target_name'" 2
583         set et_fileio_target_name $current_target
584         if [info exists et_fileio_saved] {
585             verbose "check_v3_target_fileio: removing cached result" 2
586             unset et_fileio_saved
587         }
588     }
589
590     if [info exists et_fileio_saved] {
591         verbose "check_v3_target_fileio: using cached result" 2
592     } else {
593         set et_fileio_saved 0
594
595         # Set up, compile, and execute a C++ test program that tries to use
596         # the file functions
597         set src fileio[pid].cc
598         set exe fileio[pid].x
599
600         set f [open $src "w"]
601         puts $f "#include <sys/types.h>"
602         puts $f "#include <sys/stat.h>"
603         puts $f "#include <fcntl.h>"
604         puts $f "#include <unistd.h>"
605         puts $f "#include <errno.h>"
606         puts $f "using namespace std;"  
607         puts $f "int main ()"
608         puts $f "{"
609         puts $f "  int fd  = open (\".\", O_RDONLY);"
610         puts $f "  int ret = 0;"
611         puts $f "  if (fd == -1)"
612         puts $f "  {"
613         puts $f "    int err = errno;"
614         puts $f "    if (err == EIO || err == ENOSYS)"
615         puts $f "      ret = 1;"
616         puts $f "  }"
617         puts $f "  else"
618         puts $f "  {"
619         puts $f "    if (lseek (fd, 0, SEEK_CUR) == -1)"
620         puts $f "      ret = 1;"
621         puts $f "    close (fd);"
622         puts $f "  }"
623         puts $f "  return ret;"
624         puts $f "}" 
625         close $f
626
627         set lines [v3_target_compile $src $exe executable ""]
628         file delete $src
629
630         if [string match "" $lines] {
631             # No error message, compilation succeeded.
632             set result [${tool}_load "./$exe" "" ""]
633             set status [lindex $result 0]
634             remote_file build delete $exe
635
636             verbose "check_v3_target_fileio: status is <$status>" 2
637
638             if { $status == "pass" } {
639                 set et_fileio_saved 1
640             }
641         } else {
642             verbose "check_v3_target_fileio: compilation failed" 2
643         }
644     }
645     return $et_fileio_saved
646 }
647
648 # Eventually we want C90/C99 determining and switching from this.
649 proc check_v3_target_c_std { } {
650     global et_c_std_saved
651     global et_c_std_target_name
652     global tool 
653
654     if { ![info exists et_c_std_target_name] } {
655         set et_c_std_target_name ""
656     }
657
658     # If the target has changed since we set the cached value, clear it.
659     set current_target [current_target_name]
660     if { $current_target != $et_c_std_target_name } {
661         verbose "check_v3_target_c_std: `$et_c_std_target_name'" 2
662         set et_c_std_target_name $current_target
663         if [info exists et_c_std_saved] {
664             verbose "check_v3_target_c_std: removing cached result" 2
665             unset et_c_std_saved
666         }
667     }
668
669     if [info exists et_c_std_saved] {
670         verbose "check_v3_target_c_std: using cached result" 2
671     } else {
672         set et_c_std_saved 0
673
674         # Set up, compile, and execute a C++ test program that tries to use
675         # C99 functionality.
676         # For math bits, could use check_effective_target_c99_math.
677         set src fileio[pid].cc
678         set exe fileio[pid].x
679
680         set f [open $src "w"]
681         puts $f "#include <tr1/cmath>"
682         puts $f "#include <cstdlib>"
683         puts $f "int main ()"
684         puts $f "{"
685         puts $f "  float f = 45.55;"
686         puts $f "  int i = std::tr1::isnan(f);"
687         puts $f "  "
688         puts $f "  using std::wctomb;"
689         puts $f "  return 0;"
690         puts $f "}" 
691         close $f
692
693         set lines [v3_target_compile $src $exe executable ""]
694         file delete $src
695
696         if [string match "" $lines] {
697             # No error message, compilation succeeded.
698             set result [${tool}_load "./$exe" "" ""]
699             set status [lindex $result 0]
700             remote_file build delete $exe
701
702             verbose "check_v3_target_c_std: status is <$status>" 2
703
704             if { $status == "pass" } {
705                 set et_c_std_saved 1
706             }
707         } else {
708             verbose "check_v3_target_c_std: compilation failed" 2
709         }
710     }
711     return $et_c_std_saved
712 }
713
714 proc check_v3_target_sharedlib { } {
715     global v3-sharedlib
716     return ${v3-sharedlib}
717 }
718
719 proc check_v3_target_time { } {
720     global et_time_saved
721     global et_time_target_name
722     global tool 
723
724     if { ![info exists et_time_target_name] } {
725         set et_time_target_name ""
726     }
727
728     # If the target has changed since we set the cached value, clear it.
729     set current_target [current_target_name]
730     if { $current_target != $et_time_target_name } {
731         verbose "check_v3_target_time: `$et_time_target_name'" 2
732         set et_time_target_name $current_target
733         if [info exists et_time_saved] {
734             verbose "check_v3_target_time: removing cached result" 2
735             unset et_time_saved
736         }
737     }
738
739     if [info exists et_time_saved] {
740         verbose "check_v3_target_time: using cached result" 2
741     } else {
742         set et_time_saved 0
743
744         # Set up and compile a C++ test program that tries to use
745         # the time function
746         set src time[pid].cc
747         set exe time[pid].x
748
749         set f [open $src "w"]
750         puts $f "#include <time.h>"
751         puts $f "using namespace std;"  
752         puts $f "int main ()"
753         puts $f "{"
754         puts $f "  time (0);"   
755         puts $f "}" 
756         close $f
757
758         set lines [v3_target_compile $src $exe executable ""]
759         file delete $src
760
761         if [string match "" $lines] {
762             # No error message, compilation succeeded.
763             verbose "check_v3_target_time: compilation succeeded" 2
764             remote_file build delete $exe
765             set et_time_saved 1
766         } else {
767             verbose "check_v3_target_time: compilation failed" 2
768         }
769     }
770     return $et_time_saved
771 }
772
773 proc check_v3_target_rvalref { } {
774     global et_rvalref_saved
775     global et_rvalref_target_name
776     global tool 
777
778     if { ![info exists et_rvalref_target_name] } {
779         set et_rvalref_target_name ""
780     }
781
782     # If the target has changed since we set the cached value, clear it.
783     set current_target [current_target_name]
784     if { $current_target != $et_rvalref_target_name } {
785         verbose "check_v3_target_rvalref: `$et_rvalref_target_name'" 2
786         set et_rvalref_target_name $current_target
787         if [info exists et_rvalref_saved] {
788             verbose "check_v3_target_rvalref: removing cached result" 2
789             unset et_rvalref_saved
790         }
791     }
792
793     if [info exists et_rvalref_saved] {
794         verbose "check_v3_target_rvalref: using cached result" 2
795     } else {
796         set et_rvalref_saved 0
797
798         # Set up and compile a C++ test program that tries to use
799         # the library components of rval references
800         set src rvalref[pid].cc
801         set exe rvalref[pid].x
802
803         set f [open $src "w"]
804         puts $f "#include <iterator>"
805         puts $f "#include <utility>"
806         puts $f "using std::move;"
807         puts $f "using std::identity;"
808         puts $f "using std::forward;"
809         puts $f "using std::move_iterator;"
810         puts $f "using std::make_move_iterator;"
811         close $f
812
813         set lines [v3_target_compile $src $exe executable ""]
814         file delete $src
815
816         if [string match "" $lines] {
817             # No error message, compilation succeeded.
818             verbose "check_v3_target_rvalref: compilation succeeded" 2
819             remote_file build delete $exe
820             set et_rvalref_saved 1
821         } else {
822             verbose "check_v3_target_rvalref: compilation failed" 2
823         }
824     }
825     return $et_rvalref_saved
826 }
827
828 proc check_v3_target_namedlocale { } {
829     global et_namedlocale_saved
830     global et_namedlocale_target_name
831     global tool 
832
833     if { ![info exists et_namedlocale_target_name] } {
834         set et_namedlocale_target_name ""
835     }
836
837     # If the target has changed since we set the cached value, clear it.
838     set current_target [current_target_name]
839     if { $current_target != $et_namedlocale_target_name } {
840         verbose "check_v3_target_namedlocale: `$et_namedlocale_target_name'" 2
841         set et_namedlocale_target_name $current_target
842         if [info exists et_namedlocale_saved] {
843             verbose "check_v3_target_namedlocale: removing cached result" 2
844             unset et_namedlocale_saved
845         }
846     }
847
848     if [info exists et_namedlocale_saved] {
849         verbose "check_v3_target_namedlocale: using cached result" 2
850     } else {
851         set et_namedlocale_saved 0
852
853         # Set up, compile, and execute a C++ test program that tries to use
854         # all the required named locales.
855         set src nlocale[pid].cc
856         set exe nlocale[pid].x
857
858         set f [open $src "w"]
859         puts $f "#include <locale>"
860         puts $f "using namespace std;"  
861         puts $f "int main ()"
862         puts $f "{"
863         puts $f "  try" 
864         puts $f "  {" 
865         puts $f "     locale(\"\");"
866         puts $f "     locale(\"de_DE\");"
867         puts $f "     locale(\"de_DE.ISO-8859-15@euro\");"
868         puts $f "     locale(\"de_DE@euro\");"
869         puts $f "     locale(\"en_HK\");"
870         puts $f "     locale(\"en_PH\");"
871         puts $f "     locale(\"en_US\");"
872         puts $f "     locale(\"en_US.ISO-8859-1\");"
873         puts $f "     locale(\"en_US.ISO-8859-15\");"
874         puts $f "     locale(\"en_US.UTF-8\");"
875         puts $f "     locale(\"es_ES\");"
876         puts $f "     locale(\"es_MX\");"
877         puts $f "     locale(\"fr_FR\");"
878         puts $f "     locale(\"fr_FR@euro\");"
879         puts $f "     locale(\"is_IS\");"
880         puts $f "     locale(\"is_IS.UTF-8\");"
881         puts $f "     locale(\"it_IT\");"
882         puts $f "     locale(\"ja_JP.eucjp\");"
883         puts $f "     locale(\"se_NO.UTF-8\");"
884         puts $f "     locale(\"ta_IN\");"
885         puts $f "     locale(\"zh_TW\");"
886         puts $f "     return 0;"
887         puts $f "  }"
888         puts $f "  catch(...)"
889         puts $f "  {"
890         puts $f "     return 1;"
891         puts $f "  }"   
892         puts $f "}"
893         close $f
894
895         set lines [v3_target_compile $src $exe executable ""]
896         file delete $src
897
898         if [string match "" $lines] {
899             # No error message, compilation succeeded.
900             set result [${tool}_load "./$exe" "" ""]
901             set status [lindex $result 0]
902             remote_file build delete $exe
903
904             verbose "check_v3_target_namedlocale: status is <$status>" 2
905
906             if { $status == "pass" } {
907                 set et_namedlocale_saved 1
908             }
909         } else {
910             verbose "check_v3_target_namedlocale: compilation failed" 2
911         }
912     }
913     return $et_namedlocale_saved
914 }
915
916 proc check_v3_target_debug_mode { } {
917     global cxxflags
918     global et_debug_mode
919     global tool 
920
921     if { ![info exists et_debug_mode_target_name] } {
922         set et_debug_mode_target_name ""
923     }
924
925     # If the target has changed since we set the cached value, clear it.
926     set current_target [current_target_name]
927     if { $current_target != $et_debug_mode_target_name } {
928         verbose "check_v3_target_debug_mode: `$et_debug_mode_target_name'" 2
929         set et_debug_mode_target_name $current_target
930         if [info exists et_debug_mode] {
931             verbose "check_v3_target_debug_mode: removing cached result" 2
932             unset et_debug_mode
933         }
934     }
935
936     if [info exists et_debug_mode] {
937         verbose "check_v3_target_debug_mode: using cached result" 2
938     } else {
939         set et_debug_mode 0
940
941         # Set up, compile, and execute a C++ test program that depends
942         # on debug mode working.
943         set src debug_mode[pid].cc
944         set exe debug_mode[pid].exe
945
946         set f [open $src "w"]
947         puts $f "#include <string>"
948         puts $f "using namespace std;"  
949         puts $f "int main()"
950         puts $f "{ return 0; }"
951         close $f
952
953         set cxxflags_saved $cxxflags
954         set cxxflags "$cxxflags -Werror -O0 -D_GLIBCXX_DEBUG"
955         set lines [v3_target_compile $src $exe executable ""]
956         set cxxflags $cxxflags_saved
957         file delete $src
958
959         if [string match "" $lines] {
960             # No error message, compilation succeeded.
961             set et_debug_mode 1
962         }
963     }
964     verbose "check_v3_target_debug_mode: $et_debug_mode" 2
965     return $et_debug_mode
966 }
967
968 proc check_v3_target_parallel_mode { } {
969     global cxxflags
970     global DEFAULT_CXXFLAGS
971     global et_parallel_mode
972
973     global tool 
974
975     if { ![info exists et_parallel_mode_target_name] } {
976         set et_parallel_mode_target_name ""
977     }
978
979     # If the target has changed since we set the cached value, clear it.
980     set current_target [current_target_name]
981     if { $current_target != $et_parallel_mode_target_name } {
982         verbose "check_v3_target_parallel_mode: `$et_parallel_mode_target_name'" 2
983         set et_parallel_mode_target_name $current_target
984         if [info exists et_parallel_mode] {
985             verbose "check_v3_target_parallel_mode: removing cached result" 2
986             unset et_parallel_mode
987         }
988     }
989
990     if [info exists et_parallel_mode] {
991         verbose "check_v3_target_parallel_mode: using cached result" 2
992     } else {
993         set et_parallel_mode 0
994
995         # Set up, compile, and execute a C++ test program that depends
996         # on parallel mode working.
997         set src parallel_mode[pid].cc
998         set exe parallel_mode[pid].exe
999
1000         set f [open $src "w"]
1001         puts $f "#include <omp.h>"
1002         puts $f "int main()"
1003         puts $f "{ return 0; }"
1004         close $f
1005
1006         set cxxflags_saved $cxxflags
1007         set cxxflags "$cxxflags $DEFAULT_CXXFLAGS -Werror"
1008
1009         set lines [v3_target_compile $src $exe executable ""]
1010         set cxxflags $cxxflags_saved
1011         file delete $src
1012
1013         if [string match "" $lines] {
1014             # No error message, compilation succeeded.
1015             set et_parallel_mode 1
1016         } else {
1017             verbose "check_v3_target_parallel_mode: compilation failed" 2
1018         }
1019     }
1020     verbose "check_v3_target_parallel_mode: $et_parallel_mode" 2
1021     return $et_parallel_mode
1022 }