OSDN Git Service

c1b36c9a75b258976c8d9a3d82412789375aa35c
[pf3gnuchains/gcc-fork.git] / libstdc++-v3 / configure.ac
1 # Process this file with autoreconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT(package-unused, version-unused,, libstdc++)
5 AC_CONFIG_SRCDIR(src/ios.cc)
6 AC_CONFIG_HEADER(config.h)
7
8 # This works around the fact that libtool configuration may change LD
9 # for this particular configuration, but some shells, instead of
10 # keeping the changes in LD private, export them just because LD is
11 # exported.  Only used at the end of this file.
12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
13
14 # For libtool versioning info, format is CURRENT:REVISION:AGE
15 libtool_VERSION=6:9:0
16 AC_SUBST(libtool_VERSION)
17
18 # Find the rest of the source tree framework.
19 AM_ENABLE_MULTILIB(, ..)
20
21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
22 #
23 # You will slowly go insane if you do not grok the following fact:  when
24 # building v3 as part of the compiler, the top-level /target/ becomes the
25 # library's /host/.  configure then causes --target to default to --host,
26 # exactly like any other package using autoconf.  Therefore, 'target' and
27 # 'host' will always be the same.  This makes sense both for native and
28 # cross compilers, just think about it for a little while.  :-)
29 #
30 # Also, if v3 is being configured as part of a cross compiler, the top-level
31 # configure script will pass the "real" host as $with_cross_host.
32 #
33 # Do not delete or change the following two lines.  For why, see
34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
35 AC_CANONICAL_SYSTEM
36 target_alias=${target_alias-$host_alias}
37
38 # Handy for debugging:
39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
40
41 if test "$build" != "$host"; then
42   # We are being configured with some form of cross compiler.
43   GLIBCXX_IS_NATIVE=false
44   case "$host","$target" in
45     # Darwin crosses can use the host system's libraries and headers,
46     # because of the fat library support.  Of course, it must be the
47     # same version of Darwin on both sides.  Allow the user to
48     # just say --target=foo-darwin without a version number to mean
49     # "the version on this system".
50       *-*-darwin*,*-*-darwin*)
51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
53         if test $hostos = $targetos -o $targetos = darwin ; then
54           GLIBCXX_IS_NATIVE=true
55         fi
56         ;;
57
58       *)
59         GCC_NO_EXECUTABLES
60         ;;
61   esac
62 else
63   GLIBCXX_IS_NATIVE=true
64 fi
65
66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
68 #  1.x:  minimum required version
69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
70 #              of other PACKAGE_* variables will, however, and there's nothing
71 #              we can do about that; they come from AC_INIT).
72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
73 #            file in the top srcdir, etc, etc), so stop complaining.
74 #  no-dependencies:  turns off auto dependency generation (just for now)
75 #  -Wall:  turns on all automake warnings...
76 #  -Wno-portability:  ...except this one, since GNU make is now required.
77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
78 AH_TEMPLATE(PACKAGE, [Name of package])
79 AH_TEMPLATE(VERSION, [Version number of package])
80
81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
82 # up critical shell variables.
83 GLIBCXX_CONFIGURE
84
85 AC_LIBTOOL_DLOPEN
86 AM_PROG_LIBTOOL
87 AC_SUBST(enable_shared)
88 AC_SUBST(enable_static)
89
90 # Possibly disable most of the library.
91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
92 ## than just ignoring the results.  Faster /and/ more correct, win win.
93 GLIBCXX_ENABLE_HOSTED
94
95 # Check for compiler support that doesn't require linking.
96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
97 GLIBCXX_ENABLE_PCH($is_hosted)
98
99 # Enable all the variable C++ runtime options.  
100 GLIBCXX_ENABLE_CSTDIO
101 GLIBCXX_ENABLE_CLOCALE
102 GLIBCXX_ENABLE_ALLOCATOR
103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
104 GLIBCXX_ENABLE_LONG_LONG([yes])
105 GLIBCXX_ENABLE_WCHAR_T([yes])
106 GLIBCXX_ENABLE_C99([yes])
107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
109 GLIBCXX_ENABLE_DEBUG([no])
110 GLIBCXX_ENABLE_CXX_FLAGS
111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
112
113 # No surprises, no surprises...
114 GLIBCXX_ENABLE_THREADS
115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
116 if test $atomicity_dir = cpu/generic/atomic_mutex ; then
117   AC_MSG_WARN([No native atomic operations are provided for this platform.])
118   if test $target_thread_file = single; then
119     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
120     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
121   else
122     AC_MSG_WARN([They will be faked using a mutex.])
123     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
124   fi
125 fi
126
127
128 if $GLIBCXX_IS_NATIVE; then
129
130   # We can do more elaborate tests that assume a working linker.
131   CANADIAN=no
132
133   # Check for available headers.
134   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
135   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
136   sys/types.h sys/ipc.h sys/sem.h])
137
138   GLIBCXX_CHECK_COMPILER_FEATURES
139   GLIBCXX_CHECK_LINKER_FEATURES
140   GLIBCXX_CHECK_MATH_SUPPORT
141   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
142   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
143   GLIBCXX_CHECK_ICONV_SUPPORT
144   GLIBCXX_CHECK_STDLIB_SUPPORT
145
146   # For showmanyc_helper().
147   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
148   GLIBCXX_CHECK_POLL
149   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
150
151   # For xsputn_2().
152   AC_CHECK_HEADERS(sys/uio.h)
153   GLIBCXX_CHECK_WRITEV
154
155   # For the __streamoff_base_type typedef.
156   GLIBCXX_CHECK_INT64_T
157
158   # For LFS support.
159   GLIBCXX_CHECK_LFS
160
161   # For C99 support to TR1.
162   GLIBCXX_CHECK_C99_TR1
163
164   # For dev/random and dev/urandom for TR1.
165   GLIBCXX_CHECK_RANDOM_TR1
166
167   # For TLS support.
168   GCC_CHECK_TLS
169
170   AC_LC_MESSAGES
171
172   AC_TRY_COMPILE(
173     [#include <setjmp.h>],
174     [sigjmp_buf env;
175      while (! sigsetjmp (env, 1))
176        siglongjmp (env, 1);
177     ],
178     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
179
180   AC_FUNC_MMAP
181
182 else
183
184   # This lets us hard-code the functionality we know we'll have in the cross
185   # target environment.  "Let" is a sugar-coated word placed on an especially
186   # dull and tedious hack, actually.
187   #
188   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
189   # that involve linking, can't be used:
190   #    "cannot open sim-crt0.o"
191   #    "cannot open crt0.o"
192   # etc.  All this is because there currently exists no unified, consistent
193   # way for top level CC information to be passed down to target directories:
194   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
195   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
196   # crosses can be removed.
197
198   # If Canadian cross, then don't pick up tools from the build directory.
199   # Used only in GLIBCXX_EXPORT_INCLUDES.
200   if test -n "$with_cross_host" &&
201      test x"$build_alias" != x"$with_cross_host" &&
202      test x"$build" != x"$target";
203   then
204     CANADIAN=yes
205   else
206     CANADIAN=no
207   fi
208
209   # Construct crosses by hand, eliminating bits that need ld...
210   # GLIBCXX_CHECK_COMPILER_FEATURES
211   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
212   # GLIBCXX_CHECK_MATH_SUPPORT
213
214   # First, test for "known" system libraries.  We may be using newlib even
215   # on a hosted environment.
216   if test "x${with_newlib}" = "xyes"; then
217     os_include_dir="os/newlib"
218     AC_DEFINE(HAVE_HYPOT)
219
220     # GLIBCXX_CHECK_STDLIB_SUPPORT
221     AC_DEFINE(HAVE_STRTOF)        
222     # AC_FUNC_MMAP
223     AC_DEFINE(HAVE_MMAP)
224
225     AC_DEFINE(HAVE_ACOSF)
226     AC_DEFINE(HAVE_ASINF)
227     AC_DEFINE(HAVE_ATAN2F)
228     AC_DEFINE(HAVE_ATANF)
229     AC_DEFINE(HAVE_CEILF)
230     AC_DEFINE(HAVE_COPYSIGN)
231     AC_DEFINE(HAVE_COPYSIGNF)
232     AC_DEFINE(HAVE_COSF)
233     AC_DEFINE(HAVE_COSHF)
234     AC_DEFINE(HAVE_EXPF)
235     AC_DEFINE(HAVE_FABSF)
236     AC_DEFINE(HAVE_FLOORF)
237     AC_DEFINE(HAVE_FMODF)
238     AC_DEFINE(HAVE_FREXPF)
239     AC_DEFINE(HAVE_LDEXPF)
240     AC_DEFINE(HAVE_LOG10F)
241     AC_DEFINE(HAVE_LOGF)
242     AC_DEFINE(HAVE_MODFF)
243     AC_DEFINE(HAVE_POWF)
244     AC_DEFINE(HAVE_SINF)
245     AC_DEFINE(HAVE_SINHF)
246     AC_DEFINE(HAVE_SQRTF)
247     AC_DEFINE(HAVE_TANF)
248     AC_DEFINE(HAVE_TANHF)
249
250     AC_DEFINE(HAVE_S_ISREG)
251     AC_DEFINE(HAVE_S_IFREG)
252   else
253     GLIBCXX_CROSSCONFIG
254   fi
255
256   # At some point, we should differentiate between architectures
257   # like x86, which have long double versions, and alpha/powerpc/etc.,
258   # which don't. For the time being, punt.
259   if test x"long_double_math_on_this_cpu" = x"yes"; then
260     AC_DEFINE(HAVE_ACOSL)
261     AC_DEFINE(HAVE_ASINL)
262     AC_DEFINE(HAVE_ATAN2L)
263     AC_DEFINE(HAVE_ATANL)
264     AC_DEFINE(HAVE_CEILL)
265     AC_DEFINE(HAVE_COPYSIGNL)
266     AC_DEFINE(HAVE_COSL)
267     AC_DEFINE(HAVE_COSHL)
268     AC_DEFINE(HAVE_EXPL)
269     AC_DEFINE(HAVE_FABSL)
270     AC_DEFINE(HAVE_FLOORL)
271     AC_DEFINE(HAVE_FMODL)
272     AC_DEFINE(HAVE_FREXPL)
273     AC_DEFINE(HAVE_LDEXPL)
274     AC_DEFINE(HAVE_LOG10L)
275     AC_DEFINE(HAVE_LOGL)
276     AC_DEFINE(HAVE_MODFL)
277     AC_DEFINE(HAVE_POWL)
278     AC_DEFINE(HAVE_SINCOSL)
279     AC_DEFINE(HAVE_SINL)
280     AC_DEFINE(HAVE_SINHL)
281     AC_DEFINE(HAVE_SQRTL)
282     AC_DEFINE(HAVE_TANL)
283     AC_DEFINE(HAVE_TANHL)
284   fi
285
286 fi
287
288 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
289 GLIBCXX_ENABLE_SYMVERS([yes])
290 GLIBCXX_ENABLE_VISIBILITY([yes])
291
292 ac_ldbl_compat=no
293 case "$target" in
294   powerpc*-*-*gnu* | \
295   sparc*-*-linux* | \
296   s390*-*-linux* | \
297   alpha*-*-linux*)
298   AC_TRY_COMPILE(, [
299 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
300 #error no need for long double compatibility
301 #endif
302   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
303   if test "$ac_ldbl_compat" = yes; then
304     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
305               [Define if compatibility should be provided for -mlong-double-64.])
306     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
307   fi
308 esac
309 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
310
311 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
312 GLIBCXX_CONFIGURE_TESTSUITE
313
314 # Propagate the target-specific source directories through the build chain.
315 ATOMICITY_SRCDIR=config/${atomicity_dir}
316 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
317 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
318 OS_INC_SRCDIR=config/${os_include_dir}
319 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
320 AC_SUBST(ATOMICITY_SRCDIR)
321 AC_SUBST(ATOMIC_WORD_SRCDIR)
322 AC_SUBST(CPU_DEFINES_SRCDIR)
323 AC_SUBST(ABI_TWEAKS_SRCDIR)
324 AC_SUBST(OS_INC_SRCDIR)
325
326
327 # Determine cross-compile flags and AM_CONDITIONALs.
328 #AC_SUBST(GLIBCXX_IS_NATIVE)
329 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
330 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
331 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
332 GLIBCXX_EVALUATE_CONDITIONALS
333  
334 AC_CACHE_SAVE
335
336 if test ${multilib} = yes; then
337   multilib_arg="--enable-multilib"
338 else
339   multilib_arg=
340 fi
341
342 # Export all the install information.
343 GLIBCXX_EXPORT_INSTALL_INFO
344
345 # Export all the include and flag information to Makefiles.
346 GLIBCXX_EXPORT_INCLUDES
347 GLIBCXX_EXPORT_FLAGS
348
349 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
350    grep "enable shared" > /dev/null;
351 then
352   LIBSUPCXX_PICFLAGS=-prefer-pic
353 else
354   LIBSUPCXX_PICFLAGS=
355 fi
356 AC_SUBST(LIBSUPCXX_PICFLAGS)
357
358 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
359 dnl which can all be called multiple times as needed, plus one (different)
360 dnl AC_OUTPUT macro.  This one lists the files to be created:
361 AC_CONFIG_FILES( \
362   Makefile \
363   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
364   )
365 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
366
367 dnl These commands are run at the end of config.status:
368 AC_CONFIG_COMMANDS([default],
369 [if test -n "$CONFIG_FILES"; then
370    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
371    # that multilib installs will end up installed in the correct place.
372    # The testsuite needs it for multilib-aware ABI baseline files.
373    # To work around this not being passed down from config-ml.in ->
374    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
375    # append it here.  Only modify Makefiles that have just been created.
376    #
377    # Also, get rid of this simulated-VPATH thing that automake does.
378    cat > vpsed << \_EOF
379 s!`test -f '$<' || echo '$(srcdir)/'`!!
380 _EOF
381    for i in $SUBDIRS; do
382     case $CONFIG_FILES in
383      *${i}/Makefile*)
384        #echo "Adding MULTISUBDIR to $i/Makefile"
385        sed -f vpsed $i/Makefile > tmp
386        grep '^MULTISUBDIR =' Makefile >> tmp
387        mv tmp $i/Makefile
388        ;;
389     esac
390    done
391    rm vpsed
392  fi
393  (cd include && ${MAKE-make})
394 ],
395 [
396 # Variables needed in config.status (file generation) which aren't already
397 # passed by autoconf.
398 SUBDIRS="$SUBDIRS"
399 ])
400
401 dnl And this actually makes things happen:
402 AC_OUTPUT