libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl Check to see what architecture and operating system we are compiling
   4 dnl for.  Also, if architecture- or OS-specific flags are required for
   5 dnl compilation, pick them up here.
   6 dnl
   7 AC_DEFUN(GLIBCXX_CHECK_HOST, [
   8   . $glibcxx_srcdir/configure.host
   9   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  10   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  11 ])
  12
  13
  14 dnl
  15 dnl Initialize basic configure bits.
  16 dnl
  17 dnl Substs:
  18 dnl  multi_basedir
  19 dnl
  20 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  21   # Sets up multi_basedir, which is srcdir/.. plus the usual
  22   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  23   AM_ENABLE_MULTILIB(, ..)
  24
  25   # The generated code is exactly the same, except that automake's looks in
  26   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  27   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  28   # know what they are or what the other differences might be (and they keep
  29   # changing anyhow).
  30   #
  31   # Looking in multi_basedir seems smarter, so actually execute that branch.
  32   if false; then
  33     # this is for automake
  34     AC_CONFIG_AUX_DIR(..)
  35   else
  36     # this is for autoconf
  37     AC_CONFIG_AUX_DIRS(${multi_basedir})
  38   fi
  39
  40   dnl XXX Turn this on.
  41   dnl AC_LANG_CPLUSPLUS
  42 ])
  43
  44
  45 dnl
  46 dnl Initialize the rest of the library configury.  At this point we have
  47 dnl variables like $host.
  48 dnl
  49 dnl Sets:
  50 dnl  gcc_version          (x.y.z format)
  51 dnl Substs:
  52 dnl  glibcxx_builddir     (absolute path)
  53 dnl  glibcxx_srcdir       (absolute path)
  54 dnl  toplevel_srcdir      (absolute path)
  55 dnl  with_cross_host
  56 dnl  with_newlib
  57 dnl  with_target_subdir
  58 dnl plus
  59 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  60 dnl  - default settings for all AM_CONFITIONAL test variables
  61 dnl  - lots of tools, like CC and CXX
  62 dnl
  63 AC_DEFUN(GLIBCXX_CONFIGURE, [
  64   # These need to be absolute paths, yet at the same time need to
  65   # canonicalize only relative paths, because then amd will not unmount
  66   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  67   glibcxx_builddir=`${PWDCMD-pwd}`
  68   case $srcdir in
  69     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  70     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  71   esac
  72   toplevel_srcdir=${glibcxx_srcdir}/..
  73   AC_SUBST(glibcxx_builddir)
  74   AC_SUBST(glibcxx_srcdir)
  75   AC_SUBST(toplevel_srcdir)
  76
  77   # We use these options to decide which functions to include.  They are
  78   # set from the top level.
  79   AC_ARG_WITH([target-subdir],
  80     AC_HELP_STRING([--with-target-subdir=SUBDIR],
  81                    [configuring in a subdirectory]))
  82
  83   AC_ARG_WITH([cross-host],
  84     AC_HELP_STRING([--with-cross-host=HOST],
  85                    [configuring with a cross compiler]))
  86
  87   AC_ARG_WITH([newlib],
  88     AC_HELP_STRING([--with-newlib],
  89                    [assume newlib as a system C library]))
  90
  91   # We're almost certainly being configured before anything else which uses
  92   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
  93   # we not cache the value of CXX that we "discover" here, because it's set
  94   # to something unique for us and libjava.  Other target libraries need to
  95   # find CXX for themselves.  We yank the rug out from under the normal AC_*
  96   # process by sneakily renaming the cache variable.  This also lets us debug
  97   # the value of "our" CXX in postmortems.
  98   #
  99   # We must also force CXX to /not/ be a precious variable, otherwise the
 100   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 101   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 102   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 103   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 104   #
 105   # -fno-builtin must be present here so that a non-conflicting form of
 106   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 107
 108   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 109   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 110   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 111   save_CXXFLAGS="$CXXFLAGS"
 112   CXXFLAGS="$CXXFLAGS -fno-builtin"
 113   AC_PROG_CC
 114   AC_PROG_CXX
 115   CXXFLAGS="$save_CXXFLAGS"
 116   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 117   AC_SUBST(CFLAGS)
 118   AC_SUBST(CXXFLAGS)
 119
 120   # For directory versioning (e.g., headers) and other variables.
 121   AC_MSG_CHECKING([for GCC version number])
 122   gcc_version=`$CXX -dumpversion`
 123   AC_MSG_RESULT($gcc_version)
 124
 125   # For some reason, gettext needs this.
 126   AC_ISC_POSIX
 127
 128   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 129   # available).  Uncomment the next line to force a particular method.
 130   AC_PROG_LN_S
 131   #LN_S='cp -p'
 132
 133   AC_CHECK_TOOL(AS, as)
 134   AC_CHECK_TOOL(AR, ar)
 135   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 136
 137   AM_MAINTAINER_MODE
 138
 139   # Set up safe default values for all subsequent AM_CONDITIONAL tests.
 140   need_libmath=no
 141   enable_wchar_t=no
 142   #enable_libstdcxx_debug=no
 143   #enable_libstdcxx_pch=no
 144   #enable_cheaders=c
 145   #c_compatibility=no
 146   #enable_abi_check=no
 147   #enable_symvers=no
 148
 149   # Find platform-specific directories containing configuration info.
 150   # Also possibly modify flags used elsewhere, as needed by the platform.
 151   GLIBCXX_CHECK_HOST
 152 ])
 153
 154
 155 m4_include([linkage.m4])
 156
 157
 158 dnl
 159 dnl Tests for newer compiler features, or features that are present in newer
 160 dnl compiler versions but not older compiler versions still in use, should
 161 dnl be placed here.
 162 dnl
 163 dnl Defines:
 164 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 165 dnl   new inlining code or the new system_header pragma will die on -Werror.
 166 dnl   Leave it out by default and use maint-mode to use it.
 167 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 168 dnl   compiler supports it and the user has not requested debug mode.
 169 dnl
 170 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 171   # All these tests are for C++; save the language and the compiler flags.
 172   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 173   # found in GLIBCXX_CONFIGURE.
 174   AC_LANG_SAVE
 175   AC_LANG_CPLUSPLUS
 176   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 177   ac_save_CXXFLAGS="$CXXFLAGS"
 178
 179   # Check for maintainer-mode bits.
 180   if test x"$USE_MAINTAINER_MODE" = xno; then
 181     WERROR=''
 182   else
 183     WERROR='-Werror'
 184   fi
 185
 186   # Check for -ffunction-sections -fdata-sections
 187   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 188   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 189   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 190   if test "$ac_test_CXXFLAGS" = set; then
 191     CXXFLAGS="$ac_save_CXXFLAGS"
 192   else
 193     # this is the suspicious part
 194     CXXFLAGS=''
 195   fi
 196   if test x"$ac_fdsections" = x"yes"; then
 197     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 198   fi
 199   AC_MSG_RESULT($ac_fdsections)
 200
 201   AC_LANG_RESTORE
 202   AC_SUBST(WERROR)
 203   AC_SUBST(SECTION_FLAGS)
 204 ])
 205
 206
 207 dnl
 208 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 209 dnl the native linker is in use, all variables will be defined to something
 210 dnl safe (like an empty string).
 211 dnl
 212 dnl Defines:
 213 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 214 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 215 dnl  LD (as a side effect of testing)
 216 dnl Sets:
 217 dnl  with_gnu_ld
 218 dnl  glibcxx_gnu_ld_version (possibly)
 219 dnl
 220 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 221 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 222 dnl
 223 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 224   # If we're not using GNU ld, then there's no point in even trying these
 225   # tests.  Check for that first.  We should have already tested for gld
 226   # by now (in libtool), but require it now just to be safe...
 227   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 228   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 229   AC_REQUIRE([AC_PROG_LD])
 230   AC_REQUIRE([AC_PROG_AWK])
 231
 232   # The name set by libtool depends on the version of libtool.  Shame on us
 233   # for depending on an impl detail, but c'est la vie.  Older versions used
 234   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 235   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 236   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 237   # set (hence we're using an older libtool), then set it.
 238   if test x${with_gnu_ld+set} != xset; then
 239     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 240       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 241       with_gnu_ld=no
 242     else
 243       with_gnu_ld=$ac_cv_prog_gnu_ld
 244     fi
 245   fi
 246
 247   # Start by getting the version number.  I think the libtool test already
 248   # does some of this, but throws away the result.
 249   changequote(,)
 250   ldver=`$LD --version 2>/dev/null | head -1 | \
 251          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 252   changequote([,])
 253   glibcxx_gnu_ld_version=`echo $ldver | \
 254          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 255
 256   # Set --gc-sections.
 257   if test "$with_gnu_ld" = "notbroken"; then
 258     # GNU ld it is!  Joy and bunny rabbits!
 259
 260     # All these tests are for C++; save the language and the compiler flags.
 261     # Need to do this so that g++ won't try to link in libstdc++
 262     ac_test_CFLAGS="${CFLAGS+set}"
 263     ac_save_CFLAGS="$CFLAGS"
 264     CFLAGS='-x c++  -Wl,--gc-sections'
 265
 266     # Check for -Wl,--gc-sections
 267     # XXX This test is broken at the moment, as symbols required for linking
 268     # are now in libsupc++ (not built yet).  In addition, this test has
 269     # cored on solaris in the past.  In addition, --gc-sections doesn't
 270     # really work at the moment (keeps on discarding used sections, first
 271     # .eh_frame and now some of the glibc sections for iconv).
 272     # Bzzzzt.  Thanks for playing, maybe next time.
 273     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 274     AC_TRY_RUN([
 275      int main(void)
 276      {
 277        try { throw 1; }
 278        catch (...) { };
 279        return 0;
 280      }
 281     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 282     if test "$ac_test_CFLAGS" = set; then
 283       CFLAGS="$ac_save_CFLAGS"
 284     else
 285       # this is the suspicious part
 286       CFLAGS=''
 287     fi
 288     if test "$ac_sectionLDflags" = "yes"; then
 289       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 290     fi
 291     AC_MSG_RESULT($ac_sectionLDflags)
 292   fi
 293
 294   # Set linker optimization flags.
 295   if test x"$with_gnu_ld" = x"yes"; then
 296     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 297   fi
 298
 299   AC_SUBST(SECTION_LDFLAGS)
 300   AC_SUBST(OPT_LDFLAGS)
 301 ])
 302
 303
 304 dnl
 305 dnl Check to see if this target can enable the wchar_t parts.
 306 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 307 dnl must have been previously checked.)  By default, wide characters are
 308 dnl disabled.
 309 dnl
 310 dnl Defines:
 311 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 312 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 313 dnl
 314 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 315   # Test wchar.h for mbstate_t, which is needed for char_traits and
 316   # others even if wchar_t support is not on.
 317   AC_MSG_CHECKING([for mbstate_t])
 318   AC_TRY_COMPILE([#include <wchar.h>],
 319   [mbstate_t teststate;],
 320   have_mbstate_t=yes, have_mbstate_t=no)
 321   AC_MSG_RESULT($have_mbstate_t)
 322   if test x"$have_mbstate_t" = xyes; then
 323     AC_DEFINE(HAVE_MBSTATE_T)
 324   fi
 325
 326   # Sanity check for existence of ISO C99 headers for extended encoding.
 327   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 328   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 329
 330   # Only continue checking if the ISO C99 headers exist and support is on.
 331   if test x"$ac_has_wchar_h" = xyes &&
 332      test x"$ac_has_wctype_h" = xyes &&
 333      test x"$enable_c_mbchar" != xno; then
 334
 335     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 336     # numeric_limits can instantiate type_traits<wchar_t>
 337     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 338     AC_TRY_COMPILE([#include <wchar.h>],
 339     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 340     has_wchar_minmax=yes, has_wchar_minmax=no)
 341     AC_MSG_RESULT($has_wchar_minmax)
 342
 343     # Test wchar.h for WEOF, which is what we use to determine whether
 344     # to specialize for char_traits<wchar_t> or not.
 345     AC_MSG_CHECKING([for WEOF])
 346     AC_TRY_COMPILE([
 347       #include <wchar.h>
 348       #include <stddef.h>],
 349     [wint_t i = WEOF;],
 350     has_weof=yes, has_weof=no)
 351     AC_MSG_RESULT($has_weof)
 352
 353     # Tests for wide character functions used in char_traits<wchar_t>.
 354     ac_wfuncs=yes
 355     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 356     [],[ac_wfuncs=no])
 357
 358     # Checks for names injected into std:: by the c_std headers.
 359     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 360     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 361     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 362     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 363     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 364     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 365     [],[ac_wfuncs=no])
 366
 367     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 368     if test x"$has_weof" = xyes &&
 369        test x"$has_wchar_minmax" = xyes &&
 370        test x"$ac_wfuncs" = xyes;
 371     then
 372       ac_isoC99_wchar_t=yes
 373     else
 374       ac_isoC99_wchar_t=no
 375     fi
 376     AC_MSG_RESULT($ac_isoC99_wchar_t)
 377
 378     # Use iconv for wchar_t to char conversions. As such, check for
 379     # X/Open Portability Guide, version 2 features (XPG2).
 380     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 381     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 382
 383     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 384     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 385     ac_save_LIBS="$LIBS"
 386     LIBS="$LIBS $libiconv"
 387
 388     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 389     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 390
 391     LIBS="$ac_save_LIBS"
 392
 393     AC_MSG_CHECKING([for XPG2 wchar_t support])
 394     if test x"$ac_has_iconv_h" = xyes &&
 395        test x"$ac_has_langinfo_h" = xyes &&
 396        test x"$ac_XPG2funcs" = xyes;
 397     then
 398       ac_XPG2_wchar_t=yes
 399     else
 400       ac_XPG2_wchar_t=no
 401     fi
 402     AC_MSG_RESULT($ac_XPG2_wchar_t)
 403
 404     # At the moment, only enable wchar_t specializations if all the
 405     # above support is present.
 406     if test x"$ac_isoC99_wchar_t" = xyes &&
 407        test x"$ac_XPG2_wchar_t" = xyes;
 408     then
 409       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 410       enable_wchar_t=yes
 411     fi
 412   fi
 413   AC_MSG_CHECKING([for enabled wchar_t specializations])
 414   AC_MSG_RESULT($enable_wchar_t)
 415 ])
 416
 417
 418 dnl
 419 dnl Check for headers for, and arguments to, the setrlimit() function.
 420 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 421 dnl
 422 dnl Defines:
 423 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 424 dnl  various HAVE_MEMLIMIT_* for individual limit names
 425 dnl
 426 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 427   AC_TRY_COMPILE(
 428     [#include <unistd.h>
 429      #include <sys/time.h>
 430      #include <sys/resource.h>
 431     ],
 432     [ int f = RLIMIT_$1 ; ],
 433     [glibcxx_mresult=1], [glibcxx_mresult=0])
 434   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 435                      [Only used in build directory testsuite_hooks.h.])
 436 ])
 437
 438 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 439   setrlimit_have_headers=yes
 440   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 441                    [],
 442                    [setrlimit_have_headers=no])
 443   # If don't have the headers, then we can't run the tests now, and we
 444   # won't be seeing any of these during testsuite compilation.
 445   if test $setrlimit_have_headers = yes; then
 446     # Can't do these in a loop, else the resulting syntax is wrong.
 447     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 448     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 449     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 450     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 451
 452     # Check for rlimit, setrlimit.
 453     AC_CACHE_VAL(ac_setrlimit, [
 454       AC_TRY_COMPILE(
 455         [#include <unistd.h>
 456          #include <sys/time.h>
 457          #include <sys/resource.h>
 458         ],
 459         [struct rlimit r;
 460          setrlimit(0, &r);],
 461         [ac_setrlimit=yes], [ac_setrlimit=no])
 462     ])
 463   fi
 464
 465   AC_MSG_CHECKING([for testsuite memory limit support])
 466   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 467     ac_mem_limits=yes
 468     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 469   else
 470     ac_mem_limits=no
 471   fi
 472   AC_MSG_RESULT($ac_mem_limits)
 473 ])
 474
 475
 476 dnl
 477 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 478 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 479 dnl
 480 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 481   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 482     AC_TRY_LINK(
 483       [#include <sys/stat.h>],
 484       [struct stat buffer;
 485        fstat(0, &buffer);
 486        S_ISREG(buffer.st_mode);],
 487       [glibcxx_cv_S_ISREG=yes],
 488       [glibcxx_cv_S_ISREG=no])
 489   ])
 490   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 491     AC_TRY_LINK(
 492       [#include <sys/stat.h>],
 493       [struct stat buffer;
 494        fstat(0, &buffer);
 495        S_IFREG & buffer.st_mode;],
 496       [glibcxx_cv_S_IFREG=yes],
 497       [glibcxx_cv_S_IFREG=no])
 498   ])
 499   if test $glibcxx_cv_S_ISREG = yes; then
 500     AC_DEFINE(HAVE_S_ISREG)
 501   elif test $glibcxx_cv_S_IFREG = yes; then
 502     AC_DEFINE(HAVE_S_IFREG)
 503   fi
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 509 dnl
 510 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 511   AC_CACHE_VAL(glibcxx_cv_POLL, [
 512     AC_TRY_COMPILE(
 513       [#include <poll.h>],
 514       [struct pollfd pfd[1];
 515        pfd[0].events = POLLIN;
 516        poll(pfd, 1, 0);],
 517       [glibcxx_cv_POLL=yes],
 518       [glibcxx_cv_POLL=no])
 519   ])
 520   if test $glibcxx_cv_POLL = yes; then
 521     AC_DEFINE(HAVE_POLL)
 522   fi
 523 ])
 524
 525
 526 dnl
 527 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 528 dnl
 529 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 530   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 531     AC_TRY_COMPILE(
 532       [#include <sys/uio.h>],
 533       [struct iovec iov[2];
 534        writev(0, iov, 0);],
 535       [glibcxx_cv_WRITEV=yes],
 536       [glibcxx_cv_WRITEV=no])
 537   ])
 538   if test $glibcxx_cv_WRITEV = yes; then
 539     AC_DEFINE(HAVE_WRITEV)
 540   fi
 541 ])
 542
 543
 544 dnl
 545 dnl Does any necessary configuration of the testsuite directory.  Generates
 546 dnl the testsuite_hooks.h header.
 547 dnl
 548 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 549 dnl
 550 dnl Sets:
 551 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 552 dnl Substs:
 553 dnl  baseline_dir
 554 dnl
 555 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 556   if $GLIBCXX_IS_NATIVE; then
 557     # Do checks for memory limit functions.
 558     GLIBCXX_CHECK_SETRLIMIT
 559
 560     # Look for setenv, so that extended locale tests can be performed.
 561     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 562   fi
 563
 564   # Export file names for ABI checking.
 565   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 566   AC_SUBST(baseline_dir)
 567
 568   # Determine if checking the ABI is desirable.
 569   if test $enable_symvers = no; then
 570     enable_abi_check=no
 571   else
 572     case "$host" in
 573       *-*-cygwin*)
 574         enable_abi_check=no ;;
 575       *)
 576         enable_abi_check=yes ;;
 577     esac
 578   fi
 579
 580   AM_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 581   AM_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 582 ])
 583
 584
 585 dnl
 586 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 587 dnl
 588 dnl Substs:
 589 dnl  GLIBCXX_INCLUDES
 590 dnl  TOPLEVEL_INCLUDES
 591 dnl
 592 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 593   # Used for every C++ compile we perform.
 594   GLIBCXX_INCLUDES="\
 595 -I$glibcxx_builddir/include/$host_alias \
 596 -I$glibcxx_builddir/include \
 597 -I$glibcxx_srcdir/libsupc++"
 598
 599   # For Canadian crosses, pick this up too.
 600   if test $CANADIAN = yes; then
 601     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES '-I${includedir}'"
 602   fi
 603
 604   # Stuff in the actual top level.  Currently only used by libsupc++ to
 605   # get unwind* headers from the gcc dir.
 606   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 607   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 608
 609   # Now, export this to all the little Makefiles....
 610   AC_SUBST(GLIBCXX_INCLUDES)
 611   AC_SUBST(TOPLEVEL_INCLUDES)
 612 ])
 613
 614
 615 dnl
 616 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 617 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 618 dnl
 619 dnl Substs:
 620 dnl  OPTIMIZE_CXXFLAGS
 621 dnl  WARN_FLAGS
 622 dnl
 623 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 624   # Optimization flags that are probably a good idea for thrill-seekers. Just
 625   # uncomment the lines below and make, everything else is ready to go...
 626   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 627   OPTIMIZE_CXXFLAGS=
 628   AC_SUBST(OPTIMIZE_CXXFLAGS)
 629
 630   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings'
 631   AC_SUBST(WARN_FLAGS)
 632 ])
 633
 634
 635 dnl
 636 dnl All installation directory information is determined here.
 637 dnl
 638 dnl Substs:
 639 dnl  gxx_install_dir
 640 dnl  glibcxx_prefixdir
 641 dnl  glibcxx_toolexecdir
 642 dnl  glibcxx_toolexeclibdir
 643 dnl
 644 dnl Assumes cross_compiling bits already done, and with_cross_host in
 645 dnl particular.
 646 dnl
 647 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 648   glibcxx_toolexecdir=no
 649   glibcxx_toolexeclibdir=no
 650   glibcxx_prefixdir=$prefix
 651
 652   AC_MSG_CHECKING([for gxx-include-dir])
 653   AC_ARG_WITH([gxx-include-dir],
 654     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 655                    [installation directory for include files]),
 656     [case "$withval" in
 657       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 658       no)  gxx_include_dir=no ;;
 659       *)   gxx_include_dir=$withval ;;
 660      esac],
 661     [gxx_include_dir=no])
 662   AC_MSG_RESULT($gxx_include_dir)
 663
 664   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 665   AC_ARG_ENABLE([version-specific-runtime-libs],
 666     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 667                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 668     [case "$enableval" in
 669       yes) version_specific_libs=yes ;;
 670       no)  version_specific_libs=no ;;
 671       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 672      esac],
 673     [version_specific_libs=no])
 674   AC_MSG_RESULT($version_specific_libs)
 675
 676   # Default case for install directory for include files.
 677   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 678     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 679   fi
 680
 681   # Version-specific runtime libs processing.
 682   if test $version_specific_libs = yes; then
 683     # Need the gcc compiler version to know where to install libraries
 684     # and header files if --enable-version-specific-runtime-libs option
 685     # is selected.
 686     if test x"$gxx_include_dir" = x"no"; then
 687       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 688     fi
 689     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 690     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 691   fi
 692
 693   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 694   # Install a library built with a cross compiler in tooldir, not libdir.
 695   if test x"$glibcxx_toolexecdir" = x"no"; then
 696     if test -n "$with_cross_host" &&
 697        test x"$with_cross_host" != x"no"; then
 698       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 699       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 700     else
 701       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 702       glibcxx_toolexeclibdir='${libdir}'
 703     fi
 704     multi_os_directory=`$CXX -print-multi-os-directory`
 705     case $multi_os_directory in
 706       .) ;; # Avoid trailing /.
 707       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 708     esac
 709   fi
 710
 711   AC_MSG_CHECKING([for install location])
 712   AC_MSG_RESULT($gxx_include_dir)
 713
 714   AC_SUBST(glibcxx_prefixdir)
 715   AC_SUBST(gxx_include_dir)
 716   AC_SUBST(glibcxx_toolexecdir)
 717   AC_SUBST(glibcxx_toolexeclibdir)
 718 ])
 719
 720
 721 dnl
 722 dnl GLIBCXX_ENABLE
 723 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 724 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 725 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 726 dnl
 727 dnl See docs/html/17_intro/configury.html#enable for documentation.
 728 dnl
 729 m4_define([GLIBCXX_ENABLE],[dnl
 730 m4_define([_g_switch],[--enable-$1])dnl
 731 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 732  AC_ARG_ENABLE($1,_g_help,
 733   m4_bmatch([$5],
 734    [^permit ],
 735      [[
 736       case "$enableval" in
 737        m4_bpatsubst([$5],[permit ])) ;;
 738        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 739           dnl Idea for future:  generate a URL pointing to
 740           dnl "onlinedocs/configopts.html#whatever"
 741       esac
 742      ]],
 743    [^$],
 744      [[
 745       case "$enableval" in
 746        yes|no) ;;
 747        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 748       esac
 749      ]],
 750    [[$5]]),
 751   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 752 m4_undefine([_g_switch])dnl
 753 m4_undefine([_g_help])dnl
 754 ])
 755
 756
 757 dnl
 758 dnl Check for ISO/IEC 9899:1999 "C99" support.
 759 dnl
 760 dnl --enable-c99 defines _GLIBCXX_USE_C99
 761 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 762 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 763 dnl       Where DEFAULT is either `yes' or `no'.
 764 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 765 dnl
 766 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 767   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 768
 769   AC_LANG_SAVE
 770   AC_LANG_CPLUSPLUS
 771
 772   # Check for the existence of <math.h> functions used if C99 is enabled.
 773   ac_c99_math=yes;
 774   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 775   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 776   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 777   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 778   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 779   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 780   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 781   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 782   AC_TRY_COMPILE([#include <math.h>],
 783                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 784   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 785   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 786   AC_TRY_COMPILE([#include <math.h>],
 787                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 788   AC_TRY_COMPILE([#include <math.h>],
 789                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 790   AC_MSG_RESULT($ac_c99_math)
 791
 792   # Check for the existence in <stdio.h> of vscanf, et. al.
 793   ac_c99_stdio=yes;
 794   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 795   AC_TRY_COMPILE([#include <stdio.h>],
 796                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 797   AC_TRY_COMPILE([#include <stdio.h>
 798                   #include <stdarg.h>
 799                   void foo(char* fmt, ...)
 800                   {va_list args; va_start(args, fmt);
 801                   vfscanf(stderr, "%i", args);}],
 802                   [],, [ac_c99_stdio=no])
 803   AC_TRY_COMPILE([#include <stdio.h>
 804                   #include <stdarg.h>
 805                   void foo(char* fmt, ...)
 806                   {va_list args; va_start(args, fmt);
 807                   vscanf("%i", args);}],
 808                   [],, [ac_c99_stdio=no])
 809   AC_TRY_COMPILE([#include <stdio.h>
 810                   #include <stdarg.h>
 811                   void foo(char* fmt, ...)
 812                   {va_list args; va_start(args, fmt);
 813                   vsnprintf(fmt, 0, "%i", args);}],
 814                   [],, [ac_c99_stdio=no])
 815   AC_TRY_COMPILE([#include <stdio.h>
 816                   #include <stdarg.h>
 817                   void foo(char* fmt, ...)
 818                   {va_list args; va_start(args, fmt);
 819                   vsscanf(fmt, "%i", args);}],
 820                   [],, [ac_c99_stdio=no])
 821   AC_MSG_RESULT($ac_c99_stdio)
 822
 823   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 824   ac_c99_stdlib=yes;
 825   AC_MSG_CHECKING([for lldiv_t declaration])
 826   AC_CACHE_VAL(ac_c99_lldiv_t, [
 827   AC_TRY_COMPILE([#include <stdlib.h>],
 828                    [ lldiv_t mydivt;],
 829                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 830   ])
 831   AC_MSG_RESULT($ac_c99_lldiv_t)
 832
 833   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 834   AC_TRY_COMPILE([#include <stdlib.h>],
 835                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 836   AC_TRY_COMPILE([#include <stdlib.h>],
 837                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 838   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 839   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 840   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 841   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 842   if test x"$ac_c99_lldiv_t" = x"no"; then
 843     ac_c99_stdlib=no;
 844   fi;
 845   AC_MSG_RESULT($ac_c99_stdlib)
 846
 847   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 848   # XXX the wchar.h checks should be rolled into the general C99 bits.
 849   ac_c99_wchar=yes;
 850   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 851   AC_TRY_COMPILE([#include <wchar.h>],
 852                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 853   AC_TRY_COMPILE([#include <wchar.h>],
 854                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 855   AC_TRY_COMPILE([#include <wchar.h>],
 856                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 857   AC_MSG_RESULT($ac_c99_wchar)
 858
 859   AC_MSG_CHECKING([for enabled ISO C99 support])
 860   if test x"$ac_c99_math" = x"no" ||
 861      test x"$ac_c99_stdio" = x"no" ||
 862      test x"$ac_c99_stdlib" = x"no" ||
 863      test x"$ac_c99_wchar" = x"no"; then
 864     enable_c99=no;
 865   fi;
 866   AC_MSG_RESULT($enable_c99)
 867
 868   # Option parsed, now set things appropriately
 869   if test x"$enable_c99" = x"yes"; then
 870     AC_DEFINE(_GLIBCXX_USE_C99)
 871   fi
 872
 873   AC_LANG_RESTORE
 874 ])
 875
 876
 877 dnl
 878 dnl Check for what type of C headers to use.
 879 dnl
 880 dnl --enable-cheaders= [does stuff].
 881 dnl --disable-cheaders [does not do anything, really].
 882 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 883 dnl       Where DEFAULT is either `c' or `c_std'.
 884 dnl
 885 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 886   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 887     [construct "C" headers for g++], [permit c|c_std])
 888   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 889
 890   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 891
 892   AC_SUBST(C_INCLUDE_DIR)
 893   AM_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 894   AM_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 895   AM_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 896 ])
 897
 898
 899 dnl
 900 dnl Check for which locale library to use.  The choice is mapped to
 901 dnl a subdirectory of config/locale.
 902 dnl
 903 dnl Default is generic.
 904 dnl
 905 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 906   AC_MSG_CHECKING([for C locale to use])
 907   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 908     [use MODEL for target locale package],
 909     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 910
 911   # If they didn't use this option switch, or if they specified --enable
 912   # with no specific model, we'll have to look for one.  If they
 913   # specified --disable (???), do likewise.
 914   if test $enable_clocale = no || test $enable_clocale = yes; then
 915      enable_clocale=auto
 916   fi
 917
 918   # Either a known package, or "auto"
 919   enable_clocale_flag=$enable_clocale
 920
 921   # Probe for locale support if no specific model is specified.
 922   # Default to "generic".
 923   if test $enable_clocale_flag = auto; then
 924     case x${target_os} in
 925       xlinux* | xgnu*)
 926         AC_EGREP_CPP([_GLIBCXX_ok], [
 927         #include <features.h>
 928         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 929           _GLIBCXX_ok
 930         #endif
 931         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
 932
 933         # Test for bugs early in glibc-2.2.x series
 934           if test x$enable_clocale_flag = xgnu; then
 935           AC_TRY_RUN([
 936           #define _GNU_SOURCE 1
 937           #include <locale.h>
 938           #include <string.h>
 939           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
 940           extern __typeof(newlocale) __newlocale;
 941           extern __typeof(duplocale) __duplocale;
 942           extern __typeof(strcoll_l) __strcoll_l;
 943           #endif
 944           int main()
 945           {
 946               const char __one[] = "Äuglein Augmen";
 947               const char __two[] = "Äuglein";
 948               int i;
 949               int j;
 950               __locale_t        loc;
 951                __locale_t        loc_dup;
 952               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
 953               loc_dup = __duplocale(loc);
 954               i = __strcoll_l(__one, __two, loc);
 955               j = __strcoll_l(__one, __two, loc_dup);
 956               return 0;
 957           }
 958           ],
 959           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
 960           [enable_clocale_flag=generic])
 961           fi
 962
 963         # ... at some point put __strxfrm_l tests in as well.
 964         ;;
 965       *)
 966         enable_clocale_flag=generic
 967         ;;
 968     esac
 969   fi
 970
 971   # Deal with gettext issues.  Default to not using it (=no) until we detect
 972   # support for it later.  Let the user turn it off via --e/d, but let that
 973   # default to on for easier handling.
 974   USE_NLS=no
 975   AC_ARG_ENABLE(nls,
 976     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
 977     [],
 978     [enable_nls=yes])
 979
 980   # Set configure bits for specified locale package
 981   case ${enable_clocale_flag} in
 982     generic)
 983       AC_MSG_RESULT(generic)
 984
 985       CLOCALE_H=config/locale/generic/c_locale.h
 986       CLOCALE_CC=config/locale/generic/c_locale.cc
 987       CCODECVT_H=config/locale/generic/codecvt_specializations.h
 988       CCODECVT_CC=config/locale/generic/codecvt_members.cc
 989       CCOLLATE_CC=config/locale/generic/collate_members.cc
 990       CCTYPE_CC=config/locale/generic/ctype_members.cc
 991       CMESSAGES_H=config/locale/generic/messages_members.h
 992       CMESSAGES_CC=config/locale/generic/messages_members.cc
 993       CMONEY_CC=config/locale/generic/monetary_members.cc
 994       CNUMERIC_CC=config/locale/generic/numeric_members.cc
 995       CTIME_H=config/locale/generic/time_members.h
 996       CTIME_CC=config/locale/generic/time_members.cc
 997       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
 998       ;;
 999     gnu)
1000       AC_MSG_RESULT(gnu)
1001
1002       # Declare intention to use gettext, and add support for specific
1003       # languages.
1004       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1005       ALL_LINGUAS="de fr"
1006
1007       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1008       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1009       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1010         USE_NLS=yes
1011       fi
1012       # Export the build objects.
1013       for ling in $ALL_LINGUAS; do \
1014         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1015         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1016       done
1017       AC_SUBST(glibcxx_MOFILES)
1018       AC_SUBST(glibcxx_POFILES)
1019
1020       CLOCALE_H=config/locale/gnu/c_locale.h
1021       CLOCALE_CC=config/locale/gnu/c_locale.cc
1022       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1023       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1024       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1025       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1026       CMESSAGES_H=config/locale/gnu/messages_members.h
1027       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1028       CMONEY_CC=config/locale/gnu/monetary_members.cc
1029       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1030       CTIME_H=config/locale/gnu/time_members.h
1031       CTIME_CC=config/locale/gnu/time_members.cc
1032       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1033       ;;
1034     ieee_1003.1-2001)
1035       AC_MSG_RESULT(IEEE 1003.1)
1036
1037       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1038       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1039       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1040       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1041       CCOLLATE_CC=config/locale/generic/collate_members.cc
1042       CCTYPE_CC=config/locale/generic/ctype_members.cc
1043       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1044       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1045       CMONEY_CC=config/locale/generic/monetary_members.cc
1046       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1047       CTIME_H=config/locale/generic/time_members.h
1048       CTIME_CC=config/locale/generic/time_members.cc
1049       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1050       ;;
1051   esac
1052
1053   # This is where the testsuite looks for locale catalogs, using the
1054   # -DLOCALEDIR define during testsuite compilation.
1055   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1056   AC_SUBST(glibcxx_localedir)
1057
1058   # A standalone libintl (e.g., GNU libintl) may be in use.
1059   if test $USE_NLS = yes; then
1060     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1061     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1062   fi
1063   if test $USE_NLS = yes; then
1064     AC_DEFINE(_GLIBCXX_USE_NLS)
1065   fi
1066
1067   AC_SUBST(USE_NLS)
1068   AC_SUBST(CLOCALE_H)
1069   AC_SUBST(CCODECVT_H)
1070   AC_SUBST(CMESSAGES_H)
1071   AC_SUBST(CCODECVT_CC)
1072   AC_SUBST(CCOLLATE_CC)
1073   AC_SUBST(CCTYPE_CC)
1074   AC_SUBST(CMESSAGES_CC)
1075   AC_SUBST(CMONEY_CC)
1076   AC_SUBST(CNUMERIC_CC)
1077   AC_SUBST(CTIME_H)
1078   AC_SUBST(CTIME_CC)
1079   AC_SUBST(CLOCALE_CC)
1080   AC_SUBST(CLOCALE_INTERNAL_H)
1081 ])
1082
1083
1084 dnl
1085 dnl Check for whether the Boost-derived checks should be turned on.
1086 dnl
1087 dnl --enable-concept-checks turns them on.
1088 dnl --disable-concept-checks leaves them off.
1089 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1090 dnl       Where DEFAULT is either `yes' or `no'.
1091 dnl
1092 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1093   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1094   if test $enable_concept_checks = yes; then
1095     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1096   fi
1097 ])
1098
1099
1100 dnl
1101 dnl Check for which I/O library to use:  stdio, or something specific.
1102 dnl
1103 dnl Default is stdio.
1104 dnl
1105 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1106   AC_MSG_CHECKING([for underlying I/O to use])
1107   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1108     [use target-specific I/O package], [permit stdio])
1109
1110   # Now that libio has been removed, you can have any color you want as long
1111   # as it's black.  This is one big no-op until other packages are added, but
1112   # showing the framework never hurts.
1113   case ${enable_cstdio} in
1114     stdio)
1115       CSTDIO_H=config/io/c_io_stdio.h
1116       BASIC_FILE_H=config/io/basic_file_stdio.h
1117       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1118       AC_MSG_RESULT(stdio)
1119       ;;
1120   esac
1121
1122   dnl Set directory for fpos.h
1123   FPOS_H=$fpos_include_dir
1124
1125   AC_SUBST(CSTDIO_H)
1126   AC_SUBST(FPOS_H)
1127   AC_SUBST(BASIC_FILE_H)
1128   AC_SUBST(BASIC_FILE_CC)
1129 ])
1130
1131
1132 dnl
1133 dnl Check for "unusual" flags to pass to the compiler while building.
1134 dnl
1135 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1136 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1137 dnl --disable-cxx-flags passes nothing.
1138 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1139 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1140 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1141 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1142 dnl       If "default flags" is an empty string, the effect is the same
1143 dnl       as --disable or --enable=no.
1144 dnl
1145 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1146   AC_MSG_CHECKING([for extra compiler flags for building])
1147   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1148     [pass compiler FLAGS when building library],
1149     [case "x$enable_cxx_flags" in
1150       xno | x)   enable_cxx_flags= ;;
1151       x-*)       ;;
1152       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1153      esac])
1154
1155   # Run through flags (either default or command-line) and set anything
1156   # extra (e.g., #defines) that must accompany particular g++ options.
1157   if test -n "$enable_cxx_flags"; then
1158     for f in $enable_cxx_flags; do
1159       case "$f" in
1160         -fhonor-std)  ;;
1161         -*)  ;;
1162         *)   # and we're trying to pass /what/ exactly?
1163              AC_MSG_ERROR([compiler flags start with a -]) ;;
1164       esac
1165     done
1166   fi
1167
1168   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1169   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1170   AC_SUBST(EXTRA_CXX_FLAGS)
1171 ])
1172
1173
1174 dnl
1175 dnl Check for wide character support.  Has the same effect as the option
1176 dnl in gcc's configure, but in a form that autoconf can mess with.
1177 dnl
1178 dnl --enable-c-mbchar requests all the wchar_t stuff.
1179 dnl --disable-c-mbchar doesn't.
1180 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1181 dnl       Where DEFAULT is either `yes' or `no'.
1182 dnl
1183 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1184   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1185   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1186 ])
1187
1188
1189 dnl
1190 dnl Check to see if debugging libraries are to be built.
1191 dnl
1192 dnl --enable-libstdcxx-debug
1193 dnl builds a separate set of debugging libraries in addition to the
1194 dnl normal (shared, static) libstdc++ binaries.
1195 dnl
1196 dnl --disable-libstdcxx-debug
1197 dnl builds only one (non-debug) version of libstdc++.
1198 dnl
1199 dnl --enable-libstdcxx-debug-flags=FLAGS
1200 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1201 dnl
1202 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1203 dnl       Where DEFAULT is either `yes' or `no'.
1204 dnl
1205 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1206   AC_MSG_CHECKING([for additional debug build])
1207   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1208   AC_MSG_RESULT($enable_libstdcxx_debug)
1209   AM_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1210 ])
1211
1212
1213 dnl
1214 dnl Check for explicit debug flags.
1215 dnl
1216 dnl --enable-libstdcxx-debug-flags='-O1'
1217 dnl is a general method for passing flags to be used when
1218 dnl building debug libraries with --enable-debug.
1219 dnl
1220 dnl --disable-libstdcxx-debug-flags does nothing.
1221 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1222 dnl       If "default flags" is an empty string, the effect is the same
1223 dnl       as --disable or --enable=no.
1224 dnl
1225 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1226   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1227     [pass compiler FLAGS when building debug library],
1228     [case "x$enable_libstdcxx_debug_flags" in
1229       xno | x)    enable_libstdcxx_debug_flags= ;;
1230       x-*)        ;;
1231       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1232      esac])
1233
1234   # Option parsed, now set things appropriately
1235   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1236   AC_SUBST(DEBUG_FLAGS)
1237
1238   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1239 ])
1240
1241
1242 dnl
1243 dnl Check for libunwind exception handling support.  If enabled, then
1244 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1245 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1246 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1247 dnl on libunwind as well as libgcc.
1248 dnl
1249 dnl --enable-libunwind-exceptions forces the use of libunwind.
1250 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1251 dnl
1252 dnl Substs:
1253 dnl  LIBUNWIND_FLAG
1254 dnl
1255 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1256   AC_MSG_CHECKING([for use of libunwind])
1257   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1258     [force use of libunwind for exceptions])
1259   AC_MSG_RESULT($use_libunwind_exceptions)
1260   if test $enable_libunwind_exceptions = yes; then
1261     LIBUNWIND_FLAG="-lunwind"
1262   else
1263     LIBUNWIND_FLAG=""
1264   fi
1265   AC_SUBST(LIBUNWIND_FLAG)
1266 ])
1267
1268
1269 dnl
1270 dnl Check for template specializations for the 'long long' type extension.
1271 dnl The result determines only whether 'long long' I/O is enabled; things
1272 dnl like numeric_limits<> specializations are always available.
1273 dnl
1274 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1275 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1276 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1277 dnl       Where DEFAULT is either `yes' or `no'.
1278 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1279 dnl
1280 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1281   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1282
1283   AC_LANG_SAVE
1284   AC_LANG_CPLUSPLUS
1285
1286   AC_MSG_CHECKING([for enabled long long I/O support])
1287   # iostreams require strtoll, strtoull to compile
1288   AC_TRY_COMPILE([#include <stdlib.h>],
1289                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1290   AC_TRY_COMPILE([#include <stdlib.h>],
1291                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1292
1293   # Option parsed, now set things appropriately
1294   if test $enable_long_long = yes; then
1295     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1296   fi
1297   AC_MSG_RESULT($enable_long_long)
1298
1299   AC_LANG_RESTORE
1300 ])
1301
1302
1303 dnl
1304 dnl Check to see if building and using a C++ precompiled header can be done.
1305 dnl
1306 dnl --enable-libstdcxx-pch=yes
1307 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1308 dnl may work, after some light-hearted attempts to puzzle out compiler
1309 dnl support, flip bits on in include/Makefile.am
1310 dnl
1311 dnl --disable-libstdcxx-pch
1312 dnl turns off attempts to use or build stdc++.h.gch.
1313 dnl
1314 dnl Substs:
1315 dnl  glibcxx_PCHFLAGS
1316 dnl
1317 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1318   AC_MSG_CHECKING([for enabled PCH])
1319   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1320   AC_MSG_RESULT([$enable_libstdcxx_pch])
1321
1322   if test $enable_libstdcxx_pch = yes; then
1323     AC_CACHE_CHECK([for compiler with PCH support],
1324       [glibcxx_cv_prog_CXX_pch],
1325       [ac_save_CXXFLAGS="$CXXFLAGS"
1326        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1327        AC_LANG_SAVE
1328        AC_LANG_CPLUSPLUS
1329        echo '#include <math.h>' > conftest.h
1330        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1331                           -o conftest.h.gch 1>&5 2>&1 &&
1332                 echo '#error "pch failed"' > conftest.h &&
1333           echo '#include "conftest.h"' > conftest.cc &&
1334                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1335        then
1336          glibcxx_cv_prog_CXX_pch=yes
1337        else
1338          glibcxx_cv_prog_CXX_pch=no
1339        fi
1340        rm -f conftest*
1341        CXXFLAGS=$ac_save_CXXFLAGS
1342        AC_LANG_RESTORE
1343       ])
1344     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1345   fi
1346
1347   AM_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1348   if test $enable_libstdcxx_pch = yes; then
1349     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1350   else
1351     glibcxx_PCHFLAGS=""
1352   fi
1353   AC_SUBST(glibcxx_PCHFLAGS)
1354 ])
1355
1356
1357 dnl
1358 dnl Check for exception handling support.  If an explicit enable/disable
1359 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1360 dnl target may or may not support call frame exceptions.
1361 dnl
1362 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1363 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1364 dnl Neither one forces an attempt at detection.
1365 dnl
1366 dnl Defines:
1367 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1368 dnl
1369 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1370   AC_MSG_CHECKING([for exception model to use])
1371   AC_LANG_SAVE
1372   AC_LANG_CPLUSPLUS
1373   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1374     [force use of builtin_setjmp for exceptions],
1375     [permit yes|no|auto])
1376
1377   if test $enable_sjlj_exceptions = auto; then
1378     # Botheration.  Now we've got to detect the exception model.  Link tests
1379     # against libgcc.a are problematic since we've not been given proper -L
1380     # bits for single-tree newlib and libgloss.
1381     #
1382     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1383     cat > conftest.$ac_ext << EOF
1384 [#]line __oline__ "configure"
1385 struct S { ~S(); };
1386 void bar();
1387 void foo()
1388 {
1389   S s;
1390   bar();
1391 }
1392 EOF
1393     old_CXXFLAGS="$CXXFLAGS"
1394     CXXFLAGS=-S
1395     if AC_TRY_EVAL(ac_compile); then
1396       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1397         enable_sjlj_exceptions=yes
1398       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1399         enable_sjlj_exceptions=no
1400       fi
1401     fi
1402     CXXFLAGS="$old_CXXFLAGS"
1403     rm -f conftest*
1404   fi
1405
1406   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1407   # to two different models.
1408   case $enable_sjlj_exceptions in
1409     yes)
1410       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1411         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1412       ac_exception_model_name=sjlj
1413       ;;
1414     no)
1415       ac_exception_model_name="call frame"
1416       ;;
1417     *)
1418       AC_MSG_ERROR([unable to detect exception model])
1419       ;;
1420   esac
1421  AC_LANG_RESTORE
1422  AC_MSG_RESULT($ac_exception_model_name)
1423 ])
1424
1425
1426 dnl
1427 dnl Add version tags to symbols in shared library (or not), additionally
1428 dnl marking other symbols as private/local (or not).
1429 dnl
1430 dnl --enable-symvers=style adds a version script to the linker call when
1431 dnl       creating the shared library.  The choice of version script is
1432 dnl       controlled by 'style'.
1433 dnl --disable-symvers does not.
1434 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1435 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1436 dnl       choose a default style based on linker characteristics.  Passing
1437 dnl       'no' disables versioning.
1438 dnl
1439 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1440
1441 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1442   [enables symbol versioning of the shared library],
1443   [permit yes|no|gnu])
1444
1445 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1446 # don't know enough about $LD to do tricks...
1447 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1448 # FIXME  The following test is too strict, in theory.
1449 if test $enable_shared = no ||
1450         test "x$LD" = x ||
1451         test x$glibcxx_gnu_ld_version = x; then
1452   enable_symvers=no
1453 fi
1454
1455 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1456 if test $enable_symvers != no; then
1457   AC_MSG_CHECKING([for shared libgcc])
1458   ac_save_CFLAGS="$CFLAGS"
1459   CFLAGS=' -lgcc_s'
1460   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1461   CFLAGS="$ac_save_CFLAGS"
1462   AC_MSG_RESULT($glibcxx_shared_libgcc)
1463 fi
1464
1465 # For GNU ld, we need at least this version.  The format is described in
1466 # GLIBCXX_CHECK_LINKER_FEATURES above.
1467 glibcxx_min_gnu_ld_version=21400
1468 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1469
1470 # Check to see if unspecified "yes" value can win, given results above.
1471 # Change "yes" into either "no" or a style name.
1472 if test $enable_symvers = yes; then
1473   if test $with_gnu_ld = yes &&
1474      test $glibcxx_shared_libgcc = yes;
1475   then
1476     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1477       enable_symvers=gnu
1478     else
1479       # The right tools, the right setup, but too old.  Fallbacks?
1480       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1481       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1482       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1483       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1484       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1485         # Globbing fix is present, proper block support is not.
1486         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1487         dnl enable_symvers=???
1488         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1489         enable_symvers=no
1490       else
1491         # 2.11 or older.
1492         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1493         enable_symvers=no
1494       fi
1495     fi
1496   else
1497     # just fail for now
1498     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1499     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1500     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1501     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1502     enable_symvers=no
1503   fi
1504 fi
1505
1506 # Everything parsed; figure out what file to use.
1507 case $enable_symvers in
1508   no)
1509     SYMVER_MAP=config/linker-map.dummy
1510     ;;
1511   gnu)
1512     SYMVER_MAP=config/linker-map.gnu
1513     AC_DEFINE(_GLIBCXX_SYMVER)
1514     ;;
1515 esac
1516
1517 AC_SUBST(SYMVER_MAP)
1518 AC_SUBST(port_specific_symbol_files)
1519 AM_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1520 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1521 ])
1522
1523
1524 dnl
1525 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1526 dnl We must stage the required headers so that they will be installed
1527 dnl with the library (unlike libgcc, the STL implementation is provided
1528 dnl solely within headers).  Since we must not inject random user-space
1529 dnl macro names into user-provided C++ code, we first stage into <file>-in
1530 dnl and process to <file> with an output command.  The reason for a two-
1531 dnl stage process here is to correctly handle $srcdir!=$objdir without
1532 dnl having to write complex code (the sed commands to clean the macro
1533 dnl namespace are complex and fragile enough as it is).  We must also
1534 dnl add a relative path so that -I- is supported properly.
1535 dnl
1536 dnl Substs:
1537 dnl  glibcxx_thread_h
1538 dnl
1539 dnl Defines:
1540 dnl  HAVE_GTHR_DEFAULT
1541 dnl  _GLIBCXX_SUPPORTS_WEAK
1542 dnl
1543 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1544   AC_MSG_CHECKING([for thread model used by GCC])
1545   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1546   AC_MSG_RESULT([$target_thread_file])
1547
1548   if test $target_thread_file != single; then
1549     AC_DEFINE(HAVE_GTHR_DEFAULT)
1550     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1551   fi
1552
1553   glibcxx_thread_h=gthr-$target_thread_file.h
1554   AC_SUBST(glibcxx_thread_h)
1555 ])
1556
1557
1558 # Check whether LC_MESSAGES is available in <locale.h>.
1559 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1560 #
1561 # This file file be copied and used freely without restrictions.  It can
1562 # be used in projects which are not available under the GNU Public License
1563 # but which still want to provide support for the GNU gettext functionality.
1564 # Please note that the actual code is *not* freely available.
1565
1566 # serial 1
1567 AC_DEFUN(AC_LC_MESSAGES, [
1568   AC_CHECK_HEADER(locale.h, [
1569     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1570       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1571        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1572     if test $ac_cv_val_LC_MESSAGES = yes; then
1573       AC_DEFINE(HAVE_LC_MESSAGES)
1574     fi
1575   ])
1576 ])
1577
1578
1579 sinclude([../libtool.m4])
1580 dnl The lines below arrange for aclocal not to bring an installed
1581 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1582 dnl add a definition of LIBTOOL to Makefile.in.
1583 ifelse(,,,[AC_SUBST(LIBTOOL)
1584 AC_DEFUN([AM_PROG_LIBTOOL])
1585 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1586 AC_DEFUN([AC_PROG_LD])
1587 ])
1588
1589 dnl vim:et:ts=2:sw=2