OSDN Git Service

libstdc++-v3/
[pf3gnuchains/gcc-fork.git] / libstdc++-v3 / configure.ac
1 # Process this file with autoreconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT(package-unused, version-unused,, libstdc++)
5 AC_CONFIG_SRCDIR(src/ios.cc)
6 AC_CONFIG_HEADER(config.h)
7
8 # This works around the fact that libtool configuration may change LD
9 # for this particular configuration, but some shells, instead of
10 # keeping the changes in LD private, export them just because LD is
11 # exported.  Only used at the end of this file.
12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
13
14 # For libtool versioning info, format is CURRENT:REVISION:AGE
15 libtool_VERSION=6:13:0
16 AC_SUBST(libtool_VERSION)
17
18 # Find the rest of the source tree framework.
19 AM_ENABLE_MULTILIB(, ..)
20
21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
22 #
23 # You will slowly go insane if you do not grok the following fact:  when
24 # building v3 as part of the compiler, the top-level /target/ becomes the
25 # library's /host/.  configure then causes --target to default to --host,
26 # exactly like any other package using autoconf.  Therefore, 'target' and
27 # 'host' will always be the same.  This makes sense both for native and
28 # cross compilers, just think about it for a little while.  :-)
29 #
30 # Also, if v3 is being configured as part of a cross compiler, the top-level
31 # configure script will pass the "real" host as $with_cross_host.
32 #
33 # Do not delete or change the following two lines.  For why, see
34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
35 AC_CANONICAL_SYSTEM
36 target_alias=${target_alias-$host_alias}
37
38 # Handy for debugging:
39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
40
41 if test "$build" != "$host"; then
42   # We are being configured with some form of cross compiler.
43   GLIBCXX_IS_NATIVE=false
44   case "$host","$target" in
45     # Darwin crosses can use the host system's libraries and headers,
46     # because of the fat library support.  Of course, it must be the
47     # same version of Darwin on both sides.  Allow the user to
48     # just say --target=foo-darwin without a version number to mean
49     # "the version on this system".
50       *-*-darwin*,*-*-darwin*)
51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
53         if test $hostos = $targetos -o $targetos = darwin ; then
54           GLIBCXX_IS_NATIVE=true
55         fi
56         ;;
57
58       *)
59         GCC_NO_EXECUTABLES
60         ;;
61   esac
62 else
63   GLIBCXX_IS_NATIVE=true
64 fi
65
66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
68 #  1.x:  minimum required version
69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
70 #              of other PACKAGE_* variables will, however, and there's nothing
71 #              we can do about that; they come from AC_INIT).
72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
73 #            file in the top srcdir, etc, etc), so stop complaining.
74 #  no-dependencies:  turns off auto dependency generation (just for now)
75 #  -Wall:  turns on all automake warnings...
76 #  -Wno-portability:  ...except this one, since GNU make is now required.
77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
78 AH_TEMPLATE(PACKAGE, [Name of package])
79 AH_TEMPLATE(VERSION, [Version number of package])
80
81 # We're almost certainly being configured before anything else which uses
82 # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
83 # we not cache the value of CXX that we "discover" here, because it's set
84 # to something unique for us and libjava.  Other target libraries need to
85 # find CXX for themselves.  We yank the rug out from under the normal AC_*
86 # process by sneakily renaming the cache variable.  This also lets us debug
87 # the value of "our" CXX in postmortems.
88 #
89 # We must also force CXX to /not/ be a precious variable, otherwise the
90 # wrong (non-multilib-adjusted) value will be used in multilibs.  This
91 # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
92 # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
93 # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
94 #
95 # -fno-builtin must be present here so that a non-conflicting form of
96 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
97
98 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
99 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
100 m4_define([_AC_ARG_VAR_PRECIOUS],[])
101 save_CXXFLAGS="$CXXFLAGS"
102 CXXFLAGS="$CXXFLAGS -fno-builtin"
103 AC_PROG_CC
104 AC_PROG_CXX
105 CXXFLAGS="$save_CXXFLAGS"
106 m4_rename_force([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
107 AC_SUBST(CFLAGS)
108 AC_SUBST(CXXFLAGS)
109
110 # Runs configure.host, and assorted other critical bits.  Sets
111 # up critical shell variables.
112 GLIBCXX_CONFIGURE
113
114 if test "x${with_newlib}" != "xyes"; then
115   AC_LIBTOOL_DLOPEN
116 fi
117 AM_PROG_LIBTOOL
118 AC_SUBST(enable_shared)
119 AC_SUBST(enable_static)
120
121 # Possibly disable most of the library.
122 ## TODO: Consider skipping unncessary tests altogether in this case, rather
123 ## than just ignoring the results.  Faster /and/ more correct, win win.
124 GLIBCXX_ENABLE_HOSTED
125
126 # Enable compiler support that doesn't require linking.
127 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
128 GLIBCXX_ENABLE_PCH($is_hosted)
129 GLIBCXX_ENABLE_THREADS
130 GLIBCXX_ENABLE_ATOMIC_BUILTINS
131
132 # Checks for compiler support that doesn't require linking.
133 GLIBCXX_CHECK_COMPILER_FEATURES
134
135 # Enable all the variable C++ runtime options that don't require linking.
136 GLIBCXX_ENABLE_CSTDIO
137 GLIBCXX_ENABLE_CLOCALE
138 GLIBCXX_ENABLE_ALLOCATOR
139 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
140 GLIBCXX_ENABLE_LONG_LONG([yes])
141 GLIBCXX_ENABLE_WCHAR_T([yes])
142 GLIBCXX_ENABLE_C99([yes])
143 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
144 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
145 GLIBCXX_ENABLE_DEBUG([no])
146 GLIBCXX_ENABLE_PARALLEL([yes])
147 GLIBCXX_ENABLE_CXX_FLAGS
148 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
149
150 # Checks for operating systems support that doesn't require linking.
151 GLIBCXX_CHECK_SYSTEM_ERROR
152
153 # For the streamoff typedef.
154 GLIBCXX_CHECK_INT64_T
155
156 # For LFS support.
157 GLIBCXX_CHECK_LFS
158
159 # For showmanyc_helper().
160 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
161 GLIBCXX_CHECK_POLL
162 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
163
164 # For xsputn_2().
165 AC_CHECK_HEADERS(sys/uio.h)
166 GLIBCXX_CHECK_WRITEV
167
168 # For C99 support to TR1.
169 GLIBCXX_CHECK_C99_TR1
170
171 # For common values of EOF, SEEK_CUR, SEEK_END.
172 GLIBCXX_CHECK_STDIO_MACROS
173
174 # For gettimeofday support.
175 GLIBCXX_CHECK_GETTIMEOFDAY
176
177 # For clock_gettime, nanosleep and sched_yield support.
178 # NB: The default is [no], because otherwise it requires linking.
179 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
180
181 # For gthread support
182 GLIBCXX_CHECK_GTHREADS
183
184 AC_LC_MESSAGES
185
186 # Check for available headers.
187 AC_CHECK_HEADERS([endian.h float.h fp.h ieeefp.h inttypes.h locale.h \
188 machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
189 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
190 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
191 wchar.h wctype.h])
192
193 # Only do link tests if native. Else, hardcode.
194 if $GLIBCXX_IS_NATIVE; then
195
196   # We can do more elaborate tests that assume a working linker.
197   CANADIAN=no
198
199   GLIBCXX_CHECK_LINKER_FEATURES
200   GLIBCXX_CHECK_MATH_SUPPORT
201   GLIBCXX_CHECK_STDLIB_SUPPORT
202
203   # For /dev/random and /dev/urandom for TR1.
204   GLIBCXX_CHECK_RANDOM_TR1
205
206   # For TLS support.
207   GCC_CHECK_TLS
208
209   # For iconv support.
210   AM_ICONV
211
212 else
213
214   # This lets us hard-code the functionality we know we'll have in the cross
215   # target environment.  "Let" is a sugar-coated word placed on an especially
216   # dull and tedious hack, actually.
217   #
218   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
219   # that involve linking, can't be used:
220   #    "cannot open sim-crt0.o"
221   #    "cannot open crt0.o"
222   # etc.  All this is because there currently exists no unified, consistent
223   # way for top level CC information to be passed down to target directories:
224   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
225   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
226   # crosses can be removed.
227
228   # If Canadian cross, then don't pick up tools from the build directory.
229   # Used only in GLIBCXX_EXPORT_INCLUDES.
230   if test -n "$with_cross_host" &&
231      test x"$build_alias" != x"$with_cross_host" &&
232      test x"$build" != x"$target";
233   then
234     CANADIAN=yes
235   else
236     CANADIAN=no
237   fi
238
239   # Construct crosses by hand, eliminating bits that need ld...
240   # GLIBCXX_CHECK_MATH_SUPPORT
241
242   # First, test for "known" system libraries.  We may be using newlib even
243   # on a hosted environment.
244   if test "x${with_newlib}" = "xyes"; then
245     os_include_dir="os/newlib"
246     AC_DEFINE(HAVE_HYPOT)
247
248     # GLIBCXX_CHECK_STDLIB_SUPPORT
249     AC_DEFINE(HAVE_STRTOF)        
250
251     AC_DEFINE(HAVE_ACOSF)
252     AC_DEFINE(HAVE_ASINF)
253     AC_DEFINE(HAVE_ATAN2F)
254     AC_DEFINE(HAVE_ATANF)
255     AC_DEFINE(HAVE_CEILF)
256     AC_DEFINE(HAVE_COSF)
257     AC_DEFINE(HAVE_COSHF)
258     AC_DEFINE(HAVE_EXPF)
259     AC_DEFINE(HAVE_FABSF)
260     AC_DEFINE(HAVE_FLOORF)
261     AC_DEFINE(HAVE_FMODF)
262     AC_DEFINE(HAVE_FREXPF)
263     AC_DEFINE(HAVE_LDEXPF)
264     AC_DEFINE(HAVE_LOG10F)
265     AC_DEFINE(HAVE_LOGF)
266     AC_DEFINE(HAVE_MODFF)
267     AC_DEFINE(HAVE_POWF)
268     AC_DEFINE(HAVE_SINF)
269     AC_DEFINE(HAVE_SINHF)
270     AC_DEFINE(HAVE_SQRTF)
271     AC_DEFINE(HAVE_TANF)
272     AC_DEFINE(HAVE_TANHF)
273
274     AC_DEFINE(HAVE_ICONV)
275   else
276     GLIBCXX_CROSSCONFIG
277   fi
278
279   # At some point, we should differentiate between architectures
280   # like x86, which have long double versions, and alpha/powerpc/etc.,
281   # which don't. For the time being, punt.
282   if test x"long_double_math_on_this_cpu" = x"yes"; then
283     AC_DEFINE(HAVE_ACOSL)
284     AC_DEFINE(HAVE_ASINL)
285     AC_DEFINE(HAVE_ATAN2L)
286     AC_DEFINE(HAVE_ATANL)
287     AC_DEFINE(HAVE_CEILL)
288     AC_DEFINE(HAVE_COSL)
289     AC_DEFINE(HAVE_COSHL)
290     AC_DEFINE(HAVE_EXPL)
291     AC_DEFINE(HAVE_FABSL)
292     AC_DEFINE(HAVE_FLOORL)
293     AC_DEFINE(HAVE_FMODL)
294     AC_DEFINE(HAVE_FREXPL)
295     AC_DEFINE(HAVE_LDEXPL)
296     AC_DEFINE(HAVE_LOG10L)
297     AC_DEFINE(HAVE_LOGL)
298     AC_DEFINE(HAVE_MODFL)
299     AC_DEFINE(HAVE_POWL)
300     AC_DEFINE(HAVE_SINCOSL)
301     AC_DEFINE(HAVE_SINL)
302     AC_DEFINE(HAVE_SINHL)
303     AC_DEFINE(HAVE_SQRTL)
304     AC_DEFINE(HAVE_TANL)
305     AC_DEFINE(HAVE_TANHL)
306   fi
307 fi
308
309 # Check for _Unwind_GetIPInfo.
310 GCC_CHECK_UNWIND_GETIPINFO
311
312
313 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
314
315 GCC_HEADER_STDINT(include/gstdint.h)
316
317 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
318 GLIBCXX_ENABLE_SYMVERS([yes])
319 GLIBCXX_ENABLE_VISIBILITY([yes])
320
321 ac_ldbl_compat=no
322 case "$target" in
323   powerpc*-*-linux* | \
324   powerpc*-*-gnu* | \
325   sparc*-*-linux* | \
326   s390*-*-linux* | \
327   alpha*-*-linux*)
328   AC_TRY_COMPILE(, [
329 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
330 #error no need for long double compatibility
331 #endif
332   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
333   if test "$ac_ldbl_compat" = yes; then
334     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
335               [Define if compatibility should be provided for -mlong-double-64.])
336     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
337   fi
338 esac
339 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
340
341 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
342 GLIBCXX_CONFIGURE_TESTSUITE
343
344 # Propagate the target-specific source directories through the build chain.
345 ATOMICITY_SRCDIR=config/${atomicity_dir}
346 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
347 ATOMIC_FLAGS=${atomic_flags}
348 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
349 OS_INC_SRCDIR=config/${os_include_dir}
350 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
351 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
352 AC_SUBST(ATOMICITY_SRCDIR)
353 AC_SUBST(ATOMIC_WORD_SRCDIR)
354 AC_SUBST(ATOMIC_FLAGS)
355 AC_SUBST(CPU_DEFINES_SRCDIR)
356 AC_SUBST(ABI_TWEAKS_SRCDIR)
357 AC_SUBST(OS_INC_SRCDIR)
358 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
359
360
361 # Determine cross-compile flags and AM_CONDITIONALs.
362 #AC_SUBST(GLIBCXX_IS_NATIVE)
363 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
364 GLIBCXX_EVALUATE_CONDITIONALS
365  
366 AC_CACHE_SAVE
367
368 if test ${multilib} = yes; then
369   multilib_arg="--enable-multilib"
370 else
371   multilib_arg=
372 fi
373
374 # Export all the install information.
375 GLIBCXX_EXPORT_INSTALL_INFO
376
377 # Export all the include and flag information to Makefiles.
378 GLIBCXX_EXPORT_INCLUDES
379 GLIBCXX_EXPORT_FLAGS
380
381 if test "$enable_shared" = yes; then
382   LIBSUPCXX_PICFLAGS="-prefer-pic"
383 else
384   LIBSUPCXX_PICFLAGS=
385 fi
386 AC_SUBST(LIBSUPCXX_PICFLAGS)
387
388 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
389 dnl which can all be called multiple times as needed, plus one (different)
390 dnl AC_OUTPUT macro.  This one lists the files to be created:
391 AC_CONFIG_FILES( \
392   Makefile \
393   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
394   )
395 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
396
397 dnl These commands are run at the end of config.status:
398 AC_CONFIG_COMMANDS([default],
399 [if test -n "$CONFIG_FILES"; then
400    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
401    # that multilib installs will end up installed in the correct place.
402    # The testsuite needs it for multilib-aware ABI baseline files.
403    # To work around this not being passed down from config-ml.in ->
404    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
405    # append it here.  Only modify Makefiles that have just been created.
406    #
407    # Also, get rid of this simulated-VPATH thing that automake does.
408    cat > vpsed << \_EOF
409 s!`test -f '$<' || echo '$(srcdir)/'`!!
410 _EOF
411    for i in $SUBDIRS; do
412     case $CONFIG_FILES in
413      *${i}/Makefile*)
414        #echo "Adding MULTISUBDIR to $i/Makefile"
415        sed -f vpsed $i/Makefile > tmp
416        grep '^MULTISUBDIR =' Makefile >> tmp
417        mv tmp $i/Makefile
418        ;;
419     esac
420    done
421    rm vpsed
422  fi
423  (cd include && ${MAKE-make})
424 ],
425 [
426 # Variables needed in config.status (file generation) which aren't already
427 # passed by autoconf.
428 SUBDIRS="$SUBDIRS"
429 ])
430
431 dnl And this actually makes things happen:
432 AC_OUTPUT