libstdc++-v3/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.57)
   5 AC_INIT(libstdc++, version-unused)
   6 AC_CONFIG_SRCDIR(src/ios.cc)
   7 AC_CONFIG_HEADER(config.h)
   8
   9 # This works around the fact that libtool configuration may change LD
  10 # for this particular configuration, but some shells, instead of
  11 # keeping the changes in LD private, export them just because LD is
  12 # exported.  Only used at the end of this file.
  13 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  14
  15 # For libtool versioning info, format is CURRENT:REVISION:AGE
  16 libtool_VERSION=6:0:0
  17 AC_SUBST(libtool_VERSION)
  18
  19 # Find the rest of the source tree framework.
  20 GLIBCXX_TOPREL_CONFIGURE
  21
  22 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  23 #
  24 # You will slowly go insane if you do not grok the following fact:  when
  25 # building v3 as part of the compiler, the top-level /target/ becomes the
  26 # library's /host/.  configure then causes --target to default to --host,
  27 # exactly like any other package using autoconf.  Therefore, 'target' and
  28 # 'host' will always be the same.  This makes sense both for native and
  29 # cross compilers, just think about it for a little while.  :-)
  30 #
  31 # Also, if v3 is being configured as part of a cross compiler, the top-level
  32 # configure script will pass the "real" host as $with_cross_host.
  33 #
  34 # Do not delete or change the following two lines.  For why, see
  35 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  36 AC_CANONICAL_SYSTEM
  37 target_alias=${target_alias-$host_alias}
  38
  39 # Handy for debugging:
  40 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  41
  42 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  43 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  44 #  1.x:  minimum required version
  45 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  46 #              of other PACKAGE_* variables will, however, and there's nothing
  47 #              we can do about that)
  48 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  49 #            file in the top srcdir, etc, etc), so stop complaining.
  50 #  no-dependencies:  turns off auto dependency generation (just for now)
  51 #  -Wall:  turns on all automake warnings
  52 AM_INIT_AUTOMAKE([1.7.6 no-define foreign no-dependencies -Wall])
  53
  54 # AM_INIT_AUTOMAKE sets this to the "smashed" format.  Calling the library
  55 # "libstdc--" causes remarkable amounts of breakage.  Thanks, automake.
  56 PACKAGE='libstdc++'
  57
  58 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  59 # up critical shell variables.
  60 GLIBCXX_CONFIGURE
  61
  62 #AC_MSG_NOTICE([====== Starting libtool configuration])
  63 AC_LIBTOOL_DLOPEN
  64 AM_PROG_LIBTOOL
  65 AC_SUBST(enable_shared)
  66 AC_SUBST(enable_static)
  67 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
  68
  69 # Check for support bits and g++ features that don't require linking.
  70 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  71 GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS
  72 GLIBCXX_ENABLE_PCH([yes])
  73
  74 # Enable all the variable C++ runtime options.
  75 # NB: C_MBCHAR must come early.
  76 GLIBCXX_ENABLE_CSTDIO
  77 GLIBCXX_ENABLE_CLOCALE
  78 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
  79 GLIBCXX_ENABLE_C_MBCHAR([yes])
  80 GLIBCXX_ENABLE_C99([yes])
  81 GLIBCXX_ENABLE_LONG_LONG([yes])
  82 GLIBCXX_ENABLE_THREADS
  83 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
  84 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
  85 GLIBCXX_ENABLE_DEBUG([no])
  86 GLIBCXX_ENABLE_CXX_FLAGS
  87
  88 # No surprises, no surprises...
  89 if test $atomicity_include_dir = cpu/generic ; then
  90   AC_MSG_WARN([No native atomic operations are provided for this platform.])
  91   if test $target_thread_file = single; then
  92     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
  93     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
  94   else
  95     AC_MSG_WARN([They will be faked using a mutex.])
  96     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
  97   fi
  98 fi
  99
 100
 101 if test "$build" != "$host"; then
 102
 103   # We are being configured with some form of cross compiler.
 104   GLIBCXX_IS_NATIVE=false
 105
 106   # This lets us hard-code the functionality we know we'll have in the cross
 107   # target environment.  "Let" is a sugar-coated word placed on an especially
 108   # dull and tedious hack, actually.
 109   #
 110   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 111   # that involve linking, can't be used:
 112   #    "cannot open sim-crt0.o"
 113   #    "cannot open crt0.o"
 114   # etc.  All this is because there currently exists no unified, consistent
 115   # way for top level CC information to be passed down to target directories:
 116   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 117   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 118   # crosses can be removed.
 119
 120   # If Canadian cross, then don't pick up tools from the build directory.
 121   # Used in GLIBCXX_EXPORT_INCLUDES (and nowhere else?).
 122   if test -n "$with_cross_host" &&
 123      test x"$build" != x"$with_cross_host" &&
 124      test x"$build" != x"$target";
 125   then
 126     CANADIAN=yes
 127   else
 128     CANADIAN=no
 129   fi
 130
 131   # Construct crosses by hand, eliminating bits that need ld...
 132   # GLIBCXX_CHECK_COMPILER_FEATURES
 133   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 134   # GLIBCXX_CHECK_MATH_SUPPORT
 135
 136   # First, test for "known" system libraries.  We may be using newlib even
 137   # on a hosted environment.
 138   if test "x${with_newlib}" = "xyes"; then
 139     os_include_dir="os/newlib"
 140     AC_DEFINE(HAVE_HYPOT)
 141
 142     # GLIBCXX_CHECK_STDLIB_SUPPORT
 143     AC_DEFINE(HAVE_STRTOF)
 144     AC_DEFINE(HAVE_STRTOLD)
 145     # AC_FUNC_MMAP
 146     AC_DEFINE(HAVE_MMAP)
 147
 148     AC_DEFINE(HAVE_ACOSF)
 149     AC_DEFINE(HAVE_ASINF)
 150     AC_DEFINE(HAVE_ATAN2F)
 151     AC_DEFINE(HAVE_ATANF)
 152     AC_DEFINE(HAVE_CEILF)
 153     AC_DEFINE(HAVE_COPYSIGN)
 154     AC_DEFINE(HAVE_COPYSIGNF)
 155     AC_DEFINE(HAVE_COSF)
 156     AC_DEFINE(HAVE_COSHF)
 157     AC_DEFINE(HAVE_EXPF)
 158     AC_DEFINE(HAVE_FABSF)
 159     AC_DEFINE(HAVE_FLOORF)
 160     AC_DEFINE(HAVE_FMODF)
 161     AC_DEFINE(HAVE_FREXPF)
 162     AC_DEFINE(HAVE_LDEXPF)
 163     AC_DEFINE(HAVE_LOG10F)
 164     AC_DEFINE(HAVE_LOGF)
 165     AC_DEFINE(HAVE_MODFF)
 166     AC_DEFINE(HAVE_POWF)
 167     AC_DEFINE(HAVE_SINF)
 168     AC_DEFINE(HAVE_SINHF)
 169     AC_DEFINE(HAVE_SQRTF)
 170     AC_DEFINE(HAVE_TANF)
 171     AC_DEFINE(HAVE_TANHF)
 172   else
 173     m4_include([crossconfig.m4])
 174   fi
 175
 176   # At some point, we should differentiate between architectures
 177   # like x86, which have long double versions, and alpha/powerpc/etc.,
 178   # which don't. For the time being, punt.
 179   if test x"long_double_math_on_this_cpu" = x"yes"; then
 180     AC_DEFINE(HAVE_ACOSL)
 181     AC_DEFINE(HAVE_ASINL)
 182     AC_DEFINE(HAVE_ATAN2L)
 183     AC_DEFINE(HAVE_ATANL)
 184     AC_DEFINE(HAVE_CEILL)
 185     AC_DEFINE(HAVE_COPYSIGNL)
 186     AC_DEFINE(HAVE_COSL)
 187     AC_DEFINE(HAVE_COSHL)
 188     AC_DEFINE(HAVE_EXPL)
 189     AC_DEFINE(HAVE_FABSL)
 190     AC_DEFINE(HAVE_FLOORL)
 191     AC_DEFINE(HAVE_FMODL)
 192     AC_DEFINE(HAVE_FREXPL)
 193     AC_DEFINE(HAVE_LDEXPL)
 194     AC_DEFINE(HAVE_LOG10L)
 195     AC_DEFINE(HAVE_LOGL)
 196     AC_DEFINE(HAVE_MODFL)
 197     AC_DEFINE(HAVE_POWL)
 198     AC_DEFINE(HAVE_SINCOSL)
 199     AC_DEFINE(HAVE_SINL)
 200     AC_DEFINE(HAVE_SINHL)
 201     AC_DEFINE(HAVE_SQRTL)
 202     AC_DEFINE(HAVE_TANL)
 203     AC_DEFINE(HAVE_TANHL)
 204   fi
 205
 206 else
 207
 208   # We are being configured natively.  We can do more elaborate tests that
 209   # include AC_TRY_COMPILE now, as the linker is assumed to be working.
 210   GLIBCXX_IS_NATIVE=true
 211   CANADIAN=no
 212
 213   # Check for available headers.
 214   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 215   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 216   sys/types.h])
 217
 218   GLIBCXX_CHECK_COMPILER_FEATURES
 219   GLIBCXX_CHECK_LINKER_FEATURES
 220   GLIBCXX_CHECK_MATH_SUPPORT
 221   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 222   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 223   GLIBCXX_CHECK_WCHAR_T_SUPPORT
 224   GLIBCXX_CHECK_STDLIB_SUPPORT
 225
 226   # For showmanyc_helper().
 227   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 228   GLIBCXX_CHECK_POLL
 229   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 230
 231   # For xsputn_2().
 232   AC_CHECK_HEADERS(sys/uio.h)
 233   GLIBCXX_CHECK_WRITEV
 234
 235   AC_LC_MESSAGES
 236
 237   AC_TRY_COMPILE(
 238     [#include <setjmp.h>],
 239     [sigjmp_buf env;
 240      while (! sigsetjmp (env, 1))
 241        siglongjmp (env, 1);
 242     ],
 243     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 244
 245   AC_FUNC_MMAP
 246 fi
 247
 248 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 249 GLIBCXX_ENABLE_SYMVERS([yes])
 250
 251 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 252 GLIBCXX_CONFIGURE_TESTSUITE
 253
 254 # Propagate the target-specific source directories through the build chain.
 255 # (Nothing currently uses cpu_include_dir directly; only atomicity_include_dir
 256 # uses it, and it only gets used in this file.)
 257 ATOMICITY_INC_SRCDIR=config/${atomicity_include_dir}
 258 OS_INC_SRCDIR=config/${os_include_dir}
 259 FPOS_INC_SRCDIR=config/${fpos_include_dir}
 260 AC_SUBST(ATOMICITY_INC_SRCDIR)
 261 AC_SUBST(FPOS_INC_SRCDIR)
 262 AC_SUBST(OS_INC_SRCDIR)
 263
 264 # Determine cross-compile flags and AM_CONDITIONALs.
 265 #AC_SUBST(GLIBCXX_IS_NATIVE)
 266 AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 267 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 268 AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 269
 270 AC_CACHE_SAVE
 271
 272 if test ${multilib} = yes; then
 273   multilib_arg="--enable-multilib"
 274 else
 275   multilib_arg=
 276 fi
 277
 278 # Export all the install information
 279 GLIBCXX_EXPORT_INSTALL_INFO
 280
 281 # Export all the include and flag information to Makefiles.
 282 GLIBCXX_EXPORT_INCLUDES
 283 GLIBCXX_EXPORT_FLAGS
 284
 285 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 286    grep "enable shared" > /dev/null;
 287 then
 288   LIBSUPCXX_PICFLAGS=-prefer-pic
 289 else
 290   LIBSUPCXX_PICFLAGS=
 291 fi
 292 AC_SUBST(LIBSUPCXX_PICFLAGS)
 293
 294 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 295 dnl which can all be called multiple times as needed, plus one (different)
 296 dnl AC_OUPUT macro.  This one lists the files to be created:
 297 AC_CONFIG_FILES([ \
 298   Makefile \
 299   include/Makefile \
 300   libmath/Makefile \
 301   libsupc++/Makefile \
 302   po/Makefile \
 303   src/Makefile \
 304   testsuite/Makefile \
 305   ])
 306 AC_CONFIG_FILES([scripts/check_survey],[chmod +x scripts/check_survey])
 307 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 308
 309 dnl These commands are run at the end of config.status:
 310 AC_CONFIG_COMMANDS([default],
 311 [if test -n "$CONFIG_FILES"; then
 312    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 313    # that multilib installs will end up installed in the correct place.
 314    # The testsuite needs it for multilib-aware ABI baseline files.
 315    # To work around this not being passed down from config-ml.in ->
 316    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 317    # append it here.  Only modify Makefiles that have just been created.
 318    for i in src libsupc++ testsuite; do
 319     case $CONFIG_FILES in
 320      *${i}/Makefile*)
 321        #echo "Adding MULTISUBDIR to $i/Makefile"
 322        grep '^MULTISUBDIR =' Makefile >> $i/Makefile
 323        ;;
 324     esac
 325    done
 326  fi
 327  (cd include && ${MAKE-make})
 328 ],
 329 [
 330 # No init-vars needed so far which aren't already passed by autoconf.
 331 ])
 332
 333 dnl And this actually makes things happen:
 334 AC_OUTPUT
 335