OSDN Git Service

62b1f46949ad33294872001ec3451550f313ea0d
[pf3gnuchains/gcc-fork.git] / libjava / testsuite / lib / libjava.exp
1 # Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004 Free Software Foundation
2
3 proc load_gcc_lib { filename } {
4     global srcdir
5     load_file $srcdir/../../gcc/testsuite/lib/$filename
6 }
7
8 load_lib libgloss.exp
9 load_gcc_lib target-libpath.exp
10
11 # GCJ_UNDER_TEST is the compiler under test.
12
13 global tmpdir
14
15 if ![info exists tmpdir] {
16     set tmpdir "/tmp"
17 }
18
19 # This is like `prune_warnings', but it also prunes away a warning
20 # from the bytecode front end that we don't care about.
21 proc libjava_prune_warnings {text} {
22     set text [prune_warnings $text]
23     set tlist [split $text \n]
24     set len [llength $tlist]
25     for {set i [expr {$len - 1}]} {$i >= 2} {incr i -1} {
26         if {[string match "*unreachable bytecode*" [lindex $tlist $i]]} {
27             # Delete this line, all other unreachable warnings and the previous
28             # two lines containing the method and class.
29             set j [expr {$i - 1}]
30             while {[string match "*unreachable bytecode*" [lindex $tlist $j]]} {
31                 incr j -1
32             }
33             incr j -1
34             set tlist [lreplace $tlist $j $i]
35             set i $j
36         }
37     }
38     return [join $tlist \n]
39 }
40
41 # This is like `target_compile' but it does some surgery to work
42 # around stupid DejaGNU bugs.  In particular DejaGNU has very poor
43 # quoting, so for instance a `$' will be re-evaluated at spawn time.
44 # We don't want that.
45 proc libjava_tcompile {source destfile type options} {
46     # This strange-looking expression really does quote the `$'.
47     regsub -all -- {\$} $source {\$} source
48     regsub -all -- {\$} $destfile {\$} destfile
49     return [target_compile $source $destfile $type $options]
50 }
51
52 # Read an `xfail' file if it exists.  Returns a list of xfail tokens.
53 proc libjava_read_xfail {file} {
54     if {! [file exists $file]} {
55         return ""
56     }
57     set fd [open $file r]
58     set tokens [string trim [read $fd]]
59     close $fd
60     return $tokens
61 }
62
63 # Find a particular executable.  FIXME: this relies on DejaGnu
64 # internals.  These should probably be exposed in a better way.
65 proc libjava_find_program {prog} {
66     global tool_root_dir
67
68     set file [lookfor_file $tool_root_dir $prog]
69     if { $file == "" } {
70         set file [lookfor_file $tool_root_dir gcc/$prog];
71     }
72     if {$file == ""} {
73         set file $prog
74     }
75     return $file
76 }
77
78 # Find `jv-scan'.
79 proc find_jvscan {} {
80     return [libjava_find_program jv-scan]
81 }
82
83 # Find `gcjh'.
84 proc find_gcjh {} {
85     return [libjava_find_program gcjh]
86 }
87
88 proc find_javac {} {
89     global SUN_JAVAC GCJ_UNDER_TEST env libgcj_jar
90     # If JDK doesn't run on your platform but some other
91     # JDK-compatible javac does, you may set SUN_JAVAC to point to it.
92     # One of the most important properties of a SUN_JAVAC is that it
93     # must create class-files even for classes that have not been
94     # specified in the command line, but that were needed to compile
95     # those that have.  For example, Pizza won't do it, but you can
96     # use `kaffe sun.tools.javac.Main', if you have Sun's classes.zip
97     # in the kaffe's default search path.
98     if {![info exists SUN_JAVAC]} {
99         if {[info exists env(SUN_JAVAC)]} {
100             set SUN_JAVAC $env(SUN_JAVAC)
101         } else {
102             set SUN_JAVAC "$GCJ_UNDER_TEST -C -I$libgcj_jar"
103         }
104     }
105     return $SUN_JAVAC
106 }
107
108 proc bytecompile_file { file objdir {classpath {}} } {
109     global env
110     set dirname [file dirname $file]
111
112     set javac [find_javac]
113     if {$classpath != ""} then {
114         set env(CLASSPATH) $classpath
115     }
116     set here [pwd]
117     cd $dirname
118     send_log "byte compile: $javac -g [list $file] -d $objdir 2>@ stdout\n"
119     if {[catch {
120         set q [eval exec "$javac -g [list $file] -d $objdir 2>@ stdout"]
121     } msg]} then {
122         send_log "couldn't compile $file: $msg\n"
123         set r 0
124     } else {
125         set r 1
126     }
127     cd $here
128     return $r
129 }
130
131 set libjava_initialized 0
132
133 #
134 # Build the status wrapper library as needed.
135 #
136 proc libjava_init { args } {
137     global wrapper_file;
138     global wrap_compile_flags;
139     global libjava_initialized libjava_uses_threads
140     global GCJ_UNDER_TEST
141     global TOOL_EXECUTABLE
142     global env objdir
143     global env libgcj_jar
144     global tool_root_dir
145     global libjava_libgcc_s_path
146     global target_triplet
147
148     # We set LC_ALL and LANG to C so that we get the same error messages as expected.
149     setenv LC_ALL C
150     setenv LANG C
151
152     if { $libjava_initialized == 1 } { return; }
153
154     if ![info exists GCJ_UNDER_TEST] {
155         if [info exists TOOL_EXECUTABLE] {
156             set GCJ_UNDER_TEST $TOOL_EXECUTABLE;
157         } else {
158             if [info exists env(GCJ)] {
159                 set GCJ_UNDER_TEST $env(GCJ)
160             } else {
161                 set GCJ_UNDER_TEST "[find_gcj]"
162             }
163         }
164     }
165
166     # Find the libgcj jar file.
167     set libgcj_jar [glob $objdir/../libgcj-*.jar]
168     verbose "jar file is $libgcj_jar"
169
170     # FIXME: This finds libgcj.spec for the default multilib.
171     # If thread models differ between multilibs, this has to be moved
172     # to libjava_arguments
173     set specdir [libjava_find_spec]
174
175     # The -B is so we find libgcj.spec.
176     set text [eval exec "$GCJ_UNDER_TEST -B$specdir -v 2>@ stdout"]
177     regexp -- "Thread model: (\[^\n\]+)\n" $text ignore model
178     set libjava_uses_threads [expr {! ($model == "no"
179                                        || $model == "none"
180                                        || $model == "single")}]
181
182     # Always set encoding used by gcj.
183     append GCJ_UNDER_TEST " --encoding=UTF-8"
184
185     set wrapper_file "";
186     set wrap_compile_flags "";
187     if [target_info exists needs_status_wrapper] {
188         set result [build_wrapper "testglue.o"];
189         if { $result != "" } {
190             set wrapper_file [lindex $result 0];
191             set wrap_compile_flags [lindex $result 1];
192         } else {
193             warning "Status wrapper failed to build."
194         }
195     }
196
197     # Finally, add the gcc build directory so that we can find the
198     # shared libgcc.  This, like much of dejagnu, is hideous.
199     set libjava_libgcc_s_path {}
200     
201     if { [string match "powerpc-*-darwin*" $target_triplet] } {
202         set so_extension "dylib"
203     } else {
204         set so_extension "so"
205     }
206     set gccdir [lookfor_file $tool_root_dir gcc/libgcc_s.${so_extension}]
207     if {$gccdir != ""} {
208         set gccdir [file dirname $gccdir]
209         lappend libjava_libgcc_s_path $gccdir
210         verbose "libjava_libgcc_s_path = $libjava_libgcc_s_path"
211         set compiler ${gccdir}/xgcc
212         if { [is_remote host] == 0 && [which $compiler] != 0 } {
213             foreach i "[exec $compiler --print-multi-lib]" {
214                 set mldir ""
215                 regexp -- "\[a-z0-9=/\.-\]*;" $i mldir
216                 set mldir [string trimright $mldir "\;@"]
217                 if { "$mldir" == "." } {
218                     continue
219                 }
220                 if { [llength [glob -nocomplain ${gccdir}/${mldir}/libgcc_s*.${so_extension}.*]] >= 1 } {
221                     lappend libjava_libgcc_s_path "${gccdir}/${mldir}"
222                 }
223             }
224         }
225     }
226
227     set libjava_initialized 1
228 }
229
230 # Find a library.  We know where libtool puts the actual libraries,
231 # and we look there.  The implementation is fairly hacky.  We can't
232 # compile with -nodefaultlibs, because that will also eliminate the
233 # system libraries we need.  In order to have gcj still work, it must
234 # find the appropriate libraries so we must add -L options for their
235 # paths.  However we can't simply use those libraries; we still need
236 # libtool for linking.
237 # Don't return the the lib${name}.la files here, since this causes the
238 # libraries to be linked twice: once as lib${name}.so/dylib and another time
239 # via gcj's implicit -l${name}.  This is both unnecessary and causes the
240 # Solaris ld to warn: attempted multiple inclusion of file.  This warning
241 # is not ignored by the dejagnu framework and cannot be disabled.
242 proc libjava_find_lib {dir name} {
243     global base_dir
244     set gp [get_multilibs]
245     foreach extension {so dll a} {
246         foreach sub {.libs _libs} {
247             if {$gp != ""} {
248                 if {[file exists $gp/$dir/$sub/lib${name}.${extension}]} then {
249                     # Just return the `-L' option.  The library itself
250                     # will be picked up via the spec file.
251                     return "-L$gp/$dir/$sub"
252                 }
253             }
254             # Just return the `-L' option.  The library itself will be
255             # picked up via the spec file.
256             set lib [findfile \
257                        $base_dir/../../$dir/$sub/lib${name}.${extension} \
258                        "-L$base_dir/../../$dir/$sub" \
259                        ""]
260             if {$lib != ""} {
261                 return $lib
262             }
263         }
264     }
265     return ""
266 }
267
268 # Find libgcj.spec.  We need to use the file corresponding to the multilib
269 # under test since they might differ.  Append a trailing slash since this
270 # is used with -B.
271 proc libjava_find_spec {} {
272     global objdir
273     set gp [get_multilibs]
274
275     if {[file exists $gp/libjava/libgcj.spec]} then {
276         return "$gp/libjava/"
277     }
278     return "$objdir/../"
279 }
280
281 # Find `gij'.
282 proc libjava_find_gij {} {
283     global base_dir
284     set gp [get_multilibs]
285     if {$gp != ""} {
286         set file $gp/libjava/gij
287     } else {
288         set file $base_dir/../gij
289     }
290
291     if {[file exists $file]} {
292         return $file
293     }
294     return gij
295 }
296
297 # Remove a bunch of files.
298 proc gcj_cleanup {args} {
299     foreach file $args {
300         if {[string match *.o $file]} {
301             verbose "removing [file rootname $file].lo"
302             file delete -force [file rootname $file].lo
303         }
304         file delete -force -- $file
305         verbose "removing $file"
306     }
307     # It is simplest to do this instead of trying to figure out what
308     # bits in .libs ought to be removed.
309     catch {system "rm -rf .libs"}
310 }
311
312 # Compute arguments needed for compiler.  MODE is a libtool mode:
313 # either compile or link.
314 proc libjava_arguments {{mode compile}} {
315     global base_dir
316     global LIBJAVA
317     global srcdir subdir objdir
318     global TOOL_OPTIONS
319     global GCJ_UNDER_TEST
320     global tmpdir
321     global runtests
322     global env
323     global tool_root_dir
324     global libgcj_jar
325     global libjava_libgcc_s_path
326     global libjava_ld_library_path
327     global ld_library_path
328     global target_triplet
329
330     if [info exists LIBJAVA] {
331         set libjava $LIBJAVA;
332     } else {
333         set libjava [libjava_find_lib libjava gcj]
334     }
335
336     verbose "using LIBJAVA = $libjava" 2
337     set args ""
338
339     # Basically we want to build up a colon separated path list from
340     # the value of $libjava.
341
342     set lpath "."
343     foreach dir [list $libjava] {
344         foreach item [split $dir " "] {
345             switch -glob -- $item {
346                 "-L*" {
347                     lappend lpath [string range $item 2 end]
348                 }
349             }
350         }
351     }
352
353     set lpath [concat $lpath $libjava_libgcc_s_path]
354     verbose "lpath = $lpath ; libgcc_s_path = $libjava_libgcc_s_path"
355     set ld_library_path [join $lpath :]
356     set libjava_ld_library_path "$ld_library_path"
357
358     # That's enough to make things work for the normal case.
359     # If we wanted to handle an arbitrary value of libjava,
360     # then we'd have to do a lot more work.
361
362     set_ld_library_path_env_vars
363     if [info exists env(LD_LIBRARY_PATH)] {
364         verbose "LD_LIBRARY_PATH = $env(LD_LIBRARY_PATH)"
365     }
366
367     # Determine CLASSPATH separator
368     if { [string match "i?86-pc-mingw32*" $target_triplet] } {
369         set sep ";"
370     } else {
371         set sep ":"
372     }
373
374     # Set the CLASSPATH environment variable
375     global env
376     set env(CLASSPATH) \
377         [join [list . $srcdir/$subdir $objdir $libgcj_jar] $sep]
378     verbose "CLASSPATH is $env(CLASSPATH)"
379
380     if {$mode == "link"} {
381         global wrapper_file wrap_compile_flags
382         lappend args "additional_flags=$wrap_compile_flags"
383         lappend args "libs=$wrapper_file"
384         lappend args "libs=$libjava"
385         lappend args debug
386     }
387
388     if { [target_info needs_status_wrapper]!="" && [info exists gluefile] } {
389         lappend args "libs=${gluefile}"
390         lappend args "ldflags=$wrap_flags"
391     }
392
393     if [info exists TOOL_OPTIONS] {
394         lappend args "additional_flags=$TOOL_OPTIONS"
395     }
396
397     # Determine libgcj.spec corresponding to multilib under test.
398     set specdir [libjava_find_spec]
399
400     # Search for libtool.  We need it to link.
401     set found_compiler 0
402     set d [absolute $objdir]
403     foreach x {. .. ../.. ../../..} {
404         if {[file exists $d/$x/libtool]} then {
405             # We have to run silently to avoid DejaGNU lossage.
406             lappend args \
407               "compiler=$d/$x/libtool --silent --tag=GCJ --mode=$mode $GCJ_UNDER_TEST -B$specdir"
408             set found_compiler 1
409             break
410         }
411     }
412     if {! $found_compiler} {
413         # Append -B$specdir so that we find libgcj.spec before it
414         # is installed.
415         lappend args "compiler=$GCJ_UNDER_TEST -B$specdir"
416     }
417
418     # Avoid libtool wrapper scripts when possible.
419     # but not if libtool warnings results in FAILs
420     if {$mode == "link"} {
421         if {! [istarget "*-*-cygwin*"] && ! [istarget "*-*-mingw*"] } {
422             lappend args "additional_flags=-no-install"
423         }
424         if { [istarget "*-*-darwin*"] } {
425             lappend args "additional_flags=-bind_at_load"
426             lappend args "additional_flags=-multiply_defined suppress"
427         }
428     }
429
430     return $args
431 }
432
433 # Link a bunch of objects into a program.  MAIN is the name of the
434 # class holding `main'.  Return 0 on failure.
435 proc gcj_link {program main files {options {}}} {
436     set arguments [libjava_arguments link]
437     if {[llength $options]} {
438         eval lappend arguments $options
439     }
440     lappend arguments "additional_flags=--main=$main"
441     set x [libjava_prune_warnings \
442              [libjava_tcompile $files $program executable $arguments]]
443     if {$x != ""} {
444         verbose "link failure: $x" 2
445         fail "linking $program"
446         setup_xfail "*-*-*"
447         fail "running $program"
448         return 0
449     }
450
451     pass "linking $program"
452     return 1
453 }
454
455 # Invoke the program and see what happens.  Return 0 on failure.
456 proc gcj_invoke {program expectFile ld_library_additions} {
457   global env
458   global libjava_ld_library_path
459   global ld_library_path
460
461   set ld_library_path "$libjava_ld_library_path"
462   if {[llength $ld_library_additions] > 0} {
463     append ld_library_path :[join $ld_library_additions :]
464   }
465
466   set_ld_library_path_env_vars
467   if [info exists env(LD_LIBRARY_PATH)] {
468     verbose "LD_LIBRARY_PATH=$env(LD_LIBRARY_PATH)"
469   }
470
471   set result [libjava_load ./$program]
472   set status [lindex $result 0]
473   set output [lindex $result 1]
474
475   # Restore setting
476   restore_ld_library_path_env_vars
477
478   if {$status != "pass"} {
479     verbose "got $output"
480     fail "$program run"
481     untested "$program output"
482     return 0
483   }
484
485   set id [open $expectFile r]
486   set expected [read $id]
487   close $id
488
489   if {! [string compare $output $expected]} {
490     pass "$program output"
491     return 1
492   } else {
493     fail "$program output"
494     return 0
495   }
496 }
497
498 # Invoke a program and check its output.  EXECUTABLE is the program;
499 # ARGS are the arguments to the program.  Returns 1 if tests passed
500 # (or things were left untested), 0 otherwise.
501 proc libjava_invoke {errname testName optName executable inpfile resultfile
502                       ld_library_additions args} {
503     global env
504     global libjava_ld_library_path
505     global ld_library_path
506
507     set ld_library_path "$libjava_ld_library_path"
508     if {[llength $ld_library_additions] > 0} {
509         append ld_library_path :[join $ld_library_additions :]
510     }
511
512     set_ld_library_path_env_vars
513     if [info exists env(LD_LIBRARY_PATH)] {
514         verbose "LD_LIBRARY_PATH=$env(LD_LIBRARY_PATH)"
515     }
516
517     upvar $optName opts
518
519     if {[info exists opts(no-exec)]} {
520         if {[info exists opts(need-threads)]} {
521             # This means we wanted to try to run it but we couldn't
522             # because threads aren't supported.  So we have to
523             # generate an `untested'.
524             untested "$errname execution - $testName"
525             untested "$errname output - $testName"
526         }
527         return 1
528     }
529
530     set result [libjava_load $executable $args "$inpfile"]
531     set status [lindex $result 0]
532     set output [lindex $result 1]
533
534     # Restore LD_LIBRARY_PATH setting.
535     restore_ld_library_path_env_vars
536
537     if {[info exists opts(xfail-exec)]} then {
538         setup_xfail *-*-*
539     }
540     $status "$errname execution - $testName"
541     if { $status != "pass" } {
542         untested "$errname output - $testName"
543         return 0
544     }
545
546     verbose "resultfile is $resultfile"
547     set id [open $resultfile r]
548     set expected ""
549     append expected [read $id]
550     regsub -all "\r" "$output" "" output
551     regsub "\n*$" $expected "" expected
552     regsub "\n*$" $output "" output
553     regsub "^\n*" $expected "" expected
554     regsub "^\n*" $output "" output
555     regsub -all "\[ \t\]\[ \t\]*" $expected " " expected
556     regsub -all "\[ \t\]*\n\n*" $expected "\n" expected
557     regsub -all "\[ \t\]\[ \t\]*" $output " " output
558     regsub -all "\[ \t\]*\n\n*" $output "\n" output
559     verbose "expected is $expected"
560     verbose "actual is $output"
561     set passed 0
562     if {[info exists opts(regexp_match)]} {
563         if [regexp $expected $output] {
564             set passed 1
565         }
566     } else {
567         if { $expected == $output } {
568             set passed 1
569         }
570     }
571     if {[info exists opts(xfail-output)]} {
572         setup_xfail *-*-*
573     }
574     if { $passed == 1 } {
575         pass "$errname output - $testName"
576     } else {
577         fail "$errname output - $testName"
578     }
579     close $id
580
581     return $passed
582 }
583
584 #
585 # Run the test specified by srcfile and resultfile. compile_args and
586 # exec_args are options telling this proc how to work.
587 #
588 proc test_libjava_from_source { options srcfile compile_args inpfile resultfile exec_args } {
589     global base_dir
590     global srcdir subdir objdir
591     global TOOL_OPTIONS
592     global GCJ_UNDER_TEST
593     global tmpdir
594     global runtests
595
596     # Make opts into an array.
597     set opts(_) x
598     unset opts(_)
599     foreach item $exec_args {
600         set opts($item) x
601     }
602
603     # If we need threads and we don't have them then set the `no-exec'
604     # flag.  This is case is also handled specially later.
605     if {[info exists opts(need-threads)]} {
606         global libjava_uses_threads
607         if {! $libjava_uses_threads} {
608             set opts(no-exec) x
609         }
610     }
611
612     set errname [file rootname [file tail $srcfile]]
613     if {! [runtest_file_p $runtests $errname]} {
614         return
615     }
616
617     if {[info exists opts(no-link)]} {
618         set mode compile
619     } else {
620         set mode link
621     }
622     set args [libjava_arguments $mode]
623     if {! [info exists opts(no-link)]} {
624         # Add the --main flag
625         lappend args "additional_flags=--main=[file rootname [file tail $srcfile]]"
626         if { $compile_args != "" } {
627             lappend args "additional_flags=$compile_args"
628         }
629     }
630
631     regsub "^.*/(\[^/.\]+)\[.\]\[^/]*$" "$srcfile" "\\1" out
632     set executable "${objdir}/$out"
633     if {[info exists opts(no-link)]} {
634         append executable ".o"
635         set target object
636     } else {
637         # DOS/win32 targets default to .exe if no suffix is given
638         # We then try to delete a file that doesn't exist.  It is
639         # simpler to add the suffix everywhere.
640         append executable ".exe"
641         set target executable
642     }
643     if { $compile_args != "" } {
644         set errname "$errname $compile_args"
645     }
646
647     set removeList [list $executable]
648
649     set x [libjava_prune_warnings \
650              [libjava_tcompile $srcfile "$executable" $target $args]]
651     if {[info exists opts(xfail-gcj)]} {
652         setup_xfail *-*-*
653     }
654     if { $x != "" } {
655         verbose "target_compile failed: $x" 2
656
657         if {[info exists opts(shouldfail)]} {
658             pass "$errname compilation from source"
659             eval gcj_cleanup $removeList
660             return
661         }
662
663         fail "$errname compilation from source"
664         if {[info exists opts(xfail-gcj)]
665             || ! [info exists opts(no-exec)]
666             || [info exists opts(need-threads)]} {
667             untested "$errname execution from source compiled test"
668             untested "$errname output from source compiled test"
669         }
670         return
671     }
672     if {[info exists opts(shouldfail)]} {
673         fail "$errname compilation from source"
674         return
675     }
676     pass "$errname compilation from source"
677
678     # Set up the options the way they are expected by libjava_invoke.
679     if {[info exists opts(xfail-source-output)]} {
680         set opts(xfail-output) x
681     }
682     if {[libjava_invoke $errname "source compiled test" opts $executable \
683            $inpfile $resultfile ""]} {
684         # Everything ok, so clean up.
685         eval gcj_cleanup $removeList
686     }
687 }
688
689 #
690 # Run the test specified by srcfile and resultfile. compile_args and
691 # exec_args are options telling this proc how to work.
692 #
693 proc test_libjava_from_javac { options srcfile compile_args inpfile resultfile exec_args } {
694     global base_dir
695     global srcdir subdir objdir
696     global TOOL_OPTIONS
697     global GCJ_UNDER_TEST
698     global tmpdir
699     global runtests
700     global INTERPRETER
701
702     # Make opts into an array.
703     set opts(_) x
704     unset opts(_)
705     foreach item $exec_args {
706         set opts($item) x
707     }
708
709     # If we need threads and we don't have them then set the `no-exec'
710     # flag.  This is case is also handled specially later.
711     if {[info exists opts(need-threads)]} {
712         global libjava_uses_threads
713         if {! $libjava_uses_threads} {
714             set opts(no-exec) x
715         }
716     }
717     set errname [file rootname [file tail $srcfile]]
718     if {! [runtest_file_p $runtests $errname]} {
719         return
720     }
721
722     # bytecompile files with Sun's compiler for now.
723     set bc_ok [bytecompile_file $srcfile $objdir]
724
725     set javac [find_javac]
726     # This is an ugly heuristic but it will have to do.
727     if {[string match *gcj* $javac]} {
728         set tag gcjC
729     } else {
730         set tag javac
731     }
732     if {[info exists opts(xfail-$tag)]} {
733         setup_xfail *-*-*
734     }
735     if {! $bc_ok} then {
736         if {[info exists opts(shouldfail)]} {
737             pass "$errname byte compilation"
738             return
739         }
740         fail "$errname byte compilation"
741         untested "$errname compilation from bytecode"
742         if {! [info exists opts(no-exec)]
743             || [info exists opts(need-threads)]} {
744             untested "$errname execution from bytecode->native test"
745             untested "$errname output from bytecode->native test"
746         }
747         return
748     }
749     if {[info exists opts(shouldfail)]} {
750         fail "$errname byte compilation"
751         return
752     }
753     pass "$errname byte compilation"
754
755     set removeList {}
756
757     # Find name to use for --main, and name of all class files.
758     set jvscan [find_jvscan]
759     verbose "jvscan is $jvscan"
760     set main_name [string trim \
761                      [libjava_prune_warnings \
762                         [lindex [local_exec "$jvscan --encoding=UTF-8 $srcfile --print-main" "" "" 300] 1]]]
763     verbose "main name is $main_name"
764     set class_out [string trim \
765                      [libjava_prune_warnings \
766                         [lindex [local_exec "$jvscan --encoding=UTF-8 $srcfile --list-class" "" "" 300] 1]]]
767     verbose "class list is $class_out"
768
769     if {[string match "*parse error*" $main_name]
770         || [string match "*parse error*" $class_out]} {
771         untested "$errname compilation from bytecode"
772         if {! [info exists opts(no-exec)]
773             || [info exists opts(need-threads)]} {
774             untested "$errname execution from bytecode->native test"
775             untested "$errname output from bytecode->native test"
776         }
777         return
778     }
779
780     # Turn "a b" into "a.class b.class".
781     # Also, turn "foo.bar" into "foo/bar.class".
782     set class_files {}
783     foreach file [split [string trim $class_out]] {
784         set file [join [split $file .] /]
785         lappend class_files $objdir/$file.class
786     }
787
788     eval lappend removeList $class_files
789
790     # Usually it is an error for a test program not to have a `main'
791     # method.  However, for no-exec tests it is ok.  Treat no-link
792     # like no-exec here.
793     if {[info exists opts(no-link)]} {
794         set opts(no-exec) x
795     }
796     set largs {}
797
798     if {[info exists opts(no-exec)]} {
799         set type object
800         set mode compile
801     } elseif {$main_name == ""} {
802         perror "No `main' given in program $errname"
803         return
804     } else {
805         set type executable
806         lappend largs "additional_flags=--main=$main_name"
807         # DOS/win32 targets default to .exe if no suffix is given
808         # We then try to delete a file that doesn't exist.  It is
809         # simpler to add the suffix everywhere.
810         set executable "${objdir}/${main_name}.exe"
811         set mode link
812     }
813
814     # We purposely ignore errors here; we still want to run the other
815     # appropriate tests.
816     set gij [libjava_find_gij]
817     # libjava_find_gij will return `gij' if it couldn't find the
818     # program; in this case we want to skip the test.
819     if {$INTERPRETER == "yes" && $gij != "gij"} {
820         libjava_invoke $errname "gij test" opts $gij \
821           $inpfile $resultfile "" $main_name
822     }
823
824     # Initial arguments.
825     set args [libjava_arguments $mode]
826     eval lappend args $largs
827
828     if { $compile_args != "" } {
829         lappend args "additional_flags=$compile_args"
830     }
831
832     if { $compile_args != "" } {
833         set errname "$errname $compile_args"
834     }
835
836     verbose "compilation command = $args" 2
837     # When compiling and not linking, we have to build each .o
838     # separately.  We do this because DejaGNU's target_compile won't
839     # accept an empty "destfile" argument when the mode is "compile".
840     if {$mode == "compile"} {
841         foreach c_file $class_files {
842             set executable [file rootname [file tail $c_file]].o
843             # Don't write files which contain $ chars.
844             regsub -all "\\$" $executable "\^" executable
845             set x [libjava_prune_warnings \
846                      [libjava_tcompile '$c_file' "$executable" $type $args]]
847             lappend removeList $executable
848             if {$x != ""} {
849                 break
850             }
851         }
852     } else {
853         # This is so evil: we de-listify CLASS_FILES so that we can
854         # turn around and quote the `$' in it for the shell.  I really
855         # hate DejaGNU.  It is so !@#$!@# unpredictable.
856         set hack ""
857         foreach stupid $class_files {
858             set hack "$hack $stupid"
859         }
860         lappend removeList $executable
861         set x [libjava_prune_warnings \
862                  [libjava_tcompile $hack "$executable" $type $args]]
863     }
864     if {[info exists opts(xfail-byte)]} {
865         setup_xfail *-*-*
866     }
867     if { $x != "" } {
868         verbose "target_compile failed: $x" 2
869         fail "$errname compilation from bytecode"
870         if {! [info exists opts(no-exec)]
871             || [info exists opts(need-threads)]} {
872             untested "$errname execution from bytecode->native test"
873             untested "$errname output from bytecode->native test"
874         }
875         return;
876     }
877     pass "$errname compilation from bytecode"
878
879     # Set up the options the way they are expected by libjava_invoke.
880     if {[info exists opts(xfail-byte-output)]} {
881         set opts(xfail-output) x
882     }
883     if {[libjava_invoke $errname "bytecode->native test" opts $executable \
884            $inpfile $resultfile ""]} {
885         # Everything ok, so clean up.
886         eval gcj_cleanup $removeList
887     }
888 }
889
890 #
891 # Run the test specified by srcfile and resultfile. compile_args and
892 # exec_args are options telling this proc how to work.
893 #   `no-link'     don't try to link the program
894 #   `no-exec'     don't try to run the test
895 #   `xfail-gcj'   compilation from source will fail
896 #   `xfail-javac' compilation with javac will fail
897 #   `xfail-gcjC'  compilation with gcj -C will fail
898 #   `shouldfail'  compilation from source is supposed to fail
899 #                 This is different from xfail, which marks a known
900 #                 failure that we just haven't fixed.
901 #                 A compilation marked this way should fail with any
902 #                 front end.
903 #   `xfail-byte'  compilation from bytecode will fail
904 #   `xfail-exec'  exec will fail
905 #   `xfail-output'
906 #                 output will be wrong
907 #   `xfail-byte-output'
908 #                 output will be wrong when compiled from bytecode
909 #   `xfail-source-output'
910 #                 output will be wrong when compiled from source code
911 #   `need-threads'
912 #                 test relies on thread support
913 #
914 proc test_libjava { options srcfile compile_args inpfile resultfile exec_args } {
915     test_libjava_from_source $options $srcfile $compile_args $inpfile $resultfile $exec_args
916     test_libjava_from_javac $options $srcfile $compile_args $inpfile $resultfile $exec_args
917  }
918
919 #
920 # libjava_version -- extract and print the version number of libjavap
921 #
922 proc default_libjava_version {} {
923 }
924
925 proc default_libjava_start { } {
926 }
927
928 # Local Variables:
929 # tcl-indent-level:4
930 # End: