OSDN Git Service

2003-12-09 Benjamin Kosnik <bkoz@redhat.com>
[pf3gnuchains/gcc-fork.git] / libstdc++-v3 / configure.ac
1 # Process this file with autoconf to produce a configure script, like so:
2 # aclocal && autoconf && autoheader && automake
3
4 AC_PREREQ(2.57)
5 AC_INIT(package-unused, version-unused,, libstdc++)
6 AC_CONFIG_SRCDIR(src/ios.cc)
7 AC_CONFIG_HEADER(config.h)
8
9 # This works around the fact that libtool configuration may change LD
10 # for this particular configuration, but some shells, instead of
11 # keeping the changes in LD private, export them just because LD is
12 # exported.  Only used at the end of this file.
13 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
14
15 # For libtool versioning info, format is CURRENT:REVISION:AGE
16 libtool_VERSION=6:0:0
17 AC_SUBST(libtool_VERSION)
18
19 # Find the rest of the source tree framework.
20 GLIBCXX_TOPREL_CONFIGURE
21
22 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
23 #
24 # You will slowly go insane if you do not grok the following fact:  when
25 # building v3 as part of the compiler, the top-level /target/ becomes the
26 # library's /host/.  configure then causes --target to default to --host,
27 # exactly like any other package using autoconf.  Therefore, 'target' and
28 # 'host' will always be the same.  This makes sense both for native and
29 # cross compilers, just think about it for a little while.  :-)
30 #
31 # Also, if v3 is being configured as part of a cross compiler, the top-level
32 # configure script will pass the "real" host as $with_cross_host.
33 #
34 # Do not delete or change the following two lines.  For why, see
35 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
36 AC_CANONICAL_SYSTEM
37 target_alias=${target_alias-$host_alias}
38
39 # Handy for debugging:
40 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
41
42 if test "$build" != "$host"; then
43   # We are being configured with some form of cross compiler.
44   GLIBCXX_IS_NATIVE=false
45   GCC_NO_EXECUTABLES
46 else
47   GLIBCXX_IS_NATIVE=true
48 fi
49
50 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
51 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
52 #  1.x:  minimum required version
53 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
54 #              of other PACKAGE_* variables will, however, and there's nothing
55 #              we can do about that; they come from AC_INIT).
56 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
57 #            file in the top srcdir, etc, etc), so stop complaining.
58 #  no-dependencies:  turns off auto dependency generation (just for now)
59 #  -Wall:  turns on all automake warnings
60 AM_INIT_AUTOMAKE([1.7.6 no-define foreign no-dependencies -Wall])
61
62 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
63 # up critical shell variables.
64 GLIBCXX_CONFIGURE
65
66 #AC_MSG_NOTICE([====== Starting libtool configuration])
67 AC_LIBTOOL_DLOPEN
68 AM_PROG_LIBTOOL
69 AC_SUBST(enable_shared)
70 AC_SUBST(enable_static)
71 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
72
73 # Possibly disable most of the library.
74 ## XXX Consider skipping unncessary tests altogether in this case, rather
75 ## than just ignoring the results.  Faster /and/ more correct, win win.
76 GLIBCXX_ENABLE_HOSTED
77
78 # Check for support bits and g++ features that don't require linking.
79 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
80 GLIBCXX_ENABLE_PCH($is_hosted)
81
82 # Enable all the variable C++ runtime options.  
83 # NB: C_MBCHAR must come early.
84 GLIBCXX_ENABLE_CSTDIO
85 GLIBCXX_ENABLE_CLOCALE
86 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
87 GLIBCXX_ENABLE_C_MBCHAR([yes])
88 GLIBCXX_ENABLE_C99([yes])
89 GLIBCXX_ENABLE_LONG_LONG([yes])
90 GLIBCXX_ENABLE_THREADS
91 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
92 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
93 GLIBCXX_ENABLE_DEBUG([no])
94 GLIBCXX_ENABLE_CXX_FLAGS
95
96 # No surprises, no surprises...
97 if test $atomicity_include_dir = cpu/generic ; then
98   AC_MSG_WARN([No native atomic operations are provided for this platform.])
99   if test $target_thread_file = single; then
100     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
101     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
102   else
103     AC_MSG_WARN([They will be faked using a mutex.])
104     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
105   fi
106 fi
107
108
109 if $GLIBCXX_IS_NATIVE; then
110
111   # We can do more elaborate tests that assume a working linker.
112   CANADIAN=no
113
114   # Check for available headers.
115   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
116   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
117   sys/types.h])
118
119   GLIBCXX_CHECK_COMPILER_FEATURES
120   GLIBCXX_CHECK_LINKER_FEATURES
121   GLIBCXX_CHECK_MATH_SUPPORT
122   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
123   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
124   GLIBCXX_CHECK_WCHAR_T_SUPPORT
125   GLIBCXX_CHECK_STDLIB_SUPPORT
126
127   # For showmanyc_helper().
128   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
129   GLIBCXX_CHECK_POLL
130   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
131
132   # For xsputn_2().
133   AC_CHECK_HEADERS(sys/uio.h)
134   GLIBCXX_CHECK_WRITEV
135
136   # For the __streamoff_base_type typedef.
137   GLIBCXX_CHECK_INT64_T
138
139   # For LFS support.
140   GLIBCXX_CHECK_LFS
141
142   AC_LC_MESSAGES
143
144   AC_TRY_COMPILE(
145     [#include <setjmp.h>],
146     [sigjmp_buf env;
147      while (! sigsetjmp (env, 1))
148        siglongjmp (env, 1);
149     ],
150     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
151
152   AC_FUNC_MMAP
153
154 else
155
156   # This lets us hard-code the functionality we know we'll have in the cross
157   # target environment.  "Let" is a sugar-coated word placed on an especially
158   # dull and tedious hack, actually.
159   #
160   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
161   # that involve linking, can't be used:
162   #    "cannot open sim-crt0.o"
163   #    "cannot open crt0.o"
164   # etc.  All this is because there currently exists no unified, consistent
165   # way for top level CC information to be passed down to target directories:
166   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
167   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
168   # crosses can be removed.
169
170   # If Canadian cross, then don't pick up tools from the build directory.
171   # Used only in GLIBCXX_EXPORT_INCLUDES.
172   if test -n "$with_cross_host" &&
173      test x"$build_alias" != x"$with_cross_host" &&
174      test x"$build" != x"$target";
175   then
176     CANADIAN=yes
177   else
178     CANADIAN=no
179   fi
180
181   # Construct crosses by hand, eliminating bits that need ld...
182   # GLIBCXX_CHECK_COMPILER_FEATURES
183   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
184   # GLIBCXX_CHECK_MATH_SUPPORT
185
186   # First, test for "known" system libraries.  We may be using newlib even
187   # on a hosted environment.
188   if test "x${with_newlib}" = "xyes"; then
189     os_include_dir="os/newlib"
190     AC_DEFINE(HAVE_HYPOT)
191
192     # GLIBCXX_CHECK_STDLIB_SUPPORT
193     AC_DEFINE(HAVE_STRTOF)        
194     AC_DEFINE(HAVE_STRTOLD)        
195     # AC_FUNC_MMAP
196     AC_DEFINE(HAVE_MMAP)
197
198     AC_DEFINE(HAVE_ACOSF)
199     AC_DEFINE(HAVE_ASINF)
200     AC_DEFINE(HAVE_ATAN2F)
201     AC_DEFINE(HAVE_ATANF)
202     AC_DEFINE(HAVE_CEILF)
203     AC_DEFINE(HAVE_COPYSIGN)
204     AC_DEFINE(HAVE_COPYSIGNF)
205     AC_DEFINE(HAVE_COSF)
206     AC_DEFINE(HAVE_COSHF)
207     AC_DEFINE(HAVE_EXPF)
208     AC_DEFINE(HAVE_FABSF)
209     AC_DEFINE(HAVE_FLOORF)
210     AC_DEFINE(HAVE_FMODF)
211     AC_DEFINE(HAVE_FREXPF)
212     AC_DEFINE(HAVE_LDEXPF)
213     AC_DEFINE(HAVE_LOG10F)
214     AC_DEFINE(HAVE_LOGF)
215     AC_DEFINE(HAVE_MODFF)
216     AC_DEFINE(HAVE_POWF)
217     AC_DEFINE(HAVE_SINF)
218     AC_DEFINE(HAVE_SINHF)
219     AC_DEFINE(HAVE_SQRTF)
220     AC_DEFINE(HAVE_TANF)
221     AC_DEFINE(HAVE_TANHF)
222   else
223     m4_include([crossconfig.m4])
224   fi
225
226   # At some point, we should differentiate between architectures
227   # like x86, which have long double versions, and alpha/powerpc/etc.,
228   # which don't. For the time being, punt.
229   if test x"long_double_math_on_this_cpu" = x"yes"; then
230     AC_DEFINE(HAVE_ACOSL)
231     AC_DEFINE(HAVE_ASINL)
232     AC_DEFINE(HAVE_ATAN2L)
233     AC_DEFINE(HAVE_ATANL)
234     AC_DEFINE(HAVE_CEILL)
235     AC_DEFINE(HAVE_COPYSIGNL)
236     AC_DEFINE(HAVE_COSL)
237     AC_DEFINE(HAVE_COSHL)
238     AC_DEFINE(HAVE_EXPL)
239     AC_DEFINE(HAVE_FABSL)
240     AC_DEFINE(HAVE_FLOORL)
241     AC_DEFINE(HAVE_FMODL)
242     AC_DEFINE(HAVE_FREXPL)
243     AC_DEFINE(HAVE_LDEXPL)
244     AC_DEFINE(HAVE_LOG10L)
245     AC_DEFINE(HAVE_LOGL)
246     AC_DEFINE(HAVE_MODFL)
247     AC_DEFINE(HAVE_POWL)
248     AC_DEFINE(HAVE_SINCOSL)
249     AC_DEFINE(HAVE_SINL)
250     AC_DEFINE(HAVE_SINHL)
251     AC_DEFINE(HAVE_SQRTL)
252     AC_DEFINE(HAVE_TANL)
253     AC_DEFINE(HAVE_TANHL)
254   fi
255
256 fi
257
258 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
259 GLIBCXX_ENABLE_SYMVERS([yes])
260
261 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
262 GLIBCXX_CONFIGURE_TESTSUITE
263
264 # Propagate the target-specific source directories through the build chain.
265 # (Nothing currently uses cpu_include_dir directly; only atomicity_include_dir 
266 # uses it, and it only gets used in this file.)
267 ATOMICITY_INC_SRCDIR=config/${atomicity_include_dir}
268 OS_INC_SRCDIR=config/${os_include_dir}
269 AC_SUBST(ATOMICITY_INC_SRCDIR)
270 AC_SUBST(OS_INC_SRCDIR)
271
272 # Determine cross-compile flags and AM_CONDITIONALs.
273 #AC_SUBST(GLIBCXX_IS_NATIVE)
274 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
275 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
276 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
277 GLIBCXX_EVALUATE_CONDITIONALS
278  
279 AC_CACHE_SAVE
280
281 if test ${multilib} = yes; then
282   multilib_arg="--enable-multilib"
283 else
284   multilib_arg=
285 fi
286
287 # Export all the install information.
288 GLIBCXX_EXPORT_INSTALL_INFO
289
290 # Export all the include and flag information to Makefiles.
291 GLIBCXX_EXPORT_INCLUDES
292 GLIBCXX_EXPORT_FLAGS
293
294 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
295    grep "enable shared" > /dev/null;
296 then
297   LIBSUPCXX_PICFLAGS=-prefer-pic
298 else
299   LIBSUPCXX_PICFLAGS=
300 fi
301 AC_SUBST(LIBSUPCXX_PICFLAGS)
302
303 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
304 dnl which can all be called multiple times as needed, plus one (different)
305 dnl AC_OUTPUT macro.  This one lists the files to be created:
306 AC_CONFIG_FILES( \
307   Makefile \
308   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
309   )
310 AC_CONFIG_FILES([scripts/check_survey],[chmod +x scripts/check_survey])
311 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
312
313 dnl These commands are run at the end of config.status:
314 AC_CONFIG_COMMANDS([default],
315 [if test -n "$CONFIG_FILES"; then
316    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
317    # that multilib installs will end up installed in the correct place.
318    # The testsuite needs it for multilib-aware ABI baseline files.
319    # To work around this not being passed down from config-ml.in ->
320    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
321    # append it here.  Only modify Makefiles that have just been created.
322    #
323    # Also, get rid of this simulated-VPATH thing that automake does.
324    cat > vpsed << \_EOF
325 s!`test -f '$<' || echo '$(srcdir)/'`!!
326 _EOF
327    for i in $SUBDIRS; do
328     case $CONFIG_FILES in
329      *${i}/Makefile*)
330        #echo "Adding MULTISUBDIR to $i/Makefile"
331        sed -f vpsed $i/Makefile > tmp
332        grep '^MULTISUBDIR =' Makefile >> tmp
333        mv tmp $i/Makefile
334        ;;
335     esac
336    done
337    rm vpsed
338  fi
339  (cd include && ${MAKE-make})
340 ],
341 [
342 # Variables needed in config.status (file generation) which aren't already
343 # passed by autoconf.
344 SUBDIRS="$SUBDIRS"
345 ])
346
347 dnl And this actually makes things happen:
348 AC_OUTPUT