libjava/scripts/makemake.tcl

   1 #!/usr/bin/tclsh
   2
   3 # Helper to enforce array-ness.
   4 proc makearray {name} {
   5   upvar $name ary
   6   set ary(_) 1
   7   unset ary(_)
   8 }
   9
  10 global is_verbose
  11 set is_verbose 0
  12
  13 # Verbose printer.
  14 proc verbose {text} {
  15   global is_verbose
  16   if {$is_verbose} {
  17     puts stderr $text
  18   }
  19 }
  20
  21 # This maps a name to its style:
  22 # * bc    objects in this package and all its sub-packages
  23 #         are to be compiled with the BC ABI.  It is an error
  24 #         for sub-packages to also appear in the map.
  25 # * bcheaders
  26 #         as bc, but generate header files and compile with CNI.
  27 # * package
  28 #         objects in this package (and possibly sub-packages,
  29 #         if they do not appear in the map) will be compiled en masse
  30 #         from source into a single object, using the C++ ABI.
  31 # * ordinary
  32 #         objects in this package (and possibly sub-packages
  33 #         if they do not appear in the map) will be compiled one at
  34 #         a time into separate .o files.
  35 # * ignore
  36 #         objects in this package are not used.  Note however that
  37 #         most ignored files are actually handled by listing them in
  38 #         'standard.omit'
  39 #
  40 # If a package does not appear in the map, the default is 'package'.
  41 global package_map
  42 set package_map(.) package
  43
  44 # These are ignored in Classpath.
  45 set package_map(gnu/test) ignore
  46 set package_map(gnu/javax/swing/plaf/gtk) ignore
  47 set package_map(gnu/gcj/tools/gc_analyze) ignore
  48
  49 set package_map(gnu/java/awt/peer/swing) bc
  50
  51 set package_map(gnu/xml/aelfred2) bc
  52 set package_map(gnu/xml/dom) bc
  53 set package_map(gnu/xml/libxmlj) bc
  54 set package_map(gnu/xml/pipeline) bc
  55 set package_map(gnu/xml/stream) bc
  56 set package_map(gnu/xml/transform) bc
  57 set package_map(gnu/xml/util) bc
  58 set package_map(gnu/xml/validation) bc
  59 set package_map(gnu/xml/xpath) bc
  60 set package_map(javax/imageio) bc
  61 set package_map(javax/xml) bc
  62 set package_map(gnu/java/beans) bc
  63 set package_map(gnu/java/awt/dnd/peer/gtk) bc
  64 set package_map(gnu/java/util/prefs/gconf) bc
  65 set package_map(gnu/java/awt/peer/gtk) bc
  66 set package_map(gnu/java/awt/dnd/peer/gtk) bc
  67 set package_map(gnu/java/awt/peer/qt) bc
  68 set package_map(gnu/java/awt/peer/x) bc
  69 set package_map(gnu/java/util/prefs/gconf) bc
  70 set package_map(gnu/javax/sound/midi) bc
  71 set package_map(org/xml) bc
  72 set package_map(org/w3c) bc
  73 set package_map(org/relaxng) bc
  74 set package_map(javax/rmi) bc
  75 set package_map(org/omg) bc
  76 set package_map(gnu/CORBA) bc
  77 set package_map(gnu/javax/rmi) bc
  78 set package_map(gnu/java/lang/management) bcheaders
  79 set package_map(java/lang/management) bc
  80 set package_map(gnu/classpath/management) bc
  81 set package_map(gnu/javax/management) bc
  82
  83 # parser/HTML_401F.class is really big, and there have been complaints
  84 # about this package requiring too much memory to build.  So, we
  85 # compile it as separate objects.  But, we're careful to compile the
  86 # sub-packages as packages.
  87 set package_map(gnu/javax/swing/text/html/parser) ordinary
  88 set package_map(gnu/javax/swing/text/html/parser/models) package
  89 set package_map(gnu/javax/swing/text/html/parser/support) package
  90
  91 # More special cases.  These end up in their own library.
  92 # Note that if we BC-compile AWT we must update these as well.
  93 set package_map(gnu/gcj/xlib) package
  94 set package_map(gnu/awt/xlib) package
  95
  96 # Some BC ABI packages have classes which must not be compiled BC.
  97 # This maps such packages to a grep expression for excluding such
  98 # classes.
  99 global exclusion_map
 100 makearray exclusion_map
 101 # set exclusion_map(java/awt) AWTPermission
 102
 103 # This maps a package name to a list of corresponding .java file base
 104 # names.  The package name will either appear as a key in package_map,
 105 # or it will be '.' for the default.
 106 global name_map
 107 makearray name_map
 108
 109 # This maps a java file base name, like 'java/lang/Object.java', to
 110 # the source directory in which it resides.  We keep a layer of
 111 # indirection here so that we can override sources in Classpath with
 112 # our own sources.
 113 global dir_map
 114 makearray dir_map
 115
 116 # An entry in this map means that all .properties files in the
 117 # corresponding directory should be ignored.
 118 global properties_map
 119 makearray properties_map
 120
 121 # logging.properties is installed and is editable.
 122 set properties_map(java/util/logging) _
 123 # We haven't merged locale resources yet.
 124 set properties_map(gnu/java/locale) _
 125
 126
 127 # List of all properties files.
 128 set properties_files {}
 129
 130 # List of all '@' files that we are going to compile.
 131 set package_files {}
 132
 133 # List of all header file variables.
 134 set header_vars {}
 135
 136 # List of all BC object files.
 137 set bc_objects {}
 138
 139 # List of regexps for matching ignored files.
 140 set ignore_rx_list {}
 141
 142
 143 # Return true if a given file should be ignored.
 144 # The argument is the path name including the package part.
 145 proc ignore_file_p {file} {
 146   global ignore_rx_list
 147   foreach rx $ignore_rx_list {
 148     if {[regexp -- $rx $file]} {
 149       verbose "ignoring $file for $rx"
 150       return 1
 151     }
 152   }
 153   return 0
 154 }
 155
 156 # Read a '.omit' file and update the internal data structures.
 157 proc read_omit_file {name} {
 158   global ignore_rx_list
 159   set fd [open $name r]
 160   while {! [eof $fd]} {
 161     set line [gets $fd]
 162
 163     # Classpath's entries bogusly start with "../".
 164     if {[string match ../* $line]} {
 165       set line [string range $line 3 end]
 166     }
 167
 168     if {$line != ""} {
 169       lappend ignore_rx_list $line
 170     }
 171   }
 172   close $fd
 173 }
 174
 175 # Classify a single source file.
 176 proc classify_source_file {basedir file} {
 177   global package_map name_map dir_map
 178
 179   if {[ignore_file_p $file]} {
 180     return
 181   }
 182
 183   set seen [info exists dir_map($file)]
 184   set dir_map($file) $basedir
 185   set pkg $file
 186   while {1} {
 187     if {[info exists package_map($pkg)]} {
 188       # If the entry is 'package', then set up a new entry for the
 189       # file's package.
 190       if {$package_map($pkg) == "package"} {
 191         set pkg [file dirname $file]
 192         set package_map($pkg) package
 193       }
 194       verbose "classify succeeded: $file -> $pkg"
 195       if {! $seen} {
 196         lappend name_map($pkg) $file
 197       }
 198       return
 199     }
 200     set pkg [file dirname $pkg]
 201   }
 202   error "can't happen"
 203 }
 204
 205 # Scan a directory and its subdirectories for .java source files or
 206 # .properties files.  Note that we keep basedir and subdir separate so
 207 # we can properly update our global data structures.
 208 proc scan_directory {basedir subdir} {
 209   global dir_map properties_map properties_files
 210
 211   set subdirs {}
 212   set files {}
 213   set here [pwd]
 214   cd $basedir/$subdir
 215   foreach file [lsort [glob -nocomplain *]] {
 216     if {[string match *.java $file]} {
 217       lappend files $subdir/$file
 218     } elseif {[string match *.properties $file]} {
 219       if {! [info exists properties_map($subdir)]} {
 220         # We assume there aren't any overrides.
 221         lappend properties_files $basedir/$subdir/$file
 222       }
 223     } elseif {[file isdirectory $file]} {
 224       lappend subdirs $subdir/$file
 225     } elseif {$subdir == "META-INF/services"} {
 226       # All service files are included as properties.
 227       lappend properties_files $basedir/$subdir/$file
 228     }
 229   }
 230   cd $here
 231
 232   # Recurse first, so that we don't create new packages too eagerly.
 233   foreach dir $subdirs {
 234     scan_directory $basedir $dir
 235   }
 236
 237   foreach file $files {
 238     classify_source_file $basedir $file
 239   }
 240 }
 241
 242 # Scan known packages beneath the base directory for .java source
 243 # files.
 244 proc scan_packages {basedir} {
 245   foreach subdir {gnu java javax org sun META-INF} {
 246     if {[file exists $basedir/$subdir]} {
 247       scan_directory $basedir $subdir
 248     }
 249   }
 250 }
 251
 252 # Emit a rule for a 'bc' package.
 253 proc emit_bc_rule {package} {
 254   global package_map exclusion_map bc_objects
 255
 256   if {$package == "."} {
 257     set pkgname ordinary
 258   } else {
 259     set pkgname $package
 260   }
 261   set varname [join [split $pkgname /] _]_source_files
 262   set loname [join [split $pkgname /] -].lo
 263   set tname [join [split $pkgname /] -].list
 264
 265   puts "$loname: \$($varname)"
 266   # Create a temporary list file and then compile it.  This works
 267   # around the libtool problem mentioned in PR 21058.  classpath was
 268   # built first, so the class files are to be found there.
 269   set omit ""
 270   if {[info exists exclusion_map($package)]} {
 271     set omit "| grep -v $exclusion_map($package)"
 272   }
 273   puts  "\t@find \$(srcdir)/classpath/lib/$package -name '*.class'${omit} > $tname"
 274   puts -nonewline "\t\$(LTGCJCOMPILE) -fsource-filename=\$(here)/classpath/lib/classes "
 275   if {$package_map($package) == "bc"} {
 276     puts -nonewline "-fjni "
 277   }
 278   puts "-findirect-dispatch -fno-indirect-classes -c -o $loname @$tname"
 279   puts "\t@rm -f $tname"
 280   puts ""
 281
 282   # We skip these because they are built into their own libraries and
 283   # are handled specially in Makefile.am.
 284   if {$loname != "gnu-java-awt-peer-qt.lo" && $loname != "gnu-java-awt-peer-x.lo"} {
 285     lappend bc_objects $loname
 286   }
 287 }
 288
 289 # Emit a rule for a 'package' package.
 290 proc emit_package_rule {package} {
 291   global package_map exclusion_map package_files
 292
 293   if {$package == "."} {
 294     set pkgname ordinary
 295   } else {
 296     set pkgname $package
 297   }
 298   set varname [join [split $pkgname /] _]_source_files
 299   set base $pkgname
 300   set lname $base.list
 301   set dname $base.deps
 302
 303   if {$pkgname == "java/lang"} {
 304     # Object and Class are special cases due to an apparent compiler
 305     # bug.  Process is a special case because we don't build all
 306     # concrete implementations of Process on all platforms.
 307     set omit "| tr ' ' '\\n' | fgrep -v Object.class | fgrep -v Class.class | egrep -v '\(Ecos\|Posix\|Win32\)Process' "
 308   } else {
 309     set omit ""
 310   }
 311
 312   # A rule to make the phony file we are going to compile.
 313   puts "$lname: \$($varname)"
 314   puts "\t@\$(mkinstalldirs) \$(dir \$@)"
 315   puts "\techo \$(srcdir)/classpath/lib/$package/*.class $omit> $lname"
 316   puts ""
 317   puts "-include $dname"
 318   puts ""
 319   puts ""
 320
 321   if {$pkgname != "gnu/gcj/xlib" && $pkgname != "gnu/awt/xlib"
 322       && $pkgname != "gnu/gcj/tools/gcj_dbtool"} {
 323     lappend package_files $lname
 324   }
 325 }
 326
 327 # Emit a rule to build a package full of 'ordinary' files, that is,
 328 # one .o for each .java.
 329 proc emit_ordinary_rule {package} {
 330   global name_map package_files
 331
 332   foreach file $name_map($package) {
 333     # Strip off the '.java'.
 334     set root [file rootname $file]
 335
 336     # Look for all included .class files.  Assumes that we don't have
 337     # multiple top-level classes in a .java file.
 338     set lname $root.list
 339     set dname $root.deps
 340
 341     puts "$lname: classpath/$file"
 342     puts "\t@\$(mkinstalldirs) \$(dir \$@)"
 343     puts "\techo \$(srcdir)/classpath/lib/${root}*.class> $lname"
 344     puts ""
 345     puts "-include $dname"
 346     puts ""
 347     puts ""
 348
 349     lappend package_files $lname
 350   }
 351 }
 352
 353 # Emit a package-like rule for a platform-specific Process
 354 # implementation.
 355 proc emit_process_package_rule {platform} {
 356   set base "java/process-$platform"
 357   set lname $base.list
 358   set dname $base.deps
 359
 360   puts "$lname: java/lang/${platform}Process.java"
 361   puts "\t@\$(mkinstalldirs) \$(dir \$@)"
 362   puts "\techo \$(srcdir)/classpath/lib/java/lang/${platform}Process*.class > $lname"
 363   puts ""
 364   puts "-include $dname"
 365   puts ""
 366   puts ""
 367 }
 368
 369 # Emit a source file variable for a package, and corresponding header
 370 # file variable, if needed.
 371 proc emit_source_var {package} {
 372   global package_map name_map dir_map header_vars
 373
 374   if {$package == "."} {
 375     set pkgname ordinary
 376   } else {
 377     set pkgname $package
 378   }
 379   set uname [join [split $pkgname /] _]
 380   set varname ${uname}_source_files
 381   puts -nonewline "$varname ="
 382
 383   makearray dirs
 384   foreach base [lsort $name_map($package)] {
 385     # Terminate previous line.
 386     puts " \\"
 387     # Having files start with './' is ugly and confuses the automake
 388     # "dirstamp" code; see automake PR 461.
 389     set ndir $dir_map($base)/
 390     if {$ndir == "./"} {
 391       set ndir ""
 392     }
 393     puts -nonewline "${ndir}${base}"
 394     set dirs($dir_map($base)) 1
 395   }
 396   puts ""
 397   puts ""
 398
 399   if {$package_map($package) != "bc"} {
 400     # Ugly code to build up the appropriate patsubst.
 401     set result "\$(patsubst %.java,%.h,\$($varname))"
 402     # We use -decreasing so that classpath/external will be stripped
 403     # before classpath.
 404     foreach dir [lsort -decreasing [array names dirs]] {
 405       if {$dir != "."} {
 406         set result "\$(patsubst $dir/%,%,$result)"
 407       }
 408     }
 409
 410     if {$package == "." || $package == "java/lang"} {
 411       # Ugly hack.
 412       set result "\$(filter-out java/lang/Object.h java/lang/Class.h,$result)"
 413     }
 414
 415     puts "${uname}_header_files = $result"
 416     puts ""
 417     if {$pkgname != "gnu/gcj/xlib" && $pkgname != "gnu/awt/xlib"} {
 418       lappend header_vars "${uname}_header_files"
 419     }
 420   }
 421 }
 422
 423 # Pretty-print a Makefile variable.
 424 proc pp_var {name valueList {pre ""} {post ""}} {
 425   puts ""
 426   puts -nonewline "$name ="
 427   foreach val $valueList {
 428     puts " \\"
 429     puts -nonewline "  ${pre}${val}${post}"
 430   }
 431   puts ""
 432 }
 433
 434 global argv
 435 if {[llength $argv] > 0 && [lindex $argv 0] == "-verbose"} {
 436   set is_verbose 1
 437 }
 438
 439 # Read the proper .omit files.
 440 read_omit_file standard.omit.in
 441 read_omit_file classpath/lib/standard.omit.in
 442
 443 # Scan classpath first.
 444 scan_packages classpath
 445 scan_packages classpath/external/sax
 446 scan_packages classpath/external/w3c_dom
 447 scan_packages classpath/external/relaxngDatatype
 448 scan_packages classpath/external/jsr166
 449 # Resource files.
 450 scan_packages classpath/resource
 451 # Now scan our own files; this will correctly override decisions made
 452 # when scanning classpath.
 453 scan_packages .
 454 # Files created by the build.
 455 classify_source_file classpath gnu/java/locale/LocaleData.java
 456 classify_source_file classpath gnu/java/security/Configuration.java
 457
 458 puts "## This file was automatically generated by scripts/makemake.tcl"
 459 puts "## Do not edit!"
 460 puts ""
 461
 462 foreach package [lsort [array names package_map]] {
 463   if {$package_map($package) == "ignore"} {
 464     continue
 465   }
 466   if {! [info exists name_map($package)]} {
 467     continue
 468   }
 469
 470   emit_source_var $package
 471
 472   if {$package_map($package) == "bc"} {
 473     emit_bc_rule $package
 474   } elseif {$package_map($package) == "bcheaders"} {
 475     emit_bc_rule $package
 476   } elseif {$package_map($package) == "ordinary"} {
 477     emit_ordinary_rule $package
 478   } elseif {$package_map($package) == "package"} {
 479     emit_package_rule $package
 480   } else {
 481     error "unrecognized type: $package_map($package)"
 482   }
 483 }
 484
 485 emit_process_package_rule Ecos
 486 emit_process_package_rule Win32
 487 emit_process_package_rule Posix
 488
 489 pp_var all_packages_source_files $package_files
 490 pp_var ordinary_header_files $header_vars "\$(" ")"
 491 pp_var bc_objects $bc_objects
 492 pp_var property_files $properties_files