OSDN Git Service

Introduce and use config/gcc-version.m4.
[pf3gnuchains/gcc-fork.git] / libmudflap / configure.ac
1 # Process this file with autoconf to produce a configure script, like so:
2 # aclocal && autoconf && autoheader && automake
3
4 AC_PREREQ(2.59)
5 AC_INIT(libmudflap, 1.0)
6 AC_CONFIG_SRCDIR(mf-runtime.c)
7 AC_CANONICAL_SYSTEM
8
9 AM_INIT_AUTOMAKE
10
11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
12 AC_ARG_ENABLE(version-specific-runtime-libs,
13 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
14 [case "$enableval" in
15  yes) version_specific_libs=yes ;;
16  no)  version_specific_libs=no ;;
17  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
18  esac],
19 [version_specific_libs=no])
20 AC_MSG_RESULT($version_specific_libs)
21
22 AM_MAINTAINER_MODE
23 AC_EXEEXT
24
25 AM_ENABLE_MULTILIB(, ..)
26
27 target_alias=${target_alias-$host_alias}
28 AC_SUBST(target_alias)
29
30 AC_CONFIG_HEADERS(config.h)
31
32 AC_LANG_C
33 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
34 # We must force CC to /not/ be precious variables; otherwise
35 # the wrong, non-multilib-adjusted value will be used in multilibs.
36 # As a side effect, we have to subst CFLAGS ourselves.
37
38 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
39 m4_define([_AC_ARG_VAR_PRECIOUS],[])
40 AC_PROG_CC
41 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
42
43 AC_SUBST(CFLAGS)
44
45 if test "x$GCC" != "xyes"; then
46   AC_MSG_ERROR([libmudflap must be built with GCC])
47 fi
48 AC_PROG_CPP
49
50 # Some hosts don't have dlsym(RTLD_NEXT, "symbol") for use in
51 # symbol interposition.  We disable shared libraries for these.
52 AC_MSG_CHECKING([whether dlsym(RTLD_NEXT,...) is available])
53 AC_TRY_COMPILE([
54 #define _GNU_SOURCE
55 #include <dlfcn.h>
56 ],
57 [void *foo = dlsym (RTLD_NEXT, "exit");],
58 [AC_MSG_RESULT(yes)],
59 [AC_MSG_RESULT(no)
60 enable_shared=no])
61
62 AC_CHECK_HEADERS(stdint.h execinfo.h signal.h dlfcn.h dirent.h pwd.h grp.h \
63   netdb.h sys/ipc.h sys/sem.h sys/shm.h sys/wait.h ctype.h mntent.h \
64   sys/socket.h netinet/in.h arpa/inet.h dlfcn.h sys/mman.h)
65
66 AC_CHECK_FUNCS(backtrace backtrace_symbols gettimeofday signal)
67 AC_CHECK_FUNCS(fopen64 fseeko64 ftello64 stat64 freopen64)
68 AC_CHECK_FUNCS(setbuf setbuffer setlinebuf setvbuf)
69 AC_CHECK_FUNCS(strnlen memrchr strncpy memmem sethostname)
70 AC_CHECK_FUNCS(__ctype_b_loc __ctype_tolower_loc __ctype_toupper_loc)
71 AC_CHECK_FUNCS(getlogin cuserid getpwnam getpwuid getpwent getgrnam getgrgid getgrent)
72 AC_CHECK_FUNCS(getlogin_r getpwnam_r getpwuid_r getgrnam_r getgrgid_r)
73 AC_CHECK_FUNCS(getservent getservbyname getservbyport getaddrinfo gai_strerror)
74 AC_CHECK_FUNCS(getprotoent getprotobyname getprotobynumber)
75 AC_CHECK_FUNCS(getmntent setmntent addmntent)
76 AC_CHECK_FUNCS(inet_ntoa mmap munmap)
77
78 AC_TRY_COMPILE([#include <sys/types.h>
79 #include <sys/ipc.h>
80 #include <sys/sem.h>],[union semun foo;], [mf_have_semun=1], [mf_have_semun=0])
81 if test $mf_have_semun = 1
82 then
83   AC_DEFINE(HAVE_UNION_SEMUN, 1, [union semun defined in sys/ipc.h or sys/sem.h])
84 fi
85
86
87 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
88 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
89 #include <sys/types.h>
90 #include <sys/socket.h>], [socklen_t x = 5;],
91   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
92    AC_MSG_RESULT(yes)],
93   [AC_MSG_RESULT(no)])
94
95 AC_LIBTOOL_DLOPEN
96 AM_PROG_LIBTOOL
97 AC_SUBST(enable_shared)
98 AC_SUBST(enable_static)
99
100 AC_CHECK_HEADER(stdint.h, [MF_HAVE_STDINT_H=1], [MF_HAVE_STDINT_H=0])
101 AC_SUBST(MF_HAVE_STDINT_H)
102 if test $MF_HAVE_STDINT_H = 1
103 then
104    MF_HAVE_UINTPTR_T=1
105 else
106    AC_TRY_COMPILE([#include <sys/types.h>], [uintptr_t k = 0;],
107         [MF_HAVE_UINTPTR_T=1], [MF_HAVE_UINTPTR_T=0])
108 fi
109 AC_SUBST(MF_HAVE_UINTPTR_T)
110
111 if test ! -d pth
112 then
113   # libmudflapth objects are built in this subdirectory
114   mkdir pth
115 fi
116
117 pthread_create_version='""'
118 AC_CHECK_HEADER(pthread.h,[
119 AC_DEFINE_UNQUOTED(HAVE_PTHREAD_H, 1, [define if you have <pthread.h>])
120 ac_have_pthread_h=yes
121 ],[
122 ac_have_pthread_h=
123 ])
124 AM_CONDITIONAL(LIBMUDFLAPTH, [test "x$ac_have_pthread_h" != "x"])
125 if test "x$ac_have_pthread_h" != "x"
126 then
127         build_libmudflapth=1
128 else
129         build_libmudflapth=0
130 fi
131 AC_SUBST(build_libmudflapth)
132
133 AC_CHECK_LIB(dl, dlsym)
134
135 TL_AC_GCC_VERSION([$srcdir/..])
136
137 # Calculate toolexeclibdir
138 # Also toolexecdir, though it's only used in toolexeclibdir
139 case ${version_specific_libs} in
140   yes)
141     # Need the gcc compiler version to know where to install libraries
142     # and header files if --enable-version-specific-runtime-libs option
143     # is selected.
144     toolexecdir='$(libdir)/gcc/$(target_alias)'
145     toolexeclibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
146     ;;
147   no)
148     if test -n "$with_cross_host" &&
149        test x"$with_cross_host" != x"no"; then
150       # Install a library built with a cross compiler in tooldir, not libdir.
151       toolexecdir='$(exec_prefix)/$(target_alias)'
152       toolexeclibdir='$(toolexecdir)/lib'
153     else
154       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
155       toolexeclibdir='$(libdir)'
156     fi
157     multi_os_directory=`$CC -print-multi-os-directory`
158     case $multi_os_directory in
159       .) ;; # Avoid trailing /.
160       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
161     esac
162     ;;
163 esac
164 AC_SUBST(toolexecdir)
165 AC_SUBST(toolexeclibdir)
166
167 if test "x$enable_shared" = "xyes" && test "x$ac_have_pthread_h" != "x"; then
168   # NB: don't check for -lpthread here, because then it would be
169   # added to LIBS.  For the thread-unaware libmudflap.la, we don't
170   # want it there.
171
172   # glibc-related hacks.  dlsym() may pick the wrong version of
173   # interposed functions like pthread_create on modern glibc.
174   # We need to find the proper symbol version string, and use
175   # the nonstandard dlvsym().
176   AC_CHECK_FUNCS(dlvsym)
177   AC_CHECK_TOOL(NM, nm)
178   if test "x$ac_cv_have_dlvsym" != "x"; then
179     # Try compiling a simple pthreads program.  Find the shared libraries it
180     # ends up with.  Then use "nm" on those libraries to extract the
181     # default symbol versioning suffix ("@@"), if any.  But that's tricky.
182     # Rather, run nm on the resulting executable.  Unfortunately, autoconf
183     # doesn't appear to have a macro that builds a test executable for
184     # subsequent analysis ... so we do it by hand here.
185     cat >> conftest.c << EOF
186 #include <pthread.h>
187 int main () { void *p = (void *) & pthread_create; return (int) p; }
188 EOF
189     oldLIBS="$LIBS"
190     LIBS="$LIBS -lpthread"
191     pthread_create_version="\"\""
192     AC_MSG_CHECKING(pthread_create symbol version)
193     if eval $ac_link 2>&5 && test -s conftest${ac_exeext}; then
194       version=`$NM conftest${ac_exeect} | grep 'pthread_create@@' | sed -e 's/^.*@@//'`
195       if test "x$version" != "x"; then
196         pthread_create_version="\"$version\""
197       fi
198     fi
199     AC_MSG_RESULT($pthread_create_version)
200     LIBS="$oldLIBS"
201   fi
202 fi
203 AC_DEFINE_UNQUOTED(PTHREAD_CREATE_VERSION, $pthread_create_version, [pthread_create symbol version])
204
205
206 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
207 # similarly to how libstdc++ does it
208 ac_test_CFLAGS="${CFLAGS+set}"
209 ac_save_CFLAGS="$CFLAGS"
210
211 # Check for -ffunction-sections -fdata-sections
212 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
213 CFLAGS='-Werror -ffunction-sections -fdata-sections'
214 AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
215 if test "$ac_test_CFLAGS" = set; then
216   CFLAGS="$ac_save_CFLAGS"
217 else
218   # this is the suspicious part
219   CFLAGS=""
220 fi
221 if test x"$ac_fdsections" = x"yes"; then
222   SECTION_FLAGS='-ffunction-sections -fdata-sections'
223 fi
224 AC_MSG_RESULT($ac_fdsections)
225 AC_SUBST(SECTION_FLAGS)
226
227
228 if test ${multilib} = yes; then
229   multilib_arg="--enable-multilib"
230 else
231   multilib_arg=
232 fi
233
234 AC_CONFIG_FILES([Makefile testsuite/Makefile testsuite/mfconfig.exp mf-runtime.h])
235 AC_OUTPUT