OSDN Git Service

2008-08-12 Paolo Carlini <paolo.carlini@oracle.com>
[pf3gnuchains/gcc-fork.git] / libstdc++-v3 / configure.ac
1 # Process this file with autoreconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT(package-unused, version-unused,, libstdc++)
5 AC_CONFIG_SRCDIR(src/ios.cc)
6 AC_CONFIG_HEADER(config.h)
7
8 # This works around the fact that libtool configuration may change LD
9 # for this particular configuration, but some shells, instead of
10 # keeping the changes in LD private, export them just because LD is
11 # exported.  Only used at the end of this file.
12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
13
14 # For libtool versioning info, format is CURRENT:REVISION:AGE
15 libtool_VERSION=6:11:0
16 AC_SUBST(libtool_VERSION)
17
18 # Find the rest of the source tree framework.
19 AM_ENABLE_MULTILIB(, ..)
20
21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
22 #
23 # You will slowly go insane if you do not grok the following fact:  when
24 # building v3 as part of the compiler, the top-level /target/ becomes the
25 # library's /host/.  configure then causes --target to default to --host,
26 # exactly like any other package using autoconf.  Therefore, 'target' and
27 # 'host' will always be the same.  This makes sense both for native and
28 # cross compilers, just think about it for a little while.  :-)
29 #
30 # Also, if v3 is being configured as part of a cross compiler, the top-level
31 # configure script will pass the "real" host as $with_cross_host.
32 #
33 # Do not delete or change the following two lines.  For why, see
34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
35 AC_CANONICAL_SYSTEM
36 target_alias=${target_alias-$host_alias}
37
38 # Handy for debugging:
39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
40
41 if test "$build" != "$host"; then
42   # We are being configured with some form of cross compiler.
43   GLIBCXX_IS_NATIVE=false
44   case "$host","$target" in
45     # Darwin crosses can use the host system's libraries and headers,
46     # because of the fat library support.  Of course, it must be the
47     # same version of Darwin on both sides.  Allow the user to
48     # just say --target=foo-darwin without a version number to mean
49     # "the version on this system".
50       *-*-darwin*,*-*-darwin*)
51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
53         if test $hostos = $targetos -o $targetos = darwin ; then
54           GLIBCXX_IS_NATIVE=true
55         fi
56         ;;
57
58       *)
59         GCC_NO_EXECUTABLES
60         ;;
61   esac
62 else
63   GLIBCXX_IS_NATIVE=true
64 fi
65
66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
68 #  1.x:  minimum required version
69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
70 #              of other PACKAGE_* variables will, however, and there's nothing
71 #              we can do about that; they come from AC_INIT).
72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
73 #            file in the top srcdir, etc, etc), so stop complaining.
74 #  no-dependencies:  turns off auto dependency generation (just for now)
75 #  -Wall:  turns on all automake warnings...
76 #  -Wno-portability:  ...except this one, since GNU make is now required.
77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
78 AH_TEMPLATE(PACKAGE, [Name of package])
79 AH_TEMPLATE(VERSION, [Version number of package])
80
81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
82 # up critical shell variables.
83 GLIBCXX_CONFIGURE
84
85 if test "x${with_newlib}" != "xyes"; then
86   AC_LIBTOOL_DLOPEN
87 fi
88 AM_PROG_LIBTOOL
89 AC_SUBST(enable_shared)
90 AC_SUBST(enable_static)
91
92 # Possibly disable most of the library.
93 ## TODO: Consider skipping unncessary tests altogether in this case, rather
94 ## than just ignoring the results.  Faster /and/ more correct, win win.
95 GLIBCXX_ENABLE_HOSTED
96
97 # Enable compiler support that doesn't require linking.
98 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
99 GLIBCXX_ENABLE_PCH($is_hosted)
100 GLIBCXX_ENABLE_ATOMIC_BUILTINS
101 GLIBCXX_ENABLE_THREADS
102
103 # Checks for compiler support that don't require linking.
104 GLIBCXX_CHECK_COMPILER_FEATURES
105 GLIBCXX_CHECK_STANDARD_LAYOUT
106
107 # Enable all the variable C++ runtime options that doesn't require linking.
108 GLIBCXX_ENABLE_CSTDIO
109 GLIBCXX_ENABLE_CLOCALE
110 GLIBCXX_ENABLE_ALLOCATOR
111 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
112 GLIBCXX_ENABLE_LONG_LONG([yes])
113 GLIBCXX_ENABLE_WCHAR_T([yes])
114 GLIBCXX_ENABLE_C99([yes])
115 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
116 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
117 GLIBCXX_ENABLE_DEBUG([no])
118 GLIBCXX_ENABLE_PARALLEL([yes])
119 GLIBCXX_ENABLE_CXX_FLAGS
120 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
121
122 # Checks for operating systems support that don't require linking.
123 GLIBCXX_CHECK_SYSTEM_ERROR
124
125 # For the streamoff typedef.
126 GLIBCXX_CHECK_INT64_T
127
128 # For C99 support to TR1.
129 GLIBCXX_CHECK_C99_TR1
130
131 # For common values of EOF, SEEK_CUR, SEEK_END.
132 GLIBCXX_CHECK_STDIO_MACROS
133
134 # Only do link tests if native. Else, hardcode.
135 if $GLIBCXX_IS_NATIVE; then
136
137   # We can do more elaborate tests that assume a working linker.
138   CANADIAN=no
139
140   # Check for available headers.
141   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
142   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h \
143   sys/types.h sys/ipc.h sys/sem.h])
144
145   GLIBCXX_CHECK_LINKER_FEATURES
146   GLIBCXX_CHECK_MATH_SUPPORT
147   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
148   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
149   GLIBCXX_CHECK_STDLIB_SUPPORT
150
151   # For showmanyc_helper().
152   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
153   GLIBCXX_CHECK_POLL
154   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
155
156   # For xsputn_2().
157   AC_CHECK_HEADERS(sys/uio.h)
158   GLIBCXX_CHECK_WRITEV
159
160   # For LFS support.
161   GLIBCXX_CHECK_LFS
162
163   # For dev/random and dev/urandom for TR1.
164   GLIBCXX_CHECK_RANDOM_TR1
165
166   # For clock_gettime support.
167   GLIBCXX_CHECK_CLOCK_GETTIME
168
169   # For gettimeofday support.
170   GLIBCXX_CHECK_GETTIMEOFDAY
171
172   # For TLS support.
173   GCC_CHECK_TLS
174
175   # For _Unwind_GetIPInfo.
176   GCC_CHECK_UNWIND_GETIPINFO
177
178   AC_LC_MESSAGES
179
180   # For iconv support.
181   AM_ICONV
182
183 else
184
185   # This lets us hard-code the functionality we know we'll have in the cross
186   # target environment.  "Let" is a sugar-coated word placed on an especially
187   # dull and tedious hack, actually.
188   #
189   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
190   # that involve linking, can't be used:
191   #    "cannot open sim-crt0.o"
192   #    "cannot open crt0.o"
193   # etc.  All this is because there currently exists no unified, consistent
194   # way for top level CC information to be passed down to target directories:
195   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
196   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
197   # crosses can be removed.
198
199   # If Canadian cross, then don't pick up tools from the build directory.
200   # Used only in GLIBCXX_EXPORT_INCLUDES.
201   if test -n "$with_cross_host" &&
202      test x"$build_alias" != x"$with_cross_host" &&
203      test x"$build" != x"$target";
204   then
205     CANADIAN=yes
206   else
207     CANADIAN=no
208   fi
209
210   # Construct crosses by hand, eliminating bits that need ld...
211   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
212   # GLIBCXX_CHECK_MATH_SUPPORT
213
214   # First, test for "known" system libraries.  We may be using newlib even
215   # on a hosted environment.
216   if test "x${with_newlib}" = "xyes"; then
217     os_include_dir="os/newlib"
218     AC_DEFINE(HAVE_HYPOT)
219
220     # GLIBCXX_CHECK_STDLIB_SUPPORT
221     AC_DEFINE(HAVE_STRTOF)        
222
223     AC_DEFINE(HAVE_ACOSF)
224     AC_DEFINE(HAVE_ASINF)
225     AC_DEFINE(HAVE_ATAN2F)
226     AC_DEFINE(HAVE_ATANF)
227     AC_DEFINE(HAVE_CEILF)
228     AC_DEFINE(HAVE_COPYSIGN)
229     AC_DEFINE(HAVE_COPYSIGNF)
230     AC_DEFINE(HAVE_COSF)
231     AC_DEFINE(HAVE_COSHF)
232     AC_DEFINE(HAVE_EXPF)
233     AC_DEFINE(HAVE_FABSF)
234     AC_DEFINE(HAVE_FLOORF)
235     AC_DEFINE(HAVE_FMODF)
236     AC_DEFINE(HAVE_FREXPF)
237     AC_DEFINE(HAVE_LDEXPF)
238     AC_DEFINE(HAVE_LOG10F)
239     AC_DEFINE(HAVE_LOGF)
240     AC_DEFINE(HAVE_MODFF)
241     AC_DEFINE(HAVE_POWF)
242     AC_DEFINE(HAVE_SINF)
243     AC_DEFINE(HAVE_SINHF)
244     AC_DEFINE(HAVE_SQRTF)
245     AC_DEFINE(HAVE_TANF)
246     AC_DEFINE(HAVE_TANHF)
247
248     AC_DEFINE(HAVE_S_ISREG)
249     AC_DEFINE(HAVE_S_IFREG)
250
251     AC_DEFINE(HAVE_ICONV)
252   else
253     GLIBCXX_CROSSCONFIG
254   fi
255
256   # At some point, we should differentiate between architectures
257   # like x86, which have long double versions, and alpha/powerpc/etc.,
258   # which don't. For the time being, punt.
259   if test x"long_double_math_on_this_cpu" = x"yes"; then
260     AC_DEFINE(HAVE_ACOSL)
261     AC_DEFINE(HAVE_ASINL)
262     AC_DEFINE(HAVE_ATAN2L)
263     AC_DEFINE(HAVE_ATANL)
264     AC_DEFINE(HAVE_CEILL)
265     AC_DEFINE(HAVE_COPYSIGNL)
266     AC_DEFINE(HAVE_COSL)
267     AC_DEFINE(HAVE_COSHL)
268     AC_DEFINE(HAVE_EXPL)
269     AC_DEFINE(HAVE_FABSL)
270     AC_DEFINE(HAVE_FLOORL)
271     AC_DEFINE(HAVE_FMODL)
272     AC_DEFINE(HAVE_FREXPL)
273     AC_DEFINE(HAVE_LDEXPL)
274     AC_DEFINE(HAVE_LOG10L)
275     AC_DEFINE(HAVE_LOGL)
276     AC_DEFINE(HAVE_MODFL)
277     AC_DEFINE(HAVE_POWL)
278     AC_DEFINE(HAVE_SINCOSL)
279     AC_DEFINE(HAVE_SINL)
280     AC_DEFINE(HAVE_SINHL)
281     AC_DEFINE(HAVE_SQRTL)
282     AC_DEFINE(HAVE_TANL)
283     AC_DEFINE(HAVE_TANHL)
284   fi
285
286   # Assume we have _Unwind_GetIPInfo for cross-compiles.
287   AC_DEFINE(HAVE_GETIPINFO)
288 fi
289
290 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
291
292 GCC_HEADER_STDINT(include/gstdint.h)
293
294 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
295 GLIBCXX_ENABLE_SYMVERS([yes])
296 GLIBCXX_ENABLE_VISIBILITY([yes])
297
298 ac_ldbl_compat=no
299 case "$target" in
300   powerpc*-*-linux* | \
301   powerpc*-*-gnu* | \
302   sparc*-*-linux* | \
303   s390*-*-linux* | \
304   alpha*-*-linux*)
305   AC_TRY_COMPILE(, [
306 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
307 #error no need for long double compatibility
308 #endif
309   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
310   if test "$ac_ldbl_compat" = yes; then
311     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
312               [Define if compatibility should be provided for -mlong-double-64.])
313     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
314   fi
315 esac
316 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
317
318 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
319 GLIBCXX_CONFIGURE_TESTSUITE
320
321 # Propagate the target-specific source directories through the build chain.
322 ATOMICITY_SRCDIR=config/${atomicity_dir}
323 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
324 ATOMIC_FLAGS=${atomic_flags}
325 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
326 OS_INC_SRCDIR=config/${os_include_dir}
327 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
328 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
329 AC_SUBST(ATOMICITY_SRCDIR)
330 AC_SUBST(ATOMIC_WORD_SRCDIR)
331 AC_SUBST(ATOMIC_FLAGS)
332 AC_SUBST(CPU_DEFINES_SRCDIR)
333 AC_SUBST(ABI_TWEAKS_SRCDIR)
334 AC_SUBST(OS_INC_SRCDIR)
335 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
336
337
338 # Determine cross-compile flags and AM_CONDITIONALs.
339 #AC_SUBST(GLIBCXX_IS_NATIVE)
340 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
341 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
342 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
343 GLIBCXX_EVALUATE_CONDITIONALS
344  
345 AC_CACHE_SAVE
346
347 if test ${multilib} = yes; then
348   multilib_arg="--enable-multilib"
349 else
350   multilib_arg=
351 fi
352
353 # Export all the install information.
354 GLIBCXX_EXPORT_INSTALL_INFO
355
356 # Export all the include and flag information to Makefiles.
357 GLIBCXX_EXPORT_INCLUDES
358 GLIBCXX_EXPORT_FLAGS
359
360 if test "$enable_shared" = yes; then
361   LIBSUPCXX_PICFLAGS="-prefer-pic"
362 else
363   LIBSUPCXX_PICFLAGS=
364 fi
365 AC_SUBST(LIBSUPCXX_PICFLAGS)
366
367 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
368 dnl which can all be called multiple times as needed, plus one (different)
369 dnl AC_OUTPUT macro.  This one lists the files to be created:
370 AC_CONFIG_FILES( \
371   Makefile \
372   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
373   )
374 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
375
376 dnl These commands are run at the end of config.status:
377 AC_CONFIG_COMMANDS([default],
378 [if test -n "$CONFIG_FILES"; then
379    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
380    # that multilib installs will end up installed in the correct place.
381    # The testsuite needs it for multilib-aware ABI baseline files.
382    # To work around this not being passed down from config-ml.in ->
383    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
384    # append it here.  Only modify Makefiles that have just been created.
385    #
386    # Also, get rid of this simulated-VPATH thing that automake does.
387    cat > vpsed << \_EOF
388 s!`test -f '$<' || echo '$(srcdir)/'`!!
389 _EOF
390    for i in $SUBDIRS; do
391     case $CONFIG_FILES in
392      *${i}/Makefile*)
393        #echo "Adding MULTISUBDIR to $i/Makefile"
394        sed -f vpsed $i/Makefile > tmp
395        grep '^MULTISUBDIR =' Makefile >> tmp
396        mv tmp $i/Makefile
397        ;;
398     esac
399    done
400    rm vpsed
401  fi
402  (cd include && ${MAKE-make})
403 ],
404 [
405 # Variables needed in config.status (file generation) which aren't already
406 # passed by autoconf.
407 SUBDIRS="$SUBDIRS"
408 ])
409
410 dnl And this actually makes things happen:
411 AC_OUTPUT