libstdc++-v3/config/abi/pre/gnu.ver

   1 ## Linker script for GNU versioning (GNU ld 2.13.91+ only.)
   2 ##
   3 ## Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007
   4 ## Free Software Foundation, Inc.
   5 ##
   6 ## This file is part of the GNU ISO C++ Library.  This library is free
   7 ## software; you can redistribute it and/or modify it under the
   8 ## terms of the GNU General Public License as published by the
   9 ## Free Software Foundation; either version 2, or (at your option)
  10 ## any later version.
  11 ##
  12 ## This library is distributed in the hope that it will be useful,
  13 ## but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ## MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ## GNU General Public License for more details.
  16 ##
  17 ## You should have received a copy of the GNU General Public License along
  18 ## with this library; see the file COPYING.  If not, write to the Free
  19 ## Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301,
  20 ## USA.
  21
  22 GLIBCXX_3.4 {
  23
  24   global:
  25
  26     # Names inside the 'extern' block are demangled names.
  27     extern "C++"
  28     {
  29       std::[A-Za]*;
  30 #     std::ba[a-r]*;
  31       std::basic_[a-e]*;
  32       std::basic_f[a-r]*;
  33 #     std::basic_fstream;
  34       std::basic_f[t-z]*;
  35       std::basic_[g-h]*;
  36       std::basic_i[a-e]*;
  37 #     std::basic_ifstream;
  38       std::basic_i[g-r]*;
  39       std::basic_istr[a-d]*;
  40 #     std::basic_istream;
  41       std::basic_istr[f-z]*;
  42       std::basic_i[t-z]*;
  43       std::basic_[j-n]*;
  44       std::basic_o[a-e]*;
  45 #     std::basic_ofstream;
  46 #     std::basic_o[g-z]*;
  47       std::basic_o[g-r]*;
  48       std::basic_ostr[a-d]*;
  49       std::basic_ostr[f-z]*;
  50       std::basic_[p-r]*;
  51       std::basic_streambuf*;
  52 #     std::basic_string
  53 #     std::basic_stringbuf
  54       std::basic_stringstream*;
  55       std::basic_[t-z]*;
  56       std::ba[t-z]*;
  57       std::b[b-z]*;
  58       std::c[a-g]*;
  59 #     std::char_traits;
  60 #     std::c[i-z]*;
  61       std::c[i-s]*;
  62       std::c[u-z]*;
  63       std::[d-h]*;
  64       std::i[a-n]*;
  65       std::ios_base::[A-Ha-z]*;
  66       std::ios_base::_M_grow_words*;
  67       std::ios_base::_M_init*;
  68       std::ios_base::Init::[A-Za-z]*;
  69       std::ios_base::[J-Za-z]*;
  70       std::i[p-r]*;
  71 #     std::istream
  72 #     std::istreambuf_iterator
  73       std::istringstream*;
  74       std::istrstream*;
  75       std::i[t-z]*;
  76       std::[A-Zj-k]*;
  77       std::length_error*;
  78       std::logic_error*;
  79       std::locale::[A-Za-e]*;
  80       std::locale::facet::[A-Za-z]*;
  81       std::locale::facet::_S_get_c_locale*;
  82       std::locale::facet::_S_clone_c_locale*;
  83       std::locale::facet::_S_create_c_locale*;
  84       std::locale::facet::_S_destroy_c_locale*;
  85       std::locale::[A-Zg-h]*;
  86       std::locale::id::[A-Za-z]*;
  87       std::locale::id::_M_id*;
  88       std::locale::[A-Zj-z]*;
  89       std::locale::_[A-Ha-z]*;
  90       std::locale::_Impl::[A-Za-z]*;
  91 #     std::locale::_Impl::_M_[A-Za-z]*;
  92       std::locale::_[J-Ra-z]*;
  93       std::locale::_S_normalize_category*;
  94       std::locale::_[T-Za-z]*;
  95 #     std::[A-Zm-r]*;
  96       std::[A-Zm]*;
  97       std::n[^u]*;
  98       std::nu[^m]*;
  99       std::num[^e]*;
 100       std::[p-r]*;
 101       std::ostrstream*;
 102       std::out_of_range*;
 103       std::overflow_error*;
 104       std::set_new_handler*;
 105       std::set_terminate*;
 106       std::set_unexpected*;
 107 #     std::string
 108       std::strstream*;
 109       std::strstreambuf*;
 110       std::[A-Zt-z]*;
 111       std::_List_node_base::hook*;
 112       std::_List_node_base::swap*;
 113       std::_List_node_base::unhook*;
 114       std::_List_node_base::reverse*;
 115       std::_List_node_base::transfer*;
 116       std::__throw_*;
 117       std::__timepunct*;
 118       std::__numeric_limits_base*;
 119       std::__num_base::_S_format_float*;
 120       std::__num_base::_S_format_int*;
 121       std::__num_base::_S_atoms_in;
 122       std::__num_base::_S_atoms_out;
 123       std::__moneypunct_cache*;
 124       std::__numpunct_cache*;
 125       std::__timepunct_cache*;
 126       __gnu_debug::_Error_formatter*
 127     };
 128
 129     # Names not in an 'extern' block are mangled names.
 130
 131     # __gnu_debug::_Safe_sequence_base and _Safe_iterator_base
 132     _ZN11__gnu_debug19_Safe_sequence_base13_M_detach_allEv;
 133     _ZN11__gnu_debug19_Safe_sequence_base18_M_detach_singularEv;
 134     _ZN11__gnu_debug19_Safe_sequence_base22_M_revalidate_singularEv;
 135     _ZN11__gnu_debug19_Safe_sequence_base7_M_swapERS0_;
 136     _ZN11__gnu_debug19_Safe_iterator_base9_M_attachEPNS_19_Safe_sequence_baseEb;
 137     _ZN11__gnu_debug19_Safe_iterator_base9_M_detachEv;
 138     _ZNK11__gnu_debug19_Safe_iterator_base11_M_singularEv;
 139     _ZNK11__gnu_debug19_Safe_iterator_base14_M_can_compareERKS0_;
 140
 141     # std::string
 142     _ZNSsC*;
 143     _ZNSsD*;
 144     _ZNSs[0-9][a-z]*;
 145     _ZNSs12_Alloc_hiderC*;
 146     _ZNSs12_M_leak_hardEv;
 147     _ZNSs12_S_constructE[jm]cRKSaIcE;
 148     _ZNSs12_S_empty_repEv;
 149     _ZNSs13_S_copy_chars*;
 150     _ZNSs[0-9][0-9]_M_replace*;
 151     _ZNSs4_Rep10_M_destroy*;
 152     _ZNSs4_Rep10_M_dispose*;
 153     _ZNSs4_Rep10_M_refcopyEv;
 154     _ZNSs4_Rep10_M_refdataEv;
 155     _ZNSs4_Rep12_S_empty_repEv;
 156     _ZNSs4_Rep13_M_set_leakedEv;
 157     _ZNSs4_Rep15_M_set_sharableEv;
 158     _ZNSs4_Rep7_M_grab*;
 159     _ZNSs4_Rep8_M_clone*;
 160     _ZNSs4_Rep9_S_createE[jm][jm]*;
 161     _ZNSs7_M_dataEPc;
 162     _ZNSs7_M_leakEv;
 163     _ZNSs9_M_mutateE[jm][jm][jm];
 164     _ZNSs4_Rep20_S_empty_rep_storageE;
 165     _ZNSs4_Rep11_S_max_sizeE;
 166     _ZNSs4_Rep11_S_terminalE;
 167     _ZNSsaSE*;
 168     _ZNSsixE*;
 169     _ZNSspLE*;
 170     _ZNKSs[0-9][a-z]*;
 171     _ZNKSs[0-9][0-9][a-z]*;
 172     _ZNKSs[a-z]*;
 173     _ZNKSs4_Rep12_M_is_leakedEv;
 174     _ZNKSs4_Rep12_M_is_sharedEv;
 175     _ZNKSs6_M_repEv;
 176     _ZNKSs7_M_dataEv;
 177     _ZNKSs7_M_iendEv;
 178     _ZNKSs8_M_check*;
 179     _ZNKSs8_M_limit*;
 180     _ZNKSs9_M_ibeginEv;
 181     _ZStplIcSt11char_traitsIcESaIcEESbIT_T0_T1_E*;
 182
 183     # std::wstring
 184     _ZNSbIwSt11char_traitsIwESaIwEEC*;
 185     _ZNSbIwSt11char_traitsIwESaIwEED*;
 186     _ZNSbIwSt11char_traitsIwESaIwEE[0-9][a-z]*;
 187     _ZNSbIwSt11char_traitsIwESaIwEE12_Alloc_hiderC*;
 188     _ZNSbIwSt11char_traitsIwESaIwEE12_M_leak_hardEv;
 189     _ZNSbIwSt11char_traitsIwESaIwEE12_S_constructE[jm]wRKS1_;
 190     _ZNSbIwSt11char_traitsIwESaIwEE12_S_empty_repEv;
 191     _ZNSbIwSt11char_traitsIwESaIwEE13_S_copy_chars*;
 192     _ZNSbIwSt11char_traitsIwESaIwEE[0-9][0-9]_M_replace*;
 193     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep10_M_destroy*;
 194     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep10_M_dispose*;
 195     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep10_M_refcopyEv;
 196     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep10_M_refdataEv;
 197     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep12_S_empty_repEv;
 198     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep13_M_set_leakedEv;
 199     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep15_M_set_sharableEv;
 200     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep7_M_grab*;
 201     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep8_M_clone*;
 202     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep9_S_createE[jm][jm]*;
 203     _ZNSbIwSt11char_traitsIwESaIwEE7_M_dataEPw;
 204     _ZNSbIwSt11char_traitsIwESaIwEE7_M_leakEv;
 205     _ZNSbIwSt11char_traitsIwESaIwEE9_M_mutateE[jm][jm][jm];
 206     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep20_S_empty_rep_storageE;
 207     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep11_S_max_sizeE;
 208     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep11_S_terminalE;
 209     _ZNSbIwSt11char_traitsIwESaIwEEaSE*;
 210     _ZNSbIwSt11char_traitsIwESaIwEEixE*;
 211     _ZNSbIwSt11char_traitsIwESaIwEEpLE*;
 212     _ZNKSbIwSt11char_traitsIwESaIwEE[0-9][a-z]*;
 213     _ZNKSbIwSt11char_traitsIwESaIwEE[0-9][0-9][a-z]*;
 214     _ZNKSbIwSt11char_traitsIwESaIwEE[a-z]*;
 215     _ZNKSbIwSt11char_traitsIwESaIwEE4_Rep12_M_is_leakedEv;
 216     _ZNKSbIwSt11char_traitsIwESaIwEE4_Rep12_M_is_sharedEv;
 217     _ZNKSbIwSt11char_traitsIwESaIwEE6_M_repEv;
 218     _ZNKSbIwSt11char_traitsIwESaIwEE7_M_dataEv;
 219     _ZNKSbIwSt11char_traitsIwESaIwEE7_M_iendEv;
 220     _ZNKSbIwSt11char_traitsIwESaIwEE8_M_check*;
 221     _ZNKSbIwSt11char_traitsIwESaIwEE8_M_limit*;
 222     _ZNKSbIwSt11char_traitsIwESaIwEE9_M_ibeginEv;
 223     _ZStplIwSt11char_traitsIwESaIwEESbIT_T0_T1_E*;
 224
 225     # std::basic_stringbuf
 226     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[CD]*;
 227     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9][a-r]*;
 228     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9]seek*;
 229     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9]set*;
 230     _ZNKSt15basic_stringbufIcSt11char_traitsIcESaIcEE3strEv;
 231     _ZNKSt15basic_stringbufIwSt11char_traitsIwESaIwEE3strEv;
 232     _ZNSt15basic_stringbufIcSt11char_traitsIcESaIcEE3strERKSs;
 233     _ZNSt15basic_stringbufIwSt11char_traitsIwESaIwEE3strERKSbIwS1_S2_E;
 234     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9][t-z]*;
 235     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9]_M_[a-z]*;
 236     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE[0-9][0-9]_M_[a-z]*;
 237
 238
 239     # std::basic_iostream constructors, destructors
 240     _ZNSdC*;
 241     _ZNSdD*;
 242
 243     # std::basic_fstream
 244     _ZNSt13basic_fstreamI[cw]St11char_traitsI[cw]EEC*;
 245     _ZNSt13basic_fstreamI[cw]St11char_traitsI[cw]EED*;
 246     _ZNSt13basic_fstreamI[cw]St11char_traitsI[cw]EE5closeEv;
 247     _ZNSt13basic_fstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 248     _ZNSt13basic_fstreamI[cw]St11char_traitsI[cw]EE4open*;
 249     _ZNKSt13basic_fstreamI[cw]St11char_traitsI[cw]EE5rdbufEv;
 250
 251     # std::basic_ifstream
 252     _ZNSt14basic_ifstreamI[cw]St11char_traitsI[cw]EEC*;
 253     _ZNSt14basic_ifstreamI[cw]St11char_traitsI[cw]EED*;
 254     _ZNSt14basic_ifstreamI[cw]St11char_traitsI[cw]EE5closeEv;
 255     _ZNSt14basic_ifstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 256     _ZNSt14basic_ifstreamI[cw]St11char_traitsI[cw]EE4open*;
 257     _ZNKSt14basic_ifstreamI[cw]St11char_traitsI[cw]EE5rdbufEv;
 258
 259     # std::basic_ofstream
 260     _ZNSt14basic_ofstreamI[cw]St11char_traitsI[cw]EEC*;
 261     _ZNSt14basic_ofstreamI[cw]St11char_traitsI[cw]EED*;
 262     _ZNSt14basic_ofstreamI[cw]St11char_traitsI[cw]EE5closeEv;
 263     _ZNSt14basic_ofstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 264     _ZNSt14basic_ofstreamI[cw]St11char_traitsI[cw]EE4open*;
 265     _ZNKSt14basic_ofstreamI[cw]St11char_traitsI[cw]EE5rdbufEv;
 266
 267     # std::basic_istream<char>
 268     _ZNSiC*;
 269     _ZNSiD*;
 270     _ZNKSi[0-9][a-z]*;
 271     _ZNSi[0-9][a-h]*;
 272     _ZNSi[0-9][j-z]*;
 273     _ZNSi6ignoreE[il][il];
 274     _ZNSirsE*[^g];
 275
 276     # std::basic_istream<wchar_t>
 277     _ZNSt13basic_istreamIwSt11char_traitsIwEEC*;
 278     _ZNSt13basic_istreamIwSt11char_traitsIwEED*;
 279     _ZNKSt13basic_istreamIwSt11char_traitsIwEE[0-9][a-z]*;
 280     _ZNSt13basic_istreamIwSt11char_traitsIwEE[0-9][a-h]*;
 281     _ZNSt13basic_istreamIwSt11char_traitsIwEE[0-9][j-z]*;
 282     _ZNSt13basic_istreamIwSt11char_traitsIwEE6ignoreE[il][ijlm];
 283     _ZNSt13basic_istreamIwSt11char_traitsIwEErsE*[^g];
 284
 285     # std::istream operators and extractors
 286     _ZSt7getlineI[cw]St11char_traitsI[cw]ESaI[cw]EERSt13basic_istream*;
 287     _ZSt2wsI[cw]St11char_traitsI[cw]EE*;
 288     _ZStrsI[cw]St11char_traitsI[cw]EERSt13basic_istream*;
 289     _ZStrsI[cw]St11char_traitsI[cw]ESaI[cw]EERSt13basic_istream*;
 290     _ZStrsISt11char_traitsI[cw]EERSt13basic_istream*;
 291     _ZStrsId[cw]St11char_traitsI[cw]EERSt13basic_istream*;
 292     _ZStrsIe[cw]St11char_traitsI[cw]EERSt13basic_istream*;
 293     _ZStrsIf[cw]St11char_traitsI[cw]EERSt13basic_istream*;
 294
 295     # std::basic_ostream<char>
 296     _ZNSoC*;
 297     _ZNSoD*;
 298     _ZNKSo6sentrycvbEv;
 299     _ZNSo8_M_writeEPKc[il];
 300     _ZNSo[0-9][a-z]*;
 301     _ZNSolsE*[^g];
 302
 303     # std::basic_ostream<wchar_t>
 304     _ZNSt13basic_ostreamIwSt11char_traitsIwEEC*;
 305     _ZNSt13basic_ostreamIwSt11char_traitsIwEED*;
 306     _ZNKSt13basic_ostreamIwSt11char_traitsIwEE[0-9][a-z]*;
 307     _ZNSt13basic_ostreamIwSt11char_traitsIwEE3putEw;
 308     _ZNSt13basic_ostreamIwSt11char_traitsIwEE5flushEv;
 309     _ZNSt13basic_ostreamIwSt11char_traitsIwEE5seekpE*;
 310     _ZNSt13basic_ostreamIwSt11char_traitsIwEE5tellpEv;
 311     _ZNSt13basic_ostreamIwSt11char_traitsIwEE5writeEPKw*;
 312     _ZNSt13basic_ostreamIwSt11char_traitsIwEE6sentry*;
 313     _ZNSt13basic_ostreamIwSt11char_traitsIwEE8_M_writeEPKw[il];
 314     _ZNSt13basic_ostreamIwSt11char_traitsIwEElsE*[^g];
 315
 316     # std::ostream operators and inserters
 317     _ZSt4end[ls]I[cw]St11char_traitsI[cw]EERSt13basic_ostream*;
 318     _ZSt5flushI[cw]St11char_traitsI[cw]EERSt13basic_ostream*;
 319     _ZStlsI[cw]St11char_traitsI[cw]EERSt13basic_ostream*;
 320     _ZStlsI[cw]St11char_traitsI[cw]ESaI[cw]EERSt13basic_ostream*;
 321     _ZStlsISt11char_traitsI[cw]EERSt13basic_ostream*;
 322     _ZStlsId[cw]St11char_traitsI[cw]EERSt13basic_ostream*;
 323     _ZStlsIe[cw]St11char_traitsI[cw]EERSt13basic_ostream*;
 324     _ZStlsIf[cw]St11char_traitsI[cw]EERSt13basic_ostream*;
 325
 326     # std::locale destructors
 327     _ZNSt6localeD*;
 328
 329     # std::locale::facet destructors
 330     _ZNSt6locale5facetD*;
 331
 332     # std::locale::_Impl constructors, destructors
 333     _ZNSt6locale5_ImplC*;
 334     _ZNSt6locale5_ImplD*;
 335
 336     # std::ios_base, std::ios_base::Init destructors
 337     _ZNSt8ios_baseD*;
 338     _ZNSt8ios_base4InitD*;
 339
 340     # bool std::has_facet
 341     _ZSt9has_facetIS*;
 342
 343     # std::use_facet
 344     _ZSt9use_facetIS*;
 345
 346     # std::ctype
 347     _ZNKSt5ctypeIcE8*;
 348     _ZNKSt5ctypeIcE9*;
 349     _ZNKSt5ctypeIcE10*;
 350     _ZNKSt5ctypeIw*;
 351     _ZNSt5ctypeI[cw]*;
 352
 353     # std::ctype_base
 354     _ZNSt10ctype_base*;
 355
 356     # std::ctype_byname
 357     _ZNSt12ctype_bynameI[cw]*;
 358
 359     # std::num_get
 360     _ZNKSt7num_getI[cw]St19istreambuf_iteratorI[cw]St11char_traitsI[cw]EEE*;
 361
 362     # std::num_put
 363     _ZNKSt7num_putI[cw]St19ostreambuf_iteratorI[cw]St11char_traitsI[cw]EEE*;
 364
 365     # std::money_get
 366     _ZNKSt9money_getI[cw]St19istreambuf_iteratorI[cw]St11char_traitsI[cw]EEE*;
 367
 368     # std::money_put
 369     _ZNKSt9money_putI[cw]St19ostreambuf_iteratorI[cw]St11char_traitsI[cw]EEE*;
 370
 371     # std::numeric_limits
 372     _ZNSt14numeric_limitsI[^g]*;
 373
 374     # std::_Rb_tree
 375     _ZSt18_Rb_tree_decrementPKSt18_Rb_tree_node_base;
 376     _ZSt18_Rb_tree_decrementPSt18_Rb_tree_node_base;
 377     _ZSt18_Rb_tree_incrementPKSt18_Rb_tree_node_base;
 378     _ZSt18_Rb_tree_incrementPSt18_Rb_tree_node_base;
 379     _ZSt20_Rb_tree_black_countPKSt18_Rb_tree_node_baseS1_;
 380     _ZSt20_Rb_tree_rotate_leftPSt18_Rb_tree_node_baseRS0_;
 381     _ZSt21_Rb_tree_rotate_rightPSt18_Rb_tree_node_baseRS0_;
 382     _ZSt28_Rb_tree_rebalance_for_erasePSt18_Rb_tree_node_baseRS_;
 383     _ZSt29_Rb_tree_insert_and_rebalancebPSt18_Rb_tree_node_baseS0_RS_;
 384
 385     # std::__basic_file
 386     _ZNKSt12__basic_fileIcE7is_openEv;
 387     _ZNSt12__basic_fileIcE2fdEv;
 388     _ZNSt12__basic_fileIcE4openEPKcSt13_Ios_Openmodei;
 389     _ZNSt12__basic_fileIcE4syncEv;
 390     _ZNSt12__basic_fileIcE5closeEv;
 391     _ZNSt12__basic_fileIcE6xsgetn*;
 392     _ZNSt12__basic_fileIcE6xsputn*;
 393     _ZNSt12__basic_fileIcE7seekoff*;
 394     _ZNSt12__basic_fileIcE8sys_openE*St13_Ios_Openmode;
 395     _ZNSt12__basic_fileIcE8xsputn_2*;
 396     _ZNSt12__basic_fileIcE9showmanycEv;
 397     _ZNSt12__basic_fileIcEC*;
 398     _ZNSt12__basic_fileIcED*;
 399
 400     # std::__convert_to_v
 401     _ZSt14__convert_to_vI[^g]*;
 402
 403     # __gnu_cxx::stdio_sync_filebuf
 404     _ZTVN9__gnu_cxx18stdio_sync_filebufI[cw]St11char_traitsI[cw]EEE;
 405
 406     # __gnu_cxx::__atomic_add
 407     # __gnu_cxx::__exchange_and_add
 408     _ZN9__gnu_cxx12__atomic_addEPV[il]i;
 409     _ZN9__gnu_cxx18__exchange_and_addEPV[il]i;
 410
 411     # debug mode
 412     _ZN10__gnu_norm15_List_node_base4hook*;
 413     _ZN10__gnu_norm15_List_node_base4swap*;
 414     _ZN10__gnu_norm15_List_node_base6unhookEv;
 415     _ZN10__gnu_norm15_List_node_base7reverseEv;
 416     _ZN10__gnu_norm15_List_node_base8transfer*;
 417
 418     # operator new(size_t)
 419     _Znw[jm];
 420     # operator new(size_t, std::nothrow_t const&)
 421     _Znw[jm]RKSt9nothrow_t;
 422
 423     # operator delete(void*)
 424     _ZdlPv;
 425     # operator delete(void*, std::nothrow_t const&)
 426     _ZdlPvRKSt9nothrow_t;
 427
 428     # operator new[](size_t)
 429     _Zna[jm];
 430     # operator new[](size_t, std::nothrow_t const&)
 431     _Zna[jm]RKSt9nothrow_t;
 432
 433     # operator delete[](void*)
 434     _ZdaPv;
 435     # operator delete[](void*, std::nothrow_t const&)
 436     _ZdaPvRKSt9nothrow_t;
 437
 438     # virtual table
 439     _ZTVNSt8ios_base7failureE;
 440     _ZTVNSt6locale5facetE;
 441     _ZTVS[a-z];
 442     _ZTVSt[0-9][A-Za-z]*;
 443     _ZTVSt[0-9][0-9][A-Za-z]*;
 444     _ZTVSt11__timepunctI[cw]E;
 445     _ZTVSt23__codecvt_abstract_baseI[cw]c11__mbstate_tE;
 446     _ZTVSt21__ctype_abstract_baseI[cw]E;
 447
 448     # VTT structure
 449     _ZTTS[a-z];
 450     _ZTTSt[0-9][A-Za-z]*;
 451     _ZTTSt[0-9][0-9][A-Za-z]*;
 452
 453     # typeinfo structure
 454     _ZTIS[a-z];
 455     _ZTINSt8ios_base7failureE;
 456     _ZTINSt6locale5facetE;
 457     _ZTISt[0-9][A-Za-z]*;
 458     _ZTISt[0-9][0-9][A-Za-z]*;
 459     _ZTISt11__timepunctI[cw]E;
 460     _ZTISt10__num_base;
 461     _ZTISt21__ctype_abstract_baseI[cw]E;
 462     _ZTISt23__codecvt_abstract_baseI[cw]c11__mbstate_tE;
 463     _ZTIN9__gnu_cxx18stdio_sync_filebufI[cw]St11char_traitsI[cw]EEE;
 464     _ZTIN9__gnu_cxx13stdio_filebufI[cw]St11char_traitsI[cw]EEE;
 465
 466     # typeinfo name
 467     _ZTSNSt8ios_base7failureE;
 468     _ZTSNSt6locale5facetE;
 469     _ZTSS[a-z];
 470     _ZTSSt[0-9][A-Za-z]*;
 471     _ZTSSt[0-9][0-9][A-Za-z]*;
 472     _ZTSSt11__timepunctI[cw]E;
 473     _ZTSSt10__num_base;
 474     _ZTSSt21__ctype_abstract_baseI[cw]E;
 475     _ZTSSt23__codecvt_abstract_baseI[cw]c11__mbstate_tE;
 476     _ZTSN9__gnu_cxx18stdio_sync_filebufI[cw]St11char_traitsI[cw]EEE;
 477     _ZTSN9__gnu_cxx13stdio_filebufI[cw]St11char_traitsI[cw]EEE;
 478
 479     # std::bad_alloc::~bad_alloc, std::bad_cast::~bad_cast,
 480     # std::bad_typeid::~bad_typeid, std::bad_exception::~bad_exception
 481     _ZNSt9bad_allocD*;
 482     _ZNSt8bad_castD*;
 483     _ZNSt10bad_typeidD*;
 484     _ZNSt13bad_exceptionD*;
 485
 486     # function-scope static objects requires a guard variable.
 487     _ZGVNSt[^1]*;
 488     _ZGVNSt1[^7]*;
 489
 490     # virtual function thunks
 491     _ZThn8_NS*;
 492     _ZThn16_NS*;
 493     _ZTv0_n12_NS*;
 494     _ZTv0_n24_NS*;
 495
 496     # stub functions from libmath
 497     sinf;
 498     sinl;
 499     sinhf;
 500     sinhl;
 501     cosf;
 502     cosl;
 503     coshf;
 504     coshl;
 505     tanf;
 506     tanl;
 507     tanhf;
 508     tanhl;
 509     atan2f;
 510     atan2l;
 511     expf;
 512     expl;
 513     hypotf;
 514     hypotl;
 515     hypot;
 516     logf;
 517     logl;
 518     log10f;
 519     log10l;
 520     powf;
 521     powl;
 522     sqrtf;
 523     sqrtl;
 524     copysignf;
 525     __signbit;
 526     __signbitf;
 527     __signbitl;
 528
 529    # GLIBCXX_ABI compatibility only.
 530     # std::string
 531     _ZNKSs11_M_disjunctEPKc;
 532     _ZNKSs15_M_check_lengthE[jm][jm]PKc;
 533     _ZNSs4_Rep26_M_set_length_and_sharableE*;
 534     _ZNSs7_M_copyEPcPKc[jm];
 535     _ZNSs7_M_moveEPcPKc[jm];
 536     _ZNSs9_M_assignEPc[jm]c;
 537
 538     # std::wstring
 539     _ZNKSbIwSt11char_traitsIwESaIwEE11_M_disjunctEPKw;
 540     _ZNKSbIwSt11char_traitsIwESaIwEE15_M_check_lengthE[jm][jm]PKc;
 541     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep26_M_set_length_and_sharableE*;
 542     _ZNSbIwSt11char_traitsIwESaIwEE7_M_copyEPwPKw[jm];
 543     _ZNSbIwSt11char_traitsIwESaIwEE7_M_moveEPwPKw[jm];
 544     _ZNSbIwSt11char_traitsIwESaIwEE9_M_assignEPw[jm]w;
 545
 546     _ZNKSt13basic_fstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 547     _ZNKSt14basic_ifstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 548     _ZNKSt14basic_ofstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 549
 550     _ZNSi6ignoreE[ilv];
 551     _ZNSt13basic_istreamIwSt11char_traitsIwEE6ignoreE[ilv];
 552
 553     _ZNSt11char_traitsI[cw]E2eqERK[cw]S2_;
 554
 555     _ZNSt19istreambuf_iteratorI[cw]St11char_traitsI[cw]EEppEv;
 556
 557     # std::locale::Impl _M_ members
 558     _ZNSt6locale5_Impl16_M_install_facetEPKNS_2idEPKNS_5facetE;
 559     _ZNSt6locale5_Impl16_M_replace_facetEPKS0_PKNS_2idE;
 560     _ZNSt6locale5_Impl19_M_replace_categoryEPKS0_PKPKNS_2idE;
 561     _ZNSt6locale5_Impl21_M_replace_categoriesEPKS0_i;
 562
 563   # DO NOT DELETE THIS LINE.  Port-specific symbols, if any, will be here.
 564
 565   local:
 566     *;
 567 };
 568
 569 GLIBCXX_3.4.1 {
 570
 571     _ZNSt12__basic_fileIcE4fileEv;
 572
 573 } GLIBCXX_3.4;
 574
 575 GLIBCXX_3.4.2 {
 576
 577     _ZN9__gnu_cxx18stdio_sync_filebufI[cw]St11char_traitsI[cw]EE4fileEv;
 578
 579     _ZN9__gnu_cxx17__pool_alloc_base9_M_refillE[jm];
 580     _ZN9__gnu_cxx17__pool_alloc_base16_M_get_free_listE[jm];
 581     _ZN9__gnu_cxx17__pool_alloc_base12_M_get_mutexEv;
 582
 583 } GLIBCXX_3.4.1;
 584
 585 GLIBCXX_3.4.3 {
 586
 587     # stub functions from libmath
 588     acosf;
 589     acosl;
 590     asinf;
 591     asinl;
 592     atanf;
 593     atanl;
 594     ceilf;
 595     ceill;
 596     floorf;
 597     floorl;
 598     fmodf;
 599     fmodl;
 600     frexpf;
 601     frexpl;
 602     ldexpf;
 603     ldexpl;
 604     modff;
 605     modfl;
 606
 607 } GLIBCXX_3.4.2;
 608
 609 GLIBCXX_3.4.4 {
 610
 611     _ZN9__gnu_cxx6__poolILb0EE13_M_initializeEv;
 612     _ZN9__gnu_cxx6__poolILb1EE13_M_initializeEPFvPvE;
 613     _ZN9__gnu_cxx6__poolILb1EE21_M_destroy_thread_keyEPv;
 614     _ZN9__gnu_cxx6__poolILb1EE16_M_get_thread_idEv;
 615     _ZN9__gnu_cxx6__poolILb[01]EE16_M_reserve_blockE[jm][jm];
 616     _ZN9__gnu_cxx6__poolILb[01]EE16_M_reclaim_blockEPc[jm];
 617     _ZN9__gnu_cxx6__poolILb[01]EE10_M_destroyEv;
 618
 619     _ZN9__gnu_cxx9free_list6_M_getE*;
 620     _ZN9__gnu_cxx9free_list8_M_clearEv;
 621
 622 } GLIBCXX_3.4.3;
 623
 624 GLIBCXX_3.4.5 {
 625
 626     # std::string
 627     _ZNKSs11_M_disjunctEPKc;
 628     _ZNKSs15_M_check_lengthE[jm][jm]PKc;
 629     _ZNSs4_Rep26_M_set_length_and_sharableE*;
 630     _ZNSs7_M_copyEPcPKc[jm];
 631     _ZNSs7_M_moveEPcPKc[jm];
 632     _ZNSs9_M_assignEPc[jm]c;
 633
 634     # std::wstring
 635     _ZNKSbIwSt11char_traitsIwESaIwEE11_M_disjunctEPKw;
 636     _ZNKSbIwSt11char_traitsIwESaIwEE15_M_check_lengthE[jm][jm]PKc;
 637     _ZNSbIwSt11char_traitsIwESaIwEE4_Rep26_M_set_length_and_sharableE*;
 638     _ZNSbIwSt11char_traitsIwESaIwEE7_M_copyEPwPKw[jm];
 639     _ZNSbIwSt11char_traitsIwESaIwEE7_M_moveEPwPKw[jm];
 640     _ZNSbIwSt11char_traitsIwESaIwEE9_M_assignEPw[jm]w;
 641
 642     _ZNKSt13basic_fstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 643     _ZNKSt14basic_ifstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 644     _ZNKSt14basic_ofstreamI[cw]St11char_traitsI[cw]EE7is_openEv;
 645
 646     _ZNSi6ignoreE[ilv];
 647     _ZNSt13basic_istreamIwSt11char_traitsIwEE6ignoreE[ilv];
 648
 649     _ZNSt11char_traitsI[cw]E2eqERK[cw]S2_;
 650
 651     _ZNSt19istreambuf_iteratorI[cw]St11char_traitsI[cw]EEppEv;
 652
 653 } GLIBCXX_3.4.4;
 654
 655 GLIBCXX_3.4.6 {
 656
 657     _ZSt17__copy_streambufsI[cw]St11char_traitsI[cw]EEiPSt15basic_streambuf*;
 658     _ZNSt8ios_base17_M_call_callbacksENS_5eventE;
 659     _ZNSt8ios_base20_M_dispose_callbacksEv;
 660     _ZNSt6locale5facet13_S_get_c_nameEv;
 661
 662     _ZNSt15basic_stringbufI[cw]St11char_traitsI[cw]ESaI[cw]EE9showmanycEv;
 663
 664     _ZNKSt15basic_stringbufIwSt11char_traitsIwESaIwEE3strEv;
 665
 666     _ZN9__gnu_cxx6__poolILb1EE13_M_initializeEv;
 667
 668 } GLIBCXX_3.4.5;
 669
 670 GLIBCXX_3.4.7 {
 671
 672     _ZNSt6locale5_Impl16_M_install_cacheEPKNS_5facetE[jm];
 673
 674 } GLIBCXX_3.4.6;
 675
 676 GLIBCXX_3.4.8 {
 677
 678     _ZSt17__copy_streambufsI[cw]St11char_traitsI[cw]EElPSt15basic_streambuf*;
 679
 680 } GLIBCXX_3.4.7;
 681
 682 GLIBCXX_3.4.9 {
 683
 684     _ZNSt6__norm15_List_node_base4hook*;
 685     _ZNSt6__norm15_List_node_base4swap*;
 686     _ZNSt6__norm15_List_node_base6unhookEv;
 687     _ZNSt6__norm15_List_node_base7reverseEv;
 688     _ZNSt6__norm15_List_node_base8transfer*;
 689
 690     _ZNSo9_M_insertI[^g]*;
 691     _ZNSt13basic_ostreamIwSt11char_traitsIwEE9_M_insertI[^g]*;
 692     _ZNSi10_M_extractI[^g]*;
 693     _ZNSt13basic_istreamIwSt11char_traitsIwEE10_M_extractI[^g]*;
 694
 695     _ZSt21__copy_streambufs_eofI[cw]St11char_traitsI[cw]EE[il]PSt15basic_streambuf*;
 696
 697     _ZSt16__ostream_insert*;
 698
 699     _ZN11__gnu_debug19_Safe_sequence_base12_M_get_mutexEv;
 700     _ZN11__gnu_debug19_Safe_iterator_base16_M_attach_singleEPNS_19_Safe_sequence_baseEb;
 701     _ZN11__gnu_debug19_Safe_iterator_base16_M_detach_singleEv;
 702     _ZN11__gnu_debug19_Safe_iterator_base12_M_get_mutexEv;
 703
 704     _ZNKSt9bad_alloc4whatEv;
 705     _ZNKSt8bad_cast4whatEv;
 706     _ZNKSt10bad_typeid4whatEv;
 707     _ZNKSt13bad_exception4whatEv;
 708
 709 } GLIBCXX_3.4.8;
 710
 711 # Symbols in the support library (libsupc++) have their own tag.
 712 CXXABI_1.3 {
 713
 714   global:
 715     __cxa_allocate_exception;
 716     __cxa_bad_cast;
 717     __cxa_bad_typeid;
 718     __cxa_begin_catch;
 719     __cxa_begin_cleanup;
 720     __cxa_call_unexpected;
 721     __cxa_current_exception_type;
 722     __cxa_demangle;
 723     __cxa_end_catch;
 724     __cxa_end_cleanup;
 725     __cxa_free_exception;
 726     __cxa_get_globals;
 727     __cxa_get_globals_fast;
 728     __cxa_guard_abort;
 729     __cxa_guard_acquire;
 730     __cxa_guard_release;
 731     __cxa_pure_virtual;
 732     __cxa_rethrow;
 733     __cxa_throw;
 734     __cxa_type_match;
 735     __cxa_vec_cctor;
 736     __cxa_vec_cleanup;
 737     __cxa_vec_ctor;
 738     __cxa_vec_delete2;
 739     __cxa_vec_delete3;
 740     __cxa_vec_delete;
 741     __cxa_vec_dtor;
 742     __cxa_vec_new2;
 743     __cxa_vec_new3;
 744     __cxa_vec_new;
 745     __gxx_personality_v0;
 746     __gxx_personality_sj0;
 747     __dynamic_cast;
 748
 749     # *_type_info classes, ctor and dtor
 750     _ZN10__cxxabiv117__array_type_info*;
 751     _ZN10__cxxabiv117__class_type_info*;
 752     _ZN10__cxxabiv116__enum_type_info*;
 753     _ZN10__cxxabiv120__function_type_info*;
 754     _ZN10__cxxabiv123__fundamental_type_info*;
 755     _ZN10__cxxabiv117__pbase_type_info*;
 756     _ZN10__cxxabiv129__pointer_to_member_type_info*;
 757     _ZN10__cxxabiv119__pointer_type_info*;
 758     _ZN10__cxxabiv120__si_class_type_info*;
 759     _ZN10__cxxabiv121__vmi_class_type_info*;
 760
 761     # *_type_info classes, member functions
 762     _ZNK10__cxxabiv117__class_type_info*;
 763     _ZNK10__cxxabiv120__function_type_info*;
 764     _ZNK10__cxxabiv117__pbase_type_info*;
 765     _ZNK10__cxxabiv129__pointer_to_member_type_info*;
 766     _ZNK10__cxxabiv119__pointer_type_info*;
 767     _ZNK10__cxxabiv120__si_class_type_info*;
 768     _ZNK10__cxxabiv121__vmi_class_type_info*;
 769
 770     # virtual table
 771     _ZTVN10__cxxabiv117__array_type_infoE;
 772     _ZTVN10__cxxabiv117__class_type_infoE;
 773     _ZTVN10__cxxabiv116__enum_type_infoE;
 774     _ZTVN10__cxxabiv120__function_type_infoE;
 775     _ZTVN10__cxxabiv123__fundamental_type_infoE;
 776     _ZTVN10__cxxabiv117__pbase_type_infoE;
 777     _ZTVN10__cxxabiv129__pointer_to_member_type_infoE;
 778     _ZTVN10__cxxabiv119__pointer_type_infoE;
 779     _ZTVN10__cxxabiv120__si_class_type_infoE;
 780     _ZTVN10__cxxabiv121__vmi_class_type_infoE;
 781
 782     # typeinfo structure (and some names)
 783     _ZTI[a-fh-z];
 784     _ZTIP[a-fh-z];
 785     _ZTIPK[a-fh-z];
 786     _ZTIN10__cxxabiv117__array_type_infoE;
 787     _ZTIN10__cxxabiv117__class_type_infoE;
 788     _ZTIN10__cxxabiv116__enum_type_infoE;
 789     _ZTIN10__cxxabiv120__function_type_infoE;
 790     _ZTIN10__cxxabiv123__fundamental_type_infoE;
 791     _ZTIN10__cxxabiv117__pbase_type_infoE;
 792     _ZTIN10__cxxabiv129__pointer_to_member_type_infoE;
 793     _ZTIN10__cxxabiv119__pointer_type_infoE;
 794     _ZTIN10__cxxabiv120__si_class_type_infoE;
 795     _ZTIN10__cxxabiv121__vmi_class_type_infoE;
 796
 797     # typeinfo name
 798     _ZTS[a-fh-z];
 799     _ZTSP[a-fh-z];
 800     _ZTSPK[a-fh-z];
 801     _ZTSN10__cxxabiv117__array_type_infoE;
 802     _ZTSN10__cxxabiv117__class_type_infoE;
 803     _ZTSN10__cxxabiv116__enum_type_infoE;
 804     _ZTSN10__cxxabiv120__function_type_infoE;
 805     _ZTSN10__cxxabiv123__fundamental_type_infoE;
 806     _ZTSN10__cxxabiv117__pbase_type_infoE;
 807     _ZTSN10__cxxabiv129__pointer_to_member_type_infoE;
 808     _ZTSN10__cxxabiv119__pointer_type_infoE;
 809     _ZTSN10__cxxabiv120__si_class_type_infoE;
 810     _ZTSN10__cxxabiv121__vmi_class_type_infoE;
 811
 812     # __gnu_cxx::_verbose_terminate_handler()
 813     _ZN9__gnu_cxx27__verbose_terminate_handlerEv;
 814
 815   local:
 816     *;
 817 };
 818
 819 CXXABI_1.3.1 {
 820
 821     __cxa_get_exception_ptr;
 822
 823 } CXXABI_1.3;