libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # Find the rest of the source tree framework.
  15 AM_ENABLE_MULTILIB(, ..)
  16
  17 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  18 #
  19 # You will slowly go insane if you do not grok the following fact:  when
  20 # building v3 as part of the compiler, the top-level /target/ becomes the
  21 # library's /host/.  configure then causes --target to default to --host,
  22 # exactly like any other package using autoconf.  Therefore, 'target' and
  23 # 'host' will always be the same.  This makes sense both for native and
  24 # cross compilers, just think about it for a little while.  :-)
  25 #
  26 # Also, if v3 is being configured as part of a cross compiler, the top-level
  27 # configure script will pass the "real" host as $with_cross_host.
  28 #
  29 # Do not delete or change the following two lines.  For why, see
  30 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  31 AC_CANONICAL_SYSTEM
  32 target_alias=${target_alias-$host_alias}
  33
  34 # Handy for debugging:
  35 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  36
  37 if test "$build" != "$host"; then
  38   # We are being configured with some form of cross compiler.
  39   GLIBCXX_IS_NATIVE=false
  40   case "$host","$target" in
  41     # Darwin crosses can use the host system's libraries and headers,
  42     # because of the fat library support.  Of course, it must be the
  43     # same version of Darwin on both sides.  Allow the user to
  44     # just say --target=foo-darwin without a version number to mean
  45     # "the version on this system".
  46       *-*-darwin*,*-*-darwin*)
  47         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  48         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  49         if test $hostos = $targetos -o $targetos = darwin ; then
  50           GLIBCXX_IS_NATIVE=true
  51         fi
  52         ;;
  53
  54       *)
  55         GCC_NO_EXECUTABLES
  56         ;;
  57   esac
  58 else
  59   GLIBCXX_IS_NATIVE=true
  60 fi
  61
  62 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  63 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  64 #  1.x:  minimum required version
  65 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  66 #              of other PACKAGE_* variables will, however, and there's nothing
  67 #              we can do about that; they come from AC_INIT).
  68 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  69 #            file in the top srcdir, etc, etc), so stop complaining.
  70 #  no-dependencies:  turns off auto dependency generation (just for now)
  71 #  no-dist:  we don't want 'dist' and related rules.
  72 #  -Wall:  turns on all automake warnings...
  73 #  -Wno-portability:  ...except this one, since GNU make is now required.
  74 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  75 AH_TEMPLATE(PACKAGE, [Name of package])
  76 AH_TEMPLATE(VERSION, [Version number of package])
  77
  78 # -fno-builtin must be present here so that a non-conflicting form of
  79 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  80
  81 save_CXXFLAGS="$CXXFLAGS"
  82 CXXFLAGS="$CXXFLAGS -fno-builtin"
  83 AC_PROG_CC
  84 AC_PROG_CXX
  85 CXXFLAGS="$save_CXXFLAGS"
  86
  87 # Runs configure.host, and assorted other critical bits.  Sets
  88 # up critical shell variables.
  89 GLIBCXX_CONFIGURE
  90
  91 if test "x${with_newlib}" != "xyes"; then
  92   AC_LIBTOOL_DLOPEN
  93 fi
  94 AM_PROG_LIBTOOL
  95 ACX_LT_HOST_FLAGS
  96 AC_SUBST(enable_shared)
  97 AC_SUBST(enable_static)
  98
  99 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 100 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 101
 102 # Possibly disable most of the library.
 103 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 104 ## than just ignoring the results.  Faster /and/ more correct, win win.
 105 GLIBCXX_ENABLE_HOSTED
 106
 107 # Enable compiler support that doesn't require linking.
 108 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
 109 GLIBCXX_ENABLE_PCH($is_hosted)
 110 GLIBCXX_ENABLE_THREADS
 111 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 112 GLIBCXX_ENABLE_DECIMAL_FLOAT
 113 GLIBCXX_ENABLE_INT128_FLOAT128
 114
 115 # Checks for compiler support that doesn't require linking.
 116 GLIBCXX_CHECK_COMPILER_FEATURES
 117
 118 # Enable all the variable C++ runtime options that don't require linking.
 119 GLIBCXX_ENABLE_CSTDIO
 120 GLIBCXX_ENABLE_CLOCALE
 121 GLIBCXX_ENABLE_ALLOCATOR
 122 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 123 GLIBCXX_ENABLE_LONG_LONG([yes])
 124 GLIBCXX_ENABLE_WCHAR_T([yes])
 125 GLIBCXX_ENABLE_C99([yes])
 126 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 127 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0"])
 128 GLIBCXX_ENABLE_DEBUG([no])
 129 GLIBCXX_ENABLE_PARALLEL([yes])
 130 GLIBCXX_ENABLE_CXX_FLAGS
 131 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 132 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 133 GLIBCXX_ENABLE_PYTHON
 134 GLIBCXX_ENABLE_WERROR([yes])
 135
 136 # Checks for operating systems support that doesn't require linking.
 137 GLIBCXX_CHECK_MATH_PROTO
 138 GLIBCXX_CHECK_STDLIB_PROTO
 139 GLIBCXX_CHECK_STDIO_PROTO
 140 GLIBCXX_CHECK_SYSTEM_ERROR
 141
 142 # For the streamoff typedef.
 143 GLIBCXX_CHECK_INT64_T
 144
 145 # For LFS support.
 146 GLIBCXX_CHECK_LFS
 147
 148 # For showmanyc_helper().
 149 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 150 GLIBCXX_CHECK_POLL
 151 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 152
 153 # For xsputn_2().
 154 AC_CHECK_HEADERS(sys/uio.h)
 155 GLIBCXX_CHECK_WRITEV
 156
 157 # For C99 support to TR1.
 158 GLIBCXX_CHECK_C99_TR1
 159
 160 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 161 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 162
 163 # For gettimeofday support.
 164 GLIBCXX_CHECK_GETTIMEOFDAY
 165
 166 # For clock_gettime, nanosleep and sched_yield support.
 167 # NB: The default is [no], because otherwise it requires linking.
 168 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
 169
 170 AC_LC_MESSAGES
 171
 172 # For hardware_concurrency
 173 AC_CHECK_HEADERS(sys/sysinfo.h)
 174 GLIBCXX_CHECK_GET_NPROCS
 175 AC_CHECK_HEADERS(unistd.h)
 176 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 177 GLIBCXX_CHECK_SC_NPROC_ONLN
 178 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 179 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 180
 181 # Check for available headers.
 182 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 183 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 184 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 185 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 186 wchar.h wctype.h])
 187
 188 # Only do link tests if native. Else, hardcode.
 189 if $GLIBCXX_IS_NATIVE; then
 190
 191   # We can do more elaborate tests that assume a working linker.
 192   CANADIAN=no
 193
 194   GLIBCXX_CHECK_LINKER_FEATURES
 195   GLIBCXX_CHECK_MATH_SUPPORT
 196   GLIBCXX_CHECK_STDLIB_SUPPORT
 197
 198   # For /dev/random and /dev/urandom for TR1.
 199   GLIBCXX_CHECK_RANDOM_TR1
 200
 201   # For TLS support.
 202   GCC_CHECK_TLS
 203
 204   # For iconv support.
 205   AM_ICONV
 206
 207 else
 208
 209   # This lets us hard-code the functionality we know we'll have in the cross
 210   # target environment.  "Let" is a sugar-coated word placed on an especially
 211   # dull and tedious hack, actually.
 212   #
 213   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 214   # that involve linking, can't be used:
 215   #    "cannot open sim-crt0.o"
 216   #    "cannot open crt0.o"
 217   # etc.  All this is because there currently exists no unified, consistent
 218   # way for top level CC information to be passed down to target directories:
 219   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 220   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 221   # crosses can be removed.
 222
 223   # If Canadian cross, then don't pick up tools from the build directory.
 224   # Used only in GLIBCXX_EXPORT_INCLUDES.
 225   if test -n "$with_cross_host" &&
 226      test x"$build_alias" != x"$with_cross_host" &&
 227      test x"$build" != x"$target";
 228   then
 229     CANADIAN=yes
 230   else
 231     CANADIAN=no
 232   fi
 233
 234   # Construct crosses by hand, eliminating bits that need ld...
 235   # GLIBCXX_CHECK_MATH_SUPPORT
 236
 237   # First, test for "known" system libraries.  We may be using newlib even
 238   # on a hosted environment.
 239   if test "x${with_newlib}" = "xyes"; then
 240     os_include_dir="os/newlib"
 241     AC_DEFINE(HAVE_HYPOT)
 242
 243     # GLIBCXX_CHECK_STDLIB_SUPPORT
 244     AC_DEFINE(HAVE_STRTOF)
 245
 246     AC_DEFINE(HAVE_ACOSF)
 247     AC_DEFINE(HAVE_ASINF)
 248     AC_DEFINE(HAVE_ATAN2F)
 249     AC_DEFINE(HAVE_ATANF)
 250     AC_DEFINE(HAVE_CEILF)
 251     AC_DEFINE(HAVE_COSF)
 252     AC_DEFINE(HAVE_COSHF)
 253     AC_DEFINE(HAVE_EXPF)
 254     AC_DEFINE(HAVE_FABSF)
 255     AC_DEFINE(HAVE_FLOORF)
 256     AC_DEFINE(HAVE_FMODF)
 257     AC_DEFINE(HAVE_FREXPF)
 258     AC_DEFINE(HAVE_LDEXPF)
 259     AC_DEFINE(HAVE_LOG10F)
 260     AC_DEFINE(HAVE_LOGF)
 261     AC_DEFINE(HAVE_MODFF)
 262     AC_DEFINE(HAVE_POWF)
 263     AC_DEFINE(HAVE_SINF)
 264     AC_DEFINE(HAVE_SINHF)
 265     AC_DEFINE(HAVE_SQRTF)
 266     AC_DEFINE(HAVE_TANF)
 267     AC_DEFINE(HAVE_TANHF)
 268
 269     AC_DEFINE(HAVE_ICONV)
 270   else
 271     GLIBCXX_CROSSCONFIG
 272   fi
 273
 274   # At some point, we should differentiate between architectures
 275   # like x86, which have long double versions, and alpha/powerpc/etc.,
 276   # which don't. For the time being, punt.
 277   if test x"long_double_math_on_this_cpu" = x"yes"; then
 278     AC_DEFINE(HAVE_ACOSL)
 279     AC_DEFINE(HAVE_ASINL)
 280     AC_DEFINE(HAVE_ATAN2L)
 281     AC_DEFINE(HAVE_ATANL)
 282     AC_DEFINE(HAVE_CEILL)
 283     AC_DEFINE(HAVE_COSL)
 284     AC_DEFINE(HAVE_COSHL)
 285     AC_DEFINE(HAVE_EXPL)
 286     AC_DEFINE(HAVE_FABSL)
 287     AC_DEFINE(HAVE_FLOORL)
 288     AC_DEFINE(HAVE_FMODL)
 289     AC_DEFINE(HAVE_FREXPL)
 290     AC_DEFINE(HAVE_LDEXPL)
 291     AC_DEFINE(HAVE_LOG10L)
 292     AC_DEFINE(HAVE_LOGL)
 293     AC_DEFINE(HAVE_MODFL)
 294     AC_DEFINE(HAVE_POWL)
 295     AC_DEFINE(HAVE_SINCOSL)
 296     AC_DEFINE(HAVE_SINL)
 297     AC_DEFINE(HAVE_SINHL)
 298     AC_DEFINE(HAVE_SQRTL)
 299     AC_DEFINE(HAVE_TANL)
 300     AC_DEFINE(HAVE_TANHL)
 301   fi
 302 fi
 303
 304 # Check for _Unwind_GetIPInfo.
 305 GCC_CHECK_UNWIND_GETIPINFO
 306
 307 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 308
 309 GCC_HEADER_STDINT(include/gstdint.h)
 310
 311 GLIBCXX_ENABLE_SYMVERS([yes])
 312 AC_SUBST(libtool_VERSION)
 313
 314 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 315
 316 ac_ldbl_compat=no
 317 case "$target" in
 318   powerpc*-*-linux* | \
 319   sparc*-*-linux* | \
 320   s390*-*-linux* | \
 321   alpha*-*-linux*)
 322   AC_TRY_COMPILE(, [
 323 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 324 #error no need for long double compatibility
 325 #endif
 326   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 327   if test "$ac_ldbl_compat" = yes; then
 328     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 329               [Define if compatibility should be provided for -mlong-double-64.])
 330     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 331   fi
 332 esac
 333 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 334
 335 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 336 GLIBCXX_CONFIGURE_TESTSUITE
 337
 338 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 339 GLIBCXX_CHECK_GTHREADS
 340
 341 # Define documentation rules conditionally.
 342
 343 # See if makeinfo has been installed and is modern enough
 344 # that we can use it.
 345 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 346                    [GNU texinfo.* \([0-9][0-9.]*\)],
 347                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 348 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 349
 350 # Check for doxygen
 351 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 352 AC_CHECK_PROG([DOT], dot, yes, no)
 353
 354 # Check for docbook
 355 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 356 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 357 GLIBCXX_CONFIGURE_DOCBOOK
 358
 359 # Check for xml/html dependencies.
 360 AM_CONDITIONAL(BUILD_XML,
 361                test $ac_cv_prog_DOXYGEN = "yes" &&
 362                test $ac_cv_prog_DOT = "yes" &&
 363                test $ac_cv_prog_XSLTPROC = "yes" &&
 364                test $ac_cv_prog_XMLLINT = "yes" &&
 365                test $glibcxx_stylesheets = "yes")
 366
 367 AM_CONDITIONAL(BUILD_HTML,
 368                test $ac_cv_prog_DOXYGEN = "yes" &&
 369                test $ac_cv_prog_DOT = "yes" &&
 370                test $ac_cv_prog_XSLTPROC = "yes" &&
 371                test $ac_cv_prog_XMLLINT = "yes" &&
 372                test $glibcxx_stylesheets = "yes")
 373
 374 # Check for man dependencies.
 375 AM_CONDITIONAL(BUILD_MAN,
 376                test $ac_cv_prog_DOXYGEN = "yes" &&
 377                test $ac_cv_prog_DOT = "yes")
 378
 379 # Check for pdf dependencies.
 380 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 381 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 382 AM_CONDITIONAL(BUILD_PDF,
 383                test $ac_cv_prog_DBLATEX = "yes" &&
 384                test $ac_cv_prog_PDFLATEX = "yes")
 385
 386
 387 # Propagate the target-specific source directories through the build chain.
 388 ATOMICITY_SRCDIR=config/${atomicity_dir}
 389 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 390 ATOMIC_FLAGS=${atomic_flags}
 391 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 392 OS_INC_SRCDIR=config/${os_include_dir}
 393 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 394 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 395 AC_SUBST(ATOMICITY_SRCDIR)
 396 AC_SUBST(ATOMIC_WORD_SRCDIR)
 397 AC_SUBST(ATOMIC_FLAGS)
 398 AC_SUBST(CPU_DEFINES_SRCDIR)
 399 AC_SUBST(ABI_TWEAKS_SRCDIR)
 400 AC_SUBST(OS_INC_SRCDIR)
 401 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 402
 403
 404 # Determine cross-compile flags and AM_CONDITIONALs.
 405 #AC_SUBST(GLIBCXX_IS_NATIVE)
 406 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 407 GLIBCXX_EVALUATE_CONDITIONALS
 408
 409 AC_CACHE_SAVE
 410
 411 if test ${multilib} = yes; then
 412   multilib_arg="--enable-multilib"
 413 else
 414   multilib_arg=
 415 fi
 416
 417 # Export all the install information.
 418 GLIBCXX_EXPORT_INSTALL_INFO
 419
 420 # Export all the include and flag information to Makefiles.
 421 GLIBCXX_EXPORT_INCLUDES
 422 GLIBCXX_EXPORT_FLAGS
 423
 424 if test "$enable_shared" = yes; then
 425   PIC_CXXFLAGS="-prefer-pic"
 426 else
 427   PIC_CXXFLAGS=
 428 fi
 429 AC_SUBST(PIC_CXXFLAGS)
 430
 431 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 432 dnl which can all be called multiple times as needed, plus one (different)
 433 dnl AC_OUTPUT macro.  This one lists the files to be created:
 434 AC_CONFIG_FILES(Makefile)
 435 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 436 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 437 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 438
 439 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 440 # that multilib installs will end up installed in the correct place.
 441 # The testsuite needs it for multilib-aware ABI baseline files.
 442 # To work around this not being passed down from config-ml.in ->
 443 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 444 # append it here.  Only modify Makefiles that have just been created.
 445 #
 446 # Also, get rid of this simulated-VPATH thing that automake does.
 447 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 448   [cat > vpsed$$ << \_EOF
 449 s!`test -f '$<' || echo '$(srcdir)/'`!!
 450 _EOF
 451    sed -f vpsed$$ $ac_file > tmp$$
 452    mv tmp$$ $ac_file
 453    rm vpsed$$
 454    echo 'MULTISUBDIR =' >> $ac_file
 455    ml_norecursion=yes
 456    . ${multi_basedir}/config-ml.in
 457    AS_UNSET([ml_norecursion])
 458 ])
 459
 460 AC_CONFIG_COMMANDS([generate-headers],
 461   [(cd include && ${MAKE-make} pch_build= )])
 462
 463 dnl And this actually makes things happen:
 464 AC_OUTPUT