libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  27   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN(GLIBCXX_CONFIGURE, [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 387     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     # Checks for wide character functions that are not required
 394     # for basic wchar_t support.  Don't disable support if they are missing.
 395     # Injection of these is wrapped with guard macros.
 396     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 397
 398     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 399     if test x"$has_weof" = xyes &&
 400        test x"$has_wchar_minmax" = xyes &&
 401        test x"$ac_wfuncs" = xyes;
 402     then
 403       ac_isoC99_wchar_t=yes
 404     else
 405       ac_isoC99_wchar_t=no
 406     fi
 407     AC_MSG_RESULT($ac_isoC99_wchar_t)
 408
 409     # Use iconv for wchar_t to char conversions. As such, check for
 410     # X/Open Portability Guide, version 2 features (XPG2).
 411     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 412     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 413
 414     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 415     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 416     ac_save_LIBS="$LIBS"
 417     LIBS="$LIBS $libiconv"
 418
 419     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 420     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 421
 422     LIBS="$ac_save_LIBS"
 423
 424     AC_MSG_CHECKING([for XPG2 wchar_t support])
 425     if test x"$ac_has_iconv_h" = xyes &&
 426        test x"$ac_has_langinfo_h" = xyes &&
 427        test x"$ac_XPG2funcs" = xyes;
 428     then
 429       ac_XPG2_wchar_t=yes
 430     else
 431       ac_XPG2_wchar_t=no
 432     fi
 433     AC_MSG_RESULT($ac_XPG2_wchar_t)
 434
 435     # At the moment, only enable wchar_t specializations if all the
 436     # above support is present.
 437     if test x"$ac_isoC99_wchar_t" = xyes &&
 438        test x"$ac_XPG2_wchar_t" = xyes;
 439     then
 440       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 441       enable_wchar_t=yes
 442     fi
 443   fi
 444   AC_MSG_CHECKING([for enabled wchar_t specializations])
 445   AC_MSG_RESULT($enable_wchar_t)
 446 ])
 447
 448
 449 dnl
 450 dnl Check for headers for, and arguments to, the setrlimit() function.
 451 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 452 dnl
 453 dnl Defines:
 454 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 455 dnl  various HAVE_MEMLIMIT_* for individual limit names
 456 dnl
 457 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 458   AC_TRY_COMPILE(
 459     [#include <unistd.h>
 460      #include <sys/time.h>
 461      #include <sys/resource.h>
 462     ],
 463     [ int f = RLIMIT_$1 ; ],
 464     [glibcxx_mresult=1], [glibcxx_mresult=0])
 465   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 466                      [Only used in build directory testsuite_hooks.h.])
 467 ])
 468
 469 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 470   setrlimit_have_headers=yes
 471   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 472                    [],
 473                    [setrlimit_have_headers=no])
 474   # If don't have the headers, then we can't run the tests now, and we
 475   # won't be seeing any of these during testsuite compilation.
 476   if test $setrlimit_have_headers = yes; then
 477     # Can't do these in a loop, else the resulting syntax is wrong.
 478     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 479     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 480     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 481     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 482
 483     # Check for rlimit, setrlimit.
 484     AC_CACHE_VAL(ac_setrlimit, [
 485       AC_TRY_COMPILE(
 486         [#include <unistd.h>
 487          #include <sys/time.h>
 488          #include <sys/resource.h>
 489         ],
 490         [struct rlimit r;
 491          setrlimit(0, &r);],
 492         [ac_setrlimit=yes], [ac_setrlimit=no])
 493     ])
 494   fi
 495
 496   AC_MSG_CHECKING([for testsuite memory limit support])
 497   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 498     ac_mem_limits=yes
 499     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 500   else
 501     ac_mem_limits=no
 502   fi
 503   AC_MSG_RESULT($ac_mem_limits)
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 509 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 510 dnl
 511 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 512   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 513     AC_TRY_LINK(
 514       [#include <sys/stat.h>],
 515       [struct stat buffer;
 516        fstat(0, &buffer);
 517        S_ISREG(buffer.st_mode);],
 518       [glibcxx_cv_S_ISREG=yes],
 519       [glibcxx_cv_S_ISREG=no])
 520   ])
 521   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 522     AC_TRY_LINK(
 523       [#include <sys/stat.h>],
 524       [struct stat buffer;
 525        fstat(0, &buffer);
 526        S_IFREG & buffer.st_mode;],
 527       [glibcxx_cv_S_IFREG=yes],
 528       [glibcxx_cv_S_IFREG=no])
 529   ])
 530   if test $glibcxx_cv_S_ISREG = yes; then
 531     AC_DEFINE(HAVE_S_ISREG)
 532   elif test $glibcxx_cv_S_IFREG = yes; then
 533     AC_DEFINE(HAVE_S_IFREG)
 534   fi
 535 ])
 536
 537
 538 dnl
 539 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 540 dnl
 541 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 542   AC_CACHE_VAL(glibcxx_cv_POLL, [
 543     AC_TRY_LINK(
 544       [#include <poll.h>],
 545       [struct pollfd pfd[1];
 546        pfd[0].events = POLLIN;
 547        poll(pfd, 1, 0);],
 548       [glibcxx_cv_POLL=yes],
 549       [glibcxx_cv_POLL=no])
 550   ])
 551   if test $glibcxx_cv_POLL = yes; then
 552     AC_DEFINE(HAVE_POLL)
 553   fi
 554 ])
 555
 556
 557 dnl
 558 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 559 dnl
 560 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 561   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 562     AC_TRY_LINK(
 563       [#include <sys/uio.h>],
 564       [struct iovec iov[2];
 565        writev(0, iov, 0);],
 566       [glibcxx_cv_WRITEV=yes],
 567       [glibcxx_cv_WRITEV=no])
 568   ])
 569   if test $glibcxx_cv_WRITEV = yes; then
 570     AC_DEFINE(HAVE_WRITEV)
 571   fi
 572 ])
 573
 574
 575 dnl
 576 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 577 dnl
 578 AC_DEFUN(GLIBCXX_CHECK_INT64_T, [
 579   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 580     AC_TRY_COMPILE(
 581       [#include <stdint.h>],
 582       [int64_t var;],
 583       [glibcxx_cv_INT64_T=yes],
 584       [glibcxx_cv_INT64_T=no])
 585   ])
 586   if test $glibcxx_cv_INT64_T = yes; then
 587     AC_DEFINE(HAVE_INT64_T)
 588   fi
 589 ])
 590
 591
 592 dnl
 593 dnl Check whether LFS support is available.
 594 dnl
 595 AC_DEFUN(GLIBCXX_CHECK_LFS, [
 596   AC_CACHE_VAL(glibcxx_cv_LFS, [
 597     AC_TRY_LINK(
 598       [#include <unistd.h>],
 599       [fopen64("t", "w");
 600        lseek64(1, 0, SEEK_CUR);],
 601       [glibcxx_cv_LFS=yes],
 602       [glibcxx_cv_LFS=no])
 603   ])
 604   if test $glibcxx_cv_LFS = yes; then
 605     AC_DEFINE(_GLIBCXX_USE_LFS)
 606   fi
 607 ])
 608
 609
 610 dnl
 611 dnl Does any necessary configuration of the testsuite directory.  Generates
 612 dnl the testsuite_hooks.h header.
 613 dnl
 614 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 615 dnl
 616 dnl Sets:
 617 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 618 dnl Substs:
 619 dnl  baseline_dir
 620 dnl
 621 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 622   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 623     # Do checks for memory limit functions.
 624     GLIBCXX_CHECK_SETRLIMIT
 625
 626     # Look for setenv, so that extended locale tests can be performed.
 627     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 628
 629     if test $enable_symvers = no; then
 630       enable_abi_check=no
 631     else
 632       case "$host" in
 633         *-*-cygwin*)
 634           enable_abi_check=no ;;
 635         *)
 636           enable_abi_check=yes ;;
 637       esac
 638     fi
 639   else
 640     # Only build this as native, since automake does not understand
 641     # CXX_FOR_BUILD.
 642     enable_abi_check=no
 643   fi
 644
 645   # Export file names for ABI checking.
 646   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 647   AC_SUBST(baseline_dir)
 648
 649   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 650   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 651 ])
 652
 653
 654 dnl
 655 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 656 dnl
 657 dnl Substs:
 658 dnl  GLIBCXX_INCLUDES
 659 dnl  TOPLEVEL_INCLUDES
 660 dnl
 661 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 662   # Used for every C++ compile we perform.
 663   GLIBCXX_INCLUDES="\
 664 -I$glibcxx_builddir/include/$host_alias \
 665 -I$glibcxx_builddir/include \
 666 -I$glibcxx_srcdir/libsupc++"
 667
 668   # For Canadian crosses, pick this up too.
 669   if test $CANADIAN = yes; then
 670     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 671   fi
 672
 673   # Stuff in the actual top level.  Currently only used by libsupc++ to
 674   # get unwind* headers from the gcc dir.
 675   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 676   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 677
 678   # Now, export this to all the little Makefiles....
 679   AC_SUBST(GLIBCXX_INCLUDES)
 680   AC_SUBST(TOPLEVEL_INCLUDES)
 681 ])
 682
 683
 684 dnl
 685 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 686 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 687 dnl
 688 dnl Substs:
 689 dnl  OPTIMIZE_CXXFLAGS
 690 dnl  WARN_FLAGS
 691 dnl
 692 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 693   # Optimization flags that are probably a good idea for thrill-seekers. Just
 694   # uncomment the lines below and make, everything else is ready to go...
 695   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 696   OPTIMIZE_CXXFLAGS=
 697   AC_SUBST(OPTIMIZE_CXXFLAGS)
 698
 699   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 700   AC_SUBST(WARN_FLAGS)
 701 ])
 702
 703
 704 dnl
 705 dnl All installation directory information is determined here.
 706 dnl
 707 dnl Substs:
 708 dnl  gxx_install_dir
 709 dnl  glibcxx_prefixdir
 710 dnl  glibcxx_toolexecdir
 711 dnl  glibcxx_toolexeclibdir
 712 dnl
 713 dnl Assumes cross_compiling bits already done, and with_cross_host in
 714 dnl particular.
 715 dnl
 716 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 717   glibcxx_toolexecdir=no
 718   glibcxx_toolexeclibdir=no
 719   glibcxx_prefixdir=$prefix
 720
 721   AC_MSG_CHECKING([for gxx-include-dir])
 722   AC_ARG_WITH([gxx-include-dir],
 723     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 724                    [installation directory for include files]),
 725     [case "$withval" in
 726       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 727       no)  gxx_include_dir=no ;;
 728       *)   gxx_include_dir=$withval ;;
 729      esac],
 730     [gxx_include_dir=no])
 731   AC_MSG_RESULT($gxx_include_dir)
 732
 733   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 734   AC_ARG_ENABLE([version-specific-runtime-libs],
 735     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 736                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 737     [case "$enableval" in
 738       yes) version_specific_libs=yes ;;
 739       no)  version_specific_libs=no ;;
 740       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 741      esac],
 742     [version_specific_libs=no])
 743   AC_MSG_RESULT($version_specific_libs)
 744
 745   # Default case for install directory for include files.
 746   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 747     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 748   fi
 749
 750   # Version-specific runtime libs processing.
 751   if test $version_specific_libs = yes; then
 752     # Need the gcc compiler version to know where to install libraries
 753     # and header files if --enable-version-specific-runtime-libs option
 754     # is selected.
 755     if test x"$gxx_include_dir" = x"no"; then
 756       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 757     fi
 758     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 759     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 760   fi
 761
 762   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 763   # Install a library built with a cross compiler in tooldir, not libdir.
 764   if test x"$glibcxx_toolexecdir" = x"no"; then
 765     if test -n "$with_cross_host" &&
 766        test x"$with_cross_host" != x"no"; then
 767       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 768       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 769     else
 770       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 771       glibcxx_toolexeclibdir='${libdir}'
 772     fi
 773     multi_os_directory=`$CXX -print-multi-os-directory`
 774     case $multi_os_directory in
 775       .) ;; # Avoid trailing /.
 776       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 777     esac
 778   fi
 779
 780   AC_MSG_CHECKING([for install location])
 781   AC_MSG_RESULT($gxx_include_dir)
 782
 783   AC_SUBST(glibcxx_prefixdir)
 784   AC_SUBST(gxx_include_dir)
 785   AC_SUBST(glibcxx_toolexecdir)
 786   AC_SUBST(glibcxx_toolexeclibdir)
 787 ])
 788
 789
 790 dnl
 791 dnl GLIBCXX_ENABLE
 792 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 793 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 794 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 795 dnl
 796 dnl See docs/html/17_intro/configury.html#enable for documentation.
 797 dnl
 798 m4_define([GLIBCXX_ENABLE],[dnl
 799 m4_define([_g_switch],[--enable-$1])dnl
 800 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 801  AC_ARG_ENABLE($1,_g_help,
 802   m4_bmatch([$5],
 803    [^permit ],
 804      [[
 805       case "$enableval" in
 806        m4_bpatsubst([$5],[permit ])) ;;
 807        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 808           dnl Idea for future:  generate a URL pointing to
 809           dnl "onlinedocs/configopts.html#whatever"
 810       esac
 811      ]],
 812    [^$],
 813      [[
 814       case "$enableval" in
 815        yes|no) ;;
 816        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 817       esac
 818      ]],
 819    [[$5]]),
 820   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 821 m4_undefine([_g_switch])dnl
 822 m4_undefine([_g_help])dnl
 823 ])
 824
 825
 826 dnl
 827 dnl Check for ISO/IEC 9899:1999 "C99" support.
 828 dnl
 829 dnl --enable-c99 defines _GLIBCXX_USE_C99
 830 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 831 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 832 dnl       Where DEFAULT is either `yes' or `no'.
 833 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 834 dnl
 835 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 836   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 837
 838   AC_LANG_SAVE
 839   AC_LANG_CPLUSPLUS
 840
 841   # Check for the existence of <math.h> functions used if C99 is enabled.
 842   ac_c99_math=yes;
 843   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 844   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 845   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 846   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 847   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 848   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 849   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 850   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 851   AC_TRY_COMPILE([#include <math.h>],
 852                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 853   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 854   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 855   AC_TRY_COMPILE([#include <math.h>],
 856                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 857   AC_TRY_COMPILE([#include <math.h>],
 858                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 859   AC_MSG_RESULT($ac_c99_math)
 860
 861   # Check for the existence in <stdio.h> of vscanf, et. al.
 862   ac_c99_stdio=yes;
 863   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 864   AC_TRY_COMPILE([#include <stdio.h>],
 865                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 866   AC_TRY_COMPILE([#include <stdio.h>
 867                   #include <stdarg.h>
 868                   void foo(char* fmt, ...)
 869                   {va_list args; va_start(args, fmt);
 870                   vfscanf(stderr, "%i", args);}],
 871                   [],, [ac_c99_stdio=no])
 872   AC_TRY_COMPILE([#include <stdio.h>
 873                   #include <stdarg.h>
 874                   void foo(char* fmt, ...)
 875                   {va_list args; va_start(args, fmt);
 876                   vscanf("%i", args);}],
 877                   [],, [ac_c99_stdio=no])
 878   AC_TRY_COMPILE([#include <stdio.h>
 879                   #include <stdarg.h>
 880                   void foo(char* fmt, ...)
 881                   {va_list args; va_start(args, fmt);
 882                   vsnprintf(fmt, 0, "%i", args);}],
 883                   [],, [ac_c99_stdio=no])
 884   AC_TRY_COMPILE([#include <stdio.h>
 885                   #include <stdarg.h>
 886                   void foo(char* fmt, ...)
 887                   {va_list args; va_start(args, fmt);
 888                   vsscanf(fmt, "%i", args);}],
 889                   [],, [ac_c99_stdio=no])
 890   AC_MSG_RESULT($ac_c99_stdio)
 891
 892   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 893   ac_c99_stdlib=yes;
 894   AC_MSG_CHECKING([for lldiv_t declaration])
 895   AC_CACHE_VAL(ac_c99_lldiv_t, [
 896   AC_TRY_COMPILE([#include <stdlib.h>],
 897                    [ lldiv_t mydivt;],
 898                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 899   ])
 900   AC_MSG_RESULT($ac_c99_lldiv_t)
 901
 902   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 903   AC_TRY_COMPILE([#include <stdlib.h>],
 904                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 905   AC_TRY_COMPILE([#include <stdlib.h>],
 906                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 907   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 908   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 909   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 910   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 911   if test x"$ac_c99_lldiv_t" = x"no"; then
 912     ac_c99_stdlib=no;
 913   fi;
 914   AC_MSG_RESULT($ac_c99_stdlib)
 915
 916   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 917   # XXX the wchar.h checks should be rolled into the general C99 bits.
 918   ac_c99_wchar=yes;
 919   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 920   AC_TRY_COMPILE([#include <wchar.h>],
 921                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 922   AC_TRY_COMPILE([#include <wchar.h>],
 923                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 924   AC_TRY_COMPILE([#include <wchar.h>],
 925                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 926   AC_MSG_RESULT($ac_c99_wchar)
 927
 928   AC_MSG_CHECKING([for enabled ISO C99 support])
 929   if test x"$ac_c99_math" = x"no" ||
 930      test x"$ac_c99_stdio" = x"no" ||
 931      test x"$ac_c99_stdlib" = x"no" ||
 932      test x"$ac_c99_wchar" = x"no"; then
 933     enable_c99=no;
 934   fi;
 935   AC_MSG_RESULT($enable_c99)
 936
 937   # Option parsed, now set things appropriately
 938   if test x"$enable_c99" = x"yes"; then
 939     AC_DEFINE(_GLIBCXX_USE_C99)
 940   fi
 941
 942   AC_LANG_RESTORE
 943 ])
 944
 945
 946 dnl
 947 dnl Check for what type of C headers to use.
 948 dnl
 949 dnl --enable-cheaders= [does stuff].
 950 dnl --disable-cheaders [does not do anything, really].
 951 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 952 dnl       Where DEFAULT is either `c' or `c_std'.
 953 dnl
 954 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 955   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 956     [construct "C" headers for g++], [permit c|c_std])
 957   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 958
 959   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 960
 961   AC_SUBST(C_INCLUDE_DIR)
 962   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 963   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 964   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 965 ])
 966
 967
 968 dnl
 969 dnl Check for which locale library to use.  The choice is mapped to
 970 dnl a subdirectory of config/locale.
 971 dnl
 972 dnl Default is generic.
 973 dnl
 974 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 975   AC_MSG_CHECKING([for C locale to use])
 976   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 977     [use MODEL for target locale package],
 978     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 979
 980   # If they didn't use this option switch, or if they specified --enable
 981   # with no specific model, we'll have to look for one.  If they
 982   # specified --disable (???), do likewise.
 983   if test $enable_clocale = no || test $enable_clocale = yes; then
 984      enable_clocale=auto
 985   fi
 986
 987   # Either a known package, or "auto"
 988   enable_clocale_flag=$enable_clocale
 989
 990   # Probe for locale support if no specific model is specified.
 991   # Default to "generic".
 992   if test $enable_clocale_flag = auto; then
 993     case x${target_os} in
 994       xlinux* | xgnu*)
 995         AC_EGREP_CPP([_GLIBCXX_ok], [
 996         #include <features.h>
 997         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 998           _GLIBCXX_ok
 999         #endif
1000         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1001
1002         # Test for bugs early in glibc-2.2.x series
1003           if test x$enable_clocale_flag = xgnu; then
1004           AC_TRY_RUN([
1005           #define _GNU_SOURCE 1
1006           #include <locale.h>
1007           #include <string.h>
1008           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
1009           extern __typeof(newlocale) __newlocale;
1010           extern __typeof(duplocale) __duplocale;
1011           extern __typeof(strcoll_l) __strcoll_l;
1012           #endif
1013           int main()
1014           {
1015               const char __one[] = "Äuglein Augmen";
1016               const char __two[] = "Äuglein";
1017               int i;
1018               int j;
1019               __locale_t        loc;
1020                __locale_t        loc_dup;
1021               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
1022               loc_dup = __duplocale(loc);
1023               i = __strcoll_l(__one, __two, loc);
1024               j = __strcoll_l(__one, __two, loc_dup);
1025               return 0;
1026           }
1027           ],
1028           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
1029           [enable_clocale_flag=generic])
1030           fi
1031
1032         # ... at some point put __strxfrm_l tests in as well.
1033         ;;
1034       *)
1035         enable_clocale_flag=generic
1036         ;;
1037     esac
1038   fi
1039
1040   # Deal with gettext issues.  Default to not using it (=no) until we detect
1041   # support for it later.  Let the user turn it off via --e/d, but let that
1042   # default to on for easier handling.
1043   USE_NLS=no
1044   AC_ARG_ENABLE(nls,
1045     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1046     [],
1047     [enable_nls=yes])
1048
1049   # Set configure bits for specified locale package
1050   case ${enable_clocale_flag} in
1051     generic)
1052       AC_MSG_RESULT(generic)
1053
1054       CLOCALE_H=config/locale/generic/c_locale.h
1055       CLOCALE_CC=config/locale/generic/c_locale.cc
1056       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1057       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1058       CCOLLATE_CC=config/locale/generic/collate_members.cc
1059       CCTYPE_CC=config/locale/generic/ctype_members.cc
1060       CMESSAGES_H=config/locale/generic/messages_members.h
1061       CMESSAGES_CC=config/locale/generic/messages_members.cc
1062       CMONEY_CC=config/locale/generic/monetary_members.cc
1063       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1064       CTIME_H=config/locale/generic/time_members.h
1065       CTIME_CC=config/locale/generic/time_members.cc
1066       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1067       ;;
1068     gnu)
1069       AC_MSG_RESULT(gnu)
1070
1071       # Declare intention to use gettext, and add support for specific
1072       # languages.
1073       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1074       ALL_LINGUAS="de fr"
1075
1076       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1077       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1078       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1079         USE_NLS=yes
1080       fi
1081       # Export the build objects.
1082       for ling in $ALL_LINGUAS; do \
1083         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1084         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1085       done
1086       AC_SUBST(glibcxx_MOFILES)
1087       AC_SUBST(glibcxx_POFILES)
1088
1089       CLOCALE_H=config/locale/gnu/c_locale.h
1090       CLOCALE_CC=config/locale/gnu/c_locale.cc
1091       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1092       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1093       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1094       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1095       CMESSAGES_H=config/locale/gnu/messages_members.h
1096       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1097       CMONEY_CC=config/locale/gnu/monetary_members.cc
1098       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1099       CTIME_H=config/locale/gnu/time_members.h
1100       CTIME_CC=config/locale/gnu/time_members.cc
1101       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1102       ;;
1103     ieee_1003.1-2001)
1104       AC_MSG_RESULT(IEEE 1003.1)
1105
1106       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1107       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1108       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1109       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1110       CCOLLATE_CC=config/locale/generic/collate_members.cc
1111       CCTYPE_CC=config/locale/generic/ctype_members.cc
1112       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1113       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1114       CMONEY_CC=config/locale/generic/monetary_members.cc
1115       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1116       CTIME_H=config/locale/generic/time_members.h
1117       CTIME_CC=config/locale/generic/time_members.cc
1118       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1119       ;;
1120   esac
1121
1122   # This is where the testsuite looks for locale catalogs, using the
1123   # -DLOCALEDIR define during testsuite compilation.
1124   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1125   AC_SUBST(glibcxx_localedir)
1126
1127   # A standalone libintl (e.g., GNU libintl) may be in use.
1128   if test $USE_NLS = yes; then
1129     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1130     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1131   fi
1132   if test $USE_NLS = yes; then
1133     AC_DEFINE(_GLIBCXX_USE_NLS)
1134   fi
1135
1136   AC_SUBST(USE_NLS)
1137   AC_SUBST(CLOCALE_H)
1138   AC_SUBST(CCODECVT_H)
1139   AC_SUBST(CMESSAGES_H)
1140   AC_SUBST(CCODECVT_CC)
1141   AC_SUBST(CCOLLATE_CC)
1142   AC_SUBST(CCTYPE_CC)
1143   AC_SUBST(CMESSAGES_CC)
1144   AC_SUBST(CMONEY_CC)
1145   AC_SUBST(CNUMERIC_CC)
1146   AC_SUBST(CTIME_H)
1147   AC_SUBST(CTIME_CC)
1148   AC_SUBST(CLOCALE_CC)
1149   AC_SUBST(CLOCALE_INTERNAL_H)
1150 ])
1151
1152
1153 dnl
1154 dnl Check for whether the Boost-derived checks should be turned on.
1155 dnl
1156 dnl --enable-concept-checks turns them on.
1157 dnl --disable-concept-checks leaves them off.
1158 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1159 dnl       Where DEFAULT is either `yes' or `no'.
1160 dnl
1161 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1162   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1163   if test $enable_concept_checks = yes; then
1164     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1165   fi
1166 ])
1167
1168
1169 dnl
1170 dnl Check for which I/O library to use:  stdio, or something specific.
1171 dnl
1172 dnl Default is stdio.
1173 dnl
1174 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1175   AC_MSG_CHECKING([for underlying I/O to use])
1176   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1177     [use target-specific I/O package], [permit stdio])
1178
1179   # Now that libio has been removed, you can have any color you want as long
1180   # as it's black.  This is one big no-op until other packages are added, but
1181   # showing the framework never hurts.
1182   case ${enable_cstdio} in
1183     stdio)
1184       CSTDIO_H=config/io/c_io_stdio.h
1185       BASIC_FILE_H=config/io/basic_file_stdio.h
1186       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1187       AC_MSG_RESULT(stdio)
1188       ;;
1189   esac
1190
1191   AC_SUBST(CSTDIO_H)
1192   AC_SUBST(BASIC_FILE_H)
1193   AC_SUBST(BASIC_FILE_CC)
1194 ])
1195
1196
1197 dnl
1198 dnl Check for "unusual" flags to pass to the compiler while building.
1199 dnl
1200 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1201 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1202 dnl --disable-cxx-flags passes nothing.
1203 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1204 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1205 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1206 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1207 dnl       If "default flags" is an empty string, the effect is the same
1208 dnl       as --disable or --enable=no.
1209 dnl
1210 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1211   AC_MSG_CHECKING([for extra compiler flags for building])
1212   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1213     [pass compiler FLAGS when building library],
1214     [case "x$enable_cxx_flags" in
1215       xno | x)   enable_cxx_flags= ;;
1216       x-*)       ;;
1217       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1218      esac])
1219
1220   # Run through flags (either default or command-line) and set anything
1221   # extra (e.g., #defines) that must accompany particular g++ options.
1222   if test -n "$enable_cxx_flags"; then
1223     for f in $enable_cxx_flags; do
1224       case "$f" in
1225         -fhonor-std)  ;;
1226         -*)  ;;
1227         *)   # and we're trying to pass /what/ exactly?
1228              AC_MSG_ERROR([compiler flags start with a -]) ;;
1229       esac
1230     done
1231   fi
1232
1233   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1234   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1235   AC_SUBST(EXTRA_CXX_FLAGS)
1236 ])
1237
1238
1239 dnl
1240 dnl Check for wide character support.  Has the same effect as the option
1241 dnl in gcc's configure, but in a form that autoconf can mess with.
1242 dnl
1243 dnl --enable-c-mbchar requests all the wchar_t stuff.
1244 dnl --disable-c-mbchar doesn't.
1245 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1246 dnl       Where DEFAULT is either `yes' or `no'.
1247 dnl
1248 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1249   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1250   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1251 ])
1252
1253
1254 dnl
1255 dnl Check to see if debugging libraries are to be built.
1256 dnl
1257 dnl --enable-libstdcxx-debug
1258 dnl builds a separate set of debugging libraries in addition to the
1259 dnl normal (shared, static) libstdc++ binaries.
1260 dnl
1261 dnl --disable-libstdcxx-debug
1262 dnl builds only one (non-debug) version of libstdc++.
1263 dnl
1264 dnl --enable-libstdcxx-debug-flags=FLAGS
1265 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1266 dnl
1267 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1268 dnl       Where DEFAULT is either `yes' or `no'.
1269 dnl
1270 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1271   AC_MSG_CHECKING([for additional debug build])
1272   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1273   AC_MSG_RESULT($enable_libstdcxx_debug)
1274   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1275 ])
1276
1277
1278 dnl
1279 dnl Check for explicit debug flags.
1280 dnl
1281 dnl --enable-libstdcxx-debug-flags='-O1'
1282 dnl is a general method for passing flags to be used when
1283 dnl building debug libraries with --enable-debug.
1284 dnl
1285 dnl --disable-libstdcxx-debug-flags does nothing.
1286 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1287 dnl       If "default flags" is an empty string, the effect is the same
1288 dnl       as --disable or --enable=no.
1289 dnl
1290 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1291   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1292     [pass compiler FLAGS when building debug library],
1293     [case "x$enable_libstdcxx_debug_flags" in
1294       xno | x)    enable_libstdcxx_debug_flags= ;;
1295       x-*)        ;;
1296       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1297      esac])
1298
1299   # Option parsed, now set things appropriately
1300   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1301   AC_SUBST(DEBUG_FLAGS)
1302
1303   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1304 ])
1305
1306
1307 dnl
1308 dnl Check if the user only wants a freestanding library implementation.
1309 dnl
1310 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1311 dnl installing only the headers required by [17.4.1.3] and the language
1312 dnl support library.  More than that will be built (to keep the Makefiles
1313 dnl conveniently clean), but not installed.
1314 dnl
1315 dnl Sets:
1316 dnl  is_hosted  (yes/no)
1317 dnl
1318 dnl Defines:
1319 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1320 dnl
1321 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1322   AC_ARG_ENABLE([hosted-libstdcxx],
1323     AC_HELP_STRING([--disable-hosted-libstdcxx],
1324                    [only build freestanding C++ runtime support]),,
1325     [enable_hosted_libstdcxx=yes])
1326   if test "$enable_hosted_libstdcxx" = no; then
1327     AC_MSG_NOTICE([Only freestanding libraries will be built])
1328     is_hosted=no
1329     hosted_define=0
1330     enable_abi_check=no
1331     enable_libstdcxx_pch=no
1332   else
1333     is_hosted=yes
1334     hosted_define=1
1335   fi
1336   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1337   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1338     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1339 ])
1340
1341
1342 dnl
1343 dnl Check for libunwind exception handling support.  If enabled, then
1344 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1345 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1346 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1347 dnl on libunwind as well as libgcc.
1348 dnl
1349 dnl --enable-libunwind-exceptions forces the use of libunwind.
1350 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1351 dnl
1352 dnl Substs:
1353 dnl  LIBUNWIND_FLAG
1354 dnl
1355 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1356   AC_MSG_CHECKING([for use of libunwind])
1357   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1358     [force use of libunwind for exceptions])
1359   AC_MSG_RESULT($use_libunwind_exceptions)
1360   if test $enable_libunwind_exceptions = yes; then
1361     LIBUNWIND_FLAG="-lunwind"
1362   else
1363     LIBUNWIND_FLAG=""
1364   fi
1365   AC_SUBST(LIBUNWIND_FLAG)
1366 ])
1367
1368
1369 dnl
1370 dnl Check for template specializations for the 'long long' type extension.
1371 dnl The result determines only whether 'long long' I/O is enabled; things
1372 dnl like numeric_limits<> specializations are always available.
1373 dnl
1374 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1375 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1376 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1377 dnl       Where DEFAULT is either `yes' or `no'.
1378 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1379 dnl
1380 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1381   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1382
1383   AC_LANG_SAVE
1384   AC_LANG_CPLUSPLUS
1385
1386   AC_MSG_CHECKING([for enabled long long I/O support])
1387   # iostreams require strtoll, strtoull to compile
1388   AC_TRY_COMPILE([#include <stdlib.h>],
1389                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1390   AC_TRY_COMPILE([#include <stdlib.h>],
1391                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1392
1393   # Option parsed, now set things appropriately
1394   if test $enable_long_long = yes; then
1395     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1396   fi
1397   AC_MSG_RESULT($enable_long_long)
1398
1399   AC_LANG_RESTORE
1400 ])
1401
1402
1403 dnl
1404 dnl Check to see if building and using a C++ precompiled header can be done.
1405 dnl
1406 dnl --enable-libstdcxx-pch=yes
1407 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1408 dnl may work, after some light-hearted attempts to puzzle out compiler
1409 dnl support, flip bits on in include/Makefile.am
1410 dnl
1411 dnl --disable-libstdcxx-pch
1412 dnl turns off attempts to use or build stdc++.h.gch.
1413 dnl
1414 dnl Substs:
1415 dnl  glibcxx_PCHFLAGS
1416 dnl
1417 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1418   AC_MSG_CHECKING([for enabled PCH])
1419   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1420   AC_MSG_RESULT([$enable_libstdcxx_pch])
1421
1422   if test $enable_libstdcxx_pch = yes; then
1423     AC_CACHE_CHECK([for compiler with PCH support],
1424       [glibcxx_cv_prog_CXX_pch],
1425       [ac_save_CXXFLAGS="$CXXFLAGS"
1426        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1427        AC_LANG_SAVE
1428        AC_LANG_CPLUSPLUS
1429        echo '#include <math.h>' > conftest.h
1430        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1431                           -o conftest.h.gch 1>&5 2>&1 &&
1432                 echo '#error "pch failed"' > conftest.h &&
1433           echo '#include "conftest.h"' > conftest.cc &&
1434                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1435        then
1436          glibcxx_cv_prog_CXX_pch=yes
1437        else
1438          glibcxx_cv_prog_CXX_pch=no
1439        fi
1440        rm -f conftest*
1441        CXXFLAGS=$ac_save_CXXFLAGS
1442        AC_LANG_RESTORE
1443       ])
1444     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1445   fi
1446
1447   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1448   if test $enable_libstdcxx_pch = yes; then
1449     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1450   else
1451     glibcxx_PCHFLAGS=""
1452   fi
1453   AC_SUBST(glibcxx_PCHFLAGS)
1454 ])
1455
1456
1457 dnl
1458 dnl Check for exception handling support.  If an explicit enable/disable
1459 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1460 dnl target may or may not support call frame exceptions.
1461 dnl
1462 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1463 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1464 dnl Neither one forces an attempt at detection.
1465 dnl
1466 dnl Defines:
1467 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1468 dnl
1469 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1470   AC_MSG_CHECKING([for exception model to use])
1471   AC_LANG_SAVE
1472   AC_LANG_CPLUSPLUS
1473   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1474     [force use of builtin_setjmp for exceptions],
1475     [permit yes|no|auto])
1476
1477   if test $enable_sjlj_exceptions = auto; then
1478     # Botheration.  Now we've got to detect the exception model.  Link tests
1479     # against libgcc.a are problematic since we've not been given proper -L
1480     # bits for single-tree newlib and libgloss.
1481     #
1482     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1483     cat > conftest.$ac_ext << EOF
1484 [#]line __oline__ "configure"
1485 struct S { ~S(); };
1486 void bar();
1487 void foo()
1488 {
1489   S s;
1490   bar();
1491 }
1492 EOF
1493     old_CXXFLAGS="$CXXFLAGS"
1494     CXXFLAGS=-S
1495     if AC_TRY_EVAL(ac_compile); then
1496       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1497         enable_sjlj_exceptions=yes
1498       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1499         enable_sjlj_exceptions=no
1500       fi
1501     fi
1502     CXXFLAGS="$old_CXXFLAGS"
1503     rm -f conftest*
1504   fi
1505
1506   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1507   # to two different models.
1508   case $enable_sjlj_exceptions in
1509     yes)
1510       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1511         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1512       ac_exception_model_name=sjlj
1513       ;;
1514     no)
1515       ac_exception_model_name="call frame"
1516       ;;
1517     *)
1518       AC_MSG_ERROR([unable to detect exception model])
1519       ;;
1520   esac
1521  AC_LANG_RESTORE
1522  AC_MSG_RESULT($ac_exception_model_name)
1523 ])
1524
1525
1526 dnl
1527 dnl Add version tags to symbols in shared library (or not), additionally
1528 dnl marking other symbols as private/local (or not).
1529 dnl
1530 dnl --enable-symvers=style adds a version script to the linker call when
1531 dnl       creating the shared library.  The choice of version script is
1532 dnl       controlled by 'style'.
1533 dnl --disable-symvers does not.
1534 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1535 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1536 dnl       choose a default style based on linker characteristics.  Passing
1537 dnl       'no' disables versioning.
1538 dnl
1539 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1540
1541 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1542   [enables symbol versioning of the shared library],
1543   [permit yes|no|gnu])
1544
1545 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1546 # don't know enough about $LD to do tricks...
1547 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1548 # FIXME  The following test is too strict, in theory.
1549 if test $enable_shared = no ||
1550         test "x$LD" = x ||
1551         test x$glibcxx_gnu_ld_version = x; then
1552   enable_symvers=no
1553 fi
1554
1555 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1556 if test $enable_symvers != no; then
1557   AC_MSG_CHECKING([for shared libgcc])
1558   ac_save_CFLAGS="$CFLAGS"
1559   CFLAGS=' -lgcc_s'
1560   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1561   CFLAGS="$ac_save_CFLAGS"
1562   AC_MSG_RESULT($glibcxx_shared_libgcc)
1563 fi
1564
1565 # For GNU ld, we need at least this version.  The format is described in
1566 # GLIBCXX_CHECK_LINKER_FEATURES above.
1567 glibcxx_min_gnu_ld_version=21400
1568 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1569
1570 # Check to see if unspecified "yes" value can win, given results above.
1571 # Change "yes" into either "no" or a style name.
1572 if test $enable_symvers = yes; then
1573   if test $with_gnu_ld = yes &&
1574      test $glibcxx_shared_libgcc = yes;
1575   then
1576     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1577       enable_symvers=gnu
1578     else
1579       # The right tools, the right setup, but too old.  Fallbacks?
1580       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1581       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1582       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1583       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1584       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1585         # Globbing fix is present, proper block support is not.
1586         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1587         dnl enable_symvers=???
1588         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1589         enable_symvers=no
1590       else
1591         # 2.11 or older.
1592         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1593         enable_symvers=no
1594       fi
1595     fi
1596   else
1597     # just fail for now
1598     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1599     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1600     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1601     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1602     enable_symvers=no
1603   fi
1604 fi
1605
1606 # Everything parsed; figure out what file to use.
1607 case $enable_symvers in
1608   no)
1609     SYMVER_MAP=config/linker-map.dummy
1610     ;;
1611   gnu)
1612     SYMVER_MAP=config/linker-map.gnu
1613     AC_DEFINE(_GLIBCXX_SYMVER)
1614     ;;
1615 esac
1616
1617 AC_SUBST(SYMVER_MAP)
1618 AC_SUBST(port_specific_symbol_files)
1619 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1620 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1621 ])
1622
1623
1624 dnl
1625 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1626 dnl We must stage the required headers so that they will be installed
1627 dnl with the library (unlike libgcc, the STL implementation is provided
1628 dnl solely within headers).  Since we must not inject random user-space
1629 dnl macro names into user-provided C++ code, we first stage into <file>-in
1630 dnl and process to <file> with an output command.  The reason for a two-
1631 dnl stage process here is to correctly handle $srcdir!=$objdir without
1632 dnl having to write complex code (the sed commands to clean the macro
1633 dnl namespace are complex and fragile enough as it is).  We must also
1634 dnl add a relative path so that -I- is supported properly.
1635 dnl
1636 dnl Substs:
1637 dnl  glibcxx_thread_h
1638 dnl
1639 dnl Defines:
1640 dnl  HAVE_GTHR_DEFAULT
1641 dnl  _GLIBCXX_SUPPORTS_WEAK
1642 dnl
1643 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1644   AC_MSG_CHECKING([for thread model used by GCC])
1645   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1646   AC_MSG_RESULT([$target_thread_file])
1647
1648   if test $target_thread_file != single; then
1649     AC_DEFINE(HAVE_GTHR_DEFAULT)
1650     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1651   fi
1652
1653   glibcxx_thread_h=gthr-$target_thread_file.h
1654   AC_SUBST(glibcxx_thread_h)
1655 ])
1656
1657
1658 # Check whether LC_MESSAGES is available in <locale.h>.
1659 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1660 #
1661 # This file file be copied and used freely without restrictions.  It can
1662 # be used in projects which are not available under the GNU Public License
1663 # but which still want to provide support for the GNU gettext functionality.
1664 # Please note that the actual code is *not* freely available.
1665
1666 # serial 1
1667 AC_DEFUN(AC_LC_MESSAGES, [
1668   AC_CHECK_HEADER(locale.h, [
1669     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1670       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1671        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1672     if test $ac_cv_val_LC_MESSAGES = yes; then
1673       AC_DEFINE(HAVE_LC_MESSAGES)
1674     fi
1675   ])
1676 ])
1677
1678
1679 sinclude([../libtool.m4])
1680 dnl The lines below arrange for aclocal not to bring an installed
1681 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1682 dnl add a definition of LIBTOOL to Makefile.in.
1683 ifelse(,,,[AC_SUBST(LIBTOOL)
1684 AC_DEFUN([AM_PROG_LIBTOOL])
1685 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1686 AC_DEFUN([AC_PROG_LD])
1687 ])
1688
1689 dnl vim:et:ts=2:sw=2