libstdc++-v3/config/linker-map.gnu

   1 ## Linker script for GNU ld 2.11.94+ only.
   2 ##
   3 ## Copyright (C) 2002 Free Software Foundation, Inc.
   4 ##
   5 ## This file is part of the libstdc++ version 3 distribution.
   6 ##
   7 ## This file is part of the GNU ISO C++ Library.  This library is free
   8 ## software; you can redistribute it and/or modify it under the
   9 ## terms of the GNU General Public License as published by the
  10 ## Free Software Foundation; either version 2, or (at your option)
  11 ## any later version.
  12 ##
  13 ## This library is distributed in the hope that it will be useful,
  14 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ## GNU General Public License for more details.
  17 ##
  18 ## You should have received a copy of the GNU General Public License along
  19 ## with this library; see the file COPYING.  If not, write to the Free
  20 ## Software Foundation, 59 Temple Place - Suite 330, Boston, MA 02111-1307,
  21 ## USA.
  22
  23
  24 GLIBCPP_3.1 {
  25
  26   global:
  27
  28     # Names inside the 'extern' block are demangled names.
  29     # All but the last are terminated with a semicolon.
  30     extern "C++"
  31     {
  32       std::[A-Za-z]*;
  33       std::__throw_*;
  34       std::__basic_file*;
  35       std::__num_base*;
  36       std::__timepunct*
  37     };
  38
  39     # Names not in an 'extern' block are mangled names.
  40
  41     # operator new(unsigned)
  42     _Znwj;
  43     # operator new(unsigned, std::nothrow_t const&)
  44     _ZnwjRKSt9nothrow_t;
  45     # operator new(unsigned long)
  46     _Znwm;
  47     # operator new(unsigned long, std::nothrow_t const&)
  48     _ZnwmRKSt9nothrow_t;
  49
  50     # operator delete(void*)
  51     _ZdlPv;
  52     # operator delete(void*, std::nothrow_t const&)
  53     _ZdlPvRKSt9nothrow_t;
  54
  55     # operator new[](unsigned)
  56     _Znaj;
  57     # operator new[](unsigned, std::nothrow_t const&)
  58     _ZnajRKSt9nothrow_t;
  59     # operator new[](unsigned long)
  60     _Znam;
  61     # operator new[](unsigned long, std::nothrow_t const&)
  62     _ZnamRKSt9nothrow_t;
  63
  64     # operator delete[](void*)
  65     _ZdaPv;
  66     # operator delete[](void*, std::nothrow_t const&)
  67     _ZdaPvRKSt9nothrow_t;
  68
  69     # vtable
  70     _ZTV*;
  71     _ZTT*;
  72
  73     # typeinfo
  74     _ZTI*;
  75     _ZTS*;
  76
  77     # function-scope static objects requires a guard variable.
  78     _ZGV*;
  79
  80     # virtual function thunks
  81     _ZTh*;
  82     _ZTv*;
  83     _ZTc*;
  84
  85     # std::_S_rb_tree_red
  86     _ZSt14_S_rb_tree_red;
  87
  88     # std::_S_rb_tree_black
  89     _ZSt16_S_rb_tree_black;
  90
  91     # std::__stl_threshold
  92     _ZSt15__stl_threshold;
  93
  94     # std::__stl_chunk_size
  95     _ZSt16__stl_chunk_size;
  96
  97     # std::__convert_to_v
  98     _ZSt14__convert_to_v*;
  99
 100   local:
 101     *;
 102 };
 103
 104
 105 # Symbols in the support library (libsupc++) have their own tag.
 106 CXXABI_1 {
 107
 108   global:
 109     __cxa_*;
 110     __gxx_personality_v0;
 111     __dynamic_cast;
 112
 113   local:
 114     *;
 115 };
 116