libstdc++-v3/acinclude.m4

   1 dnl
   2 dnl Initialize configure bits.
   3 dnl
   4 dnl GLIBCPP_CONFIGURE
   5 AC_DEFUN(GLIBCPP_CONFIGURE, [
   6   dnl Default to --enable-multilib
   7   AC_ARG_ENABLE(multilib,
   8   [  --enable-multilib       build hella library versions (default)],
   9   [case "${enableval}" in
  10     yes) multilib=yes ;;
  11     no)  multilib=no ;;
  12     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  13    esac], [multilib=yes])dnl
  14
  15 # When building with srcdir == objdir, links to the source files will
  16 # be created in directories within the target_subdir.  We have to
  17 # adjust toplevel_srcdir accordingly, so that configure finds
  18 # install-sh and other auxiliary files that live in the top-level
  19 # source directory.
  20 if test "${srcdir}" = "."; then
  21   if test -z "${with_target_subdir}"; then
  22     toprel=".."
  23   else
  24     if test "${with_target_subdir}" != "."; then
  25       toprel="${with_multisrctop}../.."
  26     else
  27       toprel="${with_multisrctop}.."
  28     fi
  29   fi
  30 else
  31   toprel=".."
  32 fi
  33 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  34 toplevel_srcdir=\${top_srcdir}/$toprel
  35 AC_SUBST(toplevel_srcdir)
  36
  37 # Export build and source directories.
  38 # These need to be absolute paths, yet at the same time need to
  39 # canonicalize only relative paths, because then amd will not unmount
  40 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  41 glibcpp_builddir=`pwd`
  42 case $srcdir in
  43 [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
  44 *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  45 esac
  46 AC_SUBST(glibcpp_builddir)
  47 AC_SUBST(glibcpp_srcdir)
  48
  49 dnl This is here just to satisfy automake.
  50 ifelse(not,equal,[AC_CONFIG_AUX_DIR(..)])
  51
  52 # Will set LN_S to either 'ln -s' or 'ln'.  With autoconf 2.50+, can also
  53 # be 'cp -p' if linking isn't available.
  54 #ac_cv_prog_LN_S='cp -p'
  55 AC_PROG_LN_S
  56
  57 # We use these options to decide which functions to include.
  58 AC_ARG_WITH(target-subdir,
  59 [  --with-target-subdir=SUBDIR
  60                            configuring in a subdirectory])
  61 AC_ARG_WITH(cross-host,
  62 [  --with-cross-host=HOST  configuring with a cross compiler])
  63
  64   glibcpp_basedir=$srcdir/$toprel/$1/libstdc++-v3
  65   AC_SUBST(glibcpp_basedir)
  66
  67   # Never versions of autoconf add an underscore to these functions.
  68   # Prevent future problems ...
  69   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  70   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  71   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  72   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  73
  74 #  AC_PROG_CC
  75
  76 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  77 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  78 # are probably using a cross compiler, which will not be able to fully
  79 # link an executable.  This should really be fixed in autoconf
  80 # itself.
  81
  82 AC_DEFUN(LIB_AC_PROG_CC,
  83 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  84 dnl Fool anybody using AC_PROG_CC.
  85 AC_PROVIDE([AC_PROG_CC])
  86 AC_CHECK_PROG(CC, gcc, gcc)
  87 if test -z "$CC"; then
  88   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  89   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  90 fi
  91
  92 AC_PROG_CC_GNU
  93
  94 if test $ac_cv_prog_gcc = yes; then
  95   GCC=yes
  96 dnl Check whether -g works, even if CFLAGS is set, in case the package
  97 dnl plays around with CFLAGS (such as to build both debugging and
  98 dnl normal versions of a library), tasteless as that idea is.
  99   ac_test_CFLAGS="${CFLAGS+set}"
 100   ac_save_CFLAGS="$CFLAGS"
 101   CFLAGS=
 102   AC_PROG_CC_G
 103   if test "$ac_test_CFLAGS" = set; then
 104     CFLAGS="$ac_save_CFLAGS"
 105   elif test $ac_cv_prog_cc_g = yes; then
 106     CFLAGS="-g -O2"
 107   else
 108     CFLAGS="-O2"
 109   fi
 110 else
 111   GCC=
 112   test "${CFLAGS+set}" = set || CFLAGS="-g"
 113 fi
 114 ])
 115
 116 LIB_AC_PROG_CC
 117
 118 # Can't just call these here as g++ requires libstc++ to be built....
 119 #  AC_PROG_CXX
 120
 121 # Likewise for AC_PROG_CXX.
 122 AC_DEFUN(LIB_AC_PROG_CXX,
 123 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
 124 dnl Fool anybody using AC_PROG_CXX.
 125 AC_PROVIDE([AC_PROG_CXX])
 126 # Use glibcpp_CXX so that we do not cause CXX to be cached with the
 127 # flags that come in CXX while configuring libstdc++.  They're different
 128 # from those used for all other target libraries.  If CXX is set in
 129 # the environment, respect that here.
 130 glibcpp_CXX=$CXX
 131 AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
 132 AC_SUBST(glibcpp_CXX)
 133 CXX=$glibcpp_CXX
 134 test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 135
 136 AC_PROG_CXX_GNU
 137
 138 if test $ac_cv_prog_gxx = yes; then
 139   GXX=yes
 140 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 141 dnl plays around with CXXFLAGS (such as to build both debugging and
 142 dnl normal versions of a library), tasteless as that idea is.
 143   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 144   ac_save_CXXFLAGS="$CXXFLAGS"
 145   CXXFLAGS=
 146   AC_PROG_CXX_G
 147   if test "$ac_test_CXXFLAGS" = set; then
 148     CXXFLAGS="$ac_save_CXXFLAGS"
 149   elif test $ac_cv_prog_cxx_g = yes; then
 150     CXXFLAGS="-g -O2"
 151   else
 152     CXXFLAGS="-O2"
 153   fi
 154 else
 155   GXX=
 156   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 157 fi
 158 ])
 159
 160 LIB_AC_PROG_CXX
 161
 162    # For some reason, gettext needs this.
 163    AC_ISC_POSIX
 164
 165   AC_CHECK_TOOL(AS, as)
 166   AC_CHECK_TOOL(AR, ar)
 167   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 168   AC_PROG_INSTALL
 169
 170   AM_MAINTAINER_MODE
 171
 172   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 173   # at least currently, we never actually build a program, so we never
 174   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 175   # fails, because we are probably configuring with a cross compiler
 176   # which can't create executables.  So we include AC_EXEEXT to keep
 177   # automake happy, but we don't execute it, since we don't care about
 178   # the result.
 179   if false; then
 180     # autoconf 2.50 runs AC_EXEEXT by default, and the macro expands
 181     # to nothing, so nothing would remain between `then' and `fi' if it
 182     # were not for the `:' below.
 183     :
 184     AC_EXEEXT
 185   fi
 186
 187   . [$]{glibcpp_basedir}/configure.host
 188
 189   case [$]{glibcpp_basedir} in
 190     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 191     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 192   esac
 193
 194   # This does for the target what configure.host does for the host.  In
 195   # addition to possibly modifying the same flags, it also sets up symlinks.
 196   GLIBCPP_CHECK_TARGET
 197
 198   #
 199 ])
 200
 201
 202 dnl
 203 dnl Check to see if g++ can compile this library, and if so, if any version-
 204 dnl specific precautions need to be taken.
 205 dnl
 206 dnl GLIBCPP_CHECK_COMPILER_VERSION
 207 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 208 if test ! -f stamp-sanity-compiler; then
 209   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 210   AC_LANG_SAVE
 211   AC_LANG_CPLUSPLUS
 212   AC_TRY_COMPILE(, [
 213   #if __GNUC__ < 3
 214     not_ok
 215   #endif
 216   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 217   AC_LANG_RESTORE
 218   AC_MSG_RESULT($gpp_satisfactory)
 219   touch stamp-sanity-compiler
 220 fi
 221 ])
 222
 223
 224 dnl
 225 dnl Tests for newer compiler features, or features that are present in newer
 226 dnl compiler versions but not older compiler versions still in use, should
 227 dnl be placed here.
 228 dnl
 229 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 230 dnl new inlining code or the new system_header pragma will die on -Werror.
 231 dnl Leave it out by default and use maint-mode to use it.
 232 dnl
 233 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 234 dnl compiler supports it and the user has not requested debug mode.
 235 dnl
 236 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 237 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 238   # All these tests are for C++; save the language and the compiler flags.
 239   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 240   # found in GLIBCPP_CONFIGURE.
 241   AC_LANG_SAVE
 242   AC_LANG_CPLUSPLUS
 243   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 244   ac_save_CXXFLAGS="$CXXFLAGS"
 245
 246   # Check for maintainer-mode bits.
 247   if test x"$USE_MAINTAINER_MODE" = xno; then
 248     WERROR=''
 249   else
 250     WERROR='-Werror'
 251   fi
 252
 253   # Check for -ffunction-sections -fdata-sections
 254   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 255   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 256   AC_TRY_COMPILE(, [int foo;
 257   ], [ac_fdsections=yes], [ac_fdsections=no])
 258   if test "$ac_test_CXXFLAGS" = set; then
 259     CXXFLAGS="$ac_save_CXXFLAGS"
 260   else
 261     # this is the suspicious part
 262     CXXFLAGS=''
 263   fi
 264   if test x"$ac_fdsections" = x"yes" &&
 265      test x"$enable_debug" = x"no"; then
 266     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 267   fi
 268   AC_MSG_RESULT($ac_fdsections)
 269
 270   AC_LANG_RESTORE
 271   AC_SUBST(WERROR)
 272   AC_SUBST(SECTION_FLAGS)
 273 ])
 274
 275
 276 dnl
 277 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 278 dnl the native linker is in use, all variables will be defined to something
 279 dnl safe (like an empty string).
 280 dnl
 281 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 282 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 283 dnl
 284 dnl GLIBCPP_CHECK_LINKER_FEATURES
 285 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 286   # If we're not using GNU ld, then there's no point in even trying these
 287   # tests.  Check for that first.  We should have already tested for gld
 288   # by now (in libtool), but require it now just to be safe...
 289   SECTION_LDFLAGS=''
 290   OPT_LDFLAGS=''
 291   AC_REQUIRE([AC_PROG_LD])
 292
 293   # Set --gc-sections.
 294   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 295     # GNU ld it is!  Joy and bunny rabbits!
 296
 297     # All these tests are for C++; save the language and the compiler flags.
 298     # Need to do this so that g++ won't try to link in libstdc++
 299     ac_test_CFLAGS="${CFLAGS+set}"
 300     ac_save_CFLAGS="$CFLAGS"
 301     CFLAGS='-x c++  -Wl,--gc-sections'
 302
 303     # Check for -Wl,--gc-sections
 304     # XXX This test is broken at the moment, as symbols required for
 305     # linking are now in libsupc++ (not built yet.....). In addition,
 306     # this test has cored on solaris in the past. In addition,
 307     # --gc-sections doesn't really work at the moment (keeps on discarding
 308     # used sections, first .eh_frame and now some of the glibc sections for
 309     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 310     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 311     AC_TRY_RUN([
 312      int main(void)
 313      {
 314        try { throw 1; }
 315        catch (...) { };
 316        return 0;
 317      }
 318     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 319     if test "$ac_test_CFLAGS" = set; then
 320       CFLAGS="$ac_save_CFLAGS"
 321     else
 322       # this is the suspicious part
 323       CFLAGS=''
 324     fi
 325     if test "$ac_sectionLDflags" = "yes"; then
 326       SECTION_LDFLAGS='-Wl,--gc-sections'
 327     fi
 328     AC_MSG_RESULT($ac_sectionLDflags)
 329   fi
 330
 331   # Set linker optimization flags.
 332   if test x"$ac_cv_prog_gnu_ld" = x"yes" &&
 333      test x"$enable_debug" = x"no"; then
 334     OPT_LDFLAGS='-Wl,-O1'
 335   fi
 336
 337   AC_SUBST(SECTION_LDFLAGS)
 338   AC_SUBST(OPT_LDFLAGS)
 339 ])
 340
 341
 342 dnl
 343 dnl Check to see if the (math function) argument passed is
 344 dnl declared when using the c++ compiler
 345 dnl ASSUMES argument is a math function with ONE parameter
 346 dnl
 347 dnl GLIBCPP_CHECK_MATH_DECL_1
 348 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 349   AC_MSG_CHECKING([for $1 declaration])
 350   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 351     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 352       AC_LANG_SAVE
 353       AC_LANG_CPLUSPLUS
 354       AC_TRY_COMPILE([#include <math.h>
 355                       #ifdef HAVE_IEEEFP_H
 356                       #include <ieeefp.h>
 357                       #endif
 358                      ],
 359                      [ $1(0);],
 360                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 361       AC_LANG_RESTORE
 362     ])
 363   fi
 364   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 365 ])
 366
 367 dnl
 368 dnl Check to see if the (math function) argument passed is
 369 dnl 1) declared when using the c++ compiler
 370 dnl 2) has "C" linkage
 371 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 372 dnl
 373 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 374 dnl
 375 dnl argument 1 is name of function to check
 376 dnl
 377 dnl ASSUMES argument is a math function with ONE parameter
 378 dnl
 379 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 380 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 381   GLIBCPP_CHECK_MATH_DECL_1($1)
 382   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 383     AC_CHECK_FUNCS($1)
 384   else
 385     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 386     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 387       AC_CHECK_FUNCS(_$1)
 388     fi
 389   fi
 390 ])
 391
 392
 393 dnl
 394 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 395 dnl of functions at once.  It's an all-or-nothing check -- either
 396 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 397 dnl Doing it this way saves significant configure time.
 398 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 399   AC_MSG_CHECKING([for $1 functions])
 400   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 401     AC_LANG_SAVE
 402     AC_LANG_CPLUSPLUS
 403     AC_TRY_COMPILE([#include <math.h>],
 404                    [ `for x in $3; do echo "$x (0);"; done` ],
 405                    [glibcpp_cv_func_$2_use=yes],
 406                    [glibcpp_cv_func_$2_use=no])
 407     AC_LANG_RESTORE])
 408   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 409   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 410     AC_CHECK_FUNCS($3)
 411   fi
 412 ])
 413
 414 dnl
 415 dnl Check to see if the (math function) argument passed is
 416 dnl declared when using the c++ compiler
 417 dnl ASSUMES argument is a math function with TWO parameters
 418 dnl
 419 dnl GLIBCPP_CHECK_MATH_DECL_2
 420 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 421   AC_MSG_CHECKING([for $1 declaration])
 422   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 423     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 424       AC_LANG_SAVE
 425       AC_LANG_CPLUSPLUS
 426       AC_TRY_COMPILE([#include <math.h>],
 427                      [ $1(0, 0);],
 428                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 429       AC_LANG_RESTORE
 430     ])
 431   fi
 432   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 433 ])
 434
 435 dnl
 436 dnl Check to see if the (math function) argument passed is
 437 dnl 1) declared when using the c++ compiler
 438 dnl 2) has "C" linkage
 439 dnl
 440 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 441 dnl
 442 dnl argument 1 is name of function to check
 443 dnl
 444 dnl ASSUMES argument is a math function with TWO parameters
 445 dnl
 446 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 447 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 448   GLIBCPP_CHECK_MATH_DECL_2($1)
 449   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 450     AC_CHECK_FUNCS($1)
 451   else
 452     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 453     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 454       AC_CHECK_FUNCS(_$1)
 455     fi
 456   fi
 457 ])
 458
 459
 460 dnl
 461 dnl Check to see if the (math function) argument passed is
 462 dnl declared when using the c++ compiler
 463 dnl ASSUMES argument is a math function with THREE parameters
 464 dnl
 465 dnl GLIBCPP_CHECK_MATH_DECL_3
 466 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 467   AC_MSG_CHECKING([for $1 declaration])
 468   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 469     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 470       AC_LANG_SAVE
 471       AC_LANG_CPLUSPLUS
 472       AC_TRY_COMPILE([#include <math.h>],
 473                      [ $1(0, 0, 0);],
 474                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 475       AC_LANG_RESTORE
 476     ])
 477   fi
 478   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 479 ])
 480
 481 dnl
 482 dnl Check to see if the (math function) argument passed is
 483 dnl 1) declared when using the c++ compiler
 484 dnl 2) has "C" linkage
 485 dnl
 486 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 487 dnl
 488 dnl argument 1 is name of function to check
 489 dnl
 490 dnl ASSUMES argument is a math function with THREE parameters
 491 dnl
 492 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 493 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 494   GLIBCPP_CHECK_MATH_DECL_3($1)
 495   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 496     AC_CHECK_FUNCS($1)
 497   else
 498     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 499     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 500       AC_CHECK_FUNCS(_$1)
 501     fi
 502   fi
 503 ])
 504
 505
 506 dnl
 507 dnl Check to see if the (stdlib function) argument passed is
 508 dnl 1) declared when using the c++ compiler
 509 dnl 2) has "C" linkage
 510 dnl
 511 dnl argument 1 is name of function to check
 512 dnl
 513 dnl ASSUMES argument is a math function with TWO parameters
 514 dnl
 515 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 516 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 517   AC_MSG_CHECKING([for $1 declaration])
 518   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 519     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 520       AC_LANG_SAVE
 521       AC_LANG_CPLUSPLUS
 522       AC_TRY_COMPILE([#include <stdlib.h>],
 523                      [ $1(0, 0);],
 524                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 525       AC_LANG_RESTORE
 526     ])
 527   fi
 528   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 529   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 530     AC_CHECK_FUNCS($1)
 531   fi
 532 ])
 533
 534
 535 dnl
 536 dnl Because the builtins are picky picky picky about the arguments they take,
 537 dnl do an explict linkage tests here.
 538 dnl Check to see if the (math function) argument passed is
 539 dnl 1) declared when using the c++ compiler
 540 dnl 2) has "C" linkage
 541 dnl
 542 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 543 dnl
 544 dnl argument 1 is name of function to check
 545 dnl
 546 dnl ASSUMES argument is a math function with ONE parameter
 547 dnl
 548 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 549 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 550   AC_MSG_CHECKING([for $1 declaration])
 551   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 552     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 553       AC_LANG_SAVE
 554       AC_LANG_CPLUSPLUS
 555       AC_TRY_COMPILE([#include <math.h>],
 556                      [ $1(0);],
 557                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 558       AC_LANG_RESTORE
 559     ])
 560   fi
 561   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 562   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 563     AC_MSG_CHECKING([for $1 linkage])
 564     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 565       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 566         AC_TRY_LINK([#include <math.h>],
 567                     [ $1(0);],
 568                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 569       ])
 570     fi
 571     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 572     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 573       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 574       AC_DEFINE_UNQUOTED(${ac_tr_func})
 575     fi
 576   fi
 577 ])
 578
 579
 580 dnl
 581 dnl Check to see what builtin math functions are supported
 582 dnl
 583 dnl check for __builtin_abs
 584 dnl check for __builtin_fabsf
 585 dnl check for __builtin_fabs
 586 dnl check for __builtin_fabl
 587 dnl check for __builtin_labs
 588 dnl check for __builtin_sqrtf
 589 dnl check for __builtin_sqrtl
 590 dnl check for __builtin_sqrt
 591 dnl check for __builtin_sinf
 592 dnl check for __builtin_sin
 593 dnl check for __builtin_sinl
 594 dnl check for __builtin_cosf
 595 dnl check for __builtin_cos
 596 dnl check for __builtin_cosl
 597 dnl
 598 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 599 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 600   dnl Test for builtin math functions.
 601   dnl These are made in gcc/c-common.c
 602   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 603   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 604   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 605   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 606   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 607
 608   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 609   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrt)
 610   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 611
 612   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 613   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 614   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 615
 616   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 617   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 618   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 619
 620   dnl There is, without a doubt, a more elegant way to have these
 621   dnl names exported so that they won't be stripped out of acconfig.h by
 622   dnl autoheader. I leave this as an exercise to somebody less frustrated
 623   dnl than I.... please email the libstdc++ list if you can figure out a
 624   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 625   dnl AC_CHECK_FUNC for things to steal.)
 626   dummyvar=no
 627   if test x$dummyvar = x"yes"; then
 628     AC_DEFINE(HAVE___BUILTIN_ABS)
 629     AC_DEFINE(HAVE___BUILTIN_LABS)
 630     AC_DEFINE(HAVE___BUILTIN_COS)
 631     AC_DEFINE(HAVE___BUILTIN_COSF)
 632     AC_DEFINE(HAVE___BUILTIN_COSL)
 633     AC_DEFINE(HAVE___BUILTIN_FABS)
 634     AC_DEFINE(HAVE___BUILTIN_FABSF)
 635     AC_DEFINE(HAVE___BUILTIN_FABSL)
 636     AC_DEFINE(HAVE___BUILTIN_SIN)
 637     AC_DEFINE(HAVE___BUILTIN_SINF)
 638     AC_DEFINE(HAVE___BUILTIN_SINL)
 639     AC_DEFINE(HAVE___BUILTIN_SQRT)
 640     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 641     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 642   fi
 643 ])
 644
 645
 646 dnl
 647 dnl Check to see what the underlying c library
 648 dnl These checks need to do two things:
 649 dnl 1) make sure the name is declared when using the c++ compiler
 650 dnl 2) make sure the name has "C" linkage
 651 dnl This might seem like overkill but experience has shown that it's not...
 652 dnl
 653 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 654 dnl Define HAVE_STRTOF if "strtof" is declared and links
 655 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 656 dnl
 657 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 658 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 659   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 660   ac_save_CXXFLAGS="$CXXFLAGS"
 661   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 662
 663   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 664   AC_CHECK_FUNCS(drand48)
 665
 666   CXXFLAGS="$ac_save_CXXFLAGS"
 667 ])
 668
 669
 670 dnl
 671 dnl Check to see what the underlying c library or math library is like.
 672 dnl These checks need to do two things:
 673 dnl 1) make sure the name is declared when using the c++ compiler
 674 dnl 2) make sure the name has "C" linkage
 675 dnl This might seem like overkill but experience has shown that it's not...
 676 dnl
 677 dnl Define HAVE_CARGF etc if "cargf" is found.
 678 dnl
 679 dnl GLIBCPP_CHECK_MATH_SUPPORT
 680 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 681   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 682   ac_save_CXXFLAGS="$CXXFLAGS"
 683   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 684
 685   dnl Check libm
 686   AC_CHECK_LIB(m, sin, libm="-lm")
 687   ac_save_LIBS="$LIBS"
 688   LIBS="$LIBS $libm"
 689
 690   dnl Check to see if certain C math functions exist.
 691   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypot)
 699
 700   dnl Check to see if basic C math functions have float versions.
 701   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 702                                           float_trig,
 703                                           acosf asinf atanf \
 704                                           cosf sinf tanf \
 705                                           coshf sinhf tanhf)
 706   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 707                                           float_round,
 708                                           ceilf floorf)
 709   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 710   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 711   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2f)
 712   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 713   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 714   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 715   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotf)
 716   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 717   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 718   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 719   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 720   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 721   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 722   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 723   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 724
 725   dnl Check to see if basic C math functions have long double versions.
 726   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 727                                           long_double_trig,
 728                                           acosl asinl atanl \
 729                                           cosl sinl tanl \
 730                                           coshl sinhl tanhl)
 731   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 732                                           long_double_round,
 733                                           ceill floorl)
 734   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 735   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 736   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 737   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 738   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 739   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 740   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 741   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 742   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(hypotl)
 743   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 744   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 745   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 746   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 747   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 748   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 749   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 750   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 751
 752   dnl Some runtimes have these functions with a preceding underscore. Please
 753   dnl keep this sync'd with the one above. And if you add any new symbol,
 754   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 755   dnl Check to see if certain C math functions exist.
 756
 757   dnl Check to see if basic C math functions have float versions.
 758   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 759                                           _float_trig,
 760                                           _acosf _asinf _atanf \
 761                                           _cosf _sinf _tanf \
 762                                           _coshf _sinhf _tanhf)
 763   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 764                                           _float_round,
 765                                           _ceilf _floorf)
 766
 767   dnl Check to see if basic C math functions have long double versions.
 768   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 769                                           _long_double_trig,
 770                                           _acosl _asinl _atanl \
 771                                           _cosl _sinl _tanl \
 772                                           _coshl _sinhl _tanhl)
 773   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 774                                           _long_double_round,
 775                                           _ceill _floorl)
 776
 777   LIBS="$ac_save_LIBS"
 778   CXXFLAGS="$ac_save_CXXFLAGS"
 779 ])
 780
 781
 782 dnl
 783 dnl Check to see if there is native support for complex
 784 dnl
 785 dnl Don't compile bits in math/* if native support exits.
 786 dnl
 787 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "copysignl" is found.
 788 dnl
 789 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 790 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 791   dnl Check for complex versions of math functions of platform.
 792   AC_CHECK_LIB(m, main)
 793   AC_REPLACE_MATHFUNCS(nan copysignf)
 794
 795   dnl Compile the long double complex functions only if the function
 796   dnl provides the non-complex long double functions that are needed.
 797   dnl Currently this includes copysignl, which should be
 798   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 799   USE_COMPLEX_LONG_DOUBLE=no
 800   if test x$ac_cv_func_copysignl = x"yes"; then
 801     USE_COMPLEX_LONG_DOUBLE=yes
 802     AC_REPLACE_MATHFUNCS(signbitl)
 803   fi
 804
 805   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 806 ])
 807
 808
 809 dnl Check to see what architecture and operating system we are compiling
 810 dnl for.  Also, if architecture- or OS-specific flags are required for
 811 dnl compilation, pick them up here.
 812 dnl
 813 dnl GLIBCPP_CHECK_TARGET
 814 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 815     . [$]{glibcpp_basedir}/configure.target
 816     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 817     AC_MSG_RESULT(OS config directory is $os_include_dir)
 818 ])
 819
 820
 821 dnl
 822 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 823 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 824 dnl must have been previously checked.)
 825 dnl
 826 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 827 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 828 dnl
 829 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 830 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 831
 832   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 833   dnl others even if wchar_t support is not on.
 834   AC_MSG_CHECKING([for mbstate_t])
 835   AC_TRY_COMPILE([#include <wchar.h>],
 836   [mbstate_t teststate;],
 837   have_mbstate_t=yes, have_mbstate_t=no)
 838   AC_MSG_RESULT($have_mbstate_t)
 839   if test x"$have_mbstate_t" = xyes; then
 840     AC_DEFINE(HAVE_MBSTATE_T)
 841   fi
 842
 843   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 844   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 845   AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 846
 847   dnl Only continue checking if the ISO C99 headers exist and support is on.
 848   if test x"$ac_has_wchar_h" = xyes &&
 849      test x"$ac_has_wctype_h" = xyes &&
 850      test x"$enable_c_mbchar" != xno; then
 851
 852     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 853     dnl numeric_limits can instantiate type_traits<wchar_t>
 854     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 855     AC_TRY_COMPILE([#include <wchar.h>],
 856     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 857     has_wchar_minmax=yes, has_wchar_minmax=no)
 858     AC_MSG_RESULT($has_wchar_minmax)
 859
 860     dnl Test wchar.h for WEOF, which is what we use to determine whether
 861     dnl to specialize for char_traits<wchar_t> or not.
 862     AC_MSG_CHECKING([for WEOF])
 863     AC_TRY_COMPILE([
 864       #include <wchar.h>
 865       #include <stddef.h>],
 866     [wint_t i = WEOF;],
 867     has_weof=yes, has_weof=no)
 868     AC_MSG_RESULT($has_weof)
 869
 870     dnl Tests for wide character functions used in char_traits<wchar_t>.
 871     ac_wfuncs=yes
 872     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset,, \
 873     ac_wfuncs=no)
 874
 875     dnl Checks for names injected into std:: by the c_std headers.
 876     AC_CHECK_FUNCS(btowc wctob fgetwc fgetwc fgetws fputwc fputws fwide \
 877     fwprintf fwscanf swprintf swscanf vfwprintf vfwscanf vswprintf vswscanf \
 878     vwprintf vwscanf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 879     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstof wcstol \
 880     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 881     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr,, \
 882     ac_wfuncs=no)
 883
 884     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 885     if test x"$has_weof" = xyes &&
 886        test x"$has_wchar_minmax" = xyes &&
 887        test x"$ac_wfuncs" = xyes; then
 888       ac_isoC99_wchar_t=yes
 889     else
 890       ac_isoC99_wchar_t=no
 891     fi
 892     AC_MSG_RESULT($ac_isoC99_wchar_t)
 893
 894     dnl Use iconv for wchar_t to char conversions. As such, check for
 895     dnl X/Open Portability Guide, version 2 features (XPG2).
 896     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 897     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 898
 899     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 900     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 901     ac_save_LIBS="$LIBS"
 902     LIBS="$LIBS $libiconv"
 903
 904     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 905     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 906
 907     LIBS="$ac_save_LIBS"
 908
 909     AC_MSG_CHECKING([for XPG2 wchar_t support])
 910     if test x"$ac_has_iconv_h" = xyes &&
 911        test x"$ac_has_langinfo_h" = xyes &&
 912        test x"$ac_XPG2funcs" = xyes; then
 913       ac_XPG2_wchar_t=yes
 914     else
 915       ac_XPG2_wchar_t=no
 916     fi
 917     AC_MSG_RESULT($ac_XPG2_wchar_t)
 918
 919     dnl At the moment, only enable wchar_t specializations if all the
 920     dnl above support is present.
 921     AC_MSG_CHECKING([for enabled wchar_t specializations])
 922     if test x"$ac_isoC99_wchar_t" = xyes &&
 923        test x"$ac_XPG2_wchar_t" = xyes; then
 924       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 925       AC_MSG_RESULT("yes")
 926     else
 927       AC_MSG_RESULT("no")
 928     fi
 929   else
 930     dnl Wide characters disabled by the user.
 931     AC_MSG_WARN([wchar_t support disabled.])
 932   fi
 933 ])
 934
 935
 936 dnl
 937 dnl Check for special debugging mode; not for production use.
 938 dnl
 939 dnl GLIBCPP_ENABLE_DEBUG
 940 dnl --enable-debug sets '-ggdb3 -O0'.
 941 dnl --disable-debug sets '-g' and whatever optimization options the
 942 dnl     compiler can handle.
 943 dnl  +  --enable-maintainer-mode automatically defaults this to on.
 944 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
 945 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
 946 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
 947 dnl       defaults to `no'.
 948 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
 949 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
 950 AC_ARG_ENABLE(debug,
 951 changequote(<<, >>)dnl
 952 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
 953 changequote([, ])dnl
 954 [case "${enableval}" in
 955  yes) enable_debug=yes ;;
 956  no)  enable_debug=no ;;
 957  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
 958  esac],
 959 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
 960
 961 dnl Option parsed, now set things appropriately
 962 case "${enable_debug}" in
 963     yes)
 964         DEBUG_FLAGS='-O0 -ggdb3'
 965         ;;
 966     no)
 967         DEBUG_FLAGS='-g'
 968         ;;
 969 esac
 970 AC_SUBST(DEBUG_FLAGS)
 971 ])
 972
 973
 974 dnl
 975 dnl Check for "unusual" flags to pass to the compiler while building.
 976 dnl
 977 dnl GLIBCPP_ENABLE_CXX_FLAGS
 978 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
 979 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
 980 dnl     Somehow this same set of flags must be passed when [re]building
 981 dnl     libgcc.
 982 dnl --disable-cxx-flags passes nothing.
 983 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
 984 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
 985 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
 986 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
 987 dnl       If "default flags" is an empty string (or "none"), the effect is
 988 dnl       the same as --disable or --enable=no.
 989 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
 990 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
 991 AC_ARG_ENABLE(cxx-flags,
 992 changequote(<<, >>)dnl
 993 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
 994                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
 995 changequote([, ])dnl
 996 [case "x$enableval" in
 997  xyes)
 998         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
 999  xno|x)
1000         enable_cxx_flags='' ;;
1001  *)
1002         enable_cxx_flags="$enableval" ;;
1003  esac],
1004 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
1005
1006 dnl Thinko on my part during design.  This kludge is the workaround.
1007 if test "$enable_cxx_flags" = "none"; then
1008   enable_cxx_flags='';
1009 fi
1010
1011 dnl Run through flags (either default or command-line) and set anything
1012 dnl extra (e.g., #defines) that must accompany particular g++ options.
1013 if test -n "$enable_cxx_flags"; then
1014     for f in $enable_cxx_flags; do
1015         case "$f" in
1016             -fhonor-std)  ;;
1017             -*)  ;;
1018             *)   # and we're trying to pass /what/ exactly?
1019                  AC_MSG_ERROR([compiler flags start with a -]) ;;
1020         esac
1021     done
1022 fi
1023 EXTRA_CXX_FLAGS="$enable_cxx_flags"
1024 AC_SUBST(EXTRA_CXX_FLAGS)
1025 ])
1026
1027
1028 dnl
1029 dnl Check for which locale library to use:  gnu or generic.
1030 dnl
1031 dnl GLIBCPP_ENABLE_CLOCALE
1032 dnl --enable-clocale=gnu sets config/locale/c_locale_gnu.cc and friends
1033 dnl --enable-clocale=generic sets config/locale/c_locale_generic.cc and friends
1034 dnl
1035 dnl default is generic
1036 dnl
1037 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
1038   AC_MSG_CHECKING([for clocale to use])
1039   AC_ARG_ENABLE(clocale,
1040   [  --enable-clocale        enable model for target locale package.
1041   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
1042   ],
1043   if test x$enable_clocale = xno; then
1044      enable_clocale=generic
1045   fi,
1046      enable_clocale=generic)
1047
1048   enable_clocale_flag=$enable_clocale
1049
1050   dnl Check if a valid locale package
1051   case x${enable_clocale_flag} in
1052     xgeneric)
1053       AC_MSG_RESULT(generic)
1054
1055       # Don't use gettext.
1056       USE_NLS=no
1057
1058       CLOCALE_H=config/locale/c_locale_generic.h
1059       CLOCALE_CC=config/locale/c_locale_generic.cc
1060       CCODECVT_H=config/locale/codecvt_specializations_generic.h
1061       CCOLLATE_CC=config/locale/collate_members_generic.cc
1062       CMESSAGES_H=config/locale/messages_members_generic.h
1063       CMESSAGES_CC=config/locale/messages_members_generic.cc
1064       CMONEY_CC=config/locale/moneypunct_members_generic.cc
1065       CNUMERIC_CC=config/locale/numpunct_members_generic.cc
1066       CTIME_CC=config/locale/time_members_generic.cc
1067       ;;
1068     xgnu)
1069       AC_MSG_RESULT(gnu)
1070
1071       # Declare intention to use gettext, and add support for specific
1072       # languages.
1073       # For some reason, ALL_LINGUAS has to be before AM_GNU_GETTEXT
1074       ALL_LINGUAS="de fr"
1075       # Don't call AM_GNU_GETTEXT here. Instead, assume glibc.
1076       # Need to deal with MSGFMT, USE_NLS, and glibcpp_[P,M]OFILES
1077       USE_NLS=yes
1078
1079       # Export the build objects.
1080       for ling in $ALL_LINGUAS; do \
1081         glibcpp_MOFILES="$glibcpp_MOFILES $ling.mo"; \
1082         glibcpp_POFILES="$glibcpp_POFILES $ling.po"; \
1083       done
1084       AC_SUBST(glibcpp_MOFILES)
1085       AC_SUBST(glibcpp_POFILES)
1086
1087       CLOCALE_H=config/locale/c_locale_gnu.h
1088       CLOCALE_CC=config/locale/c_locale_gnu.cc
1089       CCODECVT_H=config/locale/codecvt_specializations_ieee_1003.1-200x.h
1090       CCOLLATE_CC=config/locale/collate_members_gnu.cc
1091       CMESSAGES_H=config/locale/messages_members_gnu.h
1092       CMESSAGES_CC=config/locale/messages_members_gnu.cc
1093       CMONEY_CC=config/locale/moneypunct_members_gnu.cc
1094       CNUMERIC_CC=config/locale/numpunct_members_gnu.cc
1095       CTIME_CC=config/locale/time_members_gnu.cc
1096       ;;
1097     xieee_1003.1)
1098       AC_MSG_RESULT(generic)
1099
1100       # Don't use gettext.
1101       USE_NLS=no
1102
1103       CLOCALE_H=config/locale/c_locale_ieee_1003.1-200x.h
1104       CLOCALE_CC=config/locale/c_locale_ieee_1003.1-200x.cc
1105       CCODECVT_H=config/locale/codecvt_specializations_ieee_1003.1-200x.h
1106       CCOLLATE_CC=config/locale/collate_members_generic.cc
1107       CMESSAGES_H=config/locale/messages_members_ieee_1003.1-200x.h
1108       CMESSAGES_CC=config/locale/messages_members_ieee_1003.1-200x.cc
1109       CMONEY_CC=config/locale/moneypunct_members_generic.cc
1110       CNUMERIC_CC=config/locale/numpunct_members_generic.cc
1111       CTIME_CC=config/locale/time_members_generic.cc
1112       ;;
1113     *)
1114       echo "$enable_clocale is an unknown locale package" 1>&2
1115       exit 1
1116       ;;
1117   esac
1118
1119   # This is where the testsuite looks for locale catalogs, using the
1120   # -DLOCALEDIR define during testsuite compilation.
1121   glibcpp_localedir=${glibcpp_builddir}/po/share/locale
1122   AC_SUBST(glibcpp_localedir)
1123
1124   AC_SUBST(USE_NLS)
1125   AC_SUBST(CLOCALE_H)
1126   AC_SUBST(CCODECVT_H)
1127   AC_SUBST(CMESSAGES_H)
1128   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1129   AC_LINK_FILES($CCOLLATE_CC, src/collate.cc)
1130   AC_LINK_FILES($CMESSAGES_CC, src/messages.cc)
1131   AC_LINK_FILES($CMONEY_CC, src/moneypunct.cc)
1132   AC_LINK_FILES($CNUMERIC_CC, src/numpunct.cc)
1133   AC_LINK_FILES($CTIME_CC, src/time.cc)
1134 ])
1135
1136
1137 dnl
1138 dnl Check for which I/O library to use:  libio, or something specific.
1139 dnl
1140 dnl GLIBCPP_ENABLE_CSTDIO
1141 dnl --enable-cstdio=libio sets config/io/c_io_libio.h and friends
1142 dnl
1143 dnl default is stdio
1144 dnl
1145 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1146   AC_MSG_CHECKING([for cstdio to use])
1147   AC_ARG_ENABLE(cstdio,
1148   [  --enable-cstdio         enable stdio for target io package.
1149   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1150   ],
1151   if test x$enable_cstdio = xno; then
1152      enable_cstdio=stdio
1153   fi,
1154      enable_cstdio=stdio)
1155
1156   enable_cstdio_flag=$enable_cstdio
1157
1158   dnl Check if a valid I/O package
1159   case x${enable_cstdio_flag} in
1160     xlibio)
1161       CSTDIO_H=config/io/c_io_libio.h
1162       BASIC_FILE_H=config/io/basic_file_libio.h
1163       BASIC_FILE_CC=config/io/basic_file_libio.cc
1164       AC_MSG_RESULT(libio)
1165
1166       # see if we are on a system with libio native (ie, linux)
1167       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1168
1169       # Need to check and see what version of glibc is being used. If
1170       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1171       # compile most of libio for linux systems.
1172       if test x$has_libio = x"yes"; then
1173         case "$target" in
1174           *-*-linux*)
1175               AC_MSG_CHECKING([for glibc version >= 2.2])
1176               AC_EGREP_CPP([ok], [
1177             #include <features.h>
1178               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1179                     ok
1180               #endif
1181               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1182               AC_MSG_RESULT($glibc_satisfactory)
1183             ;;
1184         esac
1185
1186         # XXX at the moment, admit defeat and force the recompilation
1187         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1188         glibc_satisfactory=no
1189
1190         if test x$glibc_satisfactory = x"yes"; then
1191            need_libio=no
1192            need_wlibio=no
1193         else
1194            need_libio=yes
1195            # bkoz XXX need to add checks to enable this
1196            # pme XXX here's a first pass at such a check
1197            if test x$enable_c_mbchar != xno; then
1198               need_wlibio=yes
1199            else
1200               need_wlibio=no
1201            fi
1202         fi
1203
1204       else
1205          # Using libio, but <libio.h> doesn't exist on the target system. . .
1206          need_libio=yes
1207          # bkoz XXX need to add checks to enable this
1208          # pme XXX here's a first pass at such a check
1209          if test x$enable_c_mbchar != xno; then
1210              need_wlibio=yes
1211          else
1212              need_wlibio=no
1213          fi
1214       fi
1215       ;;
1216     xstdio | x | xno | xnone | xyes)
1217       # default
1218       CSTDIO_H=config/io/c_io_stdio.h
1219       BASIC_FILE_H=config/io/basic_file_stdio.h
1220       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1221       AC_MSG_RESULT(stdio)
1222
1223       # We're not using stdio.
1224       need_libio=no
1225       need_wlibio=no
1226       ;;
1227     *)
1228       echo "$enable_cstdio is an unknown io package" 1>&2
1229       exit 1
1230       ;;
1231   esac
1232   AC_SUBST(CSTDIO_H)
1233   AC_SUBST(BASIC_FILE_H)
1234   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1235
1236   # 2000-08-04 bkoz hack
1237   CCODECVT_C=config/io/c_io_libio_codecvt.c
1238   AC_SUBST(CCODECVT_C)
1239   # 2000-08-04 bkoz hack
1240
1241   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1242                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1243   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1244   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1245   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1246     libio_la=../libio/libio.la
1247   else
1248     libio_la=
1249   fi
1250   AC_SUBST(libio_la)
1251 ])
1252
1253
1254 dnl
1255 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1256 dnl We must stage the required headers so that they will be installed
1257 dnl with the library (unlike libgcc, the STL implementation is provided
1258 dnl solely within headers).  Since we must not inject random user-space
1259 dnl macro names into user-provided C++ code, we first stage into <file>-in
1260 dnl and process to <file> with an output command.  The reason for a two-
1261 dnl stage process here is to correctly handle $srcdir!=$objdir without
1262 dnl having to write complex code (the sed commands to clean the macro
1263 dnl namespace are complex and fragile enough as it is).  We must also
1264 dnl add a relative path so that -I- is supported properly.
1265 dnl
1266 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1267   AC_MSG_CHECKING([for thread model used by GCC])
1268   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1269   AC_MSG_RESULT([$target_thread_file])
1270
1271   if test $target_thread_file != single; then
1272     AC_DEFINE(HAVE_GTHR_DEFAULT)
1273     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1274   fi
1275
1276   glibcpp_thread_h=gthr-$target_thread_file.h
1277   AC_SUBST(glibcpp_thread_h)
1278 ])
1279
1280
1281 dnl
1282 dnl Check for exception handling support.  If an explicit enable/disable
1283 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1284 dnl target may or may not support call frame exceptions.
1285 dnl
1286 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1287 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1288 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1289 dnl
1290 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1291 dnl
1292 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1293   AC_MSG_CHECKING([for exception model to use])
1294   AC_LANG_SAVE
1295   AC_LANG_CPLUSPLUS
1296   AC_ARG_ENABLE(sjlj-exceptions,
1297   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1298   [:],
1299   [dnl Botheration.  Now we've got to detect the exception model.
1300    dnl Link tests against libgcc.a are problematic since -- at least
1301    dnl as of this writing -- we've not been given proper -L bits for
1302    dnl single-tree newlib and libgloss.
1303    dnl
1304    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1305    dnl conftest files before we got a change to grep them first.
1306    cat > conftest.$ac_ext << EOF
1307 [#]line __oline__ "configure"
1308 struct S { ~S(); };
1309 void bar();
1310 void foo()
1311 {
1312   S s;
1313   bar();
1314 }
1315 EOF
1316    old_CXXFLAGS="$CXXFLAGS"
1317    CXXFLAGS=-S
1318    if AC_TRY_EVAL(ac_compile); then
1319      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1320        enable_sjlj_exceptions=yes
1321      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1322        enable_sjlj_exceptions=no
1323      fi
1324    fi
1325    CXXFLAGS="$old_CXXFLAGS"
1326    rm -f conftest*])
1327    if test x$enable_sjlj_exceptions = xyes; then
1328      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1329         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1330      ac_exception_model_name=sjlj
1331    elif test x$enable_sjlj_exceptions = xno; then
1332      ac_exception_model_name="call frame"
1333    else
1334      AC_MSG_ERROR([unable to detect exception model])
1335    fi
1336    AC_LANG_RESTORE
1337    AC_MSG_RESULT($ac_exception_model_name)
1338 ])
1339
1340
1341 dnl
1342 dnl Check for ISO/IEC 9899:1999 "C99" support.
1343 dnl
1344 dnl GLIBCPP_ENABLE_C99
1345 dnl --enable-c99 defines _GLIBCPP_USE_C99
1346 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1347 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1348 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1349 dnl       defaults to `no'.
1350 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1351 dnl
1352 dnl GLIBCPP_ENABLE_C99
1353 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1354   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1355
1356   AC_ARG_ENABLE(c99,
1357   changequote(<<, >>)dnl
1358   <<--enable-c99            turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1359   changequote([, ])dnl
1360   [case "$enableval" in
1361    yes) enable_c99=yes ;;
1362    no)  enable_c99=no ;;
1363    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1364    esac],
1365   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1366
1367   AC_LANG_SAVE
1368   AC_LANG_CPLUSPLUS
1369
1370   # Check for the existence of <math.h> functions used if C99 is enabled.
1371   ac_c99_math=yes;
1372   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1373   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1374   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1375   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1376   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1377   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1378   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1379   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1380   AC_TRY_COMPILE([#include <math.h>],
1381                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1382   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1383   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1384   AC_TRY_COMPILE([#include <math.h>],
1385                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1386   AC_TRY_COMPILE([#include <math.h>],
1387                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1388   AC_MSG_RESULT($ac_c99_math)
1389
1390   # Check for the existence in <stdio.h> of vscanf, et. al.
1391   ac_c99_stdio=yes;
1392   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1393   AC_TRY_COMPILE([#include <stdio.h>],
1394                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
1395   AC_TRY_COMPILE([#include <stdio.h>
1396                   #include <stdarg.h>
1397                   void foo(char* fmt, ...)
1398                   {va_list args; va_start(args, fmt);
1399                   vfscanf(stderr, "%i", args);}],
1400                   [],, [ac_c99_stdio=no])
1401   AC_TRY_COMPILE([#include <stdio.h>
1402                   #include <stdarg.h>
1403                   void foo(char* fmt, ...)
1404                   {va_list args; va_start(args, fmt);
1405                   vscanf("%i", args);}],
1406                   [],, [ac_c99_stdio=no])
1407   AC_TRY_COMPILE([#include <stdio.h>
1408                   #include <stdarg.h>
1409                   void foo(char* fmt, ...)
1410                   {va_list args; va_start(args, fmt);
1411                   vsnprintf(fmt, 0, "%i", args);}],
1412                   [],, [ac_c99_stdio=no])
1413   AC_TRY_COMPILE([#include <stdio.h>
1414                   #include <stdarg.h>
1415                   void foo(char* fmt, ...)
1416                   {va_list args; va_start(args, fmt);
1417                   vsscanf(fmt, "%i", args);}],
1418                   [],, [ac_c99_stdio=no])
1419   AC_MSG_RESULT($ac_c99_stdio)
1420
1421   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1422   ac_c99_stdlib=yes;
1423   AC_MSG_CHECKING([for lldiv_t declaration])
1424   AC_CACHE_VAL(ac_c99_lldiv_t, [
1425   AC_TRY_COMPILE([#include <stdlib.h>],
1426                    [ lldiv_t mydivt;],
1427                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1428   ])
1429   AC_MSG_RESULT($ac_c99_lldiv_t)
1430
1431   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1432   AC_TRY_COMPILE([#include <stdlib.h>],
1433                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
1434   AC_TRY_COMPILE([#include <stdlib.h>],
1435                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
1436   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1437   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1438   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1439   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
1440   if test x"$ac_c99_lldiv_t" = x"no"; then
1441     ac_c99_stdlib=no;
1442   fi;
1443   AC_MSG_RESULT($ac_c99_stdlib)
1444
1445   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1446   # XXX the wchar.h checks should be rolled into the general C99 bits.
1447   ac_c99_wchar=yes;
1448   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
1449   AC_TRY_COMPILE([#include <wchar.h>],
1450                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1451   AC_TRY_COMPILE([#include <wchar.h>],
1452                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1453   AC_TRY_COMPILE([#include <wchar.h>],
1454                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1455   AC_MSG_RESULT($ac_c99_wchar)
1456
1457   AC_MSG_CHECKING([for enabled ISO C99 support])
1458   if test x"$ac_c99_math" = x"no" ||
1459      test x"$ac_c99_stdio" = x"no" ||
1460      test x"$ac_c99_stdlib" = x"no" ||
1461      test x"$ac_c99_wchar" = x"no"; then
1462     enable_c99=no;
1463   fi;
1464   AC_MSG_RESULT($enable_c99)
1465
1466   # Option parsed, now set things appropriately
1467   if test x"$enable_c99" = x"yes"; then
1468     AC_DEFINE(_GLIBCPP_USE_C99)
1469   fi
1470
1471   AC_LANG_RESTORE
1472 ])
1473
1474
1475 dnl
1476 dnl Check for template specializations for the 'long long' type extension.
1477 dnl The result determines only whether 'long long' I/O is enabled; things
1478 dnl like numeric_limits<> specializations are always available.
1479 dnl
1480 dnl GLIBCPP_ENABLE_LONG_LONG
1481 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1482 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1483 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1484 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1485 dnl       defaults to `no'.
1486 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1487 dnl
1488 dnl GLIBCPP_ENABLE_LONG_LONG
1489 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1490   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1491
1492   AC_ARG_ENABLE(long-long,
1493   changequote(<<, >>)dnl
1494   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1495   changequote([, ])dnl
1496   [case "$enableval" in
1497    yes) enable_long_long=yes ;;
1498    no)  enable_long_long=no ;;
1499    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1500    esac],
1501   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1502
1503   AC_LANG_SAVE
1504   AC_LANG_CPLUSPLUS
1505
1506   AC_MSG_CHECKING([for enabled long long I/O support])
1507   # iostreams require strtoll, strtoull to compile
1508   AC_TRY_COMPILE([#include <stdlib.h>],
1509                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1510   AC_TRY_COMPILE([#include <stdlib.h>],
1511                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1512
1513   # Option parsed, now set things appropriately
1514   if test x"$enable_long_long" = xyes; then
1515     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1516   fi
1517   AC_MSG_RESULT($enable_long_long)
1518
1519   AC_LANG_RESTORE
1520 ])
1521
1522
1523 dnl
1524 dnl Check for what kind of C headers to use.
1525 dnl
1526 dnl GLIBCPP_ENABLE_CHEADERS
1527 dnl --enable-cheaders= [does stuff].
1528 dnl --disable-cheaders [does not do anything, really].
1529 dnl  +  This will eventually need to be 'c_shadow' by default.
1530 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1531 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1532 dnl       If ommitted, it defaults to `c_std'.
1533 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1534 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1535 AC_MSG_CHECKING([for c header strategy to use])
1536 AC_ARG_ENABLE(cheaders,
1537 changequote(<<, >>)dnl
1538 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1539 changequote([, ])
1540   [case "$enableval" in
1541    c)
1542         enable_cheaders=c
1543         ;;
1544    c_std)
1545         enable_cheaders=c_std
1546         ;;
1547    c_shadow)
1548         enable_cheaders=c_shadow
1549         ;;
1550    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1551         ;;
1552   esac],
1553   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1554   AC_MSG_RESULT($enable_cheaders)
1555
1556   dnl Option parsed, now set things appropriately
1557   case "$enable_cheaders" in
1558     c_shadow)
1559         CSHADOW_FLAGS="-fno-builtin"
1560         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_shadow'
1561         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1562         ;;
1563     c_std)
1564         CSHADOW_FLAGS=""
1565         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c_std'
1566         ;;
1567     c)
1568         CSHADOW_FLAGS=""
1569         C_INCLUDE_DIR='${glibcpp_srcdir}/include/c'
1570         ;;
1571   esac
1572
1573   AC_SUBST(CSHADOW_FLAGS)
1574   AC_SUBST(C_INCLUDE_DIR)
1575   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cheaders" = c_shadow)
1576 ])
1577
1578
1579 dnl
1580 dnl Check for wide character support.  Has the same effect as the option
1581 dnl in gcc's configure, but in a form that autoconf can mess with.
1582 dnl
1583 dnl GLIBCPP_ENABLE_C_MBCHAR
1584 dnl --enable-c-mbchar requests all the wchar_t stuff.
1585 dnl --disable-c-mbchar doesn't.
1586 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1587 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1588 dnl       defaults to `no'.
1589 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1590 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1591 AC_ARG_ENABLE(c-mbchar,
1592 changequote(<<, >>)dnl
1593 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1594 changequote([, ])dnl
1595 [case "$enableval" in
1596  yes) enable_c_mbchar=yes ;;
1597  no)  enable_c_mbchar=no ;;
1598  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1599  esac],
1600 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1601 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1602 ])
1603
1604
1605 dnl
1606 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1607 dnl
1608 dnl TOPLEVEL_INCLUDES
1609 dnl LIBMATH_INCLUDES
1610 dnl LIBSUPCXX_INCLUDES
1611 dnl LIBIO_INCLUDES
1612 dnl CSHADOW_INCLUDES
1613 dnl
1614 dnl GLIBCPP_EXPORT_INCLUDES
1615 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1616   # Root level of the build directory include sources.
1617   GLIBCPP_INCLUDES="-I${glibcpp_builddir}/include/${target_alias} -I${glibcpp_builddir}/include"
1618
1619   # Passed down for canadian crosses.
1620   if test x"$CANADIAN" = xyes; then
1621     TOPLEVEL_INCLUDES='-I$(includedir)'
1622   fi
1623
1624   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1625
1626   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1627
1628   if test x"$need_libio" = xyes; then
1629     LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1630     AC_SUBST(LIBIO_INCLUDES)
1631   fi
1632
1633   # Now, export this to all the little Makefiles....
1634   AC_SUBST(GLIBCPP_INCLUDES)
1635   AC_SUBST(TOPLEVEL_INCLUDES)
1636   AC_SUBST(LIBMATH_INCLUDES)
1637   AC_SUBST(LIBSUPCXX_INCLUDES)
1638 ])
1639
1640
1641 dnl
1642 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1643 dnl
1644 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1645   # Optimization flags that are probably a good idea for thrill-seekers. Just
1646   # uncomment the lines below and make, everything else is ready to go...
1647   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1648   OPTIMIZE_CXXFLAGS=
1649   AC_SUBST(OPTIMIZE_CXXFLAGS)
1650
1651   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1652   AC_SUBST(WARN_FLAGS)
1653 ])
1654
1655 dnl
1656 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1657 dnl  calculates gxx_install_dir
1658 dnl  exports glibcpp_toolexecdir
1659 dnl  exports glibcpp_toolexeclibdir
1660 dnl  exports glibcpp_prefixdir
1661 dnl
1662 dnl Assumes cross_compiling bits already done, and with_cross_host in
1663 dnl particular
1664 dnl
1665 dnl GLIBCPP_EXPORT_INSTALL_INFO
1666 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1667 # Assumes glibcpp_builddir, glibcpp_srcdir are alreay set up and
1668 # exported correctly in GLIBCPP_CONFIGURE.
1669 glibcpp_toolexecdir=no
1670 glibcpp_toolexeclibdir=no
1671 glibcpp_prefixdir=${prefix}
1672
1673 AC_MSG_CHECKING([for interface version number])
1674 libstdcxx_interface=$INTERFACE
1675 AC_MSG_RESULT($libstdcxx_interface)
1676
1677 # Process the option --with-gxx-include-dir=<path to include-files directory>
1678 AC_MSG_CHECKING([for --with-gxx-include-dir])
1679 AC_ARG_WITH(gxx-include-dir,
1680 [  --with-gxx-include-dir  the installation directory for include files],
1681 [case "${withval}" in
1682   yes)
1683     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1684     gxx_include_dir=no
1685     ;;
1686   no)
1687     gxx_include_dir=no
1688     ;;
1689   *)
1690     gxx_include_dir=${withval}
1691     ;;
1692 esac], [gxx_include_dir=no])
1693 AC_MSG_RESULT($gxx_include_dir)
1694
1695 # Process the option "--enable-version-specific-runtime-libs"
1696 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1697 AC_ARG_ENABLE(version-specific-runtime-libs,
1698 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1699 [case "$enableval" in
1700  yes) version_specific_libs=yes ;;
1701  no)  version_specific_libs=no ;;
1702  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
1703  esac],
1704 version_specific_libs=no)dnl
1705 # Option set, now we can test it.
1706 AC_MSG_RESULT($version_specific_libs)
1707
1708 if test $version_specific_libs = yes; then
1709   # Need the gcc compiler version to know where to install libraries
1710   # and header files if --enable-version-specific-runtime-libs option
1711   # is selected.
1712   changequote(,)dnl
1713   gcc_version_trigger=${srcdir}/../gcc/version.c
1714   gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1715   gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1716   gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1717   glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1718   glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1719   changequote([,])dnl
1720 fi
1721
1722 # Default case for install directory for include files.
1723 if test $version_specific_libs = no &&
1724    test $gxx_include_dir = no; then
1725   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1726 fi
1727
1728 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1729 # Install a library built with a cross compiler in tooldir, not libdir.
1730 if test x"$glibcpp_toolexecdir" = x"no"; then
1731   if test -n "$with_cross_host" &&
1732      test x"$with_cross_host" != x"no"; then
1733     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1734     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1735   else
1736     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1737     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1738   fi
1739 fi
1740
1741 AC_MSG_CHECKING([for install location])
1742 AC_MSG_RESULT($gxx_include_dir)
1743
1744 AC_SUBST(glibcpp_prefixdir)
1745 AC_SUBST(gxx_include_dir)
1746 AC_SUBST(glibcpp_toolexecdir)
1747 AC_SUBST(glibcpp_toolexeclibdir)
1748 ])
1749
1750
1751 # Check for functions in math library.
1752 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1753 #
1754 # This file can be copied and used freely without restrictions.  It can
1755 # be used in projects which are not available under the GNU Public License
1756 # but which still want to provide support for the GNU gettext functionality.
1757 # Please note that the actual code is *not* freely available.
1758
1759 # serial 1
1760
1761 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1762 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1763 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1764 AC_SUBST(LIBMATHOBJS)dnl
1765 ])
1766
1767
1768
1769 dnl This macro searches for a GNU version of make.  If a match is found, the
1770 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1771 dnl set to "#". This is useful for  including a special features in a Makefile,
1772 dnl which cannot be handled by other versions of make.  The variable
1773 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1774 dnl the empty string otherwise.
1775 dnl
1776 dnl Here is an example of its use:
1777 dnl
1778 dnl Makefile.in might contain:
1779 dnl
1780 dnl     # A failsafe way of putting a dependency rule into a makefile
1781 dnl     $(DEPEND):
1782 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1783 dnl
1784 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1785 dnl     @ifGNUmake@ include $(DEPEND)
1786 dnl     @ifGNUmake@ endif
1787 dnl
1788 dnl Then configure.in would normally contain:
1789 dnl
1790 dnl     CHECK_GNU_MAKE()
1791 dnl     AC_OUTPUT(Makefile)
1792 dnl
1793 dnl Then perhaps to cause gnu make to override any other make, we could do
1794 dnl something like this (note that GNU make always looks for GNUmakefile first):
1795 dnl
1796 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1797 dnl             mv Makefile GNUmakefile
1798 dnl             echo .DEFAULT: > Makefile ;
1799 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1800 dnl     fi
1801 dnl
1802 dnl Then, if any (well almost any) other make is called, and GNU make also
1803 dnl exists, then the other make wraps the GNU make.
1804 dnl
1805 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1806 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1807 dnl
1808 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1809 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1810 dnl #### conditional's subshell (" --version" is not a command), using a
1811 dnl #### different option to grep(1).
1812 dnl #### -pme
1813 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1814 dnl #### ${MAKE:-make}).
1815 dnl #### -msokolov
1816 AC_DEFUN(
1817   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1818           _cv_gnu_make_command='' ;
1819 dnl Search all the common names for GNU make
1820           for a in "${MAKE-make}" make gmake gnumake ; do
1821                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1822                   then
1823                           _cv_gnu_make_command=$a ;
1824                           break;
1825                   fi
1826           done ;
1827   ) ;
1828 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1829 dnl string, '#' otherwise
1830   if test  "x$_cv_gnu_make_command" != "x"  ; then
1831           ifGNUmake='' ;
1832   else
1833           ifGNUmake='#' ;
1834   fi
1835   AC_SUBST(ifGNUmake)
1836 ])
1837
1838
1839 dnl Check for headers for, and arguments to, the setrlimit() function.
1840 dnl Used only in testsuite_hooks.h.
1841 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT_ancilliary, [
1842   AC_TRY_COMPILE([#include <sys/resource.h>
1843                   #include <unistd.h>
1844                  ], [ int f = RLIMIT_$1 ; ],
1845                  [glibcpp_mresult=1], [glibcpp_mresult=0])
1846   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcpp_mresult,
1847                      [Only used in build directory testsuite_hooks.h.])
1848 ])
1849 AC_DEFUN(GLIBCPP_CHECK_SETRLIMIT, [
1850   setrlimit_have_headers=yes
1851   AC_CHECK_HEADERS(sys/resource.h unistd.h,
1852                    [],
1853                    setrlimit_have_headers=no)
1854   # If don't have the headers, then we can't run the tests now, and we
1855   # won't be seeing any of these during testsuite compilation.
1856   if test $setrlimit_have_headers = yes; then
1857     # Can't do these in a loop, else the resulting syntax is wrong.
1858     GLIBCPP_CHECK_SETRLIMIT_ancilliary(DATA)
1859     GLIBCPP_CHECK_SETRLIMIT_ancilliary(RSS)
1860     GLIBCPP_CHECK_SETRLIMIT_ancilliary(VMEM)
1861     GLIBCPP_CHECK_SETRLIMIT_ancilliary(AS)
1862
1863     # Check for rlimit, setrlimit.
1864     AC_CACHE_VAL(ac_setrlimit, [
1865       AC_TRY_COMPILE([#include <sys/resource.h>
1866                       #include <unistd.h>
1867                      ],
1868                      [ struct rlimit r; setrlimit(0, &r);],
1869                      [ac_setrlimit=yes], [ac_setrlimit=no])
1870     ])
1871   fi
1872
1873   AC_MSG_CHECKING([for testsuite memory limit support])
1874   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
1875     ac_mem_limits=yes
1876     AC_DEFINE(_GLIBCPP_MEM_LIMITS)
1877   else
1878     ac_mem_limits=no
1879   fi
1880   AC_MSG_RESULT($ac_mem_limits)
1881 ])
1882
1883
1884 dnl
1885 dnl Does any necessary configuration of the testsuite directory.  Generates
1886 dnl the testsuite_hooks.h header.
1887 dnl
1888 dnl GLIBCPP_CONFIGURE_TESTSUITE  [no args]
1889 AC_DEFUN(GLIBCPP_CONFIGURE_TESTSUITE, [
1890   GLIBCPP_CHECK_SETRLIMIT
1891 ])
1892
1893
1894 sinclude(../libtool.m4)
1895 dnl The lines below arrange for aclocal not to bring an installed
1896 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1897 dnl add a definition of LIBTOOL to Makefile.in.
1898 ifelse(,,,[AC_SUBST(LIBTOOL)
1899 AC_DEFUN([AM_PROG_LIBTOOL])
1900 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1901 AC_DEFUN([AC_PROG_LD])
1902 ])
1903
1904
1905 # Check whether LC_MESSAGES is available in <locale.h>.
1906 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1907 #
1908 # This file file be copied and used freely without restrictions.  It can
1909 # be used in projects which are not available under the GNU Public License
1910 # but which still want to provide support for the GNU gettext functionality.
1911 # Please note that the actual code is *not* freely available.
1912
1913 # serial 1
1914
1915 AC_DEFUN(AC_LC_MESSAGES, [
1916   AC_CHECK_HEADER(locale.h, [
1917     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1918       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1919        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1920     if test $ac_cv_val_LC_MESSAGES = yes; then
1921       AC_DEFINE(HAVE_LC_MESSAGES)
1922     fi
1923   ])
1924 ])
1925
1926
1927 dnl
1928 dnl Check for whether the Boost-derived checks should be turned on.
1929 dnl
1930 dnl GLIBCPP_ENABLE_CONCEPT_CHECKS
1931 dnl --enable-concept-checks turns them on.
1932 dnl --disable-concept-checks leaves them off.
1933 dnl  +  Usage:  GLIBCPP_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1934 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1935 dnl       defaults to `no'.
1936 AC_DEFUN(GLIBCPP_ENABLE_CONCEPT_CHECKS, [dnl
1937 define([GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT], ifelse($1, yes, yes, no))dnl
1938 AC_ARG_ENABLE(concept-checks,
1939 changequote(<<, >>)dnl
1940 <<  --enable-concept-checks use Boost-derived template checks [default=>>GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT],
1941 changequote([, ])dnl
1942 [case "$enableval" in
1943  yes) enable_concept_checks=yes ;;
1944  no)  enable_concept_checks=no ;;
1945  *)   AC_MSG_ERROR([Unknown argument to enable/disable concept checks]) ;;
1946  esac],
1947 enable_concept_checks=GLIBCPP_ENABLE_CONCEPT_CHECKS_DEFAULT)dnl
1948 dnl Option parsed, now set things appropriately
1949 if test x"$enable_concept_checks" = xyes; then
1950   AC_DEFINE(_GLIBCPP_CONCEPT_CHECKS)
1951 fi
1952 ])
1953
1954