libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:11:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Enable compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options that doesn't require linking.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_LONG_LONG([yes])
 105 GLIBCXX_ENABLE_WCHAR_T([yes])
 106 GLIBCXX_ENABLE_C99([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_PARALLEL
 111 GLIBCXX_ENABLE_CXX_FLAGS
 112 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 113
 114 # Checks for operating systems support that don't require linking.
 115 GLIBCXX_CHECK_SYSTEM_ERROR
 116 GLIBCXX_CHECK_STANDARD_LAYOUT
 117
 118 # No surprises, no surprises...
 119 GLIBCXX_ENABLE_THREADS
 120 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 121 if test $atomicity_dir = cpu/generic/atomicity_mutex ; then
 122   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 123   if test $target_thread_file = single; then
 124     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 125     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 126   else
 127     AC_MSG_WARN([They will be faked using a mutex.])
 128     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 129   fi
 130 fi
 131
 132 GLIBCXX_CHECK_COMPILER_FEATURES
 133
 134 if $GLIBCXX_IS_NATIVE; then
 135
 136   # We can do more elaborate tests that assume a working linker.
 137   CANADIAN=no
 138
 139   # Check for available headers.
 140   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 141   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 142   sys/types.h sys/ipc.h sys/sem.h])
 143
 144   GLIBCXX_CHECK_LINKER_FEATURES
 145   GLIBCXX_CHECK_MATH_SUPPORT
 146   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 147   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 148   GLIBCXX_CHECK_STDLIB_SUPPORT
 149
 150   # For showmanyc_helper().
 151   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 152   GLIBCXX_CHECK_POLL
 153   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 154
 155   # For xsputn_2().
 156   AC_CHECK_HEADERS(sys/uio.h)
 157   GLIBCXX_CHECK_WRITEV
 158
 159   # For the __streamoff_base_type typedef.
 160   GLIBCXX_CHECK_INT64_T
 161
 162   # For LFS support.
 163   GLIBCXX_CHECK_LFS
 164
 165   # For C99 support to TR1.
 166   GLIBCXX_CHECK_C99_TR1
 167
 168   # For dev/random and dev/urandom for TR1.
 169   GLIBCXX_CHECK_RANDOM_TR1
 170
 171   # For TLS support.
 172   GCC_CHECK_TLS
 173
 174   # For _Unwind_GetIPInfo.
 175   GCC_CHECK_UNWIND_GETIPINFO
 176
 177   AC_LC_MESSAGES
 178
 179   AC_TRY_COMPILE(
 180     [#include <setjmp.h>],
 181     [sigjmp_buf env;
 182      while (! sigsetjmp (env, 1))
 183        siglongjmp (env, 1);
 184     ],
 185     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 186
 187   AC_FUNC_MMAP
 188
 189   # For iconv support.
 190   AM_ICONV
 191
 192 else
 193
 194   # This lets us hard-code the functionality we know we'll have in the cross
 195   # target environment.  "Let" is a sugar-coated word placed on an especially
 196   # dull and tedious hack, actually.
 197   #
 198   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 199   # that involve linking, can't be used:
 200   #    "cannot open sim-crt0.o"
 201   #    "cannot open crt0.o"
 202   # etc.  All this is because there currently exists no unified, consistent
 203   # way for top level CC information to be passed down to target directories:
 204   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 205   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 206   # crosses can be removed.
 207
 208   # If Canadian cross, then don't pick up tools from the build directory.
 209   # Used only in GLIBCXX_EXPORT_INCLUDES.
 210   if test -n "$with_cross_host" &&
 211      test x"$build_alias" != x"$with_cross_host" &&
 212      test x"$build" != x"$target";
 213   then
 214     CANADIAN=yes
 215   else
 216     CANADIAN=no
 217   fi
 218
 219   # Construct crosses by hand, eliminating bits that need ld...
 220   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 221   # GLIBCXX_CHECK_MATH_SUPPORT
 222
 223   # First, test for "known" system libraries.  We may be using newlib even
 224   # on a hosted environment.
 225   if test "x${with_newlib}" = "xyes"; then
 226     os_include_dir="os/newlib"
 227     AC_DEFINE(HAVE_HYPOT)
 228
 229     # GLIBCXX_CHECK_STDLIB_SUPPORT
 230     AC_DEFINE(HAVE_STRTOF)
 231     # AC_FUNC_MMAP
 232     AC_DEFINE(HAVE_MMAP)
 233
 234     AC_DEFINE(HAVE_ACOSF)
 235     AC_DEFINE(HAVE_ASINF)
 236     AC_DEFINE(HAVE_ATAN2F)
 237     AC_DEFINE(HAVE_ATANF)
 238     AC_DEFINE(HAVE_CEILF)
 239     AC_DEFINE(HAVE_COPYSIGN)
 240     AC_DEFINE(HAVE_COPYSIGNF)
 241     AC_DEFINE(HAVE_COSF)
 242     AC_DEFINE(HAVE_COSHF)
 243     AC_DEFINE(HAVE_EXPF)
 244     AC_DEFINE(HAVE_FABSF)
 245     AC_DEFINE(HAVE_FLOORF)
 246     AC_DEFINE(HAVE_FMODF)
 247     AC_DEFINE(HAVE_FREXPF)
 248     AC_DEFINE(HAVE_LDEXPF)
 249     AC_DEFINE(HAVE_LOG10F)
 250     AC_DEFINE(HAVE_LOGF)
 251     AC_DEFINE(HAVE_MODFF)
 252     AC_DEFINE(HAVE_POWF)
 253     AC_DEFINE(HAVE_SINF)
 254     AC_DEFINE(HAVE_SINHF)
 255     AC_DEFINE(HAVE_SQRTF)
 256     AC_DEFINE(HAVE_TANF)
 257     AC_DEFINE(HAVE_TANHF)
 258
 259     AC_DEFINE(HAVE_S_ISREG)
 260     AC_DEFINE(HAVE_S_IFREG)
 261
 262     AC_DEFINE(HAVE_ICONV)
 263   else
 264     GLIBCXX_CROSSCONFIG
 265   fi
 266
 267   # At some point, we should differentiate between architectures
 268   # like x86, which have long double versions, and alpha/powerpc/etc.,
 269   # which don't. For the time being, punt.
 270   if test x"long_double_math_on_this_cpu" = x"yes"; then
 271     AC_DEFINE(HAVE_ACOSL)
 272     AC_DEFINE(HAVE_ASINL)
 273     AC_DEFINE(HAVE_ATAN2L)
 274     AC_DEFINE(HAVE_ATANL)
 275     AC_DEFINE(HAVE_CEILL)
 276     AC_DEFINE(HAVE_COPYSIGNL)
 277     AC_DEFINE(HAVE_COSL)
 278     AC_DEFINE(HAVE_COSHL)
 279     AC_DEFINE(HAVE_EXPL)
 280     AC_DEFINE(HAVE_FABSL)
 281     AC_DEFINE(HAVE_FLOORL)
 282     AC_DEFINE(HAVE_FMODL)
 283     AC_DEFINE(HAVE_FREXPL)
 284     AC_DEFINE(HAVE_LDEXPL)
 285     AC_DEFINE(HAVE_LOG10L)
 286     AC_DEFINE(HAVE_LOGL)
 287     AC_DEFINE(HAVE_MODFL)
 288     AC_DEFINE(HAVE_POWL)
 289     AC_DEFINE(HAVE_SINCOSL)
 290     AC_DEFINE(HAVE_SINL)
 291     AC_DEFINE(HAVE_SINHL)
 292     AC_DEFINE(HAVE_SQRTL)
 293     AC_DEFINE(HAVE_TANL)
 294     AC_DEFINE(HAVE_TANHL)
 295   fi
 296
 297   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 298   AC_DEFINE(HAVE_GETIPINFO)
 299 fi
 300
 301 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 302
 303 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 304 GLIBCXX_ENABLE_SYMVERS([yes])
 305 GLIBCXX_ENABLE_VISIBILITY([yes])
 306
 307 ac_ldbl_compat=no
 308 case "$target" in
 309   powerpc*-*-linux* | \
 310   powerpc*-*-gnu* | \
 311   sparc*-*-linux* | \
 312   s390*-*-linux* | \
 313   alpha*-*-linux*)
 314   AC_TRY_COMPILE(, [
 315 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 316 #error no need for long double compatibility
 317 #endif
 318   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 319   if test "$ac_ldbl_compat" = yes; then
 320     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 321               [Define if compatibility should be provided for -mlong-double-64.])
 322     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 323   fi
 324 esac
 325 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 326
 327 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 328 GLIBCXX_CONFIGURE_TESTSUITE
 329
 330 # Propagate the target-specific source directories through the build chain.
 331 ATOMICITY_SRCDIR=config/${atomicity_dir}
 332 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 333 ATOMIC_FLAGS=${atomic_flags}
 334 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 335 OS_INC_SRCDIR=config/${os_include_dir}
 336 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 337 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 338 AC_SUBST(ATOMICITY_SRCDIR)
 339 AC_SUBST(ATOMIC_WORD_SRCDIR)
 340 AC_SUBST(ATOMIC_FLAGS)
 341 AC_SUBST(CPU_DEFINES_SRCDIR)
 342 AC_SUBST(ABI_TWEAKS_SRCDIR)
 343 AC_SUBST(OS_INC_SRCDIR)
 344 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 345
 346
 347 # Determine cross-compile flags and AM_CONDITIONALs.
 348 #AC_SUBST(GLIBCXX_IS_NATIVE)
 349 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 350 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 351 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 352 GLIBCXX_EVALUATE_CONDITIONALS
 353
 354 AC_CACHE_SAVE
 355
 356 if test ${multilib} = yes; then
 357   multilib_arg="--enable-multilib"
 358 else
 359   multilib_arg=
 360 fi
 361
 362 # Export all the install information.
 363 GLIBCXX_EXPORT_INSTALL_INFO
 364
 365 # Export all the include and flag information to Makefiles.
 366 GLIBCXX_EXPORT_INCLUDES
 367 GLIBCXX_EXPORT_FLAGS
 368
 369 if test "$enable_shared" = yes; then
 370   LIBSUPCXX_PICFLAGS="-prefer-pic"
 371 else
 372   LIBSUPCXX_PICFLAGS=
 373 fi
 374 AC_SUBST(LIBSUPCXX_PICFLAGS)
 375
 376 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 377 dnl which can all be called multiple times as needed, plus one (different)
 378 dnl AC_OUTPUT macro.  This one lists the files to be created:
 379 AC_CONFIG_FILES( \
 380   Makefile \
 381   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 382   )
 383 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 384
 385 dnl These commands are run at the end of config.status:
 386 AC_CONFIG_COMMANDS([default],
 387 [if test -n "$CONFIG_FILES"; then
 388    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 389    # that multilib installs will end up installed in the correct place.
 390    # The testsuite needs it for multilib-aware ABI baseline files.
 391    # To work around this not being passed down from config-ml.in ->
 392    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 393    # append it here.  Only modify Makefiles that have just been created.
 394    #
 395    # Also, get rid of this simulated-VPATH thing that automake does.
 396    cat > vpsed << \_EOF
 397 s!`test -f '$<' || echo '$(srcdir)/'`!!
 398 _EOF
 399    for i in $SUBDIRS; do
 400     case $CONFIG_FILES in
 401      *${i}/Makefile*)
 402        #echo "Adding MULTISUBDIR to $i/Makefile"
 403        sed -f vpsed $i/Makefile > tmp
 404        grep '^MULTISUBDIR =' Makefile >> tmp
 405        mv tmp $i/Makefile
 406        ;;
 407     esac
 408    done
 409    rm vpsed
 410  fi
 411  (cd include && ${MAKE-make})
 412 ],
 413 [
 414 # Variables needed in config.status (file generation) which aren't already
 415 # passed by autoconf.
 416 SUBDIRS="$SUBDIRS"
 417 ])
 418
 419 dnl And this actually makes things happen:
 420 AC_OUTPUT