OSDN Git Service

Fix for Homebrew. I don't care about another environments. This may be reverted and...
[pf3gnuchains/gcc-fork.git] / libquadmath / configure.ac
1 # Process this file with autoconf to produce a configure script, like so:
2 # aclocal && autoconf && autoheader && automake
3
4 AC_PREREQ(2.64)
5 AC_INIT([GCC Quad-precision Math Library], 0.1,,[libquadmath])
6 AC_CONFIG_HEADER(config.h)
7
8 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
9 #
10 # You will slowly go insane if you do not grok the following fact:  when
11 # building this library, the top-level /target/ becomes the library's /host/.
12 #
13 # configure then causes --target to default to --host, exactly like any
14 # other package using autoconf.  Therefore, 'target' and 'host' will
15 # always be the same.  This makes sense both for native and cross compilers
16 # just think about it for a little while.  :-)
17 #
18 # Also, if this library is being configured as part of a cross compiler, the
19 # top-level configure script will pass the "real" host as $with_cross_host.
20 #
21 # Do not delete or change the following two lines.  For why, see
22 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
23 AC_CANONICAL_SYSTEM
24 ACX_NONCANONICAL_TARGET
25
26 target_alias=${target_alias-$host_alias}
27 AC_SUBST(target_alias)
28
29 AM_INIT_AUTOMAKE([1.9.0 foreign subdir-objects no-dist -Wall -Wno-override -Werror])
30
31 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
32 AC_ARG_ENABLE(version-specific-runtime-libs,
33 AS_HELP_STRING([--enable-version-specific-runtime-libs],
34  [specify that runtime libraries should be installed in a compiler-specific directory]),
35 [case "$enableval" in
36  yes) version_specific_libs=yes ;;
37  no)  version_specific_libs=no ;;
38  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
39  esac],
40 [version_specific_libs=no])
41 AC_MSG_RESULT($version_specific_libs)
42
43 GCC_NO_EXECUTABLES
44
45 AC_USE_SYSTEM_EXTENSIONS
46
47 # See if makeinfo has been installed and is modern enough
48 # that we can use it.
49 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
50                    [GNU texinfo.* \([0-9][0-9.]*\)],
51                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
52 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
53
54 ACX_BUGURL([http://gcc.gnu.org/bugs.html])
55
56 # Configure libtool
57 AM_PROG_LIBTOOL
58 ACX_LT_HOST_FLAGS
59 AC_SUBST(enable_shared)
60 AC_SUBST(enable_static)
61
62 AM_MAINTAINER_MODE
63 AM_ENABLE_MULTILIB(, ..)
64
65 AC_LANG_C
66 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
67 # We must force CC to /not/ be precious variables; otherwise
68 # the wrong, non-multilib-adjusted value will be used in multilibs.
69 # As a side effect, we have to subst CFLAGS ourselves.
70
71 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
72 m4_define([_AC_ARG_VAR_PRECIOUS],[])
73 AC_PROG_CC
74 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
75
76 AC_SUBST(CFLAGS)
77
78 AM_PROG_CC_C_O
79
80 if test "x$GCC" != "xyes"; then
81   AC_MSG_ERROR([libquadmath must be built with GCC])
82 fi
83 AC_PROG_CPP
84
85 # Calculate toolexeclibdir
86 # Also toolexecdir, though it's only used in toolexeclibdir
87 case ${version_specific_libs} in
88   yes)
89     # Need the gcc compiler version to know where to install libraries
90     # and header files if --enable-version-specific-runtime-libs option
91     # is selected.
92     toolexecdir='$(libdir)/gcc/$(target_alias)'
93     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
94     ;;
95   no)
96     if test -n "$with_cross_host" &&
97        test x"$with_cross_host" != x"no"; then
98       # Install a library built with a cross compiler in tooldir, not libdir.
99       toolexecdir='$(exec_prefix)/$(target_alias)'
100       toolexeclibdir='$(toolexecdir)/lib'
101     else
102       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
103       toolexeclibdir='$(libdir)'
104     fi
105     multi_os_directory=`$CC -print-multi-os-directory`
106     case $multi_os_directory in
107       .) ;; # Avoid trailing /.
108       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
109     esac
110     ;;
111 esac
112 AC_SUBST(toolexecdir)
113 AC_SUBST(toolexeclibdir)
114
115 AC_CHECK_HEADERS(fenv.h langinfo.h locale.h wchar.h wctype.h limits.h ctype.h printf.h errno.h)
116
117 # If available, sqrtl and cbrtl speed up the calculation -
118 # but they are not required
119 if test x$gcc_no_link != xyes; then
120   AC_CHECK_LIB([m],[sqrtl],[AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])])
121   AC_CHECK_LIB([m],[cbrtl],[AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])])
122   AC_CHECK_LIB([m],[feholdexcept],[AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])])
123   AC_CHECK_LIB([m],[fesetround],[AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])])
124   AC_CHECK_LIB([m],[feupdateenv],[AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])])
125   AC_CHECK_LIB([m],[fesetenv],[AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])])
126   AC_CHECK_LIB([m],[fetestexcept],[AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])])
127   AC_CHECK_FUNCS(strtoull)
128 else
129   if test "x$ac_cv_lib_m_sqrtl" = x""yes; then
130     AC_DEFINE([HAVE_SQRTL],[1],[libm includes sqrtl])  
131   fi
132   if test "x$ac_cv_lib_m_cbrtl" = x""yes; then
133     AC_DEFINE([HAVE_CBRTL],[1],[libm includes cbrtl])  
134   fi
135   if test "x$ac_cv_lib_m_feholdexcept" = x""yes; then
136     AC_DEFINE([HAVE_FEHOLDEXCEPT],[1],[libm includes feholdexcept])
137   fi
138   if test "x$ac_cv_lib_m_fesetround" = x""yes; then
139     AC_DEFINE([HAVE_FESETROUND],[1],[libm includes fesetround])
140   fi
141   if test "x$ac_cv_lib_m_feupdateenv" = x""yes; then
142     AC_DEFINE([HAVE_FEUPDATEENV],[1],[libm includes feupdateenv])
143   fi
144   if test "x$ac_cv_lib_m_fesetenv" = x""yes; then
145     AC_DEFINE([HAVE_FESETENV],[1],[libm includes fesetenv])
146   fi
147   if test "x$ac_cv_lib_m_fetestexcept" = x""yes; then
148     AC_DEFINE([HAVE_FETESTEXCEPT],[1],[libm includes fetestexcept])
149   fi
150 fi
151
152 # Check for hidden visibility (copied from libssp).
153 saved_CFLAGS="$CFLAGS"
154 CFLAGS="$CFLAGS -Werror"
155 AC_MSG_CHECKING([whether hidden visibility is supported])
156 AC_TRY_COMPILE([
157 void __attribute__((visibility ("hidden"))) bar (void) {}],,
158 [quadmath_hidden=yes],[quadmath_hidden=no])
159 AC_MSG_RESULT($quadmath_hidden)
160 if test x$quadmath_hidden = xyes; then
161   AC_DEFINE([HAVE_HIDDEN_VISIBILITY],[1],[__attribute__((visibility ("hidden"))) supported])
162 fi
163 CFLAGS="$saved_CFLAGS"
164
165 # Check for symbol versioning (copied from libssp).
166 AC_MSG_CHECKING([whether symbol versioning is supported])
167 AC_ARG_ENABLE(symvers,
168 AS_HELP_STRING([--disable-symvers],
169   [disable symbol versioning for libquadmath]),
170 quadmath_use_symver=$enableval,
171 quadmath_use_symver=yes)
172 if test "x$quadmath_use_symver" = xyes; then
173   if test x$gcc_no_link = xyes; then
174     # If we cannot link, we cannot build shared libraries, so do not use
175     # symbol versioning.
176     quadmath_use_symver=no
177   else
178     save_LDFLAGS="$LDFLAGS"
179     LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
180     cat > conftest.map <<EOF
181 FOO_1.0 {
182   global: *foo*; bar; local: *;
183 };
184 EOF
185     AC_TRY_LINK([int foo;],[],[quadmath_use_symver=gnu],[quadmath_use_symver=no])
186     if test x$quadmath_use_symver = xno; then
187       case "$target_os" in
188         solaris2*)
189           LDFLAGS="$save_LDFLAGS"
190           LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
191           # Sun ld cannot handle wildcards and treats all entries as undefined.
192           cat > conftest.map <<EOF
193 FOO_1.0 {
194   global: foo; local: *;
195 };
196 EOF
197           AC_TRY_LINK([int foo;],[],[quadmath_use_symver=sun],[quadmath_use_symver=no])
198           ;;
199       esac
200     fi
201     LDFLAGS="$save_LDFLAGS"
202   fi
203 fi
204 AC_MSG_RESULT($quadmath_use_symver)
205 AM_CONDITIONAL(LIBQUAD_USE_SYMVER, [test "x$quadmath_use_symver" != xno])
206 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_GNU, [test "x$quadmath_use_symver" = xgnu])
207 AM_CONDITIONAL(LIBQUAD_USE_SYMVER_SUN, [test "x$quadmath_use_symver" = xsun])
208
209 AC_CACHE_CHECK([whether __float128 is supported], [libquad_cv_have_float128],
210   [GCC_TRY_COMPILE_OR_LINK([
211     typedef _Complex float __attribute__((mode(TC))) __complex128;
212
213     __float128 foo (__float128 x)
214     {
215
216      __complex128 z1, z2;
217
218      z1 = x;
219      z2 = x / 7.Q;
220      z2 /= z1;
221
222      return (__float128) z2;
223     }
224
225     __float128 bar (__float128 x)
226     {
227       return x * __builtin_huge_valq ();
228     }
229   ],[
230     foo (1.2Q);
231     bar (1.2Q);
232   ],[
233     libquad_cv_have_float128=yes
234   ],[
235     libquad_cv_have_float128=no
236 ])])
237 AM_CONDITIONAL(BUILD_LIBQUADMATH, [test "x$libquad_cv_have_float128" = xyes])
238
239 # Check for printf hook support.
240 AC_MSG_CHECKING([whether printf hooks are supported])
241 AC_TRY_COMPILE([
242 #include <printf.h>
243 #include <stdarg.h>
244 #include <stdlib.h>
245 extern void flt128_va (void *, va_list *);
246 extern int flt128_ais (const struct printf_info *, size_t, int *, int *);
247 extern int flt128_printf_fp (FILE *, const struct printf_info *, const void *const *);
248 ],[
249 int pa_flt128 = register_printf_type (flt128_va);
250 int mod_Q = register_printf_modifier (L"Q");
251 int res = register_printf_specifier ('f', flt128_printf_fp, flt128_ais);
252 struct printf_info info = { .user = -1 };
253 ],
254 [quadmath_printf_hooks=yes],[quadmath_printf_hooks=no])
255 AC_MSG_RESULT($quadmath_printf_hooks)
256 if test x$quadmath_printf_hooks = xyes; then
257   AC_DEFINE([HAVE_PRINTF_HOOKS],[1],[GNU C Library stype printf hooks supported])
258 fi
259
260 # Check for whether locale support for quadmath_snprintf or Q printf hooks
261 # should be provided.
262 AC_MSG_CHECKING([whether nl_langinfo should be used])
263 AC_TRY_COMPILE([#include <langinfo.h>],[
264 const char *s;
265 s = nl_langinfo (DECIMAL_POINT);
266 s = nl_langinfo (MON_DECIMAL_POINT);
267 s = nl_langinfo (GROUPING);
268 s = nl_langinfo (MON_GROUPING);
269 s = nl_langinfo (THOUSANDS_SEP);
270 s = nl_langinfo (MON_THOUSANDS_SEP);
271 (void) s;
272 ],
273 [quadmath_use_nl_langinfo=yes],[quadmath_use_nl_langinfo=no])
274 AC_MSG_RESULT($quadmath_use_nl_langinfo)
275 if test x$quadmath_use_nl_langinfo = xyes; then
276   AC_DEFINE([USE_NL_LANGINFO],[1],[whether nl_langinfo should be used])
277 fi
278
279 AC_MSG_CHECKING([whether nl_langinfo should be used for wide char locale info])
280 AC_TRY_COMPILE([#include <langinfo.h>],[
281 const char *s;
282 s = nl_langinfo (_NL_NUMERIC_DECIMAL_POINT_WC);
283 s = nl_langinfo (_NL_MONETARY_DECIMAL_POINT_WC);
284 s = nl_langinfo (_NL_NUMERIC_THOUSANDS_SEP_WC);
285 s = nl_langinfo (_NL_MONETARY_THOUSANDS_SEP_WC);
286 (void) s;
287 ],
288 [quadmath_use_nl_langinfo_wc=yes],[quadmath_use_nl_langinfo_wc=no])
289 AC_MSG_RESULT($quadmath_use_nl_langinfo_wc)
290 if test x$quadmath_use_nl_langinfo_wc = xyes; then
291   AC_DEFINE([USE_NL_LANGINFO_WC],[1],[whether nl_langinfo should be used for wide char locale info])
292 fi
293
294 AC_MSG_CHECKING([whether localeconv should be used])
295 AC_TRY_COMPILE([#include <locale.h>],[
296 const struct lconv *l = localeconv ();
297 const char *s;
298 s = l->decimal_point;
299 s = l->mon_decimal_point;
300 s = l->grouping;
301 s = l->mon_grouping;
302 s = l->thousands_sep;
303 s = l->mon_thousands_sep;
304 (void) s;
305 ],
306 [quadmath_use_localeconv=yes],[quadmath_use_localeconv=no])
307 AC_MSG_RESULT($quadmath_use_localeconv)
308 if test x$quadmath_use_localeconv = xyes; then
309   AC_DEFINE([USE_LOCALECONV],[1],[whether localeconv should be used])
310 fi
311
312 # Check for whether i18n number rewriting support for quadmath_snprintf
313 # or Q printf hooks should be provided.
314 AC_MSG_CHECKING([whether i18n number rewriting support for quadmath_snprintf should be added])
315 AC_TRY_COMPILE([#include <langinfo.h>
316 #include <limits.h>
317 #include <string.h>
318 #include <wchar.h>
319 #include <wctype.h>],[
320 const char *s;
321 char decimal[MB_LEN_MAX];
322 wctrans_t map = wctrans ("to_outpunct");
323 wint_t wdecimal = towctrans (L'.', map);
324 mbstate_t state;
325 memset (&state, '\0', sizeof (state));
326 wcrtomb (decimal, wdecimal, &state);
327 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
328 s = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
329 s = nl_langinfo (_NL_CTYPE_MB_CUR_MAX);
330 (void) s;
331 ],
332 [quadmath_use_i18n_number_h=yes],[quadmath_use_i18n_number_h=no])
333 AC_MSG_RESULT($quadmath_use_i18n_number_h)
334 if test x$quadmath_use_i18n_number_h = xyes; then
335   AC_DEFINE([USE_I18N_NUMBER_H],[1],[whether i18n number rewriting can be supported])
336 fi
337
338 AC_CACHE_SAVE
339
340 if test ${multilib} = yes; then
341   multilib_arg="--enable-multilib"
342 else
343   multilib_arg=
344 fi
345
346
347 # We would like our source tree to be readonly. However when releases or
348 # pre-releases are generated, the flex/bison generated files as well as the
349 # various formats of manuals need to be included along with the rest of the
350 # sources.  Therefore we have --enable-generated-files-in-srcdir to do 
351 # just that.
352 AC_MSG_CHECKING(generated-files-in-srcdir)
353 AC_ARG_ENABLE(generated-files-in-srcdir,
354 AS_HELP_STRING([--enable-generated-files-in-srcdir],
355  [put copies of generated files in source dir intended for creating source tarballs for users without texinfo bison or flex]),
356 [case "$enableval" in
357  yes) enable_generated_files_in_srcdir=yes ;;
358  no)  enable_generated_files_in_srcdir=no ;;
359  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
360  esac],
361 [enable_generated_files_in_srcdir=no])
362 AC_MSG_RESULT($enable_generated_files_in_srcdir)
363 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
364
365
366 AC_CONFIG_FILES(Makefile)
367 AC_OUTPUT