libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   3 dnl
   4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   5 dnl end of configure.  This lets tested variables be reassigned, and the
   6 dnl conditional will depend on the final state of the variable.  For a simple
   7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   8 dnl
   9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
  11   m4_divert_text([glibcxx_diversion],dnl
  12    AM_CONDITIONAL([$1],[$2])
  13   )dnl
  14 ])dnl
  15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
  16
  17
  18 dnl
  19 dnl Check to see what architecture and operating system we are compiling
  20 dnl for.  Also, if architecture- or OS-specific flags are required for
  21 dnl compilation, pick them up here.
  22 dnl
  23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
  24   . $glibcxx_srcdir/configure.host
  25   AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
  26   AC_MSG_NOTICE([OS config directory is $os_include_dir])
  27 ])
  28
  29 dnl
  30 dnl Initialize the rest of the library configury.  At this point we have
  31 dnl variables like $host.
  32 dnl
  33 dnl Sets:
  34 dnl  SUBDIRS
  35 dnl Substs:
  36 dnl  glibcxx_builddir     (absolute path)
  37 dnl  glibcxx_srcdir       (absolute path)
  38 dnl  toplevel_builddir    (absolute path)
  39 dnl  toplevel_srcdir      (absolute path)
  40 dnl  with_cross_host
  41 dnl  with_newlib
  42 dnl  with_target_subdir
  43 dnl plus
  44 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  45 dnl  - default settings for all AM_CONFITIONAL test variables
  46 dnl  - lots of tools, like CC and CXX
  47 dnl
  48 AC_DEFUN([GLIBCXX_CONFIGURE], [
  49   # Keep these sync'd with the list in Makefile.am.  The first provides an
  50   # expandable list at autoconf time; the second provides an expandable list
  51   # (i.e., shell variable) at configure time.
  52   m4_define([glibcxx_SUBDIRS],[include libsupc++ python src doc po testsuite])
  53   SUBDIRS='glibcxx_SUBDIRS'
  54
  55   # These need to be absolute paths, yet at the same time need to
  56   # canonicalize only relative paths, because then amd will not unmount
  57   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  58   glibcxx_builddir=`${PWDCMD-pwd}`
  59   case $srcdir in
  60     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  61     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  62   esac
  63   toplevel_builddir=${glibcxx_builddir}/..
  64   toplevel_srcdir=${glibcxx_srcdir}/..
  65   AC_SUBST(glibcxx_builddir)
  66   AC_SUBST(glibcxx_srcdir)
  67   AC_SUBST(toplevel_builddir)
  68   AC_SUBST(toplevel_srcdir)
  69
  70   # We use these options to decide which functions to include.  They are
  71   # set from the top level.
  72   AC_ARG_WITH([target-subdir],
  73     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  74                    [configuring in a subdirectory]))
  75
  76   AC_ARG_WITH([cross-host],
  77     AC_HELP_STRING([--with-cross-host=HOST],
  78                    [configuring with a cross compiler]))
  79
  80   AC_ARG_WITH([newlib],
  81     AC_HELP_STRING([--with-newlib],
  82                    [assume newlib as a system C library]))
  83
  84   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
  85   # available).  Uncomment the next line to force a particular method.
  86   AC_PROG_LN_S
  87   #LN_S='cp -p'
  88
  89   AC_CHECK_TOOL(AS, as)
  90   AC_CHECK_TOOL(AR, ar)
  91   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
  92
  93   AM_MAINTAINER_MODE
  94
  95   # Set up safe default values for all subsequent AM_CONDITIONAL tests
  96   # which are themselves conditionally expanded.
  97   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
  98   ## other macros from doing the same.  This should be automated.)  -pme
  99
 100   # Check for C library flavor since GNU/Linux platforms use different
 101   # configuration directories depending on the C library in use.
 102   AC_EGREP_CPP([_using_uclibc], [
 103   #include <stdio.h>
 104   #if __UCLIBC__
 105     _using_uclibc
 106   #endif
 107   ], uclibc=yes, uclibc=no)
 108
 109   AC_EGREP_CPP([_using_bionic], [
 110   #include <stdio.h>
 111   #if __BIONIC__
 112     _using_bionic
 113   #endif
 114   ], bionic=yes, bionic=no)
 115
 116   # Find platform-specific directories containing configuration info.
 117   # Also possibly modify flags used elsewhere, as needed by the platform.
 118   GLIBCXX_CHECK_HOST
 119 ])
 120
 121
 122 dnl
 123 dnl Tests for newer compiler features, or features that are present in newer
 124 dnl compiler versions but not older compiler versions still in use, should
 125 dnl be placed here.
 126 dnl
 127 dnl Defines:
 128 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 129 dnl   new inlining code or the new system_header pragma will die on -Werror.
 130 dnl   Leave it out by default and use maint-mode to use it.
 131 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 132 dnl   compiler supports it and the user has not requested debug mode.
 133 dnl
 134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
 135   # All these tests are for C++; save the language and the compiler flags.
 136   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 137   # found in GLIBCXX_CONFIGURE.
 138   AC_LANG_SAVE
 139   AC_LANG_CPLUSPLUS
 140   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 141   ac_save_CXXFLAGS="$CXXFLAGS"
 142
 143   # Check for maintainer-mode bits.
 144   if test x"$USE_MAINTAINER_MODE" = xno; then
 145     WERROR=''
 146   else
 147     WERROR='-Werror'
 148   fi
 149
 150   # Check for -ffunction-sections -fdata-sections
 151   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 152   CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
 153   AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
 154   if test "$ac_test_CXXFLAGS" = set; then
 155     CXXFLAGS="$ac_save_CXXFLAGS"
 156   else
 157     # this is the suspicious part
 158     CXXFLAGS=''
 159   fi
 160   if test x"$ac_fdsections" = x"yes"; then
 161     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 162   fi
 163   AC_MSG_RESULT($ac_fdsections)
 164
 165   AC_LANG_RESTORE
 166   AC_SUBST(WERROR)
 167   AC_SUBST(SECTION_FLAGS)
 168 ])
 169
 170
 171 dnl
 172 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 173 dnl the native linker is in use, all variables will be defined to something
 174 dnl safe (like an empty string).
 175 dnl
 176 dnl Defines:
 177 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 178 dnl  OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
 179 dnl  LD (as a side effect of testing)
 180 dnl Sets:
 181 dnl  with_gnu_ld
 182 dnl  glibcxx_ld_is_gold (set to "no" or "yes")
 183 dnl  glibcxx_gnu_ld_version (possibly)
 184 dnl
 185 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 186 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 187 dnl
 188 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
 189   # If we're not using GNU ld, then there's no point in even trying these
 190   # tests.  Check for that first.  We should have already tested for gld
 191   # by now (in libtool), but require it now just to be safe...
 192   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 193   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 194   AC_REQUIRE([AC_PROG_LD])
 195   AC_REQUIRE([AC_PROG_AWK])
 196
 197   # The name set by libtool depends on the version of libtool.  Shame on us
 198   # for depending on an impl detail, but c'est la vie.  Older versions used
 199   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 200   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 201   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 202   # set (hence we're using an older libtool), then set it.
 203   if test x${with_gnu_ld+set} != xset; then
 204     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 205       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 206       with_gnu_ld=no
 207     else
 208       with_gnu_ld=$ac_cv_prog_gnu_ld
 209     fi
 210   fi
 211
 212   # Start by getting the version number.  I think the libtool test already
 213   # does some of this, but throws away the result.
 214   glibcxx_ld_is_gold=no
 215   if test x"$with_gnu_ld" = x"yes"; then
 216     AC_MSG_CHECKING([for ld version])
 217     changequote(,)
 218     if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
 219       glibcxx_ld_is_gold=yes
 220     fi
 221     ldver=`$LD --version 2>/dev/null |
 222            sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
 223     changequote([,])
 224     glibcxx_gnu_ld_version=`echo $ldver | \
 225            $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 226     AC_MSG_RESULT($glibcxx_gnu_ld_version)
 227   fi
 228
 229   # Set --gc-sections.
 230   glibcxx_have_gc_sections=no
 231   if test "$glibcxx_ld_is_gold" = "yes"; then
 232     if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
 233       glibcxx_have_gc_sections=yes
 234     fi
 235   else
 236     glibcxx_gcsections_min_ld=21602
 237     if test x"$with_gnu_ld" = x"yes" &&
 238         test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
 239       glibcxx_have_gc_sections=yes
 240     fi
 241   fi
 242   if test "$glibcxx_have_gc_sections" = "yes"; then
 243     # Sufficiently young GNU ld it is!  Joy and bunny rabbits!
 244     # NB: This flag only works reliably after 2.16.1. Configure tests
 245     # for this are difficult, so hard wire a value that should work.
 246
 247     ac_test_CFLAGS="${CFLAGS+set}"
 248     ac_save_CFLAGS="$CFLAGS"
 249     CFLAGS='-Wl,--gc-sections'
 250
 251     # Check for -Wl,--gc-sections
 252     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 253     AC_TRY_LINK([ int one(void) { return 1; }
 254      int two(void) { return 2; }
 255         ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
 256     if test "$ac_gcsections" = "yes"; then
 257       rm -f conftest.c
 258       touch conftest.c
 259       if $CC -c conftest.c; then
 260         if $LD --gc-sections -o conftest conftest.o 2>&1 | \
 261            grep "Warning: gc-sections option ignored" > /dev/null; then
 262           ac_gcsections=no
 263         fi
 264       fi
 265       rm -f conftest.c conftest.o conftest
 266     fi
 267     if test "$ac_gcsections" = "yes"; then
 268       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 269     fi
 270     AC_MSG_RESULT($ac_gcsections)
 271
 272     if test "$ac_test_CFLAGS" = set; then
 273       CFLAGS="$ac_save_CFLAGS"
 274     else
 275       # this is the suspicious part
 276       CFLAGS=''
 277     fi
 278   fi
 279
 280   # Set -z,relro.
 281   # Note this is only for shared objects.
 282   ac_ld_relro=no
 283   if test x"$with_gnu_ld" = x"yes"; then
 284     AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
 285     cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
 286     if test -n "$cxx_z_relo"; then
 287       OPT_LDFLAGS="-Wl,-z,relro"
 288       ac_ld_relro=yes
 289     fi
 290     AC_MSG_RESULT($ac_ld_relro)
 291   fi
 292
 293   # Set linker optimization flags.
 294   if test x"$with_gnu_ld" = x"yes"; then
 295     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 296   fi
 297
 298   AC_SUBST(SECTION_LDFLAGS)
 299   AC_SUBST(OPT_LDFLAGS)
 300 ])
 301
 302
 303 dnl
 304 dnl Check for headers for, and arguments to, the setrlimit() function.
 305 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 306 dnl
 307 dnl Defines:
 308 dnl  _GLIBCXX_RES_LIMITS if we can set artificial resource limits
 309 dnl  various HAVE_LIMIT_* for individual limit names
 310 dnl
 311 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
 312   AC_MSG_CHECKING([for RLIMIT_$1])
 313   AC_TRY_COMPILE(
 314     [#include <unistd.h>
 315      #include <sys/time.h>
 316      #include <sys/resource.h>
 317     ],
 318     [ int f = RLIMIT_$1 ; ],
 319     [glibcxx_mresult=1], [glibcxx_mresult=0])
 320   AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
 321                      [Only used in build directory testsuite_hooks.h.])
 322   if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
 323   AC_MSG_RESULT($res)
 324 ])
 325
 326 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
 327   setrlimit_have_headers=yes
 328   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 329                    [],
 330                    [setrlimit_have_headers=no])
 331   # If don't have the headers, then we can't run the tests now, and we
 332   # won't be seeing any of these during testsuite compilation.
 333   if test $setrlimit_have_headers = yes; then
 334     # Can't do these in a loop, else the resulting syntax is wrong.
 335     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 336     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 337     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 338     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 339     GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
 340
 341     # Check for rlimit, setrlimit.
 342     AC_CACHE_VAL(glibcxx_cv_setrlimit, [
 343       AC_TRY_COMPILE(
 344         [#include <unistd.h>
 345          #include <sys/time.h>
 346          #include <sys/resource.h>
 347         ],
 348         [struct rlimit r;
 349          setrlimit(0, &r);],
 350         [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
 351     ])
 352   fi
 353
 354   AC_MSG_CHECKING([for testsuite resource limits support])
 355   if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
 356     ac_res_limits=yes
 357     AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
 358               [Define if using setrlimit to set resource limits during
 359               "make check"])
 360   else
 361     ac_res_limits=no
 362   fi
 363   AC_MSG_RESULT($ac_res_limits)
 364 ])
 365
 366
 367 dnl
 368 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 369 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 370 dnl
 371 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
 372
 373   AC_LANG_SAVE
 374   AC_LANG_CPLUSPLUS
 375   ac_save_CXXFLAGS="$CXXFLAGS"
 376   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 377
 378   AC_MSG_CHECKING([for S_ISREG or S_IFREG])
 379   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 380     GCC_TRY_COMPILE_OR_LINK(
 381       [#include <sys/stat.h>],
 382       [struct stat buffer;
 383        fstat(0, &buffer);
 384        S_ISREG(buffer.st_mode);],
 385       [glibcxx_cv_S_ISREG=yes],
 386       [glibcxx_cv_S_ISREG=no])
 387   ])
 388   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 389     GCC_TRY_COMPILE_OR_LINK(
 390       [#include <sys/stat.h>],
 391       [struct stat buffer;
 392        fstat(0, &buffer);
 393        S_IFREG & buffer.st_mode;],
 394       [glibcxx_cv_S_IFREG=yes],
 395       [glibcxx_cv_S_IFREG=no])
 396   ])
 397   res=no
 398   if test $glibcxx_cv_S_ISREG = yes; then
 399     AC_DEFINE(HAVE_S_ISREG, 1,
 400               [Define if S_IFREG is available in <sys/stat.h>.])
 401     res=S_ISREG
 402   elif test $glibcxx_cv_S_IFREG = yes; then
 403     AC_DEFINE(HAVE_S_IFREG, 1,
 404               [Define if S_IFREG is available in <sys/stat.h>.])
 405     res=S_IFREG
 406   fi
 407   AC_MSG_RESULT($res)
 408
 409   CXXFLAGS="$ac_save_CXXFLAGS"
 410   AC_LANG_RESTORE
 411 ])
 412
 413
 414 dnl
 415 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 416 dnl
 417 AC_DEFUN([GLIBCXX_CHECK_POLL], [
 418
 419   AC_LANG_SAVE
 420   AC_LANG_CPLUSPLUS
 421   ac_save_CXXFLAGS="$CXXFLAGS"
 422   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 423
 424   AC_MSG_CHECKING([for poll])
 425   AC_CACHE_VAL(glibcxx_cv_POLL, [
 426     GCC_TRY_COMPILE_OR_LINK(
 427       [#include <poll.h>],
 428       [struct pollfd pfd[1];
 429        pfd[0].events = POLLIN;
 430        poll(pfd, 1, 0);],
 431       [glibcxx_cv_POLL=yes],
 432       [glibcxx_cv_POLL=no])
 433   ])
 434   if test $glibcxx_cv_POLL = yes; then
 435     AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
 436   fi
 437   AC_MSG_RESULT($glibcxx_cv_POLL)
 438
 439   CXXFLAGS="$ac_save_CXXFLAGS"
 440   AC_LANG_RESTORE
 441 ])
 442
 443
 444 dnl
 445 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 446 dnl
 447 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
 448
 449   AC_LANG_SAVE
 450   AC_LANG_CPLUSPLUS
 451   ac_save_CXXFLAGS="$CXXFLAGS"
 452   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 453
 454   AC_MSG_CHECKING([for writev])
 455   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 456     GCC_TRY_COMPILE_OR_LINK(
 457       [#include <sys/uio.h>],
 458       [struct iovec iov[2];
 459        writev(0, iov, 0);],
 460       [glibcxx_cv_WRITEV=yes],
 461       [glibcxx_cv_WRITEV=no])
 462   ])
 463   if test $glibcxx_cv_WRITEV = yes; then
 464     AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
 465   fi
 466   AC_MSG_RESULT($glibcxx_cv_WRITEV)
 467
 468   CXXFLAGS="$ac_save_CXXFLAGS"
 469   AC_LANG_RESTORE
 470 ])
 471
 472
 473 dnl
 474 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
 475 dnl Also check whether int64_t is actually a typedef to long or long long.
 476 dnl
 477 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
 478
 479   AC_LANG_SAVE
 480   AC_LANG_CPLUSPLUS
 481
 482   AC_MSG_CHECKING([for int64_t])
 483   AC_CACHE_VAL(glibcxx_cv_INT64_T, [
 484     AC_TRY_COMPILE(
 485       [#include <stdint.h>],
 486       [int64_t var;],
 487       [glibcxx_cv_INT64_T=yes],
 488       [glibcxx_cv_INT64_T=no])
 489   ])
 490
 491   if test $glibcxx_cv_INT64_T = yes; then
 492     AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
 493     AC_MSG_RESULT($glibcxx_cv_INT64_T)
 494
 495     AC_MSG_CHECKING([for int64_t as long])
 496     AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
 497       AC_TRY_COMPILE(
 498         [#include <stdint.h>
 499         template<typename, typename> struct same { enum { value = -1 }; };
 500         template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
 501         int array[same<int64_t, long>::value];], [],
 502         [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
 503     ])
 504
 505     if test $glibcxx_cv_int64_t_long = yes; then
 506       AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
 507       AC_MSG_RESULT($glibcxx_cv_int64_t_long)
 508     fi
 509
 510     AC_MSG_CHECKING([for int64_t as long long])
 511     AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
 512       AC_TRY_COMPILE(
 513         [#include <stdint.h>
 514         template<typename, typename> struct same { enum { value = -1 }; };
 515         template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
 516         int array[same<int64_t, long long>::value];], [],
 517         [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
 518     ])
 519
 520     if test $glibcxx_cv_int64_t_long_long = yes; then
 521       AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
 522       AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
 523     fi
 524   fi
 525
 526   AC_LANG_RESTORE
 527 ])
 528
 529
 530 dnl
 531 dnl Check whether LFS support is available.
 532 dnl
 533 AC_DEFUN([GLIBCXX_CHECK_LFS], [
 534   AC_LANG_SAVE
 535   AC_LANG_CPLUSPLUS
 536   ac_save_CXXFLAGS="$CXXFLAGS"
 537   CXXFLAGS="$CXXFLAGS -fno-exceptions"
 538   AC_MSG_CHECKING([for LFS support])
 539   AC_CACHE_VAL(glibcxx_cv_LFS, [
 540     GCC_TRY_COMPILE_OR_LINK(
 541       [#include <unistd.h>
 542        #include <stdio.h>
 543        #include <sys/stat.h>
 544       ],
 545       [FILE* fp;
 546        fopen64("t", "w");
 547        fseeko64(fp, 0, SEEK_CUR);
 548        ftello64(fp);
 549        lseek64(1, 0, SEEK_CUR);
 550        struct stat64 buf;
 551        fstat64(1, &buf);],
 552       [glibcxx_cv_LFS=yes],
 553       [glibcxx_cv_LFS=no])
 554   ])
 555   if test $glibcxx_cv_LFS = yes; then
 556     AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
 557   fi
 558   AC_MSG_RESULT($glibcxx_cv_LFS)
 559   CXXFLAGS="$ac_save_CXXFLAGS"
 560   AC_LANG_RESTORE
 561 ])
 562
 563
 564 dnl
 565 dnl Check for whether a fully dynamic basic_string implementation should
 566 dnl be turned on, that does not put empty objects in per-process static
 567 dnl memory (mostly useful together with shared memory allocators, see PR
 568 dnl libstdc++/16612 for details).
 569 dnl
 570 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
 571 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
 572 dnl otherwise undefined
 573 dnl  +  Usage:  GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
 574 dnl       Where DEFAULT is either `yes' or `no'.
 575 dnl
 576 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
 577   GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
 578   if test $enable_fully_dynamic_string = yes; then
 579     enable_fully_dynamic_string_def=1
 580   else
 581     enable_fully_dynamic_string_def=0
 582   fi
 583   AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
 584               [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
 585 ])
 586
 587
 588 dnl
 589 dnl Does any necessary configuration of the testsuite directory.  Generates
 590 dnl the testsuite_hooks.h header.
 591 dnl
 592 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 593 dnl
 594 dnl Sets:
 595 dnl  enable_abi_check
 596 dnl  GLIBCXX_TEST_WCHAR_T
 597 dnl  GLIBCXX_TEST_THREAD
 598 dnl Substs:
 599 dnl  baseline_dir
 600 dnl  baseline_subdir_switch
 601 dnl
 602 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
 603   if $GLIBCXX_IS_NATIVE ; then
 604     # Do checks for resource limit functions.
 605     GLIBCXX_CHECK_SETRLIMIT
 606
 607     # Look for setenv, so that extended locale tests can be performed.
 608     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 609   fi
 610
 611   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
 612      test $enable_symvers != no; then
 613     case "$host" in
 614       *-*-cygwin*)
 615         enable_abi_check=no ;;
 616       *)
 617         enable_abi_check=yes ;;
 618     esac
 619   else
 620     # Only build this as native, since automake does not understand
 621     # CXX_FOR_BUILD.
 622     enable_abi_check=no
 623   fi
 624
 625   # Export file names for ABI checking.
 626   baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
 627   AC_SUBST(baseline_dir)
 628   baseline_subdir_switch="$abi_baseline_subdir_switch"
 629   AC_SUBST(baseline_subdir_switch)
 630 ])
 631
 632
 633 dnl
 634 dnl Does any necessary configuration of the documentation directory.
 635 dnl
 636 dnl XSLTPROC must be set before this
 637 dnl
 638 dnl Sets:
 639 dnl  glibcxx_stylesheets
 640 dnl Substs:
 641 dnl  XSL_STYLE_DIR
 642 dnl
 643 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
 644
 645 AC_MSG_CHECKING([for stylesheets used in generation of documentation])
 646 glibcxx_stylesheets=no
 647 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
 648   glibcxx_stylesheets=yes
 649 fi
 650 AC_MSG_RESULT($glibcxx_stylesheets)
 651
 652 AC_MSG_CHECKING([for local stylesheet directory])
 653 glibcxx_local_stylesheets=no
 654 if test x"$glibcxx_stylesheets" = x"yes"; then
 655   if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
 656     glibcxx_local_stylesheets=yes
 657     XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
 658   fi
 659   if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
 660     glibcxx_local_stylesheets=yes
 661     XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
 662   fi
 663 fi
 664 AC_MSG_RESULT($glibcxx_local_stylesheets)
 665
 666 if test x"$glibcxx_local_stylesheets" = x"yes"; then
 667   AC_SUBST(XSL_STYLE_DIR)
 668   AC_MSG_NOTICE($XSL_STYLE_DIR)
 669 else
 670   glibcxx_stylesheets=no
 671 fi
 672 ])
 673
 674
 675 dnl
 676 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 677 dnl
 678 dnl Substs:
 679 dnl  GLIBCXX_INCLUDES
 680 dnl  TOPLEVEL_INCLUDES
 681 dnl
 682 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
 683   # Used for every C++ compile we perform.
 684   GLIBCXX_INCLUDES="\
 685 -I$glibcxx_builddir/include/$host_alias \
 686 -I$glibcxx_builddir/include \
 687 -I$glibcxx_srcdir/libsupc++"
 688
 689   # For Canadian crosses, pick this up too.
 690   if test $CANADIAN = yes; then
 691     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 692   fi
 693
 694   # Stuff in the actual top level.  Currently only used by libsupc++ to
 695   # get unwind* headers from the libgcc dir.
 696   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
 697   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
 698
 699   # Now, export this to all the little Makefiles....
 700   AC_SUBST(GLIBCXX_INCLUDES)
 701   AC_SUBST(TOPLEVEL_INCLUDES)
 702 ])
 703
 704
 705 dnl
 706 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 707 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 708 dnl
 709 dnl Substs:
 710 dnl  OPTIMIZE_CXXFLAGS
 711 dnl  WARN_FLAGS
 712 dnl
 713 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
 714   # Optimization flags that are probably a good idea for thrill-seekers. Just
 715   # uncomment the lines below and make, everything else is ready to go...
 716   # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
 717   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 718   AC_SUBST(OPTIMIZE_CXXFLAGS)
 719
 720   WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
 721   AC_SUBST(WARN_FLAGS)
 722 ])
 723
 724
 725 dnl
 726 dnl All installation directory information is determined here.
 727 dnl
 728 dnl Substs:
 729 dnl  gxx_install_dir
 730 dnl  glibcxx_prefixdir
 731 dnl  glibcxx_toolexecdir
 732 dnl  glibcxx_toolexeclibdir
 733 dnl
 734 dnl Assumes cross_compiling bits already done, and with_cross_host in
 735 dnl particular.
 736 dnl
 737 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
 738 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
 739 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
 740   glibcxx_toolexecdir=no
 741   glibcxx_toolexeclibdir=no
 742   glibcxx_prefixdir=$prefix
 743
 744   AC_MSG_CHECKING([for gxx-include-dir])
 745   AC_ARG_WITH([gxx-include-dir],
 746     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 747                    [installation directory for include files]),
 748     [case "$withval" in
 749       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 750       no)  gxx_include_dir=no ;;
 751       *)   gxx_include_dir=$withval ;;
 752      esac],
 753     [gxx_include_dir=no])
 754   AC_MSG_RESULT($gxx_include_dir)
 755
 756   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 757   AC_ARG_ENABLE([version-specific-runtime-libs],
 758     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 759                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 760     [case "$enableval" in
 761       yes) version_specific_libs=yes ;;
 762       no)  version_specific_libs=no ;;
 763       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 764      esac],
 765     [version_specific_libs=no])
 766   AC_MSG_RESULT($version_specific_libs)
 767
 768   # Default case for install directory for include files.
 769   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 770     gxx_include_dir='include/c++/${gcc_version}'
 771     if test -n "$with_cross_host" &&
 772        test x"$with_cross_host" != x"no"; then
 773       gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
 774     else
 775       gxx_include_dir='${prefix}/'"$gxx_include_dir"
 776     fi
 777   fi
 778
 779   # Version-specific runtime libs processing.
 780   if test $version_specific_libs = yes; then
 781     # Need the gcc compiler version to know where to install libraries
 782     # and header files if --enable-version-specific-runtime-libs option
 783     # is selected.  FIXME: these variables are misnamed, there are
 784     # no executables installed in _toolexecdir or _toolexeclibdir.
 785     if test x"$gxx_include_dir" = x"no"; then
 786       gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
 787     fi
 788     glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 789     glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
 790   fi
 791
 792   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 793   # Install a library built with a cross compiler in tooldir, not libdir.
 794   if test x"$glibcxx_toolexecdir" = x"no"; then
 795     if test -n "$with_cross_host" &&
 796        test x"$with_cross_host" != x"no"; then
 797       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 798       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 799     else
 800       glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
 801       glibcxx_toolexeclibdir='${libdir}'
 802     fi
 803     multi_os_directory=`$CXX -print-multi-os-directory`
 804     case $multi_os_directory in
 805       .) ;; # Avoid trailing /.
 806       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 807     esac
 808   fi
 809
 810   AC_MSG_CHECKING([for install location])
 811   AC_MSG_RESULT($gxx_include_dir)
 812
 813   AC_SUBST(glibcxx_prefixdir)
 814   AC_SUBST(gxx_include_dir)
 815   AC_SUBST(glibcxx_toolexecdir)
 816   AC_SUBST(glibcxx_toolexeclibdir)
 817 ])
 818
 819
 820 dnl
 821 dnl GLIBCXX_ENABLE
 822 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 823 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 824 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 825 dnl
 826 dnl See docs/html/17_intro/configury.html#enable for documentation.
 827 dnl
 828 m4_define([GLIBCXX_ENABLE],[dnl
 829 m4_define([_g_switch],[--enable-$1])dnl
 830 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
 831  AC_ARG_ENABLE([$1],m4_dquote(_g_help),
 832   m4_bmatch([$5],
 833    [^permit ],
 834      [[
 835       case "$enableval" in
 836        m4_bpatsubst([$5],[permit ])) ;;
 837        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 838           dnl Idea for future:  generate a URL pointing to
 839           dnl "onlinedocs/configopts.html#whatever"
 840       esac
 841      ]],
 842    [^$],
 843      [[
 844       case "$enableval" in
 845        yes|no) ;;
 846        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 847       esac
 848      ]],
 849    [[$5]]),
 850   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 851 m4_undefine([_g_switch])dnl
 852 m4_undefine([_g_help])dnl
 853 ])
 854
 855
 856 dnl
 857 dnl Check for ISO/IEC 9899:1999 "C99" support.
 858 dnl
 859 dnl --enable-c99 defines _GLIBCXX_USE_C99
 860 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 861 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 862 dnl       Where DEFAULT is either `yes' or `no'.
 863 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 864 dnl
 865 AC_DEFUN([GLIBCXX_ENABLE_C99], [
 866   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 867
 868   if test x"$enable_c99" = x"yes"; then
 869
 870   AC_LANG_SAVE
 871   AC_LANG_CPLUSPLUS
 872
 873   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
 874   # undefined and fake C99 facilities - like pre-standard snprintf - may be
 875   # spuriously enabled.
 876   # Long term, -std=c++0x could be even better, could manage to explicitely
 877   # request C99 facilities to the underlying C headers.
 878   ac_save_CXXFLAGS="$CXXFLAGS"
 879   CXXFLAGS="$CXXFLAGS -std=c++98"
 880   ac_save_LIBS="$LIBS"
 881   ac_save_gcc_no_link="$gcc_no_link"
 882
 883   if test x$gcc_no_link != xyes; then
 884     # Use -fno-exceptions to that the C driver can link these tests without
 885     # hitting undefined references to personality routines.
 886     CXXFLAGS="$CXXFLAGS -fno-exceptions"
 887     AC_CHECK_LIB(m, sin, [
 888       LIBS="$LIBS -lm"
 889     ], [
 890       # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
 891       gcc_no_link=yes
 892     ])
 893   fi
 894
 895   # Check for the existence of <math.h> functions used if C99 is enabled.
 896   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 897   AC_CACHE_VAL(glibcxx_cv_c99_math, [
 898   GCC_TRY_COMPILE_OR_LINK(
 899      [#include <math.h>
 900       volatile double d1, d2;
 901       volatile int i;],
 902      [i = fpclassify(d1);
 903       i = isfinite(d1);
 904       i = isinf(d1);
 905       i = isnan(d1);
 906       i = isnormal(d1);
 907       i = signbit(d1);
 908       i = isgreater(d1, d2);
 909       i = isgreaterequal(d1, d2);
 910       i = isless(d1, d2);
 911       i = islessequal(d1, d2);
 912       i = islessgreater(d1, d2);
 913       i = islessgreater(d1, d2);
 914       i = isunordered(d1, d2);
 915      ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
 916   ])
 917   AC_MSG_RESULT($glibcxx_cv_c99_math)
 918   if test x"$glibcxx_cv_c99_math" = x"yes"; then
 919     AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
 920               [Define if C99 functions or macros in <math.h> should be imported
 921               in <cmath> in namespace std.])
 922   fi
 923
 924   # Check for the existence of <complex.h> complex math functions.
 925   # This is necessary even though libstdc++ uses the builtin versions
 926   # of these functions, because if the builtin cannot be used, a reference
 927   # to the library function is emitted.
 928   AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
 929   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
 930   glibcxx_cv_c99_complex=no;
 931   if test x"$ac_has_complex_h" = x"yes"; then
 932     AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
 933     GCC_TRY_COMPILE_OR_LINK(
 934        [#include <complex.h>
 935         typedef __complex__ float float_type;
 936         typedef __complex__ double double_type;
 937         typedef __complex__ long double ld_type;
 938         volatile float_type tmpf;
 939         volatile double_type tmpd;
 940         volatile ld_type tmpld;
 941         volatile float f;
 942         volatile double d;
 943         volatile long double ld;],
 944        [f = cabsf(tmpf);
 945         f = cargf(tmpf);
 946         tmpf = ccosf(tmpf);
 947         tmpf = ccoshf(tmpf);
 948         tmpf = cexpf(tmpf);
 949         tmpf = clogf(tmpf);
 950         tmpf = csinf(tmpf);
 951         tmpf = csinhf(tmpf);
 952         tmpf = csqrtf(tmpf);
 953         tmpf = ctanf(tmpf);
 954         tmpf = ctanhf(tmpf);
 955         tmpf = cpowf(tmpf, tmpf);
 956         tmpf = cprojf(tmpf);
 957         d = cabs(tmpd);
 958         d = carg(tmpd);
 959         tmpd = ccos(tmpd);
 960         tmpd = ccosh(tmpd);
 961         tmpd = cexp(tmpd);
 962         tmpd = clog(tmpd);
 963         tmpd = csin(tmpd);
 964         tmpd = csinh(tmpd);
 965         tmpd = csqrt(tmpd);
 966         tmpd = ctan(tmpd);
 967         tmpd = ctanh(tmpd);
 968         tmpd = cpow(tmpd, tmpd);
 969         tmpd = cproj(tmpd);
 970         ld = cabsl(tmpld);
 971         ld = cargl(tmpld);
 972         tmpld = ccosl(tmpld);
 973         tmpld = ccoshl(tmpld);
 974         tmpld = cexpl(tmpld);
 975         tmpld = clogl(tmpld);
 976         tmpld = csinl(tmpld);
 977         tmpld = csinhl(tmpld);
 978         tmpld = csqrtl(tmpld);
 979         tmpld = ctanl(tmpld);
 980         tmpld = ctanhl(tmpld);
 981         tmpld = cpowl(tmpld, tmpld);
 982         tmpld = cprojl(tmpld);
 983        ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
 984   fi
 985   AC_MSG_RESULT($glibcxx_cv_c99_complex)
 986   if test x"$glibcxx_cv_c99_complex" = x"yes"; then
 987     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
 988               [Define if C99 functions in <complex.h> should be used in
 989               <complex>. Using compiler builtins for these functions requires
 990               corresponding C99 library functions to be present.])
 991   fi
 992
 993   # Check for the existence in <stdio.h> of vscanf, et. al.
 994   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 995   AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
 996   GCC_TRY_COMPILE_OR_LINK(
 997      [#include <stdio.h>
 998       #include <stdarg.h>
 999       void foo(char* fmt, ...)
1000       {
1001         va_list args; va_start(args, fmt);
1002         vfscanf(stderr, "%i", args);
1003         vscanf("%i", args);
1004         vsnprintf(fmt, 0, "%i", args);
1005         vsscanf(fmt, "%i", args);
1006       }],
1007      [snprintf("12", 0, "%i");],
1008      [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1009   ])
1010   AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1011
1012   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1013   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1014   AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1015   GCC_TRY_COMPILE_OR_LINK(
1016      [#include <stdlib.h>
1017       volatile float f;
1018       volatile long double ld;
1019       volatile unsigned long long ll;
1020       lldiv_t mydivt;],
1021      [char* tmp;
1022       f = strtof("gnu", &tmp);
1023       ld = strtold("gnu", &tmp);
1024       ll = strtoll("gnu", &tmp, 10);
1025       ll = strtoull("gnu", &tmp, 10);
1026       ll = llabs(10);
1027       mydivt = lldiv(10,1);
1028       ll = mydivt.quot;
1029       ll = mydivt.rem;
1030       ll = atoll("10");
1031       _Exit(0);
1032       ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1033   ])
1034   AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1035
1036   # Check for the existence in <wchar.h> of wcstold, etc.
1037   glibcxx_cv_c99_wchar=no;
1038   if test x"$ac_has_wchar_h" = xyes &&
1039      test x"$ac_has_wctype_h" = xyes; then
1040     AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1041     AC_TRY_COMPILE([#include <wchar.h>
1042                     namespace test
1043                     {
1044                       using ::wcstold;
1045                       using ::wcstoll;
1046                       using ::wcstoull;
1047                     }
1048                    ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1049
1050     # Checks for wide character functions that may not be present.
1051     # Injection of these is wrapped with guard macros.
1052     # NB: only put functions here, instead of immediately above, if
1053     # absolutely necessary.
1054     AC_TRY_COMPILE([#include <wchar.h>
1055                     namespace test { using ::vfwscanf; } ], [],
1056                    [AC_DEFINE(HAVE_VFWSCANF,1,
1057                         [Defined if vfwscanf exists.])],[])
1058
1059     AC_TRY_COMPILE([#include <wchar.h>
1060                     namespace test { using ::vswscanf; } ], [],
1061                    [AC_DEFINE(HAVE_VSWSCANF,1,
1062                         [Defined if vswscanf exists.])],[])
1063
1064     AC_TRY_COMPILE([#include <wchar.h>
1065                     namespace test { using ::vwscanf; } ], [],
1066                    [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1067
1068     AC_TRY_COMPILE([#include <wchar.h>
1069                     namespace test { using ::wcstof; } ], [],
1070                    [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1071
1072     AC_TRY_COMPILE([#include <wctype.h>],
1073                    [ wint_t t; int i = iswblank(t);],
1074                    [AC_DEFINE(HAVE_ISWBLANK,1,
1075                         [Defined if iswblank exists.])],[])
1076
1077     AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1078   fi
1079
1080   # Option parsed, now set things appropriately.
1081   if test x"$glibcxx_cv_c99_math" = x"no" ||
1082      test x"$glibcxx_cv_c99_complex" = x"no" ||
1083      test x"$glibcxx_cv_c99_stdio" = x"no" ||
1084      test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1085      test x"$glibcxx_cv_c99_wchar" = x"no"; then
1086     enable_c99=no;
1087   else
1088     AC_DEFINE(_GLIBCXX_USE_C99, 1,
1089     [Define if C99 functions or macros from <wchar.h>, <math.h>,
1090     <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1091   fi
1092
1093   gcc_no_link="$ac_save_gcc_no_link"
1094   LIBS="$ac_save_LIBS"
1095   CXXFLAGS="$ac_save_CXXFLAGS"
1096   AC_LANG_RESTORE
1097   fi
1098
1099   AC_MSG_CHECKING([for fully enabled ISO C99 support])
1100   AC_MSG_RESULT($enable_c99)
1101 ])
1102
1103
1104 dnl
1105 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1106 dnl implementation of 20.8.5 [time.clock], and 30.2.2 [thread.thread.this]
1107 dnl in the current C++0x working draft.
1108 dnl
1109 dnl --enable-libstdcxx-time
1110 dnl --enable-libstdcxx-time=yes
1111 dnl        checks for the availability of monotonic and realtime clocks,
1112 dnl        nanosleep and sched_yield in libc and libposix4 and, in case, links
1113 dnl       the latter
1114 dnl --enable-libstdcxx-time=rt
1115 dnl        also searches (and, in case, links) librt.  Note that this is
1116 dnl        not always desirable because, in glibc, for example, in turn it
1117 dnl        triggers the linking of libpthread too, which activates locking,
1118 dnl        a large overhead for single-thread programs.
1119 dnl --enable-libstdcxx-time=no
1120 dnl --disable-libstdcxx-time
1121 dnl        disables the checks completely
1122 dnl
1123 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1124
1125   AC_MSG_CHECKING([for clock_gettime, nanosleep and sched_yield])
1126   GLIBCXX_ENABLE(libstdcxx-time,$1,[[[=KIND]]],
1127     [use KIND for check type],
1128     [permit yes|no|rt])
1129
1130   AC_LANG_SAVE
1131   AC_LANG_CPLUSPLUS
1132   ac_save_CXXFLAGS="$CXXFLAGS"
1133   CXXFLAGS="$CXXFLAGS -fno-exceptions"
1134   ac_save_LIBS="$LIBS"
1135
1136   ac_has_clock_monotonic=no
1137   ac_has_clock_realtime=no
1138   AC_MSG_RESULT($enable_libstdcxx_time)
1139
1140   if test x"$enable_libstdcxx_time" != x"no"; then
1141
1142     if test x"$enable_libstdcxx_time" = x"rt"; then
1143       AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1144       AC_SEARCH_LIBS(nanosleep, [rt posix4])
1145     else
1146       AC_SEARCH_LIBS(clock_gettime, [posix4])
1147       AC_SEARCH_LIBS(nanosleep, [posix4])
1148     fi
1149
1150     case "$ac_cv_search_clock_gettime" in
1151       -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1152       ;;
1153     esac
1154     case "$ac_cv_search_nanosleep" in
1155       -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1156       ;;
1157     esac
1158
1159     AC_SEARCH_LIBS(sched_yield, [rt posix4])
1160
1161     case "$ac_cv_search_sched_yield" in
1162       -lposix4*)
1163       GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1164       AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1165                 [ Defined if sched_yield is available. ])
1166       ;;
1167       -lrt*)
1168       if test x"$enable_libstdcxx_time" = x"rt"; then
1169         GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1170         AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1171                   [ Defined if sched_yield is available. ])
1172       fi
1173       ;;
1174       *)
1175       AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1176                 [ Defined if sched_yield is available. ])
1177       ;;
1178     esac
1179
1180     AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1181
1182     if test x"$ac_has_unistd_h" = x"yes"; then
1183       AC_MSG_CHECKING([for monotonic clock])
1184       AC_TRY_LINK(
1185         [#include <unistd.h>
1186          #include <time.h>
1187         ],
1188         [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1189           timespec tp;
1190          #endif
1191           clock_gettime(CLOCK_MONOTONIC, &tp);
1192         ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1193
1194       AC_MSG_RESULT($ac_has_clock_monotonic)
1195
1196       AC_MSG_CHECKING([for realtime clock])
1197       AC_TRY_LINK(
1198         [#include <unistd.h>
1199          #include <time.h>
1200         ],
1201         [#if _POSIX_TIMERS > 0
1202           timespec tp;
1203          #endif
1204           clock_gettime(CLOCK_REALTIME, &tp);
1205         ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1206
1207       AC_MSG_RESULT($ac_has_clock_realtime)
1208
1209       AC_MSG_CHECKING([for nanosleep])
1210       AC_TRY_LINK(
1211         [#include <unistd.h>
1212          #include <time.h>
1213         ],
1214         [#if _POSIX_TIMERS > 0
1215           timespec tp;
1216          #endif
1217           nanosleep(&tp, 0);
1218         ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1219
1220       AC_MSG_RESULT($ac_has_nanosleep)
1221     fi
1222   fi
1223
1224   if test x"$ac_has_clock_monotonic" = x"yes"; then
1225     AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1226       [ Defined if clock_gettime has monotonic clock support. ])
1227   fi
1228
1229   if test x"$ac_has_clock_realtime" = x"yes"; then
1230     AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1231       [ Defined if clock_gettime has realtime clock support. ])
1232   fi
1233
1234   if test x"$ac_has_nanosleep" = x"yes"; then
1235     AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1236       [ Defined if nanosleep is available. ])
1237   fi
1238
1239   AC_SUBST(GLIBCXX_LIBS)
1240
1241   CXXFLAGS="$ac_save_CXXFLAGS"
1242   LIBS="$ac_save_LIBS"
1243   AC_LANG_RESTORE
1244 ])
1245
1246 dnl
1247 dnl Check for gettimeofday, used in the implementation of 20.8.5
1248 dnl [time.clock] in the current C++0x working draft.
1249 dnl
1250 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1251
1252   AC_MSG_CHECKING([for gettimeofday])
1253
1254   AC_LANG_SAVE
1255   AC_LANG_CPLUSPLUS
1256   ac_save_CXXFLAGS="$CXXFLAGS"
1257   CXXFLAGS="$CXXFLAGS -fno-exceptions"
1258
1259   ac_has_gettimeofday=no;
1260   AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1261   if test x"$ac_has_sys_time_h" = x"yes"; then
1262     AC_MSG_CHECKING([for gettimeofday])
1263     GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1264       [timeval tv; gettimeofday(&tv, 0);],
1265       [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1266
1267     AC_MSG_RESULT($ac_has_gettimeofday)
1268   fi
1269
1270   if test x"$ac_has_gettimeofday" = x"yes"; then
1271     AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1272       [ Defined if gettimeofday is available. ])
1273   fi
1274
1275   CXXFLAGS="$ac_save_CXXFLAGS"
1276   AC_LANG_RESTORE
1277 ])
1278
1279 dnl
1280 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1281 dnl facilities in Chapter 8, "C compatibility".
1282 dnl
1283 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1284
1285   AC_LANG_SAVE
1286   AC_LANG_CPLUSPLUS
1287
1288   # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1289   # undefined and fake C99 facilities may be spuriously enabled.
1290   ac_save_CXXFLAGS="$CXXFLAGS"
1291   CXXFLAGS="$CXXFLAGS -std=c++98"
1292
1293   # Check for the existence of <complex.h> complex math functions used
1294   # by tr1/complex.
1295   AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1296   ac_c99_complex_tr1=no;
1297   if test x"$ac_has_complex_h" = x"yes"; then
1298     AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1299     AC_TRY_COMPILE([#include <complex.h>],
1300                    [typedef __complex__ float float_type; float_type tmpf;
1301                     cacosf(tmpf);
1302                     casinf(tmpf);
1303                     catanf(tmpf);
1304                     cacoshf(tmpf);
1305                     casinhf(tmpf);
1306                     catanhf(tmpf);
1307                     typedef __complex__ double double_type; double_type tmpd;
1308                     cacos(tmpd);
1309                     casin(tmpd);
1310                     catan(tmpd);
1311                     cacosh(tmpd);
1312                     casinh(tmpd);
1313                     catanh(tmpd);
1314                     typedef __complex__ long double ld_type; ld_type tmpld;
1315                     cacosl(tmpld);
1316                     casinl(tmpld);
1317                     catanl(tmpld);
1318                     cacoshl(tmpld);
1319                     casinhl(tmpld);
1320                     catanhl(tmpld);
1321                    ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1322   fi
1323   AC_MSG_RESULT($ac_c99_complex_tr1)
1324   if test x"$ac_c99_complex_tr1" = x"yes"; then
1325     AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1326               [Define if C99 functions in <complex.h> should be used in
1327               <tr1/complex>. Using compiler builtins for these functions
1328               requires corresponding C99 library functions to be present.])
1329   fi
1330
1331   # Check for the existence of <ctype.h> functions.
1332   AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1333   AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1334   AC_TRY_COMPILE([#include <ctype.h>],
1335                  [int ch;
1336                   int ret;
1337                   ret = isblank(ch);
1338                  ],[glibcxx_cv_c99_ctype_tr1=yes],
1339                    [glibcxx_cv_c99_ctype_tr1=no])
1340   ])
1341   AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1342   if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1343     AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1344               [Define if C99 functions in <ctype.h> should be imported in
1345               <tr1/cctype> in namespace std::tr1.])
1346   fi
1347
1348   # Check for the existence of <fenv.h> functions.
1349   AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1350   ac_c99_fenv_tr1=no;
1351   if test x"$ac_has_fenv_h" = x"yes"; then
1352     AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1353     AC_TRY_COMPILE([#include <fenv.h>],
1354                    [int except, mode;
1355                     fexcept_t* pflag;
1356                     fenv_t* penv;
1357                     int ret;
1358                     ret = feclearexcept(except);
1359                     ret = fegetexceptflag(pflag, except);
1360                     ret = feraiseexcept(except);
1361                     ret = fesetexceptflag(pflag, except);
1362                     ret = fetestexcept(except);
1363                     ret = fegetround();
1364                     ret = fesetround(mode);
1365                     ret = fegetenv(penv);
1366                     ret = feholdexcept(penv);
1367                     ret = fesetenv(penv);
1368                     ret = feupdateenv(penv);
1369                    ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1370   fi
1371   AC_MSG_RESULT($ac_c99_fenv_tr1)
1372   if test x"$ac_c99_fenv_tr1" = x"yes"; then
1373     AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1374               [Define if C99 functions in <fenv.h> should be imported in
1375               <tr1/cfenv> in namespace std::tr1.])
1376   fi
1377
1378   # Check for the existence of <stdint.h> types.
1379   AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1380   AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1381   AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1382                   #define __STDC_CONSTANT_MACROS
1383                   #include <stdint.h>],
1384                  [typedef int8_t          my_int8_t;
1385                   my_int8_t               i8 = INT8_MIN;
1386                   i8 = INT8_MAX;
1387                   typedef int16_t         my_int16_t;
1388                   my_int16_t              i16 = INT16_MIN;
1389                   i16 = INT16_MAX;
1390                   typedef int32_t         my_int32_t;
1391                   my_int32_t              i32 = INT32_MIN;
1392                   i32 = INT32_MAX;
1393                   typedef int64_t         my_int64_t;
1394                   my_int64_t              i64 = INT64_MIN;
1395                   i64 = INT64_MAX;
1396                   typedef int_fast8_t     my_int_fast8_t;
1397                   my_int_fast8_t          if8 = INT_FAST8_MIN;
1398                   if8 = INT_FAST8_MAX;
1399                   typedef int_fast16_t    my_int_fast16_t;
1400                   my_int_fast16_t         if16 = INT_FAST16_MIN;
1401                   if16 = INT_FAST16_MAX;
1402                   typedef int_fast32_t    my_int_fast32_t;
1403                   my_int_fast32_t         if32 = INT_FAST32_MIN;
1404                   if32 = INT_FAST32_MAX;
1405                   typedef int_fast64_t    my_int_fast64_t;
1406                   my_int_fast64_t         if64 = INT_FAST64_MIN;
1407                   if64 = INT_FAST64_MAX;
1408                   typedef int_least8_t    my_int_least8_t;
1409                   my_int_least8_t         il8 = INT_LEAST8_MIN;
1410                   il8 = INT_LEAST8_MAX;
1411                   typedef int_least16_t   my_int_least16_t;
1412                   my_int_least16_t        il16 = INT_LEAST16_MIN;
1413                   il16 = INT_LEAST16_MAX;
1414                   typedef int_least32_t   my_int_least32_t;
1415                   my_int_least32_t        il32 = INT_LEAST32_MIN;
1416                   il32 = INT_LEAST32_MAX;
1417                   typedef int_least64_t   my_int_least64_t;
1418                   my_int_least64_t        il64 = INT_LEAST64_MIN;
1419                   il64 = INT_LEAST64_MAX;
1420                   typedef intmax_t        my_intmax_t;
1421                   my_intmax_t             im = INTMAX_MAX;
1422                   im = INTMAX_MIN;
1423                   typedef intptr_t        my_intptr_t;
1424                   my_intptr_t             ip = INTPTR_MAX;
1425                   ip = INTPTR_MIN;
1426                   typedef uint8_t         my_uint8_t;
1427                   my_uint8_t              ui8 = UINT8_MAX;
1428                   ui8 = UINT8_MAX;
1429                   typedef uint16_t        my_uint16_t;
1430                   my_uint16_t             ui16 = UINT16_MAX;
1431                   ui16 = UINT16_MAX;
1432                   typedef uint32_t        my_uint32_t;
1433                   my_uint32_t             ui32 = UINT32_MAX;
1434                   ui32 = UINT32_MAX;
1435                   typedef uint64_t        my_uint64_t;
1436                   my_uint64_t             ui64 = UINT64_MAX;
1437                   ui64 = UINT64_MAX;
1438                   typedef uint_fast8_t    my_uint_fast8_t;
1439                   my_uint_fast8_t         uif8 = UINT_FAST8_MAX;
1440                   uif8 = UINT_FAST8_MAX;
1441                   typedef uint_fast16_t   my_uint_fast16_t;
1442                   my_uint_fast16_t        uif16 = UINT_FAST16_MAX;
1443                   uif16 = UINT_FAST16_MAX;
1444                   typedef uint_fast32_t   my_uint_fast32_t;
1445                   my_uint_fast32_t        uif32 = UINT_FAST32_MAX;
1446                   uif32 = UINT_FAST32_MAX;
1447                   typedef uint_fast64_t   my_uint_fast64_t;
1448                   my_uint_fast64_t        uif64 = UINT_FAST64_MAX;
1449                   uif64 = UINT_FAST64_MAX;
1450                   typedef uint_least8_t   my_uint_least8_t;
1451                   my_uint_least8_t        uil8 = UINT_LEAST8_MAX;
1452                   uil8 = UINT_LEAST8_MAX;
1453                   typedef uint_least16_t  my_uint_least16_t;
1454                   my_uint_least16_t       uil16 = UINT_LEAST16_MAX;
1455                   uil16 = UINT_LEAST16_MAX;
1456                   typedef uint_least32_t  my_uint_least32_t;
1457                   my_uint_least32_t       uil32 = UINT_LEAST32_MAX;
1458                   uil32 = UINT_LEAST32_MAX;
1459                   typedef uint_least64_t  my_uint_least64_t;
1460                   my_uint_least64_t       uil64 = UINT_LEAST64_MAX;
1461                   uil64 = UINT_LEAST64_MAX;
1462                   typedef uintmax_t       my_uintmax_t;
1463                   my_uintmax_t            uim = UINTMAX_MAX;
1464                   uim = UINTMAX_MAX;
1465                   typedef uintptr_t       my_uintptr_t;
1466                   my_uintptr_t            uip = UINTPTR_MAX;
1467                   uip = UINTPTR_MAX;
1468                  ],[glibcxx_cv_c99_stdint_tr1=yes],
1469                    [glibcxx_cv_c99_stdint_tr1=no])
1470   ])
1471   AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1472   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1473     AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1474               [Define if C99 types in <stdint.h> should be imported in
1475               <tr1/cstdint> in namespace std::tr1.])
1476   fi
1477
1478   # Check for the existence of <math.h> functions.
1479   AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1480   AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1481   AC_TRY_COMPILE([#include <math.h>],
1482                  [typedef double_t  my_double_t;
1483                   typedef float_t   my_float_t;
1484                   acosh(0.0);
1485                   acoshf(0.0f);
1486                   acoshl(0.0l);
1487                   asinh(0.0);
1488                   asinhf(0.0f);
1489                   asinhl(0.0l);
1490                   atanh(0.0);
1491                   atanhf(0.0f);
1492                   atanhl(0.0l);
1493                   cbrt(0.0);
1494                   cbrtf(0.0f);
1495                   cbrtl(0.0l);
1496                   copysign(0.0, 0.0);
1497                   copysignf(0.0f, 0.0f);
1498                   copysignl(0.0l, 0.0l);
1499                   erf(0.0);
1500                   erff(0.0f);
1501                   erfl(0.0l);
1502                   erfc(0.0);
1503                   erfcf(0.0f);
1504                   erfcl(0.0l);
1505                   exp2(0.0);
1506                   exp2f(0.0f);
1507                   exp2l(0.0l);
1508                   expm1(0.0);
1509                   expm1f(0.0f);
1510                   expm1l(0.0l);
1511                   fdim(0.0, 0.0);
1512                   fdimf(0.0f, 0.0f);
1513                   fdiml(0.0l, 0.0l);
1514                   fma(0.0, 0.0, 0.0);
1515                   fmaf(0.0f, 0.0f, 0.0f);
1516                   fmal(0.0l, 0.0l, 0.0l);
1517                   fmax(0.0, 0.0);
1518                   fmaxf(0.0f, 0.0f);
1519                   fmaxl(0.0l, 0.0l);
1520                   fmin(0.0, 0.0);
1521                   fminf(0.0f, 0.0f);
1522                   fminl(0.0l, 0.0l);
1523                   hypot(0.0, 0.0);
1524                   hypotf(0.0f, 0.0f);
1525                   hypotl(0.0l, 0.0l);
1526                   ilogb(0.0);
1527                   ilogbf(0.0f);
1528                   ilogbl(0.0l);
1529                   lgamma(0.0);
1530                   lgammaf(0.0f);
1531                   lgammal(0.0l);
1532                   llrint(0.0);
1533                   llrintf(0.0f);
1534                   llrintl(0.0l);
1535                   llround(0.0);
1536                   llroundf(0.0f);
1537                   llroundl(0.0l);
1538                   log1p(0.0);
1539                   log1pf(0.0f);
1540                   log1pl(0.0l);
1541                   log2(0.0);
1542                   log2f(0.0f);
1543                   log2l(0.0l);
1544                   logb(0.0);
1545                   logbf(0.0f);
1546                   logbl(0.0l);
1547                   lrint(0.0);
1548                   lrintf(0.0f);
1549                   lrintl(0.0l);
1550                   lround(0.0);
1551                   lroundf(0.0f);
1552                   lroundl(0.0l);
1553                   nan(0);
1554                   nanf(0);
1555                   nanl(0);
1556                   nearbyint(0.0);
1557                   nearbyintf(0.0f);
1558                   nearbyintl(0.0l);
1559                   nextafter(0.0, 0.0);
1560                   nextafterf(0.0f, 0.0f);
1561                   nextafterl(0.0l, 0.0l);
1562                   nexttoward(0.0, 0.0);
1563                   nexttowardf(0.0f, 0.0f);
1564                   nexttowardl(0.0l, 0.0l);
1565                   remainder(0.0, 0.0);
1566                   remainderf(0.0f, 0.0f);
1567                   remainderl(0.0l, 0.0l);
1568                   remquo(0.0, 0.0, 0);
1569                   remquof(0.0f, 0.0f, 0);
1570                   remquol(0.0l, 0.0l, 0);
1571                   rint(0.0);
1572                   rintf(0.0f);
1573                   rintl(0.0l);
1574                   round(0.0);
1575                   roundf(0.0f);
1576                   roundl(0.0l);
1577                   scalbln(0.0, 0l);
1578                   scalblnf(0.0f, 0l);
1579                   scalblnl(0.0l, 0l);
1580                   scalbn(0.0, 0);
1581                   scalbnf(0.0f, 0);
1582                   scalbnl(0.0l, 0);
1583                   tgamma(0.0);
1584                   tgammaf(0.0f);
1585                   tgammal(0.0l);
1586                   trunc(0.0);
1587                   truncf(0.0f);
1588                   truncl(0.0l);
1589                  ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1590   ])
1591   AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1592   if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1593     AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1594               [Define if C99 functions or macros in <math.h> should be imported
1595               in <tr1/cmath> in namespace std::tr1.])
1596   fi
1597
1598   # Check for the existence of <inttypes.h> functions (NB: doesn't make
1599   # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1600   ac_c99_inttypes_tr1=no;
1601   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1602     AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1603     AC_TRY_COMPILE([#include <inttypes.h>],
1604                    [intmax_t i, numer, denom, base;
1605                     const char* s;
1606                     char** endptr;
1607                     intmax_t ret = imaxabs(i);
1608                     imaxdiv_t dret = imaxdiv(numer, denom);
1609                     ret = strtoimax(s, endptr, base);
1610                     uintmax_t uret = strtoumax(s, endptr, base);
1611                    ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1612   fi
1613   AC_MSG_RESULT($ac_c99_inttypes_tr1)
1614   if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1615     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1616               [Define if C99 functions in <inttypes.h> should be imported in
1617               <tr1/cinttypes> in namespace std::tr1.])
1618   fi
1619
1620   # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1621   # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1622   ac_c99_inttypes_wchar_t_tr1=no;
1623   if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1624     AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1625     AC_TRY_COMPILE([#include <inttypes.h>],
1626                    [intmax_t base;
1627                     const wchar_t* s;
1628                     wchar_t** endptr;
1629                     intmax_t ret = wcstoimax(s, endptr, base);
1630                     uintmax_t uret = wcstoumax(s, endptr, base);
1631                    ],[ac_c99_inttypes_wchar_t_tr1=yes],
1632                      [ac_c99_inttypes_wchar_t_tr1=no])
1633   fi
1634   AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1635   if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1636     AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1637               [Define if wchar_t C99 functions in <inttypes.h> should be
1638               imported in <tr1/cinttypes> in namespace std::tr1.])
1639   fi
1640
1641   # Check for the existence of the <stdbool.h> header.
1642   AC_CHECK_HEADERS(stdbool.h)
1643
1644   # Check for the existence of the <stdalign.h> header.
1645   AC_CHECK_HEADERS(stdalign.h)
1646
1647   CXXFLAGS="$ac_save_CXXFLAGS"
1648   AC_LANG_RESTORE
1649 ])
1650
1651 dnl
1652 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1653 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1654 dnl
1655 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1656
1657   AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1658   AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1659     if test -r /dev/random && test -r /dev/urandom; then
1660       glibcxx_cv_random_tr1=yes;
1661     else
1662       glibcxx_cv_random_tr1=no;
1663     fi
1664   ])
1665   AC_MSG_RESULT($glibcxx_cv_random_tr1)
1666
1667   if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1668     AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1669               [Define if /dev/random and /dev/urandom are available for
1670                the random_device of TR1 (Chapter 5.1).])
1671   fi
1672
1673 ])
1674
1675 dnl
1676 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1677 dnl
1678 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1679
1680   AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1681   AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1682                  [#include <stdio.h>],
1683                  [AC_MSG_ERROR([computing EOF failed])])
1684   ])
1685   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1686                      [Define to the value of the EOF integer constant.])
1687
1688   AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1689   AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1690                  [#include <stdio.h>],
1691                  [AC_MSG_ERROR([computing SEEK_CUR failed])])
1692   ])
1693   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1694                      [Define to the value of the SEEK_CUR integer constant.])
1695
1696   AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1697   AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1698                  [#include <stdio.h>],
1699                  [AC_MSG_ERROR([computing SEEK_END failed])])
1700   ])
1701   AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1702                      [Define to the value of the SEEK_END integer constant.])
1703 ])
1704
1705 dnl
1706 dnl Check whether required C++ overloads are present in <math.h>.
1707 dnl
1708
1709 AC_DEFUN([GLIBCXX_CHECK_MATH_PROTO], [
1710
1711   AC_LANG_SAVE
1712   AC_LANG_CPLUSPLUS
1713
1714   case "$host" in
1715     *-*-solaris2.*)
1716       # Solaris 8 FCS only had an overload for double std::abs(double) in
1717       # <iso/math_iso.h>.  Patches 111721-04 (SPARC) and 112757-01 (x86)
1718       # introduced the full set also found from Solaris 9 onwards.
1719       AC_MSG_CHECKING([for float std::abs(float) overload])
1720       AC_CACHE_VAL(glibcxx_cv_abs_float, [
1721         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1722           [#include <math.h>
1723            namespace std {
1724              inline float abs(float __x)
1725              {  return __builtin_fabsf(__x); }
1726            }
1727         ])],
1728         [glibcxx_cv_abs_float=no],
1729         [glibcxx_cv_abs_float=yes]
1730       )])
1731
1732       # autoheader cannot handle indented templates.
1733       AH_VERBATIM([__CORRECT_ISO_CPP_MATH_H_PROTO1],
1734         [/* Define if all C++ overloads are available in <math.h>.  */
1735 #if __cplusplus >= 199711L
1736 #undef __CORRECT_ISO_CPP_MATH_H_PROTO1
1737 #endif])
1738       AH_VERBATIM([__CORRECT_ISO_CPP_MATH_H_PROTO2],
1739         [/* Define if only double std::abs(double) is available in <math.h>.  */
1740 #if __cplusplus >= 199711L
1741 #undef __CORRECT_ISO_CPP_MATH_H_PROTO2
1742 #endif])
1743
1744       if test $glibcxx_cv_abs_float = yes; then
1745         AC_DEFINE(__CORRECT_ISO_CPP_MATH_H_PROTO1)
1746       else
1747         AC_DEFINE(__CORRECT_ISO_CPP_MATH_H_PROTO2)
1748       fi
1749       AC_MSG_RESULT($glibcxx_cv_abs_float)
1750       ;;
1751   esac
1752
1753   AC_LANG_RESTORE
1754 ])
1755
1756 dnl
1757 dnl Check whether required C++ overloads are present in <stdlib.h>.
1758 dnl
1759
1760 AC_DEFUN([GLIBCXX_CHECK_STDLIB_PROTO], [
1761
1762   AC_LANG_SAVE
1763   AC_LANG_CPLUSPLUS
1764
1765   case "$host" in
1766     *-*-solaris2.*)
1767       # Solaris 8 FCS lacked the overloads for long std::abs(long) and
1768       # ldiv_t std::div(long, long) in <iso/stdlib_iso.h>.  Patches 109607-02
1769       # (SPARC) and 109608-02 (x86) introduced them.
1770       AC_MSG_CHECKING([for long std::abs(long) overload])
1771       AC_CACHE_VAL(glibcxx_cv_abs_long, [
1772         AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1773           [#include <stdlib.h>
1774            namespace std {
1775              inline long
1776              abs(long __i) { return labs(__i); }
1777            }
1778         ])],
1779         [glibcxx_cv_abs_long=no],
1780         [glibcxx_cv_abs_long=yes]
1781       )])
1782
1783       # autoheader cannot handle indented templates.
1784       AH_VERBATIM([__CORRECT_ISO_CPP_STDLIB_H_PROTO],
1785         [/* Define if all C++ overloads are available in <stdlib.h>.  */
1786 #if __cplusplus >= 199711L
1787 #undef __CORRECT_ISO_CPP_STDLIB_H_PROTO
1788 #endif])
1789       if test $glibcxx_cv_abs_long = yes; then
1790         AC_DEFINE(__CORRECT_ISO_CPP_STDLIB_H_PROTO, 1)
1791       fi
1792       AC_MSG_RESULT($glibcxx_cv_abs_long)
1793       ;;
1794   esac
1795
1796   AC_LANG_RESTORE
1797 ])
1798
1799 dnl
1800 dnl Check whether macros, etc are present for <system_error>
1801 dnl
1802 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1803
1804 m4_pushdef([n_syserr], [1])dnl
1805 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1806                       ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1807                       EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1808                       ECHILD, ENOSPC, EPERM,
1809                       ETIMEDOUT, EWOULDBLOCK],
1810 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1811 AC_MSG_CHECKING([for syserr])
1812 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1813 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1814                                    [int i = syserr;])],
1815                   [glibcxx_cv_system_error[]n_syserr=yes],
1816                   [glibcxx_cv_system_error[]n_syserr=no])
1817 ])
1818 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1819 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1820   AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1821 fi
1822 m4_define([n_syserr], m4_incr(n_syserr))dnl
1823 m4_popdef([SYSERR])dnl
1824 ])
1825 m4_popdef([n_syserr])dnl
1826 ])
1827
1828 dnl
1829 dnl Check for what type of C headers to use.
1830 dnl
1831 dnl --enable-cheaders= [does stuff].
1832 dnl --disable-cheaders [does not do anything, really].
1833 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1834 dnl       Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1835 dnl
1836 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1837   GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1838     [construct "C" headers for g++], [permit c|c_std|c_global])
1839   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1840
1841   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1842
1843   # Allow overrides to configure.host here.
1844   if test $enable_cheaders = c_global; then
1845      c_compatibility=yes
1846   fi
1847
1848   AC_SUBST(C_INCLUDE_DIR)
1849   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1850   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1851   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1852   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1853 ])
1854
1855
1856 dnl
1857 dnl Check for which locale library to use.  The choice is mapped to
1858 dnl a subdirectory of config/locale.
1859 dnl
1860 dnl Default is generic.
1861 dnl
1862 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1863   GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1864     [use MODEL for target locale package],
1865     [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1866
1867   # Deal with gettext issues.  Default to not using it (=no) until we detect
1868   # support for it later.  Let the user turn it off via --e/d, but let that
1869   # default to on for easier handling.
1870   USE_NLS=no
1871   AC_ARG_ENABLE(nls,
1872     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1873     [],
1874     [enable_nls=yes])
1875
1876   # Either a known package, or "auto"
1877   if test $enable_clocale = no || test $enable_clocale = yes; then
1878      enable_clocale=auto
1879   fi
1880   enable_clocale_flag=$enable_clocale
1881
1882   # Probe for locale model to use if none specified.
1883   # Default to "generic".
1884   if test $enable_clocale_flag = auto; then
1885     case ${target_os} in
1886       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1887         enable_clocale_flag=gnu
1888         ;;
1889       darwin* | freebsd*)
1890         enable_clocale_flag=darwin
1891         ;;
1892       *)
1893         if test x"$with_newlib" = x"yes"; then
1894           enable_clocale_flag=newlib
1895         else
1896           enable_clocale_flag=generic
1897         fi
1898         ;;
1899     esac
1900   fi
1901
1902   # Sanity check model, and test for special functionality.
1903   if test $enable_clocale_flag = gnu; then
1904     AC_EGREP_CPP([_GLIBCXX_ok], [
1905     #include <features.h>
1906     #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
1907       _GLIBCXX_ok
1908     #endif
1909     ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1910
1911     # Set it to scream when it hurts.
1912     ac_save_CFLAGS="$CFLAGS"
1913     CFLAGS="-Wimplicit-function-declaration -Werror"
1914
1915     # Use strxfrm_l if available.
1916     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1917                     #include <string.h>
1918                     #include <locale.h>],
1919                     [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1920                     AC_DEFINE(HAVE_STRXFRM_L, 1,
1921                     [Define if strxfrm_l is available in <string.h>.]),)
1922
1923     # Use strerror_l if available.
1924     AC_TRY_COMPILE([#define _GNU_SOURCE 1
1925                     #include <string.h>
1926                     #include <locale.h>],
1927                     [__locale_t loc; strerror_l(5, loc);],
1928                     AC_DEFINE(HAVE_STRERROR_L, 1,
1929                     [Define if strerror_l is available in <string.h>.]),)
1930
1931     CFLAGS="$ac_save_CFLAGS"
1932   fi
1933
1934   # Perhaps use strerror_r if available, and strerror_l isn't.
1935   ac_save_CFLAGS="$CFLAGS"
1936   CFLAGS="-Wimplicit-function-declaration -Werror"
1937   AC_TRY_COMPILE([#define _GNU_SOURCE 1
1938                   #include <string.h>
1939                   #include <locale.h>],
1940                   [char s[128]; strerror_r(5, s, 128);],
1941                   AC_DEFINE(HAVE_STRERROR_R, 1,
1942                   [Define if strerror_r is available in <string.h>.]),)
1943   CFLAGS="$ac_save_CFLAGS"
1944
1945   # Set configure bits for specified locale package
1946   AC_MSG_CHECKING([for C locale to use])
1947   case ${enable_clocale_flag} in
1948     generic)
1949       AC_MSG_RESULT(generic)
1950
1951       CLOCALE_H=config/locale/generic/c_locale.h
1952       CLOCALE_CC=config/locale/generic/c_locale.cc
1953       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1954       CCOLLATE_CC=config/locale/generic/collate_members.cc
1955       CCTYPE_CC=config/locale/generic/ctype_members.cc
1956       CMESSAGES_H=config/locale/generic/messages_members.h
1957       CMESSAGES_CC=config/locale/generic/messages_members.cc
1958       CMONEY_CC=config/locale/generic/monetary_members.cc
1959       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1960       CTIME_H=config/locale/generic/time_members.h
1961       CTIME_CC=config/locale/generic/time_members.cc
1962       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1963       ;;
1964     darwin)
1965       AC_MSG_RESULT(darwin or freebsd)
1966
1967       CLOCALE_H=config/locale/generic/c_locale.h
1968       CLOCALE_CC=config/locale/generic/c_locale.cc
1969       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1970       CCOLLATE_CC=config/locale/generic/collate_members.cc
1971       CCTYPE_CC=config/locale/darwin/ctype_members.cc
1972       CMESSAGES_H=config/locale/generic/messages_members.h
1973       CMESSAGES_CC=config/locale/generic/messages_members.cc
1974       CMONEY_CC=config/locale/generic/monetary_members.cc
1975       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1976       CTIME_H=config/locale/generic/time_members.h
1977       CTIME_CC=config/locale/generic/time_members.cc
1978       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1979       ;;
1980
1981     gnu)
1982       AC_MSG_RESULT(gnu)
1983
1984       # Declare intention to use gettext, and add support for specific
1985       # languages.
1986       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1987       ALL_LINGUAS="de fr"
1988
1989       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1990       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1991       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1992         USE_NLS=yes
1993       fi
1994       # Export the build objects.
1995       for ling in $ALL_LINGUAS; do \
1996         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1997         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1998       done
1999       AC_SUBST(glibcxx_MOFILES)
2000       AC_SUBST(glibcxx_POFILES)
2001
2002       CLOCALE_H=config/locale/gnu/c_locale.h
2003       CLOCALE_CC=config/locale/gnu/c_locale.cc
2004       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
2005       CCOLLATE_CC=config/locale/gnu/collate_members.cc
2006       CCTYPE_CC=config/locale/gnu/ctype_members.cc
2007       CMESSAGES_H=config/locale/gnu/messages_members.h
2008       CMESSAGES_CC=config/locale/gnu/messages_members.cc
2009       CMONEY_CC=config/locale/gnu/monetary_members.cc
2010       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
2011       CTIME_H=config/locale/gnu/time_members.h
2012       CTIME_CC=config/locale/gnu/time_members.cc
2013       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
2014       ;;
2015     ieee_1003.1-2001)
2016       AC_MSG_RESULT(IEEE 1003.1)
2017
2018       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2019       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2020       CCODECVT_CC=config/locale/generic/codecvt_members.cc
2021       CCOLLATE_CC=config/locale/generic/collate_members.cc
2022       CCTYPE_CC=config/locale/generic/ctype_members.cc
2023       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2024       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2025       CMONEY_CC=config/locale/generic/monetary_members.cc
2026       CNUMERIC_CC=config/locale/generic/numeric_members.cc
2027       CTIME_H=config/locale/generic/time_members.h
2028       CTIME_CC=config/locale/generic/time_members.cc
2029       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2030       ;;
2031     newlib)
2032       AC_MSG_RESULT(newlib)
2033
2034       CLOCALE_H=config/locale/generic/c_locale.h
2035       CLOCALE_CC=config/locale/generic/c_locale.cc
2036       CCODECVT_CC=config/locale/generic/codecvt_members.cc
2037       CCOLLATE_CC=config/locale/generic/collate_members.cc
2038       CCTYPE_CC=config/locale/newlib/ctype_members.cc
2039       CMESSAGES_H=config/locale/generic/messages_members.h
2040       CMESSAGES_CC=config/locale/generic/messages_members.cc
2041       CMONEY_CC=config/locale/generic/monetary_members.cc
2042       CNUMERIC_CC=config/locale/generic/numeric_members.cc
2043       CTIME_H=config/locale/generic/time_members.h
2044       CTIME_CC=config/locale/generic/time_members.cc
2045       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2046       ;;
2047   esac
2048
2049   # This is where the testsuite looks for locale catalogs, using the
2050   # -DLOCALEDIR define during testsuite compilation.
2051   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2052   AC_SUBST(glibcxx_localedir)
2053
2054   # A standalone libintl (e.g., GNU libintl) may be in use.
2055   if test $USE_NLS = yes; then
2056     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2057     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2058   fi
2059   if test $USE_NLS = yes; then
2060     AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2061               [Define if NLS translations are to be used.])
2062   fi
2063
2064   AC_SUBST(USE_NLS)
2065   AC_SUBST(CLOCALE_H)
2066   AC_SUBST(CMESSAGES_H)
2067   AC_SUBST(CCODECVT_CC)
2068   AC_SUBST(CCOLLATE_CC)
2069   AC_SUBST(CCTYPE_CC)
2070   AC_SUBST(CMESSAGES_CC)
2071   AC_SUBST(CMONEY_CC)
2072   AC_SUBST(CNUMERIC_CC)
2073   AC_SUBST(CTIME_H)
2074   AC_SUBST(CTIME_CC)
2075   AC_SUBST(CLOCALE_CC)
2076   AC_SUBST(CLOCALE_INTERNAL_H)
2077 ])
2078
2079
2080 dnl
2081 dnl Check for which std::allocator base class to use.  The choice is
2082 dnl mapped from a subdirectory of include/ext.
2083 dnl
2084 dnl Default is new.
2085 dnl
2086 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2087   AC_MSG_CHECKING([for std::allocator base class])
2088   GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2089     [use KIND for target std::allocator base],
2090     [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2091
2092   # If they didn't use this option switch, or if they specified --enable
2093   # with no specific model, we'll have to look for one.  If they
2094   # specified --disable (???), do likewise.
2095   if test $enable_libstdcxx_allocator = no ||
2096      test $enable_libstdcxx_allocator = yes;
2097   then
2098      enable_libstdcxx_allocator=auto
2099   fi
2100
2101   # Either a known package, or "auto". Auto implies the default choice
2102   # for a particular platform.
2103   enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2104
2105   # Probe for host-specific support if no specific model is specified.
2106   # Default to "new".
2107   if test $enable_libstdcxx_allocator_flag = auto; then
2108     case ${target_os} in
2109       linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2110         enable_libstdcxx_allocator_flag=new
2111         ;;
2112       *)
2113         enable_libstdcxx_allocator_flag=new
2114         ;;
2115     esac
2116   fi
2117   AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2118
2119
2120   # Set configure bits for specified locale package
2121   case ${enable_libstdcxx_allocator_flag} in
2122     bitmap)
2123       ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2124       ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2125       ;;
2126     malloc)
2127       ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2128       ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2129       ;;
2130     mt)
2131       ALLOCATOR_H=config/allocator/mt_allocator_base.h
2132       ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2133       ;;
2134     new)
2135       ALLOCATOR_H=config/allocator/new_allocator_base.h
2136       ALLOCATOR_NAME=__gnu_cxx::new_allocator
2137       ;;
2138     pool)
2139       ALLOCATOR_H=config/allocator/pool_allocator_base.h
2140       ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2141       ;;
2142   esac
2143
2144   AC_SUBST(ALLOCATOR_H)
2145   AC_SUBST(ALLOCATOR_NAME)
2146 ])
2147
2148
2149 dnl
2150 dnl Check for whether the Boost-derived checks should be turned on.
2151 dnl
2152 dnl --enable-concept-checks turns them on.
2153 dnl --disable-concept-checks leaves them off.
2154 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2155 dnl       Where DEFAULT is either `yes' or `no'.
2156 dnl
2157 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2158   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2159   if test $enable_concept_checks = yes; then
2160     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2161               [Define to use concept checking code from the boost libraries.])
2162   fi
2163 ])
2164
2165 dnl
2166 dnl Use extern templates.
2167 dnl
2168 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2169 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2170
2171 dnl  +  Usage:  GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2172 dnl       Where DEFAULT is `yes' or `no'.
2173 dnl
2174 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2175
2176   GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2177
2178   AC_MSG_CHECKING([for extern template support])
2179   AC_MSG_RESULT([$enable_extern_template])
2180
2181   GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2182 ])
2183
2184 dnl
2185 dnl Check for parallel mode pre-requisites, including OpenMP support.
2186 dnl
2187 dnl  +  Usage:  GLIBCXX_ENABLE_PARALLEL
2188 dnl
2189 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2190
2191   enable_parallel=no;
2192
2193   # See if configured libgomp/omp.h exists. (libgomp may be in
2194   # noconfigdirs but not explicitly disabled.)
2195   if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2196     enable_parallel=yes;
2197   else
2198     AC_MSG_NOTICE([target-libgomp not built])
2199   fi
2200
2201   AC_MSG_CHECKING([for parallel mode support])
2202   AC_MSG_RESULT([$enable_parallel])
2203   GLIBCXX_CONDITIONAL(ENABLE_PARALLEL, test $enable_parallel = yes)
2204 ])
2205
2206
2207 dnl
2208 dnl Check for which I/O library to use:  stdio, or something specific.
2209 dnl
2210 dnl Default is stdio.
2211 dnl
2212 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2213   AC_MSG_CHECKING([for underlying I/O to use])
2214   GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2215     [use target-specific I/O package], [permit stdio])
2216
2217   # Now that libio has been removed, you can have any color you want as long
2218   # as it's black.  This is one big no-op until other packages are added, but
2219   # showing the framework never hurts.
2220   case ${enable_cstdio} in
2221     stdio)
2222       CSTDIO_H=config/io/c_io_stdio.h
2223       BASIC_FILE_H=config/io/basic_file_stdio.h
2224       BASIC_FILE_CC=config/io/basic_file_stdio.cc
2225       AC_MSG_RESULT(stdio)
2226       ;;
2227   esac
2228
2229   AC_SUBST(CSTDIO_H)
2230   AC_SUBST(BASIC_FILE_H)
2231   AC_SUBST(BASIC_FILE_CC)
2232 ])
2233
2234
2235 dnl
2236 dnl Check for "unusual" flags to pass to the compiler while building.
2237 dnl
2238 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2239 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2240 dnl --disable-cxx-flags passes nothing.
2241 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2242 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2243 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2244 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2245 dnl       If "default flags" is an empty string, the effect is the same
2246 dnl       as --disable or --enable=no.
2247 dnl
2248 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2249   AC_MSG_CHECKING([for extra compiler flags for building])
2250   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2251     [pass compiler FLAGS when building library],
2252     [case "x$enable_cxx_flags" in
2253       xno | x)   enable_cxx_flags= ;;
2254       x-*)       ;;
2255       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2256      esac])
2257
2258   # Run through flags (either default or command-line) and set anything
2259   # extra (e.g., #defines) that must accompany particular g++ options.
2260   if test -n "$enable_cxx_flags"; then
2261     for f in $enable_cxx_flags; do
2262       case "$f" in
2263         -fhonor-std)  ;;
2264         -*)  ;;
2265         *)   # and we're trying to pass /what/ exactly?
2266              AC_MSG_ERROR([compiler flags start with a -]) ;;
2267       esac
2268     done
2269   fi
2270
2271   EXTRA_CXX_FLAGS="$enable_cxx_flags"
2272   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2273   AC_SUBST(EXTRA_CXX_FLAGS)
2274 ])
2275
2276
2277 dnl
2278 dnl Check to see if debugging libraries are to be built.
2279 dnl
2280 dnl --enable-libstdcxx-debug
2281 dnl builds a separate set of debugging libraries in addition to the
2282 dnl normal (shared, static) libstdc++ binaries.
2283 dnl
2284 dnl --disable-libstdcxx-debug
2285 dnl builds only one (non-debug) version of libstdc++.
2286 dnl
2287 dnl --enable-libstdcxx-debug-flags=FLAGS
2288 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2289 dnl
2290 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2291 dnl       Where DEFAULT is either `yes' or `no'.
2292 dnl
2293 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2294   AC_MSG_CHECKING([for additional debug build])
2295   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2296   AC_MSG_RESULT($enable_libstdcxx_debug)
2297   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2298 ])
2299
2300
2301 dnl
2302 dnl Check for explicit debug flags.
2303 dnl
2304 dnl --enable-libstdcxx-debug-flags='-O1'
2305 dnl is a general method for passing flags to be used when
2306 dnl building debug libraries with --enable-debug.
2307 dnl
2308 dnl --disable-libstdcxx-debug-flags does nothing.
2309 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2310 dnl       If "default flags" is an empty string, the effect is the same
2311 dnl       as --disable or --enable=no.
2312 dnl
2313 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2314   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2315     [pass compiler FLAGS when building debug library],
2316     [case "x$enable_libstdcxx_debug_flags" in
2317       xno | x)    enable_libstdcxx_debug_flags= ;;
2318       x-*)        ;;
2319       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2320      esac])
2321
2322   # Option parsed, now set things appropriately
2323   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2324   AC_SUBST(DEBUG_FLAGS)
2325
2326   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2327 ])
2328
2329
2330 dnl
2331 dnl Check if the user only wants a freestanding library implementation.
2332 dnl
2333 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2334 dnl installing only the headers required by [17.4.1.3] and the language
2335 dnl support library.  More than that will be built (to keep the Makefiles
2336 dnl conveniently clean), but not installed.
2337 dnl
2338 dnl Sets:
2339 dnl  is_hosted  (yes/no)
2340 dnl
2341 dnl Defines:
2342 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
2343 dnl
2344 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2345   AC_ARG_ENABLE([hosted-libstdcxx],
2346     AC_HELP_STRING([--disable-hosted-libstdcxx],
2347                    [only build freestanding C++ runtime support]),,
2348     [case "$host" in
2349         arm*-*-symbianelf*)
2350             enable_hosted_libstdcxx=no
2351             ;;
2352         *)
2353             enable_hosted_libstdcxx=yes
2354             ;;
2355      esac])
2356   if test "$enable_hosted_libstdcxx" = no; then
2357     AC_MSG_NOTICE([Only freestanding libraries will be built])
2358     is_hosted=no
2359     hosted_define=0
2360     enable_abi_check=no
2361     enable_libstdcxx_pch=no
2362   else
2363     is_hosted=yes
2364     hosted_define=1
2365   fi
2366   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2367   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2368     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2369 ])
2370
2371
2372 dnl
2373 dnl Check for template specializations for the 'long long' type.
2374 dnl The result determines only whether 'long long' I/O is enabled; things
2375 dnl like numeric_limits<> specializations are always available.
2376 dnl
2377 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2378 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2379 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2380 dnl       Where DEFAULT is either `yes' or `no'.
2381 dnl
2382 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2383   GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2384   if test $enable_long_long = yes; then
2385     AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2386               [Define if code specialized for long long should be used.])
2387   fi
2388   AC_MSG_CHECKING([for enabled long long specializations])
2389   AC_MSG_RESULT([$enable_long_long])
2390 ])
2391
2392
2393 dnl
2394 dnl Check for decimal floating point.
2395 dnl See:
2396 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2397 dnl
2398 dnl This checks to see if the host supports decimal floating point types.
2399 dnl
2400 dnl Defines:
2401 dnl  _GLIBCXX_USE_DECIMAL_FLOAT
2402 dnl
2403 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2404
2405   # Fake what AC_TRY_COMPILE does, without linking as this is
2406   # unnecessary for this test.
2407
2408     cat > conftest.$ac_ext << EOF
2409 [#]line __oline__ "configure"
2410 int main()
2411 {
2412   _Decimal32 d1;
2413   _Decimal64 d2;
2414   _Decimal128 d3;
2415   return 0;
2416 }
2417 EOF
2418
2419     AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2420     if AC_TRY_EVAL(ac_compile); then
2421       AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2422       [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2423       enable_dfp=yes
2424     else
2425       enable_dfp=no
2426     fi
2427     AC_MSG_RESULT($enable_dfp)
2428     rm -f conftest*
2429 ])
2430
2431 dnl
2432 dnl Check for GNU 128-bit integer and floating point types.
2433 dnl
2434 dnl Note: also checks that the types aren't standard types.
2435 dnl
2436 dnl Defines:
2437 dnl  _GLIBCXX_USE_INT128
2438 dnl  _GLIBCXX_USE_FLOAT128
2439 dnl
2440 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2441
2442   AC_LANG_SAVE
2443   AC_LANG_CPLUSPLUS
2444
2445   # Fake what AC_TRY_COMPILE does, without linking as this is
2446   # unnecessary for this test.
2447
2448     cat > conftest.$ac_ext << EOF
2449 [#]line __oline__ "configure"
2450 template<typename T1, typename T2>
2451   struct same
2452   { typedef T2 type; };
2453
2454 template<typename T>
2455   struct same<T, T>;
2456
2457 int main()
2458 {
2459   typename same<long, __int128>::type                i1;
2460   typename same<long long, __int128>::type           i2;
2461 }
2462 EOF
2463
2464     AC_MSG_CHECKING([for __int128])
2465     if AC_TRY_EVAL(ac_compile); then
2466       AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2467       [Define if __int128 is supported on this host.])
2468       enable_int128=yes
2469     else
2470       enable_int128=no
2471     fi
2472     AC_MSG_RESULT($enable_int128)
2473     rm -f conftest*
2474
2475     cat > conftest.$ac_ext << EOF
2476 [#]line __oline__ "configure"
2477 template<typename T1, typename T2>
2478   struct same
2479   { typedef T2 type; };
2480
2481 template<typename T>
2482   struct same<T, T>;
2483
2484 int main()
2485 {
2486   typename same<double, __float128>::type      f1;
2487   typename same<long double, __float128>::type f2;
2488 }
2489 EOF
2490
2491     AC_MSG_CHECKING([for __float128])
2492     if AC_TRY_EVAL(ac_compile); then
2493       AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2494       [Define if __float128 is supported on this host.])
2495       enable_float128=yes
2496     else
2497       enable_float128=no
2498     fi
2499     AC_MSG_RESULT($enable_float128)
2500     rm -f conftest*
2501
2502   AC_LANG_RESTORE
2503 ])
2504
2505 dnl
2506 dnl Check for template specializations for the 'wchar_t' type.
2507 dnl
2508 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2509 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2510 dnl  +  Usage:  GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2511 dnl       Where DEFAULT is either `yes' or `no'.
2512 dnl
2513 dnl Necessary support must also be present.
2514 dnl
2515 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2516   GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2517
2518   # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2519   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2520   AC_MSG_CHECKING([for mbstate_t])
2521   AC_TRY_COMPILE([#include <wchar.h>],
2522   [mbstate_t teststate;],
2523   have_mbstate_t=yes, have_mbstate_t=no)
2524   AC_MSG_RESULT($have_mbstate_t)
2525   if test x"$have_mbstate_t" = xyes; then
2526     AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2527   fi
2528
2529   # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2530   # ac_has_wchar_h.
2531   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2532
2533   if test x"$enable_wchar_t" = x"yes"; then
2534
2535     AC_LANG_SAVE
2536     AC_LANG_CPLUSPLUS
2537
2538     if test x"$ac_has_wchar_h" = xyes &&
2539        test x"$ac_has_wctype_h" = xyes; then
2540       AC_TRY_COMPILE([#include <wchar.h>
2541                       #include <stddef.h>
2542                       wint_t i;
2543                       long l = WEOF;
2544                       long j = WCHAR_MIN;
2545                       long k = WCHAR_MAX;
2546                       namespace test
2547                       {
2548                         using ::btowc;
2549                         using ::fgetwc;
2550                         using ::fgetws;
2551                         using ::fputwc;
2552                         using ::fputws;
2553                         using ::fwide;
2554                         using ::fwprintf;
2555                         using ::fwscanf;
2556                         using ::getwc;
2557                         using ::getwchar;
2558                         using ::mbrlen;
2559                         using ::mbrtowc;
2560                         using ::mbsinit;
2561                         using ::mbsrtowcs;
2562                         using ::putwc;
2563                         using ::putwchar;
2564                         using ::swprintf;
2565                         using ::swscanf;
2566                         using ::ungetwc;
2567                         using ::vfwprintf;
2568                         using ::vswprintf;
2569                         using ::vwprintf;
2570                         using ::wcrtomb;
2571                         using ::wcscat;
2572                         using ::wcschr;
2573                         using ::wcscmp;
2574                         using ::wcscoll;
2575                         using ::wcscpy;
2576                         using ::wcscspn;
2577                         using ::wcsftime;
2578                         using ::wcslen;
2579                         using ::wcsncat;
2580                         using ::wcsncmp;
2581                         using ::wcsncpy;
2582                         using ::wcspbrk;
2583                         using ::wcsrchr;
2584                         using ::wcsrtombs;
2585                         using ::wcsspn;
2586                         using ::wcsstr;
2587                         using ::wcstod;
2588                         using ::wcstok;
2589                         using ::wcstol;
2590                         using ::wcstoul;
2591                         using ::wcsxfrm;
2592                         using ::wctob;
2593                         using ::wmemchr;
2594                         using ::wmemcmp;
2595                         using ::wmemcpy;
2596                         using ::wmemmove;
2597                         using ::wmemset;
2598                         using ::wprintf;
2599                         using ::wscanf;
2600                       }
2601                      ],[],[], [enable_wchar_t=no])
2602     else
2603       enable_wchar_t=no
2604     fi
2605
2606     AC_LANG_RESTORE
2607   fi
2608
2609   if test x"$enable_wchar_t" = x"yes"; then
2610     AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2611               [Define if code specialized for wchar_t should be used.])
2612   fi
2613
2614   AC_MSG_CHECKING([for enabled wchar_t specializations])
2615   AC_MSG_RESULT([$enable_wchar_t])
2616 ])
2617
2618
2619 dnl
2620 dnl Check to see if building and using a C++ precompiled header can be done.
2621 dnl
2622 dnl --enable-libstdcxx-pch=yes
2623 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2624 dnl may work, after some light-hearted attempts to puzzle out compiler
2625 dnl support, flip bits on in include/Makefile.am
2626 dnl
2627 dnl --disable-libstdcxx-pch
2628 dnl turns off attempts to use or build stdc++.h.gch.
2629 dnl
2630 dnl Substs:
2631 dnl  glibcxx_PCHFLAGS
2632 dnl
2633 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2634   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2635   if test $enable_libstdcxx_pch = yes; then
2636     AC_CACHE_CHECK([for compiler with PCH support],
2637       [glibcxx_cv_prog_CXX_pch],
2638       [ac_save_CXXFLAGS="$CXXFLAGS"
2639        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2640        AC_LANG_SAVE
2641        AC_LANG_CPLUSPLUS
2642        echo '#include <math.h>' > conftest.h
2643        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2644                           -o conftest.h.gch 1>&5 2>&1 &&
2645                 echo '#error "pch failed"' > conftest.h &&
2646           echo '#include "conftest.h"' > conftest.cc &&
2647                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2648        then
2649          glibcxx_cv_prog_CXX_pch=yes
2650        else
2651          glibcxx_cv_prog_CXX_pch=no
2652        fi
2653        rm -f conftest*
2654        CXXFLAGS=$ac_save_CXXFLAGS
2655        AC_LANG_RESTORE
2656       ])
2657     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2658   fi
2659
2660   AC_MSG_CHECKING([for enabled PCH])
2661   AC_MSG_RESULT([$enable_libstdcxx_pch])
2662
2663   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2664   if test $enable_libstdcxx_pch = yes; then
2665     glibcxx_PCHFLAGS="-include bits/stdc++.h"
2666   else
2667     glibcxx_PCHFLAGS=""
2668   fi
2669   AC_SUBST(glibcxx_PCHFLAGS)
2670 ])
2671
2672
2673 dnl
2674 dnl Check for atomic builtins.
2675 dnl See:
2676 dnl http://gcc.gnu.org/onlinedocs/gcc/Atomic-Builtins.html#Atomic-Builtins
2677 dnl
2678 dnl This checks to see if the host supports the compiler-generated
2679 dnl builtins for atomic operations for various integral sizes. Note, this
2680 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2681 dnl that are used should be checked.
2682 dnl
2683 dnl Note:
2684 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2685 dnl
2686 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2687   AC_LANG_SAVE
2688   AC_LANG_CPLUSPLUS
2689   old_CXXFLAGS="$CXXFLAGS"
2690
2691   # Do link tests if possible, instead asm tests, limited to some platforms
2692   # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2693   # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2694   atomic_builtins_link_tests=no
2695   if test x$gcc_no_link != xyes; then
2696     # Can do link tests. Limit to some tested platforms
2697     case "$host" in
2698       *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2699         atomic_builtins_link_tests=yes
2700         ;;
2701     esac
2702   fi
2703
2704   if test x$atomic_builtins_link_tests = xyes; then
2705
2706   # Do link tests.
2707
2708   CXXFLAGS="$CXXFLAGS -fno-exceptions"
2709
2710   AC_MSG_CHECKING([for atomic builtins for bool])
2711   AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2712     AC_TRY_LINK(
2713       [ ],
2714       [typedef bool atomic_type;
2715        atomic_type c1;
2716        atomic_type c2;
2717        const atomic_type c3(0);
2718        __sync_fetch_and_add(&c1, c2);
2719        __sync_val_compare_and_swap(&c1, c3, c2);
2720        __sync_lock_test_and_set(&c1, c3);
2721        __sync_lock_release(&c1);
2722        __sync_synchronize();],
2723       [glibcxx_cv_atomic_bool=yes],
2724       [glibcxx_cv_atomic_bool=no])
2725   ])
2726   AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2727
2728   AC_MSG_CHECKING([for atomic builtins for short])
2729   AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2730     AC_TRY_LINK(
2731       [ ],
2732       [typedef short atomic_type;
2733        atomic_type c1;
2734        atomic_type c2;
2735        const atomic_type c3(0);
2736        __sync_fetch_and_add(&c1, c2);
2737        __sync_val_compare_and_swap(&c1, c3, c2);
2738        __sync_lock_test_and_set(&c1, c3);
2739        __sync_lock_release(&c1);
2740        __sync_synchronize();],
2741       [glibcxx_cv_atomic_short=yes],
2742       [glibcxx_cv_atomic_short=no])
2743   ])
2744   AC_MSG_RESULT($glibcxx_cv_atomic_short)
2745
2746   AC_MSG_CHECKING([for atomic builtins for int])
2747   AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2748     AC_TRY_LINK(
2749       [ ],
2750       [typedef int atomic_type;
2751        atomic_type c1;
2752        atomic_type c2;
2753        const atomic_type c3(0);
2754        __sync_fetch_and_add(&c1, c2);
2755        __sync_val_compare_and_swap(&c1, c3, c2);
2756        __sync_lock_test_and_set(&c1, c3);
2757        __sync_lock_release(&c1);
2758        __sync_synchronize();],
2759       [glibcxx_cv_atomic_int=yes],
2760       [glibcxx_cv_atomic_int=no])
2761   ])
2762   AC_MSG_RESULT($glibcxx_cv_atomic_int)
2763
2764   AC_MSG_CHECKING([for atomic builtins for long long])
2765   AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2766     AC_TRY_LINK(
2767       [ ],
2768       [typedef long long atomic_type;
2769        atomic_type c1;
2770        atomic_type c2;
2771        const atomic_type c3(0);
2772        __sync_fetch_and_add(&c1, c2);
2773        __sync_val_compare_and_swap(&c1, c3, c2);
2774        __sync_lock_test_and_set(&c1, c3);
2775        __sync_lock_release(&c1);
2776        __sync_synchronize();],
2777       [glibcxx_cv_atomic_long_long=yes],
2778       [glibcxx_cv_atomic_long_long=no])
2779   ])
2780   AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2781
2782   else
2783
2784   # Do asm tests.
2785
2786   # Compile unoptimized.
2787   CXXFLAGS='-O0 -S'
2788
2789   # Fake what AC_TRY_COMPILE does.
2790
2791     cat > conftest.$ac_ext << EOF
2792 [#]line __oline__ "configure"
2793 int main()
2794 {
2795   typedef bool atomic_type;
2796   atomic_type c1;
2797   atomic_type c2;
2798   const atomic_type c3(0);
2799   __sync_fetch_and_add(&c1, c2);
2800   __sync_val_compare_and_swap(&c1, c3, c2);
2801   __sync_lock_test_and_set(&c1, c3);
2802   __sync_lock_release(&c1);
2803   __sync_synchronize();
2804   return 0;
2805 }
2806 EOF
2807
2808     AC_MSG_CHECKING([for atomic builtins for bool])
2809     if AC_TRY_EVAL(ac_compile); then
2810       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2811         glibcxx_cv_atomic_bool=no
2812       else
2813         glibcxx_cv_atomic_bool=yes
2814       fi
2815     fi
2816     AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2817     rm -f conftest*
2818
2819     cat > conftest.$ac_ext << EOF
2820 [#]line __oline__ "configure"
2821 int main()
2822 {
2823   typedef short atomic_type;
2824   atomic_type c1;
2825   atomic_type c2;
2826   const atomic_type c3(0);
2827   __sync_fetch_and_add(&c1, c2);
2828   __sync_val_compare_and_swap(&c1, c3, c2);
2829   __sync_lock_test_and_set(&c1, c3);
2830   __sync_lock_release(&c1);
2831   __sync_synchronize();
2832   return 0;
2833 }
2834 EOF
2835
2836     AC_MSG_CHECKING([for atomic builtins for short])
2837     if AC_TRY_EVAL(ac_compile); then
2838       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2839         glibcxx_cv_atomic_short=no
2840       else
2841         glibcxx_cv_atomic_short=yes
2842       fi
2843     fi
2844     AC_MSG_RESULT($glibcxx_cv_atomic_short)
2845     rm -f conftest*
2846
2847     cat > conftest.$ac_ext << EOF
2848 [#]line __oline__ "configure"
2849 int main()
2850 {
2851   // NB: _Atomic_word not necessarily int.
2852   typedef int atomic_type;
2853   atomic_type c1;
2854   atomic_type c2;
2855   const atomic_type c3(0);
2856   __sync_fetch_and_add(&c1, c2);
2857   __sync_val_compare_and_swap(&c1, c3, c2);
2858   __sync_lock_test_and_set(&c1, c3);
2859   __sync_lock_release(&c1);
2860   __sync_synchronize();
2861   return 0;
2862 }
2863 EOF
2864
2865     AC_MSG_CHECKING([for atomic builtins for int])
2866     if AC_TRY_EVAL(ac_compile); then
2867       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2868         glibcxx_cv_atomic_int=no
2869       else
2870         glibcxx_cv_atomic_int=yes
2871       fi
2872     fi
2873     AC_MSG_RESULT($glibcxx_cv_atomic_int)
2874     rm -f conftest*
2875
2876     cat > conftest.$ac_ext << EOF
2877 [#]line __oline__ "configure"
2878 int main()
2879 {
2880   typedef long long atomic_type;
2881   atomic_type c1;
2882   atomic_type c2;
2883   const atomic_type c3(0);
2884   __sync_fetch_and_add(&c1, c2);
2885   __sync_val_compare_and_swap(&c1, c3, c2);
2886   __sync_lock_test_and_set(&c1, c3);
2887   __sync_lock_release(&c1);
2888   __sync_synchronize();
2889   return 0;
2890 }
2891 EOF
2892
2893     AC_MSG_CHECKING([for atomic builtins for long long])
2894     if AC_TRY_EVAL(ac_compile); then
2895       if grep __sync_ conftest.s >/dev/null 2>&1 ; then
2896         glibcxx_cv_atomic_long_long=no
2897       else
2898         glibcxx_cv_atomic_long_long=yes
2899       fi
2900     fi
2901     AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2902     rm -f conftest*
2903
2904   fi
2905
2906   CXXFLAGS="$old_CXXFLAGS"
2907   AC_LANG_RESTORE
2908
2909   # Set atomicity_dir to builtins if either of above tests pass.
2910   if test $glibcxx_cv_atomic_int = yes || test $glibcxx_cv_atomic_bool = yes ; then
2911     AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
2912     [Define if the compiler supports C++11 atomics.])
2913     atomicity_dir=cpu/generic/atomicity_builtins
2914   fi
2915
2916   # If still generic, set to mutex.
2917   if test $atomicity_dir = "cpu/generic" ; then
2918     atomicity_dir=cpu/generic/atomicity_mutex
2919     AC_MSG_WARN([No native atomic operations are provided for this platform.])
2920       if test "x$target_thread_file" = xsingle; then
2921         AC_MSG_WARN([They cannot be faked when thread support is disabled.])
2922         AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
2923       else
2924         AC_MSG_WARN([They will be faked using a mutex.])
2925         AC_MSG_WARN([Performance of certain classes will degrade as a result.])
2926       fi
2927   fi
2928
2929 ])
2930
2931
2932 dnl
2933 dnl Check for exception handling support.  If an explicit enable/disable
2934 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
2935 dnl target may or may not support call frame exceptions.
2936 dnl
2937 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2938 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2939 dnl Neither one forces an attempt at detection.
2940 dnl
2941 dnl Defines:
2942 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2943 dnl
2944 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2945   AC_MSG_CHECKING([for exception model to use])
2946   AC_LANG_SAVE
2947   AC_LANG_CPLUSPLUS
2948   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
2949     [force use of builtin_setjmp for exceptions],
2950     [permit yes|no|auto])
2951
2952   if test $enable_sjlj_exceptions = auto; then
2953     # Botheration.  Now we've got to detect the exception model.  Link tests
2954     # against libgcc.a are problematic since we've not been given proper -L
2955     # bits for single-tree newlib and libgloss.
2956     #
2957     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
2958     cat > conftest.$ac_ext << EOF
2959 [#]line __oline__ "configure"
2960 struct S { ~S(); };
2961 void bar();
2962 void foo()
2963 {
2964   S s;
2965   bar();
2966 }
2967 EOF
2968     old_CXXFLAGS="$CXXFLAGS"
2969     CXXFLAGS=-S
2970     if AC_TRY_EVAL(ac_compile); then
2971       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
2972         enable_sjlj_exceptions=yes
2973       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
2974         enable_sjlj_exceptions=no
2975       elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
2976         enable_sjlj_exceptions=no
2977       fi
2978     fi
2979     CXXFLAGS="$old_CXXFLAGS"
2980     rm -f conftest*
2981   fi
2982
2983   # This is a tad weird, for hysterical raisins.  We have to map
2984   # enable/disable to two different models.
2985   case $enable_sjlj_exceptions in
2986     yes)
2987       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
2988         [Define if the compiler is configured for setjmp/longjmp exceptions.])
2989       ac_exception_model_name=sjlj
2990       ;;
2991     no)
2992       ac_exception_model_name="call frame"
2993       ;;
2994     *)
2995       AC_MSG_ERROR([unable to detect exception model])
2996       ;;
2997   esac
2998  AC_LANG_RESTORE
2999  AC_MSG_RESULT($ac_exception_model_name)
3000 ])
3001
3002
3003 dnl
3004 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3005 dnl
3006 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3007 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3008 dnl  +  Usage:  GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3009 dnl       Where DEFAULT is 'yes'.
3010 dnl
3011 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3012 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3013
3014 if test x$enable_libstdcxx_visibility = xyes ; then
3015   dnl all hail libgfortran
3016   dnl Check whether the target supports hidden visibility.
3017   AC_CACHE_CHECK([whether the target supports hidden visibility],
3018                  glibcxx_cv_have_attribute_visibility, [
3019   save_CFLAGS="$CFLAGS"
3020   CFLAGS="$CFLAGS -Werror"
3021   AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3022                  [], glibcxx_cv_have_attribute_visibility=yes,
3023                  glibcxx_cv_have_attribute_visibility=no)
3024   CFLAGS="$save_CFLAGS"])
3025   if test $glibcxx_cv_have_attribute_visibility = no; then
3026     enable_libstdcxx_visibility=no
3027   fi
3028 fi
3029
3030 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3031 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3032 ])
3033
3034
3035 dnl
3036 dnl Add version tags to symbols in shared library (or not), additionally
3037 dnl marking other symbols as private/local (or not).
3038 dnl
3039 dnl Sets libtool_VERSION, and determines shared library SONAME.
3040 dnl
3041 dnl  This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3042 dnl
3043 dnl --enable-symvers=style adds a version script to the linker call when
3044 dnl       creating the shared library.  The choice of version script is
3045 dnl       controlled by 'style'.
3046 dnl --disable-symvers does not.
3047 dnl
3048 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3049 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
3050 dnl       choose a default style based on linker characteristics.  Passing
3051 dnl       'no' disables versioning.
3052 dnl
3053 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3054
3055 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3056   [enables symbol versioning of the shared library],
3057   [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3058
3059 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3060 # don't know enough about $LD to do tricks...
3061 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3062 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3063 # with extern "C++" in version scripts.
3064 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3065
3066 # Turn a 'yes' into a suitable default.
3067 if test x$enable_symvers = xyes ; then
3068   if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3069     enable_symvers=no
3070   else
3071     if test $with_gnu_ld = yes ; then
3072       case ${target_os} in
3073         hpux*)
3074           enable_symvers=no ;;
3075         *)
3076           enable_symvers=gnu ;;
3077       esac
3078     else
3079       case ${target_os} in
3080         darwin*)
3081           enable_symvers=darwin ;;
3082         # Sun symbol versioning exists since Solaris 2.5.
3083         solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3084           # make_sunver.pl needs GNU c++filt to support extern "C++" in
3085           # version scripts, so disable symbol versioning if none can be
3086           # found.
3087           if test -z "$ac_cv_path_CXXFILT"; then
3088             AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3089             AC_MSG_WARN([=== no GNU c++filt could  be found.])
3090             AC_MSG_WARN([=== Symbol versioning will be disabled.])
3091             enable_symvers=no
3092           else
3093             enable_symvers=sun
3094           fi
3095           ;;
3096         *)
3097           enable_symvers=no ;;
3098       esac
3099     fi
3100   fi
3101 fi
3102
3103 # Check to see if 'darwin' or 'darwin-export' can win.
3104 if test x$enable_symvers = xdarwin-export ; then
3105     enable_symvers=darwin
3106 fi
3107
3108 # Check if 'sun' was requested on non-Solaris 2 platforms.
3109 if test x$enable_symvers = xsun ; then
3110   case ${target_os} in
3111     solaris2*)
3112       # All fine.
3113       ;;
3114     *)
3115       # Unlikely to work.
3116       AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3117       AC_MSG_WARN([=== you are not targetting Solaris 2.])
3118       AC_MSG_WARN([=== Symbol versioning will be disabled.])
3119       enable_symvers=no
3120       ;;
3121   esac
3122 fi
3123
3124 # Check to see if 'gnu' can win.
3125 if test $enable_symvers = gnu ||
3126   test $enable_symvers = gnu-versioned-namespace ||
3127   test $enable_symvers = sun; then
3128   # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3129   AC_MSG_CHECKING([for shared libgcc])
3130   ac_save_CFLAGS="$CFLAGS"
3131   CFLAGS=' -lgcc_s'
3132   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3133   CFLAGS="$ac_save_CFLAGS"
3134   if test $glibcxx_shared_libgcc = no; then
3135     cat > conftest.c <<EOF
3136 int main (void) { return 0; }
3137 EOF
3138 changequote(,)dnl
3139     glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3140                              -shared -shared-libgcc -o conftest.so \
3141                              conftest.c -v 2>&1 >/dev/null \
3142                              | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3143 changequote([,])dnl
3144     rm -f conftest.c conftest.so
3145     if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3146       CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3147       AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3148       CFLAGS="$ac_save_CFLAGS"
3149     fi
3150   fi
3151   AC_MSG_RESULT($glibcxx_shared_libgcc)
3152
3153   # For GNU ld, we need at least this version.  The format is described in
3154   # GLIBCXX_CHECK_LINKER_FEATURES above.
3155   glibcxx_min_gnu_ld_version=21400
3156
3157   # If no shared libgcc, can't win.
3158   if test $glibcxx_shared_libgcc != yes; then
3159       AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3160       AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3161       AC_MSG_WARN([=== Symbol versioning will be disabled.])
3162       enable_symvers=no
3163   elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3164     : All interesting versions of Sun ld support sun style symbol versioning.
3165   elif test $with_gnu_ld != yes ; then
3166     # just fail for now
3167     AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3168     AC_MSG_WARN([=== you are not using the GNU linker.])
3169     AC_MSG_WARN([=== Symbol versioning will be disabled.])
3170     enable_symvers=no
3171   elif test $glibcxx_ld_is_gold = yes ; then
3172     : All versions of gold support symbol versioning.
3173   elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3174     # The right tools, the right setup, but too old.  Fallbacks?
3175     AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3176     AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3177     AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3178     AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3179     AC_MSG_WARN([=== Symbol versioning will be disabled.])
3180     enable_symvers=no
3181   fi
3182 fi
3183
3184 # For libtool versioning info, format is CURRENT:REVISION:AGE
3185 libtool_VERSION=6:17:0
3186
3187 # Everything parsed; figure out what files and settings to use.
3188 case $enable_symvers in
3189   no)
3190     SYMVER_FILE=config/abi/pre/none.ver
3191     ;;
3192   gnu)
3193     SYMVER_FILE=config/abi/pre/gnu.ver
3194     AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3195               [Define to use GNU versioning in the shared library.])
3196     ;;
3197   gnu-versioned-namespace)
3198     libtool_VERSION=7:0:0
3199     SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3200     AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3201               [Define to use GNU namespace versioning in the shared library.])
3202     ;;
3203   darwin)
3204     SYMVER_FILE=config/abi/pre/gnu.ver
3205     AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3206               [Define to use darwin versioning in the shared library.])
3207     ;;
3208   sun)
3209     SYMVER_FILE=config/abi/pre/gnu.ver
3210     AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3211               [Define to use Sun versioning in the shared library.])
3212     ;;
3213 esac
3214
3215 if test x$enable_symvers != xno ; then
3216   AC_DEFINE(_GLIBCXX_SYMVER, 1,
3217          [Define to use symbol versioning in the shared library.])
3218 fi
3219
3220 AC_CACHE_CHECK([whether the target supports .symver directive],
3221                glibcxx_cv_have_as_symver_directive, [
3222   AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3223                  [], glibcxx_cv_have_as_symver_directive=yes,
3224                  glibcxx_cv_have_as_symver_directive=no)])
3225 if test $glibcxx_cv_have_as_symver_directive = yes; then
3226   AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3227     [Define to 1 if the target assembler supports .symver directive.])
3228 fi
3229
3230 AC_SUBST(SYMVER_FILE)
3231 AC_SUBST(port_specific_symbol_files)
3232 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3233 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3234 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3235 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3236 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3237 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3238
3239 if test $enable_symvers != no ; then
3240    case ${target_os} in
3241      # The Solaris 2 runtime linker doesn't support the GNU extension of
3242      # binding the same symbol to different versions
3243      solaris2*)
3244        symvers_renaming=no  ;;
3245      # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3246      *)
3247        AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3248          [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3249        symvers_renaming=yes  ;;
3250     esac
3251 else
3252     symvers_renaming=no
3253 fi
3254 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SOL2, test $symvers_renaming = no)
3255
3256 # Now, set up compatibility support, if any.
3257 # In addition, need this to deal with std::size_t mangling in
3258 # src/compatibility.cc.  In a perfect world, could use
3259 # typeid(std::size_t).name()[0] to do direct substitution.
3260 AC_MSG_CHECKING([for size_t as unsigned int])
3261 ac_save_CFLAGS="$CFLAGS"
3262 CFLAGS="-Werror"
3263 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3264                  [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3265 CFLAGS=$ac_save_CFLAGS
3266 if test "$glibcxx_size_t_is_i" = yes; then
3267   AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3268 fi
3269 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3270
3271 AC_MSG_CHECKING([for ptrdiff_t as int])
3272 ac_save_CFLAGS="$CFLAGS"
3273 CFLAGS="-Werror"
3274 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3275                  [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3276 CFLAGS=$ac_save_CFLAGS
3277 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3278   AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3279 fi
3280 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3281 ])
3282
3283
3284 dnl
3285 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3286 dnl We must stage the required headers so that they will be installed
3287 dnl with the library (unlike libgcc, the STL implementation is provided
3288 dnl solely within headers).  Since we must not inject random user-space
3289 dnl macro names into user-provided C++ code, we first stage into <file>-in
3290 dnl and process to <file> with an output command.  The reason for a two-
3291 dnl stage process here is to correctly handle $srcdir!=$objdir without
3292 dnl having to write complex code (the sed commands to clean the macro
3293 dnl namespace are complex and fragile enough as it is).  We must also
3294 dnl add a relative path so that -I- is supported properly.
3295 dnl
3296 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3297   AC_MSG_CHECKING([for thread model used by GCC])
3298   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3299   AC_MSG_RESULT([$target_thread_file])
3300 ])
3301
3302
3303 dnl
3304 dnl Check if gthread implementation defines the types and functions
3305 dnl required by the c++0x thread library.  Conforming gthread
3306 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3307 dnl
3308 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3309   AC_LANG_SAVE
3310   AC_LANG_CPLUSPLUS
3311
3312   ac_save_CXXFLAGS="$CXXFLAGS"
3313   CXXFLAGS="$CXXFLAGS -fno-exceptions \
3314         -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3315
3316   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3317   case $target_thread_file in
3318     posix)
3319       CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3320   esac
3321
3322   AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3323
3324   AC_TRY_COMPILE([#include <unistd.h>],
3325     [
3326       // In case of POSIX threads check _POSIX_TIMEOUTS.
3327       #if (defined(_PTHREADS) \
3328           && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3329       #error
3330       #endif
3331     ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3332
3333   AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3334                      [Define to 1 if mutex_timedlock is available.])
3335
3336   if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3337   else res_mutex_timedlock=no ; fi
3338   AC_MSG_RESULT([$res_mutex_timedlock])
3339
3340   AC_MSG_CHECKING([for gthreads library])
3341
3342   AC_TRY_COMPILE([#include "gthr.h"],
3343     [
3344       #ifndef __GTHREADS_CXX0X
3345       #error
3346       #endif
3347     ], [ac_has_gthreads=yes], [ac_has_gthreads=no])
3348
3349   AC_MSG_RESULT([$ac_has_gthreads])
3350
3351   if test x"$ac_has_gthreads" = x"yes"; then
3352     AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3353               [Define if gthreads library is available.])
3354   fi
3355
3356   CXXFLAGS="$ac_save_CXXFLAGS"
3357   AC_LANG_RESTORE
3358 ])
3359
3360
3361 # Check whether LC_MESSAGES is available in <locale.h>.
3362 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3363 #
3364 # This file file be copied and used freely without restrictions.  It can
3365 # be used in projects which are not available under the GNU Public License
3366 # but which still want to provide support for the GNU gettext functionality.
3367 # Please note that the actual code is *not* freely available.
3368 AC_DEFUN([AC_LC_MESSAGES], [
3369   AC_CHECK_HEADER(locale.h, [
3370     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3371       [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3372        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3373     if test $ac_cv_val_LC_MESSAGES = yes; then
3374       AC_DEFINE(HAVE_LC_MESSAGES, 1,
3375                 [Define if LC_MESSAGES is available in <locale.h>.])
3376     fi
3377   ])
3378 ])
3379
3380 dnl
3381 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3382 dnl
3383 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3384
3385   AC_LANG_SAVE
3386   AC_LANG_CPLUSPLUS
3387   ac_save_CXXFLAGS="$CXXFLAGS"
3388   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3389
3390   AC_MSG_CHECKING([for get_nprocs])
3391   AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3392     GCC_TRY_COMPILE_OR_LINK(
3393       [#include <sys/sysinfo.h>],
3394       [int n = get_nprocs();],
3395       [glibcxx_cv_GET_NPROCS=yes],
3396       [glibcxx_cv_GET_NPROCS=no])
3397   ])
3398   if test $glibcxx_cv_GET_NPROCS = yes; then
3399     AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3400   fi
3401   AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3402
3403   CXXFLAGS="$ac_save_CXXFLAGS"
3404   AC_LANG_RESTORE
3405 ])
3406
3407 dnl
3408 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3409 dnl
3410 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3411
3412   AC_LANG_SAVE
3413   AC_LANG_CPLUSPLUS
3414   ac_save_CXXFLAGS="$CXXFLAGS"
3415   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3416
3417   AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3418   AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3419     GCC_TRY_COMPILE_OR_LINK(
3420       [#include <unistd.h>],
3421       [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3422       [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3423       [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3424   ])
3425   if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3426     AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN  is available in <unistd.h>.])
3427   fi
3428   AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3429
3430   CXXFLAGS="$ac_save_CXXFLAGS"
3431   AC_LANG_RESTORE
3432 ])
3433
3434 dnl
3435 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3436 dnl
3437 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3438
3439   AC_LANG_SAVE
3440   AC_LANG_CPLUSPLUS
3441   ac_save_CXXFLAGS="$CXXFLAGS"
3442   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3443
3444   AC_MSG_CHECKING([for _SC_NPROC_ONLN])
3445   AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
3446     GCC_TRY_COMPILE_OR_LINK(
3447       [#include <unistd.h>],
3448       [int n = sysconf(_SC_NPROC_ONLN);],
3449       [glibcxx_cv_SC_NPROC_ONLN=yes],
3450       [glibcxx_cv_SC_NPROC_ONLN=no])
3451   ])
3452   if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
3453     AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN  is available in <unistd.h>.])
3454   fi
3455   AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
3456
3457   CXXFLAGS="$ac_save_CXXFLAGS"
3458   AC_LANG_RESTORE
3459 ])
3460
3461 dnl
3462 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
3463 dnl
3464 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
3465
3466   AC_LANG_SAVE
3467   AC_LANG_CPLUSPLUS
3468   ac_save_CXXFLAGS="$CXXFLAGS"
3469   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3470
3471   AC_MSG_CHECKING([for pthreads_num_processors_np])
3472   AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
3473     GCC_TRY_COMPILE_OR_LINK(
3474       [#include <pthread.h>],
3475       [int n = pthread_num_processors_np();],
3476       [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
3477       [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
3478   ])
3479   if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
3480     AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
3481   fi
3482   AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
3483
3484   CXXFLAGS="$ac_save_CXXFLAGS"
3485   AC_LANG_RESTORE
3486 ])
3487
3488 dnl
3489 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
3490 dnl
3491 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
3492
3493   AC_LANG_SAVE
3494   AC_LANG_CPLUSPLUS
3495   ac_save_CXXFLAGS="$CXXFLAGS"
3496   CXXFLAGS="$CXXFLAGS -fno-exceptions"
3497
3498   AC_MSG_CHECKING([for hw.ncpu sysctl])
3499   AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
3500     GCC_TRY_COMPILE_OR_LINK(
3501       [
3502        #include <stddef.h>
3503        #include <sys/sysctl.h>
3504        ],
3505       [
3506        int count;
3507        size_t size = sizeof(count);
3508        int mib[] = { CTL_HW, HW_NCPU };
3509        sysctl(mib, 2, &count, &size, NULL, 0);
3510       ],
3511       [glibcxx_cv_SYSCTL_HW_NCPU=yes],
3512       [glibcxx_cv_SYSCTL_HW_NCPU=no])
3513   ])
3514   if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
3515     AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
3516   fi
3517   AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
3518
3519   CXXFLAGS="$ac_save_CXXFLAGS"
3520   AC_LANG_RESTORE
3521 ])
3522
3523 # Macros from the top-level gcc directory.
3524 m4_include([../config/gc++filt.m4])
3525 m4_include([../config/tls.m4])