libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:11:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 if test "x${with_newlib}" != "xyes"; then
  86   AC_LIBTOOL_DLOPEN
  87 fi
  88 AM_PROG_LIBTOOL
  89 AC_SUBST(enable_shared)
  90 AC_SUBST(enable_static)
  91
  92 # Possibly disable most of the library.
  93 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  94 ## than just ignoring the results.  Faster /and/ more correct, win win.
  95 GLIBCXX_ENABLE_HOSTED
  96
  97 # Enable compiler support that doesn't require linking.
  98 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  99 GLIBCXX_ENABLE_PCH($is_hosted)
 100 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 101 GLIBCXX_ENABLE_THREADS
 102
 103 # Checks for compiler support that don't require linking.
 104 GLIBCXX_CHECK_COMPILER_FEATURES
 105 GLIBCXX_CHECK_STANDARD_LAYOUT
 106
 107 # Enable all the variable C++ runtime options that doesn't require linking.
 108 GLIBCXX_ENABLE_CSTDIO
 109 GLIBCXX_ENABLE_CLOCALE
 110 GLIBCXX_ENABLE_ALLOCATOR
 111 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 112 GLIBCXX_ENABLE_LONG_LONG([yes])
 113 GLIBCXX_ENABLE_WCHAR_T([yes])
 114 GLIBCXX_ENABLE_C99([yes])
 115 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 116 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 117 GLIBCXX_ENABLE_DEBUG([no])
 118 GLIBCXX_ENABLE_PARALLEL([yes])
 119 GLIBCXX_ENABLE_CXX_FLAGS
 120 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 121
 122 # Checks for operating systems support that don't require linking.
 123 GLIBCXX_CHECK_SYSTEM_ERROR
 124
 125 # For common values of EOF, SEEK_CUR, SEEK_END.
 126 GLIBCXX_CHECK_STDIO_MACROS
 127
 128 # Only do link tests if native. Else, hardcode.
 129 if $GLIBCXX_IS_NATIVE; then
 130
 131   # We can do more elaborate tests that assume a working linker.
 132   CANADIAN=no
 133
 134   # Check for available headers.
 135   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 136   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h \
 137   sys/types.h sys/ipc.h sys/sem.h])
 138
 139   GLIBCXX_CHECK_LINKER_FEATURES
 140   GLIBCXX_CHECK_MATH_SUPPORT
 141   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 142   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 143   GLIBCXX_CHECK_STDLIB_SUPPORT
 144
 145   # For showmanyc_helper().
 146   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 147   GLIBCXX_CHECK_POLL
 148   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 149
 150   # For xsputn_2().
 151   AC_CHECK_HEADERS(sys/uio.h)
 152   GLIBCXX_CHECK_WRITEV
 153
 154   # For the __streamoff_base_type typedef.
 155   GLIBCXX_CHECK_INT64_T
 156
 157   # For LFS support.
 158   GLIBCXX_CHECK_LFS
 159
 160   # For C99 support to TR1.
 161   GLIBCXX_CHECK_C99_TR1
 162
 163   # For dev/random and dev/urandom for TR1.
 164   GLIBCXX_CHECK_RANDOM_TR1
 165
 166   # For clock_gettime support.
 167   GLIBCXX_CHECK_CLOCK_GETTIME
 168
 169   # For gettimeofday support.
 170   GLIBCXX_CHECK_GETTIMEOFDAY
 171
 172   # For TLS support.
 173   GCC_CHECK_TLS
 174
 175   # For _Unwind_GetIPInfo.
 176   GCC_CHECK_UNWIND_GETIPINFO
 177
 178   AC_LC_MESSAGES
 179
 180   AC_TRY_COMPILE(
 181     [#include <setjmp.h>],
 182     [sigjmp_buf env;
 183      while (! sigsetjmp (env, 1))
 184        siglongjmp (env, 1);
 185     ],
 186     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 187
 188   AC_FUNC_MMAP
 189
 190   # For iconv support.
 191   AM_ICONV
 192
 193 else
 194
 195   # This lets us hard-code the functionality we know we'll have in the cross
 196   # target environment.  "Let" is a sugar-coated word placed on an especially
 197   # dull and tedious hack, actually.
 198   #
 199   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 200   # that involve linking, can't be used:
 201   #    "cannot open sim-crt0.o"
 202   #    "cannot open crt0.o"
 203   # etc.  All this is because there currently exists no unified, consistent
 204   # way for top level CC information to be passed down to target directories:
 205   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 206   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 207   # crosses can be removed.
 208
 209   # If Canadian cross, then don't pick up tools from the build directory.
 210   # Used only in GLIBCXX_EXPORT_INCLUDES.
 211   if test -n "$with_cross_host" &&
 212      test x"$build_alias" != x"$with_cross_host" &&
 213      test x"$build" != x"$target";
 214   then
 215     CANADIAN=yes
 216   else
 217     CANADIAN=no
 218   fi
 219
 220   # Construct crosses by hand, eliminating bits that need ld...
 221   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 222   # GLIBCXX_CHECK_MATH_SUPPORT
 223
 224   # First, test for "known" system libraries.  We may be using newlib even
 225   # on a hosted environment.
 226   if test "x${with_newlib}" = "xyes"; then
 227     os_include_dir="os/newlib"
 228     AC_DEFINE(HAVE_HYPOT)
 229
 230     # GLIBCXX_CHECK_STDLIB_SUPPORT
 231     AC_DEFINE(HAVE_STRTOF)
 232     # AC_FUNC_MMAP
 233     AC_DEFINE(HAVE_MMAP)
 234
 235     AC_DEFINE(HAVE_ACOSF)
 236     AC_DEFINE(HAVE_ASINF)
 237     AC_DEFINE(HAVE_ATAN2F)
 238     AC_DEFINE(HAVE_ATANF)
 239     AC_DEFINE(HAVE_CEILF)
 240     AC_DEFINE(HAVE_COPYSIGN)
 241     AC_DEFINE(HAVE_COPYSIGNF)
 242     AC_DEFINE(HAVE_COSF)
 243     AC_DEFINE(HAVE_COSHF)
 244     AC_DEFINE(HAVE_EXPF)
 245     AC_DEFINE(HAVE_FABSF)
 246     AC_DEFINE(HAVE_FLOORF)
 247     AC_DEFINE(HAVE_FMODF)
 248     AC_DEFINE(HAVE_FREXPF)
 249     AC_DEFINE(HAVE_LDEXPF)
 250     AC_DEFINE(HAVE_LOG10F)
 251     AC_DEFINE(HAVE_LOGF)
 252     AC_DEFINE(HAVE_MODFF)
 253     AC_DEFINE(HAVE_POWF)
 254     AC_DEFINE(HAVE_SINF)
 255     AC_DEFINE(HAVE_SINHF)
 256     AC_DEFINE(HAVE_SQRTF)
 257     AC_DEFINE(HAVE_TANF)
 258     AC_DEFINE(HAVE_TANHF)
 259
 260     AC_DEFINE(HAVE_S_ISREG)
 261     AC_DEFINE(HAVE_S_IFREG)
 262
 263     AC_DEFINE(HAVE_ICONV)
 264   else
 265     GLIBCXX_CROSSCONFIG
 266   fi
 267
 268   # At some point, we should differentiate between architectures
 269   # like x86, which have long double versions, and alpha/powerpc/etc.,
 270   # which don't. For the time being, punt.
 271   if test x"long_double_math_on_this_cpu" = x"yes"; then
 272     AC_DEFINE(HAVE_ACOSL)
 273     AC_DEFINE(HAVE_ASINL)
 274     AC_DEFINE(HAVE_ATAN2L)
 275     AC_DEFINE(HAVE_ATANL)
 276     AC_DEFINE(HAVE_CEILL)
 277     AC_DEFINE(HAVE_COPYSIGNL)
 278     AC_DEFINE(HAVE_COSL)
 279     AC_DEFINE(HAVE_COSHL)
 280     AC_DEFINE(HAVE_EXPL)
 281     AC_DEFINE(HAVE_FABSL)
 282     AC_DEFINE(HAVE_FLOORL)
 283     AC_DEFINE(HAVE_FMODL)
 284     AC_DEFINE(HAVE_FREXPL)
 285     AC_DEFINE(HAVE_LDEXPL)
 286     AC_DEFINE(HAVE_LOG10L)
 287     AC_DEFINE(HAVE_LOGL)
 288     AC_DEFINE(HAVE_MODFL)
 289     AC_DEFINE(HAVE_POWL)
 290     AC_DEFINE(HAVE_SINCOSL)
 291     AC_DEFINE(HAVE_SINL)
 292     AC_DEFINE(HAVE_SINHL)
 293     AC_DEFINE(HAVE_SQRTL)
 294     AC_DEFINE(HAVE_TANL)
 295     AC_DEFINE(HAVE_TANHL)
 296   fi
 297
 298   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 299   AC_DEFINE(HAVE_GETIPINFO)
 300 fi
 301
 302 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 303
 304 GCC_HEADER_STDINT(include/gstdint.h)
 305
 306 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 307 GLIBCXX_ENABLE_SYMVERS([yes])
 308 GLIBCXX_ENABLE_VISIBILITY([yes])
 309
 310 ac_ldbl_compat=no
 311 case "$target" in
 312   powerpc*-*-linux* | \
 313   powerpc*-*-gnu* | \
 314   sparc*-*-linux* | \
 315   s390*-*-linux* | \
 316   alpha*-*-linux*)
 317   AC_TRY_COMPILE(, [
 318 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 319 #error no need for long double compatibility
 320 #endif
 321   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 322   if test "$ac_ldbl_compat" = yes; then
 323     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 324               [Define if compatibility should be provided for -mlong-double-64.])
 325     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 326   fi
 327 esac
 328 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 329
 330 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 331 GLIBCXX_CONFIGURE_TESTSUITE
 332
 333 # Propagate the target-specific source directories through the build chain.
 334 ATOMICITY_SRCDIR=config/${atomicity_dir}
 335 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 336 ATOMIC_FLAGS=${atomic_flags}
 337 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 338 OS_INC_SRCDIR=config/${os_include_dir}
 339 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 340 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 341 AC_SUBST(ATOMICITY_SRCDIR)
 342 AC_SUBST(ATOMIC_WORD_SRCDIR)
 343 AC_SUBST(ATOMIC_FLAGS)
 344 AC_SUBST(CPU_DEFINES_SRCDIR)
 345 AC_SUBST(ABI_TWEAKS_SRCDIR)
 346 AC_SUBST(OS_INC_SRCDIR)
 347 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 348
 349
 350 # Determine cross-compile flags and AM_CONDITIONALs.
 351 #AC_SUBST(GLIBCXX_IS_NATIVE)
 352 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 353 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 354 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 355 GLIBCXX_EVALUATE_CONDITIONALS
 356
 357 AC_CACHE_SAVE
 358
 359 if test ${multilib} = yes; then
 360   multilib_arg="--enable-multilib"
 361 else
 362   multilib_arg=
 363 fi
 364
 365 # Export all the install information.
 366 GLIBCXX_EXPORT_INSTALL_INFO
 367
 368 # Export all the include and flag information to Makefiles.
 369 GLIBCXX_EXPORT_INCLUDES
 370 GLIBCXX_EXPORT_FLAGS
 371
 372 if test "$enable_shared" = yes; then
 373   LIBSUPCXX_PICFLAGS="-prefer-pic"
 374 else
 375   LIBSUPCXX_PICFLAGS=
 376 fi
 377 AC_SUBST(LIBSUPCXX_PICFLAGS)
 378
 379 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 380 dnl which can all be called multiple times as needed, plus one (different)
 381 dnl AC_OUTPUT macro.  This one lists the files to be created:
 382 AC_CONFIG_FILES( \
 383   Makefile \
 384   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 385   )
 386 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 387
 388 dnl These commands are run at the end of config.status:
 389 AC_CONFIG_COMMANDS([default],
 390 [if test -n "$CONFIG_FILES"; then
 391    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 392    # that multilib installs will end up installed in the correct place.
 393    # The testsuite needs it for multilib-aware ABI baseline files.
 394    # To work around this not being passed down from config-ml.in ->
 395    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 396    # append it here.  Only modify Makefiles that have just been created.
 397    #
 398    # Also, get rid of this simulated-VPATH thing that automake does.
 399    cat > vpsed << \_EOF
 400 s!`test -f '$<' || echo '$(srcdir)/'`!!
 401 _EOF
 402    for i in $SUBDIRS; do
 403     case $CONFIG_FILES in
 404      *${i}/Makefile*)
 405        #echo "Adding MULTISUBDIR to $i/Makefile"
 406        sed -f vpsed $i/Makefile > tmp
 407        grep '^MULTISUBDIR =' Makefile >> tmp
 408        mv tmp $i/Makefile
 409        ;;
 410     esac
 411    done
 412    rm vpsed
 413  fi
 414  (cd include && ${MAKE-make})
 415 ],
 416 [
 417 # Variables needed in config.status (file generation) which aren't already
 418 # passed by autoconf.
 419 SUBDIRS="$SUBDIRS"
 420 ])
 421
 422 dnl And this actually makes things happen:
 423 AC_OUTPUT