OSDN Git Service

* Fix for g++/15861
[pf3gnuchains/gcc-fork.git] / libmudflap / configure.ac
1 # Process this file with autoconf to produce a configure script, like so:
2 # aclocal && autoconf && autoheader && automake
3
4 AC_PREREQ(2.59)
5 AC_INIT(libmudflap, 1.0)
6 AC_CONFIG_SRCDIR(mf-runtime.c)
7 AC_CANONICAL_SYSTEM
8
9 AM_INIT_AUTOMAKE
10
11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
12 AC_ARG_ENABLE(version-specific-runtime-libs,
13 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
14 [case "$enableval" in
15  yes) version_specific_libs=yes ;;
16  no)  version_specific_libs=no ;;
17  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
18  esac],
19 [version_specific_libs=no])
20 AC_MSG_RESULT($version_specific_libs)
21
22 AM_MAINTAINER_MODE
23 AC_EXEEXT
24
25 AM_ENABLE_MULTILIB(, ..)
26
27 target_alias=${target_alias-$target}
28 AC_SUBST(target_alias)
29
30 AC_CONFIG_HEADERS(config.h)
31
32 AC_LANG_C
33 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
34 # We must force CC to /not/ be precious variables; otherwise
35 # the wrong, non-multilib-adjusted value will be used in multilibs.
36 # As a side effect, we have to subst CFLAGS ourselves.
37
38 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
39 m4_define([_AC_ARG_VAR_PRECIOUS],[])
40 AC_PROG_CC
41 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
42
43 AC_SUBST(CFLAGS)
44
45 if test "x$GCC" != "xyes"; then
46   AC_MSG_ERROR([libmudflap must be built with GCC])
47 fi
48 AC_PROG_CPP
49
50 # Some hosts don't have dlsym(RTLD_NEXT, "symbol") for use in
51 # symbol interposition.  We disable shared libraries for these.
52 AC_MSG_CHECKING([whether dlsym(RTLD_NEXT,...) is available])
53 AC_TRY_COMPILE([
54 #define _GNU_SOURCE
55 #include <dlfcn.h>
56 ],
57 [void *foo = dlsym (RTLD_NEXT, "exit");],
58 [AC_MSG_RESULT(yes)],
59 [AC_MSG_RESULT(no)
60 enable_shared=no])
61
62 AC_CHECK_HEADERS(stdint.h execinfo.h signal.h dlfcn.h dirent.h \
63   netdb.h sys/ipc.h sys/sem.h sys/shm.h sys/wait.h sys/socket.h ctype.h)
64 AC_CHECK_FUNCS(backtrace backtrace_symbols gettimeofday signal)
65
66 dnl Check for 64-bit stdio calls related to Large File Support
67 AC_CHECK_FUNCS(fopen64 fseeko64 ftello64 stat64)
68
69 dnl Check for nonstandard functions
70 AC_CHECK_FUNCS(strnlen memrchr strncpy memmem sethostname)
71
72 dnl Check for glibc ctype functions
73 AC_CHECK_FUNCS(__ctype_b_loc __ctype_tolower_loc __ctype_toupper_loc)
74
75 AC_TRY_COMPILE([#include <sys/types.h>
76 #include <sys/ipc.h>
77 #include <sys/sem.h>],[union semun foo;], [mf_have_semun=1], [mf_have_semun=0])
78 if test $mf_have_semun = 1
79 then
80   AC_DEFINE(HAVE_UNION_SEMUN, 1, [union semun defined in sys/ipc.h or sys/sem.h])
81 fi
82
83
84 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
85 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
86 #include <sys/types.h>
87 #include <sys/socket.h>], [socklen_t x = 5;],
88   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
89    AC_MSG_RESULT(yes)],
90   [AC_MSG_RESULT(no)])
91
92 AC_LIBTOOL_DLOPEN
93 AM_PROG_LIBTOOL
94 AC_SUBST(enable_shared)
95 AC_SUBST(enable_static)
96
97 AC_CHECK_HEADER(stdint.h, [MF_HAVE_STDINT_H=1], [MF_HAVE_STDINT_H=0])
98 AC_SUBST(MF_HAVE_STDINT_H)
99 if test $MF_HAVE_STDINT_H = 1
100 then
101    MF_HAVE_UINTPTR_T=1
102 else
103    AC_TRY_COMPILE([#include <sys/types.h>], [uintptr_t k = 0;],
104         [MF_HAVE_UINTPTR_T=1], [MF_HAVE_UINTPTR_T=0])
105 fi
106 AC_SUBST(MF_HAVE_UINTPTR_T)
107
108 if test ! -d pth
109 then
110   # libmudflapth objects are built in this subdirectory
111   mkdir pth
112 fi
113
114 pthread_create_version='""'
115 AC_CHECK_HEADER(pthread.h,[
116 AC_DEFINE_UNQUOTED(HAVE_PTHREAD_H, 1, [define if you have <pthread.h>])
117 ac_have_pthread_h=yes
118 ],[
119 ac_have_pthread_h=
120 ])
121 AM_CONDITIONAL(LIBMUDFLAPTH, [test "x$ac_have_pthread_h" != "x"])
122 if test "x$ac_have_pthread_h" != "x"
123 then
124         build_libmudflapth=1
125 else
126         build_libmudflapth=0
127 fi
128 AC_SUBST(build_libmudflapth)
129
130 AC_CHECK_LIB(dl, dlsym)
131
132 # Process the option "--enable-version-specific-runtime-libs"
133 gcc_version_trigger=${srcdir}/../gcc/version.c
134 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^ \"]]*\)[[ \"]].*/\1/'`
135 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
136 AC_SUBST(gcc_version)
137
138 # Calculate toolexeclibdir
139 # Also toolexecdir, though it's only used in toolexeclibdir
140 case ${version_specific_libs} in
141   yes)
142     # Need the gcc compiler version to know where to install libraries
143     # and header files if --enable-version-specific-runtime-libs option
144     # is selected.
145     toolexecdir='$(libdir)/gcc/$(target_alias)'
146     toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
147     ;;
148   no)
149     if test -n "$with_cross_host" &&
150        test x"$with_cross_host" != x"no"; then
151       # Install a library built with a cross compiler in tooldir, not libdir.
152       toolexecdir='$(exec_prefix)/$(target_alias)'
153       toolexeclibdir='$(toolexecdir)/lib'
154     else
155       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
156       toolexeclibdir='$(libdir)'
157     fi
158     multi_os_directory=`$CC -print-multi-os-directory`
159     case $multi_os_directory in
160       .) ;; # Avoid trailing /.
161       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
162     esac
163     ;;
164 esac
165 AC_SUBST(toolexecdir)
166 AC_SUBST(toolexeclibdir)
167
168 if test "x$enable_shared" = "xyes" && test "x$ac_have_pthread_h" != "x"; then
169   # NB: don't check for -lpthread here, because then it would be
170   # added to LIBS.  For the thread-unaware libmudflap.la, we don't
171   # want it there.
172
173   # glibc-related hacks.  dlsym() may pick the wrong version of
174   # interposed functions like pthread_create on modern glibc.
175   # We need to find the proper symbol version string, and use
176   # the nonstandard dlvsym().
177   AC_CHECK_FUNCS(dlvsym)
178   AC_CHECK_TOOL(NM, nm)
179   if test "x$ac_cv_have_dlvsym" != "x"; then
180     # Try compiling a simple pthreads program.  Find the shared libraries it
181     # ends up with.  Then use "nm" on those libraries to extract the
182     # default symbol versioning suffix ("@@"), if any.  But that's tricky.
183     # Rather, run nm on the resulting executable.  Unfortunately, autoconf
184     # doesn't appear to have a macro that builds a test executable for
185     # subsequent analysis ... so we do it by hand here.
186     cat >> conftest.c << EOF
187 #include <pthread.h>
188 int main () { void *p = (void *) & pthread_create; return (int) p; }
189 EOF
190     oldLIBS="$LIBS"
191     LIBS="$LIBS -lpthread"
192     pthread_create_version="\"\""
193     AC_MSG_CHECKING(pthread_create symbol version)
194     if eval $ac_link 2>&5 && test -s conftest${ac_exeext}; then
195       version=`$NM conftest${ac_exeect} | grep 'pthread_create@@' | sed -e 's/^.*@@//'`
196       if test "x$version" != "x"; then
197         pthread_create_version="\"$version\""
198       fi
199     fi
200     AC_MSG_RESULT($pthread_create_version)
201     LIBS="$oldLIBS"
202   fi
203 fi
204 AC_DEFINE_UNQUOTED(PTHREAD_CREATE_VERSION, $pthread_create_version, [pthread_create symbol version])
205
206
207 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
208 # similarly to how libstdc++ does it
209 ac_test_CFLAGS="${CFLAGS+set}"
210 ac_save_CFLAGS="$CFLAGS"
211
212 # Check for -ffunction-sections -fdata-sections
213 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
214 CFLAGS='-Werror -ffunction-sections -fdata-sections'
215 AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
216 if test "$ac_test_CFLAGS" = set; then
217   CFLAGS="$ac_save_CFLAGS"
218 else
219   # this is the suspicious part
220   CFLAGS=""
221 fi
222 if test x"$ac_fdsections" = x"yes"; then
223   SECTION_FLAGS='-ffunction-sections -fdata-sections'
224 fi
225 AC_MSG_RESULT($ac_fdsections)
226 AC_SUBST(SECTION_FLAGS)
227
228
229 if test ${multilib} = yes; then
230   multilib_arg="--enable-multilib"
231 else
232   multilib_arg=
233 fi
234
235 AC_CONFIG_FILES([Makefile testsuite/Makefile testsuite/mfconfig.exp mf-runtime.h])
236 AC_OUTPUT