libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4-p6
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999, 2001 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize basic configure bits, set toplevel_srcdir for Makefiles.
  15 dnl
  16 dnl GLIBCPP_TOPREL_CONFIGURE
  17 AC_DEFUN(GLIBCPP_TOPREL_CONFIGURE, [
  18   dnl Default to --enable-multilib (this is also passed by default
  19   dnl from the ubercommon-top-level configure)
  20   AC_ARG_ENABLE(multilib,
  21   [  --enable-multilib       build hella library versions (default)],
  22   [case "${enableval}" in
  23     yes) multilib=yes ;;
  24     no)  multilib=no ;;
  25     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  26    esac], [multilib=yes])dnl
  27
  28   # When building with srcdir == objdir, links to the source files will
  29   # be created in directories within the target_subdir.  We have to
  30   # adjust toplevel_srcdir accordingly, so that configure finds
  31   # install-sh and other auxiliary files that live in the top-level
  32   # source directory.
  33   if test "${srcdir}" = "."; then
  34     if test -z "${with_target_subdir}"; then
  35       toprel=".."
  36     else
  37       if test "${with_target_subdir}" != "."; then
  38         toprel="${with_multisrctop}../.."
  39       else
  40         toprel="${with_multisrctop}.."
  41       fi
  42     fi
  43   else
  44     toprel=".."
  45   fi
  46   AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  47   toplevel_srcdir=\${top_srcdir}/$toprel
  48   AC_SUBST(toplevel_srcdir)
  49 ])
  50
  51 dnl
  52 dnl Initialize the rest of the library configury.
  53 dnl
  54 dnl GLIBCPP_CONFIGURE
  55 AC_DEFUN(GLIBCPP_CONFIGURE, [
  56   # Export build and source directories.
  57   # These need to be absolute paths, yet at the same time need to
  58   # canonicalize only relative paths, because then amd will not unmount
  59   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  60   glibcpp_builddir=`${PWDCMD-pwd}`
  61   case $srcdir in
  62   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  63   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  64   esac
  65   AC_SUBST(glibcpp_builddir)
  66   AC_SUBST(glibcpp_srcdir)
  67
  68   dnl This is here just to satisfy automake.
  69   ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  70
  71   AC_PROG_AWK
  72   # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.5x, can also
  73   # be 'cp -p' if linking isn't available.  Uncomment the next line to
  74   # force a particular method.
  75   #ac_cv_prog_LN_S='cp -p'
  76   AC_PROG_LN_S
  77
  78   # We use these options to decide which functions to include.
  79   AC_ARG_WITH(target-subdir,
  80   [  --with-target-subdir=SUBDIR
  81                           configuring in a subdirectory])
  82   AC_ARG_WITH(cross-host,
  83   [  --with-cross-host=HOST  configuring with a cross compiler])
  84
  85   AC_ARG_WITH(newlib,
  86   [  --with-newlib                    Configuring with newlib])
  87
  88   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  89   AC_SUBST(glibcpp_basedir)
  90
  91   # Never versions of autoconf add an underscore to these functions.
  92   # Prevent future problems ...
  93   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  94   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  95   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  96   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  97
  98   # AC_PROG_CC
  99   # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
 100   # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
 101   # are probably using a cross compiler, which will not be able to fully
 102   # link an executable.  This is addressed in later versions of autoconf.
 103
 104   AC_DEFUN(LIB_AC_PROG_CC,
 105   [AC_BEFORE([$0], [AC_PROG_CPP])dnl
 106   dnl Fool anybody using AC_PROG_CC.
 107   AC_PROVIDE([AC_PROG_CC])
 108   AC_CHECK_PROG(CC, gcc, gcc)
 109   if test -z "$CC"; then
 110     AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
 111     test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
 112   fi
 113
 114   AC_PROG_CC_GNU
 115
 116   if test $ac_cv_prog_gcc = yes; then
 117     GCC=yes
 118   dnl Check whether -g works, even if CFLAGS is set, in case the package
 119   dnl plays around with CFLAGS (such as to build both debugging and
 120   dnl normal versions of a library), tasteless as that idea is.
 121     ac_test_CFLAGS="${CFLAGS+set}"
 122     ac_save_CFLAGS="$CFLAGS"
 123     CFLAGS=
 124     AC_PROG_CC_G
 125     if test "$ac_test_CFLAGS" = set; then
 126       CFLAGS="$ac_save_CFLAGS"
 127     elif test $ac_cv_prog_cc_g = yes; then
 128       CFLAGS="-g -O2"
 129     else
 130       CFLAGS="-O2"
 131     fi
 132   else
 133     GCC=
 134     test "${CFLAGS+set}" = set || CFLAGS="-g"
 135   fi
 136   ])
 137
 138   LIB_AC_PROG_CC
 139
 140   # Likewise for AC_PROG_CXX.  We can't just call it directly because g++
 141   # will try to link in libstdc++.
 142   AC_DEFUN(LIB_AC_PROG_CXX,
 143   [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 144   dnl Fool anybody using AC_PROG_CXX.
 145   AC_PROVIDE([AC_PROG_CXX])
 146   # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 147   # flags that come in CXX while configuring libstdc++.  They're different
 148   # from those used for all other target libraries.  If CXX is set in
 149   # the environment, respect that here.
 150   glibcpp_CXX=$CXX
 151   AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 152   AC_SUBST(glibcpp_CXX)
 153   CXX=$glibcpp_CXX
 154   test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 155
 156   AC_PROG_CXX_GNU
 157
 158   if test $ac_cv_prog_gxx = yes; then
 159     GXX=yes
 160     dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 161     dnl plays around with CXXFLAGS (such as to build both debugging and
 162     dnl normal versions of a library), tasteless as that idea is.
 163     ac_test_CXXFLAGS="${CXXFLAGS+set}"
 164     ac_save_CXXFLAGS="$CXXFLAGS"
 165     CXXFLAGS=
 166     AC_PROG_CXX_G
 167     if test "$ac_test_CXXFLAGS" = set; then
 168       CXXFLAGS="$ac_save_CXXFLAGS"
 169     elif test $ac_cv_prog_cxx_g = yes; then
 170       CXXFLAGS="-g -O2"
 171     else
 172       CXXFLAGS="-O2"
 173     fi
 174   else
 175     GXX=
 176     test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 177   fi
 178   ])
 179
 180   LIB_AC_PROG_CXX
 181
 182   # For directory versioning (e.g., headers) and other variables.
 183   AC_MSG_CHECKING([for GCC version number])
 184   gcc_version=`$glibcpp_CXX -dumpversion`
 185   AC_MSG_RESULT($gcc_version)
 186
 187   # For some reason, gettext needs this.
 188   AC_ISC_POSIX
 189
 190   AC_CHECK_TOOL(AS, as)
 191   AC_CHECK_TOOL(AR, ar)
 192   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 193   AC_PROG_INSTALL
 194
 195   AM_MAINTAINER_MODE
 196
 197   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 198   # at least currently, we never actually build a program, so we never
 199   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 200   # fails, because we are probably configuring with a cross compiler
 201   # which can't create executables.  So we include AC_EXEEXT to keep
 202   # automake happy, but we don't execute it, since we don't care about
 203   # the result.
 204   if false; then
 205     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 206     # to nothing, so nothing would remain between `then' and `fi' if it
 207     # were not for the `:' below.
 208     :
 209     AC_EXEEXT
 210   fi
 211
 212   case [$]{glibcpp_basedir} in
 213     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 214     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 215   esac
 216
 217   # Set up safe default values for all subsequent AM_CONDITIONAL tests.
 218   need_libmath=no
 219   enable_wchar_t=no
 220   #enable_debug=no
 221   #glibcpp_pch_comp=no
 222   #enable_cheaders=c
 223   #c_compatibility=no
 224   #enable_abi_check=no
 225   #enable_symvers=no
 226
 227   # Find platform-specific directories containing configuration info.  In
 228   # addition to possibly modifying the same flags, it also sets up symlinks.
 229   GLIBCPP_CHECK_HOST
 230 ])
 231
 232
 233 dnl
 234 dnl Check to see if g++ can compile this library, and if so, if any version-
 235 dnl specific precautions need to be taken.
 236 dnl
 237 dnl GLIBCPP_CHECK_COMPILER_VERSION
 238 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 239 if test ! -f stamp-sanity-compiler; then
 240   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 241   AC_LANG_SAVE
 242   AC_LANG_CPLUSPLUS
 243   AC_TRY_COMPILE(, [
 244   #if __GNUC__ < 3
 245     not_ok
 246   #endif
 247   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 248   AC_LANG_RESTORE
 249   AC_MSG_RESULT($gpp_satisfactory)
 250   touch stamp-sanity-compiler
 251 fi
 252 ])
 253
 254
 255 dnl
 256 dnl Tests for newer compiler features, or features that are present in newer
 257 dnl compiler versions but not older compiler versions still in use, should
 258 dnl be placed here.
 259 dnl
 260 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 261 dnl new inlining code or the new system_header pragma will die on -Werror.
 262 dnl Leave it out by default and use maint-mode to use it.
 263 dnl
 264 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 265 dnl compiler supports it and the user has not requested debug mode.
 266 dnl
 267 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 268 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 269   # All these tests are for C++; save the language and the compiler flags.
 270   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 271   # found in GLIBCPP_CONFIGURE.
 272   AC_LANG_SAVE
 273   AC_LANG_CPLUSPLUS
 274   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 275   ac_save_CXXFLAGS="$CXXFLAGS"
 276
 277   # Check for maintainer-mode bits.
 278   if test x"$USE_MAINTAINER_MODE" = xno; then
 279     WERROR=''
 280   else
 281     WERROR='-Werror'
 282   fi
 283
 284   # Check for -ffunction-sections -fdata-sections
 285   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 286   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 287   AC_TRY_COMPILE(, [int foo;
 288   ], [ac_fdsections=yes], [ac_fdsections=no])
 289   if test "$ac_test_CXXFLAGS" = set; then
 290     CXXFLAGS="$ac_save_CXXFLAGS"
 291   else
 292     # this is the suspicious part
 293     CXXFLAGS=''
 294   fi
 295   if test x"$ac_fdsections" = x"yes"; then
 296     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 297   fi
 298   AC_MSG_RESULT($ac_fdsections)
 299
 300   AC_LANG_RESTORE
 301   AC_SUBST(WERROR)
 302   AC_SUBST(SECTION_FLAGS)
 303 ])
 304
 305
 306 dnl
 307 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 308 dnl the native linker is in use, all variables will be defined to something
 309 dnl safe (like an empty string).
 310 dnl
 311 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 312 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 313 dnl Define LD, with_gnu_ld, and (possibly) glibcpp_gnu_ld_version as
 314 dnl side-effects of testing.
 315 dnl
 316 dnl GLIBCPP_CHECK_LINKER_FEATURES
 317 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 318   # If we're not using GNU ld, then there's no point in even trying these
 319   # tests.  Check for that first.  We should have already tested for gld
 320   # by now (in libtool), but require it now just to be safe...
 321   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 322   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 323   AC_REQUIRE([AC_PROG_LD])
 324
 325   # The name set by libtool depends on the version of libtool.  Shame on us
 326   # for depending on an impl detail, but c'est la vie.  Older versions used
 327   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 328   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 329   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 330   # set (hence we're using an older libtool), then set it.
 331   if test x${with_gnu_ld+set} != xset; then
 332     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 333       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 334       with_gnu_ld=no
 335     else
 336       with_gnu_ld=$ac_cv_prog_gnu_ld
 337     fi
 338   fi
 339
 340   # Start by getting the version number.  I think the libtool test already
 341   # does some of this, but throws away the result.
 342   changequote(,)
 343   ldver=`$LD --version 2>/dev/null | head -1 | \
 344          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 345   changequote([,])
 346   glibcpp_gnu_ld_version=`echo $ldver | \
 347          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 348
 349   # Set --gc-sections.
 350   if test "$with_gnu_ld" = "notbroken"; then
 351     # GNU ld it is!  Joy and bunny rabbits!
 352
 353     # All these tests are for C++; save the language and the compiler flags.
 354     # Need to do this so that g++ won't try to link in libstdc++
 355     ac_test_CFLAGS="${CFLAGS+set}"
 356     ac_save_CFLAGS="$CFLAGS"
 357     CFLAGS='-x c++  -Wl,--gc-sections'
 358
 359     # Check for -Wl,--gc-sections
 360     # XXX This test is broken at the moment, as symbols required for
 361     # linking are now in libsupc++ (not built yet.....). In addition,
 362     # this test has cored on solaris in the past. In addition,
 363     # --gc-sections doesn't really work at the moment (keeps on discarding
 364     # used sections, first .eh_frame and now some of the glibc sections for
 365     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 366     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 367     AC_TRY_RUN([
 368      int main(void)
 369      {
 370        try { throw 1; }
 371        catch (...) { };
 372        return 0;
 373      }
 374     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 375     if test "$ac_test_CFLAGS" = set; then
 376       CFLAGS="$ac_save_CFLAGS"
 377     else
 378       # this is the suspicious part
 379       CFLAGS=''
 380     fi
 381     if test "$ac_sectionLDflags" = "yes"; then
 382       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 383     fi
 384     AC_MSG_RESULT($ac_sectionLDflags)
 385   fi
 386
 387   # Set linker optimization flags.
 388   if test x"$with_gnu_ld" = x"yes"; then
 389     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 390   fi
 391
 392   AC_SUBST(SECTION_LDFLAGS)
 393   AC_SUBST(OPT_LDFLAGS)
 394 ])
 395
 396
 397 dnl
 398 dnl Check to see if the (math function) argument passed is
 399 dnl declared when using the c++ compiler
 400 dnl ASSUMES argument is a math function with ONE parameter
 401 dnl
 402 dnl GLIBCPP_CHECK_MATH_DECL_1
 403 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 404   AC_MSG_CHECKING([for $1 declaration])
 405   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 406     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 407       AC_LANG_SAVE
 408       AC_LANG_CPLUSPLUS
 409       AC_TRY_COMPILE([#include <math.h>
 410                       #ifdef HAVE_IEEEFP_H
 411                       #include <ieeefp.h>
 412                       #endif
 413                      ],
 414                      [ $1(0);],
 415                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 416       AC_LANG_RESTORE
 417     ])
 418   fi
 419   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 420 ])
 421
 422 dnl
 423 dnl Check to see if the (math function) argument passed is
 424 dnl 1) declared when using the c++ compiler
 425 dnl 2) has "C" linkage
 426 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 427 dnl
 428 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 429 dnl
 430 dnl argument 1 is name of function to check
 431 dnl
 432 dnl ASSUMES argument is a math function with ONE parameter
 433 dnl
 434 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 435 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 436   GLIBCPP_CHECK_MATH_DECL_1($1)
 437   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 438     AC_CHECK_FUNCS($1)
 439   else
 440     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 441     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 442       AC_CHECK_FUNCS(_$1)
 443     fi
 444   fi
 445 ])
 446
 447
 448 dnl
 449 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 450 dnl of functions at once.  It's an all-or-nothing check -- either
 451 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 452 dnl Doing it this way saves significant configure time.
 453 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 454   AC_MSG_CHECKING([for $1 functions])
 455   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 456     AC_LANG_SAVE
 457     AC_LANG_CPLUSPLUS
 458     AC_TRY_COMPILE([#include <math.h>],
 459                    [ `for x in $3; do echo "$x (0);"; done` ],
 460                    [glibcpp_cv_func_$2_use=yes],
 461                    [glibcpp_cv_func_$2_use=no])
 462     AC_LANG_RESTORE])
 463   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 464   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 465     AC_CHECK_FUNCS($3)
 466   fi
 467 ])
 468
 469 dnl
 470 dnl Check to see if the (math function) argument passed is
 471 dnl declared when using the c++ compiler
 472 dnl ASSUMES argument is a math function with TWO parameters
 473 dnl
 474 dnl GLIBCPP_CHECK_MATH_DECL_2
 475 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 476   AC_MSG_CHECKING([for $1 declaration])
 477   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 478     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 479       AC_LANG_SAVE
 480       AC_LANG_CPLUSPLUS
 481       AC_TRY_COMPILE([#include <math.h>],
 482                      [ $1(0, 0);],
 483                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 484       AC_LANG_RESTORE
 485     ])
 486   fi
 487   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 488 ])
 489
 490 dnl
 491 dnl Check to see if the (math function) argument passed is
 492 dnl 1) declared when using the c++ compiler
 493 dnl 2) has "C" linkage
 494 dnl
 495 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 496 dnl
 497 dnl argument 1 is name of function to check
 498 dnl
 499 dnl ASSUMES argument is a math function with TWO parameters
 500 dnl
 501 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 502 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 503   GLIBCPP_CHECK_MATH_DECL_2($1)
 504   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 505     AC_CHECK_FUNCS($1)
 506   else
 507     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 508     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 509       AC_CHECK_FUNCS(_$1)
 510     fi
 511   fi
 512 ])
 513
 514
 515 dnl
 516 dnl Check to see if the (math function) argument passed is
 517 dnl declared when using the c++ compiler
 518 dnl ASSUMES argument is a math function with THREE parameters
 519 dnl
 520 dnl GLIBCPP_CHECK_MATH_DECL_3
 521 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 522   AC_MSG_CHECKING([for $1 declaration])
 523   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 524     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 525       AC_LANG_SAVE
 526       AC_LANG_CPLUSPLUS
 527       AC_TRY_COMPILE([#include <math.h>],
 528                      [ $1(0, 0, 0);],
 529                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 530       AC_LANG_RESTORE
 531     ])
 532   fi
 533   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 534 ])
 535
 536 dnl
 537 dnl Check to see if the (math function) argument passed is
 538 dnl 1) declared when using the c++ compiler
 539 dnl 2) has "C" linkage
 540 dnl
 541 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 542 dnl
 543 dnl argument 1 is name of function to check
 544 dnl
 545 dnl ASSUMES argument is a math function with THREE parameters
 546 dnl
 547 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 548 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 549   GLIBCPP_CHECK_MATH_DECL_3($1)
 550   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 551     AC_CHECK_FUNCS($1)
 552   else
 553     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 554     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 555       AC_CHECK_FUNCS(_$1)
 556     fi
 557   fi
 558 ])
 559
 560
 561 dnl
 562 dnl Check to see if the (stdlib function) argument passed is
 563 dnl 1) declared when using the c++ compiler
 564 dnl 2) has "C" linkage
 565 dnl
 566 dnl argument 1 is name of function to check
 567 dnl
 568 dnl ASSUMES argument is a math function with TWO parameters
 569 dnl
 570 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 571 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 572   AC_MSG_CHECKING([for $1 declaration])
 573   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 574     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 575       AC_LANG_SAVE
 576       AC_LANG_CPLUSPLUS
 577       AC_TRY_COMPILE([#include <stdlib.h>],
 578                      [ $1(0, 0);],
 579                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 580       AC_LANG_RESTORE
 581     ])
 582   fi
 583   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 584   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 585     AC_CHECK_FUNCS($1)
 586   fi
 587 ])
 588
 589
 590 dnl
 591 dnl Check to see if the (stdlib function) argument passed is
 592 dnl 1) declared when using the c++ compiler
 593 dnl 2) has "C" linkage
 594 dnl
 595 dnl argument 1 is name of function to check
 596 dnl
 597 dnl ASSUMES argument is a function with THREE parameters
 598 dnl
 599 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3
 600 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3, [
 601   AC_MSG_CHECKING([for $1 declaration])
 602   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 603     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 604       AC_LANG_SAVE
 605       AC_LANG_CPLUSPLUS
 606       AC_TRY_COMPILE([#include <stdlib.h>],
 607                      [ $1(0, 0, 0);],
 608                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 609       AC_LANG_RESTORE
 610     ])
 611   fi
 612   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 613   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 614     AC_CHECK_FUNCS($1)
 615   fi
 616 ])
 617
 618 dnl
 619 dnl Because the builtins are picky picky picky about the arguments they take,
 620 dnl do an explict linkage tests here.
 621 dnl Check to see if the (math function) argument passed is
 622 dnl 1) declared when using the c++ compiler
 623 dnl 2) has "C" linkage
 624 dnl
 625 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 626 dnl
 627 dnl argument 1 is name of function to check
 628 dnl
 629 dnl ASSUMES argument is a math function with ONE parameter
 630 dnl
 631 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 632 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 633   AC_MSG_CHECKING([for $1 declaration])
 634   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 635     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 636       AC_LANG_SAVE
 637       AC_LANG_CPLUSPLUS
 638       AC_TRY_COMPILE([#include <math.h>],
 639                      [ $1(0);],
 640                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 641       AC_LANG_RESTORE
 642     ])
 643   fi
 644   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 645   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 646     AC_MSG_CHECKING([for $1 linkage])
 647     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 648       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 649         AC_TRY_LINK([#include <math.h>],
 650                     [ $1(0);],
 651                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 652       ])
 653     fi
 654     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 655     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 656       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 657       AC_DEFINE_UNQUOTED(${ac_tr_func})
 658     fi
 659   fi
 660 ])
 661
 662
 663 dnl
 664 dnl Check to see what builtin math functions are supported
 665 dnl
 666 dnl check for __builtin_abs
 667 dnl check for __builtin_fabsf
 668 dnl check for __builtin_fabs
 669 dnl check for __builtin_fabl
 670 dnl check for __builtin_labs
 671 dnl check for __builtin_sqrtf
 672 dnl check for __builtin_sqrtl
 673 dnl check for __builtin_sqrt
 674 dnl check for __builtin_sinf
 675 dnl check for __builtin_sin
 676 dnl check for __builtin_sinl
 677 dnl check for __builtin_cosf
 678 dnl check for __builtin_cos
 679 dnl check for __builtin_cosl
 680 dnl
 681 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 682 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 683   dnl Test for builtin math functions.
 684   dnl These are made in gcc/c-common.c
 685   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 686   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 687   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 688   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 689   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 690
 691   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 692   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 693   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 694
 695   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 696   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 697   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 698
 699   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 700   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 701   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 702
 703   dnl There is, without a doubt, a more elegant way to have these
 704   dnl names exported so that they won't be stripped out of acconfig.h by
 705   dnl autoheader. I leave this as an exercise to somebody less frustrated
 706   dnl than I.... please email the libstdc++ list if you can figure out a
 707   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 708   dnl AC_CHECK_FUNC for things to steal.)
 709   dummyvar=no
 710   if test x$dummyvar = x"yes"; then
 711     AC_DEFINE(HAVE___BUILTIN_ABS)
 712     AC_DEFINE(HAVE___BUILTIN_LABS)
 713     AC_DEFINE(HAVE___BUILTIN_COS)
 714     AC_DEFINE(HAVE___BUILTIN_COSF)
 715     AC_DEFINE(HAVE___BUILTIN_COSL)
 716     AC_DEFINE(HAVE___BUILTIN_FABS)
 717     AC_DEFINE(HAVE___BUILTIN_FABSF)
 718     AC_DEFINE(HAVE___BUILTIN_FABSL)
 719     AC_DEFINE(HAVE___BUILTIN_SIN)
 720     AC_DEFINE(HAVE___BUILTIN_SINF)
 721     AC_DEFINE(HAVE___BUILTIN_SINL)
 722     AC_DEFINE(HAVE___BUILTIN_SQRT)
 723     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 724     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 725   fi
 726 ])
 727
 728 dnl
 729 dnl Check to see what the underlying c library is like
 730 dnl These checks need to do two things:
 731 dnl 1) make sure the name is declared when using the c++ compiler
 732 dnl 2) make sure the name has "C" linkage
 733 dnl This might seem like overkill but experience has shown that it's not...
 734 dnl
 735 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 736 dnl Define HAVE_STRTOF if "strtof" is declared and links
 737 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 738 dnl
 739 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 740 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 741   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 742   ac_save_CXXFLAGS="$CXXFLAGS"
 743   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 744
 745   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 746   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtof)
 747   AC_CHECK_FUNCS(drand48)
 748
 749   CXXFLAGS="$ac_save_CXXFLAGS"
 750 ])
 751
 752 dnl
 753 dnl Check to see what the underlying c library or math library is like.
 754 dnl These checks need to do two things:
 755 dnl 1) make sure the name is declared when using the c++ compiler
 756 dnl 2) make sure the name has "C" linkage
 757 dnl This might seem like overkill but experience has shown that it's not...
 758 dnl
 759 dnl Define HAVE_CARGF etc if "cargf" is found.
 760 dnl
 761 dnl GLIBCPP_CHECK_MATH_SUPPORT
 762 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 763   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 764   ac_save_CXXFLAGS="$CXXFLAGS"
 765   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 766
 767   dnl Check libm
 768   AC_CHECK_LIB(m, sin, libm="-lm")
 769   ac_save_LIBS="$LIBS"
 770   LIBS="$LIBS $libm"
 771
 772   dnl Check to see if certain C math functions exist.
 773   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 774   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 775   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 776   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 777   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 778   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 779   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 780   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 781
 782   dnl Check to see if basic C math functions have float versions.
 783   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 784                                           float_trig,
 785                                           acosf asinf atanf \
 786                                           cosf sinf tanf \
 787                                           coshf sinhf tanhf)
 788   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 789                                           float_round,
 790                                           ceilf floorf)
 791   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 792   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 793   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 794   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 795   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 796   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 797   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 798   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 799   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 800   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 801   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 802   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 803   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 804   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 805   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 806   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 807
 808   dnl Check to see if basic C math functions have long double versions.
 809   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 810                                           long_double_trig,
 811                                           acosl asinl atanl \
 812                                           cosl sinl tanl \
 813                                           coshl sinhl tanhl)
 814   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 815                                           long_double_round,
 816                                           ceill floorl)
 817   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 818   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 819   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 820   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 821   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 822   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 823   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 824   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 825   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 826   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 827   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 828   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 829   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 830   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 831   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 832   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 833   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 834
 835   dnl Some runtimes have these functions with a preceding underscore. Please
 836   dnl keep this sync'd with the one above. And if you add any new symbol,
 837   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 838   dnl Check to see if certain C math functions exist.
 839
 840   dnl Check to see if basic C math functions have float versions.
 841   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 842                                           _float_trig,
 843                                           _acosf _asinf _atanf \
 844                                           _cosf _sinf _tanf \
 845                                           _coshf _sinhf _tanhf)
 846   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 847                                           _float_round,
 848                                           _ceilf _floorf)
 849
 850   dnl Check to see if basic C math functions have long double versions.
 851   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 852                                           _long_double_trig,
 853                                           _acosl _asinl _atanl \
 854                                           _cosl _sinl _tanl \
 855                                           _coshl _sinhl _tanhl)
 856   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 857                                           _long_double_round,
 858                                           _ceill _floorl)
 859
 860   LIBS="$ac_save_LIBS"
 861   CXXFLAGS="$ac_save_CXXFLAGS"
 862 ])
 863
 864
 865 dnl
 866 dnl Check to see if there is native support for complex
 867 dnl
 868 dnl Don't compile bits in math/* if native support exits.
 869 dnl
 870 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 871 dnl
 872 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 873 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 874   dnl Check for complex versions of math functions of platform.  This will
 875   dnl always pass if libm is available, and fail if it isn't.  If it is
 876   dnl available, we assume we'll need it later, so add it to LIBS.
 877   AC_CHECK_LIB(m, main)
 878   AC_REPLACE_MATHFUNCS(nan copysignf)
 879
 880   dnl For __signbit to signbit conversions.
 881   AC_CHECK_FUNCS([__signbit], , [LIBMATHOBJS="$LIBMATHOBJS signbit.lo"])
 882   AC_CHECK_FUNCS([__signbitf], , [LIBMATHOBJS="$LIBMATHOBJS signbitf.lo"])
 883
 884   dnl Compile the long double complex functions only if the function
 885   dnl provides the non-complex long double functions that are needed.
 886   dnl Currently this includes copysignl, which should be
 887   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 888   if test x$ac_cv_func_copysignl = x"yes"; then
 889     AC_CHECK_FUNCS([__signbitl], , [LIBMATHOBJS="$LIBMATHOBJS signbitl.lo"])
 890   fi
 891
 892   if test -n "$LIBMATHOBJS"; then
 893     need_libmath=yes
 894   fi
 895   AC_SUBST(LIBMATHOBJS)
 896 ])
 897
 898
 899 dnl Check to see what architecture and operating system we are compiling
 900 dnl for.  Also, if architecture- or OS-specific flags are required for
 901 dnl compilation, pick them up here.
 902 dnl
 903 dnl GLIBCPP_CHECK_HOST
 904 AC_DEFUN(GLIBCPP_CHECK_HOST, [
 905   . [$]{glibcpp_basedir}/configure.host
 906   AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 907   AC_MSG_RESULT(OS config directory is $os_include_dir)
 908 ])
 909
 910
 911 dnl
 912 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 913 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 914 dnl must have been previously checked.)
 915 dnl
 916 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 917 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 918 dnl
 919 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 920 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 921   dnl Wide characters disabled by default.
 922
 923   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 924   dnl others even if wchar_t support is not on.
 925   AC_MSG_CHECKING([for mbstate_t])
 926   AC_TRY_COMPILE([#include <wchar.h>],
 927   [mbstate_t teststate;],
 928   have_mbstate_t=yes, have_mbstate_t=no)
 929   AC_MSG_RESULT($have_mbstate_t)
 930   if test x"$have_mbstate_t" = xyes; then
 931     AC_DEFINE(HAVE_MBSTATE_T)
 932   fi
 933
 934   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 935   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 936   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 937
 938   dnl Only continue checking if the ISO C99 headers exist and support is on.
 939   if test x"$ac_has_wchar_h" = xyes &&
 940      test x"$ac_has_wctype_h" = xyes &&
 941      test x"$enable_c_mbchar" != xno; then
 942
 943     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 944     dnl numeric_limits can instantiate type_traits<wchar_t>
 945     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 946     AC_TRY_COMPILE([#include <wchar.h>],
 947     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 948     has_wchar_minmax=yes, has_wchar_minmax=no)
 949     AC_MSG_RESULT($has_wchar_minmax)
 950
 951     dnl Test wchar.h for WEOF, which is what we use to determine whether
 952     dnl to specialize for char_traits<wchar_t> or not.
 953     AC_MSG_CHECKING([for WEOF])
 954     AC_TRY_COMPILE([
 955       #include <wchar.h>
 956       #include <stddef.h>],
 957     [wint_t i = WEOF;],
 958     has_weof=yes, has_weof=no)
 959     AC_MSG_RESULT($has_weof)
 960
 961     dnl Tests for wide character functions used in char_traits<wchar_t>.
 962     ac_wfuncs=yes
 963     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 964     ac_wfuncs=no)
 965
 966     dnl Checks for names injected into std:: by the c_std headers.
 967     AC_CHECK_FUNCS(btowc wctob fgetwc fgetws fputwc fputws fwide \
 968     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 969     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 970     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 971     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 972     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 973     ac_wfuncs=no)
 974
 975     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 976     if test x"$has_weof" = xyes &&
 977        test x"$has_wchar_minmax" = xyes &&
 978        test x"$ac_wfuncs" = xyes; then
 979       ac_isoC99_wchar_t=yes
 980     else
 981       ac_isoC99_wchar_t=no
 982     fi
 983     AC_MSG_RESULT($ac_isoC99_wchar_t)
 984
 985     dnl Use iconv for wchar_t to char conversions. As such, check for
 986     dnl X/Open Portability Guide, version 2 features (XPG2).
 987     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 988     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 989
 990     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 991     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 992     ac_save_LIBS="$LIBS"
 993     LIBS="$LIBS $libiconv"
 994
 995     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 996     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 997
 998     LIBS="$ac_save_LIBS"
 999
1000     AC_MSG_CHECKING([for XPG2 wchar_t support])
1001     if test x"$ac_has_iconv_h" = xyes &&
1002        test x"$ac_has_langinfo_h" = xyes &&
1003        test x"$ac_XPG2funcs" = xyes; then
1004       ac_XPG2_wchar_t=yes
1005     else
1006       ac_XPG2_wchar_t=no
1007     fi
1008     AC_MSG_RESULT($ac_XPG2_wchar_t)
1009
1010     dnl At the moment, only enable wchar_t specializations if all the
1011     dnl above support is present.
1012     if test x"$ac_isoC99_wchar_t" = xyes &&
1013         test x"$ac_XPG2_wchar_t" = xyes; then
1014       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
1015       enable_wchar_t=yes
1016     fi
1017   fi
1018   AC_MSG_CHECKING([for enabled wchar_t specializations])
1019   AC_MSG_RESULT($enable_wchar_t)
1020 ])
1021
1022
1023 dnl
1024 dnl Check to see if debugging libraries are to be built.
1025 dnl
1026 dnl GLIBCPP_ENABLE_DEBUG
1027 dnl
1028 dnl --enable-debug
1029 dnl builds a separate set of debugging libraries in addition to the
1030 dnl normal (shared, static) libstdc++ binaries.
1031 dnl
1032 dnl --disable-debug
1033 dnl builds only one (non-debug) version of libstdc++.
1034 dnl
1035 dnl --enable-debug-flags=FLAGS
1036 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1037 dnl
1038 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1039 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1040 dnl       defaults to `no'.
1041 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1042 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1043 AC_ARG_ENABLE(debug,
1044 changequote(<<, >>)dnl
1045 <<  --enable-debug          build extra debug library [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1046 changequote([, ])dnl
1047 [case "${enableval}" in
1048  yes) enable_debug=yes ;;
1049  no)  enable_debug=no ;;
1050  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1051  esac],
1052 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1053 AC_MSG_CHECKING([for additional debug build])
1054 AC_MSG_RESULT($enable_debug)
1055 AM_CONDITIONAL(GLIBCPP_BUILD_DEBUG, test "$enable_debug" = yes)
1056 ])
1057
1058
1059 dnl Check for explicit debug flags.
1060 dnl
1061 dnl GLIBCPP_ENABLE_DEBUG_FLAGS
1062 dnl
1063 dnl --enable-debug-flags='-O1'
1064 dnl is a general method for passing flags to be used when
1065 dnl building debug libraries with --enable-debug.
1066 dnl
1067 dnl --disable-debug-flags does nothing.
1068 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG_FLAGS(default flags)
1069 dnl       If "default flags" is an empty string (or "none"), the effect is
1070 dnl       the same as --disable or --enable=no.
1071 AC_DEFUN(GLIBCPP_ENABLE_DEBUG_FLAGS, [dnl
1072 define([GLIBCPP_ENABLE_DEBUG_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1073 AC_ARG_ENABLE(debug_flags,
1074 changequote(<<, >>)dnl
1075 <<  --enable-debug-flags=FLAGS    pass compiler FLAGS when building debug
1076                         library;[default=>>GLIBCPP_ENABLE_DEBUG_FLAGS_DEFAULT],
1077 changequote([, ])dnl
1078 [case "${enableval}" in
1079  none)  ;;
1080  -*) enable_debug_flags="${enableval}" ;;
1081  *)   AC_MSG_ERROR([Unknown argument to extra debugging flags]) ;;
1082  esac],
1083 enable_debug_flags=GLIBCPP_ENABLE_DEBUG_FLAGS_DEFAULT)dnl
1084
1085 dnl Option parsed, now set things appropriately
1086 case x"$enable_debug" in
1087     xyes)
1088         case "$enable_debug_flags" in
1089           none)
1090             DEBUG_FLAGS="-g3 -O0";;
1091           -*) #valid input
1092             DEBUG_FLAGS="${enableval}"
1093         esac
1094         ;;
1095     xno)
1096         DEBUG_FLAGS=""
1097         ;;
1098 esac
1099 AC_SUBST(DEBUG_FLAGS)
1100
1101 AC_MSG_CHECKING([for debug build flags])
1102 AC_MSG_RESULT($DEBUG_FLAGS)
1103 ])
1104
1105
1106 dnl
1107 dnl Check for "unusual" flags to pass to the compiler while building.
1108 dnl
1109 dnl GLIBCPP_ENABLE_CXX_FLAGS
1110 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1111 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1112 dnl     Somehow this same set of flags must be passed when [re]building
1113 dnl     libgcc.
1114 dnl --disable-cxx-flags passes nothing.
1115 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1116 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1117 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1118 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1119 dnl       If "default flags" is an empty string (or "none"), the effect is
1120 dnl       the same as --disable or --enable=no.
1121 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1122 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1123 AC_MSG_CHECKING([for extra compiler flags for building])
1124 AC_ARG_ENABLE(cxx_flags,
1125 changequote(<<, >>)dnl
1126 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1127                                   [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1128 changequote([, ])dnl
1129 [case "x$enable_cxx_flags" in
1130   xyes)
1131     AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1132   xno | xnone | x)
1133     enable_cxx_flags='' ;;
1134   *)
1135     enable_cxx_flags="$enableval" ;;
1136 esac],
1137 enable_cxx_flags=GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT)
1138
1139 dnl Run through flags (either default or command-line) and set anything
1140 dnl extra (e.g., #defines) that must accompany particular g++ options.
1141 if test -n "$enable_cxx_flags"; then
1142   for f in $enable_cxx_flags; do
1143     case "$f" in
1144       -fhonor-std)  ;;
1145       -*)  ;;
1146       *)   # and we're trying to pass /what/ exactly?
1147            AC_MSG_ERROR([compiler flags start with a -]) ;;
1148     esac
1149   done
1150 fi
1151 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1152 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1153 AC_SUBST(EXTRA_CXX_FLAGS)
1154 ])
1155
1156
1157 dnl
1158 dnl Check for which locale library to use:  gnu or generic.
1159 dnl
1160 dnl GLIBCPP_ENABLE_CLOCALE
1161 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1162 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1163 dnl
1164 dnl default is generic
1165 dnl
1166 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1167   AC_MSG_CHECKING([for clocale to use])
1168   AC_ARG_ENABLE(clocale,
1169   [  --enable-clocale        enable model for target locale package.
1170   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1171   ],
1172   if test x$enable_clocale = xno; then
1173      enable_clocale=no
1174   fi,
1175      enable_clocale=no)
1176
1177   enable_clocale_flag=$enable_clocale
1178
1179   dnl Probe for locale support if no specific model is specified.
1180   dnl Default to "generic"
1181   if test x$enable_clocale_flag = xno; then
1182     case x${target_os} in
1183       xlinux* | xgnu*)
1184         AC_EGREP_CPP([_GLIBCPP_ok], [
1185         #include <features.h>
1186         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1187           _GLIBCPP_ok
1188         #endif
1189         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1190
1191         # Test for bugs early in glibc-2.2.x series
1192         if test x$enable_clocale_flag = xgnu; then
1193           AC_TRY_RUN([
1194           #define _GNU_SOURCE 1
1195           #include <locale.h>
1196           #include <string.h>
1197           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1198           extern __typeof(newlocale) __newlocale;
1199           extern __typeof(duplocale) __duplocale;
1200           extern __typeof(strcoll_l) __strcoll_l;
1201           #endif
1202           int main()
1203           {
1204             const char __one[] = "Äuglein Augmen";
1205             const char __two[] = "Äuglein";
1206             int i;
1207             int j;
1208             __locale_t  loc;
1209             __locale_t  loc_dup;
1210             loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1211             loc_dup = __duplocale(loc);
1212             i = __strcoll_l(__one, __two, loc);
1213             j = __strcoll_l(__one, __two, loc_dup);
1214             return 0;
1215           }
1216           ],
1217           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1218           [enable_clocale_flag=generic])
1219         fi
1220
1221         # ... at some point put __strxfrm_l tests in as well.
1222         ;;
1223       *)
1224         enable_clocale_flag=generic
1225         ;;
1226     esac
1227   fi
1228
1229   dnl Deal with gettext issues.
1230   AC_ARG_ENABLE(nls,
1231   [  --enable-nls            use Native Language Support (default)],
1232   , enable_nls=yes)
1233   USE_NLS=no
1234
1235   dnl Set configure bits for specified locale package
1236   case x${enable_clocale_flag} in
1237     xgeneric)
1238       AC_MSG_RESULT(generic)
1239
1240       CLOCALE_H=config/locale/generic/c_locale.h
1241       CLOCALE_CC=config/locale/generic/c_locale.cc
1242       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1243       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1244       CCOLLATE_CC=config/locale/generic/collate_members.cc
1245       CCTYPE_CC=config/locale/generic/ctype_members.cc
1246       CMESSAGES_H=config/locale/generic/messages_members.h
1247       CMESSAGES_CC=config/locale/generic/messages_members.cc
1248       CMONEY_CC=config/locale/generic/monetary_members.cc
1249       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1250       CTIME_H=config/locale/generic/time_members.h
1251       CTIME_CC=config/locale/generic/time_members.cc
1252       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1253       ;;
1254     xgnu)
1255       AC_MSG_RESULT(gnu)
1256
1257       # Declare intention to use gettext, and add support for specific
1258       # languages.
1259       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1260       ALL_LINGUAS="de fr"
1261
1262       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1263       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1264       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1265         USE_NLS=yes
1266       fi
1267       # Export the build objects.
1268       for ling in $ALL_LINGUAS; do \
1269         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1270         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1271       done
1272       AC_SUBST(glibcpp_MOFILES)
1273       AC_SUBST(glibcpp_POFILES)
1274
1275       CLOCALE_H=config/locale/gnu/c_locale.h
1276       CLOCALE_CC=config/locale/gnu/c_locale.cc
1277       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1278       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1279       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1280       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1281       CMESSAGES_H=config/locale/gnu/messages_members.h
1282       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1283       CMONEY_CC=config/locale/gnu/monetary_members.cc
1284       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1285       CTIME_H=config/locale/gnu/time_members.h
1286       CTIME_CC=config/locale/gnu/time_members.cc
1287       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1288       ;;
1289     xieee_1003.1-2001)
1290       AC_MSG_RESULT(IEEE 1003.1)
1291
1292       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1293       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1294       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1295       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1296       CCOLLATE_CC=config/locale/generic/collate_members.cc
1297       CCTYPE_CC=config/locale/generic/ctype_members.cc
1298       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1299       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1300       CMONEY_CC=config/locale/generic/monetary_members.cc
1301       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1302       CTIME_H=config/locale/generic/time_members.h
1303       CTIME_CC=config/locale/generic/time_members.cc
1304       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1305       ;;
1306     *)
1307       echo "$enable_clocale is an unknown locale package" 1>&2
1308       exit 1
1309       ;;
1310   esac
1311
1312   # This is where the testsuite looks for locale catalogs, using the
1313   # -DLOCALEDIR define during testsuite compilation.
1314   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1315   AC_SUBST(glibcpp_localedir)
1316
1317   # A standalone libintl (e.g., GNU libintl) may be in use.
1318   if test $USE_NLS = yes; then
1319     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1320     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1321   fi
1322   if test $USE_NLS = yes; then
1323     AC_DEFINE(_GLIBCPP_USE_NLS)
1324   fi
1325
1326   AC_SUBST(USE_NLS)
1327   AC_SUBST(CLOCALE_H)
1328   AC_SUBST(CCODECVT_H)
1329   AC_SUBST(CMESSAGES_H)
1330   AC_SUBST(CCODECVT_CC)
1331   AC_SUBST(CCOLLATE_CC)
1332   AC_SUBST(CCTYPE_CC)
1333   AC_SUBST(CMESSAGES_CC)
1334   AC_SUBST(CMONEY_CC)
1335   AC_SUBST(CNUMERIC_CC)
1336   AC_SUBST(CTIME_H)
1337   AC_SUBST(CTIME_CC)
1338   AC_SUBST(CLOCALE_CC)
1339   AC_SUBST(CLOCALE_INTERNAL_H)
1340 ])
1341
1342
1343 dnl
1344 dnl Check for which I/O library to use:  stdio, or something specific.
1345 dnl
1346 dnl GLIBCPP_ENABLE_CSTDIO
1347 dnl
1348 dnl default is stdio
1349 dnl
1350 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1351   AC_MSG_CHECKING([for cstdio to use])
1352   AC_ARG_ENABLE(cstdio,
1353   [  --enable-cstdio         enable stdio for target io package.
1354   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1355   ],
1356   if test x$enable_cstdio = xno; then
1357      enable_cstdio=stdio
1358   fi,
1359      enable_cstdio=stdio)
1360
1361   enable_cstdio_flag=$enable_cstdio
1362
1363   dnl Check if a valid I/O package
1364   case x${enable_cstdio_flag} in
1365     xstdio | x | xno | xnone | xyes)
1366       # default
1367       CSTDIO_H=config/io/c_io_stdio.h
1368       BASIC_FILE_H=config/io/basic_file_stdio.h
1369       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1370       AC_MSG_RESULT(stdio)
1371       ;;
1372     *)
1373       echo "$enable_cstdio is an unknown io package" 1>&2
1374       exit 1
1375       ;;
1376   esac
1377   AC_SUBST(CSTDIO_H)
1378   AC_SUBST(BASIC_FILE_H)
1379   AC_SUBST(BASIC_FILE_CC)
1380 ])
1381
1382
1383 dnl
1384 dnl Check to see if building and using a C++ precompiled header can be done.
1385 dnl
1386 dnl GLIBCPP_CHECK_PCH
1387 dnl
1388 dnl If it looks like it may work, flip bits on in include/Makefile.am
1389 dnl
1390 AC_DEFUN(GLIBCPP_CHECK_PCH, [
1391   ac_test_CXXFLAGS="${CXXFLAGS+set}"
1392   ac_save_CXXFLAGS="$CXXFLAGS"
1393   CXXFLAGS='-Werror -Winvalid-pch -Wno-deprecated -x c++-header'
1394
1395   AC_MSG_CHECKING([for compiler that seems to compile .gch files])
1396   if test x${glibcpp_pch_comp+set} != xset; then
1397     AC_CACHE_VAL(glibcpp_pch_comp, [
1398       AC_LANG_SAVE
1399       AC_LANG_CPLUSPLUS
1400       AC_TRY_COMPILE([#include <math.h>
1401                      ],
1402                      [ $1(0);],
1403                      [glibcpp_pch_comp=yes], [glibcpp_pch_comp=no])
1404       AC_LANG_RESTORE
1405     ])
1406   fi
1407   AC_MSG_RESULT([$glibcpp_pch_comp])
1408
1409   CXXFLAGS="$ac_save_CXXFLAGS"
1410   AM_CONDITIONAL(GLIBCPP_BUILD_PCH, test "$glibcpp_pch_comp" = yes)
1411   if test "$glibcpp_pch_comp" = yes; then
1412         glibcpp_PCHFLAGS="-include bits/stdc++.h"
1413   else
1414         glibcpp_PCHFLAGS=""
1415   fi
1416   AC_SUBST(glibcpp_PCHFLAGS)
1417 ])
1418
1419 dnl
1420 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1421 dnl We must stage the required headers so that they will be installed
1422 dnl with the library (unlike libgcc, the STL implementation is provided
1423 dnl solely within headers).  Since we must not inject random user-space
1424 dnl macro names into user-provided C++ code, we first stage into <file>-in
1425 dnl and process to <file> with an output command.  The reason for a two-
1426 dnl stage process here is to correctly handle $srcdir!=$objdir without
1427 dnl having to write complex code (the sed commands to clean the macro
1428 dnl namespace are complex and fragile enough as it is).  We must also
1429 dnl add a relative path so that -I- is supported properly.
1430 dnl
1431 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1432   AC_MSG_CHECKING([for thread model used by GCC])
1433   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1434   AC_MSG_RESULT([$target_thread_file])
1435
1436   if test $target_thread_file != single; then
1437     AC_DEFINE(HAVE_GTHR_DEFAULT)
1438     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1439   fi
1440
1441   glibcpp_thread_h=gthr-$target_thread_file.h
1442   AC_SUBST(glibcpp_thread_h)
1443 ])
1444
1445
1446 dnl
1447 dnl Check for exception handling support.  If an explicit enable/disable
1448 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1449 dnl target may or may not support call frame exceptions.
1450 dnl
1451 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1452 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1453 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1454 dnl
1455 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1456 dnl
1457 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1458   AC_MSG_CHECKING([for exception model to use])
1459   AC_LANG_SAVE
1460   AC_LANG_CPLUSPLUS
1461   AC_ARG_ENABLE(sjlj-exceptions,
1462   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1463   [:],
1464   [dnl Botheration.  Now we've got to detect the exception model.
1465    dnl Link tests against libgcc.a are problematic since -- at least
1466    dnl as of this writing -- we've not been given proper -L bits for
1467    dnl single-tree newlib and libgloss.
1468    dnl
1469    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1470    dnl conftest files before we got a change to grep them first.
1471    cat > conftest.$ac_ext << EOF
1472 [#]line __oline__ "configure"
1473 struct S { ~S(); };
1474 void bar();
1475 void foo()
1476 {
1477   S s;
1478   bar();
1479 }
1480 EOF
1481    old_CXXFLAGS="$CXXFLAGS"
1482    CXXFLAGS=-S
1483    if AC_TRY_EVAL(ac_compile); then
1484      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1485        enable_sjlj_exceptions=yes
1486      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1487        enable_sjlj_exceptions=no
1488      fi
1489    fi
1490    CXXFLAGS="$old_CXXFLAGS"
1491    rm -f conftest*])
1492    if test x$enable_sjlj_exceptions = xyes; then
1493      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1494         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1495      ac_exception_model_name=sjlj
1496    elif test x$enable_sjlj_exceptions = xno; then
1497      ac_exception_model_name="call frame"
1498    else
1499      AC_MSG_ERROR([unable to detect exception model])
1500    fi
1501    AC_LANG_RESTORE
1502    AC_MSG_RESULT($ac_exception_model_name)
1503 ])
1504
1505
1506 dnl
1507 dnl Check for libunwind exception handling support. If enabled then
1508 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1509 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1510 dnl libunwind instead of libgcc and that libstdc++ has a dependency
1511 dnl on libunwind as well as libgcc.
1512 dnl
1513 dnl GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS
1514 dnl --enable-libunwind-exceptions forces the use of libunwind.
1515 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1516 dnl
1517 dnl Define _GLIBCPP_LIBUNWIND_EXCEPTIONS if requested.
1518 dnl
1519 AC_DEFUN(GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS, [
1520   AC_MSG_CHECKING([for use of libunwind])
1521   AC_ARG_ENABLE(libunwind-exceptions,
1522   [  --enable-libunwind-exceptions  force use of libunwind for exceptions],
1523   use_libunwind_exceptions=$enableval,
1524   use_libunwind_exceptions=no)
1525   AC_MSG_RESULT($use_libunwind_exceptions)
1526   dnl Option parsed, now set things appropriately
1527   if test x"$use_libunwind_exceptions" = xyes; then
1528     LIBUNWIND_FLAG="-lunwind"
1529   else
1530     LIBUNWIND_FLAG=""
1531   fi
1532   AC_SUBST(LIBUNWIND_FLAG)
1533 ])
1534
1535 dnl
1536 dnl Check for ISO/IEC 9899:1999 "C99" support.
1537 dnl
1538 dnl GLIBCPP_ENABLE_C99
1539 dnl --enable-c99 defines _GLIBCPP_USE_C99
1540 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1541 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1542 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1543 dnl       defaults to `no'.
1544 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1545 dnl
1546 dnl GLIBCPP_ENABLE_C99
1547 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1548   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1549
1550   AC_ARG_ENABLE(c99,
1551   changequote(<<, >>)dnl
1552   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1553   changequote([, ])dnl
1554   [case "$enableval" in
1555    yes) enable_c99=yes ;;
1556    no)  enable_c99=no ;;
1557    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1558    esac],
1559   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1560
1561   AC_LANG_SAVE
1562   AC_LANG_CPLUSPLUS
1563
1564   # Check for the existence of <math.h> functions used if C99 is enabled.
1565   ac_c99_math=yes;
1566   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1567   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1568   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1569   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1570   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1571   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1572   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1573   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1574   AC_TRY_COMPILE([#include <math.h>],
1575                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1576   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1577   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1578   AC_TRY_COMPILE([#include <math.h>],
1579                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1580   AC_TRY_COMPILE([#include <math.h>],
1581                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1582   AC_MSG_RESULT($ac_c99_math)
1583
1584   # Check for the existence in <stdio.h> of vscanf, et. al.
1585   ac_c99_stdio=yes;
1586   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1587   AC_TRY_COMPILE([#include <stdio.h>],
1588                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1589   AC_TRY_COMPILE([#include <stdio.h>
1590                   #include <stdarg.h>
1591                   void foo(char* fmt, ...)
1592                   {va_list args; va_start(args, fmt);
1593                   vfscanf(stderr, "%i", args);}],
1594                   [],, [ac_c99_stdio=no])
1595   AC_TRY_COMPILE([#include <stdio.h>
1596                   #include <stdarg.h>
1597                   void foo(char* fmt, ...)
1598                   {va_list args; va_start(args, fmt);
1599                   vscanf("%i", args);}],
1600                   [],, [ac_c99_stdio=no])
1601   AC_TRY_COMPILE([#include <stdio.h>
1602                   #include <stdarg.h>
1603                   void foo(char* fmt, ...)
1604                   {va_list args; va_start(args, fmt);
1605                   vsnprintf(fmt, 0, "%i", args);}],
1606                   [],, [ac_c99_stdio=no])
1607   AC_TRY_COMPILE([#include <stdio.h>
1608                   #include <stdarg.h>
1609                   void foo(char* fmt, ...)
1610                   {va_list args; va_start(args, fmt);
1611                   vsscanf(fmt, "%i", args);}],
1612                   [],, [ac_c99_stdio=no])
1613   AC_MSG_RESULT($ac_c99_stdio)
1614
1615   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1616   ac_c99_stdlib=yes;
1617   AC_MSG_CHECKING([for lldiv_t declaration])
1618   AC_CACHE_VAL(ac_c99_lldiv_t, [
1619   AC_TRY_COMPILE([#include <stdlib.h>],
1620                    [ lldiv_t mydivt;],
1621                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1622   ])
1623   AC_MSG_RESULT($ac_c99_lldiv_t)
1624
1625   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1626   AC_TRY_COMPILE([#include <stdlib.h>],
1627                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1628   AC_TRY_COMPILE([#include <stdlib.h>],
1629                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1630   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1631   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1632   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1633   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1634   if test x"$ac_c99_lldiv_t" = x"no"; then
1635     ac_c99_stdlib=no;
1636   fi;
1637   AC_MSG_RESULT($ac_c99_stdlib)
1638
1639   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1640   # XXX the wchar.h checks should be rolled into the general C99 bits.
1641   ac_c99_wchar=yes;
1642   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1643   AC_TRY_COMPILE([#include <wchar.h>],
1644                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1645   AC_TRY_COMPILE([#include <wchar.h>],
1646                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1647   AC_TRY_COMPILE([#include <wchar.h>],
1648                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1649   AC_MSG_RESULT($ac_c99_wchar)
1650
1651   AC_MSG_CHECKING([for enabled ISO C99 support])
1652   if test x"$ac_c99_math" = x"no" ||
1653      test x"$ac_c99_stdio" = x"no" ||
1654      test x"$ac_c99_stdlib" = x"no" ||
1655      test x"$ac_c99_wchar" = x"no"; then
1656     enable_c99=no;
1657   fi;
1658   AC_MSG_RESULT($enable_c99)
1659
1660   # Option parsed, now set things appropriately
1661   if test x"$enable_c99" = x"yes"; then
1662     AC_DEFINE(_GLIBCPP_USE_C99)
1663   fi
1664
1665   AC_LANG_RESTORE
1666 ])
1667
1668
1669 dnl
1670 dnl Check for template specializations for the 'long long' type extension.
1671 dnl The result determines only whether 'long long' I/O is enabled; things
1672 dnl like numeric_limits<> specializations are always available.
1673 dnl
1674 dnl GLIBCPP_ENABLE_LONG_LONG
1675 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1676 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1677 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1678 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1679 dnl       defaults to `no'.
1680 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1681 dnl
1682 dnl GLIBCPP_ENABLE_LONG_LONG
1683 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1684   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1685
1686   AC_ARG_ENABLE(long-long,
1687   changequote(<<, >>)dnl
1688   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1689   changequote([, ])dnl
1690   [case "$enableval" in
1691    yes) enable_long_long=yes ;;
1692    no)  enable_long_long=no ;;
1693    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1694    esac],
1695   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1696
1697   AC_LANG_SAVE
1698   AC_LANG_CPLUSPLUS
1699
1700   AC_MSG_CHECKING([for enabled long long I/O support])
1701   # iostreams require strtoll, strtoull to compile
1702   AC_TRY_COMPILE([#include <stdlib.h>],
1703                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1704   AC_TRY_COMPILE([#include <stdlib.h>],
1705                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1706
1707   # Option parsed, now set things appropriately
1708   if test x"$enable_long_long" = xyes; then
1709     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1710   fi
1711   AC_MSG_RESULT($enable_long_long)
1712
1713   AC_LANG_RESTORE
1714 ])
1715
1716
1717 dnl
1718 dnl Check for what type of C headers to use.
1719 dnl
1720 dnl GLIBCPP_ENABLE_CHEADERS
1721 dnl --enable-cheaders= [does stuff].
1722 dnl --disable-cheaders [does not do anything, really].
1723 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1724 dnl       Where DEFAULT is either `c' or `c_std'.
1725 dnl       If ommitted, it defaults to `c_std'.
1726 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1727 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1728 AC_MSG_CHECKING([for c header strategy to use])
1729 AC_ARG_ENABLE(cheaders,
1730 changequote(<<, >>)dnl
1731 <<  --enable-cheaders=MODEL       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1732 changequote([, ])
1733   [case "$enableval" in
1734    c)
1735         enable_cheaders=c
1736         ;;
1737    c_std)
1738         enable_cheaders=c_std
1739         ;;
1740    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1741         ;;
1742   esac],
1743   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1744   AC_MSG_RESULT($enable_cheaders)
1745
1746   dnl Option parsed, now set things appropriately
1747   case "$enable_cheaders" in
1748     c_std)
1749         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1750         ;;
1751     c)
1752         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1753         ;;
1754   esac
1755
1756   AC_SUBST(C_INCLUDE_DIR)
1757   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C, test "$enable_cheaders" = c)
1758   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C_STD, test "$enable_cheaders" = c_std)
1759   AM_CONDITIONAL(GLIBCPP_C_HEADERS_COMPATIBILITY, test "$c_compatibility" = yes)
1760 ])
1761
1762
1763 dnl
1764 dnl Check for wide character support.  Has the same effect as the option
1765 dnl in gcc's configure, but in a form that autoconf can mess with.
1766 dnl
1767 dnl GLIBCPP_ENABLE_C_MBCHAR
1768 dnl --enable-c-mbchar requests all the wchar_t stuff.
1769 dnl --disable-c-mbchar doesn't.
1770 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1771 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1772 dnl       defaults to `no'.
1773 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1774 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1775 AC_ARG_ENABLE(c-mbchar,
1776 changequote(<<, >>)dnl
1777 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1778 changequote([, ])dnl
1779 [case "$enableval" in
1780  yes) enable_c_mbchar=yes ;;
1781  no)  enable_c_mbchar=no ;;
1782  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1783  esac],
1784 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1785 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1786 ])
1787
1788
1789 dnl
1790 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1791 dnl
1792 dnl TOPLEVEL_INCLUDES
1793 dnl LIBMATH_INCLUDES
1794 dnl LIBSUPCXX_INCLUDES
1795 dnl
1796 dnl GLIBCPP_EXPORT_INCLUDES
1797 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1798   # Root level of the build directory include sources.
1799   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1800
1801   # Passed down for canadian crosses.
1802   if test x"$CANADIAN" = xyes; then
1803     TOPLEVEL_INCLUDES='-I$(includedir)'
1804   fi
1805
1806   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1807
1808   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1809
1810   # Now, export this to all the little Makefiles....
1811   AC_SUBST(GLIBCPP_INCLUDES)
1812   AC_SUBST(TOPLEVEL_INCLUDES)
1813   AC_SUBST(LIBMATH_INCLUDES)
1814   AC_SUBST(LIBSUPCXX_INCLUDES)
1815 ])
1816
1817
1818 dnl
1819 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1820 dnl
1821 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1822   # Optimization flags that are probably a good idea for thrill-seekers. Just
1823   # uncomment the lines below and make, everything else is ready to go...
1824   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1825   OPTIMIZE_CXXFLAGS=
1826   AC_SUBST(OPTIMIZE_CXXFLAGS)
1827
1828   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings'
1829   AC_SUBST(WARN_FLAGS)
1830 ])
1831
1832 dnl
1833 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1834 dnl  calculates gxx_install_dir
1835 dnl  exports glibcpp_toolexecdir
1836 dnl  exports glibcpp_toolexeclibdir
1837 dnl  exports glibcpp_prefixdir
1838 dnl
1839 dnl Assumes cross_compiling bits already done, and with_cross_host in
1840 dnl particular
1841 dnl
1842 dnl GLIBCPP_EXPORT_INSTALL_INFO
1843 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1844 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1845 # exported correctly in GLIBCPP_CONFIGURE.
1846 glibcpp_toolexecdir=no
1847 glibcpp_toolexeclibdir=no
1848 glibcpp_prefixdir=${prefix}
1849
1850 # Process the option --with-gxx-include-dir=<path to include-files directory>
1851 AC_MSG_CHECKING([for --with-gxx-include-dir])
1852 AC_ARG_WITH(gxx-include-dir,
1853 [  --with-gxx-include-dir  the installation directory for include files],
1854 [case "${withval}" in
1855   yes)
1856     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1857     gxx_include_dir=no
1858     ;;
1859   no)
1860     gxx_include_dir=no
1861     ;;
1862   *)
1863     gxx_include_dir=${withval}
1864     ;;
1865 esac], [gxx_include_dir=no])
1866 AC_MSG_RESULT($gxx_include_dir)
1867
1868 # Process the option "--enable-version-specific-runtime-libs"
1869 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1870 AC_ARG_ENABLE(version-specific-runtime-libs,
1871 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1872 [case "$enableval" in
1873  yes) version_specific_libs=yes ;;
1874  no)  version_specific_libs=no ;;
1875  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1876  esac],
1877 version_specific_libs=no)dnl
1878 # Option set, now we can test it.
1879 AC_MSG_RESULT($version_specific_libs)
1880
1881 # Default case for install directory for include files.
1882 if test $version_specific_libs = no && test $gxx_include_dir = no; then
1883   gxx_include_dir='$(prefix)'/include/c++/${gcc_version}
1884 fi
1885
1886 # Version-specific runtime libs processing.
1887 if test $version_specific_libs = yes; then
1888   # Need the gcc compiler version to know where to install libraries
1889   # and header files if --enable-version-specific-runtime-libs option
1890   # is selected.
1891   if test x"$gxx_include_dir" = x"no"; then
1892     gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/c++
1893   fi
1894   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1895   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1896 fi
1897
1898 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1899 # Install a library built with a cross compiler in tooldir, not libdir.
1900 if test x"$glibcpp_toolexecdir" = x"no"; then
1901   if test -n "$with_cross_host" &&
1902      test x"$with_cross_host" != x"no"; then
1903     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1904     glibcpp_toolexeclibdir='$(toolexecdir)/lib'
1905   else
1906     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1907     glibcpp_toolexeclibdir='$(libdir)'
1908   fi
1909   multi_os_directory=`$CC -print-multi-os-directory`
1910   case $multi_os_directory in
1911   .) ;; # Avoid trailing /.
1912   *) glibcpp_toolexeclibdir=$glibcpp_toolexeclibdir/$multi_os_directory ;;
1913   esac
1914 fi
1915
1916 AC_MSG_CHECKING([for install location])
1917 AC_MSG_RESULT($gxx_include_dir)
1918
1919 AC_SUBST(glibcpp_prefixdir)
1920 AC_SUBST(gxx_include_dir)
1921 AC_SUBST(glibcpp_toolexecdir)
1922 AC_SUBST(glibcpp_toolexeclibdir)
1923 ])
1924
1925
1926 # Check for functions in math library.
1927 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1928 #
1929 # This file can be copied and used freely without restrictions.  It can
1930 # be used in projects which are not available under the GNU Public License
1931 # but which still want to provide support for the GNU gettext functionality.
1932 # Please note that the actual code is *not* freely available.
1933
1934 # serial 1
1935
1936 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1937 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1938 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])])
1939
1940
1941 dnl This macro searches for a GNU version of make.  If a match is found, the
1942 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1943 dnl set to "#". This is useful for  including a special features in a Makefile,
1944 dnl which cannot be handled by other versions of make.  The variable
1945 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1946 dnl the empty string otherwise.
1947 dnl
1948 dnl Here is an example of its use:
1949 dnl
1950 dnl Makefile.in might contain:
1951 dnl
1952 dnl     # A failsafe way of putting a dependency rule into a makefile
1953 dnl     $(DEPEND):
1954 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1955 dnl
1956 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1957 dnl     @ifGNUmake@ include $(DEPEND)
1958 dnl     @ifGNUmake@ endif
1959 dnl
1960 dnl Then configure.in would normally contain:
1961 dnl
1962 dnl     CHECK_GNU_MAKE()
1963 dnl     AC_OUTPUT(Makefile)
1964 dnl
1965 dnl Then perhaps to cause gnu make to override any other make, we could do
1966 dnl something like this (note that GNU make always looks for GNUmakefile first):
1967 dnl
1968 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1969 dnl             mv Makefile GNUmakefile
1970 dnl             echo .DEFAULT: > Makefile ;
1971 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1972 dnl     fi
1973 dnl
1974 dnl Then, if any (well almost any) other make is called, and GNU make also
1975 dnl exists, then the other make wraps the GNU make.
1976 dnl
1977 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1978 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1979 dnl
1980 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1981 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1982 dnl #### conditional's subshell (" --version" is not a command), using a
1983 dnl #### different option to grep(1).
1984 dnl #### -pme
1985 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1986 dnl #### ${MAKE:-make}).
1987 dnl #### -msokolov
1988 AC_DEFUN(
1989   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1990           _cv_gnu_make_command='' ;
1991 dnl Search all the common names for GNU make
1992           for a in "${MAKE-make}" make gmake gnumake ; do
1993                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1994                   then
1995                           _cv_gnu_make_command=$a ;
1996                           break;
1997                   fi
1998           done ;
1999   ) ;
2000 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
2001 dnl string, '#' otherwise
2002   if test  "x$_cv_gnu_make_command" != "x"  ; then
2003           ifGNUmake='' ;
2004   else
2005           ifGNUmake='#' ;
2006   fi
2007   AC_SUBST(ifGNUmake)
2008 ])
2009
2010
2011 dnl Check for headers for, and arguments to, the setrlimit() function.
2012 dnl Used only in testsuite_hooks.h.
2013 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
2014   AC_TRY_COMPILE([#include <unistd.h>
2015                   #include <sys/time.h>
2016                   #include <sys/resource.h>
2017                  ], [ int f = RLIMIT_$1 ; ],
2018                  [glibcpp_mresult=1], [glibcpp_mresult=0])
2019   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
2020                      [Only used in build directory testsuite_hooks.h.])
2021 ])
2022 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
2023   setrlimit_have_headers=yes
2024   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
2025                    [],
2026                    setrlimit_have_headers=no)
2027   # If don't have the headers, then we can't run the tests now, and we
2028   # won't be seeing any of these during testsuite compilation.
2029   if test $setrlimit_have_headers = yes; then
2030     # Can't do these in a loop, else the resulting syntax is wrong.
2031     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
2032     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
2033     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
2034     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
2035
2036     # Check for rlimit, setrlimit.
2037     AC_CACHE_VAL(ac_setrlimit, [
2038       AC_TRY_COMPILE([#include <unistd.h>
2039                   #include <sys/time.h>
2040                   #include <sys/resource.h>
2041                      ],
2042                      [ struct rlimit r; setrlimit(0, &r);],
2043                      [ac_setrlimit=yes], [ac_setrlimit=no])
2044     ])
2045   fi
2046
2047   AC_MSG_CHECKING([for testsuite memory limit support])
2048   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
2049     ac_mem_limits=yes
2050     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
2051   else
2052     ac_mem_limits=no
2053   fi
2054   AC_MSG_RESULT($ac_mem_limits)
2055 ])
2056
2057
2058 dnl
2059 dnl Does any necessary configuration of the testsuite directory.  Generates
2060 dnl the testsuite_hooks.h header.
2061 dnl
2062 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
2063 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
2064
2065   if test  x"$GLIBCPP_IS_CROSS_COMPILING" = xfalse; then
2066     # Do checks for memory limit functions.
2067     GLIBCPP_CHECK_SETRLIMIT
2068
2069     # Look for setenv, so that extended locale tests can be performed.
2070     GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
2071   fi
2072
2073   # Export file names for ABI checking.
2074   baseline_dir="${glibcpp_srcdir}/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
2075   AC_SUBST(baseline_dir)
2076
2077   # Determine if checking the ABI is desirable.
2078   if test x$enable_symvers = xno; then
2079     enable_abi_check=no
2080   else
2081     case "$host" in
2082       *-*-cygwin*)
2083         enable_abi_check=no ;;
2084       *)
2085         enable_abi_check=yes ;;
2086     esac
2087   fi
2088
2089   AM_CONDITIONAL(GLIBCPP_TEST_WCHAR_T, test "$enable_wchar_t" = yes)
2090   AM_CONDITIONAL(GLIBCPP_TEST_ABI, test "$enable_abi_check" = yes)
2091 ])
2092
2093
2094 sinclude(../libtool.m4)
2095 dnl The lines below arrange for aclocal not to bring an installed
2096 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
2097 dnl add a definition of LIBTOOL to Makefile.in.
2098 ifelse(,,,[AC_SUBST(LIBTOOL)
2099 AC_DEFUN([AM_PROG_LIBTOOL])
2100 AC_DEFUN([AC_LIBTOOL_DLOPEN])
2101 AC_DEFUN([AC_PROG_LD])
2102 ])
2103
2104 dnl
2105 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
2106 dnl
2107
2108 AC_DEFUN(GLIBCPP_CHECK_S_ISREG_OR_S_IFREG, [
2109   AC_CACHE_VAL(glibcpp_cv_S_ISREG, [
2110     AC_TRY_LINK([#include <sys/stat.h>],
2111                 [struct stat buffer; fstat(0, &buffer); S_ISREG(buffer.st_mode); ],
2112                 [glibcpp_cv_S_ISREG=yes],
2113                 [glibcpp_cv_S_ISREG=no])
2114   ])
2115   AC_CACHE_VAL(glibcpp_cv_S_IFREG, [
2116     AC_TRY_LINK([#include <sys/stat.h>],
2117                 [struct stat buffer; fstat(0, &buffer); S_IFREG & buffer.st_mode; ],
2118                 [glibcpp_cv_S_IFREG=yes],
2119                 [glibcpp_cv_S_IFREG=no])
2120   ])
2121   if test x$glibcpp_cv_S_ISREG = xyes; then
2122     AC_DEFINE(HAVE_S_ISREG)
2123   elif test x$glibcpp_cv_S_IFREG = xyes; then
2124     AC_DEFINE(HAVE_S_IFREG)
2125   fi
2126 ])
2127
2128 dnl
2129 dnl Check whether poll is available in <poll.h>.
2130 dnl
2131
2132 AC_DEFUN(GLIBCPP_CHECK_POLL, [
2133   AC_CACHE_VAL(glibcpp_cv_POLL, [
2134     AC_TRY_COMPILE([#include <poll.h>],
2135                 [struct pollfd pfd[1]; pfd[0].events = POLLIN; poll(pfd, 1, 0); ],
2136                 [glibcpp_cv_POLL=yes],
2137                 [glibcpp_cv_POLL=no])
2138   ])
2139   if test x$glibcpp_cv_POLL = xyes; then
2140     AC_DEFINE(HAVE_POLL)
2141   fi
2142 ])
2143
2144 # Check whether LC_MESSAGES is available in <locale.h>.
2145 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2146 #
2147 # This file file be copied and used freely without restrictions.  It can
2148 # be used in projects which are not available under the GNU Public License
2149 # but which still want to provide support for the GNU gettext functionality.
2150 # Please note that the actual code is *not* freely available.
2151
2152 # serial 1
2153
2154 AC_DEFUN(AC_LC_MESSAGES, [
2155   AC_CHECK_HEADER(locale.h, [
2156     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2157       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2158        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2159     if test $ac_cv_val_LC_MESSAGES = yes; then
2160       AC_DEFINE(HAVE_LC_MESSAGES)
2161     fi
2162   ])
2163 ])
2164
2165
2166 dnl
2167 dnl Check for whether the Boost-derived checks should be turned on.
2168 dnl
2169 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
2170 dnl --enable-concept-checks turns them on.
2171 dnl --disable-concept-checks leaves them off.
2172 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2173 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2174 dnl       defaults to `no'.
2175 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
2176 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
2177 AC_ARG_ENABLE(concept-checks,
2178 changequote(<<, >>)dnl
2179 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
2180 changequote([, ])dnl
2181 [case "$enableval" in
2182  yes) enable_concept_checks=yes ;;
2183  no)  enable_concept_checks=no ;;
2184  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
2185  esac],
2186 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
2187 dnl Option parsed, now set things appropriately
2188 if test x"$enable_concept_checks" = xyes; then
2189   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
2190 fi
2191 ])
2192
2193
2194 dnl
2195 dnl Add version tags to symbols in shared library (or not), additionally
2196 dnl marking other symbols as private/local (or not).
2197 dnl
2198 dnl GLIBCPP_ENABLE_SYMVERS
2199 dnl --enable-symvers=style adds a version script to the linker call when
2200 dnl       creating the shared library.  The choice of version script is
2201 dnl       controlled by 'style'.
2202 dnl --disable-symvers does not.
2203 dnl  +  Usage:  GLIBCPP_ENABLE_SYMVERS[(DEFAULT)]
2204 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2205 dnl       defaults to `no'.  Passing `yes' tries to choose a default style
2206 dnl       based on linker characteristics.  Passing 'no' disables versioning.
2207 AC_DEFUN(GLIBCPP_ENABLE_SYMVERS, [dnl
2208 define([GLIBCPP_ENABLE_SYMVERS_DEFAULT], ifelse($1, yes, yes, no))dnl
2209 AC_ARG_ENABLE(symvers,
2210 changequote(<<, >>)dnl
2211 <<  --enable-symvers=style  enables symbol versioning of the shared library [default=>>GLIBCPP_ENABLE_SYMVERS_DEFAULT],
2212 changequote([, ])dnl
2213 [case "$enableval" in
2214  yes) enable_symvers=yes ;;
2215  no)  enable_symvers=no ;;
2216  # other names here, just as sanity checks
2217  #gnu|sun|etcetera) enable_symvers=$enableval ;;
2218  gnu) enable_symvers=$enableval ;;
2219  *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]) ;;
2220  esac],
2221 enable_symvers=GLIBCPP_ENABLE_SYMVERS_DEFAULT)dnl
2222
2223 # If we never went through the GLIBCPP_CHECK_LINKER_FEATURES macro, then we
2224 # don't know enough about $LD to do tricks...
2225 if test x$enable_shared = xno ||
2226         test "x$LD" = x ||
2227         test x$glibcpp_gnu_ld_version = x; then
2228   enable_symvers=no
2229 fi
2230
2231 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2232 if test $enable_symvers != no; then
2233   AC_MSG_CHECKING([for shared libgcc])
2234   ac_save_CFLAGS="$CFLAGS"
2235   CFLAGS=' -lgcc_s'
2236   AC_TRY_LINK(, [return 0], glibcpp_shared_libgcc=yes, glibcpp_shared_libgcc=no)
2237   CFLAGS="$ac_save_CFLAGS"
2238   AC_MSG_RESULT($glibcpp_shared_libgcc)
2239 fi
2240
2241 # For GNU ld, we need at least this version.  It's 2.12 in the same format
2242 # as the tested-for version.  See GLIBCPP_CHECK_LINKER_FEATURES for more.
2243 glibcpp_min_gnu_ld_version=21200
2244
2245 # Check to see if unspecified "yes" value can win, given results
2246 # above.
2247 if test $enable_symvers = yes ; then
2248   if test $with_gnu_ld = yes &&
2249     test $glibcpp_shared_libgcc = yes ;
2250   then
2251     if test $glibcpp_gnu_ld_version -ge $glibcpp_min_gnu_ld_version ; then
2252         enable_symvers=gnu
2253     else
2254       ac_test_CFLAGS="${CFLAGS+set}"
2255       ac_save_CFLAGS="$CFLAGS"
2256       CFLAGS='-shared -Wl,--version-script,conftest.map'
2257       enable_symvers=no
2258       changequote(,)
2259       echo 'FOO { global: f[a-z]o; local: *; };' > conftest.map
2260       changequote([,])
2261       AC_TRY_LINK([int foo;],, enable_symvers=gnu)
2262       if test "$ac_test_CFLAGS" = set; then
2263         CFLAGS="$ac_save_CFLAGS"
2264       else
2265         # this is the suspicious part
2266         CFLAGS=''
2267       fi
2268       rm -f conftest.map
2269     fi
2270   else
2271     # just fail for now
2272     enable_symvers=no
2273   fi
2274 fi
2275
2276 dnl Everything parsed; figure out what file to use.
2277 case $enable_symvers in
2278   no)
2279       SYMVER_MAP=config/linker-map.dummy
2280       ;;
2281   gnu)
2282       SYMVER_MAP=config/linker-map.gnu
2283       AC_DEFINE(_GLIBCPP_SYMVER)
2284       ;;
2285 esac
2286
2287 AC_SUBST(SYMVER_MAP)
2288 AM_CONDITIONAL(GLIBCPP_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
2289 AC_MSG_CHECKING([versioning on shared library symbols])
2290 AC_MSG_RESULT($enable_symvers)
2291 ])
2292
2293
2294 # isc-posix.m4 serial 2 (gettext-0.11.2)
2295 dnl Copyright (C) 1995-2002 Free Software Foundation, Inc.
2296 dnl This file is free software, distributed under the terms of the GNU
2297 dnl General Public License.  As a special exception to the GNU General
2298 dnl Public License, this file may be distributed as part of a program
2299 dnl that contains a configuration script generated by Autoconf, under
2300 dnl the same distribution terms as the rest of that program.
2301
2302 # This file is not needed with autoconf-2.53 and newer.  Remove it in 2005.
2303
2304 # This test replaces the one in autoconf.
2305 # Currently this macro should have the same name as the autoconf macro
2306 # because gettext's gettext.m4 (distributed in the automake package)
2307 # still uses it.  Otherwise, the use in gettext.m4 makes autoheader
2308 # give these diagnostics:
2309 #   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
2310 #   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
2311
2312 undefine([AC_ISC_POSIX])
2313
2314 AC_DEFUN([AC_ISC_POSIX],
2315   [
2316     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
2317     AC_CHECK_LIB(cposix, strerror, [LIBS="$LIBS -lcposix"])
2318   ]
2319 )
2320
2321 # Add --enable-maintainer-mode option to configure.
2322 # From Jim Meyering
2323
2324 # serial 1
2325
2326 AC_DEFUN([AM_MAINTAINER_MODE],
2327 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2328   dnl maintainer-mode is disabled by default
2329   AC_ARG_ENABLE(maintainer-mode,
2330 [  --enable-maintainer-mode enable make rules and dependencies not useful
2331                           (and sometimes confusing) to the casual installer],
2332       USE_MAINTAINER_MODE=$enableval,
2333       USE_MAINTAINER_MODE=no)
2334   AC_MSG_RESULT($USE_MAINTAINER_MODE)
2335   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
2336   MAINT=$MAINTAINER_MODE_TRUE
2337   AC_SUBST(MAINT)dnl
2338 ]
2339 )
2340
2341 # Define a conditional.
2342
2343 AC_DEFUN([AM_CONDITIONAL],
2344 [AC_SUBST($1_TRUE)
2345 AC_SUBST($1_FALSE)
2346 if $2; then
2347   $1_TRUE=
2348   $1_FALSE='#'
2349 else
2350   $1_TRUE='#'
2351   $1_FALSE=
2352 fi])
2353
2354 # Do all the work for Automake.  This macro actually does too much --
2355 # some checks are only needed if your package does certain things.
2356 # But this isn't really a big deal.
2357
2358 # serial 1
2359
2360 dnl Usage:
2361 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
2362
2363 AC_DEFUN([AM_INIT_AUTOMAKE],
2364 [AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
2365 AC_REQUIRE([AC_PROG_INSTALL])
2366 PACKAGE=[$1]
2367 AC_SUBST(PACKAGE)
2368 VERSION=[$2]
2369 AC_SUBST(VERSION)
2370 dnl test to see if srcdir already configured
2371 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
2372   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
2373 fi
2374 ifelse([$3],,
2375 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
2376 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
2377 AC_REQUIRE([AM_SANITY_CHECK])
2378 AC_REQUIRE([AC_ARG_PROGRAM])
2379 dnl FIXME This is truly gross.
2380 missing_dir=`cd $ac_aux_dir && pwd`
2381 AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version}, $missing_dir)
2382 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
2383 AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version}, $missing_dir)
2384 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
2385 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
2386 AC_REQUIRE([AC_PROG_MAKE_SET])])
2387
2388 # Copyright 2002  Free Software Foundation, Inc.
2389
2390 # This program is free software; you can redistribute it and/or modify
2391 # it under the terms of the GNU General Public License as published by
2392 # the Free Software Foundation; either version 2, or (at your option)
2393 # any later version.
2394
2395 # This program is distributed in the hope that it will be useful,
2396 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2397 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2398 # GNU General Public License for more details.
2399
2400 # You should have received a copy of the GNU General Public License
2401 # along with this program; if not, write to the Free Software
2402 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2403
2404 # AM_AUTOMAKE_VERSION(VERSION)
2405 # ----------------------------
2406 # Automake X.Y traces this macro to ensure aclocal.m4 has been
2407 # generated from the m4 files accompanying Automake X.Y.
2408 AC_DEFUN([AM_AUTOMAKE_VERSION],[am__api_version="1.4"])
2409
2410 # AM_SET_CURRENT_AUTOMAKE_VERSION
2411 # -------------------------------
2412 # Call AM_AUTOMAKE_VERSION so it can be traced.
2413 # This function is AC_REQUIREd by AC_INIT_AUTOMAKE.
2414 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
2415          [AM_AUTOMAKE_VERSION([1.4-p6])])
2416
2417 #
2418 # Check to make sure that the build environment is sane.
2419 #
2420
2421 AC_DEFUN([AM_SANITY_CHECK],
2422 [AC_MSG_CHECKING([whether build environment is sane])
2423 # Just in case
2424 sleep 1
2425 echo timestamp > conftestfile
2426 # Do `set' in a subshell so we don't clobber the current shell's
2427 # arguments.  Must try -L first in case configure is actually a
2428 # symlink; some systems play weird games with the mod time of symlinks
2429 # (eg FreeBSD returns the mod time of the symlink's containing
2430 # directory).
2431 if (
2432    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
2433    if test "[$]*" = "X"; then
2434       # -L didn't work.
2435       set X `ls -t $srcdir/configure conftestfile`
2436    fi
2437    if test "[$]*" != "X $srcdir/configure conftestfile" \
2438       && test "[$]*" != "X conftestfile $srcdir/configure"; then
2439
2440       # If neither matched, then we have a broken ls.  This can happen
2441       # if, for instance, CONFIG_SHELL is bash and it inherits a
2442       # broken ls alias from the environment.  This has actually
2443       # happened.  Such a system could not be considered "sane".
2444       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2445 alias in your environment])
2446    fi
2447
2448    test "[$]2" = conftestfile
2449    )
2450 then
2451    # Ok.
2452    :
2453 else
2454    AC_MSG_ERROR([newly created file is older than distributed files!
2455 Check your system clock])
2456 fi
2457 rm -f conftest*
2458 AC_MSG_RESULT(yes)])
2459
2460 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
2461 dnl The program must properly implement --version.
2462 AC_DEFUN([AM_MISSING_PROG],
2463 [AC_MSG_CHECKING(for working $2)
2464 # Run test in a subshell; some versions of sh will print an error if
2465 # an executable is not found, even if stderr is redirected.
2466 # Redirect stdin to placate older versions of autoconf.  Sigh.
2467 if ($2 --version) < /dev/null > /dev/null 2>&1; then
2468    $1=$2
2469    AC_MSG_RESULT(found)
2470 else
2471    $1="$3/missing $2"
2472    AC_MSG_RESULT(missing)
2473 fi
2474 AC_SUBST($1)])
2475
2476 # Like AC_CONFIG_HEADER, but automatically create stamp file.
2477
2478 AC_DEFUN([AM_CONFIG_HEADER],
2479 [AC_PREREQ([2.12])
2480 AC_CONFIG_HEADER([$1])
2481 dnl When config.status generates a header, we must update the stamp-h file.
2482 dnl This file resides in the same directory as the config header
2483 dnl that is generated.  We must strip everything past the first ":",
2484 dnl and everything past the last "/".
2485 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
2486 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
2487 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
2488 <<am_indx=1
2489 for am_file in <<$1>>; do
2490   case " <<$>>CONFIG_HEADERS " in
2491   *" <<$>>am_file "*<<)>>
2492     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
2493     ;;
2494   esac
2495   am_indx=`expr "<<$>>am_indx" + 1`
2496 done<<>>dnl>>)
2497 changequote([,]))])
2498