libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4-p6
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999, 2001 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize basic configure bits, set toplevel_srcdir for Makefiles.
  15 dnl
  16 dnl GLIBCPP_TOPREL_CONFIGURE
  17 AC_DEFUN(GLIBCPP_TOPREL_CONFIGURE, [
  18   dnl Default to --enable-multilib (this is also passed by default
  19   dnl from the ubercommon-top-level configure)
  20   AC_ARG_ENABLE(multilib,
  21   [  --enable-multilib       build hella library versions (default)],
  22   [case "${enableval}" in
  23     yes) multilib=yes ;;
  24     no)  multilib=no ;;
  25     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  26    esac], [multilib=yes])dnl
  27
  28   # When building with srcdir == objdir, links to the source files will
  29   # be created in directories within the target_subdir.  We have to
  30   # adjust toplevel_srcdir accordingly, so that configure finds
  31   # install-sh and other auxiliary files that live in the top-level
  32   # source directory.
  33   if test "${srcdir}" = "."; then
  34     if test -z "${with_target_subdir}"; then
  35       toprel=".."
  36     else
  37       if test "${with_target_subdir}" != "."; then
  38         toprel="${with_multisrctop}../.."
  39       else
  40         toprel="${with_multisrctop}.."
  41       fi
  42     fi
  43   else
  44     toprel=".."
  45   fi
  46   AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  47   toplevel_srcdir=\${top_srcdir}/$toprel
  48   AC_SUBST(toplevel_srcdir)
  49 ])
  50
  51 dnl
  52 dnl Initialize the rest of the library configury.
  53 dnl
  54 dnl GLIBCPP_CONFIGURE
  55 AC_DEFUN(GLIBCPP_CONFIGURE, [
  56   # Export build and source directories.
  57   # These need to be absolute paths, yet at the same time need to
  58   # canonicalize only relative paths, because then amd will not unmount
  59   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  60   glibcpp_builddir=`${PWDCMD-pwd}`
  61   case $srcdir in
  62   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  63   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  64   esac
  65   AC_SUBST(glibcpp_builddir)
  66   AC_SUBST(glibcpp_srcdir)
  67
  68   dnl This is here just to satisfy automake.
  69   ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  70
  71   AC_PROG_AWK
  72   # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.5x, can also
  73   # be 'cp -p' if linking isn't available.  Uncomment the next line to
  74   # force a particular method.
  75   #ac_cv_prog_LN_S='cp -p'
  76   AC_PROG_LN_S
  77
  78   # We use these options to decide which functions to include.
  79   AC_ARG_WITH(target-subdir,
  80   [  --with-target-subdir=SUBDIR
  81                           configuring in a subdirectory])
  82   AC_ARG_WITH(cross-host,
  83   [  --with-cross-host=HOST  configuring with a cross compiler])
  84
  85   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  86   AC_SUBST(glibcpp_basedir)
  87
  88   # Never versions of autoconf add an underscore to these functions.
  89   # Prevent future problems ...
  90   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  91   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  92   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  93   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  94
  95   # AC_PROG_CC
  96   # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  97   # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  98   # are probably using a cross compiler, which will not be able to fully
  99   # link an executable.  This is addressed in later versions of autoconf.
 100
 101   AC_DEFUN(LIB_AC_PROG_CC,
 102   [AC_BEFORE([$0], [AC_PROG_CPP])dnl
 103   dnl Fool anybody using AC_PROG_CC.
 104   AC_PROVIDE([AC_PROG_CC])
 105   AC_CHECK_PROG(CC, gcc, gcc)
 106   if test -z "$CC"; then
 107     AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
 108     test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
 109   fi
 110
 111   AC_PROG_CC_GNU
 112
 113   if test $ac_cv_prog_gcc = yes; then
 114     GCC=yes
 115   dnl Check whether -g works, even if CFLAGS is set, in case the package
 116   dnl plays around with CFLAGS (such as to build both debugging and
 117   dnl normal versions of a library), tasteless as that idea is.
 118     ac_test_CFLAGS="${CFLAGS+set}"
 119     ac_save_CFLAGS="$CFLAGS"
 120     CFLAGS=
 121     AC_PROG_CC_G
 122     if test "$ac_test_CFLAGS" = set; then
 123       CFLAGS="$ac_save_CFLAGS"
 124     elif test $ac_cv_prog_cc_g = yes; then
 125       CFLAGS="-g -O2"
 126     else
 127       CFLAGS="-O2"
 128     fi
 129   else
 130     GCC=
 131     test "${CFLAGS+set}" = set || CFLAGS="-g"
 132   fi
 133   ])
 134
 135   LIB_AC_PROG_CC
 136
 137   # Likewise for AC_PROG_CXX.  We can't just call it directly because g++
 138   # will try to link in libstdc++.
 139   AC_DEFUN(LIB_AC_PROG_CXX,
 140   [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 141   dnl Fool anybody using AC_PROG_CXX.
 142   AC_PROVIDE([AC_PROG_CXX])
 143   # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 144   # flags that come in CXX while configuring libstdc++.  They're different
 145   # from those used for all other target libraries.  If CXX is set in
 146   # the environment, respect that here.
 147   glibcpp_CXX=$CXX
 148   AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 149   AC_SUBST(glibcpp_CXX)
 150   CXX=$glibcpp_CXX
 151   test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 152
 153   AC_PROG_CXX_GNU
 154
 155   if test $ac_cv_prog_gxx = yes; then
 156     GXX=yes
 157     dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 158     dnl plays around with CXXFLAGS (such as to build both debugging and
 159     dnl normal versions of a library), tasteless as that idea is.
 160     ac_test_CXXFLAGS="${CXXFLAGS+set}"
 161     ac_save_CXXFLAGS="$CXXFLAGS"
 162     CXXFLAGS=
 163     AC_PROG_CXX_G
 164     if test "$ac_test_CXXFLAGS" = set; then
 165       CXXFLAGS="$ac_save_CXXFLAGS"
 166     elif test $ac_cv_prog_cxx_g = yes; then
 167       CXXFLAGS="-g -O2"
 168     else
 169       CXXFLAGS="-O2"
 170     fi
 171   else
 172     GXX=
 173     test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 174   fi
 175   ])
 176
 177   LIB_AC_PROG_CXX
 178
 179   # For directory versioning (e.g., headers) and other variables.
 180   AC_MSG_CHECKING([for GCC version number])
 181   gcc_version=`$glibcpp_CXX -dumpversion`
 182   AC_MSG_RESULT($gcc_version)
 183
 184   # For some reason, gettext needs this.
 185   AC_ISC_POSIX
 186
 187   AC_CHECK_TOOL(AS, as)
 188   AC_CHECK_TOOL(AR, ar)
 189   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 190   AC_PROG_INSTALL
 191
 192   AM_MAINTAINER_MODE
 193
 194   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 195   # at least currently, we never actually build a program, so we never
 196   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 197   # fails, because we are probably configuring with a cross compiler
 198   # which can't create executables.  So we include AC_EXEEXT to keep
 199   # automake happy, but we don't execute it, since we don't care about
 200   # the result.
 201   if false; then
 202     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 203     # to nothing, so nothing would remain between `then' and `fi' if it
 204     # were not for the `:' below.
 205     :
 206     AC_EXEEXT
 207   fi
 208
 209   case [$]{glibcpp_basedir} in
 210     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 211     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 212   esac
 213
 214   # Find platform-specific directories containing configuration info.  In
 215   # addition to possibly modifying the same flags, it also sets up symlinks.
 216   GLIBCPP_CHECK_TARGET
 217 ])
 218
 219
 220 dnl
 221 dnl Check to see if g++ can compile this library, and if so, if any version-
 222 dnl specific precautions need to be taken.
 223 dnl
 224 dnl GLIBCPP_CHECK_COMPILER_VERSION
 225 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 226 if test ! -f stamp-sanity-compiler; then
 227   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 228   AC_LANG_SAVE
 229   AC_LANG_CPLUSPLUS
 230   AC_TRY_COMPILE(, [
 231   #if __GNUC__ < 3
 232     not_ok
 233   #endif
 234   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 235   AC_LANG_RESTORE
 236   AC_MSG_RESULT($gpp_satisfactory)
 237   touch stamp-sanity-compiler
 238 fi
 239 ])
 240
 241
 242 dnl
 243 dnl Tests for newer compiler features, or features that are present in newer
 244 dnl compiler versions but not older compiler versions still in use, should
 245 dnl be placed here.
 246 dnl
 247 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 248 dnl new inlining code or the new system_header pragma will die on -Werror.
 249 dnl Leave it out by default and use maint-mode to use it.
 250 dnl
 251 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 252 dnl compiler supports it and the user has not requested debug mode.
 253 dnl
 254 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 255 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 256   # All these tests are for C++; save the language and the compiler flags.
 257   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 258   # found in GLIBCPP_CONFIGURE.
 259   AC_LANG_SAVE
 260   AC_LANG_CPLUSPLUS
 261   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 262   ac_save_CXXFLAGS="$CXXFLAGS"
 263
 264   # Check for maintainer-mode bits.
 265   if test x"$USE_MAINTAINER_MODE" = xno; then
 266     WERROR=''
 267   else
 268     WERROR='-Werror'
 269   fi
 270
 271   # Check for -ffunction-sections -fdata-sections
 272   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 273   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 274   AC_TRY_COMPILE(, [int foo;
 275   ], [ac_fdsections=yes], [ac_fdsections=no])
 276   if test "$ac_test_CXXFLAGS" = set; then
 277     CXXFLAGS="$ac_save_CXXFLAGS"
 278   else
 279     # this is the suspicious part
 280     CXXFLAGS=''
 281   fi
 282   if test x"$ac_fdsections" = x"yes"; then
 283     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 284   fi
 285   AC_MSG_RESULT($ac_fdsections)
 286
 287   AC_LANG_RESTORE
 288   AC_SUBST(WERROR)
 289   AC_SUBST(SECTION_FLAGS)
 290 ])
 291
 292
 293 dnl
 294 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 295 dnl the native linker is in use, all variables will be defined to something
 296 dnl safe (like an empty string).
 297 dnl
 298 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 299 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 300 dnl Define LD, with_gnu_ld, and (possibly) glibcpp_gnu_ld_version as
 301 dnl side-effects of testing.
 302 dnl
 303 dnl GLIBCPP_CHECK_LINKER_FEATURES
 304 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 305   # If we're not using GNU ld, then there's no point in even trying these
 306   # tests.  Check for that first.  We should have already tested for gld
 307   # by now (in libtool), but require it now just to be safe...
 308   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 309   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 310   AC_REQUIRE([AC_PROG_LD])
 311
 312   # The name set by libtool depends on the version of libtool.  Shame on us
 313   # for depending on an impl detail, but c'est la vie.  Older versions used
 314   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 315   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 316   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 317   # set (hence we're using an older libtool), then set it.
 318   if test x${with_gnu_ld+set} != xset; then
 319     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 320       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 321       with_gnu_ld=no
 322     else
 323       with_gnu_ld=$ac_cv_prog_gnu_ld
 324     fi
 325   fi
 326
 327   # Start by getting the version number.  I think the libtool test already
 328   # does some of this, but throws away the result.
 329   changequote(,)
 330   ldver=`$LD --version 2>/dev/null | head -1 | \
 331          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 332   changequote([,])
 333   glibcpp_gnu_ld_version=`echo $ldver | \
 334          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 335
 336   # Set --gc-sections.
 337   if test "$with_gnu_ld" = "notbroken"; then
 338     # GNU ld it is!  Joy and bunny rabbits!
 339
 340     # All these tests are for C++; save the language and the compiler flags.
 341     # Need to do this so that g++ won't try to link in libstdc++
 342     ac_test_CFLAGS="${CFLAGS+set}"
 343     ac_save_CFLAGS="$CFLAGS"
 344     CFLAGS='-x c++  -Wl,--gc-sections'
 345
 346     # Check for -Wl,--gc-sections
 347     # XXX This test is broken at the moment, as symbols required for
 348     # linking are now in libsupc++ (not built yet.....). In addition,
 349     # this test has cored on solaris in the past. In addition,
 350     # --gc-sections doesn't really work at the moment (keeps on discarding
 351     # used sections, first .eh_frame and now some of the glibc sections for
 352     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 353     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 354     AC_TRY_RUN([
 355      int main(void)
 356      {
 357        try { throw 1; }
 358        catch (...) { };
 359        return 0;
 360      }
 361     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 362     if test "$ac_test_CFLAGS" = set; then
 363       CFLAGS="$ac_save_CFLAGS"
 364     else
 365       # this is the suspicious part
 366       CFLAGS=''
 367     fi
 368     if test "$ac_sectionLDflags" = "yes"; then
 369       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 370     fi
 371     AC_MSG_RESULT($ac_sectionLDflags)
 372   fi
 373
 374   # Set linker optimization flags.
 375   if test x"$with_gnu_ld" = x"yes"; then
 376     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 377   fi
 378
 379   AC_SUBST(SECTION_LDFLAGS)
 380   AC_SUBST(OPT_LDFLAGS)
 381 ])
 382
 383
 384 dnl
 385 dnl Check to see if the (math function) argument passed is
 386 dnl declared when using the c++ compiler
 387 dnl ASSUMES argument is a math function with ONE parameter
 388 dnl
 389 dnl GLIBCPP_CHECK_MATH_DECL_1
 390 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 391   AC_MSG_CHECKING([for $1 declaration])
 392   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 393     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 394       AC_LANG_SAVE
 395       AC_LANG_CPLUSPLUS
 396       AC_TRY_COMPILE([#include <math.h>
 397                       #ifdef HAVE_IEEEFP_H
 398                       #include <ieeefp.h>
 399                       #endif
 400                      ],
 401                      [ $1(0);],
 402                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 403       AC_LANG_RESTORE
 404     ])
 405   fi
 406   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 407 ])
 408
 409 dnl
 410 dnl Check to see if the (math function) argument passed is
 411 dnl 1) declared when using the c++ compiler
 412 dnl 2) has "C" linkage
 413 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 414 dnl
 415 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 416 dnl
 417 dnl argument 1 is name of function to check
 418 dnl
 419 dnl ASSUMES argument is a math function with ONE parameter
 420 dnl
 421 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 422 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 423   GLIBCPP_CHECK_MATH_DECL_1($1)
 424   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 425     AC_CHECK_FUNCS($1)
 426   else
 427     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 428     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 429       AC_CHECK_FUNCS(_$1)
 430     fi
 431   fi
 432 ])
 433
 434
 435 dnl
 436 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 437 dnl of functions at once.  It's an all-or-nothing check -- either
 438 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 439 dnl Doing it this way saves significant configure time.
 440 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 441   AC_MSG_CHECKING([for $1 functions])
 442   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 443     AC_LANG_SAVE
 444     AC_LANG_CPLUSPLUS
 445     AC_TRY_COMPILE([#include <math.h>],
 446                    [ `for x in $3; do echo "$x (0);"; done` ],
 447                    [glibcpp_cv_func_$2_use=yes],
 448                    [glibcpp_cv_func_$2_use=no])
 449     AC_LANG_RESTORE])
 450   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 451   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 452     AC_CHECK_FUNCS($3)
 453   fi
 454 ])
 455
 456 dnl
 457 dnl Check to see if the (math function) argument passed is
 458 dnl declared when using the c++ compiler
 459 dnl ASSUMES argument is a math function with TWO parameters
 460 dnl
 461 dnl GLIBCPP_CHECK_MATH_DECL_2
 462 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 463   AC_MSG_CHECKING([for $1 declaration])
 464   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 465     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 466       AC_LANG_SAVE
 467       AC_LANG_CPLUSPLUS
 468       AC_TRY_COMPILE([#include <math.h>],
 469                      [ $1(0, 0);],
 470                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 471       AC_LANG_RESTORE
 472     ])
 473   fi
 474   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 475 ])
 476
 477 dnl
 478 dnl Check to see if the (math function) argument passed is
 479 dnl 1) declared when using the c++ compiler
 480 dnl 2) has "C" linkage
 481 dnl
 482 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 483 dnl
 484 dnl argument 1 is name of function to check
 485 dnl
 486 dnl ASSUMES argument is a math function with TWO parameters
 487 dnl
 488 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 489 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 490   GLIBCPP_CHECK_MATH_DECL_2($1)
 491   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 492     AC_CHECK_FUNCS($1)
 493   else
 494     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 495     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 496       AC_CHECK_FUNCS(_$1)
 497     fi
 498   fi
 499 ])
 500
 501
 502 dnl
 503 dnl Check to see if the (math function) argument passed is
 504 dnl declared when using the c++ compiler
 505 dnl ASSUMES argument is a math function with THREE parameters
 506 dnl
 507 dnl GLIBCPP_CHECK_MATH_DECL_3
 508 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 509   AC_MSG_CHECKING([for $1 declaration])
 510   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 511     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 512       AC_LANG_SAVE
 513       AC_LANG_CPLUSPLUS
 514       AC_TRY_COMPILE([#include <math.h>],
 515                      [ $1(0, 0, 0);],
 516                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 517       AC_LANG_RESTORE
 518     ])
 519   fi
 520   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 521 ])
 522
 523 dnl
 524 dnl Check to see if the (math function) argument passed is
 525 dnl 1) declared when using the c++ compiler
 526 dnl 2) has "C" linkage
 527 dnl
 528 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 529 dnl
 530 dnl argument 1 is name of function to check
 531 dnl
 532 dnl ASSUMES argument is a math function with THREE parameters
 533 dnl
 534 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 535 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 536   GLIBCPP_CHECK_MATH_DECL_3($1)
 537   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 538     AC_CHECK_FUNCS($1)
 539   else
 540     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 541     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 542       AC_CHECK_FUNCS(_$1)
 543     fi
 544   fi
 545 ])
 546
 547
 548 dnl
 549 dnl Check to see if the (stdlib function) argument passed is
 550 dnl 1) declared when using the c++ compiler
 551 dnl 2) has "C" linkage
 552 dnl
 553 dnl argument 1 is name of function to check
 554 dnl
 555 dnl ASSUMES argument is a math function with TWO parameters
 556 dnl
 557 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 558 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 559   AC_MSG_CHECKING([for $1 declaration])
 560   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 561     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 562       AC_LANG_SAVE
 563       AC_LANG_CPLUSPLUS
 564       AC_TRY_COMPILE([#include <stdlib.h>],
 565                      [ $1(0, 0);],
 566                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 567       AC_LANG_RESTORE
 568     ])
 569   fi
 570   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 571   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 572     AC_CHECK_FUNCS($1)
 573   fi
 574 ])
 575
 576
 577 dnl
 578 dnl Check to see if the (stdlib function) argument passed is
 579 dnl 1) declared when using the c++ compiler
 580 dnl 2) has "C" linkage
 581 dnl
 582 dnl argument 1 is name of function to check
 583 dnl
 584 dnl ASSUMES argument is a function with THREE parameters
 585 dnl
 586 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3
 587 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3, [
 588   AC_MSG_CHECKING([for $1 declaration])
 589   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 590     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 591       AC_LANG_SAVE
 592       AC_LANG_CPLUSPLUS
 593       AC_TRY_COMPILE([#include <stdlib.h>],
 594                      [ $1(0, 0, 0);],
 595                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 596       AC_LANG_RESTORE
 597     ])
 598   fi
 599   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 600   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 601     AC_CHECK_FUNCS($1)
 602   fi
 603 ])
 604
 605 dnl
 606 dnl Because the builtins are picky picky picky about the arguments they take,
 607 dnl do an explict linkage tests here.
 608 dnl Check to see if the (math function) argument passed is
 609 dnl 1) declared when using the c++ compiler
 610 dnl 2) has "C" linkage
 611 dnl
 612 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 613 dnl
 614 dnl argument 1 is name of function to check
 615 dnl
 616 dnl ASSUMES argument is a math function with ONE parameter
 617 dnl
 618 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 619 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 620   AC_MSG_CHECKING([for $1 declaration])
 621   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 622     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 623       AC_LANG_SAVE
 624       AC_LANG_CPLUSPLUS
 625       AC_TRY_COMPILE([#include <math.h>],
 626                      [ $1(0);],
 627                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 628       AC_LANG_RESTORE
 629     ])
 630   fi
 631   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 632   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 633     AC_MSG_CHECKING([for $1 linkage])
 634     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 635       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 636         AC_TRY_LINK([#include <math.h>],
 637                     [ $1(0);],
 638                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 639       ])
 640     fi
 641     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 642     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 643       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 644       AC_DEFINE_UNQUOTED(${ac_tr_func})
 645     fi
 646   fi
 647 ])
 648
 649
 650 dnl
 651 dnl Check to see what builtin math functions are supported
 652 dnl
 653 dnl check for __builtin_abs
 654 dnl check for __builtin_fabsf
 655 dnl check for __builtin_fabs
 656 dnl check for __builtin_fabl
 657 dnl check for __builtin_labs
 658 dnl check for __builtin_sqrtf
 659 dnl check for __builtin_sqrtl
 660 dnl check for __builtin_sqrt
 661 dnl check for __builtin_sinf
 662 dnl check for __builtin_sin
 663 dnl check for __builtin_sinl
 664 dnl check for __builtin_cosf
 665 dnl check for __builtin_cos
 666 dnl check for __builtin_cosl
 667 dnl
 668 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 669 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 670   dnl Test for builtin math functions.
 671   dnl These are made in gcc/c-common.c
 672   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 673   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 674   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 675   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 676   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 677
 678   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 679   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 680   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 681
 682   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 683   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 684   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 685
 686   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 687   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 688   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 689
 690   dnl There is, without a doubt, a more elegant way to have these
 691   dnl names exported so that they won't be stripped out of acconfig.h by
 692   dnl autoheader. I leave this as an exercise to somebody less frustrated
 693   dnl than I.... please email the libstdc++ list if you can figure out a
 694   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 695   dnl AC_CHECK_FUNC for things to steal.)
 696   dummyvar=no
 697   if test x$dummyvar = x"yes"; then
 698     AC_DEFINE(HAVE___BUILTIN_ABS)
 699     AC_DEFINE(HAVE___BUILTIN_LABS)
 700     AC_DEFINE(HAVE___BUILTIN_COS)
 701     AC_DEFINE(HAVE___BUILTIN_COSF)
 702     AC_DEFINE(HAVE___BUILTIN_COSL)
 703     AC_DEFINE(HAVE___BUILTIN_FABS)
 704     AC_DEFINE(HAVE___BUILTIN_FABSF)
 705     AC_DEFINE(HAVE___BUILTIN_FABSL)
 706     AC_DEFINE(HAVE___BUILTIN_SIN)
 707     AC_DEFINE(HAVE___BUILTIN_SINF)
 708     AC_DEFINE(HAVE___BUILTIN_SINL)
 709     AC_DEFINE(HAVE___BUILTIN_SQRT)
 710     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 711     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 712   fi
 713 ])
 714
 715 dnl
 716 dnl Check to see what the underlying c library is like
 717 dnl These checks need to do two things:
 718 dnl 1) make sure the name is declared when using the c++ compiler
 719 dnl 2) make sure the name has "C" linkage
 720 dnl This might seem like overkill but experience has shown that it's not...
 721 dnl
 722 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 723 dnl Define HAVE_STRTOF if "strtof" is declared and links
 724 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 725 dnl
 726 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 727 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 728   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 729   ac_save_CXXFLAGS="$CXXFLAGS"
 730   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 731
 732   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 733   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtof)
 734   AC_CHECK_FUNCS(drand48)
 735
 736   CXXFLAGS="$ac_save_CXXFLAGS"
 737 ])
 738
 739 dnl
 740 dnl Check to see what the underlying c library or math library is like.
 741 dnl These checks need to do two things:
 742 dnl 1) make sure the name is declared when using the c++ compiler
 743 dnl 2) make sure the name has "C" linkage
 744 dnl This might seem like overkill but experience has shown that it's not...
 745 dnl
 746 dnl Define HAVE_CARGF etc if "cargf" is found.
 747 dnl
 748 dnl GLIBCPP_CHECK_MATH_SUPPORT
 749 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 750   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 751   ac_save_CXXFLAGS="$CXXFLAGS"
 752   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 753
 754   dnl Check libm
 755   AC_CHECK_LIB(m, sin, libm="-lm")
 756   ac_save_LIBS="$LIBS"
 757   LIBS="$LIBS $libm"
 758
 759   dnl Check to see if certain C math functions exist.
 760   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 761   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 762   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 763   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 764   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 765   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 766   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 767   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 768
 769   dnl Check to see if basic C math functions have float versions.
 770   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 771                                           float_trig,
 772                                           acosf asinf atanf \
 773                                           cosf sinf tanf \
 774                                           coshf sinhf tanhf)
 775   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 776                                           float_round,
 777                                           ceilf floorf)
 778   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 779   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 780   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 781   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 782   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 783   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 784   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 785   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 786   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 787   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 788   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 789   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 790   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 791   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 792   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 793   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 794
 795   dnl Check to see if basic C math functions have long double versions.
 796   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 797                                           long_double_trig,
 798                                           acosl asinl atanl \
 799                                           cosl sinl tanl \
 800                                           coshl sinhl tanhl)
 801   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 802                                           long_double_round,
 803                                           ceill floorl)
 804   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 805   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 806   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 807   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 808   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 809   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 810   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 811   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 812   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 813   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 814   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 815   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 816   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 817   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 818   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 819   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 820   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 821
 822   dnl Some runtimes have these functions with a preceding underscore. Please
 823   dnl keep this sync'd with the one above. And if you add any new symbol,
 824   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 825   dnl Check to see if certain C math functions exist.
 826
 827   dnl Check to see if basic C math functions have float versions.
 828   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 829                                           _float_trig,
 830                                           _acosf _asinf _atanf \
 831                                           _cosf _sinf _tanf \
 832                                           _coshf _sinhf _tanhf)
 833   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 834                                           _float_round,
 835                                           _ceilf _floorf)
 836
 837   dnl Check to see if basic C math functions have long double versions.
 838   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 839                                           _long_double_trig,
 840                                           _acosl _asinl _atanl \
 841                                           _cosl _sinl _tanl \
 842                                           _coshl _sinhl _tanhl)
 843   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 844                                           _long_double_round,
 845                                           _ceill _floorl)
 846
 847   LIBS="$ac_save_LIBS"
 848   CXXFLAGS="$ac_save_CXXFLAGS"
 849 ])
 850
 851
 852 dnl
 853 dnl Check to see if there is native support for complex
 854 dnl
 855 dnl Don't compile bits in math/* if native support exits.
 856 dnl
 857 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 858 dnl
 859 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 860 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 861   dnl Check for complex versions of math functions of platform.
 862   AC_CHECK_LIB(m, main)
 863   AC_REPLACE_MATHFUNCS(nan copysignf)
 864
 865   dnl For __signbit to signbit conversions.
 866   AC_CHECK_FUNCS([__signbit], , [LIBMATHOBJS="$LIBMATHOBJS signbit.lo"])
 867   AC_CHECK_FUNCS([__signbitf], , [LIBMATHOBJS="$LIBMATHOBJS signbitf.lo"])
 868
 869   dnl Compile the long double complex functions only if the function
 870   dnl provides the non-complex long double functions that are needed.
 871   dnl Currently this includes copysignl, which should be
 872   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 873   if test x$ac_cv_func_copysignl = x"yes"; then
 874     AC_CHECK_FUNCS([__signbitl], , [LIBMATHOBJS="$LIBMATHOBJS signbitl.lo"])
 875   fi
 876
 877   if test -n "$LIBMATHOBJS"; then
 878     need_libmath=yes
 879   fi
 880   AC_SUBST(LIBMATHOBJS)
 881   AM_CONDITIONAL(GLIBCPP_BUILD_LIBMATH,  test "$need_libmath" = yes)
 882 ])
 883
 884
 885 dnl Check to see what architecture and operating system we are compiling
 886 dnl for.  Also, if architecture- or OS-specific flags are required for
 887 dnl compilation, pick them up here.
 888 dnl
 889 dnl GLIBCPP_CHECK_TARGET
 890 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 891   . [$]{glibcpp_basedir}/configure.target
 892   AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 893   AC_MSG_RESULT(OS config directory is $os_include_dir)
 894 ])
 895
 896
 897 dnl
 898 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 899 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 900 dnl must have been previously checked.)
 901 dnl
 902 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 903 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 904 dnl
 905 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 906 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 907   dnl Wide characters disabled by default.
 908   enable_wchar_t=no
 909
 910   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 911   dnl others even if wchar_t support is not on.
 912   AC_MSG_CHECKING([for mbstate_t])
 913   AC_TRY_COMPILE([#include <wchar.h>],
 914   [mbstate_t teststate;],
 915   have_mbstate_t=yes, have_mbstate_t=no)
 916   AC_MSG_RESULT($have_mbstate_t)
 917   if test x"$have_mbstate_t" = xyes; then
 918     AC_DEFINE(HAVE_MBSTATE_T)
 919   fi
 920
 921   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 922   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 923   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 924
 925   dnl Only continue checking if the ISO C99 headers exist and support is on.
 926   if test x"$ac_has_wchar_h" = xyes &&
 927      test x"$ac_has_wctype_h" = xyes &&
 928      test x"$enable_c_mbchar" != xno; then
 929
 930     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 931     dnl numeric_limits can instantiate type_traits<wchar_t>
 932     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 933     AC_TRY_COMPILE([#include <wchar.h>],
 934     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 935     has_wchar_minmax=yes, has_wchar_minmax=no)
 936     AC_MSG_RESULT($has_wchar_minmax)
 937
 938     dnl Test wchar.h for WEOF, which is what we use to determine whether
 939     dnl to specialize for char_traits<wchar_t> or not.
 940     AC_MSG_CHECKING([for WEOF])
 941     AC_TRY_COMPILE([
 942       #include <wchar.h>
 943       #include <stddef.h>],
 944     [wint_t i = WEOF;],
 945     has_weof=yes, has_weof=no)
 946     AC_MSG_RESULT($has_weof)
 947
 948     dnl Tests for wide character functions used in char_traits<wchar_t>.
 949     ac_wfuncs=yes
 950     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 951     ac_wfuncs=no)
 952
 953     dnl Checks for names injected into std:: by the c_std headers.
 954     AC_CHECK_FUNCS(btowc wctob fgetwc fgetws fputwc fputws fwide \
 955     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 956     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 957     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 958     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 959     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 960     ac_wfuncs=no)
 961
 962     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 963     if test x"$has_weof" = xyes &&
 964        test x"$has_wchar_minmax" = xyes &&
 965        test x"$ac_wfuncs" = xyes; then
 966       ac_isoC99_wchar_t=yes
 967     else
 968       ac_isoC99_wchar_t=no
 969     fi
 970     AC_MSG_RESULT($ac_isoC99_wchar_t)
 971
 972     dnl Use iconv for wchar_t to char conversions. As such, check for
 973     dnl X/Open Portability Guide, version 2 features (XPG2).
 974     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 975     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 976
 977     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 978     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 979     ac_save_LIBS="$LIBS"
 980     LIBS="$LIBS $libiconv"
 981
 982     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 983     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 984
 985     LIBS="$ac_save_LIBS"
 986
 987     AC_MSG_CHECKING([for XPG2 wchar_t support])
 988     if test x"$ac_has_iconv_h" = xyes &&
 989        test x"$ac_has_langinfo_h" = xyes &&
 990        test x"$ac_XPG2funcs" = xyes; then
 991       ac_XPG2_wchar_t=yes
 992     else
 993       ac_XPG2_wchar_t=no
 994     fi
 995     AC_MSG_RESULT($ac_XPG2_wchar_t)
 996
 997     dnl At the moment, only enable wchar_t specializations if all the
 998     dnl above support is present.
 999     if test x"$ac_isoC99_wchar_t" = xyes &&
1000         test x"$ac_XPG2_wchar_t" = xyes; then
1001       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
1002       enable_wchar_t=yes
1003     fi
1004   fi
1005   AC_MSG_CHECKING([for enabled wchar_t specializations])
1006   AC_MSG_RESULT($enable_wchar_t)
1007   AM_CONDITIONAL(GLIBCPP_TEST_WCHAR_T, test "$enable_wchar_t" = yes)
1008 ])
1009
1010
1011 dnl
1012 dnl Check to see if debugging libraries are to be built.
1013 dnl
1014 dnl GLIBCPP_ENABLE_DEBUG
1015 dnl
1016 dnl --enable-debug
1017 dnl builds a separate set of debugging libraries in addition to the
1018 dnl normal (shared, static) libstdc++ binaries.
1019 dnl
1020 dnl --disable-debug
1021 dnl builds only one (non-debug) version of libstdc++.
1022 dnl
1023 dnl --enable-debug-flags=FLAGS
1024 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1025 dnl
1026 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1027 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1028 dnl       defaults to `no'.
1029 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1030 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1031 AC_ARG_ENABLE(debug,
1032 changequote(<<, >>)dnl
1033 <<  --enable-debug          build extra debug library [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1034 changequote([, ])dnl
1035 [case "${enableval}" in
1036  yes) enable_debug=yes ;;
1037  no)  enable_debug=no ;;
1038  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1039  esac],
1040 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1041 AC_MSG_CHECKING([for additional debug build])
1042 AC_MSG_RESULT($enable_debug)
1043 AM_CONDITIONAL(GLIBCPP_BUILD_DEBUG, test "$enable_debug" = yes)
1044 ])
1045
1046
1047 dnl Check for explicit debug flags.
1048 dnl
1049 dnl GLIBCPP_ENABLE_DEBUG_FLAGS
1050 dnl
1051 dnl --enable-debug-flags='-O1'
1052 dnl is a general method for passing flags to be used when
1053 dnl building debug libraries with --enable-debug.
1054 dnl
1055 dnl --disable-debug-flags does nothing.
1056 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG_FLAGS(default flags)
1057 dnl       If "default flags" is an empty string (or "none"), the effect is
1058 dnl       the same as --disable or --enable=no.
1059 AC_DEFUN(GLIBCPP_ENABLE_DEBUG_FLAGS, [dnl
1060 define([GLIBCPP_ENABLE_DEBUG_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1061 AC_ARG_ENABLE(debug_flags,
1062 changequote(<<, >>)dnl
1063 <<  --enable-debug-flags=FLAGS    pass compiler FLAGS when building debug
1064                         library;[default=>>GLIBCPP_ENABLE_DEBUG_FLAGS_DEFAULT],
1065 changequote([, ])dnl
1066 [case "${enableval}" in
1067  none)  ;;
1068  -*) enable_debug_flags="${enableval}" ;;
1069  *)   AC_MSG_ERROR([Unknown argument to extra debugging flags]) ;;
1070  esac],
1071 enable_debug_flags=GLIBCPP_ENABLE_DEBUG_FLAGS_DEFAULT)dnl
1072
1073 dnl Option parsed, now set things appropriately
1074 case x"$enable_debug" in
1075     xyes)
1076         case "$enable_debug_flags" in
1077           none)
1078             DEBUG_FLAGS="-g3 -O0";;
1079           -*) #valid input
1080             DEBUG_FLAGS="${enableval}"
1081         esac
1082         ;;
1083     xno)
1084         DEBUG_FLAGS=""
1085         ;;
1086 esac
1087 AC_SUBST(DEBUG_FLAGS)
1088
1089 AC_MSG_CHECKING([for debug build flags])
1090 AC_MSG_RESULT($DEBUG_FLAGS)
1091 ])
1092
1093
1094 dnl
1095 dnl Check for "unusual" flags to pass to the compiler while building.
1096 dnl
1097 dnl GLIBCPP_ENABLE_CXX_FLAGS
1098 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1099 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1100 dnl     Somehow this same set of flags must be passed when [re]building
1101 dnl     libgcc.
1102 dnl --disable-cxx-flags passes nothing.
1103 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1104 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1105 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1106 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1107 dnl       If "default flags" is an empty string (or "none"), the effect is
1108 dnl       the same as --disable or --enable=no.
1109 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1110 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1111 AC_MSG_CHECKING([for extra compiler flags for building])
1112 AC_ARG_ENABLE(cxx_flags,
1113 changequote(<<, >>)dnl
1114 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1115                                   [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1116 changequote([, ])dnl
1117 [case "x$enable_cxx_flags" in
1118   xyes)
1119     AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1120   xno | xnone | x)
1121     enable_cxx_flags='' ;;
1122   *)
1123     enable_cxx_flags="$enableval" ;;
1124 esac],
1125 enable_cxx_flags=GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT)
1126
1127 dnl Run through flags (either default or command-line) and set anything
1128 dnl extra (e.g., #defines) that must accompany particular g++ options.
1129 if test -n "$enable_cxx_flags"; then
1130   for f in $enable_cxx_flags; do
1131     case "$f" in
1132       -fhonor-std)  ;;
1133       -*)  ;;
1134       *)   # and we're trying to pass /what/ exactly?
1135            AC_MSG_ERROR([compiler flags start with a -]) ;;
1136     esac
1137   done
1138 fi
1139 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1140 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1141 AC_SUBST(EXTRA_CXX_FLAGS)
1142 ])
1143
1144
1145 dnl
1146 dnl Check for which locale library to use:  gnu or generic.
1147 dnl
1148 dnl GLIBCPP_ENABLE_CLOCALE
1149 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1150 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1151 dnl
1152 dnl default is generic
1153 dnl
1154 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1155   AC_MSG_CHECKING([for clocale to use])
1156   AC_ARG_ENABLE(clocale,
1157   [  --enable-clocale        enable model for target locale package.
1158   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1159   ],
1160   if test x$enable_clocale = xno; then
1161      enable_clocale=no
1162   fi,
1163      enable_clocale=no)
1164
1165   enable_clocale_flag=$enable_clocale
1166
1167   dnl Probe for locale support if no specific model is specified.
1168   dnl Default to "generic"
1169   if test x$enable_clocale_flag = xno; then
1170     case x${target_os} in
1171       xlinux* | xgnu*)
1172         AC_EGREP_CPP([_GLIBCPP_ok], [
1173         #include <features.h>
1174         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1175           _GLIBCPP_ok
1176         #endif
1177         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1178
1179         # Test for bugs early in glibc-2.2.x series
1180         if test x$enable_clocale_flag = xgnu; then
1181           AC_TRY_RUN([
1182           #define _GNU_SOURCE 1
1183           #include <locale.h>
1184           #include <string.h>
1185           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1186           extern __typeof(newlocale) __newlocale;
1187           extern __typeof(duplocale) __duplocale;
1188           extern __typeof(strcoll_l) __strcoll_l;
1189           #endif
1190           int main()
1191           {
1192             const char __one[] = "Äuglein Augmen";
1193             const char __two[] = "Äuglein";
1194             int i;
1195             int j;
1196             __locale_t  loc;
1197             __locale_t  loc_dup;
1198             loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1199             loc_dup = __duplocale(loc);
1200             i = __strcoll_l(__one, __two, loc);
1201             j = __strcoll_l(__one, __two, loc_dup);
1202             return 0;
1203           }
1204           ],
1205           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1206           [enable_clocale_flag=generic])
1207         fi
1208
1209         # ... at some point put __strxfrm_l tests in as well.
1210         ;;
1211       *)
1212         enable_clocale_flag=generic
1213         ;;
1214     esac
1215   fi
1216
1217   dnl Deal with gettext issues.
1218   AC_ARG_ENABLE(nls,
1219   [  --enable-nls            use Native Language Support (default)],
1220   , enable_nls=yes)
1221   USE_NLS=no
1222
1223   dnl Set configure bits for specified locale package
1224   case x${enable_clocale_flag} in
1225     xgeneric)
1226       AC_MSG_RESULT(generic)
1227
1228       CLOCALE_H=config/locale/generic/c_locale.h
1229       CLOCALE_CC=config/locale/generic/c_locale.cc
1230       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1231       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1232       CCOLLATE_CC=config/locale/generic/collate_members.cc
1233       CCTYPE_CC=config/locale/generic/ctype_members.cc
1234       CMESSAGES_H=config/locale/generic/messages_members.h
1235       CMESSAGES_CC=config/locale/generic/messages_members.cc
1236       CMONEY_CC=config/locale/generic/monetary_members.cc
1237       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1238       CTIME_H=config/locale/generic/time_members.h
1239       CTIME_CC=config/locale/generic/time_members.cc
1240       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1241       ;;
1242     xgnu)
1243       AC_MSG_RESULT(gnu)
1244
1245       # Declare intention to use gettext, and add support for specific
1246       # languages.
1247       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1248       ALL_LINGUAS="de fr"
1249
1250       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1251       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1252       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1253         USE_NLS=yes
1254       fi
1255       # Export the build objects.
1256       for ling in $ALL_LINGUAS; do \
1257         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1258         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1259       done
1260       AC_SUBST(glibcpp_MOFILES)
1261       AC_SUBST(glibcpp_POFILES)
1262
1263       CLOCALE_H=config/locale/gnu/c_locale.h
1264       CLOCALE_CC=config/locale/gnu/c_locale.cc
1265       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1266       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1267       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1268       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1269       CMESSAGES_H=config/locale/gnu/messages_members.h
1270       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1271       CMONEY_CC=config/locale/gnu/monetary_members.cc
1272       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1273       CTIME_H=config/locale/gnu/time_members.h
1274       CTIME_CC=config/locale/gnu/time_members.cc
1275       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1276       ;;
1277     xieee_1003.1-2001)
1278       AC_MSG_RESULT(IEEE 1003.1)
1279
1280       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1281       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1282       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1283       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1284       CCOLLATE_CC=config/locale/generic/collate_members.cc
1285       CCTYPE_CC=config/locale/generic/ctype_members.cc
1286       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1287       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1288       CMONEY_CC=config/locale/generic/monetary_members.cc
1289       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1290       CTIME_H=config/locale/generic/time_members.h
1291       CTIME_CC=config/locale/generic/time_members.cc
1292       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1293       ;;
1294     *)
1295       echo "$enable_clocale is an unknown locale package" 1>&2
1296       exit 1
1297       ;;
1298   esac
1299
1300   # This is where the testsuite looks for locale catalogs, using the
1301   # -DLOCALEDIR define during testsuite compilation.
1302   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1303   AC_SUBST(glibcpp_localedir)
1304
1305   # A standalone libintl (e.g., GNU libintl) may be in use.
1306   if test $USE_NLS = yes; then
1307     AC_SEARCH_LIBS(gettext, intl,, USE_NLS=no)
1308   fi
1309
1310   AC_SUBST(USE_NLS)
1311   AC_SUBST(CLOCALE_H)
1312   AC_SUBST(CCODECVT_H)
1313   AC_SUBST(CMESSAGES_H)
1314   AC_SUBST(CCODECVT_CC)
1315   AC_SUBST(CCOLLATE_CC)
1316   AC_SUBST(CCTYPE_CC)
1317   AC_SUBST(CMESSAGES_CC)
1318   AC_SUBST(CMONEY_CC)
1319   AC_SUBST(CNUMERIC_CC)
1320   AC_SUBST(CTIME_H)
1321   AC_SUBST(CTIME_CC)
1322   AC_SUBST(CLOCALE_CC)
1323   AC_SUBST(CLOCALE_INTERNAL_H)
1324 ])
1325
1326
1327 dnl
1328 dnl Check for which I/O library to use:  libio, or something specific.
1329 dnl
1330 dnl GLIBCPP_ENABLE_CSTDIO
1331 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1332 dnl
1333 dnl default is stdio
1334 dnl
1335 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1336   AC_MSG_CHECKING([for cstdio to use])
1337   AC_ARG_ENABLE(cstdio,
1338   [  --enable-cstdio         enable stdio for target io package.
1339   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1340   ],
1341   if test x$enable_cstdio = xno; then
1342      enable_cstdio=stdio
1343   fi,
1344      enable_cstdio=stdio)
1345
1346   enable_cstdio_flag=$enable_cstdio
1347
1348   dnl Check if a valid I/O package
1349   case x${enable_cstdio_flag} in
1350     xlibio)
1351       CSTDIO_H=config/io/c_io_libio.h
1352       BASIC_FILE_H=config/io/basic_file_libio.h
1353       BASIC_FILE_CC=config/io/basic_file_libio.cc
1354       AC_MSG_RESULT(libio)
1355
1356       # see if we are on a system with libio native (ie, linux)
1357       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1358
1359       # Need to check and see what version of glibc is being used. If
1360       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1361       # compile most of libio for linux systems.
1362       if test x$has_libio = x"yes"; then
1363         case "$target" in
1364           *-*-linux*)
1365               AC_MSG_CHECKING([for glibc version >= 2.2])
1366               AC_EGREP_CPP([ok], [
1367             #include <features.h>
1368               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1369                     ok
1370               #endif
1371               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1372               AC_MSG_RESULT($glibc_satisfactory)
1373             ;;
1374         esac
1375
1376         # XXX at the moment, admit defeat and force the recompilation
1377         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1378         glibc_satisfactory=no
1379
1380         if test x$glibc_satisfactory = x"yes"; then
1381            need_libio=no
1382            need_wlibio=no
1383         else
1384            need_libio=yes
1385            # bkoz XXX need to add checks to enable this
1386            # pme XXX here's a first pass at such a check
1387            if test x$enable_c_mbchar != xno; then
1388               need_wlibio=yes
1389            else
1390               need_wlibio=no
1391            fi
1392         fi
1393
1394       else
1395          # Using libio, but <libio.h> doesn't exist on the target system. . .
1396          need_libio=yes
1397          # bkoz XXX need to add checks to enable this
1398          # pme XXX here's a first pass at such a check
1399          if test x$enable_c_mbchar != xno; then
1400              need_wlibio=yes
1401          else
1402              need_wlibio=no
1403          fi
1404       fi
1405       ;;
1406     xstdio | x | xno | xnone | xyes)
1407       # default
1408       CSTDIO_H=config/io/c_io_stdio.h
1409       BASIC_FILE_H=config/io/basic_file_stdio.h
1410       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1411       AC_MSG_RESULT(stdio)
1412
1413       # We're not using stdio.
1414       need_libio=no
1415       need_wlibio=no
1416       ;;
1417     *)
1418       echo "$enable_cstdio is an unknown io package" 1>&2
1419       exit 1
1420       ;;
1421   esac
1422   AC_SUBST(CSTDIO_H)
1423   AC_SUBST(BASIC_FILE_H)
1424   AC_SUBST(BASIC_FILE_CC)
1425
1426   # 2000-08-04 bkoz hack
1427   CCODECVT_C=config/io/c_io_libio_codecvt.c
1428   AC_SUBST(CCODECVT_C)
1429   # 2000-08-04 bkoz hack
1430
1431   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1432                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1433   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1434   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1435   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1436     libio_la=../libio/libio.la
1437   else
1438     libio_la=
1439   fi
1440   AC_SUBST(libio_la)
1441 ])
1442
1443
1444 dnl
1445 dnl Check to see if building and using a C++ precompiled header can be done.
1446 dnl
1447 dnl GLIBCPP_CHECK_PCH
1448 dnl
1449 dnl If it looks like it may work, flip bits on in include/Makefile.am
1450 dnl
1451 AC_DEFUN(GLIBCPP_CHECK_PCH, [
1452   ac_test_CXXFLAGS="${CXXFLAGS+set}"
1453   ac_save_CXXFLAGS="$CXXFLAGS"
1454   CXXFLAGS='-Werror -Winvalid-pch -Wno-deprecated -x c++-header'
1455
1456   AC_MSG_CHECKING([for compiler that seems to compile .gch files])
1457   if test x${glibcpp_pch_comp+set} != xset; then
1458     AC_CACHE_VAL(glibcpp_pch_comp, [
1459       AC_LANG_SAVE
1460       AC_LANG_CPLUSPLUS
1461       AC_TRY_COMPILE([#include <math.h>
1462                      ],
1463                      [ $1(0);],
1464                      [glibcpp_pch_comp=yes], [glibcpp_pch_comp=no])
1465       AC_LANG_RESTORE
1466     ])
1467   fi
1468   AC_MSG_RESULT([$glibcpp_pch_comp])
1469
1470   CXXFLAGS="$ac_save_CXXFLAGS"
1471   AM_CONDITIONAL(GLIBCPP_BUILD_PCH, test "$glibcpp_pch_comp" = yes)
1472 ])
1473
1474 dnl
1475 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1476 dnl We must stage the required headers so that they will be installed
1477 dnl with the library (unlike libgcc, the STL implementation is provided
1478 dnl solely within headers).  Since we must not inject random user-space
1479 dnl macro names into user-provided C++ code, we first stage into <file>-in
1480 dnl and process to <file> with an output command.  The reason for a two-
1481 dnl stage process here is to correctly handle $srcdir!=$objdir without
1482 dnl having to write complex code (the sed commands to clean the macro
1483 dnl namespace are complex and fragile enough as it is).  We must also
1484 dnl add a relative path so that -I- is supported properly.
1485 dnl
1486 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1487   AC_MSG_CHECKING([for thread model used by GCC])
1488   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1489   AC_MSG_RESULT([$target_thread_file])
1490
1491   if test $target_thread_file != single; then
1492     AC_DEFINE(HAVE_GTHR_DEFAULT)
1493     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1494   fi
1495
1496   glibcpp_thread_h=gthr-$target_thread_file.h
1497   AC_SUBST(glibcpp_thread_h)
1498 ])
1499
1500
1501 dnl
1502 dnl Check for exception handling support.  If an explicit enable/disable
1503 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1504 dnl target may or may not support call frame exceptions.
1505 dnl
1506 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1507 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1508 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1509 dnl
1510 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1511 dnl
1512 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1513   AC_MSG_CHECKING([for exception model to use])
1514   AC_LANG_SAVE
1515   AC_LANG_CPLUSPLUS
1516   AC_ARG_ENABLE(sjlj-exceptions,
1517   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1518   [:],
1519   [dnl Botheration.  Now we've got to detect the exception model.
1520    dnl Link tests against libgcc.a are problematic since -- at least
1521    dnl as of this writing -- we've not been given proper -L bits for
1522    dnl single-tree newlib and libgloss.
1523    dnl
1524    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1525    dnl conftest files before we got a change to grep them first.
1526    cat > conftest.$ac_ext << EOF
1527 [#]line __oline__ "configure"
1528 struct S { ~S(); };
1529 void bar();
1530 void foo()
1531 {
1532   S s;
1533   bar();
1534 }
1535 EOF
1536    old_CXXFLAGS="$CXXFLAGS"
1537    CXXFLAGS=-S
1538    if AC_TRY_EVAL(ac_compile); then
1539      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1540        enable_sjlj_exceptions=yes
1541      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1542        enable_sjlj_exceptions=no
1543      fi
1544    fi
1545    CXXFLAGS="$old_CXXFLAGS"
1546    rm -f conftest*])
1547    if test x$enable_sjlj_exceptions = xyes; then
1548      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1549         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1550      ac_exception_model_name=sjlj
1551    elif test x$enable_sjlj_exceptions = xno; then
1552      ac_exception_model_name="call frame"
1553    else
1554      AC_MSG_ERROR([unable to detect exception model])
1555    fi
1556    AC_LANG_RESTORE
1557    AC_MSG_RESULT($ac_exception_model_name)
1558 ])
1559
1560
1561 dnl
1562 dnl Check for libunwind exception handling support. If enabled then
1563 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1564 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1565 dnl libunwind instead of libgcc and that libstdc++ has a dependency
1566 dnl on libunwind as well as libgcc.
1567 dnl
1568 dnl GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS
1569 dnl --enable-libunwind-exceptions forces the use of libunwind.
1570 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1571 dnl
1572 dnl Define _GLIBCPP_LIBUNWIND_EXCEPTIONS if requested.
1573 dnl
1574 AC_DEFUN(GLIBCPP_ENABLE_LIBUNWIND_EXCEPTIONS, [
1575   AC_MSG_CHECKING([for use of libunwind])
1576   AC_ARG_ENABLE(libunwind-exceptions,
1577   [  --enable-libunwind-exceptions  force use of libunwind for exceptions],
1578   use_libunwind_exceptions=$enableval,
1579   use_libunwind_exceptions=no)
1580   AC_MSG_RESULT($use_libunwind_exceptions)
1581   dnl Option parsed, now set things appropriately
1582   if test x"$use_libunwind_exceptions" = xyes; then
1583     LIBUNWIND_FLAG="-lunwind"
1584   else
1585     LIBUNWIND_FLAG=""
1586   fi
1587   AC_SUBST(LIBUNWIND_FLAG)
1588 ])
1589
1590 dnl
1591 dnl Check for ISO/IEC 9899:1999 "C99" support.
1592 dnl
1593 dnl GLIBCPP_ENABLE_C99
1594 dnl --enable-c99 defines _GLIBCPP_USE_C99
1595 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1596 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1597 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1598 dnl       defaults to `no'.
1599 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1600 dnl
1601 dnl GLIBCPP_ENABLE_C99
1602 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1603   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1604
1605   AC_ARG_ENABLE(c99,
1606   changequote(<<, >>)dnl
1607   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1608   changequote([, ])dnl
1609   [case "$enableval" in
1610    yes) enable_c99=yes ;;
1611    no)  enable_c99=no ;;
1612    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1613    esac],
1614   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1615
1616   AC_LANG_SAVE
1617   AC_LANG_CPLUSPLUS
1618
1619   # Check for the existence of <math.h> functions used if C99 is enabled.
1620   ac_c99_math=yes;
1621   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1622   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1623   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1624   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1625   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1626   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1627   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1628   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1629   AC_TRY_COMPILE([#include <math.h>],
1630                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1631   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1632   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1633   AC_TRY_COMPILE([#include <math.h>],
1634                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1635   AC_TRY_COMPILE([#include <math.h>],
1636                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1637   AC_MSG_RESULT($ac_c99_math)
1638
1639   # Check for the existence in <stdio.h> of vscanf, et. al.
1640   ac_c99_stdio=yes;
1641   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1642   AC_TRY_COMPILE([#include <stdio.h>],
1643                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1644   AC_TRY_COMPILE([#include <stdio.h>
1645                   #include <stdarg.h>
1646                   void foo(char* fmt, ...)
1647                   {va_list args; va_start(args, fmt);
1648                   vfscanf(stderr, "%i", args);}],
1649                   [],, [ac_c99_stdio=no])
1650   AC_TRY_COMPILE([#include <stdio.h>
1651                   #include <stdarg.h>
1652                   void foo(char* fmt, ...)
1653                   {va_list args; va_start(args, fmt);
1654                   vscanf("%i", args);}],
1655                   [],, [ac_c99_stdio=no])
1656   AC_TRY_COMPILE([#include <stdio.h>
1657                   #include <stdarg.h>
1658                   void foo(char* fmt, ...)
1659                   {va_list args; va_start(args, fmt);
1660                   vsnprintf(fmt, 0, "%i", args);}],
1661                   [],, [ac_c99_stdio=no])
1662   AC_TRY_COMPILE([#include <stdio.h>
1663                   #include <stdarg.h>
1664                   void foo(char* fmt, ...)
1665                   {va_list args; va_start(args, fmt);
1666                   vsscanf(fmt, "%i", args);}],
1667                   [],, [ac_c99_stdio=no])
1668   AC_MSG_RESULT($ac_c99_stdio)
1669
1670   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1671   ac_c99_stdlib=yes;
1672   AC_MSG_CHECKING([for lldiv_t declaration])
1673   AC_CACHE_VAL(ac_c99_lldiv_t, [
1674   AC_TRY_COMPILE([#include <stdlib.h>],
1675                    [ lldiv_t mydivt;],
1676                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1677   ])
1678   AC_MSG_RESULT($ac_c99_lldiv_t)
1679
1680   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1681   AC_TRY_COMPILE([#include <stdlib.h>],
1682                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1683   AC_TRY_COMPILE([#include <stdlib.h>],
1684                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1685   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1686   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1687   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1688   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1689   if test x"$ac_c99_lldiv_t" = x"no"; then
1690     ac_c99_stdlib=no;
1691   fi;
1692   AC_MSG_RESULT($ac_c99_stdlib)
1693
1694   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1695   # XXX the wchar.h checks should be rolled into the general C99 bits.
1696   ac_c99_wchar=yes;
1697   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1698   AC_TRY_COMPILE([#include <wchar.h>],
1699                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1700   AC_TRY_COMPILE([#include <wchar.h>],
1701                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1702   AC_TRY_COMPILE([#include <wchar.h>],
1703                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1704   AC_MSG_RESULT($ac_c99_wchar)
1705
1706   AC_MSG_CHECKING([for enabled ISO C99 support])
1707   if test x"$ac_c99_math" = x"no" ||
1708      test x"$ac_c99_stdio" = x"no" ||
1709      test x"$ac_c99_stdlib" = x"no" ||
1710      test x"$ac_c99_wchar" = x"no"; then
1711     enable_c99=no;
1712   fi;
1713   AC_MSG_RESULT($enable_c99)
1714
1715   # Option parsed, now set things appropriately
1716   if test x"$enable_c99" = x"yes"; then
1717     AC_DEFINE(_GLIBCPP_USE_C99)
1718   fi
1719
1720   AC_LANG_RESTORE
1721 ])
1722
1723
1724 dnl
1725 dnl Check for template specializations for the 'long long' type extension.
1726 dnl The result determines only whether 'long long' I/O is enabled; things
1727 dnl like numeric_limits<> specializations are always available.
1728 dnl
1729 dnl GLIBCPP_ENABLE_LONG_LONG
1730 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1731 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1732 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1733 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1734 dnl       defaults to `no'.
1735 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1736 dnl
1737 dnl GLIBCPP_ENABLE_LONG_LONG
1738 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1739   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1740
1741   AC_ARG_ENABLE(long-long,
1742   changequote(<<, >>)dnl
1743   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1744   changequote([, ])dnl
1745   [case "$enableval" in
1746    yes) enable_long_long=yes ;;
1747    no)  enable_long_long=no ;;
1748    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1749    esac],
1750   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1751
1752   AC_LANG_SAVE
1753   AC_LANG_CPLUSPLUS
1754
1755   AC_MSG_CHECKING([for enabled long long I/O support])
1756   # iostreams require strtoll, strtoull to compile
1757   AC_TRY_COMPILE([#include <stdlib.h>],
1758                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1759   AC_TRY_COMPILE([#include <stdlib.h>],
1760                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1761
1762   # Option parsed, now set things appropriately
1763   if test x"$enable_long_long" = xyes; then
1764     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1765   fi
1766   AC_MSG_RESULT($enable_long_long)
1767
1768   AC_LANG_RESTORE
1769 ])
1770
1771
1772 dnl
1773 dnl Check for what type of C headers to use.
1774 dnl
1775 dnl GLIBCPP_ENABLE_CHEADERS
1776 dnl --enable-cheaders= [does stuff].
1777 dnl --disable-cheaders [does not do anything, really].
1778 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1779 dnl       Where DEFAULT is either `c' or `c_std'.
1780 dnl       If ommitted, it defaults to `c_std'.
1781 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1782 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1783 AC_MSG_CHECKING([for c header strategy to use])
1784 AC_ARG_ENABLE(cheaders,
1785 changequote(<<, >>)dnl
1786 <<  --enable-cheaders=MODEL       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1787 changequote([, ])
1788   [case "$enableval" in
1789    c)
1790         enable_cheaders=c
1791         ;;
1792    c_std)
1793         enable_cheaders=c_std
1794         ;;
1795    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1796         ;;
1797   esac],
1798   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1799   AC_MSG_RESULT($enable_cheaders)
1800
1801   dnl Option parsed, now set things appropriately
1802   case "$enable_cheaders" in
1803     c_std)
1804         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1805         ;;
1806     c)
1807         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1808         ;;
1809   esac
1810
1811   AC_SUBST(C_INCLUDE_DIR)
1812   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C, test "$enable_cheaders" = c)
1813   AM_CONDITIONAL(GLIBCPP_C_HEADERS_C_STD, test "$enable_cheaders" = c_std)
1814   AM_CONDITIONAL(GLIBCPP_C_HEADERS_COMPATIBILITY, test "$c_compatibility" = yes)
1815 ])
1816
1817
1818 dnl
1819 dnl Check for wide character support.  Has the same effect as the option
1820 dnl in gcc's configure, but in a form that autoconf can mess with.
1821 dnl
1822 dnl GLIBCPP_ENABLE_C_MBCHAR
1823 dnl --enable-c-mbchar requests all the wchar_t stuff.
1824 dnl --disable-c-mbchar doesn't.
1825 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1826 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1827 dnl       defaults to `no'.
1828 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1829 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1830 AC_ARG_ENABLE(c-mbchar,
1831 changequote(<<, >>)dnl
1832 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1833 changequote([, ])dnl
1834 [case "$enableval" in
1835  yes) enable_c_mbchar=yes ;;
1836  no)  enable_c_mbchar=no ;;
1837  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1838  esac],
1839 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1840 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1841 ])
1842
1843
1844 dnl
1845 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1846 dnl
1847 dnl TOPLEVEL_INCLUDES
1848 dnl LIBMATH_INCLUDES
1849 dnl LIBSUPCXX_INCLUDES
1850 dnl LIBIO_INCLUDES
1851 dnl
1852 dnl GLIBCPP_EXPORT_INCLUDES
1853 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1854   # Root level of the build directory include sources.
1855   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1856
1857   # Passed down for canadian crosses.
1858   if test x"$CANADIAN" = xyes; then
1859     TOPLEVEL_INCLUDES='-I$(includedir)'
1860   fi
1861
1862   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1863
1864   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1865
1866   if test x"$need_libio" = xyes; then
1867     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1868     AC_SUBST(LIBIO_INCLUDES)
1869   fi
1870
1871   # Now, export this to all the little Makefiles....
1872   AC_SUBST(GLIBCPP_INCLUDES)
1873   AC_SUBST(TOPLEVEL_INCLUDES)
1874   AC_SUBST(LIBMATH_INCLUDES)
1875   AC_SUBST(LIBSUPCXX_INCLUDES)
1876 ])
1877
1878
1879 dnl
1880 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1881 dnl
1882 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1883   # Optimization flags that are probably a good idea for thrill-seekers. Just
1884   # uncomment the lines below and make, everything else is ready to go...
1885   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1886   OPTIMIZE_CXXFLAGS=
1887   AC_SUBST(OPTIMIZE_CXXFLAGS)
1888
1889   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings'
1890   AC_SUBST(WARN_FLAGS)
1891 ])
1892
1893 dnl
1894 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1895 dnl  calculates gxx_install_dir
1896 dnl  exports glibcpp_toolexecdir
1897 dnl  exports glibcpp_toolexeclibdir
1898 dnl  exports glibcpp_prefixdir
1899 dnl
1900 dnl Assumes cross_compiling bits already done, and with_cross_host in
1901 dnl particular
1902 dnl
1903 dnl GLIBCPP_EXPORT_INSTALL_INFO
1904 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1905 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1906 # exported correctly in GLIBCPP_CONFIGURE.
1907 glibcpp_toolexecdir=no
1908 glibcpp_toolexeclibdir=no
1909 glibcpp_prefixdir=${prefix}
1910
1911 # Process the option --with-gxx-include-dir=<path to include-files directory>
1912 AC_MSG_CHECKING([for --with-gxx-include-dir])
1913 AC_ARG_WITH(gxx-include-dir,
1914 [  --with-gxx-include-dir  the installation directory for include files],
1915 [case "${withval}" in
1916   yes)
1917     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1918     gxx_include_dir=no
1919     ;;
1920   no)
1921     gxx_include_dir=no
1922     ;;
1923   *)
1924     gxx_include_dir=${withval}
1925     ;;
1926 esac], [gxx_include_dir=no])
1927 AC_MSG_RESULT($gxx_include_dir)
1928
1929 # Process the option "--enable-version-specific-runtime-libs"
1930 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1931 AC_ARG_ENABLE(version-specific-runtime-libs,
1932 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1933 [case "$enableval" in
1934  yes) version_specific_libs=yes ;;
1935  no)  version_specific_libs=no ;;
1936  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1937  esac],
1938 version_specific_libs=no)dnl
1939 # Option set, now we can test it.
1940 AC_MSG_RESULT($version_specific_libs)
1941
1942 # Default case for install directory for include files.
1943 if test $version_specific_libs = no && test $gxx_include_dir = no; then
1944   gxx_include_dir='$(prefix)'/include/c++/${gcc_version}
1945 fi
1946
1947 # Version-specific runtime libs processing.
1948 if test $version_specific_libs = yes; then
1949   # Need the gcc compiler version to know where to install libraries
1950   # and header files if --enable-version-specific-runtime-libs option
1951   # is selected.
1952   if test x"$gxx_include_dir" = x"no"; then
1953     gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/c++
1954   fi
1955   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1956   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1957 fi
1958
1959 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1960 # Install a library built with a cross compiler in tooldir, not libdir.
1961 if test x"$glibcpp_toolexecdir" = x"no"; then
1962   if test -n "$with_cross_host" &&
1963      test x"$with_cross_host" != x"no"; then
1964     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1965     glibcpp_toolexeclibdir='$(toolexecdir)/lib'
1966   else
1967     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1968     glibcpp_toolexeclibdir='$(libdir)'
1969   fi
1970   multi_os_directory=`$CC -print-multi-os-directory`
1971   case $multi_os_directory in
1972   .) ;; # Avoid trailing /.
1973   *) glibcpp_toolexeclibdir=$glibcpp_toolexeclibdir/$multi_os_directory ;;
1974   esac
1975 fi
1976
1977 AC_MSG_CHECKING([for install location])
1978 AC_MSG_RESULT($gxx_include_dir)
1979
1980 AC_SUBST(glibcpp_prefixdir)
1981 AC_SUBST(gxx_include_dir)
1982 AC_SUBST(glibcpp_toolexecdir)
1983 AC_SUBST(glibcpp_toolexeclibdir)
1984 ])
1985
1986
1987 # Check for functions in math library.
1988 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1989 #
1990 # This file can be copied and used freely without restrictions.  It can
1991 # be used in projects which are not available under the GNU Public License
1992 # but which still want to provide support for the GNU gettext functionality.
1993 # Please note that the actual code is *not* freely available.
1994
1995 # serial 1
1996
1997 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1998 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1999 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])])
2000
2001
2002 dnl This macro searches for a GNU version of make.  If a match is found, the
2003 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
2004 dnl set to "#". This is useful for  including a special features in a Makefile,
2005 dnl which cannot be handled by other versions of make.  The variable
2006 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
2007 dnl the empty string otherwise.
2008 dnl
2009 dnl Here is an example of its use:
2010 dnl
2011 dnl Makefile.in might contain:
2012 dnl
2013 dnl     # A failsafe way of putting a dependency rule into a makefile
2014 dnl     $(DEPEND):
2015 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
2016 dnl
2017 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
2018 dnl     @ifGNUmake@ include $(DEPEND)
2019 dnl     @ifGNUmake@ endif
2020 dnl
2021 dnl Then configure.in would normally contain:
2022 dnl
2023 dnl     CHECK_GNU_MAKE()
2024 dnl     AC_OUTPUT(Makefile)
2025 dnl
2026 dnl Then perhaps to cause gnu make to override any other make, we could do
2027 dnl something like this (note that GNU make always looks for GNUmakefile first):
2028 dnl
2029 dnl     if  ! test x$_cv_gnu_make_command = x ; then
2030 dnl             mv Makefile GNUmakefile
2031 dnl             echo .DEFAULT: > Makefile ;
2032 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
2033 dnl     fi
2034 dnl
2035 dnl Then, if any (well almost any) other make is called, and GNU make also
2036 dnl exists, then the other make wraps the GNU make.
2037 dnl
2038 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
2039 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
2040 dnl
2041 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
2042 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
2043 dnl #### conditional's subshell (" --version" is not a command), using a
2044 dnl #### different option to grep(1).
2045 dnl #### -pme
2046 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
2047 dnl #### ${MAKE:-make}).
2048 dnl #### -msokolov
2049 AC_DEFUN(
2050   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
2051           _cv_gnu_make_command='' ;
2052 dnl Search all the common names for GNU make
2053           for a in "${MAKE-make}" make gmake gnumake ; do
2054                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
2055                   then
2056                           _cv_gnu_make_command=$a ;
2057                           break;
2058                   fi
2059           done ;
2060   ) ;
2061 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
2062 dnl string, '#' otherwise
2063   if test  "x$_cv_gnu_make_command" != "x"  ; then
2064           ifGNUmake='' ;
2065   else
2066           ifGNUmake='#' ;
2067   fi
2068   AC_SUBST(ifGNUmake)
2069 ])
2070
2071
2072 dnl Check for headers for, and arguments to, the setrlimit() function.
2073 dnl Used only in testsuite_hooks.h.
2074 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
2075   AC_TRY_COMPILE([#include <unistd.h>
2076                   #include <sys/time.h>
2077                   #include <sys/resource.h>
2078                  ], [ int f = RLIMIT_$1 ; ],
2079                  [glibcpp_mresult=1], [glibcpp_mresult=0])
2080   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
2081                      [Only used in build directory testsuite_hooks.h.])
2082 ])
2083 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
2084   setrlimit_have_headers=yes
2085   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
2086                    [],
2087                    setrlimit_have_headers=no)
2088   # If don't have the headers, then we can't run the tests now, and we
2089   # won't be seeing any of these during testsuite compilation.
2090   if test $setrlimit_have_headers = yes; then
2091     # Can't do these in a loop, else the resulting syntax is wrong.
2092     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
2093     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
2094     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
2095     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
2096
2097     # Check for rlimit, setrlimit.
2098     AC_CACHE_VAL(ac_setrlimit, [
2099       AC_TRY_COMPILE([#include <unistd.h>
2100                   #include <sys/time.h>
2101                   #include <sys/resource.h>
2102                      ],
2103                      [ struct rlimit r; setrlimit(0, &r);],
2104                      [ac_setrlimit=yes], [ac_setrlimit=no])
2105     ])
2106   fi
2107
2108   AC_MSG_CHECKING([for testsuite memory limit support])
2109   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
2110     ac_mem_limits=yes
2111     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
2112   else
2113     ac_mem_limits=no
2114   fi
2115   AC_MSG_RESULT($ac_mem_limits)
2116 ])
2117
2118
2119 dnl
2120 dnl Does any necessary configuration of the testsuite directory.  Generates
2121 dnl the testsuite_hooks.h header.
2122 dnl
2123 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
2124 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
2125   GLIBCPP_CHECK_SETRLIMIT
2126
2127   # Look for setenv, so that extended locale tests can be performed.
2128   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
2129
2130   # Export file names for ABI checking.
2131   baseline_file="${glibcpp_srcdir}/config/abi/${abi_baseline_triplet}/baseline_symbols.txt"
2132   AC_SUBST(baseline_file)
2133
2134   case "$target" in
2135     *-*-cygwin* ) enable_abi_check=no ;;
2136     * ) enable_abi_check=yes ;;
2137   esac
2138
2139   # Don't do ABI checking unless native.
2140   AM_CONDITIONAL(GLIBCPP_BUILD_ABI_CHECK,
2141                  test x"$build" = x"$host" && test -z "$with_cross_host" \
2142                  && test "$enable_abi_check" = yes )
2143 ])
2144
2145
2146 sinclude(../libtool.m4)
2147 dnl The lines below arrange for aclocal not to bring an installed
2148 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
2149 dnl add a definition of LIBTOOL to Makefile.in.
2150 ifelse(,,,[AC_SUBST(LIBTOOL)
2151 AC_DEFUN([AM_PROG_LIBTOOL])
2152 AC_DEFUN([AC_LIBTOOL_DLOPEN])
2153 AC_DEFUN([AC_PROG_LD])
2154 ])
2155
2156 dnl
2157 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
2158 dnl
2159
2160 AC_DEFUN(GLIBCPP_CHECK_S_ISREG_OR_S_IFREG, [
2161   AC_CACHE_VAL(glibcpp_cv_S_ISREG, [
2162     AC_TRY_LINK([#include <sys/stat.h>],
2163                 [struct stat buffer; fstat(0, &buffer); S_ISREG(buffer.st_mode); ],
2164                 [glibcpp_cv_S_ISREG=yes],
2165                 [glibcpp_cv_S_ISREG=no])
2166   ])
2167   AC_CACHE_VAL(glibcpp_cv_S_IFREG, [
2168     AC_TRY_LINK([#include <sys/stat.h>],
2169                 [struct stat buffer; fstat(0, &buffer); S_IFREG & buffer.st_mode; ],
2170                 [glibcpp_cv_S_IFREG=yes],
2171                 [glibcpp_cv_S_IFREG=no])
2172   ])
2173   if test x$glibcpp_cv_S_ISREG = xyes; then
2174     AC_DEFINE(HAVE_S_ISREG)
2175   elif test x$glibcpp_cv_S_IFREG = xyes; then
2176     AC_DEFINE(HAVE_S_IFREG)
2177   fi
2178 ])
2179
2180 dnl
2181 dnl Check whether poll is available in <poll.h>.
2182 dnl
2183
2184 AC_DEFUN(GLIBCPP_CHECK_POLL, [
2185   AC_CACHE_VAL(glibcpp_cv_POLL, [
2186     AC_TRY_COMPILE([#include <poll.h>],
2187                 [struct pollfd pfd[1]; pfd[0].events = POLLIN; poll(pfd, 1, 0); ],
2188                 [glibcpp_cv_POLL=yes],
2189                 [glibcpp_cv_POLL=no])
2190   ])
2191   if test x$glibcpp_cv_POLL = xyes; then
2192     AC_DEFINE(HAVE_POLL)
2193   fi
2194 ])
2195
2196 # Check whether LC_MESSAGES is available in <locale.h>.
2197 # Ulrich Drepper <drepper@cygnus.com>, 1995.
2198 #
2199 # This file file be copied and used freely without restrictions.  It can
2200 # be used in projects which are not available under the GNU Public License
2201 # but which still want to provide support for the GNU gettext functionality.
2202 # Please note that the actual code is *not* freely available.
2203
2204 # serial 1
2205
2206 AC_DEFUN(AC_LC_MESSAGES, [
2207   AC_CHECK_HEADER(locale.h, [
2208     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
2209       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
2210        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
2211     if test $ac_cv_val_LC_MESSAGES = yes; then
2212       AC_DEFINE(HAVE_LC_MESSAGES)
2213     fi
2214   ])
2215 ])
2216
2217
2218 dnl
2219 dnl Check for whether the Boost-derived checks should be turned on.
2220 dnl
2221 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
2222 dnl --enable-concept-checks turns them on.
2223 dnl --disable-concept-checks leaves them off.
2224 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2225 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2226 dnl       defaults to `no'.
2227 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
2228 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
2229 AC_ARG_ENABLE(concept-checks,
2230 changequote(<<, >>)dnl
2231 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
2232 changequote([, ])dnl
2233 [case "$enableval" in
2234  yes) enable_concept_checks=yes ;;
2235  no)  enable_concept_checks=no ;;
2236  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
2237  esac],
2238 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
2239 dnl Option parsed, now set things appropriately
2240 if test x"$enable_concept_checks" = xyes; then
2241   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
2242 fi
2243 ])
2244
2245
2246 dnl
2247 dnl Add version tags to symbols in shared library (or not), additionally
2248 dnl marking other symbols as private/local (or not).
2249 dnl
2250 dnl GLIBCPP_ENABLE_SYMVERS
2251 dnl --enable-symvers=style adds a version script to the linker call when
2252 dnl       creating the shared library.  The choice of version script is
2253 dnl       controlled by 'style'.
2254 dnl --disable-symvers does not.
2255 dnl  +  Usage:  GLIBCPP_ENABLE_SYMVERS[(DEFAULT)]
2256 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
2257 dnl       defaults to `no'.  Passing `yes' tries to choose a default style
2258 dnl       based on linker characteristics.  Passing 'no' disables versioning.
2259 AC_DEFUN(GLIBCPP_ENABLE_SYMVERS, [dnl
2260 define([GLIBCPP_ENABLE_SYMVERS_DEFAULT], ifelse($1, yes, yes, no))dnl
2261 AC_ARG_ENABLE(symvers,
2262 changequote(<<, >>)dnl
2263 <<  --enable-symvers=style  enables symbol versioning of the shared library [default=>>GLIBCPP_ENABLE_SYMVERS_DEFAULT],
2264 changequote([, ])dnl
2265 [case "$enableval" in
2266  yes) enable_symvers=yes ;;
2267  no)  enable_symvers=no ;;
2268  # other names here, just as sanity checks
2269  #gnu|sun|etcetera) enable_symvers=$enableval ;;
2270  gnu) enable_symvers=$enableval ;;
2271  *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]) ;;
2272  esac],
2273 enable_symvers=GLIBCPP_ENABLE_SYMVERS_DEFAULT)dnl
2274
2275 # If we never went through the GLIBCPP_CHECK_LINKER_FEATURES macro, then we
2276 # don't know enough about $LD to do tricks...
2277 if test x$enable_shared = xno ||
2278         test "x$LD" = x ||
2279         test x$glibcpp_gnu_ld_version = x; then
2280   enable_symvers=no
2281 fi
2282
2283 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
2284 if test $enable_symvers != no; then
2285   AC_MSG_CHECKING([for shared libgcc])
2286   ac_save_CFLAGS="$CFLAGS"
2287   CFLAGS=' -lgcc_s'
2288   AC_TRY_LINK(, [return 0], glibcpp_shared_libgcc=yes, glibcpp_shared_libgcc=no)
2289   CFLAGS="$ac_save_CFLAGS"
2290   AC_MSG_RESULT($glibcpp_shared_libgcc)
2291 fi
2292
2293 # For GNU ld, we need at least this version.  It's 2.12 in the same format
2294 # as the tested-for version.  See GLIBCPP_CHECK_LINKER_FEATURES for more.
2295 glibcpp_min_gnu_ld_version=21200
2296
2297 # Check to see if unspecified "yes" value can win, given results
2298 # above.
2299 if test $enable_symvers = yes ; then
2300   if test $with_gnu_ld = yes &&
2301     test $glibcpp_shared_libgcc = yes ;
2302   then
2303     if test $glibcpp_gnu_ld_version -ge $glibcpp_min_gnu_ld_version ; then
2304         enable_symvers=gnu
2305     else
2306       ac_test_CFLAGS="${CFLAGS+set}"
2307       ac_save_CFLAGS="$CFLAGS"
2308       CFLAGS='-shared -Wl,--version-script,conftest.map'
2309       enable_symvers=no
2310       changequote(,)
2311       echo 'FOO { global: f[a-z]o; local: *; };' > conftest.map
2312       changequote([,])
2313       AC_TRY_LINK([int foo;],, enable_symvers=gnu)
2314       if test "$ac_test_CFLAGS" = set; then
2315         CFLAGS="$ac_save_CFLAGS"
2316       else
2317         # this is the suspicious part
2318         CFLAGS=''
2319       fi
2320       rm -f conftest.map
2321     fi
2322   else
2323     # just fail for now
2324     enable_symvers=no
2325   fi
2326 fi
2327
2328 dnl Everything parsed; figure out what file to use.
2329 case $enable_symvers in
2330   no)
2331       SYMVER_MAP=config/linker-map.dummy
2332       ;;
2333   gnu)
2334       SYMVER_MAP=config/linker-map.gnu
2335       AC_DEFINE(_GLIBCPP_SYMVER)
2336       ;;
2337 esac
2338
2339 AC_SUBST(SYMVER_MAP)
2340 AM_CONDITIONAL(GLIBCPP_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
2341 AC_MSG_CHECKING([versioning on shared library symbols])
2342 AC_MSG_RESULT($enable_symvers)
2343 ])
2344
2345
2346 # isc-posix.m4 serial 2 (gettext-0.11.2)
2347 dnl Copyright (C) 1995-2002 Free Software Foundation, Inc.
2348 dnl This file is free software, distributed under the terms of the GNU
2349 dnl General Public License.  As a special exception to the GNU General
2350 dnl Public License, this file may be distributed as part of a program
2351 dnl that contains a configuration script generated by Autoconf, under
2352 dnl the same distribution terms as the rest of that program.
2353
2354 # This file is not needed with autoconf-2.53 and newer.  Remove it in 2005.
2355
2356 # This test replaces the one in autoconf.
2357 # Currently this macro should have the same name as the autoconf macro
2358 # because gettext's gettext.m4 (distributed in the automake package)
2359 # still uses it.  Otherwise, the use in gettext.m4 makes autoheader
2360 # give these diagnostics:
2361 #   configure.in:556: AC_TRY_COMPILE was called before AC_ISC_POSIX
2362 #   configure.in:556: AC_TRY_RUN was called before AC_ISC_POSIX
2363
2364 undefine([AC_ISC_POSIX])
2365
2366 AC_DEFUN([AC_ISC_POSIX],
2367   [
2368     dnl This test replaces the obsolescent AC_ISC_POSIX kludge.
2369     AC_CHECK_LIB(cposix, strerror, [LIBS="$LIBS -lcposix"])
2370   ]
2371 )
2372
2373 # Add --enable-maintainer-mode option to configure.
2374 # From Jim Meyering
2375
2376 # serial 1
2377
2378 AC_DEFUN([AM_MAINTAINER_MODE],
2379 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
2380   dnl maintainer-mode is disabled by default
2381   AC_ARG_ENABLE(maintainer-mode,
2382 [  --enable-maintainer-mode enable make rules and dependencies not useful
2383                           (and sometimes confusing) to the casual installer],
2384       USE_MAINTAINER_MODE=$enableval,
2385       USE_MAINTAINER_MODE=no)
2386   AC_MSG_RESULT($USE_MAINTAINER_MODE)
2387   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
2388   MAINT=$MAINTAINER_MODE_TRUE
2389   AC_SUBST(MAINT)dnl
2390 ]
2391 )
2392
2393 # Define a conditional.
2394
2395 AC_DEFUN([AM_CONDITIONAL],
2396 [AC_SUBST($1_TRUE)
2397 AC_SUBST($1_FALSE)
2398 if $2; then
2399   $1_TRUE=
2400   $1_FALSE='#'
2401 else
2402   $1_TRUE='#'
2403   $1_FALSE=
2404 fi])
2405
2406 # Do all the work for Automake.  This macro actually does too much --
2407 # some checks are only needed if your package does certain things.
2408 # But this isn't really a big deal.
2409
2410 # serial 1
2411
2412 dnl Usage:
2413 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
2414
2415 AC_DEFUN([AM_INIT_AUTOMAKE],
2416 [AC_REQUIRE([AM_SET_CURRENT_AUTOMAKE_VERSION])dnl
2417 AC_REQUIRE([AC_PROG_INSTALL])
2418 PACKAGE=[$1]
2419 AC_SUBST(PACKAGE)
2420 VERSION=[$2]
2421 AC_SUBST(VERSION)
2422 dnl test to see if srcdir already configured
2423 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
2424   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
2425 fi
2426 ifelse([$3],,
2427 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
2428 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
2429 AC_REQUIRE([AM_SANITY_CHECK])
2430 AC_REQUIRE([AC_ARG_PROGRAM])
2431 dnl FIXME This is truly gross.
2432 missing_dir=`cd $ac_aux_dir && pwd`
2433 AM_MISSING_PROG(ACLOCAL, aclocal-${am__api_version}, $missing_dir)
2434 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
2435 AM_MISSING_PROG(AUTOMAKE, automake-${am__api_version}, $missing_dir)
2436 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
2437 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
2438 AC_REQUIRE([AC_PROG_MAKE_SET])])
2439
2440 # Copyright 2002  Free Software Foundation, Inc.
2441
2442 # This program is free software; you can redistribute it and/or modify
2443 # it under the terms of the GNU General Public License as published by
2444 # the Free Software Foundation; either version 2, or (at your option)
2445 # any later version.
2446
2447 # This program is distributed in the hope that it will be useful,
2448 # but WITHOUT ANY WARRANTY; without even the implied warranty of
2449 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2450 # GNU General Public License for more details.
2451
2452 # You should have received a copy of the GNU General Public License
2453 # along with this program; if not, write to the Free Software
2454 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
2455
2456 # AM_AUTOMAKE_VERSION(VERSION)
2457 # ----------------------------
2458 # Automake X.Y traces this macro to ensure aclocal.m4 has been
2459 # generated from the m4 files accompanying Automake X.Y.
2460 AC_DEFUN([AM_AUTOMAKE_VERSION],[am__api_version="1.4"])
2461
2462 # AM_SET_CURRENT_AUTOMAKE_VERSION
2463 # -------------------------------
2464 # Call AM_AUTOMAKE_VERSION so it can be traced.
2465 # This function is AC_REQUIREd by AC_INIT_AUTOMAKE.
2466 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
2467          [AM_AUTOMAKE_VERSION([1.4-p6])])
2468
2469 #
2470 # Check to make sure that the build environment is sane.
2471 #
2472
2473 AC_DEFUN([AM_SANITY_CHECK],
2474 [AC_MSG_CHECKING([whether build environment is sane])
2475 # Just in case
2476 sleep 1
2477 echo timestamp > conftestfile
2478 # Do `set' in a subshell so we don't clobber the current shell's
2479 # arguments.  Must try -L first in case configure is actually a
2480 # symlink; some systems play weird games with the mod time of symlinks
2481 # (eg FreeBSD returns the mod time of the symlink's containing
2482 # directory).
2483 if (
2484    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
2485    if test "[$]*" = "X"; then
2486       # -L didn't work.
2487       set X `ls -t $srcdir/configure conftestfile`
2488    fi
2489    if test "[$]*" != "X $srcdir/configure conftestfile" \
2490       && test "[$]*" != "X conftestfile $srcdir/configure"; then
2491
2492       # If neither matched, then we have a broken ls.  This can happen
2493       # if, for instance, CONFIG_SHELL is bash and it inherits a
2494       # broken ls alias from the environment.  This has actually
2495       # happened.  Such a system could not be considered "sane".
2496       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
2497 alias in your environment])
2498    fi
2499
2500    test "[$]2" = conftestfile
2501    )
2502 then
2503    # Ok.
2504    :
2505 else
2506    AC_MSG_ERROR([newly created file is older than distributed files!
2507 Check your system clock])
2508 fi
2509 rm -f conftest*
2510 AC_MSG_RESULT(yes)])
2511
2512 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
2513 dnl The program must properly implement --version.
2514 AC_DEFUN([AM_MISSING_PROG],
2515 [AC_MSG_CHECKING(for working $2)
2516 # Run test in a subshell; some versions of sh will print an error if
2517 # an executable is not found, even if stderr is redirected.
2518 # Redirect stdin to placate older versions of autoconf.  Sigh.
2519 if ($2 --version) < /dev/null > /dev/null 2>&1; then
2520    $1=$2
2521    AC_MSG_RESULT(found)
2522 else
2523    $1="$3/missing $2"
2524    AC_MSG_RESULT(missing)
2525 fi
2526 AC_SUBST($1)])
2527
2528 # Like AC_CONFIG_HEADER, but automatically create stamp file.
2529
2530 AC_DEFUN([AM_CONFIG_HEADER],
2531 [AC_PREREQ([2.12])
2532 AC_CONFIG_HEADER([$1])
2533 dnl When config.status generates a header, we must update the stamp-h file.
2534 dnl This file resides in the same directory as the config header
2535 dnl that is generated.  We must strip everything past the first ":",
2536 dnl and everything past the last "/".
2537 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
2538 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
2539 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
2540 <<am_indx=1
2541 for am_file in <<$1>>; do
2542   case " <<$>>CONFIG_HEADERS " in
2543   *" <<$>>am_file "*<<)>>
2544     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
2545     ;;
2546   esac
2547   am_indx=`expr "<<$>>am_indx" + 1`
2548 done<<>>dnl>>)
2549 changequote([,]))])
2550