libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl Initialize configure bits.
   3 dnl
   4 dnl Define OPTLEVEL='-O2' if new inlining code present.
   5 dnl
   6 dnl GLIBCPP_CONFIGURE
   7 AC_DEFUN(GLIBCPP_CONFIGURE, [
   8   dnl Default to --enable-multilib
   9   AC_ARG_ENABLE(multilib,
  10   [  --enable-multilib       build hella library versions (default)],
  11   [case "${enableval}" in
  12     yes) multilib=yes ;;
  13     no)  multilib=no ;;
  14     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  15    esac], [multilib=yes])dnl
  16
  17   dnl We may get other options which we dont document:
  18   dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  19   if test "[$]{srcdir}" = "."; then
  20     if test "[$]{with_target_subdir}" != "."; then
  21       glibcpp_basedir="[$]{srcdir}/[$]{with_multisrctop}../$1"
  22     else
  23       glibcpp_basedir="[$]{srcdir}/[$]{with_multisrctop}$1"
  24     fi
  25   else
  26     glibcpp_basedir="[$]{srcdir}/$1"
  27   fi
  28   AC_SUBST(glibcpp_basedir)
  29
  30   AM_INIT_AUTOMAKE(libstdc++, 2.90.8)
  31
  32   # Never versions of autoconf add an underscore to these functions.
  33   # Prevent future problems ...
  34   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  35   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  36   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  37   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  38
  39 #  AC_PROG_CC
  40
  41 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  42 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  43 # are probably using a cross compiler, which will not be able to fully
  44 # link an executable.  This should really be fixed in autoconf
  45 # itself.
  46
  47 AC_DEFUN(LIB_AC_PROG_CC,
  48 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  49 dnl Fool anybody using AC_PROG_CC.
  50 AC_PROVIDE([AC_PROG_CC])
  51 AC_CHECK_PROG(CC, gcc, gcc)
  52 if test -z "$CC"; then
  53   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  54   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  55 fi
  56
  57 AC_PROG_CC_GNU
  58
  59 if test $ac_cv_prog_gcc = yes; then
  60   GCC=yes
  61 dnl Check whether -g works, even if CFLAGS is set, in case the package
  62 dnl plays around with CFLAGS (such as to build both debugging and
  63 dnl normal versions of a library), tasteless as that idea is.
  64   ac_test_CFLAGS="${CFLAGS+set}"
  65   ac_save_CFLAGS="$CFLAGS"
  66   CFLAGS=
  67   AC_PROG_CC_G
  68   if test "$ac_test_CFLAGS" = set; then
  69     CFLAGS="$ac_save_CFLAGS"
  70   elif test $ac_cv_prog_cc_g = yes; then
  71     CFLAGS="-g -O2"
  72   else
  73     CFLAGS="-O2"
  74   fi
  75 else
  76   GCC=
  77   test "${CFLAGS+set}" = set || CFLAGS="-g"
  78 fi
  79 ])
  80
  81 LIB_AC_PROG_CC
  82
  83 # Can't just call these here as g++ requires libstc++ to be built....
  84 #  AC_PROG_CXX
  85
  86 # Likewise for AC_PROG_CXX.
  87 AC_DEFUN(LIB_AC_PROG_CXX,
  88 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
  89 dnl Fool anybody using AC_PROG_CXX.
  90 AC_PROVIDE([AC_PROG_CXX])
  91 # Use CXX_libstdcxx so that we do not cause CXX to be cached with the
  92 # flags that come in CXX while configuring libstdc++.  They're different
  93 # from those used for all other target libraries.  If CXX is set in
  94 # the environment, respect that here.
  95 CXX_libstdcxx=$CXX
  96 AC_CHECK_PROGS(CXX_libstdcxx, $CCC c++ g++ gcc CC cxx cc++, gcc)
  97 CXX=$CXX_libstdcxx
  98 AC_SUBST(CXX)
  99 test -z "$CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 100
 101 AC_PROG_CXX_GNU
 102
 103 if test $ac_cv_prog_gxx = yes; then
 104   GXX=yes
 105 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 106 dnl plays around with CXXFLAGS (such as to build both debugging and
 107 dnl normal versions of a library), tasteless as that idea is.
 108   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 109   ac_save_CXXFLAGS="$CXXFLAGS"
 110   CXXFLAGS=
 111   AC_PROG_CXX_G
 112   if test "$ac_test_CXXFLAGS" = set; then
 113     CXXFLAGS="$ac_save_CXXFLAGS"
 114   elif test $ac_cv_prog_cxx_g = yes; then
 115     CXXFLAGS="-g -O2"
 116   else
 117     CXXFLAGS="-O2"
 118   fi
 119 else
 120   GXX=
 121   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 122 fi
 123 ])
 124
 125 LIB_AC_PROG_CXX
 126
 127   AC_CHECK_TOOL(AS, as)
 128   AC_CHECK_TOOL(AR, ar)
 129   AC_CHECK_TOOL(RANLIB, ranlib, :)
 130
 131   AC_PROG_INSTALL
 132
 133   AM_MAINTAINER_MODE
 134
 135   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 136   # at least currently, we never actually build a program, so we never
 137   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 138   # fails, because we are probably configuring with a cross compiler
 139   # which cant create executables.  So we include AC_EXEEXT to keep
 140   # automake happy, but we dont execute it, since we dont care about
 141   # the result.
 142   if false; then
 143     AC_EXEEXT
 144   fi
 145
 146   # configure.host sets the following important variables
 147   #        glibcpp_cflags    - host specific C compiler flags
 148   #        glibcpp_cxxflags  - host specific C++ compiler flags
 149   glibcpp_cflags=
 150   glibcpp_cxxflags=
 151
 152   . [$]{glibcpp_basedir}/configure.host
 153
 154   case [$]{glibcpp_basedir} in
 155     /* | [A-Za-z]:[/\\]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 156     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 157   esac
 158
 159   # This does for the target what configure.host does for the host.  In
 160   # addition to modifying the same flags, it also sets up symlinks.
 161   GLIBCPP_CHECK_TARGET
 162
 163   GLIBCPP_CFLAGS="[$]{glibcpp_cflags}"
 164   GLIBCPP_CXXFLAGS="[$]{glibcpp_cxxflags}"
 165   AC_SUBST(GLIBCPP_CFLAGS)
 166   AC_SUBST(GLIBCPP_CXXFLAGS)
 167 ])
 168
 169
 170 dnl
 171 dnl Check to see if g++ can compile this library, and if so, if any version-
 172 dnl specific precautions need to be taken.
 173 dnl
 174 dnl GLIBCPP_CHECK_COMPILER_VERSION
 175 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 176 if test ! -f stamp-sanity-compiler; then
 177   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 178   AC_LANG_SAVE
 179   AC_LANG_CPLUSPLUS
 180   AC_EGREP_CPP(ok, [
 181   #if (__GNUC__ > 2) || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
 182     ok
 183   #endif
 184   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to gcc-2.95 or above]))
 185   AC_LANG_RESTORE
 186   AC_MSG_RESULT($gpp_satisfactory)
 187   touch stamp-sanity-compiler
 188 fi
 189 ])
 190
 191
 192 dnl
 193 dnl Test for newer compiler features, or features that are present in newer
 194 dnl compiler version but not older compiler versions should be placed
 195 dnl here.
 196 dnl
 197 dnl Define WFMT_FLAGS='-fdiagnostics-show-location=once' if possible
 198 dnl
 199 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 200 dnl new inlining code or the new system_header pragma will die on -Werror.
 201 dnl Leave it out by default and use maint-mode to use it.
 202 dnl
 203 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 204 dnl compiler supports it.
 205 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 206 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 207   # All these tests are for C++; save the language and the compiler flags.
 208   # The CXXFLAGS thing is suspicious, but based on similar bits
 209   # found in GLIBCPP_CONFIGURE.
 210   AC_LANG_SAVE
 211   AC_LANG_CPLUSPLUS
 212   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 213   ac_save_CXXFLAGS="$CXXFLAGS"
 214
 215   # Check for maintainer-mode bits.
 216   if test x"$USE_MAINTAINER_MODE" = xno; then
 217     WERROR=''
 218   else
 219     WERROR='-Werror'
 220   fi
 221
 222   # Check for more sophisticated diagnostic control.
 223   AC_MSG_CHECKING([for g++ that supports -fdiagnostics-show-location=once])
 224   CXXFLAGS='-Werror -fdiagnostics-show-location=once'
 225   AC_TRY_COMPILE(, [int foo;
 226   ], [ac_gabydiags=yes], [ac_gabydiags=no])
 227   if test "$ac_test_CXXFLAGS" = set; then
 228     CXXFLAGS="$ac_save_CXXFLAGS"
 229   else
 230     # this is the suspicious part
 231     CXXFLAGS=''
 232   fi
 233   if test "$ac_gabydiags" = "yes"; then
 234     WFMT_FLAGS='-fdiagnostics-show-location=once'
 235   fi
 236   AC_MSG_RESULT($ac_gabydiags)
 237
 238   # Check for -ffunction-sections -fdata-sections
 239   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 240   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 241   AC_TRY_COMPILE(, [int foo;
 242   ], [ac_fdsections=yes], [ac_fdsections=no])
 243   if test "$ac_test_CXXFLAGS" = set; then
 244     CXXFLAGS="$ac_save_CXXFLAGS"
 245   else
 246     # this is the suspicious part
 247     CXXFLAGS=''
 248   fi
 249   if test "$ac_fdsections" = "yes"; then
 250     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 251   fi
 252   AC_MSG_RESULT($ac_fdsections)
 253
 254   AC_LANG_RESTORE
 255   AC_SUBST(WERROR)
 256   AC_SUBST(WFMT_FLAGS)
 257   AC_SUBST(SECTION_FLAGS)
 258 ])
 259
 260
 261 dnl
 262 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 263 dnl the native linker is in use, all variables will be defined to something
 264 dnl safe (like an empty string).
 265 dnl
 266 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 267 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 268 dnl
 269 dnl GLIBCPP_CHECK_LINKER_FEATURES
 270 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 271   # If we're not using GNU ld, then there's no point in even trying these
 272   # tests.  Check for that first.  We should have already tested for gld
 273   # by now (in libtool), but require it now just to be safe...
 274   SECTION_LDFLAGS=''
 275   OPT_LDFLAGS=''
 276   AC_REQUIRE([AC_PROG_LD])
 277
 278   # Set --gc-sections.
 279   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 280     # GNU ld it is!  Joy and bunny rabbits!
 281
 282     # All these tests are for C++; save the language and the compiler flags.
 283     # Need to do this so that g++ won't try to link in libstdc++
 284     ac_test_CFLAGS="${CFLAGS+set}"
 285     ac_save_CFLAGS="$CFLAGS"
 286     CFLAGS='-x c++  -Wl,--gc-sections'
 287
 288     # Check for -Wl,--gc-sections
 289     # XXX This test is broken at the moment, as symbols required for
 290     # linking are now in libsupc++ (not built yet.....). In addition,
 291     # this test has cored on solaris in the past. In addition,
 292     # --gc-sections doesn't really work at the moment (keeps on discarding
 293     # used sections, first .eh_frame and now some of the glibc sections for
 294     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 295     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 296     AC_TRY_RUN([
 297      int main(void)
 298      {
 299        try { throw 1; }
 300        catch (...) { };
 301        return 0;
 302      }
 303     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 304     if test "$ac_test_CFLAGS" = set; then
 305       CFLAGS="$ac_save_CFLAGS"
 306     else
 307       # this is the suspicious part
 308       CFLAGS=''
 309     fi
 310     if test "$ac_sectionLDflags" = "yes"; then
 311       SECTION_LDFLAGS='-Wl,--gc-sections'
 312     fi
 313     AC_MSG_RESULT($ac_sectionLDflags)
 314   fi
 315
 316   # Set linker optimization flags.
 317   if test "$ac_cv_prog_gnu_ld" = "yes"; then
 318     OPT_LDFLAGS='-Wl,-O1'
 319   fi
 320
 321   AC_SUBST(SECTION_LDFLAGS)
 322   AC_SUBST(OPT_LDFLAGS)
 323 ])
 324
 325
 326 dnl
 327 dnl Check to see if the (math function) argument passed is
 328 dnl 1) declared when using the c++ compiler
 329 dnl 2) has "C" linkage
 330 dnl
 331 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 332 dnl
 333 dnl argument 1 is name of function to check
 334 dnl
 335 dnl ASSUMES argument is a math function with ONE parameter
 336 dnl
 337 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 338 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 339   AC_MSG_CHECKING([for $1 declaration])
 340   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 341     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 342       AC_LANG_SAVE
 343       AC_LANG_CPLUSPLUS
 344       AC_TRY_COMPILE([#include <math.h>],
 345                      [ $1(0);],
 346                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 347       AC_LANG_RESTORE
 348     ])
 349   fi
 350   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 351   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 352     AC_CHECK_FUNCS($1)
 353   fi
 354 ])
 355
 356
 357 dnl
 358 dnl Check to see if the (math function) argument passed is
 359 dnl 1) declared when using the c++ compiler
 360 dnl 2) has "C" linkage
 361 dnl
 362 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 363 dnl
 364 dnl argument 1 is name of function to check
 365 dnl
 366 dnl ASSUMES argument is a math function with TWO parameters
 367 dnl
 368 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 369 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 370   AC_MSG_CHECKING([for $1 declaration])
 371   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 372     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 373       AC_LANG_SAVE
 374       AC_LANG_CPLUSPLUS
 375       AC_TRY_COMPILE([#include <math.h>],
 376                      [ $1(0, 0);],
 377                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 378       AC_LANG_RESTORE
 379     ])
 380   fi
 381   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 382   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 383     AC_CHECK_FUNCS($1)
 384   fi
 385 ])
 386
 387
 388 dnl
 389 dnl Check to see if the (math function) argument passed is
 390 dnl 1) declared when using the c++ compiler
 391 dnl 2) has "C" linkage
 392 dnl
 393 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 394 dnl
 395 dnl argument 1 is name of function to check
 396 dnl
 397 dnl ASSUMES argument is a math function with THREE parameters
 398 dnl
 399 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 400 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 401   AC_MSG_CHECKING([for $1 declaration])
 402   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 403     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 404       AC_LANG_SAVE
 405       AC_LANG_CPLUSPLUS
 406       AC_TRY_COMPILE([#include <math.h>],
 407                      [ $1(0, 0, 0);],
 408                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 409       AC_LANG_RESTORE
 410     ])
 411   fi
 412   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 413   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 414     AC_CHECK_FUNCS($1)
 415   fi
 416 ])
 417
 418
 419 dnl
 420 dnl Check to see if the (stdlib function) argument passed is
 421 dnl 1) declared when using the c++ compiler
 422 dnl 2) has "C" linkage
 423 dnl
 424 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 425 dnl Define HAVE_STRTOF if "strtof" is declared and links
 426 dnl
 427 dnl argument 1 is name of function to check
 428 dnl
 429 dnl ASSUMES argument is a math function with TWO parameters
 430 dnl
 431 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 432 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 433   AC_MSG_CHECKING([for $1 declaration])
 434   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 435     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 436       AC_LANG_SAVE
 437       AC_LANG_CPLUSPLUS
 438       AC_TRY_COMPILE([#include <stdlib.h>],
 439                      [ $1(0, 0);],
 440                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 441       AC_LANG_RESTORE
 442     ])
 443   fi
 444   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 445   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 446     AC_CHECK_FUNCS($1)
 447   fi
 448 ])
 449
 450
 451 dnl
 452 dnl Because the builtins are picky picky picky about the arguments they take,
 453 dnl do an explict linkage tests here.
 454 dnl Check to see if the (math function) argument passed is
 455 dnl 1) declared when using the c++ compiler
 456 dnl 2) has "C" linkage
 457 dnl
 458 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 459 dnl
 460 dnl argument 1 is name of function to check
 461 dnl
 462 dnl ASSUMES argument is a math function with ONE parameter
 463 dnl
 464 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 465 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 466   AC_MSG_CHECKING([for $1 declaration])
 467   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 468     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 469       AC_LANG_SAVE
 470       AC_LANG_CPLUSPLUS
 471       AC_TRY_COMPILE([#include <math.h>],
 472                      [ $1(0);],
 473                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 474       AC_LANG_RESTORE
 475     ])
 476   fi
 477   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 478   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 479     AC_MSG_CHECKING([for $1 linkage])
 480     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 481       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 482         AC_TRY_LINK([#include <math.h>],
 483                     [ $1(0);],
 484                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 485       ])
 486     fi
 487     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 488     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 489       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 490       AC_DEFINE_UNQUOTED(${ac_tr_func})
 491     fi
 492   fi
 493 ])
 494
 495
 496 dnl
 497 dnl Check to see what builtin math functions are supported
 498 dnl
 499 dnl check for __builtin_abs
 500 dnl check for __builtin_fabsf
 501 dnl check for __builtin_fabs
 502 dnl check for __builtin_fabl
 503 dnl check for __builtin_labs
 504 dnl check for __builtin_sqrtf
 505 dnl check for __builtin_sqrtl
 506 dnl check for __builtin_fsqrt
 507 dnl check for __builtin_sinf
 508 dnl check for __builtin_sin
 509 dnl check for __builtin_sinl
 510 dnl check for __builtin_cosf
 511 dnl check for __builtin_cos
 512 dnl check for __builtin_cosl
 513 dnl
 514 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 515 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 516   dnl Test for builtin math functions.
 517   dnl These are made in gcc/c-common.c
 518   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 519   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 520   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 521   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 522   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 523
 524   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 525   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fsqrt)
 526   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 527
 528   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 529   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 530   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 531
 532   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 533   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 534   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 535
 536   dnl There is, without a doubt, a more elegant way to have these
 537   dnl names exported so that they won't be stripped out of acconfig.h by
 538   dnl autoheader. I leave this as an exercise to somebody less frustrated
 539   dnl than I.... please email the libstdc++ list if you can figure out a
 540   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 541   dnl AC_CHECK_FUNC for things to steal.)
 542   dummyvar=no
 543   if test x$dummyvar = x"yes"; then
 544     AC_DEFINE(HAVE___BUILTIN_ABS)
 545     AC_DEFINE(HAVE___BUILTIN_LABS)
 546     AC_DEFINE(HAVE___BUILTIN_COS)
 547     AC_DEFINE(HAVE___BUILTIN_COSF)
 548     AC_DEFINE(HAVE___BUILTIN_COSL)
 549     AC_DEFINE(HAVE___BUILTIN_FABS)
 550     AC_DEFINE(HAVE___BUILTIN_FABSF)
 551     AC_DEFINE(HAVE___BUILTIN_FABSL)
 552     AC_DEFINE(HAVE___BUILTIN_SIN)
 553     AC_DEFINE(HAVE___BUILTIN_SINF)
 554     AC_DEFINE(HAVE___BUILTIN_SINL)
 555     AC_DEFINE(HAVE___BUILTIN_FSQRT)
 556     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 557     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 558   fi
 559 ])
 560
 561
 562 dnl
 563 dnl Check to see what the underlying c library
 564 dnl These checks need to do two things:
 565 dnl 1) make sure the name is declared when using the c++ compiler
 566 dnl 2) make sure the name has "C" linkage
 567 dnl This might seem like overkill but experience has shown that it's not...
 568 dnl
 569 dnl Define HAVE_STRTOF etc if "strtof" is found.
 570 dnl Define HAVE_STRTOLD etc if "strtold" is found.
 571 dnl
 572 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 573 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 574   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 575   ac_save_CXXFLAGS="$CXXFLAGS"
 576   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 577
 578   AC_CHECK_FUNCS(strtof)
 579   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 580
 581   CXXFLAGS="$ac_save_CXXFLAGS"
 582 ])
 583
 584
 585 dnl
 586 dnl Check to see what the underlying c library or math library is like.
 587 dnl These checks need to do two things:
 588 dnl 1) make sure the name is declared when using the c++ compiler
 589 dnl 2) make sure the name has "C" linkage
 590 dnl This might seem like overkill but experience has shown that it's not...
 591 dnl
 592 dnl Define HAVE_CARGF etc if "cargf" is found.
 593 dnl
 594 dnl GLIBCPP_CHECK_MATH_SUPPORT
 595 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 596   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 597   ac_save_CXXFLAGS="$CXXFLAGS"
 598   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 599
 600   dnl Check libm
 601   AC_CHECK_LIB(m, sin, libm="-lm")
 602   ac_save_LIBS="$LIBS"
 603   LIBS="$LIBS $libm"
 604
 605   dnl Check to see if certain C math functions exist.
 606   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 607   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 608   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 609   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 610   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 611   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 612   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 613
 614   dnl Check to see if basic C math functions have float versions.
 615   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 616   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 617   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(acosf)
 618   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(asinf)
 619   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(atanf)
 620   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 621   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(ceilf)
 622   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(cosf)
 623   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(coshf)
 624   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 625   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 626   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(floorf)
 627   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 628   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 629   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 630   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 631   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 632   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 633   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 634   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinf)
 635   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinhf)
 636   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 637   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanf)
 638   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanhf)
 639   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 640   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 641
 642   dnl Check to see if basic C math functions have long double versions.
 643   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 644   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 645   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 646   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(acosl)
 647   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(asinl)
 648   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(atanl)
 649   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 650   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(ceill)
 651   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(cosl)
 652   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(coshl)
 653   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 654   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 655   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(floorl)
 656   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 657   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 658   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 659   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 660   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 661   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 662   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 663   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinl)
 664   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinhl)
 665   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 666   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanl)
 667   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanhl)
 668   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 669   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 670
 671   dnl Some runtimes have these functions with a preceding underscore. Please
 672   dnl keep this sync'd with the one above. And if you add any new symbol,
 673   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 674   dnl Check to see if certain C math functions exist.
 675   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isinf)
 676   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isnan)
 677   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_finite)
 678   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_copysign)
 679   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(_sincos)
 680   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_fpclass)
 681   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_qfpclass)
 682
 683   dnl Check to see if basic C math functions have float versions.
 684   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isnanf)
 685   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isinff)
 686   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_acosf)
 687   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_asinf)
 688   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_atanf)
 689   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_atan2f)
 690   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_ceilf)
 691   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_cosf)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_coshf)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_expf)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_fabsf)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_floorf)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_fmodf)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_frexpf)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_ldexpf)
 699   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_logf)
 700   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_log10f)
 701   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_modff)
 702   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_powf)
 703   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinf)
 704   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinhf)
 705   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sqrtf)
 706   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanf)
 707   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanhf)
 708   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(_sincosf)
 709   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_finitef)
 710
 711   dnl Check to see if basic C math functions have long double versions.
 712   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isnanl)
 713   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isinfl)
 714   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_copysignl)
 715   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_acosl)
 716   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_asinl)
 717   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_atanl)
 718   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_atan2l)
 719   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_ceill)
 720   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_cosl)
 721   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_coshl)
 722   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_expl)
 723   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_fabsl)
 724   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_floorl)
 725   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_fmodl)
 726   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_frexpl)
 727   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_ldexpl)
 728   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_logl)
 729   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_log10l)
 730   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_modfl)
 731   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_powl)
 732   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinl)
 733   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinhl)
 734   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sqrtl)
 735   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanl)
 736   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanhl)
 737   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(_sincosl)
 738   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_finitel)
 739
 740   LIBS="$ac_save_LIBS"
 741   CXXFLAGS="$ac_save_CXXFLAGS"
 742 ])
 743
 744
 745 dnl
 746 dnl Check to see if there is native support for complex
 747 dnl
 748 dnl Don't compile bits in math/* if native support exits.
 749 dnl
 750 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "atan2l/copysignl" is found.
 751 dnl
 752 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 753 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 754   dnl Check for complex versions of math functions of platform.
 755   AC_CHECK_HEADERS([complex.h])
 756   AC_CHECK_LIB(m, main)
 757   AC_REPLACE_MATHFUNCS(ccos ccosf ccosh ccoshf cexp cexpf \
 758   csin csinf csinh csinhf csqrt \
 759   csqrtf ctan ctanf ctanh ctanhf nan hypot hypotf atan2f expf \
 760   copysignf)
 761
 762   dnl Compile the long double complex functions only if the function
 763   dnl provides the non-complex long double functions that are needed.
 764   dnl Currently this includes copysignl and atan2l, which should be
 765   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 766   USE_COMPLEX_LONG_DOUBLE=no
 767   if test x$ac_cv_func_atan2l = x"yes" \
 768      && test x$ac_cv_func_copysignl = x"yes"; then
 769     USE_COMPLEX_LONG_DOUBLE=yes
 770     AC_REPLACE_MATHFUNCS(ccoshl ccosl cexpl csinhl csinl \
 771     csqrtl ctanhl ctanl hypotl signbitl clog10l)
 772   fi
 773
 774   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 775 ])
 776
 777
 778 dnl Check to see what architecture and operating system we are compiling
 779 dnl for.  Also, if architecture- or OS-specific flags are required for
 780 dnl compilation, pick them up here.
 781 dnl
 782 dnl GLIBCPP_CHECK_TARGET
 783 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 784     . [$]{glibcpp_basedir}/configure.target
 785     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 786     AC_MSG_RESULT(OS config directory is $os_include_dir)
 787     AC_LINK_FILES($os_include_dir/bits/os_defines.h, include/bits/os_defines.h)
 788 ])
 789
 790
 791 dnl
 792 dnl Check to see what the underlying c library's interface to ctype looks
 793 dnl like. Bits of locale rely on things like isspace, toupper, etc. This
 794 dnl stuff makes sure the right bits from the clibrary get called.
 795 dnl
 796 dnl Depending on what is found, select various configure/*/bits/ctype_base.h
 797 dnl Depending on what is found, select various configure/*/ctype.cc
 798 dnl
 799 dnl GLIBCPP_CHECK_CTYPE_SUPPORT
 800 AC_DEFUN(GLIBCPP_CHECK_CTYPE_SUPPORT, [
 801   AC_CHECK_HEADER(ctype.h, [
 802
 803     dnl If doesn't match any specified, go with defaults.
 804     ctype_default=yes
 805
 806     dnl Test for <ctype> functionality -- GNU/Linux
 807     AC_MSG_CHECKING([<ctype> for GNU/Linux])
 808     AC_TRY_COMPILE([#include <ctype.h>],
 809     [int
 810     foo (int a)
 811     { return _ISspace + _ISprint + _IScntrl + _ISupper + _ISlower + _ISalpha \
 812         + _ISdigit + _ISpunct + _ISxdigit + _ISalnum + _ISgraph \
 813         + __ctype_tolower[a] + __ctype_toupper[a] + __ctype_b[a];}], \
 814     ctype_linux=yes, ctype_linux=no)
 815     AC_MSG_RESULT($ctype_linux)
 816     if test $ctype_linux = "yes"; then
 817       ctype_include_dir="config/os/gnu-linux"
 818       ctype_default=no
 819     fi
 820
 821     dnl Test for <ctype> functionality -- FreeBSD 4.0
 822     if test $ctype_default = "yes"; then
 823     AC_MSG_CHECKING([<ctype> for FreeBSD 4.0])
 824     AC_TRY_COMPILE([#include <ctype.h>],
 825     [int
 826     foo (int a)
 827     { return _CTYPE_S + _CTYPE_R + _CTYPE_C + _CTYPE_U + _CTYPE_L + _CTYPE_A \
 828         + _CTYPE_D + _CTYPE_P + _CTYPE_X + _CTYPE_G ;}], \
 829     ctype_bsd=yes, ctype_bsd=no)
 830     AC_MSG_RESULT($ctype_bsd)
 831     if test $ctype_bsd = "yes"; then
 832       ctype_include_dir="config/os/bsd/freebsd"
 833       ctype_default=no
 834     fi
 835     fi
 836
 837     dnl Test for <ctype> functionality -- FreeBSD 3.4
 838     if test $ctype_default = "yes"; then
 839     AC_MSG_CHECKING([<ctype> for FreeBSD 3.4])
 840     AC_TRY_COMPILE([#include <ctype.h>],
 841     [int
 842     foo (int a)
 843     { return _S + _R + _C + _U + _L + _A \
 844       + _D + _P + _X + _G + __istype (a, 0);}], \
 845     ctype_freebsd34=yes, ctype_freebsd34=no)
 846     AC_MSG_RESULT($ctype_freebsd34)
 847     if test $ctype_freebsd34 = "yes"; then
 848       ctype_include_dir="config/os/bsd/freebsd"
 849       ctype_default=no
 850     fi
 851     fi
 852
 853     dnl Test for <ctype> functionality -- NetBSD
 854     if test $ctype_default = "yes"; then
 855     AC_MSG_CHECKING([<ctype> for NetBSD])
 856     AC_TRY_COMPILE([#include <ctype.h>],
 857     [int
 858     foo (int a)
 859     { return _S + _C + _U + _L \
 860       + _N + _P + _X + _tolower_tab_[a] + _toupper_tab_[a];}], \
 861     ctype_netbsd=yes, ctype_netbsd=no)
 862     AC_MSG_RESULT($ctype_netbsd)
 863     if test $ctype_netbsd = "yes"; then
 864       ctype_include_dir="config/os/bsd/netbsd"
 865       ctype_default=no
 866     fi
 867     fi
 868
 869     dnl Test for <ctype> functionality -- Solaris 2.6 and up
 870     if test $ctype_default = "yes"; then
 871     AC_MSG_CHECKING([<ctype> for Solaris 2.6,7,8])
 872     AC_TRY_COMPILE([#include <ctype.h>],
 873     [int
 874     foo (int a)
 875     { return _ISSPACE + _ISPRINT + _ISCNTRL + _ISUPPER + _ISLOWER + _ISALPHA \
 876         + _ISDIGIT + _ISPUNCT + _ISXDIGIT + _ISALNUM + _ISGRAPH \
 877         + __trans_lower[a] + __trans_upper[a] + __ctype_mask[a];}], \
 878     ctype_solaris=yes, ctype_solaris=no)
 879     AC_MSG_RESULT($ctype_solaris)
 880
 881     if test $ctype_solaris = "yes"; then
 882       AC_MSG_CHECKING([  for version])
 883       AC_LANG_CPLUSPLUS
 884       AC_TRY_COMPILE([#include <ctype.h>],
 885       [typedef long* __to_type; __to_type const& _M_toupper = __trans_upper;],\
 886       ctype_solaris26=yes, ctype_solaris26=no)
 887       AC_LANG_C
 888       if test $ctype_solaris26 = "yes"; then
 889         ctype_include_dir="config/os/solaris/solaris2.6"
 890         AC_MSG_RESULT([Solaris 2.6])
 891         ctype_default=no
 892       else
 893         ctype_include_dir="config/os/solaris/solaris2.7"
 894         AC_MSG_RESULT([Solaris 7,8])
 895         ctype_default=no
 896       fi
 897     fi
 898     fi
 899
 900     dnl Test for <ctype> functionality -- Solaris 2.5.1
 901     if test $ctype_default = "yes"; then
 902     AC_MSG_CHECKING([<ctype> for Solaris 2.5.1])
 903     AC_TRY_COMPILE([#include <ctype.h>],
 904     [int
 905     foo (int a)
 906     { return _U + _L + _N + _S + _P + _C + _X + _B \
 907         + __ctype[a];}], \
 908     ctype_solaris25=yes, ctype_solaris25=no)
 909     AC_MSG_RESULT($ctype_solaris25)
 910     if test $ctype_solaris25 = "yes"; then
 911       ctype_include_dir="config/os/solaris/solaris2.5"
 912       ctype_default=no
 913     fi
 914     fi
 915
 916     dnl Test for <ctype> functionality -- AIX
 917     if test $ctype_default = "yes"; then
 918     AC_MSG_CHECKING([<ctype> for AIX])
 919     AC_TRY_COMPILE([#include <ctype.h>],
 920     [int
 921     foo (int a)
 922     { return _ISSPACE + _ISPRINT + _ISCNTRL + _ISUPPER + _ISLOWER + _ISALPHA \
 923         + _ISDIGIT + _ISPUNCT + _ISXDIGIT + _ISALNUM + _ISGRAPH \
 924         + _VALC('a') + _IS('c', 0);}], \
 925     ctype_aix=yes, ctype_aix=no)
 926     AC_MSG_RESULT($ctype_aix)
 927     if test $ctype_aix = "yes"; then
 928       ctype_include_dir="config/os/aix"
 929       ctype_default=no
 930     fi
 931     fi
 932
 933     dnl Test for <ctype> functionality -- IRIX
 934     if test $ctype_default = "yes"; then
 935     AC_MSG_CHECKING([<ctype> for IRIX])
 936     AC_TRY_COMPILE([#include <ctype.h>],
 937     [int
 938     foo (int a)
 939     { return _U + _L + _N + _S + _P + _C + _B + _X + \
 940              _A + _PR + _G + _BL;}], \
 941     ctype_irix=yes, ctype_irix=no)
 942     AC_MSG_RESULT($ctype_irix)
 943     if test $ctype_irix = "yes"; then
 944       ctype_include_dir="config/os/irix"
 945       ctype_default=no
 946     fi
 947     fi
 948
 949     dnl Test for <ctype> functionality -- newlib
 950     if test $ctype_default = "yes"; then
 951     AC_MSG_CHECKING([<ctype> for newlib])
 952     AC_TRY_COMPILE([#include <ctype.h>],
 953     [int
 954     foo (int a)
 955     { return _U + _L + _N + _S + _P + _C + _X + _B \
 956         + _ctype_[a];}], \
 957     ctype_newlib=yes, ctype_newlib=no)
 958     AC_MSG_RESULT($ctype_newlib)
 959     if test $ctype_newlib = "yes"; then
 960       ctype_include_dir="config/os/newlib"
 961       ctype_default=no
 962     fi
 963     fi
 964
 965     if test $ctype_default = "yes"; then
 966       ctype_include_dir="config/os/generic"
 967       AC_MSG_WARN("Using default ctype headers.")
 968     fi
 969
 970     AC_LINK_FILES($ctype_include_dir/bits/ctype_base.h,
 971     include/bits/ctype_base.h)
 972     AC_LINK_FILES($ctype_include_dir/bits/ctype_inline.h,
 973     include/bits/ctype_inline.h)
 974     AC_LINK_FILES($ctype_include_dir/bits/ctype_noninline.h, \
 975     include/bits/ctype_noninline.h)
 976   ])
 977 ])
 978
 979
 980 dnl
 981 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 982 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 983 dnl must have been previously checked.)
 984 dnl
 985 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 986 dnl Define _GLIBCPP_NEED_MBSTATE_T if mbstate_t is not in wchar.h
 987 dnl
 988 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 989 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 990   if test x$enable_c_mbchar != xno; then
 991
 992     dnl Sanity check for existence of ISO C99 headers for extended encoding.
 993     AC_CHECK_HEADER(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 994     AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 995
 996     dnl Only continue checking if the ISO C99 headers exist.
 997     if test x"$ac_has_wchar_h" = xyes && test x"$ac_has_wctype_h" = xyes; then
 998
 999       dnl Test wchar.h for mbstate_t, which is needed for char_traits
1000       dnl and others.
1001       AC_MSG_CHECKING([for mbstate_t])
1002       AC_TRY_COMPILE([#include <wchar.h>],
1003       [mbstate_t teststate;],
1004       use_native_mbstatet=yes, use_native_mbstatet=no)
1005       AC_MSG_RESULT($use_native_mbstatet)
1006
1007       dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
1008       dnl numeric_limits can instantiate type_traits<wchar_t>
1009       AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
1010       AC_TRY_COMPILE([#include <wchar.h>],
1011       [int i = WCHAR_MIN; int j = WCHAR_MAX;],
1012       has_wchar_minmax=yes, has_wchar_minmax=no)
1013       AC_MSG_RESULT($has_wchar_minmax)
1014
1015       dnl Test wchar.h for WEOF, which is what we use to determine whether
1016       dnl to specialize for char_traits<wchar_t> or not.
1017       AC_MSG_CHECKING([for WEOF])
1018       AC_TRY_COMPILE([
1019         #include <wchar.h>
1020         #include <stddef.h>],
1021       [wint_t i = WEOF;],
1022       has_weof=yes, has_weof=no)
1023       AC_MSG_RESULT($has_weof)
1024
1025       dnl Tests for wide character functions used in char_traits<wchar_t>.
1026       AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset \
1027       wcsrtombs mbsrtowcs, ac_wfuncs=yes, ac_wfuncs=no)
1028
1029       AC_MSG_CHECKING([for ISO C99 wchar_t support])
1030       if test x"$has_weof" = xyes && test x"$has_wchar_minmax" = xyes \
1031          && test x"$ac_wfuncs" = xyes; then
1032         ac_isoC99_wchar_t=yes
1033       else
1034         ac_isoC99_wchar_t=no
1035       fi
1036       AC_MSG_RESULT($ac_isoC99_wchar_t)
1037
1038       dnl Use iconv for wchar_t to char conversions. As such, check for
1039       dnl X/Open Portability Guide, version 2 features (XPG2).
1040       AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
1041       AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
1042
1043       dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
1044       AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
1045       ac_save_LIBS="$LIBS"
1046       LIBS="$LIBS $libiconv"
1047
1048       AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
1049       ac_XPG2funcs=yes, ac_XPG2funcs=no)
1050
1051       LIBS="$ac_save_LIBS"
1052
1053       AC_MSG_CHECKING([for XPG2 wchar_t support])
1054       if test x"$ac_has_iconv_h" = xyes && test x"$ac_has_langinfo_h" = xyes \
1055          && test x"$ac_XPG2funcs" = xyes; then
1056         ac_XPG2_wchar_t=yes
1057       else
1058         ac_XPG2_wchar_t=no
1059       fi
1060       AC_MSG_RESULT($ac_XPG2_wchar_t)
1061
1062       dnl At the moment, only enable wchar_t specializations if all the
1063       dnl above support is present.
1064       AC_MSG_CHECKING([for enabled wchar_t specializations])
1065       if test x"$ac_isoC99_wchar_t" = xyes \
1066          && test x"$ac_XPG2_wchar_t" = xyes; then
1067         libinst_wstring_la="libinst-wstring.la"
1068         AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
1069         AC_MSG_RESULT("yes")
1070       else
1071         libinst_wstring_la=""
1072         AC_MSG_RESULT("no")
1073       fi
1074       AC_SUBST(libinst_wstring_la)
1075
1076     else
1077       AC_MSG_WARN([<wchar.h> not found])
1078     fi
1079
1080   else
1081     dnl Wide characters disabled by the user.  Maybe print a warning?
1082     :
1083   fi
1084 ])
1085
1086
1087 dnl
1088 dnl Check to see if this version of GNU C++ is afflicted by bugs in
1089 dnl __complex__ float support.
1090 dnl
1091 dnl Define _GLIBCPP_BUGGY_FLOAT_COMPLEX if buggy.
1092 dnl
1093 dnl Check to see if this version of GNU C++ is afflicted by bugs in
1094 dnl __complex__ support.Check for buggy __complex__ that will cause ICE in
1095 dnl gcc-2.95.x when using the library, unless we define the default copy
1096 dnl ctor in the specializations of complex<>.
1097 dnl
1098 dnl Define _GLIBCPP_BUGGY_COMPLEX if buggy.
1099 dnl GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT
1100 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT, [
1101   AC_REQUIRE([AC_PROG_CXX])
1102
1103   AC_MSG_CHECKING([for GNU C++ __complex__ support])
1104   AC_CACHE_VAL(glibcpp_cv_complex, [
1105     AC_LANG_SAVE
1106     AC_LANG_CPLUSPLUS
1107     AC_TRY_COMPILE([struct dcomplex { __complex__ double x; }; \
1108                     dcomplex f(const dcomplex& x) { return dcomplex(x); }], \
1109                     [ dcomplex x; f(x); ],
1110       glibcpp_cv_complex=ok,
1111       glibcpp_cv_complex=buggy
1112     )
1113     AC_LANG_RESTORE
1114   ])
1115   AC_MSG_RESULT($glibcpp_cv_complex)
1116   if test $glibcpp_cv_complex = buggy; then
1117     AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
1118   fi
1119
1120   AC_MSG_CHECKING([for GNU C++ __complex__ float support])
1121   AC_CACHE_VAL(glibcpp_cv_float_complex, [
1122     AC_LANG_SAVE
1123     AC_LANG_CPLUSPLUS
1124     rm -f conftest.h
1125     cat > conftest.h <<EOB
1126       //
1127       // Check for buggy __complex__ that causes ICE in most versions of egcs
1128       // and gcc-2.95.x on certain platforms (eg., x86-win32).
1129       //
1130       // See http://gcc.gnu.org/ml/gcc-bugs/1999-07n/msg00845.html for
1131       // more info on the bug itself.
1132       //
1133       struct
1134       float_complex
1135       {
1136        __complex__ float m_value;
1137        float_complex (float = 0.0f, float = 0.0f);
1138        float_complex (__complex__ float val) : m_value (val) {}
1139        float_complex foo (const float_complex &val)
1140          { return float_complex (~val.m_value); }
1141       };
1142 EOB
1143     AC_TRY_COMPILE([#include "conftest.h"], ,
1144       glibcpp_cv_float_complex=ok,
1145       glibcpp_cv_float_complex=buggy
1146     )
1147     AC_LANG_RESTORE
1148   ])
1149   AC_MSG_RESULT($glibcpp_cv_float_complex)
1150   if test $glibcpp_cv_float_complex = buggy; then
1151     AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
1152   fi
1153 ])
1154
1155
1156 dnl
1157 dnl Check for special debugging mode; not for production use.
1158 dnl
1159 dnl GLIBCPP_ENABLE_DEBUG
1160 dnl --enable-debug sets '-ggdb3 -O0'.
1161 dnl --disable-debug sets '-g' and whatever optimization options the
1162 dnl     compiler can handle.
1163 dnl  +  --enable-maintainer-mode automatically defaults this to on.
1164 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
1165 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1166 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1167 dnl       defaults to `no'.
1168 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1169 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1170 AC_ARG_ENABLE(debug,
1171 changequote(<<, >>)dnl
1172 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1173 changequote([, ])dnl
1174 [case "${enableval}" in
1175  yes) enable_debug=yes ;;
1176  no)  enable_debug=no ;;
1177  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1178  esac],
1179 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1180
1181 dnl Option parsed, now set things appropriately
1182 case "${enable_debug}" in
1183     yes)
1184         DEBUG_FLAGS='-O0 -ggdb3'
1185         ;;
1186     no)
1187         DEBUG_FLAGS='-g'
1188         ;;
1189 esac
1190 AC_SUBST(DEBUG_FLAGS)
1191 ])
1192
1193
1194 dnl
1195 dnl Check for "unusual" flags to pass to the compiler while building.
1196 dnl
1197 dnl GLIBCPP_ENABLE_CXX_FLAGS
1198 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1199 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1200 dnl     Somehow this same set of flags must be passed when [re]building
1201 dnl     libgcc.
1202 dnl --disable-cxx-flags passes nothing.
1203 dnl  +  See http://sourceware.cygnus.com/ml/libstdc++/2000-q2/msg00131.html
1204 dnl         http://sourceware.cygnus.com/ml/libstdc++/2000-q2/msg00284.html
1205 dnl         http://sourceware.cygnus.com/ml/libstdc++/2000-q1/msg00035.html
1206 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1207 dnl       If "default flags" is an empty string (or "none"), the effect is
1208 dnl       the same as --disable or --enable=no.
1209 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1210 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1211 AC_ARG_ENABLE(cxx-flags,
1212 changequote(<<, >>)dnl
1213 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1214                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1215 changequote([, ])dnl
1216 [case "x$enableval" in
1217  xyes)
1218         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1219  xno|x)
1220         enable_cxx_flags='' ;;
1221  *)
1222         enable_cxx_flags="$enableval" ;;
1223  esac],
1224 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1225
1226 dnl Thinko on my part during design.  This kludge is the workaround.
1227 if test "$enable_cxx_flags" = "none"; then
1228   enable_cxx_flags='';
1229 fi
1230
1231 dnl Run through flags (either default or command-line) and set anything
1232 dnl extra (e.g., #defines) that must accompany particular g++ options.
1233 if test -n "$enable_cxx_flags"; then
1234     for f in $enable_cxx_flags; do
1235         case "$f" in
1236             -fhonor-std)  ;;
1237             -*)  ;;
1238             *)   # and we're trying to pass /what/ exactly?
1239                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1240         esac
1241     done
1242 fi
1243 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1244 AC_SUBST(EXTRA_CXX_FLAGS)
1245 ])
1246
1247
1248 dnl
1249 dnl Check for which I/O library to use:  libio, or something specific.
1250 dnl
1251 dnl GLIBCPP_ENABLE_CSTDIO
1252 dnl --enable-cstdio=libio sets config/c_io_libio.h and friends
1253 dnl
1254 dnl default is stdio
1255 dnl
1256 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1257   AC_MSG_CHECKING([for cstdio to use])
1258   AC_ARG_ENABLE(cstdio,
1259   [  --enable-cstdio        enable stdio for target io package. (default)
1260      --enable-cstdio=LIB    use LIB target-speific io package.],
1261   if test x$enable_cstdio = xno; then
1262      enable_cstdio=stdio
1263   fi,
1264      enable_cstdio=stdio)
1265
1266   enable_cstdio_flag=$enable_cstdio
1267
1268   dnl Check if a valid I/O package
1269   case x${enable_cstdio_flag} in
1270     xlibio)
1271       CSTDIO_H=config/c_io_libio.h
1272       CSTDIO_CC=config/c_io_libio.cc
1273       AC_MSG_RESULT(libio)
1274
1275       # see if we are on a system with libio native (ie, linux)
1276       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1277
1278       # Need to check and see what version of glibc is being used. If
1279       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1280       # compile most of libio for linux systems.
1281       if test x$has_libio = x"yes"; then
1282         case "$target" in
1283           *-*-linux*)
1284               AC_MSG_CHECKING([for glibc version >= 2.2])
1285               AC_EGREP_CPP([ok], [
1286             #include <features.h>
1287               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1288                     ok
1289               #endif
1290               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1291               AC_MSG_RESULT($glibc_satisfactory)
1292             ;;
1293         esac
1294
1295         # XXX at the moment, admit defeat and force the recompilation
1296         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1297         glibc_satisfactory=no
1298
1299         if test x$glibc_satisfactory = x"yes"; then
1300            need_libio=no
1301            need_wlibio=no
1302         else
1303            need_libio=yes
1304            # bkoz XXX need to add checks to enable this
1305            # pme XXX here's a first pass at such a check
1306            if test x$enable_c_mbchar != xno; then
1307               need_wlibio=yes
1308            else
1309               need_wlibio=no
1310            fi
1311         fi
1312
1313       else
1314          # Using libio, but <libio.h> doesn't exist on the target system. . .
1315          need_libio=yes
1316          # bkoz XXX need to add checks to enable this
1317          # pme XXX here's a first pass at such a check
1318          if test x$enable_c_mbchar != xno; then
1319              need_wlibio=yes
1320          else
1321              need_wlibio=no
1322          fi
1323       fi
1324       ;;
1325     xstdio | x | xno | xnone | xyes)
1326       # default
1327       CSTDIO_H=config/c_io_stdio.h
1328       CSTDIO_CC=config/c_io_stdio.cc
1329       AC_MSG_RESULT(stdio)
1330
1331       # We're not using stdio.
1332       need_libio=no
1333       need_wlibio=no
1334       # Wide characters are not supported with this package.
1335       enable_c_mbchar=no
1336       ;;
1337     *)
1338       echo "$enable_cstdio is an unknown io package" 1>&2
1339       exit 1
1340       ;;
1341   esac
1342   AC_LINK_FILES($CSTDIO_H, include/bits/c++io.h)
1343   AC_LINK_FILES($CSTDIO_CC, src/c++io.cc)
1344
1345   # 2000-08-04 bkoz hack
1346   CCODECVT_C=config/c_io_libio_codecvt.c
1347   AC_LINK_FILES($CCODECVT_C, libio/c_codecvt.c)
1348   # 2000-08-04 bkoz hack
1349
1350   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1351   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1352   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1353         libio_la=../libio/libio.la
1354   else
1355         libio_la=
1356   fi
1357   AC_SUBST(libio_la)
1358 ])
1359
1360
1361 dnl
1362 dnl Check for which threading library to use.
1363 dnl
1364 dnl GLIBCPP_ENABLE_THREADS
1365 dnl --enable-threads=posix sets config/threads-posix.h et. al.
1366 dnl
1367 dnl Default is no threads, which also disables _IO_MTSAFE_IO in
1368 dnl libio.  Any actual thread package will enable it.
1369 dnl
1370 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1371   dnl Note this comes from the gcc/config.in and libjava/config.in
1372   dnl Efforts should be made to keep this in sync.
1373   AC_MSG_CHECKING([for threads package to use])
1374   AC_ARG_ENABLE(threads,
1375   [  --enable-threads        enable thread usage for target GCC.
1376      --enable-threads=LIB    use LIB thread package for target GCC.],
1377   if test x$enable_threads = xno; then
1378     enable_threads=''
1379   fi,
1380     enable_threads='')
1381
1382   enable_threads_flag=$enable_threads
1383
1384   dnl Check if a valid thread package
1385   case x${enable_threads_flag} in
1386         x | xno | xnone)
1387                 # No threads
1388                 target_thread_file='single'
1389                 ;;
1390         xyes)
1391                 # default
1392                 target_thread_file='posix'
1393                 ;;
1394         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
1395         xsolaris | xwin32 | xdce | xvxworks)
1396                 target_thread_file=$enable_threads_flag
1397                 ;;
1398         *)
1399                 echo "$enable_threads is an unknown thread package" 1>&2
1400                 exit 1
1401                 ;;
1402   esac
1403
1404   dnl Check for thread package actually supported in libstdc++
1405   THREADH=
1406   case "$target_thread_file" in
1407     no | none | single)
1408       THREADH=threads-no.h
1409       ;;
1410     posix | pthreads)
1411       THREADH=threads-posix.h
1412       ;;
1413     decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
1414       AC_MSG_ERROR(thread package $THREADS not yet supported)
1415       ;;
1416     *)
1417       AC_MSG_ERROR($THREADS is an unsupported/unknown thread package)
1418       ;;
1419   esac
1420   AC_MSG_RESULT($THREADH)
1421
1422   AC_LINK_FILES(config/$THREADH, include/bits/c++threads.h)
1423   if test $THREADH != threads-no.h; then
1424     AC_DEFINE(_GLIBCPP_USE_THREADS)
1425   fi
1426 ])
1427
1428
1429 dnl Enable atomic locking
1430 dnl GLIBCPP_ENABLE_ATOMICITY
1431 AC_DEFUN(GLIBCPP_ENABLE_ATOMICITY, [
1432     AC_MSG_CHECKING([for atomicity.h])
1433     # We have ATOMICITY already from GLIBCPP_CONFIGURE
1434     if test "$ATOMICITYH" = "config/cpu/generic"; then
1435       AC_MSG_WARN([No ATOMICITY settings found, using generic atomic ops.])
1436     fi
1437     AC_MSG_RESULT($ATOMICITYH/bits/atomicity.h)
1438     AC_LINK_FILES($ATOMICITYH/bits/atomicity.h, include/bits/atomicity.h)
1439 ])
1440
1441
1442 dnl
1443 dnl Check for template specializations for the 'long long' type extension.
1444 dnl
1445 dnl GLIBCPP_ENABLE_LONG_LONG
1446 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1447 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1448 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1449 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1450 dnl       defaults to `no'.
1451 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1452 dnl
1453 dnl GLIBCPP_ENABLE_LONG_LONG
1454 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1455   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1456
1457   AC_ARG_ENABLE(long-long,
1458   changequote(<<, >>)dnl
1459   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1460   changequote([, ])dnl
1461   [case "$enableval" in
1462    yes) enable_long_long=yes ;;
1463    no)  enable_long_long=no ;;
1464    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1465    esac],
1466   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1467
1468   # Allow use of os-dependent settings, so that macros that turn on
1469   # C99 capabilities can be defined and used in a consistent way.
1470   OS_INC_PATH=${srcdir}/$os_include_dir
1471   ac_test_CFLAGS="${CFLAGS+set}"
1472   ac_save_CFLAGS="$CFLAGS"
1473   CFLAGS="-I$OS_INC_PATH"
1474
1475   # Check for the existence of functions used if long long is enabled.
1476   AC_CHECK_FUNC(strtoll,,ac_strtoll=no)
1477   AC_CHECK_FUNC(strtoull,,ac_strtoull=no)
1478
1479   # Check for lldiv_t, et. al.
1480   AC_MSG_CHECKING([for lldiv_t declaration])
1481   AC_CACHE_VAL(glibcpp_lldiv_t_use, [
1482   AC_TRY_COMPILE([#include <bits/os_defines.h>
1483                   #include <stdlib.h>],
1484                    [ lldiv_t mydivt;],
1485                    [glibcpp_lldiv_t_use=yes], [glibcpp_lldiv_t_use=no])
1486   ])
1487   AC_MSG_RESULT($glibcpp_lldiv_t_use)
1488   if test x$glibcpp_lldiv_t_use = x"yes"; then
1489     AC_DEFINE(HAVE_LLDIV_T)
1490   fi
1491
1492   AC_MSG_CHECKING([for enabled long long])
1493   if test x"$ac_strtoll" = xno || test x"$ac_strtoull" = xno; then
1494     enable_long_long=no;
1495   fi;
1496   AC_MSG_RESULT($enable_long_long)
1497
1498   # Option parsed, now set things appropriately
1499   if test x"$enable_long_long" = xyes; then
1500     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1501   fi
1502
1503   # Reset CFLAGS
1504   CFLAGS="$ac_save_CFLAGS"
1505 ])
1506
1507
1508 dnl
1509 dnl Check for whether or not to do shadowed C headers.
1510 dnl
1511 dnl GLIBCPP_ENABLE_SHADOW
1512 dnl --enable-cshadow-headers [does stuff].
1513 dnl --disable-cshadow-headers [does not do stuff].
1514 dnl  +  This will eventually need to be on by default.
1515 dnl  +  Usage:  GLIBCPP_ENABLE_SHADOW[(DEFAULT)]
1516 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1517 dnl       defaults to `no'.
1518 AC_DEFUN(GLIBCPP_ENABLE_SHADOW, [dnl
1519 define([GLIBCPP_ENABLE_SHADOW_DEFAULT], ifelse($1, yes, yes, no))dnl
1520 AC_MSG_CHECKING([for enabled cshadow headers])
1521 AC_ARG_ENABLE(cshadow-headers,
1522 changequote(<<, >>)dnl
1523 <<  --enable-cshadow-headers construct "shadowed" C header files for
1524                            g++ [default=>>GLIBCPP_ENABLE_SHADOW_DEFAULT],
1525 changequote([, ])
1526   [case "$enableval" in
1527    yes) enable_cshadow_headers=yes
1528         ;;
1529    no)  enable_cshadow_headers=no
1530         ;;
1531    *)   AC_MSG_ERROR([Unknown argument to enable/disable shadowed C headers])
1532         ;;
1533   esac],
1534   enable_cshadow_headers=GLIBCPP_ENABLE_SHADOW_DEFAULT)
1535   AC_MSG_RESULT($enable_cshadow_headers)
1536
1537   dnl Option parsed, now set things appropriately
1538   dnl NB: these things may be duplicated in c++config.h as well.
1539   case "$enable_cshadow_headers" in
1540     yes)
1541         CSHADOW_FLAGS="-fno-builtin"
1542         C_INCLUDE_DIR='${top_srcdir}/include/c_std'
1543         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1544         ;;
1545     no)
1546         CSHADOW_FLAGS=""
1547         C_INCLUDE_DIR='${top_srcdir}/include/c'
1548         ;;
1549   esac
1550
1551   AC_SUBST(CSHADOW_FLAGS)
1552   AC_SUBST(C_INCLUDE_DIR)
1553   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cshadow_headers" = yes)
1554 ])
1555
1556
1557 dnl
1558 dnl Check for wide character support.  Has the same effect as the option
1559 dnl in gcc's configure, but in a form that autoconf can mess with.
1560 dnl
1561 dnl GLIBCPP_ENABLE_C_MBCHAR
1562 dnl --enable-c-mbchar requests all the wchar_t stuff.
1563 dnl --disable-c-mbchar doesn't.
1564 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1565 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1566 dnl       defaults to `no'.
1567 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1568 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1569 AC_ARG_ENABLE(c-mbchar,
1570 changequote(<<, >>)dnl
1571 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1572 changequote([, ])dnl
1573 [case "$enableval" in
1574  yes) enable_c_mbchar=yes ;;
1575  no)  enable_c_mbchar=no ;;
1576  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1577  esac],
1578 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1579 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1580 ])
1581
1582
1583 dnl
1584 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1585 dnl
1586 dnl GLIBCPP_INCLUDE_DIR
1587 dnl C_INCLUDE_DIR
1588 dnl TOPLEVEL_INCLUDES
1589 dnl LIBMATH_INCLUDES
1590 dnl LIBSUPCXX_INCLUDES
1591 dnl LIBIO_INCLUDES
1592 dnl CSHADOW_INCLUDES
1593 dnl
1594 dnl GLIBCPP_EXPORT_INCLUDE
1595 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1596   # Root level of the include sources.
1597   GLIBCPP_INCLUDE_DIR='$(top_srcdir)/include'
1598
1599   # Can either use include/c or include/c_std to grab "C" headers. This
1600   # variable is set to the include directory currently in use.
1601   # set with C_INCLUDE_DIR in GLIBCPP_ENABLE_SHADOW
1602
1603   # Passed down for canadian crosses.
1604   if  test x"$CANADIAN" = xyes; then
1605     TOPLEVEL_INCLUDES='-I$(includedir)'
1606   fi
1607
1608   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1609
1610   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1611
1612   #if GLIBCPP_NEED_LIBIO
1613   LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1614   #else
1615   #LIBIO_INCLUDES='-I$(top_srcdir)/libio'
1616   #endif
1617
1618   #if GLIBCPP_USE_CSHADOW
1619   #  CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR) \
1620   #                   -I$(top_blddir)/cshadow'
1621   #else
1622   CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR)'
1623   #endif
1624
1625   # Now, export this to all the little Makefiles....
1626   AC_SUBST(GLIBCPP_INCLUDE_DIR)
1627   AC_SUBST(TOPLEVEL_INCLUDES)
1628   AC_SUBST(LIBMATH_INCLUDES)
1629   AC_SUBST(LIBSUPCXX_INCLUDES)
1630   AC_SUBST(LIBIO_INCLUDES)
1631   AC_SUBST(CSHADOW_INCLUDES)
1632 ])
1633
1634
1635 dnl
1636 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1637 dnl
1638 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1639   # Optimization flags that are probably a good idea for thrill-seekers. Just
1640   # uncomment the lines below and make, everything else is ready to go...
1641   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1642   OPTIMIZE_CXXFLAGS=
1643   AC_SUBST(OPTIMIZE_CXXFLAGS)
1644
1645   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1646   AC_SUBST(WARN_FLAGS)
1647 ])
1648
1649
1650 # Check whether LC_MESSAGES is available in <locale.h>.
1651 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1652 #
1653 # This file file be copied and used freely without restrictions.  It can
1654 # be used in projects which are not available under the GNU Public License
1655 # but which still want to provide support for the GNU gettext functionality.
1656 # Please note that the actual code is *not* freely available.
1657
1658 # serial 1
1659
1660 AC_DEFUN(AC_LC_MESSAGES, [
1661   AC_CHECK_HEADER(locale.h, [
1662     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1663       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1664        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1665     if test $ac_cv_val_LC_MESSAGES = yes; then
1666       AC_DEFINE(HAVE_LC_MESSAGES)
1667     fi
1668   ])
1669 ])
1670
1671
1672 # Check for functions in math library.
1673 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1674 #
1675 # This file can be copied and used freely without restrictions.  It can
1676 # be used in projects which are not available under the GNU Public License
1677 # but which still want to provide support for the GNU gettext functionality.
1678 # Please note that the actual code is *not* freely available.
1679
1680 # serial 1
1681
1682 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1683 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1684 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1685 AC_SUBST(LIBMATHOBJS)dnl
1686 ])
1687
1688
1689 # Check for string functions.
1690 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1691 #
1692 # This file can be copied and used freely without restrictions.  It can
1693 # be used in projects which are not available under the GNU Public License
1694 # but which still want to provide support for the GNU gettext functionality.
1695 # Please note that the actual code is *not* freely available.
1696
1697 # serial 1
1698
1699 dnl AC_REPLACE_STRINGFUNCS(FUNCTION...)
1700 AC_DEFUN(AC_REPLACE_STRINGFUNCS,
1701 [AC_CHECK_FUNCS([$1], , [LIBSTRINGOBJS="$LIBSTRINGOBJS ${ac_func}.lo"])
1702 AC_SUBST(LIBSTRINGOBJS)dnl
1703 ])
1704
1705
1706 dnl This macro searches for a GNU version of make.  If a match is found, the
1707 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1708 dnl set to "#". This is useful for  including a special features in a Makefile,
1709 dnl which cannot be handled by other versions of make.  The variable
1710 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1711 dnl the empty string otherwise.
1712 dnl
1713 dnl Here is an example of its use:
1714 dnl
1715 dnl Makefile.in might contain:
1716 dnl
1717 dnl     # A failsafe way of putting a dependency rule into a makefile
1718 dnl     $(DEPEND):
1719 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1720 dnl
1721 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1722 dnl     @ifGNUmake@ include $(DEPEND)
1723 dnl     @ifGNUmake@ endif
1724 dnl
1725 dnl Then configure.in would normally contain:
1726 dnl
1727 dnl     CHECK_GNU_MAKE()
1728 dnl     AC_OUTPUT(Makefile)
1729 dnl
1730 dnl Then perhaps to cause gnu make to override any other make, we could do
1731 dnl something like this (note that GNU make always looks for GNUmakefile first):
1732 dnl
1733 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1734 dnl             mv Makefile GNUmakefile
1735 dnl             echo .DEFAULT: > Makefile ;
1736 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1737 dnl     fi
1738 dnl
1739 dnl Then, if any (well almost any) other make is called, and GNU make also
1740 dnl exists, then the other make wraps the GNU make.
1741 dnl
1742 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1743 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1744 dnl
1745 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1746 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1747 dnl #### conditional's subshell (" --version" is not a command), using a
1748 dnl #### different option to grep(1).
1749 dnl #### -pme
1750 AC_DEFUN(
1751   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1752           _cv_gnu_make_command='' ;
1753 dnl Search all the common names for GNU make
1754           for a in "${MAKE:-make}" make gmake gnumake ; do
1755                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1756                   then
1757                           _cv_gnu_make_command=$a ;
1758                           break;
1759                   fi
1760           done ;
1761   ) ;
1762 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1763 dnl string, '#' otherwise
1764   if test  "x$_cv_gnu_make_command" != "x"  ; then
1765           ifGNUmake='' ;
1766   else
1767           ifGNUmake='#' ;
1768   fi
1769   AC_SUBST(ifGNUmake)
1770 ])
1771
1772 sinclude(../libtool.m4)
1773 dnl The lines below arrange for aclocal not to bring an installed
1774 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1775 dnl add a definition of LIBTOOL to Makefile.in.
1776 ifelse(,,,[AC_SUBST(LIBTOOL)
1777 AC_DEFUN([AM_PROG_LIBTOOL])
1778 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1779 AC_DEFUN([AC_PROG_LD])
1780 ])
1781