OSDN Git Service

Backported from mainline
[pf3gnuchains/gcc-fork.git] / libstdc++-v3 / configure.ac
1 # Process this file with autoreconf to produce a configure script.
2
3 AC_PREREQ(2.64)
4 AC_INIT(package-unused, version-unused,, libstdc++)
5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
6 AC_CONFIG_HEADER(config.h)
7
8 # This works around the fact that libtool configuration may change LD
9 # for this particular configuration, but some shells, instead of
10 # keeping the changes in LD private, export them just because LD is
11 # exported.  Only used at the end of this file.
12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
13
14 # Find the rest of the source tree framework.
15 AM_ENABLE_MULTILIB(, ..)
16
17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
18 #
19 # You will slowly go insane if you do not grok the following fact:  when
20 # building v3 as part of the compiler, the top-level /target/ becomes the
21 # library's /host/.  configure then causes --target to default to --host,
22 # exactly like any other package using autoconf.  Therefore, 'target' and
23 # 'host' will always be the same.  This makes sense both for native and
24 # cross compilers, just think about it for a little while.  :-)
25 #
26 # Also, if v3 is being configured as part of a cross compiler, the top-level
27 # configure script will pass the "real" host as $with_cross_host.
28 #
29 # Do not delete or change the following two lines.  For why, see
30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
31 AC_CANONICAL_SYSTEM
32 target_alias=${target_alias-$host_alias}
33
34 # Handy for debugging:
35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
36
37 if test "$build" != "$host"; then
38   # We are being configured with some form of cross compiler.
39   GLIBCXX_IS_NATIVE=false
40   case "$host","$target" in
41     # Darwin crosses can use the host system's libraries and headers,
42     # because of the fat library support.  Of course, it must be the
43     # same version of Darwin on both sides.  Allow the user to
44     # just say --target=foo-darwin without a version number to mean
45     # "the version on this system".
46       *-*-darwin*,*-*-darwin*)
47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
49         if test $hostos = $targetos -o $targetos = darwin ; then
50           GLIBCXX_IS_NATIVE=true
51         fi
52         ;;
53
54       *)
55         GCC_NO_EXECUTABLES
56         ;;
57   esac
58 else
59   GLIBCXX_IS_NATIVE=true
60 fi
61
62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
64 #  1.x:  minimum required version
65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
66 #              of other PACKAGE_* variables will, however, and there's nothing
67 #              we can do about that; they come from AC_INIT).
68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
69 #            file in the top srcdir, etc, etc), so stop complaining.
70 #  no-dependencies:  turns off auto dependency generation (just for now)
71 #  no-dist:  we don't want 'dist' and related rules.
72 #  -Wall:  turns on all automake warnings...
73 #  -Wno-portability:  ...except this one, since GNU make is now required.
74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
75 AH_TEMPLATE(PACKAGE, [Name of package])
76 AH_TEMPLATE(VERSION, [Version number of package])
77
78 # -fno-builtin must be present here so that a non-conflicting form of
79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
80
81 save_CXXFLAGS="$CXXFLAGS"
82 CXXFLAGS="$CXXFLAGS -fno-builtin"
83 AC_PROG_CC
84 AC_PROG_CXX
85 CXXFLAGS="$save_CXXFLAGS"
86
87 # Runs configure.host, and assorted other critical bits.  Sets
88 # up critical shell variables.
89 GLIBCXX_CONFIGURE
90
91 # Libtool setup.
92 if test "x${with_newlib}" != "xyes"; then
93   AC_LIBTOOL_DLOPEN
94 fi
95 AM_PROG_LIBTOOL
96 ACX_LT_HOST_FLAGS
97 AC_SUBST(enable_shared)
98 AC_SUBST(enable_static)
99
100 # libtool variables for C++ shared and position-independent compiles.
101 #
102 # Use glibcxx_lt_pic_flag to designate the automake variable
103 # used to encapsulate the default libtool approach to creating objects
104 # with position-independent code. Default: -prefer-pic.
105 #
106 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
107 # creating shared objects. Default: -D_GLIBCXX_SHARED.
108 #
109 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
110 # creating position-independent objects. This varies with the target
111 # hardware and operating system, but is often: -DPIC -fPIC.
112 if test "$enable_shared" = yes; then
113   glibcxx_lt_pic_flag="-prefer-pic"
114   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
115   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
116
117 else
118   glibcxx_lt_pic_flag=
119   glibcxx_compiler_pic_flag=
120   glibcxx_compiler_shared_flag=
121 fi
122 AC_SUBST(glibcxx_lt_pic_flag)
123 AC_SUBST(glibcxx_compiler_pic_flag)
124 AC_SUBST(glibcxx_compiler_shared_flag)
125
126 # Override the libtool's pic_flag and pic_mode.
127 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
128 # NB: this impacts --with-pic and --without-pic.
129 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
130 pic_mode='default'
131
132 # Eliminate -lstdc++ addition to postdeps for cross compiles.
133 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
134
135 # Possibly disable most of the library.
136 ## TODO: Consider skipping unncessary tests altogether in this case, rather
137 ## than just ignoring the results.  Faster /and/ more correct, win win.
138 GLIBCXX_ENABLE_HOSTED
139
140 # Enable compiler support that doesn't require linking.
141 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
142 GLIBCXX_ENABLE_PCH($is_hosted)
143 GLIBCXX_ENABLE_THREADS
144 GLIBCXX_ENABLE_ATOMIC_BUILTINS
145 GLIBCXX_ENABLE_DECIMAL_FLOAT
146 GLIBCXX_ENABLE_INT128_FLOAT128
147
148 # Checks for compiler support that doesn't require linking.
149 GLIBCXX_CHECK_COMPILER_FEATURES
150
151 # Enable all the variable C++ runtime options that don't require linking.
152 GLIBCXX_ENABLE_CSTDIO
153 GLIBCXX_ENABLE_CLOCALE
154 GLIBCXX_ENABLE_ALLOCATOR
155 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
156 GLIBCXX_ENABLE_LONG_LONG([yes])
157 GLIBCXX_ENABLE_WCHAR_T([yes])
158 GLIBCXX_ENABLE_C99([yes])
159 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
160 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
161 GLIBCXX_ENABLE_DEBUG([no])
162 GLIBCXX_ENABLE_PARALLEL([yes])
163 GLIBCXX_ENABLE_CXX_FLAGS
164 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
165 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
166 GLIBCXX_ENABLE_PYTHON
167 GLIBCXX_ENABLE_WERROR([yes])
168
169 # Checks for operating systems support that doesn't require linking.
170 GLIBCXX_CHECK_MATH_PROTO
171 GLIBCXX_CHECK_STDLIB_PROTO
172 GLIBCXX_CHECK_STDIO_PROTO
173 GLIBCXX_CHECK_SYSTEM_ERROR
174
175 # For the streamoff typedef.
176 GLIBCXX_CHECK_INT64_T
177
178 # For LFS support.
179 GLIBCXX_CHECK_LFS
180
181 # For showmanyc_helper().
182 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
183 GLIBCXX_CHECK_POLL
184 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
185
186 # For xsputn_2().
187 AC_CHECK_HEADERS(sys/uio.h)
188 GLIBCXX_CHECK_WRITEV
189
190 # For C99 support to TR1.
191 GLIBCXX_CHECK_C99_TR1
192
193 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
194 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
195
196 # For gettimeofday support.
197 GLIBCXX_CHECK_GETTIMEOFDAY
198
199 # For clock_gettime, nanosleep and sched_yield support.
200 # NB: The default is [no], because otherwise it requires linking.
201 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
202
203 AC_LC_MESSAGES
204
205 # For hardware_concurrency
206 AC_CHECK_HEADERS(sys/sysinfo.h)
207 GLIBCXX_CHECK_GET_NPROCS
208 AC_CHECK_HEADERS(unistd.h)
209 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
210 GLIBCXX_CHECK_SC_NPROC_ONLN
211 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
212 GLIBCXX_CHECK_SYSCTL_HW_NCPU
213
214 # Check for available headers.
215 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
216 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
217 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
218 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
219 wchar.h wctype.h])
220
221 # Only do link tests if native. Else, hardcode.
222 if $GLIBCXX_IS_NATIVE; then
223
224   # We can do more elaborate tests that assume a working linker.
225   CANADIAN=no
226
227   GLIBCXX_CHECK_LINKER_FEATURES
228   GLIBCXX_CHECK_MATH_SUPPORT
229   GLIBCXX_CHECK_STDLIB_SUPPORT
230
231   # For /dev/random and /dev/urandom for TR1.
232   GLIBCXX_CHECK_RANDOM_TR1
233
234   # For TLS support.
235   GCC_CHECK_TLS
236
237   # For iconv support.
238   AM_ICONV
239
240 else
241
242   # This lets us hard-code the functionality we know we'll have in the cross
243   # target environment.  "Let" is a sugar-coated word placed on an especially
244   # dull and tedious hack, actually.
245   #
246   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
247   # that involve linking, can't be used:
248   #    "cannot open sim-crt0.o"
249   #    "cannot open crt0.o"
250   # etc.  All this is because there currently exists no unified, consistent
251   # way for top level CC information to be passed down to target directories:
252   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
253   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
254   # crosses can be removed.
255
256   # If Canadian cross, then don't pick up tools from the build directory.
257   # Used only in GLIBCXX_EXPORT_INCLUDES.
258   if test -n "$with_cross_host" &&
259      test x"$build_alias" != x"$with_cross_host" &&
260      test x"$build" != x"$target";
261   then
262     CANADIAN=yes
263   else
264     CANADIAN=no
265   fi
266
267   # Construct crosses by hand, eliminating bits that need ld...
268   # GLIBCXX_CHECK_MATH_SUPPORT
269
270   # First, test for "known" system libraries.  We may be using newlib even
271   # on a hosted environment.
272   if test "x${with_newlib}" = "xyes"; then
273     os_include_dir="os/newlib"
274     AC_DEFINE(HAVE_HYPOT)
275
276     # GLIBCXX_CHECK_STDLIB_SUPPORT
277     AC_DEFINE(HAVE_STRTOF)
278
279     AC_DEFINE(HAVE_ACOSF)
280     AC_DEFINE(HAVE_ASINF)
281     AC_DEFINE(HAVE_ATAN2F)
282     AC_DEFINE(HAVE_ATANF)
283     AC_DEFINE(HAVE_CEILF)
284     AC_DEFINE(HAVE_COSF)
285     AC_DEFINE(HAVE_COSHF)
286     AC_DEFINE(HAVE_EXPF)
287     AC_DEFINE(HAVE_FABSF)
288     AC_DEFINE(HAVE_FLOORF)
289     AC_DEFINE(HAVE_FMODF)
290     AC_DEFINE(HAVE_FREXPF)
291     AC_DEFINE(HAVE_LDEXPF)
292     AC_DEFINE(HAVE_LOG10F)
293     AC_DEFINE(HAVE_LOGF)
294     AC_DEFINE(HAVE_MODFF)
295     AC_DEFINE(HAVE_POWF)
296     AC_DEFINE(HAVE_SINF)
297     AC_DEFINE(HAVE_SINHF)
298     AC_DEFINE(HAVE_SQRTF)
299     AC_DEFINE(HAVE_TANF)
300     AC_DEFINE(HAVE_TANHF)
301
302     AC_DEFINE(HAVE_ICONV)
303   else
304     GLIBCXX_CROSSCONFIG
305   fi
306
307   # At some point, we should differentiate between architectures
308   # like x86, which have long double versions, and alpha/powerpc/etc.,
309   # which don't. For the time being, punt.
310   if test x"long_double_math_on_this_cpu" = x"yes"; then
311     AC_DEFINE(HAVE_ACOSL)
312     AC_DEFINE(HAVE_ASINL)
313     AC_DEFINE(HAVE_ATAN2L)
314     AC_DEFINE(HAVE_ATANL)
315     AC_DEFINE(HAVE_CEILL)
316     AC_DEFINE(HAVE_COSL)
317     AC_DEFINE(HAVE_COSHL)
318     AC_DEFINE(HAVE_EXPL)
319     AC_DEFINE(HAVE_FABSL)
320     AC_DEFINE(HAVE_FLOORL)
321     AC_DEFINE(HAVE_FMODL)
322     AC_DEFINE(HAVE_FREXPL)
323     AC_DEFINE(HAVE_LDEXPL)
324     AC_DEFINE(HAVE_LOG10L)
325     AC_DEFINE(HAVE_LOGL)
326     AC_DEFINE(HAVE_MODFL)
327     AC_DEFINE(HAVE_POWL)
328     AC_DEFINE(HAVE_SINCOSL)
329     AC_DEFINE(HAVE_SINL)
330     AC_DEFINE(HAVE_SINHL)
331     AC_DEFINE(HAVE_SQRTL)
332     AC_DEFINE(HAVE_TANL)
333     AC_DEFINE(HAVE_TANHL)
334   fi
335 fi
336
337 # Check for _Unwind_GetIPInfo.
338 GCC_CHECK_UNWIND_GETIPINFO
339
340 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
341
342 GCC_HEADER_STDINT(include/gstdint.h)
343
344 GLIBCXX_ENABLE_SYMVERS([yes])
345 AC_SUBST(libtool_VERSION)
346
347 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
348
349 ac_ldbl_compat=no
350 case "$target" in
351   powerpc*-*-linux* | \
352   sparc*-*-linux* | \
353   s390*-*-linux* | \
354   alpha*-*-linux*)
355   AC_TRY_COMPILE(, [
356 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
357 #error no need for long double compatibility
358 #endif
359   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
360   if test "$ac_ldbl_compat" = yes; then
361     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
362               [Define if compatibility should be provided for -mlong-double-64.])
363     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
364   fi
365 esac
366 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
367
368 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
369 GLIBCXX_CONFIGURE_TESTSUITE
370
371 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
372 GLIBCXX_CHECK_GTHREADS
373
374 # Define documentation rules conditionally.
375
376 # See if makeinfo has been installed and is modern enough
377 # that we can use it.
378 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
379                    [GNU texinfo.* \([0-9][0-9.]*\)],
380                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
381 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
382
383 # Check for doxygen
384 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
385 AC_CHECK_PROG([DOT], dot, yes, no)
386
387 # Check for docbook
388 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
389 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
390 GLIBCXX_CONFIGURE_DOCBOOK
391
392 # Check for xml/html dependencies.
393 AM_CONDITIONAL(BUILD_XML,
394                test $ac_cv_prog_DOXYGEN = "yes" &&
395                test $ac_cv_prog_DOT = "yes" &&
396                test $ac_cv_prog_XSLTPROC = "yes" &&
397                test $ac_cv_prog_XMLLINT = "yes" &&
398                test $glibcxx_stylesheets = "yes")
399
400 AM_CONDITIONAL(BUILD_HTML,
401                test $ac_cv_prog_DOXYGEN = "yes" &&
402                test $ac_cv_prog_DOT = "yes" &&
403                test $ac_cv_prog_XSLTPROC = "yes" &&
404                test $ac_cv_prog_XMLLINT = "yes" &&
405                test $glibcxx_stylesheets = "yes")
406
407 # Check for man dependencies.
408 AM_CONDITIONAL(BUILD_MAN,
409                test $ac_cv_prog_DOXYGEN = "yes" &&
410                test $ac_cv_prog_DOT = "yes")
411
412 # Check for pdf dependencies.
413 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
414 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
415 AM_CONDITIONAL(BUILD_PDF,
416                test $ac_cv_prog_DBLATEX = "yes" &&
417                test $ac_cv_prog_PDFLATEX = "yes")
418
419
420 # Propagate the target-specific source directories through the build chain.
421 ATOMICITY_SRCDIR=config/${atomicity_dir}
422 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
423 ATOMIC_FLAGS=${atomic_flags}
424 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
425 OS_INC_SRCDIR=config/${os_include_dir}
426 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
427 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
428 AC_SUBST(ATOMICITY_SRCDIR)
429 AC_SUBST(ATOMIC_WORD_SRCDIR)
430 AC_SUBST(ATOMIC_FLAGS)
431 AC_SUBST(CPU_DEFINES_SRCDIR)
432 AC_SUBST(ABI_TWEAKS_SRCDIR)
433 AC_SUBST(OS_INC_SRCDIR)
434 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
435
436
437 # Determine cross-compile flags and AM_CONDITIONALs.
438 #AC_SUBST(GLIBCXX_IS_NATIVE)
439 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
440 GLIBCXX_EVALUATE_CONDITIONALS
441
442 AC_CACHE_SAVE
443
444 if test ${multilib} = yes; then
445   multilib_arg="--enable-multilib"
446 else
447   multilib_arg=
448 fi
449
450 # Export all the install information.
451 GLIBCXX_EXPORT_INSTALL_INFO
452
453 # Export all the include and flag information to Makefiles.
454 GLIBCXX_EXPORT_INCLUDES
455 GLIBCXX_EXPORT_FLAGS
456
457 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
458 dnl which can all be called multiple times as needed, plus one (different)
459 dnl AC_OUTPUT macro.  This one lists the files to be created:
460 AC_CONFIG_FILES(Makefile)
461 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
462 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
463 AC_CONFIG_FILES([doc/xsl/customization.xsl])
464
465 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
466 # that multilib installs will end up installed in the correct place.
467 # The testsuite needs it for multilib-aware ABI baseline files.
468 # To work around this not being passed down from config-ml.in ->
469 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
470 # append it here.  Only modify Makefiles that have just been created.
471 #
472 # Also, get rid of this simulated-VPATH thing that automake does.
473 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
474   [cat > vpsed$$ << \_EOF
475 s!`test -f '$<' || echo '$(srcdir)/'`!!
476 _EOF
477    sed -f vpsed$$ $ac_file > tmp$$
478    mv tmp$$ $ac_file
479    rm vpsed$$
480    echo 'MULTISUBDIR =' >> $ac_file
481    ml_norecursion=yes
482    . ${multi_basedir}/config-ml.in
483    AS_UNSET([ml_norecursion])
484 ])
485
486 AC_CONFIG_COMMANDS([generate-headers],
487   [(cd include && ${MAKE-make} pch_build= )])
488
489 dnl And this actually makes things happen:
490 AC_OUTPUT