libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  27   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  28 ])
  29
  30 dnl
  31 dnl Initialize the rest of the library configury.  At this point we have
  32 dnl variables like $host.
  33 dnl
  34 dnl Sets:
  35 dnl  gcc_version          (x.y.z format)
  36 dnl  SUBDIRS
  37 dnl Substs:
  38 dnl  glibcxx_builddir     (absolute path)
  39 dnl  glibcxx_srcdir       (absolute path)
  40 dnl  toplevel_srcdir      (absolute path)
  41 dnl  with_cross_host
  42 dnl  with_newlib
  43 dnl  with_target_subdir
  44 dnl plus
  45 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  46 dnl  - default settings for all AM_CONFITIONAL test variables
  47 dnl  - lots of tools, like CC and CXX
  48 dnl
  49 AC_DEFUN([GLIBCXX_CONFIGURE], [
  50   # Keep these sync'd with the list in Makefile.am.  The first provides an
  51   # expandable list at autoconf time; the second provides an expandable list
  52   # (i.e., shell variable) at configure time.
  53   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  54   SUBDIRS='glibcxx_SUBDIRS'
  55
  56   # These need to be absolute paths, yet at the same time need to
  57   # canonicalize only relative paths, because then amd will not unmount
  58   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  59   glibcxx_builddir=`${PWDCMD-pwd}`
  60   case $srcdir in
  61     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  62     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  63   esac
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_srcdir)
  68
  69   # We use these options to decide which functions to include.  They are
  70   # set from the top level.
  71   AC_ARG_WITH([target-subdir],
  72     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  73                    [configuring in a subdirectory]))
  74
  75   AC_ARG_WITH([cross-host],
  76     AC_HELP_STRING([--with-cross-host=HOST],
  77                    [configuring with a cross compiler]))
  78
  79   AC_ARG_WITH([newlib],
  80     AC_HELP_STRING([--with-newlib],
  81                    [assume newlib as a system C library]))
  82
  83   # We're almost certainly being configured before anything else which uses
  84   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  85   # we not cache the value of CXX that we "discover" here, because it's set
  86   # to something unique for us and libjava.  Other target libraries need to
  87   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  88   # process by sneakily renaming the cache variable.  This also lets us debug
  89   # the value of "our" CXX in postmortems.
  90   #
  91   # We must also force CXX to /not/ be a precious variable, otherwise the
  92   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
  93   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
  94   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
  95   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
  96   #
  97   # -fno-builtin must be present here so that a non-conflicting form of
  98   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  99
 100   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103   save_CXXFLAGS="$CXXFLAGS"
 104   CXXFLAGS="$CXXFLAGS -fno-builtin"
 105   AC_PROG_CC
 106   AC_PROG_CXX
 107   CXXFLAGS="$save_CXXFLAGS"
 108   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109   AC_SUBST(CFLAGS)
 110   AC_SUBST(CXXFLAGS)
 111
 112   # For directory versioning (e.g., headers) and other variables.
 113   AC_MSG_CHECKING([for GCC version number])
 114   gcc_version=`$CXX -dumpversion`
 115   AC_MSG_RESULT($gcc_version)
 116
 117   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 118   # available).  Uncomment the next line to force a particular method.
 119   AC_PROG_LN_S
 120   #LN_S='cp -p'
 121
 122   AC_CHECK_TOOL(AS, as)
 123   AC_CHECK_TOOL(AR, ar)
 124   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 125
 126   AM_MAINTAINER_MODE
 127
 128   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 129   # which are themselves conditionally expanded.
 130   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 131   ## other macros from doing the same.  This should be automated.)  -pme
 132   need_libmath=no
 133   enable_wchar_t=no
 134   #enable_libstdcxx_debug=no
 135   #enable_libstdcxx_pch=no
 136   #enable_cheaders=c
 137   #c_compatibility=no
 138   #enable_abi_check=no
 139   #enable_symvers=no
 140   #enable_hosted_libstdcxx=yes
 141
 142   # Find platform-specific directories containing configuration info.
 143   # Also possibly modify flags used elsewhere, as needed by the platform.
 144   GLIBCXX_CHECK_HOST
 145 ])
 146
 147
 148 m4_include([linkage.m4])
 149 m4_include([../config/no-executables.m4])
 150
 151
 152 dnl
 153 dnl Tests for newer compiler features, or features that are present in newer
 154 dnl compiler versions but not older compiler versions still in use, should
 155 dnl be placed here.
 156 dnl
 157 dnl Defines:
 158 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 159 dnl   new inlining code or the new system_header pragma will die on -Werror.
 160 dnl   Leave it out by default and use maint-mode to use it.
 161 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 162 dnl   compiler supports it and the user has not requested debug mode.
 163 dnl
 164 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 165   # All these tests are for C++; save the language and the compiler flags.
 166   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 167   # found in GLIBCXX_CONFIGURE.
 168   AC_LANG_SAVE
 169   AC_LANG_CPLUSPLUS
 170   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 171   ac_save_CXXFLAGS="$CXXFLAGS"
 172
 173   # Check for maintainer-mode bits.
 174   if test x"$USE_MAINTAINER_MODE" = xno; then
 175     WERROR=''
 176   else
 177     WERROR='-Werror'
 178   fi
 179
 180   # Check for -ffunction-sections -fdata-sections
 181   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 182   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 183   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 184   if test "$ac_test_CXXFLAGS" = set; then
 185     CXXFLAGS="$ac_save_CXXFLAGS"
 186   else
 187     # this is the suspicious part
 188     CXXFLAGS=''
 189   fi
 190   if test x"$ac_fdsections" = x"yes"; then
 191     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 192   fi
 193   AC_MSG_RESULT($ac_fdsections)
 194
 195   AC_LANG_RESTORE
 196   AC_SUBST(WERROR)
 197   AC_SUBST(SECTION_FLAGS)
 198 ])
 199
 200
 201 dnl
 202 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 203 dnl the native linker is in use, all variables will be defined to something
 204 dnl safe (like an empty string).
 205 dnl
 206 dnl Defines:
 207 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 208 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 209 dnl  LD (as a side effect of testing)
 210 dnl Sets:
 211 dnl  with_gnu_ld
 212 dnl  glibcxx_gnu_ld_version (possibly)
 213 dnl
 214 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 215 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 216 dnl
 217 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 218   # If we're not using GNU ld, then there's no point in even trying these
 219   # tests.  Check for that first.  We should have already tested for gld
 220   # by now (in libtool), but require it now just to be safe...
 221   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 222   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 223   AC_REQUIRE([AC_PROG_LD])
 224   AC_REQUIRE([AC_PROG_AWK])
 225
 226   # The name set by libtool depends on the version of libtool.  Shame on us
 227   # for depending on an impl detail, but c'est la vie.  Older versions used
 228   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 229   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 230   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 231   # set (hence we're using an older libtool), then set it.
 232   if test x${with_gnu_ld+set} != xset; then
 233     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 234       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 235       with_gnu_ld=no
 236     else
 237       with_gnu_ld=$ac_cv_prog_gnu_ld
 238     fi
 239   fi
 240
 241   # Start by getting the version number.  I think the libtool test already
 242   # does some of this, but throws away the result.
 243   changequote(,)
 244   ldver=`$LD --version 2>/dev/null | head -1 | \
 245          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 246   changequote([,])
 247   glibcxx_gnu_ld_version=`echo $ldver | \
 248          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 249
 250   # Set --gc-sections.
 251   if test "$with_gnu_ld" = "notbroken"; then
 252     # GNU ld it is!  Joy and bunny rabbits!
 253
 254     # All these tests are for C++; save the language and the compiler flags.
 255     # Need to do this so that g++ won't try to link in libstdc++
 256     ac_test_CFLAGS="${CFLAGS+set}"
 257     ac_save_CFLAGS="$CFLAGS"
 258     CFLAGS='-x c++  -Wl,--gc-sections'
 259
 260     # Check for -Wl,--gc-sections
 261     # XXX This test is broken at the moment, as symbols required for linking
 262     # are now in libsupc++ (not built yet).  In addition, this test has
 263     # cored on solaris in the past.  In addition, --gc-sections doesn't
 264     # really work at the moment (keeps on discarding used sections, first
 265     # .eh_frame and now some of the glibc sections for iconv).
 266     # Bzzzzt.  Thanks for playing, maybe next time.
 267     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 268     AC_TRY_RUN([
 269      int main(void)
 270      {
 271        try { throw 1; }
 272        catch (...) { };
 273        return 0;
 274      }
 275     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 276     if test "$ac_test_CFLAGS" = set; then
 277       CFLAGS="$ac_save_CFLAGS"
 278     else
 279       # this is the suspicious part
 280       CFLAGS=''
 281     fi
 282     if test "$ac_sectionLDflags" = "yes"; then
 283       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 284     fi
 285     AC_MSG_RESULT($ac_sectionLDflags)
 286   fi
 287
 288   # Set linker optimization flags.
 289   if test x"$with_gnu_ld" = x"yes"; then
 290     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 291   fi
 292
 293   AC_SUBST(SECTION_LDFLAGS)
 294   AC_SUBST(OPT_LDFLAGS)
 295 ])
 296
 297
 298 dnl
 299 dnl Check to see if this target can enable the wchar_t parts.
 300 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 301 dnl must have been previously checked.)  By default, wide characters are
 302 dnl disabled.
 303 dnl
 304 dnl Defines:
 305 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 306 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 307 dnl Substs:
 308 dnl  LIBICONV to a -l string containing the iconv library, if needed.
 309 dnl
 310 AC_DEFUN([GLIBCXX_CHECK_WCHAR_T_SUPPORT], [
 311   # Test wchar.h for mbstate_t, which is needed for char_traits and
 312   # others even if wchar_t support is not on.
 313   AC_MSG_CHECKING([for mbstate_t])
 314   AC_TRY_COMPILE([#include <wchar.h>],
 315   [mbstate_t teststate;],
 316   have_mbstate_t=yes, have_mbstate_t=no)
 317   AC_MSG_RESULT($have_mbstate_t)
 318   if test x"$have_mbstate_t" = xyes; then
 319     AC_DEFINE(HAVE_MBSTATE_T)
 320   fi
 321
 322   # Sanity check for existence of ISO C99 headers for extended encoding.
 323   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 324   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 325
 326   # Only continue checking if the ISO C99 headers exist and support is on.
 327   if test x"$ac_has_wchar_h" = xyes &&
 328      test x"$ac_has_wctype_h" = xyes &&
 329      test x"$enable_c_mbchar" != xno; then
 330
 331     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 332     # numeric_limits can instantiate type_traits<wchar_t>
 333     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 334     AC_TRY_COMPILE([#include <wchar.h>],
 335     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 336     has_wchar_minmax=yes, has_wchar_minmax=no)
 337     AC_MSG_RESULT($has_wchar_minmax)
 338
 339     # Test wchar.h for WEOF, which is what we use to determine whether
 340     # to specialize for char_traits<wchar_t> or not.
 341     AC_MSG_CHECKING([for WEOF])
 342     AC_TRY_COMPILE([
 343       #include <wchar.h>
 344       #include <stddef.h>],
 345     [wint_t i = WEOF;],
 346     has_weof=yes, has_weof=no)
 347     AC_MSG_RESULT($has_weof)
 348
 349     # Tests for wide character functions used in char_traits<wchar_t>.
 350     ac_wfuncs=yes
 351     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 352     [],[ac_wfuncs=no])
 353
 354     # Checks for names injected into std:: by the c_std headers.
 355     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 356     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 357     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 358     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 359     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 360     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 361     [],[ac_wfuncs=no])
 362
 363     # Checks for wide character functions that are not required
 364     # for basic wchar_t support.  Don't disable support if they are missing.
 365     # Injection of these is wrapped with guard macros.
 366     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 367
 368     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 369     if test x"$has_weof" = xyes &&
 370        test x"$has_wchar_minmax" = xyes &&
 371        test x"$ac_wfuncs" = xyes;
 372     then
 373       ac_isoC99_wchar_t=yes
 374     else
 375       ac_isoC99_wchar_t=no
 376     fi
 377     AC_MSG_RESULT($ac_isoC99_wchar_t)
 378
 379     # Use iconv for wchar_t to char conversions. As such, check for
 380     # X/Open Portability Guide, version 2 features (XPG2).
 381     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 382     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 383
 384     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 385     AC_CHECK_LIB(iconv, iconv, LIBICONV="-liconv")
 386     ac_save_LIBS="$LIBS"
 387     LIBS="$LIBS $LIBICONV"
 388     AC_SUBST(LIBICONV)
 389
 390     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 391     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 392
 393     LIBS="$ac_save_LIBS"
 394
 395     AC_MSG_CHECKING([for XPG2 wchar_t support])
 396     if test x"$ac_has_iconv_h" = xyes &&
 397        test x"$ac_has_langinfo_h" = xyes &&
 398        test x"$ac_XPG2funcs" = xyes;
 399     then
 400       ac_XPG2_wchar_t=yes
 401     else
 402       ac_XPG2_wchar_t=no
 403     fi
 404     AC_MSG_RESULT($ac_XPG2_wchar_t)
 405
 406     # At the moment, only enable wchar_t specializations if all the
 407     # above support is present.
 408     if test x"$ac_isoC99_wchar_t" = xyes &&
 409        test x"$ac_XPG2_wchar_t" = xyes;
 410     then
 411       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 412       enable_wchar_t=yes
 413     fi
 414   fi
 415   AC_MSG_CHECKING([for enabled wchar_t specializations])
 416   AC_MSG_RESULT($enable_wchar_t)
 417 ])
 418
 419
 420 dnl
 421 dnl Check for headers for, and arguments to, the setrlimit() function.
 422 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 423 dnl
 424 dnl Defines:
 425 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 426 dnl  various HAVE_LIMIT_* for individual limit names
 427 dnl
 428 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 429   AC_TRY_COMPILE(
 430     [#include <unistd.h>
 431      #include <sys/time.h>
 432      #include <sys/resource.h>
 433     ],
 434     [ int f = RLIMIT_$1 ; ],
 435     [glibcxx_mresult=1], [glibcxx_mresult=0])
 436   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 437                      [Only used in build directory testsuite_hooks.h.])
 438 ])
 439
 440 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 441   setrlimit_have_headers=yes
 442   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 443                    [],
 444                    [setrlimit_have_headers=no])
 445   # If don't have the headers, then we can't run the tests now, and we
 446   # won't be seeing any of these during testsuite compilation.
 447   if test $setrlimit_have_headers = yes; then
 448     # Can't do these in a loop, else the resulting syntax is wrong.
 449     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 450     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 451     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 452     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 453     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 454
 455     # Check for rlimit, setrlimit.
 456     AC_CACHE_VAL(ac_setrlimit, [
 457       AC_TRY_COMPILE(
 458         [#include <unistd.h>
 459          #include <sys/time.h>
 460          #include <sys/resource.h>
 461         ],
 462         [struct rlimit r;
 463          setrlimit(0, &r);],
 464         [ac_setrlimit=yes], [ac_setrlimit=no])
 465     ])
 466   fi
 467
 468   AC_MSG_CHECKING([for testsuite resource limits support])
 469   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 470     ac_res_limits=yes
 471     AC_DEFINE(_GLIBCXX_RES_LIMITS)
 472   else
 473     ac_res_limits=no
 474   fi
 475   AC_MSG_RESULT($ac_res_limits)
 476 ])
 477
 478
 479 dnl
 480 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 481 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 482 dnl
 483 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 484   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 485     AC_TRY_LINK(
 486       [#include <sys/stat.h>],
 487       [struct stat buffer;
 488        fstat(0, &buffer);
 489        S_ISREG(buffer.st_mode);],
 490       [glibcxx_cv_S_ISREG=yes],
 491       [glibcxx_cv_S_ISREG=no])
 492   ])
 493   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 494     AC_TRY_LINK(
 495       [#include <sys/stat.h>],
 496       [struct stat buffer;
 497        fstat(0, &buffer);
 498        S_IFREG & buffer.st_mode;],
 499       [glibcxx_cv_S_IFREG=yes],
 500       [glibcxx_cv_S_IFREG=no])
 501   ])
 502   if test $glibcxx_cv_S_ISREG = yes; then
 503     AC_DEFINE(HAVE_S_ISREG)
 504   elif test $glibcxx_cv_S_IFREG = yes; then
 505     AC_DEFINE(HAVE_S_IFREG)
 506   fi
 507 ])
 508
 509
 510 dnl
 511 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 512 dnl
 513 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 514   AC_CACHE_VAL(glibcxx_cv_POLL, [
 515     AC_TRY_LINK(
 516       [#include <poll.h>],
 517       [struct pollfd pfd[1];
 518        pfd[0].events = POLLIN;
 519        poll(pfd, 1, 0);],
 520       [glibcxx_cv_POLL=yes],
 521       [glibcxx_cv_POLL=no])
 522   ])
 523   if test $glibcxx_cv_POLL = yes; then
 524     AC_DEFINE(HAVE_POLL)
 525   fi
 526 ])
 527
 528
 529 dnl
 530 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 531 dnl
 532 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 533   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 534     AC_TRY_LINK(
 535       [#include <sys/uio.h>],
 536       [struct iovec iov[2];
 537        writev(0, iov, 0);],
 538       [glibcxx_cv_WRITEV=yes],
 539       [glibcxx_cv_WRITEV=no])
 540   ])
 541   if test $glibcxx_cv_WRITEV = yes; then
 542     AC_DEFINE(HAVE_WRITEV)
 543   fi
 544 ])
 545
 546
 547 dnl
 548 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 549 dnl
 550 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 551   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 552     AC_TRY_COMPILE(
 553       [#include <stdint.h>],
 554       [int64_t var;],
 555       [glibcxx_cv_INT64_T=yes],
 556       [glibcxx_cv_INT64_T=no])
 557   ])
 558   if test $glibcxx_cv_INT64_T = yes; then
 559     AC_DEFINE(HAVE_INT64_T)
 560   fi
 561 ])
 562
 563
 564 dnl
 565 dnl Check whether LFS support is available.
 566 dnl
 567 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 568   AC_LANG_SAVE
 569   AC_LANG_CPLUSPLUS
 570   ac_save_CXXFLAGS="$CXXFLAGS"
 571   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 572   AC_CACHE_VAL(glibcxx_cv_LFS, [
 573     AC_TRY_LINK(
 574       [#include <unistd.h>
 575        #include <stdio.h>
 576        #include <sys/stat.h>
 577       ],
 578       [FILE* fp;
 579        fopen64("t", "w");
 580        fseeko64(fp, 0, SEEK_CUR);
 581        ftello64(fp);
 582        lseek64(1, 0, SEEK_CUR);
 583        struct stat64 buf;
 584        fstat64(1, &buf);],
 585       [glibcxx_cv_LFS=yes],
 586       [glibcxx_cv_LFS=no])
 587   ])
 588   if test $glibcxx_cv_LFS = yes; then
 589     AC_DEFINE(_GLIBCXX_USE_LFS)
 590   fi
 591   CXXFLAGS="$ac_save_CXXFLAGS"
 592   AC_LANG_RESTORE
 593 ])
 594
 595
 596 dnl
 597 dnl Check for whether a fully dynamic basic_string implementation should
 598 dnl be turned on, that does not put empty objects in per-process static
 599 dnl memory (mostly useful together with shared memory allocators, see PR
 600 dnl libstdc++/16612 for details).
 601 dnl
 602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING
 603 dnl --disable-fully-dynamic-string leaves _GLIBCXX_FULLY_DYNAMIC_STRING undefined
 604 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 605 dnl       Where DEFAULT is either `yes' or `no'.
 606 dnl
 607 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 608   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 609   if test $enable_fully_dynamic_string = yes; then
 610     AC_DEFINE(_GLIBCXX_FULLY_DYNAMIC_STRING)
 611   fi
 612 ])
 613
 614
 615 dnl
 616 dnl Does any necessary configuration of the testsuite directory.  Generates
 617 dnl the testsuite_hooks.h header.
 618 dnl
 619 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 620 dnl
 621 dnl Sets:
 622 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 623 dnl  GLIBCXX_TEST_WCHAR_T
 624 dnl  GLIBCXX_TEST_THREAD
 625 dnl Substs:
 626 dnl  baseline_dir
 627 dnl
 628 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 629   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 630     # Do checks for resource limit functions.
 631     GLIBCXX_CHECK_SETRLIMIT
 632
 633     # Look for setenv, so that extended locale tests can be performed.
 634     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 635
 636     if test $enable_symvers = no; then
 637       enable_abi_check=no
 638     else
 639       case "$host" in
 640         *-*-cygwin*)
 641           enable_abi_check=no ;;
 642         *)
 643           enable_abi_check=yes ;;
 644       esac
 645     fi
 646   else
 647     # Only build this as native, since automake does not understand
 648     # CXX_FOR_BUILD.
 649     enable_abi_check=no
 650   fi
 651
 652   # Export file names for ABI checking.
 653   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 654   AC_SUBST(baseline_dir)
 655
 656   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 657   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_THREAD, test $enable_thread = yes)
 658   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 659 ])
 660
 661
 662 dnl
 663 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 664 dnl
 665 dnl Substs:
 666 dnl  GLIBCXX_INCLUDES
 667 dnl  TOPLEVEL_INCLUDES
 668 dnl
 669 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 670   # Used for every C++ compile we perform.
 671   GLIBCXX_INCLUDES="\
 672 -I$glibcxx_builddir/include/$host_alias \
 673 -I$glibcxx_builddir/include \
 674 -I$glibcxx_srcdir/libsupc++"
 675
 676   # For Canadian crosses, pick this up too.
 677   if test $CANADIAN = yes; then
 678     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 679   fi
 680
 681   # Stuff in the actual top level.  Currently only used by libsupc++ to
 682   # get unwind* headers from the gcc dir.
 683   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 684   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 685
 686   # Now, export this to all the little Makefiles....
 687   AC_SUBST(GLIBCXX_INCLUDES)
 688   AC_SUBST(TOPLEVEL_INCLUDES)
 689 ])
 690
 691
 692 dnl
 693 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 694 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 695 dnl
 696 dnl Substs:
 697 dnl  OPTIMIZE_CXXFLAGS
 698 dnl  WARN_FLAGS
 699 dnl
 700 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 701   # Optimization flags that are probably a good idea for thrill-seekers. Just
 702   # uncomment the lines below and make, everything else is ready to go...
 703   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 704   OPTIMIZE_CXXFLAGS=
 705   AC_SUBST(OPTIMIZE_CXXFLAGS)
 706
 707   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 708   AC_SUBST(WARN_FLAGS)
 709 ])
 710
 711
 712 dnl
 713 dnl All installation directory information is determined here.
 714 dnl
 715 dnl Substs:
 716 dnl  gxx_install_dir
 717 dnl  glibcxx_prefixdir
 718 dnl  glibcxx_toolexecdir
 719 dnl  glibcxx_toolexeclibdir
 720 dnl
 721 dnl Assumes cross_compiling bits already done, and with_cross_host in
 722 dnl particular.
 723 dnl
 724 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 725   glibcxx_toolexecdir=no
 726   glibcxx_toolexeclibdir=no
 727   glibcxx_prefixdir=$prefix
 728
 729   AC_MSG_CHECKING([for gxx-include-dir])
 730   AC_ARG_WITH([gxx-include-dir],
 731     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 732                    [installation directory for include files]),
 733     [case "$withval" in
 734       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 735       no)  gxx_include_dir=no ;;
 736       *)   gxx_include_dir=$withval ;;
 737      esac],
 738     [gxx_include_dir=no])
 739   AC_MSG_RESULT($gxx_include_dir)
 740
 741   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 742   AC_ARG_ENABLE([version-specific-runtime-libs],
 743     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 744                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 745     [case "$enableval" in
 746       yes) version_specific_libs=yes ;;
 747       no)  version_specific_libs=no ;;
 748       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 749      esac],
 750     [version_specific_libs=no])
 751   AC_MSG_RESULT($version_specific_libs)
 752
 753   # Default case for install directory for include files.
 754   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 755     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 756   fi
 757
 758   # Version-specific runtime libs processing.
 759   if test $version_specific_libs = yes; then
 760     # Need the gcc compiler version to know where to install libraries
 761     # and header files if --enable-version-specific-runtime-libs option
 762     # is selected.  FIXME: these variables are misnamed, there are
 763     # no executables installed in _toolexecdir or _toolexeclibdir.
 764     if test x"$gxx_include_dir" = x"no"; then
 765       gxx_include_dir='${libdir}/gcc/${host_alias}/'$gcc_version/include/c++
 766     fi
 767     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 768     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 769   fi
 770
 771   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 772   # Install a library built with a cross compiler in tooldir, not libdir.
 773   if test x"$glibcxx_toolexecdir" = x"no"; then
 774     if test -n "$with_cross_host" &&
 775        test x"$with_cross_host" != x"no"; then
 776       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 777       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 778     else
 779       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 780       glibcxx_toolexeclibdir='${libdir}'
 781     fi
 782     multi_os_directory=`$CXX -print-multi-os-directory`
 783     case $multi_os_directory in
 784       .) ;; # Avoid trailing /.
 785       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 786     esac
 787   fi
 788
 789   AC_MSG_CHECKING([for install location])
 790   AC_MSG_RESULT($gxx_include_dir)
 791
 792   AC_SUBST(glibcxx_prefixdir)
 793   AC_SUBST(gxx_include_dir)
 794   AC_SUBST(glibcxx_toolexecdir)
 795   AC_SUBST(glibcxx_toolexeclibdir)
 796 ])
 797
 798
 799 dnl
 800 dnl GLIBCXX_ENABLE
 801 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 802 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 803 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 804 dnl
 805 dnl See docs/html/17_intro/configury.html#enable for documentation.
 806 dnl
 807 m4_define([GLIBCXX_ENABLE],[dnl
 808 m4_define([_g_switch],[--enable-$1])dnl
 809 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 810  AC_ARG_ENABLE($1,_g_help,
 811   m4_bmatch([$5],
 812    [^permit ],
 813      [[
 814       case "$enableval" in
 815        m4_bpatsubst([$5],[permit ])) ;;
 816        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 817           dnl Idea for future:  generate a URL pointing to
 818           dnl "onlinedocs/configopts.html#whatever"
 819       esac
 820      ]],
 821    [^$],
 822      [[
 823       case "$enableval" in
 824        yes|no) ;;
 825        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 826       esac
 827      ]],
 828    [[$5]]),
 829   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 830 m4_undefine([_g_switch])dnl
 831 m4_undefine([_g_help])dnl
 832 ])
 833
 834
 835 dnl
 836 dnl Check for ISO/IEC 9899:1999 "C99" support.
 837 dnl
 838 dnl --enable-c99 defines _GLIBCXX_USE_C99
 839 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 840 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 841 dnl       Where DEFAULT is either `yes' or `no'.
 842 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 843 dnl
 844 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 845   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 846
 847   AC_LANG_SAVE
 848   AC_LANG_CPLUSPLUS
 849
 850   # Check for the existence of <math.h> functions used if C99 is enabled.
 851   ac_c99_math=yes;
 852   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 853   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 856   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 858   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 859   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 860   AC_TRY_COMPILE([#include <math.h>],
 861                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 862   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 863   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 864   AC_TRY_COMPILE([#include <math.h>],
 865                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 866   AC_TRY_COMPILE([#include <math.h>],
 867                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 868   AC_MSG_RESULT($ac_c99_math)
 869
 870   if test x"$ac_c99_math" = x"yes"; then
 871     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
 872   fi
 873
 874   # Check for the existence of <math.h> complex functions.
 875   # This is necessary even though libstdc++ uses the builtin versions
 876   # of these functions, because if the builtin cannot be used, a reference
 877   # to the library function is emitted.
 878   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 879   ac_c99_complex=no;
 880   if test x"$ac_has_complex_h" = x"yes"; then
 881     ac_c99_complex=yes;
 882     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 883     AC_TRY_COMPILE([#include <complex.h>],
 884                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 885                     cabsf(tmp);],, [ac_c99_complex=no])
 886     AC_TRY_COMPILE([#include <complex.h>],
 887                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 888                     cabs(tmp);],, [ac_c99_complex=no])
 889     AC_TRY_COMPILE([#include <complex.h>],
 890                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 891                     cabsl(tmp);],, [ac_c99_complex=no])
 892     AC_TRY_COMPILE([#include <complex.h>],
 893                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 894                     cargf(tmp);],, [ac_c99_complex=no])
 895     AC_TRY_COMPILE([#include <complex.h>],
 896                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 897                     carg(tmp);],, [ac_c99_complex=no])
 898     AC_TRY_COMPILE([#include <complex.h>],
 899                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 900                     cargl(tmp);],, [ac_c99_complex=no])
 901     AC_TRY_COMPILE([#include <complex.h>],
 902                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 903                     ccosf(tmp);],, [ac_c99_complex=no])
 904     AC_TRY_COMPILE([#include <complex.h>],
 905                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 906                     ccos(tmp);],, [ac_c99_complex=no])
 907     AC_TRY_COMPILE([#include <complex.h>],
 908                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 909                     ccosl(tmp);],, [ac_c99_complex=no])
 910     AC_TRY_COMPILE([#include <complex.h>],
 911                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 912                     ccoshf(tmp);],, [ac_c99_complex=no])
 913     AC_TRY_COMPILE([#include <complex.h>],
 914                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 915                     ccosh(tmp);],, [ac_c99_complex=no])
 916     AC_TRY_COMPILE([#include <complex.h>],
 917                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 918                     ccoshl(tmp);],, [ac_c99_complex=no])
 919     AC_TRY_COMPILE([#include <complex.h>],
 920                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 921                     cexpf(tmp);],, [ac_c99_complex=no])
 922     AC_TRY_COMPILE([#include <complex.h>],
 923                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 924                     cexp(tmp);],, [ac_c99_complex=no])
 925     AC_TRY_COMPILE([#include <complex.h>],
 926                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 927                     cexpl(tmp);],, [ac_c99_complex=no])
 928     AC_TRY_COMPILE([#include <complex.h>],
 929                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 930                     csinf(tmp);],, [ac_c99_complex=no])
 931     AC_TRY_COMPILE([#include <complex.h>],
 932                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 933                     csin(tmp);],, [ac_c99_complex=no])
 934     AC_TRY_COMPILE([#include <complex.h>],
 935                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 936                     csinl(tmp);],, [ac_c99_complex=no])
 937     AC_TRY_COMPILE([#include <complex.h>],
 938                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 939                     csinhf(tmp);],, [ac_c99_complex=no])
 940     AC_TRY_COMPILE([#include <complex.h>],
 941                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 942                     csinh(tmp);],, [ac_c99_complex=no])
 943     AC_TRY_COMPILE([#include <complex.h>],
 944                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 945                     csinhl(tmp);],, [ac_c99_complex=no])
 946     AC_TRY_COMPILE([#include <complex.h>],
 947                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 948                     csqrtf(tmp);],, [ac_c99_complex=no])
 949     AC_TRY_COMPILE([#include <complex.h>],
 950                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 951                     csqrt(tmp);],, [ac_c99_complex=no])
 952     AC_TRY_COMPILE([#include <complex.h>],
 953                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 954                     csqrtl(tmp);],, [ac_c99_complex=no])
 955     AC_TRY_COMPILE([#include <complex.h>],
 956                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 957                     ctanf(tmp);],, [ac_c99_complex=no])
 958     AC_TRY_COMPILE([#include <complex.h>],
 959                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 960                     ctan(tmp);],, [ac_c99_complex=no])
 961     AC_TRY_COMPILE([#include <complex.h>],
 962                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 963                     ctanl(tmp);],, [ac_c99_complex=no])
 964     AC_TRY_COMPILE([#include <complex.h>],
 965                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 966                     ctanhf(tmp);],, [ac_c99_complex=no])
 967     AC_TRY_COMPILE([#include <complex.h>],
 968                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 969                     ctanh(tmp);],, [ac_c99_complex=no])
 970     AC_TRY_COMPILE([#include <complex.h>],
 971                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 972                     ctanhl(tmp);],, [ac_c99_complex=no])
 973     AC_TRY_COMPILE([#include <complex.h>],
 974                    [typedef __complex__ float _ComplexT; _ComplexT tmp;
 975                     cpowf(tmp, tmp);],, [ac_c99_complex=no])
 976     AC_TRY_COMPILE([#include <complex.h>],
 977                    [typedef __complex__ double _ComplexT; _ComplexT tmp;
 978                     cpow(tmp, tmp);],, [ac_c99_complex=no])
 979     AC_TRY_COMPILE([#include <complex.h>],
 980                    [typedef __complex__ long double _ComplexT; _ComplexT tmp;
 981                     cpowl(tmp, tmp);],, [ac_c99_complex=no])
 982   fi
 983   AC_MSG_RESULT($ac_c99_complex)
 984
 985   if test x"$ac_c99_complex" = x"yes"; then
 986     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_MATH)
 987   fi
 988
 989   # Check for the existence in <stdio.h> of vscanf, et. al.
 990   ac_c99_stdio=yes;
 991   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 992   AC_TRY_COMPILE([#include <stdio.h>],
 993                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 994   AC_TRY_COMPILE([#include <stdio.h>
 995                   #include <stdarg.h>
 996                   void foo(char* fmt, ...)
 997                   {va_list args; va_start(args, fmt);
 998                   vfscanf(stderr, "%i", args);}],
 999                   [],, [ac_c99_stdio=no])
1000   AC_TRY_COMPILE([#include <stdio.h>
1001                   #include <stdarg.h>
1002                   void foo(char* fmt, ...)
1003                   {va_list args; va_start(args, fmt);
1004                   vscanf("%i", args);}],
1005                   [],, [ac_c99_stdio=no])
1006   AC_TRY_COMPILE([#include <stdio.h>
1007                   #include <stdarg.h>
1008                   void foo(char* fmt, ...)
1009                   {va_list args; va_start(args, fmt);
1010                   vsnprintf(fmt, 0, "%i", args);}],
1011                   [],, [ac_c99_stdio=no])
1012   AC_TRY_COMPILE([#include <stdio.h>
1013                   #include <stdarg.h>
1014                   void foo(char* fmt, ...)
1015                   {va_list args; va_start(args, fmt);
1016                   vsscanf(fmt, "%i", args);}],
1017                   [],, [ac_c99_stdio=no])
1018   AC_MSG_RESULT($ac_c99_stdio)
1019
1020   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1021   ac_c99_stdlib=yes;
1022   AC_MSG_CHECKING([for lldiv_t declaration])
1023   AC_CACHE_VAL(ac_c99_lldiv_t, [
1024   AC_TRY_COMPILE([#include <stdlib.h>],
1025                    [ lldiv_t mydivt;],
1026                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1027   ])
1028   AC_MSG_RESULT($ac_c99_lldiv_t)
1029
1030   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1031   AC_TRY_COMPILE([#include <stdlib.h>],
1032                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1033   AC_TRY_COMPILE([#include <stdlib.h>],
1034                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1035   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1036   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1037   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1038   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1039   if test x"$ac_c99_lldiv_t" = x"no"; then
1040     ac_c99_stdlib=no;
1041   fi;
1042   AC_MSG_RESULT($ac_c99_stdlib)
1043
1044   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1045   # XXX the wchar.h checks should be rolled into the general C99 bits.
1046   ac_c99_wchar=yes;
1047   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1048   AC_TRY_COMPILE([#include <wchar.h>],
1049                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1050   AC_TRY_COMPILE([#include <wchar.h>],
1051                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1052   AC_TRY_COMPILE([#include <wchar.h>],
1053                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1054   AC_MSG_RESULT($ac_c99_wchar)
1055
1056   AC_MSG_CHECKING([for enabled ISO C99 support])
1057   if test x"$ac_c99_math" = x"no" ||
1058      test x"$ac_c99_stdio" = x"no" ||
1059      test x"$ac_c99_stdlib" = x"no" ||
1060      test x"$ac_c99_wchar" = x"no"; then
1061     enable_c99=no;
1062   fi;
1063   AC_MSG_RESULT($enable_c99)
1064
1065   if test x"$ac_99_math" = x"yes"; then
1066     AC_DEFINE(_GLIBCXX_USE_C99_MATH)
1067   fi
1068
1069   # Option parsed, now set things appropriately
1070   if test x"$enable_c99" = x"yes"; then
1071     AC_DEFINE(_GLIBCXX_USE_C99)
1072   fi
1073
1074   AC_LANG_RESTORE
1075 ])
1076
1077
1078 dnl
1079 dnl Check for what type of C headers to use.
1080 dnl
1081 dnl --enable-cheaders= [does stuff].
1082 dnl --disable-cheaders [does not do anything, really].
1083 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1084 dnl       Where DEFAULT is either `c' or `c_std'.
1085 dnl
1086 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1087   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
1088     [construct "C" headers for g++], [permit c|c_std])
1089   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1090
1091   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1092
1093   AC_SUBST(C_INCLUDE_DIR)
1094   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1095   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1096   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1097 ])
1098
1099
1100 dnl
1101 dnl Check for which locale library to use.  The choice is mapped to
1102 dnl a subdirectory of config/locale.
1103 dnl
1104 dnl Default is generic.
1105 dnl
1106 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1107   AC_MSG_CHECKING([for C locale to use])
1108   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
1109     [use MODEL for target locale package],
1110     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
1111
1112   # If they didn't use this option switch, or if they specified --enable
1113   # with no specific model, we'll have to look for one.  If they
1114   # specified --disable (???), do likewise.
1115   if test $enable_clocale = no || test $enable_clocale = yes; then
1116      enable_clocale=auto
1117   fi
1118
1119   # Either a known package, or "auto"
1120   enable_clocale_flag=$enable_clocale
1121
1122   # Probe for locale support if no specific model is specified.
1123   # Default to "generic".
1124   if test $enable_clocale_flag = auto; then
1125     case ${target_os} in
1126       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1127         AC_EGREP_CPP([_GLIBCXX_ok], [
1128         #include <features.h>
1129         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1130           _GLIBCXX_ok
1131         #endif
1132         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1133
1134         # Test for bugs early in glibc-2.2.x series
1135           if test $enable_clocale_flag = gnu; then
1136           AC_TRY_RUN([
1137           #define _GNU_SOURCE 1
1138           #include <locale.h>
1139           #include <string.h>
1140           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1141           extern __typeof(newlocale) __newlocale;
1142           extern __typeof(duplocale) __duplocale;
1143           extern __typeof(strcoll_l) __strcoll_l;
1144           #endif
1145           int main()
1146           {
1147               const char __one[] = "Äuglein Augmen";
1148               const char __two[] = "Äuglein";
1149               int i;
1150               int j;
1151               __locale_t        loc;
1152                __locale_t        loc_dup;
1153               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1154               loc_dup = __duplocale(loc);
1155               i = __strcoll_l(__one, __two, loc);
1156               j = __strcoll_l(__one, __two, loc_dup);
1157               return 0;
1158           }
1159           ],
1160           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1161           [enable_clocale_flag=generic])
1162           fi
1163
1164         # ... at some point put __strxfrm_l tests in as well.
1165         ;;
1166       darwin*)
1167         enable_clocale_flag=darwin
1168         ;;
1169       *)
1170         enable_clocale_flag=generic
1171         ;;
1172     esac
1173   fi
1174
1175   # Deal with gettext issues.  Default to not using it (=no) until we detect
1176   # support for it later.  Let the user turn it off via --e/d, but let that
1177   # default to on for easier handling.
1178   USE_NLS=no
1179   AC_ARG_ENABLE(nls,
1180     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1181     [],
1182     [enable_nls=yes])
1183
1184   # Set configure bits for specified locale package
1185   case ${enable_clocale_flag} in
1186     generic)
1187       AC_MSG_RESULT(generic)
1188
1189       CLOCALE_H=config/locale/generic/c_locale.h
1190       CLOCALE_CC=config/locale/generic/c_locale.cc
1191       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1192       CCOLLATE_CC=config/locale/generic/collate_members.cc
1193       CCTYPE_CC=config/locale/generic/ctype_members.cc
1194       CMESSAGES_H=config/locale/generic/messages_members.h
1195       CMESSAGES_CC=config/locale/generic/messages_members.cc
1196       CMONEY_CC=config/locale/generic/monetary_members.cc
1197       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1198       CTIME_H=config/locale/generic/time_members.h
1199       CTIME_CC=config/locale/generic/time_members.cc
1200       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1201       ;;
1202     darwin)
1203       AC_MSG_RESULT(darwin)
1204
1205       CLOCALE_H=config/locale/generic/c_locale.h
1206       CLOCALE_CC=config/locale/generic/c_locale.cc
1207       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1208       CCOLLATE_CC=config/locale/generic/collate_members.cc
1209       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1210       CMESSAGES_H=config/locale/generic/messages_members.h
1211       CMESSAGES_CC=config/locale/generic/messages_members.cc
1212       CMONEY_CC=config/locale/generic/monetary_members.cc
1213       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1214       CTIME_H=config/locale/generic/time_members.h
1215       CTIME_CC=config/locale/generic/time_members.cc
1216       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1217       ;;
1218
1219     gnu)
1220       AC_MSG_RESULT(gnu)
1221
1222       # Declare intention to use gettext, and add support for specific
1223       # languages.
1224       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1225       ALL_LINGUAS="de fr"
1226
1227       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1228       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1229       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1230         USE_NLS=yes
1231       fi
1232       # Export the build objects.
1233       for ling in $ALL_LINGUAS; do \
1234         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1235         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1236       done
1237       AC_SUBST(glibcxx_MOFILES)
1238       AC_SUBST(glibcxx_POFILES)
1239
1240       CLOCALE_H=config/locale/gnu/c_locale.h
1241       CLOCALE_CC=config/locale/gnu/c_locale.cc
1242       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1243       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1244       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1245       CMESSAGES_H=config/locale/gnu/messages_members.h
1246       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1247       CMONEY_CC=config/locale/gnu/monetary_members.cc
1248       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1249       CTIME_H=config/locale/gnu/time_members.h
1250       CTIME_CC=config/locale/gnu/time_members.cc
1251       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1252       ;;
1253     ieee_1003.1-2001)
1254       AC_MSG_RESULT(IEEE 1003.1)
1255
1256       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1257       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1258       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1259       CCOLLATE_CC=config/locale/generic/collate_members.cc
1260       CCTYPE_CC=config/locale/generic/ctype_members.cc
1261       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1262       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1263       CMONEY_CC=config/locale/generic/monetary_members.cc
1264       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1265       CTIME_H=config/locale/generic/time_members.h
1266       CTIME_CC=config/locale/generic/time_members.cc
1267       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1268       ;;
1269   esac
1270
1271   # This is where the testsuite looks for locale catalogs, using the
1272   # -DLOCALEDIR define during testsuite compilation.
1273   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1274   AC_SUBST(glibcxx_localedir)
1275
1276   # A standalone libintl (e.g., GNU libintl) may be in use.
1277   if test $USE_NLS = yes; then
1278     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1279     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1280   fi
1281   if test $USE_NLS = yes; then
1282     AC_DEFINE(_GLIBCXX_USE_NLS)
1283   fi
1284
1285   AC_SUBST(USE_NLS)
1286   AC_SUBST(CLOCALE_H)
1287   AC_SUBST(CMESSAGES_H)
1288   AC_SUBST(CCODECVT_CC)
1289   AC_SUBST(CCOLLATE_CC)
1290   AC_SUBST(CCTYPE_CC)
1291   AC_SUBST(CMESSAGES_CC)
1292   AC_SUBST(CMONEY_CC)
1293   AC_SUBST(CNUMERIC_CC)
1294   AC_SUBST(CTIME_H)
1295   AC_SUBST(CTIME_CC)
1296   AC_SUBST(CLOCALE_CC)
1297   AC_SUBST(CLOCALE_INTERNAL_H)
1298 ])
1299
1300
1301 dnl
1302 dnl Check for which std::allocator base class to use.  The choice is
1303 dnl mapped from a subdirectory of include/ext.
1304 dnl
1305 dnl Default is new.
1306 dnl
1307 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
1308   AC_MSG_CHECKING([for std::allocator base class to use])
1309   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[=KIND],
1310     [use KIND for target std::allocator base],
1311     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
1312
1313   # If they didn't use this option switch, or if they specified --enable
1314   # with no specific model, we'll have to look for one.  If they
1315   # specified --disable (???), do likewise.
1316   if test $enable_libstdcxx_allocator = no ||
1317      test $enable_libstdcxx_allocator = yes;
1318   then
1319      enable_libstdcxx_allocator=auto
1320   fi
1321
1322   # Either a known package, or "auto". Auto implies the default choice
1323   # for a particular platform.
1324   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
1325
1326   # Probe for host-specific support if no specific model is specified.
1327   # Default to "new".
1328   if test $enable_libstdcxx_allocator_flag = auto; then
1329     case ${target_os} in
1330       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1331         enable_libstdcxx_allocator_flag=mt
1332         ;;
1333       *)
1334         enable_libstdcxx_allocator_flag=new
1335         ;;
1336     esac
1337   fi
1338   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
1339
1340
1341   # Set configure bits for specified locale package
1342   case ${enable_libstdcxx_allocator_flag} in
1343     bitmap)
1344       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
1345       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
1346       ;;
1347     malloc)
1348       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
1349       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
1350       ;;
1351     mt)
1352       ALLOCATOR_H=config/allocator/mt_allocator_base.h
1353       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
1354       ;;
1355     new)
1356       ALLOCATOR_H=config/allocator/new_allocator_base.h
1357       ALLOCATOR_NAME=__gnu_cxx::new_allocator
1358       ;;
1359     pool)
1360       ALLOCATOR_H=config/allocator/pool_allocator_base.h
1361       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
1362       ;;
1363   esac
1364
1365   AC_SUBST(ALLOCATOR_H)
1366   AC_SUBST(ALLOCATOR_NAME)
1367 ])
1368
1369
1370 dnl
1371 dnl Check for whether the Boost-derived checks should be turned on.
1372 dnl
1373 dnl --enable-concept-checks turns them on.
1374 dnl --disable-concept-checks leaves them off.
1375 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1376 dnl       Where DEFAULT is either `yes' or `no'.
1377 dnl
1378 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
1379   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1380   if test $enable_concept_checks = yes; then
1381     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1382   fi
1383 ])
1384
1385
1386 dnl
1387 dnl Check for which I/O library to use:  stdio, or something specific.
1388 dnl
1389 dnl Default is stdio.
1390 dnl
1391 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
1392   AC_MSG_CHECKING([for underlying I/O to use])
1393   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1394     [use target-specific I/O package], [permit stdio])
1395
1396   # Now that libio has been removed, you can have any color you want as long
1397   # as it's black.  This is one big no-op until other packages are added, but
1398   # showing the framework never hurts.
1399   case ${enable_cstdio} in
1400     stdio)
1401       CSTDIO_H=config/io/c_io_stdio.h
1402       BASIC_FILE_H=config/io/basic_file_stdio.h
1403       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1404       AC_MSG_RESULT(stdio)
1405       ;;
1406   esac
1407
1408   AC_SUBST(CSTDIO_H)
1409   AC_SUBST(BASIC_FILE_H)
1410   AC_SUBST(BASIC_FILE_CC)
1411 ])
1412
1413
1414 dnl
1415 dnl Check for "unusual" flags to pass to the compiler while building.
1416 dnl
1417 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1418 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1419 dnl --disable-cxx-flags passes nothing.
1420 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1421 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1422 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1423 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1424 dnl       If "default flags" is an empty string, the effect is the same
1425 dnl       as --disable or --enable=no.
1426 dnl
1427 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
1428   AC_MSG_CHECKING([for extra compiler flags for building])
1429   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1430     [pass compiler FLAGS when building library],
1431     [case "x$enable_cxx_flags" in
1432       xno | x)   enable_cxx_flags= ;;
1433       x-*)       ;;
1434       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1435      esac])
1436
1437   # Run through flags (either default or command-line) and set anything
1438   # extra (e.g., #defines) that must accompany particular g++ options.
1439   if test -n "$enable_cxx_flags"; then
1440     for f in $enable_cxx_flags; do
1441       case "$f" in
1442         -fhonor-std)  ;;
1443         -*)  ;;
1444         *)   # and we're trying to pass /what/ exactly?
1445              AC_MSG_ERROR([compiler flags start with a -]) ;;
1446       esac
1447     done
1448   fi
1449
1450   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1451   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1452   AC_SUBST(EXTRA_CXX_FLAGS)
1453 ])
1454
1455
1456 dnl
1457 dnl Check for wide character support.  Has the same effect as the option
1458 dnl in gcc's configure, but in a form that autoconf can mess with.
1459 dnl
1460 dnl --enable-c-mbchar requests all the wchar_t stuff.
1461 dnl --disable-c-mbchar doesn't.
1462 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1463 dnl       Where DEFAULT is either `yes' or `no'.
1464 dnl
1465 AC_DEFUN([GLIBCXX_ENABLE_C_MBCHAR], [
1466   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1467   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1468 ])
1469
1470
1471 dnl
1472 dnl Check to see if debugging libraries are to be built.
1473 dnl
1474 dnl --enable-libstdcxx-debug
1475 dnl builds a separate set of debugging libraries in addition to the
1476 dnl normal (shared, static) libstdc++ binaries.
1477 dnl
1478 dnl --disable-libstdcxx-debug
1479 dnl builds only one (non-debug) version of libstdc++.
1480 dnl
1481 dnl --enable-libstdcxx-debug-flags=FLAGS
1482 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1483 dnl
1484 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1485 dnl       Where DEFAULT is either `yes' or `no'.
1486 dnl
1487 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
1488   AC_MSG_CHECKING([for additional debug build])
1489   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1490   AC_MSG_RESULT($enable_libstdcxx_debug)
1491   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1492 ])
1493
1494
1495 dnl
1496 dnl Check for explicit debug flags.
1497 dnl
1498 dnl --enable-libstdcxx-debug-flags='-O1'
1499 dnl is a general method for passing flags to be used when
1500 dnl building debug libraries with --enable-debug.
1501 dnl
1502 dnl --disable-libstdcxx-debug-flags does nothing.
1503 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1504 dnl       If "default flags" is an empty string, the effect is the same
1505 dnl       as --disable or --enable=no.
1506 dnl
1507 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
1508   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1509     [pass compiler FLAGS when building debug library],
1510     [case "x$enable_libstdcxx_debug_flags" in
1511       xno | x)    enable_libstdcxx_debug_flags= ;;
1512       x-*)        ;;
1513       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1514      esac])
1515
1516   # Option parsed, now set things appropriately
1517   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1518   AC_SUBST(DEBUG_FLAGS)
1519
1520   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1521 ])
1522
1523
1524 dnl
1525 dnl Check if the user only wants a freestanding library implementation.
1526 dnl
1527 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1528 dnl installing only the headers required by [17.4.1.3] and the language
1529 dnl support library.  More than that will be built (to keep the Makefiles
1530 dnl conveniently clean), but not installed.
1531 dnl
1532 dnl Sets:
1533 dnl  is_hosted  (yes/no)
1534 dnl
1535 dnl Defines:
1536 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1537 dnl
1538 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
1539   AC_ARG_ENABLE([hosted-libstdcxx],
1540     AC_HELP_STRING([--disable-hosted-libstdcxx],
1541                    [only build freestanding C++ runtime support]),,
1542     [case "$host" in
1543         arm*-*-symbianelf*)
1544             enable_hosted_libstdcxx=no
1545             ;;
1546         *)
1547             enable_hosted_libstdcxx=yes
1548             ;;
1549      esac])
1550   if test "$enable_hosted_libstdcxx" = no; then
1551     AC_MSG_NOTICE([Only freestanding libraries will be built])
1552     is_hosted=no
1553     hosted_define=0
1554     enable_abi_check=no
1555     enable_libstdcxx_pch=no
1556   else
1557     is_hosted=yes
1558     hosted_define=1
1559   fi
1560   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1561   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1562     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1563 ])
1564
1565
1566 dnl
1567 dnl Check for template specializations for the 'long long' type extension.
1568 dnl The result determines only whether 'long long' I/O is enabled; things
1569 dnl like numeric_limits<> specializations are always available.
1570 dnl
1571 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1572 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1573 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1574 dnl       Where DEFAULT is either `yes' or `no'.
1575 dnl
1576 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
1577   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1578   if test $enable_long_long = yes; then
1579     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1580   fi
1581 ])
1582
1583
1584 dnl
1585 dnl Check to see if building and using a C++ precompiled header can be done.
1586 dnl
1587 dnl --enable-libstdcxx-pch=yes
1588 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1589 dnl may work, after some light-hearted attempts to puzzle out compiler
1590 dnl support, flip bits on in include/Makefile.am
1591 dnl
1592 dnl --disable-libstdcxx-pch
1593 dnl turns off attempts to use or build stdc++.h.gch.
1594 dnl
1595 dnl Substs:
1596 dnl  glibcxx_PCHFLAGS
1597 dnl
1598 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
1599   AC_MSG_CHECKING([for enabled PCH])
1600   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1601   AC_MSG_RESULT([$enable_libstdcxx_pch])
1602
1603   if test $enable_libstdcxx_pch = yes; then
1604     AC_CACHE_CHECK([for compiler with PCH support],
1605       [glibcxx_cv_prog_CXX_pch],
1606       [ac_save_CXXFLAGS="$CXXFLAGS"
1607        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1608        AC_LANG_SAVE
1609        AC_LANG_CPLUSPLUS
1610        echo '#include <math.h>' > conftest.h
1611        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1612                           -o conftest.h.gch 1>&5 2>&1 &&
1613                 echo '#error "pch failed"' > conftest.h &&
1614           echo '#include "conftest.h"' > conftest.cc &&
1615                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1616        then
1617          glibcxx_cv_prog_CXX_pch=yes
1618        else
1619          glibcxx_cv_prog_CXX_pch=no
1620        fi
1621        rm -f conftest*
1622        CXXFLAGS=$ac_save_CXXFLAGS
1623        AC_LANG_RESTORE
1624       ])
1625     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1626   fi
1627
1628   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1629   if test $enable_libstdcxx_pch = yes; then
1630     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1631   else
1632     glibcxx_PCHFLAGS=""
1633   fi
1634   AC_SUBST(glibcxx_PCHFLAGS)
1635 ])
1636
1637
1638 dnl
1639 dnl Check for exception handling support.  If an explicit enable/disable
1640 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1641 dnl target may or may not support call frame exceptions.
1642 dnl
1643 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1644 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1645 dnl Neither one forces an attempt at detection.
1646 dnl
1647 dnl Defines:
1648 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1649 dnl
1650 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
1651   AC_MSG_CHECKING([for exception model to use])
1652   AC_LANG_SAVE
1653   AC_LANG_CPLUSPLUS
1654   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1655     [force use of builtin_setjmp for exceptions],
1656     [permit yes|no|auto])
1657
1658   if test $enable_sjlj_exceptions = auto; then
1659     # Botheration.  Now we've got to detect the exception model.  Link tests
1660     # against libgcc.a are problematic since we've not been given proper -L
1661     # bits for single-tree newlib and libgloss.
1662     #
1663     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1664     cat > conftest.$ac_ext << EOF
1665 [#]line __oline__ "configure"
1666 struct S { ~S(); };
1667 void bar();
1668 void foo()
1669 {
1670   S s;
1671   bar();
1672 }
1673 EOF
1674     old_CXXFLAGS="$CXXFLAGS"
1675     CXXFLAGS=-S
1676     if AC_TRY_EVAL(ac_compile); then
1677       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1678         enable_sjlj_exceptions=yes
1679       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1680         enable_sjlj_exceptions=no
1681       fi
1682     fi
1683     CXXFLAGS="$old_CXXFLAGS"
1684     rm -f conftest*
1685   fi
1686
1687   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1688   # to two different models.
1689   case $enable_sjlj_exceptions in
1690     yes)
1691       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1692         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1693       ac_exception_model_name=sjlj
1694       ;;
1695     no)
1696       ac_exception_model_name="call frame"
1697       ;;
1698     *)
1699       AC_MSG_ERROR([unable to detect exception model])
1700       ;;
1701   esac
1702  AC_LANG_RESTORE
1703  AC_MSG_RESULT($ac_exception_model_name)
1704 ])
1705
1706
1707 dnl
1708 dnl Add version tags to symbols in shared library (or not), additionally
1709 dnl marking other symbols as private/local (or not).
1710 dnl
1711 dnl --enable-symvers=style adds a version script to the linker call when
1712 dnl       creating the shared library.  The choice of version script is
1713 dnl       controlled by 'style'.
1714 dnl --disable-symvers does not.
1715 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1716 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1717 dnl       choose a default style based on linker characteristics.  Passing
1718 dnl       'no' disables versioning.
1719 dnl
1720 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
1721
1722 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1723   [enables symbol versioning of the shared library],
1724   [permit yes|no|gnu])
1725
1726 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1727 # don't know enough about $LD to do tricks...
1728 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1729 # FIXME  The following test is too strict, in theory.
1730 if test $enable_shared = no ||
1731         test "x$LD" = x ||
1732         test x$glibcxx_gnu_ld_version = x; then
1733   enable_symvers=no
1734 fi
1735
1736 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1737 if test $enable_symvers != no; then
1738   AC_MSG_CHECKING([for shared libgcc])
1739   ac_save_CFLAGS="$CFLAGS"
1740   CFLAGS=' -lgcc_s'
1741   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1742   CFLAGS="$ac_save_CFLAGS"
1743   if test $glibcxx_shared_libgcc = no; then
1744     cat > conftest.c <<EOF
1745 int main (void) { return 0; }
1746 EOF
1747 changequote(,)dnl
1748     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1749                              -shared -shared-libgcc -o conftest.so \
1750                              conftest.c -v 2>&1 >/dev/null \
1751                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1752 changequote([,])dnl
1753     rm -f conftest.c conftest.so
1754     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
1755       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
1756       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
1757       CFLAGS="$ac_save_CFLAGS"
1758     fi
1759   fi
1760   AC_MSG_RESULT($glibcxx_shared_libgcc)
1761 fi
1762
1763 # For GNU ld, we need at least this version.  The format is described in
1764 # GLIBCXX_CHECK_LINKER_FEATURES above.
1765 glibcxx_min_gnu_ld_version=21400
1766 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1767
1768 # Check to see if unspecified "yes" value can win, given results above.
1769 # Change "yes" into either "no" or a style name.
1770 if test $enable_symvers = yes; then
1771   if test $with_gnu_ld = yes &&
1772      test $glibcxx_shared_libgcc = yes;
1773   then
1774     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1775       enable_symvers=gnu
1776     else
1777       # The right tools, the right setup, but too old.  Fallbacks?
1778       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1779       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1780       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1781       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1782       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1783         # Globbing fix is present, proper block support is not.
1784         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1785         dnl enable_symvers=???
1786         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1787         enable_symvers=no
1788       else
1789         # 2.11 or older.
1790         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1791         enable_symvers=no
1792       fi
1793     fi
1794   else
1795     # just fail for now
1796     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1797     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1798     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1799     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1800     enable_symvers=no
1801   fi
1802 fi
1803
1804 # Everything parsed; figure out what file to use.
1805 case $enable_symvers in
1806   no)
1807     SYMVER_MAP=config/linker-map.dummy
1808     ;;
1809   gnu)
1810     SYMVER_MAP=config/linker-map.gnu
1811     AC_DEFINE(_GLIBCXX_SYMVER)
1812     ;;
1813 esac
1814
1815 AC_SUBST(SYMVER_MAP)
1816 AC_SUBST(port_specific_symbol_files)
1817 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1818 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1819 ])
1820
1821
1822 dnl
1823 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1824 dnl We must stage the required headers so that they will be installed
1825 dnl with the library (unlike libgcc, the STL implementation is provided
1826 dnl solely within headers).  Since we must not inject random user-space
1827 dnl macro names into user-provided C++ code, we first stage into <file>-in
1828 dnl and process to <file> with an output command.  The reason for a two-
1829 dnl stage process here is to correctly handle $srcdir!=$objdir without
1830 dnl having to write complex code (the sed commands to clean the macro
1831 dnl namespace are complex and fragile enough as it is).  We must also
1832 dnl add a relative path so that -I- is supported properly.
1833 dnl
1834 dnl Substs:
1835 dnl  glibcxx_thread_h
1836 dnl
1837 dnl Defines:
1838 dnl  HAVE_GTHR_DEFAULT
1839 dnl
1840 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
1841   AC_MSG_CHECKING([for thread model used by GCC])
1842   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1843   AC_MSG_RESULT([$target_thread_file])
1844
1845   if test $target_thread_file != single; then
1846     AC_DEFINE(HAVE_GTHR_DEFAULT)
1847   fi
1848
1849   glibcxx_thread_h=gthr-$target_thread_file.h
1850
1851   dnl Check for __GTHREADS define.
1852   gthread_file=${toplevel_srcdir}/gcc/${glibcxx_thread_h}
1853   if grep __GTHREADS $gthread_file >/dev/null 2>&1 ; then
1854     enable_thread=yes
1855   else
1856    enable_thread=no
1857   fi
1858
1859   AC_SUBST(glibcxx_thread_h)
1860 ])
1861
1862
1863 # Check whether LC_MESSAGES is available in <locale.h>.
1864 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1865 #
1866 # This file file be copied and used freely without restrictions.  It can
1867 # be used in projects which are not available under the GNU Public License
1868 # but which still want to provide support for the GNU gettext functionality.
1869 # Please note that the actual code is *not* freely available.
1870
1871 # serial 1
1872 AC_DEFUN([AC_LC_MESSAGES], [
1873   AC_CHECK_HEADER(locale.h, [
1874     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1875       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1876        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1877     if test $ac_cv_val_LC_MESSAGES = yes; then
1878       AC_DEFINE(HAVE_LC_MESSAGES)
1879     fi
1880   ])
1881 ])
1882
1883
1884 sinclude([../libtool.m4])
1885 dnl The lines below arrange for aclocal not to bring an installed
1886 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1887 dnl add a definition of LIBTOOL to Makefile.in.
1888 ifelse(,,,[AC_SUBST(LIBTOOL)
1889 AC_DEFUN([AM_PROG_LIBTOOL])
1890 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1891 AC_DEFUN([AC_PROG_LD])
1892 ])
1893
1894 dnl vim:et:ts=2:sw=2