libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl Initialize configure bits.
   3 dnl
   4 dnl Define OPTLEVEL='-O2' if new inlining code present.
   5 dnl
   6 dnl GLIBCPP_CONFIGURE
   7 AC_DEFUN(GLIBCPP_CONFIGURE, [
   8   dnl Default to --enable-multilib
   9   AC_ARG_ENABLE(multilib,
  10   [  --enable-multilib       build hella library versions (default)],
  11   [case "${enableval}" in
  12     yes) multilib=yes ;;
  13     no)  multilib=no ;;
  14     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  15    esac], [multilib=yes])dnl
  16
  17   dnl We may get other options which we dont document:
  18   dnl --with-target-subdir, --with-multisrctop, --with-multisubdir
  19   if test "[$]{srcdir}" = "."; then
  20     if test "[$]{with_target_subdir}" != "."; then
  21       glibcpp_basedir="[$]{srcdir}/[$]{with_multisrctop}../$1"
  22     else
  23       glibcpp_basedir="[$]{srcdir}/[$]{with_multisrctop}$1"
  24     fi
  25   else
  26     glibcpp_basedir="[$]{srcdir}/$1"
  27   fi
  28   AC_SUBST(glibcpp_basedir)
  29
  30   AM_INIT_AUTOMAKE(libstdc++, 2.90.8)
  31
  32   # Never versions of autoconf add an underscore to these functions.
  33   # Prevent future problems ...
  34   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  35   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  36   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  37   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  38
  39 #  AC_PROG_CC
  40
  41 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  42 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  43 # are probably using a cross compiler, which will not be able to fully
  44 # link an executable.  This should really be fixed in autoconf
  45 # itself.
  46
  47 AC_DEFUN(LIB_AC_PROG_CC,
  48 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  49 dnl Fool anybody using AC_PROG_CC.
  50 AC_PROVIDE([AC_PROG_CC])
  51 AC_CHECK_PROG(CC, gcc, gcc)
  52 if test -z "$CC"; then
  53   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  54   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  55 fi
  56
  57 AC_PROG_CC_GNU
  58
  59 if test $ac_cv_prog_gcc = yes; then
  60   GCC=yes
  61 dnl Check whether -g works, even if CFLAGS is set, in case the package
  62 dnl plays around with CFLAGS (such as to build both debugging and
  63 dnl normal versions of a library), tasteless as that idea is.
  64   ac_test_CFLAGS="${CFLAGS+set}"
  65   ac_save_CFLAGS="$CFLAGS"
  66   CFLAGS=
  67   AC_PROG_CC_G
  68   if test "$ac_test_CFLAGS" = set; then
  69     CFLAGS="$ac_save_CFLAGS"
  70   elif test $ac_cv_prog_cc_g = yes; then
  71     CFLAGS="-g -O2"
  72   else
  73     CFLAGS="-O2"
  74   fi
  75 else
  76   GCC=
  77   test "${CFLAGS+set}" = set || CFLAGS="-g"
  78 fi
  79 ])
  80
  81 LIB_AC_PROG_CC
  82
  83 # Can't just call these here as g++ requires libstc++ to be built....
  84 #  AC_PROG_CXX
  85
  86 # Likewise for AC_PROG_CXX.
  87 AC_DEFUN(LIB_AC_PROG_CXX,
  88 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
  89 dnl Fool anybody using AC_PROG_CXX.
  90 AC_PROVIDE([AC_PROG_CXX])
  91 # Use CXX_libstdcxx so that we do not cause CXX to be cached with the
  92 # flags that come in CXX while configuring libstdc++.  They're different
  93 # from those used for all other target libraries.  If CXX is set in
  94 # the environment, respect that here.
  95 CXX_libstdcxx=$CXX
  96 AC_CHECK_PROGS(CXX_libstdcxx, $CCC c++ g++ gcc CC cxx cc++, gcc)
  97 CXX=$CXX_libstdcxx
  98 AC_SUBST(CXX)
  99 test -z "$CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 100
 101 AC_PROG_CXX_GNU
 102
 103 if test $ac_cv_prog_gxx = yes; then
 104   GXX=yes
 105 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 106 dnl plays around with CXXFLAGS (such as to build both debugging and
 107 dnl normal versions of a library), tasteless as that idea is.
 108   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 109   ac_save_CXXFLAGS="$CXXFLAGS"
 110   CXXFLAGS=
 111   AC_PROG_CXX_G
 112   if test "$ac_test_CXXFLAGS" = set; then
 113     CXXFLAGS="$ac_save_CXXFLAGS"
 114   elif test $ac_cv_prog_cxx_g = yes; then
 115     CXXFLAGS="-g -O2"
 116   else
 117     CXXFLAGS="-O2"
 118   fi
 119 else
 120   GXX=
 121   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 122 fi
 123 ])
 124
 125 LIB_AC_PROG_CXX
 126
 127   AC_CHECK_TOOL(AS, as)
 128   AC_CHECK_TOOL(AR, ar)
 129   AC_CHECK_TOOL(RANLIB, ranlib, :)
 130
 131   AC_PROG_INSTALL
 132
 133   AM_MAINTAINER_MODE
 134
 135   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 136   # at least currently, we never actually build a program, so we never
 137   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 138   # fails, because we are probably configuring with a cross compiler
 139   # which cant create executables.  So we include AC_EXEEXT to keep
 140   # automake happy, but we dont execute it, since we dont care about
 141   # the result.
 142   if false; then
 143     AC_EXEEXT
 144   fi
 145
 146   # configure.host sets the following important variables
 147   #        glibcpp_cflags    - host specific C compiler flags
 148   #        glibcpp_cxxflags  - host specific C++ compiler flags
 149   glibcpp_cflags=
 150   glibcpp_cxxflags=
 151
 152   . [$]{glibcpp_basedir}/configure.host
 153
 154   case [$]{glibcpp_basedir} in
 155     /* | [A-Za-z]:[/\\]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 156     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 157   esac
 158
 159   # This does for the target what configure.host does for the host.  In
 160   # addition to modifying the same flags, it also sets up symlinks.
 161   GLIBCPP_CHECK_TARGET
 162
 163   GLIBCPP_CFLAGS="[$]{glibcpp_cflags}"
 164   GLIBCPP_CXXFLAGS="[$]{glibcpp_cxxflags}"
 165   AC_SUBST(GLIBCPP_CFLAGS)
 166   AC_SUBST(GLIBCPP_CXXFLAGS)
 167 ])
 168
 169
 170 dnl
 171 dnl Check to see if g++ can compile this library, and if so, if any version-
 172 dnl specific precautions need to be taken.
 173 dnl
 174 dnl GLIBCPP_CHECK_COMPILER_VERSION
 175 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 176 if test ! -f stamp-sanity-compiler; then
 177   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 178   AC_LANG_SAVE
 179   AC_LANG_CPLUSPLUS
 180   AC_EGREP_CPP(ok, [
 181   #if (__GNUC__ > 2) || (__GNUC__ == 2 && __GNUC_MINOR__ >= 95)
 182     ok
 183   #endif
 184   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to gcc-2.95 or above]))
 185   AC_LANG_RESTORE
 186   AC_MSG_RESULT($gpp_satisfactory)
 187   touch stamp-sanity-compiler
 188 fi
 189 ])
 190
 191
 192 dnl
 193 dnl Test for newer compiler features, or features that are present in newer
 194 dnl compiler version but not older compiler versions should be placed
 195 dnl here.
 196 dnl
 197 dnl Define WFMT_FLAGS='-fdiagnostics-show-location=once' if possible
 198 dnl
 199 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 200 dnl new inlining code or the new system_header pragma will die on -Werror.
 201 dnl Leave it out by default and use maint-mode to use it.
 202 dnl
 203 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 204 dnl compiler supports it.
 205 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 206 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 207   # All these tests are for C++; save the language and the compiler flags.
 208   # The CXXFLAGS thing is suspicious, but based on similar bits
 209   # found in GLIBCPP_CONFIGURE.
 210   AC_LANG_SAVE
 211   AC_LANG_CPLUSPLUS
 212   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 213   ac_save_CXXFLAGS="$CXXFLAGS"
 214
 215   # Check for maintainer-mode bits.
 216   if test x"$USE_MAINTAINER_MODE" = xno; then
 217     WERROR=''
 218   else
 219     WERROR='-Werror'
 220   fi
 221
 222   # Check for more sophisticated diagnostic control.
 223   AC_MSG_CHECKING([for g++ that supports -fdiagnostics-show-location=once])
 224   CXXFLAGS='-Werror -fdiagnostics-show-location=once'
 225   AC_TRY_COMPILE(, [int foo;
 226   ], [ac_gabydiags=yes], [ac_gabydiags=no])
 227   if test "$ac_test_CXXFLAGS" = set; then
 228     CXXFLAGS="$ac_save_CXXFLAGS"
 229   else
 230     # this is the suspicious part
 231     CXXFLAGS=''
 232   fi
 233   if test "$ac_gabydiags" = "yes"; then
 234     WFMT_FLAGS='-fdiagnostics-show-location=once'
 235   fi
 236   AC_MSG_RESULT($ac_gabydiags)
 237
 238   # Check for -ffunction-sections -fdata-sections
 239   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 240   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 241   AC_TRY_COMPILE(, [int foo;
 242   ], [ac_fdsections=yes], [ac_fdsections=no])
 243   if test "$ac_test_CXXFLAGS" = set; then
 244     CXXFLAGS="$ac_save_CXXFLAGS"
 245   else
 246     # this is the suspicious part
 247     CXXFLAGS=''
 248   fi
 249   if test "$ac_fdsections" = "yes"; then
 250     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 251   fi
 252   AC_MSG_RESULT($ac_fdsections)
 253
 254   AC_LANG_RESTORE
 255   AC_SUBST(WERROR)
 256   AC_SUBST(WFMT_FLAGS)
 257   AC_SUBST(SECTION_FLAGS)
 258 ])
 259
 260
 261 dnl
 262 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 263 dnl the native linker is in use, all variables will be defined to something
 264 dnl safe (like an empty string).
 265 dnl
 266 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 267 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 268 dnl
 269 dnl GLIBCPP_CHECK_LINKER_FEATURES
 270 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 271   # If we're not using GNU ld, then there's no point in even trying these
 272   # tests.  Check for that first.  We should have already tested for gld
 273   # by now (in libtool), but require it now just to be safe...
 274   SECTION_LDFLAGS=''
 275   OPT_LDFLAGS=''
 276   AC_REQUIRE([AC_PROG_LD])
 277
 278   # Set --gc-sections.
 279   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 280     # GNU ld it is!  Joy and bunny rabbits!
 281
 282     # All these tests are for C++; save the language and the compiler flags.
 283     # Need to do this so that g++ won't try to link in libstdc++
 284     ac_test_CFLAGS="${CFLAGS+set}"
 285     ac_save_CFLAGS="$CFLAGS"
 286     CFLAGS='-x c++  -Wl,--gc-sections'
 287
 288     # Check for -Wl,--gc-sections
 289     # XXX This test is broken at the moment, as symbols required for
 290     # linking are now in libsupc++ (not built yet.....). In addition,
 291     # this test has cored on solaris in the past. In addition,
 292     # --gc-sections doesn't really work at the moment (keeps on discarding
 293     # used sections, first .eh_frame and now some of the glibc sections for
 294     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 295     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 296     AC_TRY_RUN([
 297      int main(void)
 298      {
 299        try { throw 1; }
 300        catch (...) { };
 301        return 0;
 302      }
 303     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 304     if test "$ac_test_CFLAGS" = set; then
 305       CFLAGS="$ac_save_CFLAGS"
 306     else
 307       # this is the suspicious part
 308       CFLAGS=''
 309     fi
 310     if test "$ac_sectionLDflags" = "yes"; then
 311       SECTION_LDFLAGS='-Wl,--gc-sections'
 312     fi
 313     AC_MSG_RESULT($ac_sectionLDflags)
 314   fi
 315
 316   # Set linker optimization flags.
 317   if test "$ac_cv_prog_gnu_ld" = "yes"; then
 318     OPT_LDFLAGS='-Wl,-O1'
 319   fi
 320
 321   AC_SUBST(SECTION_LDFLAGS)
 322   AC_SUBST(OPT_LDFLAGS)
 323 ])
 324
 325
 326 dnl
 327 dnl Check to see if the (math function) argument passed is
 328 dnl 1) declared when using the c++ compiler
 329 dnl 2) has "C" linkage
 330 dnl
 331 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 332 dnl
 333 dnl argument 1 is name of function to check
 334 dnl
 335 dnl ASSUMES argument is a math function with ONE parameter
 336 dnl
 337 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 338 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 339   AC_MSG_CHECKING([for $1 declaration])
 340   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 341     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 342       AC_LANG_SAVE
 343       AC_LANG_CPLUSPLUS
 344       AC_TRY_COMPILE([#include <math.h>],
 345                      [ $1(0);],
 346                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 347       AC_LANG_RESTORE
 348     ])
 349   fi
 350   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 351   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 352     AC_CHECK_FUNCS($1)
 353   fi
 354 ])
 355
 356
 357 dnl
 358 dnl Check to see if the (math function) argument passed is
 359 dnl 1) declared when using the c++ compiler
 360 dnl 2) has "C" linkage
 361 dnl
 362 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 363 dnl
 364 dnl argument 1 is name of function to check
 365 dnl
 366 dnl ASSUMES argument is a math function with TWO parameters
 367 dnl
 368 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 369 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 370   AC_MSG_CHECKING([for $1 declaration])
 371   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 372     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 373       AC_LANG_SAVE
 374       AC_LANG_CPLUSPLUS
 375       AC_TRY_COMPILE([#include <math.h>],
 376                      [ $1(0, 0);],
 377                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 378       AC_LANG_RESTORE
 379     ])
 380   fi
 381   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 382   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 383     AC_CHECK_FUNCS($1)
 384   fi
 385 ])
 386
 387
 388 dnl
 389 dnl Check to see if the (math function) argument passed is
 390 dnl 1) declared when using the c++ compiler
 391 dnl 2) has "C" linkage
 392 dnl
 393 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 394 dnl
 395 dnl argument 1 is name of function to check
 396 dnl
 397 dnl ASSUMES argument is a math function with THREE parameters
 398 dnl
 399 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 400 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 401   AC_MSG_CHECKING([for $1 declaration])
 402   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 403     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 404       AC_LANG_SAVE
 405       AC_LANG_CPLUSPLUS
 406       AC_TRY_COMPILE([#include <math.h>],
 407                      [ $1(0, 0, 0);],
 408                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 409       AC_LANG_RESTORE
 410     ])
 411   fi
 412   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 413   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 414     AC_CHECK_FUNCS($1)
 415   fi
 416 ])
 417
 418
 419 dnl
 420 dnl Check to see if the (stdlib function) argument passed is
 421 dnl 1) declared when using the c++ compiler
 422 dnl 2) has "C" linkage
 423 dnl
 424 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 425 dnl Define HAVE_STRTOF if "strtof" is declared and links
 426 dnl
 427 dnl argument 1 is name of function to check
 428 dnl
 429 dnl ASSUMES argument is a math function with TWO parameters
 430 dnl
 431 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 432 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 433   AC_MSG_CHECKING([for $1 declaration])
 434   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 435     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 436       AC_LANG_SAVE
 437       AC_LANG_CPLUSPLUS
 438       AC_TRY_COMPILE([#include <stdlib.h>],
 439                      [ $1(0, 0);],
 440                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 441       AC_LANG_RESTORE
 442     ])
 443   fi
 444   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 445   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 446     AC_CHECK_FUNCS($1)
 447   fi
 448 ])
 449
 450
 451 dnl
 452 dnl Because the builtins are picky picky picky about the arguments they take,
 453 dnl do an explict linkage tests here.
 454 dnl Check to see if the (math function) argument passed is
 455 dnl 1) declared when using the c++ compiler
 456 dnl 2) has "C" linkage
 457 dnl
 458 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 459 dnl
 460 dnl argument 1 is name of function to check
 461 dnl
 462 dnl ASSUMES argument is a math function with ONE parameter
 463 dnl
 464 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 465 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 466   AC_MSG_CHECKING([for $1 declaration])
 467   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 468     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 469       AC_LANG_SAVE
 470       AC_LANG_CPLUSPLUS
 471       AC_TRY_COMPILE([#include <math.h>],
 472                      [ $1(0);],
 473                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 474       AC_LANG_RESTORE
 475     ])
 476   fi
 477   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 478   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 479     AC_MSG_CHECKING([for $1 linkage])
 480     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 481       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 482         AC_TRY_LINK([#include <math.h>],
 483                     [ $1(0);],
 484                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 485       ])
 486     fi
 487     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 488     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 489       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 490       AC_DEFINE_UNQUOTED(${ac_tr_func})
 491     fi
 492   fi
 493 ])
 494
 495
 496 dnl
 497 dnl Check to see what builtin math functions are supported
 498 dnl
 499 dnl check for __builtin_abs
 500 dnl check for __builtin_fabsf
 501 dnl check for __builtin_fabs
 502 dnl check for __builtin_fabl
 503 dnl check for __builtin_labs
 504 dnl check for __builtin_sqrtf
 505 dnl check for __builtin_sqrtl
 506 dnl check for __builtin_fsqrt
 507 dnl check for __builtin_sinf
 508 dnl check for __builtin_sin
 509 dnl check for __builtin_sinl
 510 dnl check for __builtin_cosf
 511 dnl check for __builtin_cos
 512 dnl check for __builtin_cosl
 513 dnl
 514 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 515 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 516   dnl Test for builtin math functions.
 517   dnl These are made in gcc/c-common.c
 518   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 519   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 520   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 521   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 522   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 523
 524   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 525   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fsqrt)
 526   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 527
 528   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 529   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 530   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 531
 532   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 533   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 534   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 535
 536   dnl There is, without a doubt, a more elegant way to have these
 537   dnl names exported so that they won't be stripped out of acconfig.h by
 538   dnl autoheader. I leave this as an exercise to somebody less frustrated
 539   dnl than I.... please email the libstdc++ list if you can figure out a
 540   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 541   dnl AC_CHECK_FUNC for things to steal.)
 542   dummyvar=no
 543   if test x$dummyvar = x"yes"; then
 544     AC_DEFINE(HAVE___BUILTIN_ABS)
 545     AC_DEFINE(HAVE___BUILTIN_LABS)
 546     AC_DEFINE(HAVE___BUILTIN_COS)
 547     AC_DEFINE(HAVE___BUILTIN_COSF)
 548     AC_DEFINE(HAVE___BUILTIN_COSL)
 549     AC_DEFINE(HAVE___BUILTIN_FABS)
 550     AC_DEFINE(HAVE___BUILTIN_FABSF)
 551     AC_DEFINE(HAVE___BUILTIN_FABSL)
 552     AC_DEFINE(HAVE___BUILTIN_SIN)
 553     AC_DEFINE(HAVE___BUILTIN_SINF)
 554     AC_DEFINE(HAVE___BUILTIN_SINL)
 555     AC_DEFINE(HAVE___BUILTIN_FSQRT)
 556     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 557     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 558   fi
 559 ])
 560
 561
 562 dnl
 563 dnl Check to see what the underlying c library
 564 dnl These checks need to do two things:
 565 dnl 1) make sure the name is declared when using the c++ compiler
 566 dnl 2) make sure the name has "C" linkage
 567 dnl This might seem like overkill but experience has shown that it's not...
 568 dnl
 569 dnl Define HAVE_STRTOF etc if "strtof" is found.
 570 dnl Define HAVE_STRTOLD etc if "strtold" is found.
 571 dnl
 572 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 573 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 574   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 575   ac_save_CXXFLAGS="$CXXFLAGS"
 576   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 577
 578   AC_CHECK_FUNCS(strtof)
 579   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 580
 581   CXXFLAGS="$ac_save_CXXFLAGS"
 582 ])
 583
 584
 585 dnl
 586 dnl Check to see what the underlying c library or math library is like.
 587 dnl These checks need to do two things:
 588 dnl 1) make sure the name is declared when using the c++ compiler
 589 dnl 2) make sure the name has "C" linkage
 590 dnl This might seem like overkill but experience has shown that it's not...
 591 dnl
 592 dnl Define HAVE_CARGF etc if "cargf" is found.
 593 dnl
 594 dnl GLIBCPP_CHECK_MATH_SUPPORT
 595 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 596   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 597   ac_save_CXXFLAGS="$CXXFLAGS"
 598   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 599
 600   dnl Check libm
 601   AC_CHECK_LIB(m, sin, libm="-lm")
 602   ac_save_LIBS="$LIBS"
 603   LIBS="$LIBS $libm"
 604
 605   dnl Check to see if certain C math functions exist.
 606   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 607   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 608   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 609   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 610   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 611   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 612   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 613
 614   dnl Check to see if basic C math functions have float versions.
 615   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 616   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 617   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignf)
 618   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(acosf)
 619   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(asinf)
 620   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(atanf)
 621   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 622   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(ceilf)
 623   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(cosf)
 624   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(coshf)
 625   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expf)
 626   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 627   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(floorf)
 628   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 629   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 630   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 631   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 632   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 633   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 634   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 635   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinf)
 636   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinhf)
 637   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 638   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanf)
 639   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanhf)
 640   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 641   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 642
 643   dnl Check to see if basic C math functions have long double versions.
 644   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 645   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 646   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 647   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(acosl)
 648   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(asinl)
 649   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(atanl)
 650   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 651   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(ceill)
 652   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(cosl)
 653   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(coshl)
 654   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 655   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 656   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(floorl)
 657   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 658   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 659   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 660   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 661   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 662   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 663   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 664   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinl)
 665   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sinhl)
 666   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 667   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanl)
 668   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(tanhl)
 669   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 670   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 671
 672   dnl Some runtimes have these functions with a preceding underscore. Please
 673   dnl keep this sync'd with the one above. And if you add any new symbol,
 674   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 675   dnl Check to see if certain C math functions exist.
 676   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isinf)
 677   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isnan)
 678   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_finite)
 679   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_copysign)
 680   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(_sincos)
 681   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_fpclass)
 682   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_qfpclass)
 683
 684   dnl Check to see if basic C math functions have float versions.
 685   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isnanf)
 686   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isinff)
 687   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_copysignf)
 688   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_acosf)
 689   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_asinf)
 690   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_atanf)
 691   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_atan2f)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_ceilf)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_cosf)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_coshf)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_expf)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_fabsf)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_floorf)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_fmodf)
 699   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_frexpf)
 700   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_ldexpf)
 701   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_logf)
 702   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_log10f)
 703   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_modff)
 704   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_powf)
 705   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinf)
 706   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinhf)
 707   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sqrtf)
 708   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanf)
 709   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanhf)
 710   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(_sincosf)
 711   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_finitef)
 712
 713   dnl Check to see if basic C math functions have long double versions.
 714   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isnanl)
 715   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_isinfl)
 716   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_copysignl)
 717   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_acosl)
 718   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_asinl)
 719   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_atanl)
 720   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_atan2l)
 721   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_ceill)
 722   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_cosl)
 723   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_coshl)
 724   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_expl)
 725   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_fabsl)
 726   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_floorl)
 727   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_fmodl)
 728   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_frexpl)
 729   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_ldexpl)
 730   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_logl)
 731   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_log10l)
 732   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_modfl)
 733   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(_powl)
 734   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinl)
 735   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sinhl)
 736   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_sqrtl)
 737   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanl)
 738   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_tanhl)
 739   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(_sincosl)
 740   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(_finitel)
 741
 742   LIBS="$ac_save_LIBS"
 743   CXXFLAGS="$ac_save_CXXFLAGS"
 744 ])
 745
 746
 747 dnl
 748 dnl Check to see if there is native support for complex
 749 dnl
 750 dnl Don't compile bits in math/* if native support exits.
 751 dnl
 752 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "atan2l/copysignl" is found.
 753 dnl
 754 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 755 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 756   dnl Check for complex versions of math functions of platform.
 757   AC_CHECK_HEADERS([complex.h])
 758   AC_CHECK_LIB(m, main)
 759   AC_REPLACE_MATHFUNCS(csqrt csqrtf nan hypot hypotf)
 760
 761   dnl Compile the long double complex functions only if the function
 762   dnl provides the non-complex long double functions that are needed.
 763   dnl Currently this includes copysignl and atan2l, which should be
 764   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 765   USE_COMPLEX_LONG_DOUBLE=no
 766   if test x$ac_cv_func_atan2l = x"yes" \
 767      && test x$ac_cv_func_copysignl = x"yes"; then
 768     USE_COMPLEX_LONG_DOUBLE=yes
 769     AC_REPLACE_MATHFUNCS(csqrtl hypotl signbitl)
 770   fi
 771
 772   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 773 ])
 774
 775
 776 dnl Check to see what architecture and operating system we are compiling
 777 dnl for.  Also, if architecture- or OS-specific flags are required for
 778 dnl compilation, pick them up here.
 779 dnl
 780 dnl GLIBCPP_CHECK_TARGET
 781 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 782     . [$]{glibcpp_basedir}/configure.target
 783     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 784     AC_MSG_RESULT(OS config directory is $os_include_dir)
 785     AC_LINK_FILES($os_include_dir/bits/os_defines.h, include/bits/os_defines.h)
 786 ])
 787
 788
 789 dnl
 790 dnl Check to see what the underlying c library's interface to ctype looks
 791 dnl like. Bits of locale rely on things like isspace, toupper, etc. This
 792 dnl stuff makes sure the right bits from the clibrary get called.
 793 dnl
 794 dnl Depending on what is found, select various configure/*/bits/ctype_base.h
 795 dnl Depending on what is found, select various configure/*/ctype.cc
 796 dnl
 797 dnl GLIBCPP_CHECK_CTYPE_SUPPORT
 798 AC_DEFUN(GLIBCPP_CHECK_CTYPE_SUPPORT, [
 799   AC_CHECK_HEADER(ctype.h, [
 800
 801     dnl If doesn't match any specified, go with defaults.
 802     ctype_default=yes
 803
 804     dnl Test for <ctype> functionality -- GNU/Linux
 805     AC_MSG_CHECKING([<ctype> for GNU/Linux])
 806     AC_TRY_COMPILE([#include <ctype.h>],
 807     [int
 808     foo (int a)
 809     { return _ISspace + _ISprint + _IScntrl + _ISupper + _ISlower + _ISalpha \
 810         + _ISdigit + _ISpunct + _ISxdigit + _ISalnum + _ISgraph \
 811         + __ctype_tolower[a] + __ctype_toupper[a] + __ctype_b[a];}], \
 812     ctype_linux=yes, ctype_linux=no)
 813     AC_MSG_RESULT($ctype_linux)
 814     if test $ctype_linux = "yes"; then
 815       ctype_include_dir="config/os/gnu-linux"
 816       ctype_default=no
 817     fi
 818
 819     dnl Test for <ctype> functionality -- FreeBSD 4.0
 820     if test $ctype_default = "yes"; then
 821     AC_MSG_CHECKING([<ctype> for FreeBSD 4.0])
 822     AC_TRY_COMPILE([#include <ctype.h>],
 823     [int
 824     foo (int a)
 825     { return _CTYPE_S + _CTYPE_R + _CTYPE_C + _CTYPE_U + _CTYPE_L + _CTYPE_A \
 826         + _CTYPE_D + _CTYPE_P + _CTYPE_X + _CTYPE_G ;}], \
 827     ctype_bsd=yes, ctype_bsd=no)
 828     AC_MSG_RESULT($ctype_bsd)
 829     if test $ctype_bsd = "yes"; then
 830       ctype_include_dir="config/os/bsd/freebsd"
 831       ctype_default=no
 832     fi
 833     fi
 834
 835     dnl Test for <ctype> functionality -- FreeBSD 3.4
 836     if test $ctype_default = "yes"; then
 837     AC_MSG_CHECKING([<ctype> for FreeBSD 3.4])
 838     AC_TRY_COMPILE([#include <ctype.h>],
 839     [int
 840     foo (int a)
 841     { return _S + _R + _C + _U + _L + _A \
 842       + _D + _P + _X + _G + __istype (a, 0);}], \
 843     ctype_freebsd34=yes, ctype_freebsd34=no)
 844     AC_MSG_RESULT($ctype_freebsd34)
 845     if test $ctype_freebsd34 = "yes"; then
 846       ctype_include_dir="config/os/bsd/freebsd"
 847       ctype_default=no
 848     fi
 849     fi
 850
 851     dnl Test for <ctype> functionality -- NetBSD
 852     if test $ctype_default = "yes"; then
 853     AC_MSG_CHECKING([<ctype> for NetBSD])
 854     AC_TRY_COMPILE([#include <ctype.h>],
 855     [int
 856     foo (int a)
 857     { return _S + _C + _U + _L \
 858       + _N + _P + _X + _tolower_tab_[a] + _toupper_tab_[a];}], \
 859     ctype_netbsd=yes, ctype_netbsd=no)
 860     AC_MSG_RESULT($ctype_netbsd)
 861     if test $ctype_netbsd = "yes"; then
 862       ctype_include_dir="config/os/bsd/netbsd"
 863       ctype_default=no
 864     fi
 865     fi
 866
 867     dnl Test for <ctype> functionality -- Solaris 2.6 and up
 868     if test $ctype_default = "yes"; then
 869     AC_MSG_CHECKING([<ctype> for Solaris 2.6,7,8])
 870     AC_TRY_COMPILE([#include <ctype.h>],
 871     [int
 872     foo (int a)
 873     { return _ISSPACE + _ISPRINT + _ISCNTRL + _ISUPPER + _ISLOWER + _ISALPHA \
 874         + _ISDIGIT + _ISPUNCT + _ISXDIGIT + _ISALNUM + _ISGRAPH \
 875         + __trans_lower[a] + __trans_upper[a] + __ctype_mask[a];}], \
 876     ctype_solaris=yes, ctype_solaris=no)
 877     AC_MSG_RESULT($ctype_solaris)
 878
 879     if test $ctype_solaris = "yes"; then
 880       AC_MSG_CHECKING([  for version])
 881       AC_LANG_CPLUSPLUS
 882       AC_TRY_COMPILE([#include <ctype.h>],
 883       [typedef long* __to_type; __to_type const& _M_toupper = __trans_upper;],\
 884       ctype_solaris26=yes, ctype_solaris26=no)
 885       AC_LANG_C
 886       if test $ctype_solaris26 = "yes"; then
 887         ctype_include_dir="config/os/solaris/solaris2.6"
 888         AC_MSG_RESULT([Solaris 2.6])
 889         ctype_default=no
 890       else
 891         ctype_include_dir="config/os/solaris/solaris2.7"
 892         AC_MSG_RESULT([Solaris 7,8])
 893         ctype_default=no
 894       fi
 895     fi
 896     fi
 897
 898     dnl Test for <ctype> functionality -- Solaris 2.5.1
 899     if test $ctype_default = "yes"; then
 900     AC_MSG_CHECKING([<ctype> for Solaris 2.5.1])
 901     AC_TRY_COMPILE([#include <ctype.h>],
 902     [int
 903     foo (int a)
 904     { return _U + _L + _N + _S + _P + _C + _X + _B \
 905         + __ctype[a];}], \
 906     ctype_solaris25=yes, ctype_solaris25=no)
 907     AC_MSG_RESULT($ctype_solaris25)
 908     if test $ctype_solaris25 = "yes"; then
 909       ctype_include_dir="config/os/solaris/solaris2.5"
 910       ctype_default=no
 911     fi
 912     fi
 913
 914     dnl Test for <ctype> functionality -- AIX
 915     if test $ctype_default = "yes"; then
 916     AC_MSG_CHECKING([<ctype> for AIX])
 917     AC_TRY_COMPILE([#include <ctype.h>],
 918     [int
 919     foo (int a)
 920     { return _ISSPACE + _ISPRINT + _ISCNTRL + _ISUPPER + _ISLOWER + _ISALPHA \
 921         + _ISDIGIT + _ISPUNCT + _ISXDIGIT + _ISALNUM + _ISGRAPH \
 922         + _VALC('a') + _IS('c', 0);}], \
 923     ctype_aix=yes, ctype_aix=no)
 924     AC_MSG_RESULT($ctype_aix)
 925     if test $ctype_aix = "yes"; then
 926       ctype_include_dir="config/os/aix"
 927       ctype_default=no
 928     fi
 929     fi
 930
 931     dnl Test for <ctype> functionality -- IRIX
 932     if test $ctype_default = "yes"; then
 933     AC_MSG_CHECKING([<ctype> for IRIX])
 934     AC_TRY_COMPILE([#include <ctype.h>],
 935     [int
 936     foo (int a)
 937     { return _U + _L + _N + _S + _P + _C + _B + _X + \
 938              _A + _PR + _G + _BL;}], \
 939     ctype_irix=yes, ctype_irix=no)
 940     AC_MSG_RESULT($ctype_irix)
 941     if test $ctype_irix = "yes"; then
 942       ctype_include_dir="config/os/irix"
 943       ctype_default=no
 944     fi
 945     fi
 946
 947     dnl Test for <ctype> functionality -- newlib
 948     if test $ctype_default = "yes"; then
 949     AC_MSG_CHECKING([<ctype> for newlib])
 950     AC_TRY_COMPILE([#include <ctype.h>],
 951     [int
 952     foo (int a)
 953     { return _U + _L + _N + _S + _P + _C + _X + _B \
 954         + _ctype_[a];}], \
 955     ctype_newlib=yes, ctype_newlib=no)
 956     AC_MSG_RESULT($ctype_newlib)
 957     if test $ctype_newlib = "yes"; then
 958       ctype_include_dir="config/os/newlib"
 959       ctype_default=no
 960     fi
 961     fi
 962
 963     if test $ctype_default = "yes"; then
 964       ctype_include_dir="config/os/generic"
 965       AC_MSG_WARN("Using default ctype headers.")
 966     fi
 967   ])
 968 ])
 969
 970
 971 dnl
 972 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 973 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 974 dnl must have been previously checked.)
 975 dnl
 976 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 977 dnl Define _GLIBCPP_NEED_MBSTATE_T if mbstate_t is not in wchar.h
 978 dnl
 979 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 980 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 981   if test x$enable_c_mbchar != xno; then
 982
 983     dnl Sanity check for existence of ISO C99 headers for extended encoding.
 984     AC_CHECK_HEADER(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 985     AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 986
 987     dnl Only continue checking if the ISO C99 headers exist.
 988     if test x"$ac_has_wchar_h" = xyes && test x"$ac_has_wctype_h" = xyes; then
 989
 990       dnl Test wchar.h for mbstate_t, which is needed for char_traits
 991       dnl and others.
 992       AC_MSG_CHECKING([for mbstate_t])
 993       AC_TRY_COMPILE([#include <wchar.h>],
 994       [mbstate_t teststate;],
 995       use_native_mbstatet=yes, use_native_mbstatet=no)
 996       AC_MSG_RESULT($use_native_mbstatet)
 997
 998       dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 999       dnl numeric_limits can instantiate type_traits<wchar_t>
1000       AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
1001       AC_TRY_COMPILE([#include <wchar.h>],
1002       [int i = WCHAR_MIN; int j = WCHAR_MAX;],
1003       has_wchar_minmax=yes, has_wchar_minmax=no)
1004       AC_MSG_RESULT($has_wchar_minmax)
1005
1006       dnl Test wchar.h for WEOF, which is what we use to determine whether
1007       dnl to specialize for char_traits<wchar_t> or not.
1008       AC_MSG_CHECKING([for WEOF])
1009       AC_TRY_COMPILE([
1010         #include <wchar.h>
1011         #include <stddef.h>],
1012       [wint_t i = WEOF;],
1013       has_weof=yes, has_weof=no)
1014       AC_MSG_RESULT($has_weof)
1015
1016       dnl Tests for wide character functions used in char_traits<wchar_t>.
1017       AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset \
1018       wcsrtombs mbsrtowcs, ac_wfuncs=yes, ac_wfuncs=no)
1019
1020       AC_MSG_CHECKING([for ISO C99 wchar_t support])
1021       if test x"$has_weof" = xyes && test x"$has_wchar_minmax" = xyes \
1022          && test x"$ac_wfuncs" = xyes; then
1023         ac_isoC99_wchar_t=yes
1024       else
1025         ac_isoC99_wchar_t=no
1026       fi
1027       AC_MSG_RESULT($ac_isoC99_wchar_t)
1028
1029       dnl Use iconv for wchar_t to char conversions. As such, check for
1030       dnl X/Open Portability Guide, version 2 features (XPG2).
1031       AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
1032       AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
1033
1034       dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
1035       AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
1036       ac_save_LIBS="$LIBS"
1037       LIBS="$LIBS $libiconv"
1038
1039       AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
1040       ac_XPG2funcs=yes, ac_XPG2funcs=no)
1041
1042       LIBS="$ac_save_LIBS"
1043
1044       AC_MSG_CHECKING([for XPG2 wchar_t support])
1045       if test x"$ac_has_iconv_h" = xyes && test x"$ac_has_langinfo_h" = xyes \
1046          && test x"$ac_XPG2funcs" = xyes; then
1047         ac_XPG2_wchar_t=yes
1048       else
1049         ac_XPG2_wchar_t=no
1050       fi
1051       AC_MSG_RESULT($ac_XPG2_wchar_t)
1052
1053       dnl At the moment, only enable wchar_t specializations if all the
1054       dnl above support is present.
1055       AC_MSG_CHECKING([for enabled wchar_t specializations])
1056       if test x"$ac_isoC99_wchar_t" = xyes \
1057          && test x"$ac_XPG2_wchar_t" = xyes; then
1058         libinst_wstring_la="libinst-wstring.la"
1059         AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
1060         AC_MSG_RESULT("yes")
1061       else
1062         libinst_wstring_la=""
1063         AC_MSG_RESULT("no")
1064       fi
1065       AC_SUBST(libinst_wstring_la)
1066
1067     else
1068       AC_MSG_WARN([<wchar.h> not found])
1069     fi
1070
1071   else
1072     dnl Wide characters disabled by the user.  Maybe print a warning?
1073     :
1074   fi
1075 ])
1076
1077
1078 dnl
1079 dnl Check to see if this version of GNU C++ is afflicted by bugs in
1080 dnl __complex__ float support.
1081 dnl
1082 dnl Define _GLIBCPP_BUGGY_FLOAT_COMPLEX if buggy.
1083 dnl
1084 dnl Check to see if this version of GNU C++ is afflicted by bugs in
1085 dnl __complex__ support.Check for buggy __complex__ that will cause ICE in
1086 dnl gcc-2.95.x when using the library, unless we define the default copy
1087 dnl ctor in the specializations of complex<>.
1088 dnl
1089 dnl Define _GLIBCPP_BUGGY_COMPLEX if buggy.
1090 dnl GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT
1091 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_COMPILER_SUPPORT, [
1092   AC_REQUIRE([AC_PROG_CXX])
1093
1094   AC_MSG_CHECKING([for GNU C++ __complex__ support])
1095   AC_CACHE_VAL(glibcpp_cv_complex, [
1096     AC_LANG_SAVE
1097     AC_LANG_CPLUSPLUS
1098     AC_TRY_COMPILE([struct dcomplex { __complex__ double x; }; \
1099                     dcomplex f(const dcomplex& x) { return dcomplex(x); }], \
1100                     [ dcomplex x; f(x); ],
1101       glibcpp_cv_complex=ok,
1102       glibcpp_cv_complex=buggy
1103     )
1104     AC_LANG_RESTORE
1105   ])
1106   AC_MSG_RESULT($glibcpp_cv_complex)
1107   if test $glibcpp_cv_complex = buggy; then
1108     AC_DEFINE(_GLIBCPP_BUGGY_COMPLEX)
1109   fi
1110
1111   AC_MSG_CHECKING([for GNU C++ __complex__ float support])
1112   AC_CACHE_VAL(glibcpp_cv_float_complex, [
1113     AC_LANG_SAVE
1114     AC_LANG_CPLUSPLUS
1115     rm -f conftest.h
1116     cat > conftest.h <<EOB
1117       //
1118       // Check for buggy __complex__ that causes ICE in most versions of egcs
1119       // and gcc-2.95.x on certain platforms (eg., x86-win32).
1120       //
1121       // See http://gcc.gnu.org/ml/gcc-bugs/1999-07n/msg00845.html for
1122       // more info on the bug itself.
1123       //
1124       struct
1125       float_complex
1126       {
1127        __complex__ float m_value;
1128        float_complex (float = 0.0f, float = 0.0f);
1129        float_complex (__complex__ float val) : m_value (val) {}
1130        float_complex foo (const float_complex &val)
1131          { return float_complex (~val.m_value); }
1132       };
1133 EOB
1134     AC_TRY_COMPILE([#include "conftest.h"], ,
1135       glibcpp_cv_float_complex=ok,
1136       glibcpp_cv_float_complex=buggy
1137     )
1138     AC_LANG_RESTORE
1139   ])
1140   AC_MSG_RESULT($glibcpp_cv_float_complex)
1141   if test $glibcpp_cv_float_complex = buggy; then
1142     AC_DEFINE(_GLIBCPP_BUGGY_FLOAT_COMPLEX)
1143   fi
1144 ])
1145
1146
1147 dnl
1148 dnl Check for special debugging mode; not for production use.
1149 dnl
1150 dnl GLIBCPP_ENABLE_DEBUG
1151 dnl --enable-debug sets '-ggdb3 -O0'.
1152 dnl --disable-debug sets '-g' and whatever optimization options the
1153 dnl     compiler can handle.
1154 dnl  +  --enable-maintainer-mode automatically defaults this to on.
1155 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
1156 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
1157 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1158 dnl       defaults to `no'.
1159 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
1160 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
1161 AC_ARG_ENABLE(debug,
1162 changequote(<<, >>)dnl
1163 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
1164 changequote([, ])dnl
1165 [case "${enableval}" in
1166  yes) enable_debug=yes ;;
1167  no)  enable_debug=no ;;
1168  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
1169  esac],
1170 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
1171
1172 dnl Option parsed, now set things appropriately
1173 case "${enable_debug}" in
1174     yes)
1175         DEBUG_FLAGS='-O0 -ggdb3'
1176         ;;
1177     no)
1178         DEBUG_FLAGS='-g'
1179         ;;
1180 esac
1181 AC_SUBST(DEBUG_FLAGS)
1182 ])
1183
1184
1185 dnl
1186 dnl Check for "unusual" flags to pass to the compiler while building.
1187 dnl
1188 dnl GLIBCPP_ENABLE_CXX_FLAGS
1189 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1190 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
1191 dnl     Somehow this same set of flags must be passed when [re]building
1192 dnl     libgcc.
1193 dnl --disable-cxx-flags passes nothing.
1194 dnl  +  See http://sourceware.cygnus.com/ml/libstdc++/2000-q2/msg00131.html
1195 dnl         http://sourceware.cygnus.com/ml/libstdc++/2000-q2/msg00284.html
1196 dnl         http://sourceware.cygnus.com/ml/libstdc++/2000-q1/msg00035.html
1197 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
1198 dnl       If "default flags" is an empty string (or "none"), the effect is
1199 dnl       the same as --disable or --enable=no.
1200 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
1201 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
1202 AC_ARG_ENABLE(cxx-flags,
1203 changequote(<<, >>)dnl
1204 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
1205                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
1206 changequote([, ])dnl
1207 [case "x$enableval" in
1208  xyes)
1209         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
1210  xno|x)
1211         enable_cxx_flags='' ;;
1212  *)
1213         enable_cxx_flags="$enableval" ;;
1214  esac],
1215 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1216
1217 dnl Thinko on my part during design.  This kludge is the workaround.
1218 if test "$enable_cxx_flags" = "none"; then
1219   enable_cxx_flags='';
1220 fi
1221
1222 dnl Run through flags (either default or command-line) and set anything
1223 dnl extra (e.g., #defines) that must accompany particular g++ options.
1224 if test -n "$enable_cxx_flags"; then
1225     for f in $enable_cxx_flags; do
1226         case "$f" in
1227             -fhonor-std)  ;;
1228             -*)  ;;
1229             *)   # and we're trying to pass /what/ exactly?
1230                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1231         esac
1232     done
1233 fi
1234 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1235 AC_SUBST(EXTRA_CXX_FLAGS)
1236 ])
1237
1238
1239 dnl
1240 dnl Check for which I/O library to use:  libio, or something specific.
1241 dnl
1242 dnl GLIBCPP_ENABLE_CSTDIO
1243 dnl --enable-cstdio=libio sets config/c_io_libio.h and friends
1244 dnl
1245 dnl default is stdio
1246 dnl
1247 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1248   AC_MSG_CHECKING([for cstdio to use])
1249   AC_ARG_ENABLE(cstdio,
1250   [  --enable-cstdio        enable stdio for target io package. (default)
1251      --enable-cstdio=LIB    use LIB target-speific io package.],
1252   if test x$enable_cstdio = xno; then
1253      enable_cstdio=stdio
1254   fi,
1255      enable_cstdio=stdio)
1256
1257   enable_cstdio_flag=$enable_cstdio
1258
1259   dnl Check if a valid I/O package
1260   case x${enable_cstdio_flag} in
1261     xlibio)
1262       CSTDIO_H=config/c_io_libio.h
1263       CSTDIO_CC=config/c_io_libio.cc
1264       AC_MSG_RESULT(libio)
1265
1266       # see if we are on a system with libio native (ie, linux)
1267       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1268
1269       # Need to check and see what version of glibc is being used. If
1270       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1271       # compile most of libio for linux systems.
1272       if test x$has_libio = x"yes"; then
1273         case "$target" in
1274           *-*-linux*)
1275               AC_MSG_CHECKING([for glibc version >= 2.2])
1276               AC_EGREP_CPP([ok], [
1277             #include <features.h>
1278               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1279                     ok
1280               #endif
1281               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1282               AC_MSG_RESULT($glibc_satisfactory)
1283             ;;
1284         esac
1285
1286         # XXX at the moment, admit defeat and force the recompilation
1287         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1288         glibc_satisfactory=no
1289
1290         if test x$glibc_satisfactory = x"yes"; then
1291            need_libio=no
1292            need_wlibio=no
1293         else
1294            need_libio=yes
1295            # bkoz XXX need to add checks to enable this
1296            # pme XXX here's a first pass at such a check
1297            if test x$enable_c_mbchar != xno; then
1298               need_wlibio=yes
1299            else
1300               need_wlibio=no
1301            fi
1302         fi
1303
1304       else
1305          # Using libio, but <libio.h> doesn't exist on the target system. . .
1306          need_libio=yes
1307          # bkoz XXX need to add checks to enable this
1308          # pme XXX here's a first pass at such a check
1309          if test x$enable_c_mbchar != xno; then
1310              need_wlibio=yes
1311          else
1312              need_wlibio=no
1313          fi
1314       fi
1315       ;;
1316     xstdio | x | xno | xnone | xyes)
1317       # default
1318       CSTDIO_H=config/c_io_stdio.h
1319       CSTDIO_CC=config/c_io_stdio.cc
1320       AC_MSG_RESULT(stdio)
1321
1322       # We're not using stdio.
1323       need_libio=no
1324       need_wlibio=no
1325       # Wide characters are not supported with this package.
1326       enable_c_mbchar=no
1327       ;;
1328     *)
1329       echo "$enable_cstdio is an unknown io package" 1>&2
1330       exit 1
1331       ;;
1332   esac
1333   AC_LINK_FILES($CSTDIO_H, include/bits/c++io.h)
1334   AC_LINK_FILES($CSTDIO_CC, src/c++io.cc)
1335
1336   # 2000-08-04 bkoz hack
1337   CCODECVT_C=config/c_io_libio_codecvt.c
1338   AC_LINK_FILES($CCODECVT_C, libio/c_codecvt.c)
1339   # 2000-08-04 bkoz hack
1340
1341   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1342                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1343   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1344   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1345   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1346         libio_la=../libio/libio.la
1347   else
1348         libio_la=
1349   fi
1350   AC_SUBST(libio_la)
1351 ])
1352
1353
1354 dnl
1355 dnl Check for which threading library to use.
1356 dnl
1357 dnl GLIBCPP_ENABLE_THREADS
1358 dnl --enable-threads=posix sets config/threads-posix.h et. al.
1359 dnl
1360 dnl Default is no threads, which also disables _IO_MTSAFE_IO in
1361 dnl libio.  Any actual thread package will enable it.
1362 dnl
1363 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1364   dnl Note this comes from the gcc/config.in and libjava/config.in
1365   dnl Efforts should be made to keep this in sync.
1366   AC_MSG_CHECKING([for threads package to use])
1367   AC_ARG_ENABLE(threads,
1368   [  --enable-threads        enable thread usage for target GCC.
1369      --enable-threads=LIB    use LIB thread package for target GCC.],
1370   if test x$enable_threads = xno; then
1371     enable_threads=''
1372   fi,
1373     enable_threads='')
1374
1375   enable_threads_flag=$enable_threads
1376
1377   dnl Check if a valid thread package
1378   case x${enable_threads_flag} in
1379         x | xno | xnone)
1380                 # No threads
1381                 target_thread_file='single'
1382                 ;;
1383         xyes)
1384                 # default
1385                 target_thread_file='posix'
1386                 ;;
1387         xdecosf1 | xirix | xmach | xos2 | xposix | xpthreads | xsingle | \
1388         xsolaris | xwin32 | xdce | xvxworks)
1389                 target_thread_file=$enable_threads_flag
1390                 ;;
1391         *)
1392                 echo "$enable_threads is an unknown thread package" 1>&2
1393                 exit 1
1394                 ;;
1395   esac
1396
1397   dnl Check for thread package actually supported in libstdc++
1398   THREADH=
1399   case "$target_thread_file" in
1400     no | none | single)
1401       THREADH=threads-no.h
1402       ;;
1403     posix | pthreads)
1404       THREADH=threads-posix.h
1405       ;;
1406     decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
1407       AC_MSG_ERROR(thread package $THREADS not yet supported)
1408       ;;
1409     *)
1410       AC_MSG_ERROR($THREADS is an unsupported/unknown thread package)
1411       ;;
1412   esac
1413   AC_MSG_RESULT($THREADH)
1414
1415   AC_LINK_FILES(config/$THREADH, include/bits/c++threads.h)
1416   if test $THREADH != threads-no.h; then
1417     AC_DEFINE(_GLIBCPP_USE_THREADS)
1418   fi
1419 ])
1420
1421
1422 dnl Enable atomic locking
1423 dnl GLIBCPP_ENABLE_ATOMICITY
1424 AC_DEFUN(GLIBCPP_ENABLE_ATOMICITY, [
1425     AC_MSG_CHECKING([for atomicity.h])
1426     # We have ATOMICITY already from GLIBCPP_CONFIGURE
1427     if test "$ATOMICITYH" = "config/cpu/generic"; then
1428       AC_MSG_WARN([No ATOMICITY settings found, using generic atomic ops.])
1429     fi
1430     AC_MSG_RESULT($ATOMICITYH/bits/atomicity.h)
1431     AC_LINK_FILES($ATOMICITYH/bits/atomicity.h, include/bits/atomicity.h)
1432 ])
1433
1434
1435 dnl
1436 dnl Check for template specializations for the 'long long' type extension.
1437 dnl
1438 dnl GLIBCPP_ENABLE_LONG_LONG
1439 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1440 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1441 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1442 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1443 dnl       defaults to `no'.
1444 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1445 dnl
1446 dnl GLIBCPP_ENABLE_LONG_LONG
1447 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1448   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1449
1450   AC_ARG_ENABLE(long-long,
1451   changequote(<<, >>)dnl
1452   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1453   changequote([, ])dnl
1454   [case "$enableval" in
1455    yes) enable_long_long=yes ;;
1456    no)  enable_long_long=no ;;
1457    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1458    esac],
1459   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1460
1461   # Allow use of os-dependent settings, so that macros that turn on
1462   # C99 capabilities can be defined and used in a consistent way.
1463   OS_INC_PATH=${srcdir}/$os_include_dir
1464   ac_test_CFLAGS="${CFLAGS+set}"
1465   ac_save_CFLAGS="$CFLAGS"
1466   CFLAGS="-I$OS_INC_PATH"
1467
1468   # Check for the existence of functions used if long long is enabled.
1469   AC_CHECK_FUNC(strtoll,,ac_strtoll=no)
1470   AC_CHECK_FUNC(strtoull,,ac_strtoull=no)
1471
1472   # Check for lldiv_t, et. al.
1473   AC_MSG_CHECKING([for lldiv_t declaration])
1474   AC_CACHE_VAL(glibcpp_lldiv_t_use, [
1475   AC_TRY_COMPILE([#include <bits/os_defines.h>
1476                   #include <stdlib.h>],
1477                    [ lldiv_t mydivt;],
1478                    [glibcpp_lldiv_t_use=yes], [glibcpp_lldiv_t_use=no])
1479   ])
1480   AC_MSG_RESULT($glibcpp_lldiv_t_use)
1481   if test x$glibcpp_lldiv_t_use = x"yes"; then
1482     AC_DEFINE(HAVE_LLDIV_T)
1483   fi
1484
1485   AC_MSG_CHECKING([for enabled long long])
1486   if test x"$ac_strtoll" = xno || test x"$ac_strtoull" = xno; then
1487     enable_long_long=no;
1488   fi;
1489   AC_MSG_RESULT($enable_long_long)
1490
1491   # Option parsed, now set things appropriately
1492   if test x"$enable_long_long" = xyes; then
1493     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1494   fi
1495
1496   # Reset CFLAGS
1497   CFLAGS="$ac_save_CFLAGS"
1498 ])
1499
1500
1501 dnl
1502 dnl Check for whether or not to do shadowed C headers.
1503 dnl
1504 dnl GLIBCPP_ENABLE_SHADOW
1505 dnl --enable-cshadow-headers [does stuff].
1506 dnl --disable-cshadow-headers [does not do stuff].
1507 dnl  +  This will eventually need to be on by default.
1508 dnl  +  Usage:  GLIBCPP_ENABLE_SHADOW[(DEFAULT)]
1509 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1510 dnl       defaults to `no'.
1511 AC_DEFUN(GLIBCPP_ENABLE_SHADOW, [dnl
1512 define([GLIBCPP_ENABLE_SHADOW_DEFAULT], ifelse($1, yes, yes, no))dnl
1513 AC_MSG_CHECKING([for enabled cshadow headers])
1514 AC_ARG_ENABLE(cshadow-headers,
1515 changequote(<<, >>)dnl
1516 <<  --enable-cshadow-headers construct "shadowed" C header files for
1517                            g++ [default=>>GLIBCPP_ENABLE_SHADOW_DEFAULT],
1518 changequote([, ])
1519   [case "$enableval" in
1520    yes) enable_cshadow_headers=yes
1521         ;;
1522    no)  enable_cshadow_headers=no
1523         ;;
1524    *)   AC_MSG_ERROR([Unknown argument to enable/disable shadowed C headers])
1525         ;;
1526   esac],
1527   enable_cshadow_headers=GLIBCPP_ENABLE_SHADOW_DEFAULT)
1528   AC_MSG_RESULT($enable_cshadow_headers)
1529
1530   dnl Option parsed, now set things appropriately
1531   dnl NB: these things may be duplicated in c++config.h as well.
1532   case "$enable_cshadow_headers" in
1533     yes)
1534         CSHADOW_FLAGS="-fno-builtin"
1535         C_INCLUDE_DIR='${top_srcdir}/include/c_std'
1536         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1537         ;;
1538     no)
1539         CSHADOW_FLAGS=""
1540         C_INCLUDE_DIR='${top_srcdir}/include/c'
1541         ;;
1542   esac
1543
1544   AC_SUBST(CSHADOW_FLAGS)
1545   AC_SUBST(C_INCLUDE_DIR)
1546   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cshadow_headers" = yes)
1547 ])
1548
1549
1550 dnl
1551 dnl Check for wide character support.  Has the same effect as the option
1552 dnl in gcc's configure, but in a form that autoconf can mess with.
1553 dnl
1554 dnl GLIBCPP_ENABLE_C_MBCHAR
1555 dnl --enable-c-mbchar requests all the wchar_t stuff.
1556 dnl --disable-c-mbchar doesn't.
1557 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1558 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1559 dnl       defaults to `no'.
1560 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1561 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1562 AC_ARG_ENABLE(c-mbchar,
1563 changequote(<<, >>)dnl
1564 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1565 changequote([, ])dnl
1566 [case "$enableval" in
1567  yes) enable_c_mbchar=yes ;;
1568  no)  enable_c_mbchar=no ;;
1569  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1570  esac],
1571 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1572 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1573 ])
1574
1575
1576 dnl
1577 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1578 dnl
1579 dnl GLIBCPP_INCLUDE_DIR
1580 dnl C_INCLUDE_DIR
1581 dnl TOPLEVEL_INCLUDES
1582 dnl LIBMATH_INCLUDES
1583 dnl LIBSUPCXX_INCLUDES
1584 dnl LIBIO_INCLUDES
1585 dnl CSHADOW_INCLUDES
1586 dnl
1587 dnl GLIBCPP_EXPORT_INCLUDE
1588 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1589   # Root level of the include sources.
1590   GLIBCPP_INCLUDE_DIR='$(top_srcdir)/include'
1591
1592   # Can either use include/c or include/c_std to grab "C" headers. This
1593   # variable is set to the include directory currently in use.
1594   # set with C_INCLUDE_DIR in GLIBCPP_ENABLE_SHADOW
1595
1596   # Passed down for canadian crosses.
1597   if  test x"$CANADIAN" = xyes; then
1598     TOPLEVEL_INCLUDES='-I$(includedir)'
1599   fi
1600
1601   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1602
1603   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1604
1605   #if GLIBCPP_NEED_LIBIO
1606   LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1607   #else
1608   #LIBIO_INCLUDES='-I$(top_srcdir)/libio'
1609   #endif
1610
1611   #if GLIBCPP_USE_CSHADOW
1612   #  CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR) \
1613   #                   -I$(top_blddir)/cshadow'
1614   #else
1615   CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR)'
1616   #endif
1617
1618   # Now, export this to all the little Makefiles....
1619   AC_SUBST(GLIBCPP_INCLUDE_DIR)
1620   AC_SUBST(TOPLEVEL_INCLUDES)
1621   AC_SUBST(LIBMATH_INCLUDES)
1622   AC_SUBST(LIBSUPCXX_INCLUDES)
1623   AC_SUBST(LIBIO_INCLUDES)
1624   AC_SUBST(CSHADOW_INCLUDES)
1625 ])
1626
1627
1628 dnl
1629 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1630 dnl
1631 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1632   # Optimization flags that are probably a good idea for thrill-seekers. Just
1633   # uncomment the lines below and make, everything else is ready to go...
1634   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1635   OPTIMIZE_CXXFLAGS=
1636   AC_SUBST(OPTIMIZE_CXXFLAGS)
1637
1638   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1639   AC_SUBST(WARN_FLAGS)
1640 ])
1641
1642
1643 # Check whether LC_MESSAGES is available in <locale.h>.
1644 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1645 #
1646 # This file file be copied and used freely without restrictions.  It can
1647 # be used in projects which are not available under the GNU Public License
1648 # but which still want to provide support for the GNU gettext functionality.
1649 # Please note that the actual code is *not* freely available.
1650
1651 # serial 1
1652
1653 AC_DEFUN(AC_LC_MESSAGES, [
1654   AC_CHECK_HEADER(locale.h, [
1655     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1656       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1657        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1658     if test $ac_cv_val_LC_MESSAGES = yes; then
1659       AC_DEFINE(HAVE_LC_MESSAGES)
1660     fi
1661   ])
1662 ])
1663
1664
1665 # Check for functions in math library.
1666 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1667 #
1668 # This file can be copied and used freely without restrictions.  It can
1669 # be used in projects which are not available under the GNU Public License
1670 # but which still want to provide support for the GNU gettext functionality.
1671 # Please note that the actual code is *not* freely available.
1672
1673 # serial 1
1674
1675 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1676 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1677 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1678 AC_SUBST(LIBMATHOBJS)dnl
1679 ])
1680
1681
1682 # Check for string functions.
1683 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1684 #
1685 # This file can be copied and used freely without restrictions.  It can
1686 # be used in projects which are not available under the GNU Public License
1687 # but which still want to provide support for the GNU gettext functionality.
1688 # Please note that the actual code is *not* freely available.
1689
1690 # serial 1
1691
1692 dnl AC_REPLACE_STRINGFUNCS(FUNCTION...)
1693 AC_DEFUN(AC_REPLACE_STRINGFUNCS,
1694 [AC_CHECK_FUNCS([$1], , [LIBSTRINGOBJS="$LIBSTRINGOBJS ${ac_func}.lo"])
1695 AC_SUBST(LIBSTRINGOBJS)dnl
1696 ])
1697
1698
1699 dnl This macro searches for a GNU version of make.  If a match is found, the
1700 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1701 dnl set to "#". This is useful for  including a special features in a Makefile,
1702 dnl which cannot be handled by other versions of make.  The variable
1703 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1704 dnl the empty string otherwise.
1705 dnl
1706 dnl Here is an example of its use:
1707 dnl
1708 dnl Makefile.in might contain:
1709 dnl
1710 dnl     # A failsafe way of putting a dependency rule into a makefile
1711 dnl     $(DEPEND):
1712 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1713 dnl
1714 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1715 dnl     @ifGNUmake@ include $(DEPEND)
1716 dnl     @ifGNUmake@ endif
1717 dnl
1718 dnl Then configure.in would normally contain:
1719 dnl
1720 dnl     CHECK_GNU_MAKE()
1721 dnl     AC_OUTPUT(Makefile)
1722 dnl
1723 dnl Then perhaps to cause gnu make to override any other make, we could do
1724 dnl something like this (note that GNU make always looks for GNUmakefile first):
1725 dnl
1726 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1727 dnl             mv Makefile GNUmakefile
1728 dnl             echo .DEFAULT: > Makefile ;
1729 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1730 dnl     fi
1731 dnl
1732 dnl Then, if any (well almost any) other make is called, and GNU make also
1733 dnl exists, then the other make wraps the GNU make.
1734 dnl
1735 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1736 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1737 dnl
1738 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1739 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1740 dnl #### conditional's subshell (" --version" is not a command), using a
1741 dnl #### different option to grep(1).
1742 dnl #### -pme
1743 AC_DEFUN(
1744   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1745           _cv_gnu_make_command='' ;
1746 dnl Search all the common names for GNU make
1747           for a in "${MAKE:-make}" make gmake gnumake ; do
1748                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1749                   then
1750                           _cv_gnu_make_command=$a ;
1751                           break;
1752                   fi
1753           done ;
1754   ) ;
1755 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1756 dnl string, '#' otherwise
1757   if test  "x$_cv_gnu_make_command" != "x"  ; then
1758           ifGNUmake='' ;
1759   else
1760           ifGNUmake='#' ;
1761   fi
1762   AC_SUBST(ifGNUmake)
1763 ])
1764
1765 sinclude(../libtool.m4)
1766 dnl The lines below arrange for aclocal not to bring an installed
1767 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1768 dnl add a definition of LIBTOOL to Makefile.in.
1769 ifelse(,,,[AC_SUBST(LIBTOOL)
1770 AC_DEFUN([AM_PROG_LIBTOOL])
1771 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1772 AC_DEFUN([AC_PROG_LD])
1773 ])
1774