libjava/scripts/makemake.tcl

   1 #!/usr/bin/tclsh
   2
   3 # Helper to enforce array-ness.
   4 proc makearray {name} {
   5   upvar $name ary
   6   set ary(_) 1
   7   unset ary(_)
   8 }
   9
  10 global is_verbose
  11 set is_verbose 0
  12
  13 # Verbose printer.
  14 proc verbose {text} {
  15   global is_verbose
  16   if {$is_verbose} {
  17     puts stderr $text
  18   }
  19 }
  20
  21 # This maps a name to its style:
  22 # * bc    objects in this package and all its sub-packages
  23 #         are to be compiled with the BC ABI.  It is an error
  24 #         for sub-packages to also appear in the map.
  25 # * bcheaders
  26 #         as bc, but generate header files and compile with CNI.
  27 # * package
  28 #         objects in this package (and possibly sub-packages,
  29 #         if they do not appear in the map) will be compiled en masse
  30 #         from source into a single object, using the C++ ABI.
  31 # * ordinary
  32 #         objects in this package (and possibly sub-packages
  33 #         if they do not appear in the map) will be compiled one at
  34 #         a time into separate .o files.
  35 # * ignore
  36 #         objects in this package are not used.  Note however that
  37 #         most ignored files are actually handled by listing them in
  38 #         'standard.omit'
  39 # * interpreter
  40 #         objects in this package (and possibly sub-packages,
  41 #         if they do not appear in the map) are only compiled if
  42 #         the interpreter is enabled.  They are compiled as with the
  43 #         'package' specifier.
  44 #
  45 # If a package does not appear in the map, the default is 'package'.
  46 global package_map
  47 set package_map(.) package
  48
  49 # These are ignored in Classpath.
  50 set package_map(gnu/test) ignore
  51 set package_map(gnu/javax/swing/plaf/gtk) ignore
  52 set package_map(gnu/gcj/tools/gc_analyze) ignore
  53
  54 set package_map(gnu/java/awt/peer/swing) bc
  55
  56 set package_map(gnu/xml/aelfred2) bc
  57 set package_map(gnu/xml/dom) bc
  58 set package_map(gnu/xml/libxmlj) bc
  59 set package_map(gnu/xml/pipeline) bc
  60 set package_map(gnu/xml/stream) bc
  61 set package_map(gnu/xml/transform) bc
  62 set package_map(gnu/xml/util) bc
  63 set package_map(gnu/xml/validation) bc
  64 set package_map(gnu/xml/xpath) bc
  65 set package_map(javax/imageio) bc
  66 set package_map(javax/xml) bc
  67 set package_map(gnu/java/beans) bc
  68 set package_map(gnu/java/awt/dnd/peer/gtk) bc
  69 set package_map(gnu/java/util/prefs/gconf) bc
  70 set package_map(gnu/java/awt/peer/gtk) bc
  71 set package_map(gnu/java/awt/dnd/peer/gtk) bc
  72 set package_map(gnu/java/awt/peer/qt) bc
  73 set package_map(gnu/java/awt/peer/x) bc
  74 set package_map(gnu/java/util/prefs/gconf) bc
  75 set package_map(gnu/javax/sound/midi) bc
  76 set package_map(gnu/javax/sound/sampled/gstreamer) ignore
  77 set package_map(org/xml) bc
  78 set package_map(org/w3c) bc
  79 set package_map(org/relaxng) bc
  80 set package_map(javax/rmi) bc
  81 set package_map(org/omg) bc
  82 set package_map(gnu/CORBA) bc
  83 set package_map(gnu/javax/rmi) bc
  84 set package_map(gnu/java/lang/management) bcheaders
  85 set package_map(java/lang/management) bc
  86 set package_map(gnu/classpath/management) bc
  87 set package_map(gnu/javax/management) bc
  88
  89 # parser/HTML_401F.class is really big, and there have been complaints
  90 # about this package requiring too much memory to build.  So, we
  91 # compile it as separate objects.  But, we're careful to compile the
  92 # sub-packages as packages.
  93 set package_map(gnu/javax/swing/text/html/parser) ordinary
  94 set package_map(gnu/javax/swing/text/html/parser/models) package
  95 set package_map(gnu/javax/swing/text/html/parser/support) package
  96
  97 # More special cases.  These end up in their own library.
  98 # Note that if we BC-compile AWT we must update these as well.
  99 set package_map(gnu/gcj/xlib) package
 100 set package_map(gnu/awt/xlib) package
 101
 102 # These packages should only be included if the interpreter is
 103 # enabled.
 104 set package_map(gnu/classpath/jdwp) interpreter
 105 set package_map(gnu/classpath/jdwp/event) interpreter
 106 set package_map(gnu/classpath/jdwp/event/filters) interpreter
 107 set package_map(gnu/classpath/jdwp/exception) interpreter
 108 set package_map(gnu/classpath/jdwp/id) interpreter
 109 set package_map(gnu/classpath/jdwp/processor) interpreter
 110 set package_map(gnu/classpath/jdwp/transport) interpreter
 111 set package_map(gnu/classpath/jdwp/util) interpreter
 112 set package_map(gnu/classpath/jdwp/value) interpreter
 113 set package_map(gnu/gcj/jvmti) interpreter
 114
 115 # Some BC ABI packages have classes which must not be compiled BC.
 116 # This maps such packages to a grep expression for excluding such
 117 # classes.
 118 global exclusion_map
 119 makearray exclusion_map
 120 # set exclusion_map(java/awt) AWTPermission
 121
 122 # This maps a package name to a list of corresponding .java file base
 123 # names.  The package name will either appear as a key in package_map,
 124 # or it will be '.' for the default.
 125 global name_map
 126 makearray name_map
 127
 128 # This maps a java file base name, like 'java/lang/Object.java', to
 129 # the source directory in which it resides.  We keep a layer of
 130 # indirection here so that we can override sources in Classpath with
 131 # our own sources.
 132 global dir_map
 133 makearray dir_map
 134
 135 # An entry in this map means that all .properties files in the
 136 # corresponding directory should be ignored.
 137 global properties_map
 138 makearray properties_map
 139
 140 # logging.properties is installed and is editable.
 141 set properties_map(java/util/logging) _
 142 # We haven't merged locale resources yet.
 143 set properties_map(gnu/java/locale) _
 144
 145 # We want to be able to load xerces if it is on the class path.  So,
 146 # we have to avoid compiling in the XML-related service files.
 147 set properties_map(META-INF/services/javax.xml.parsers.DocumentBuilderFactory) _
 148 set properties_map(META-INF/services/javax.xml.parsers.SAXParserFactory) _
 149 set properties_map(META-INF/services/javax.xml.parsers.TransformerFactory) _
 150 set properties_map(META-INF/services/org.relaxng.datatype.DatatypeLibraryFactory) _
 151 set properties_map(META-INF/services/org.w3c.dom.DOMImplementationSourceList) _
 152 set properties_map(META-INF/services/org.xml.sax.driver) _
 153 set properties_map(META-INF/services/javax.sound.sampled.spi.AudioFileReader.in) ignore
 154 set properties_map(META-INF/services/javax.sound.sampled.spi.MixerProvider) ignore
 155 set properties_map(META-INF/services/javax.sound.sampled.spi.MixerProvider.in) ignore
 156
 157 # List of all properties files.
 158 set properties_files {}
 159
 160 # List of all '@' files that we are going to compile.
 161 set package_files {}
 162
 163 # List of all '@' files that we are going to compile if the
 164 # interpreter is enabled.
 165 set interpreter_package_files {}
 166
 167 # List of all header file variables.
 168 set header_vars {}
 169
 170 # List of all header file variables for interpreter packages.
 171 set interpreter_header_vars {}
 172
 173 # List of all BC object files.
 174 set bc_objects {}
 175
 176 # List of regexps for matching ignored files.
 177 set ignore_rx_list {}
 178
 179
 180 # Return true if a given file should be ignored.
 181 # The argument is the path name including the package part.
 182 proc ignore_file_p {file} {
 183   global ignore_rx_list
 184   foreach rx $ignore_rx_list {
 185     if {[regexp -- $rx $file]} {
 186       verbose "ignoring $file for $rx"
 187       return 1
 188     }
 189   }
 190   return 0
 191 }
 192
 193 # Read a '.omit' file and update the internal data structures.
 194 proc read_omit_file {name} {
 195   global ignore_rx_list
 196   set fd [open $name r]
 197   while {! [eof $fd]} {
 198     set line [gets $fd]
 199
 200     # Classpath's entries bogusly start with "../".
 201     if {[string match ../* $line]} {
 202       set line [string range $line 3 end]
 203     }
 204
 205     if {$line != ""} {
 206       lappend ignore_rx_list $line
 207     }
 208   }
 209   close $fd
 210 }
 211
 212 # Classify a single source file.
 213 proc classify_source_file {basedir file} {
 214   global package_map name_map dir_map
 215
 216   if {[ignore_file_p $file]} {
 217     return
 218   }
 219
 220   set seen [info exists dir_map($file)]
 221   set dir_map($file) $basedir
 222   set pkg $file
 223   while {1} {
 224     if {[info exists package_map($pkg)]} {
 225       # If the entry is 'package', then set up a new entry for the
 226       # file's package.
 227       if {$package_map($pkg) == "package"} {
 228         set pkg [file dirname $file]
 229         set package_map($pkg) package
 230       }
 231       verbose "classify succeeded: $file -> $pkg"
 232       if {! $seen} {
 233         lappend name_map($pkg) $file
 234       }
 235       return
 236     }
 237     set pkg [file dirname $pkg]
 238   }
 239   error "can't happen"
 240 }
 241
 242 # Scan a directory and its subdirectories for .java source files or
 243 # .properties files.  Note that we keep basedir and subdir separate so
 244 # we can properly update our global data structures.
 245 proc scan_directory {basedir subdir} {
 246   global dir_map properties_map properties_files
 247
 248   set subdirs {}
 249   set files {}
 250   set here [pwd]
 251   cd $basedir/$subdir
 252   foreach file [lsort [glob -nocomplain *]] {
 253     if {[string match *.java $file]} {
 254       lappend files $subdir/$file
 255     } elseif {[string match *.properties $file]} {
 256       if {! [info exists properties_map($subdir)]} {
 257         # We assume there aren't any overrides.
 258         lappend properties_files $basedir/$subdir/$file
 259       }
 260     } elseif {[string match *.css $file]} {
 261         # Special case for default.css needed by javax.swing.text.html.
 262         lappend properties_files $basedir/$subdir/$file
 263     } elseif {[file isdirectory $file]} {
 264       lappend subdirs $subdir/$file
 265     } elseif {$subdir == "META-INF/services"} {
 266       # Service files are generally included as properties.
 267       if {! [info exists properties_map($subdir/$file)]} {
 268         lappend properties_files $basedir/$subdir/$file
 269       }
 270     }
 271   }
 272   cd $here
 273
 274   # Recurse first, so that we don't create new packages too eagerly.
 275   foreach dir $subdirs {
 276     scan_directory $basedir $dir
 277   }
 278
 279   foreach file $files {
 280     classify_source_file $basedir $file
 281   }
 282 }
 283
 284 # Scan known packages beneath the base directory for .java source
 285 # files.
 286 proc scan_packages {basedir} {
 287   foreach subdir {gnu java javax org sun com META-INF} {
 288     if {[file exists $basedir/$subdir]} {
 289       scan_directory $basedir $subdir
 290     }
 291   }
 292 }
 293
 294 # Emit a rule for a 'bc' package.
 295 proc emit_bc_rule {package} {
 296   global package_map exclusion_map bc_objects
 297
 298   if {$package == "."} {
 299     set pkgname ordinary
 300   } else {
 301     set pkgname $package
 302   }
 303   set varname [join [split $pkgname /] _]_source_files
 304   set loname [join [split $pkgname /] -].lo
 305   set tname [join [split $pkgname /] -].list
 306
 307   puts "$loname: \$($varname)"
 308   # Create a temporary list file and then compile it.  This works
 309   # around the libtool problem mentioned in PR 21058.  classpath was
 310   # built first, so the class files are to be found there.
 311   set omit ""
 312   if {[info exists exclusion_map($package)]} {
 313     set omit "| grep -v $exclusion_map($package)"
 314   }
 315   puts  "\t@find \$(srcdir)/classpath/lib/$package -name '*.class'${omit} > $tname"
 316   puts -nonewline "\t\$(LTGCJCOMPILE) -fsource-filename=\$(here)/classpath/lib/classes "
 317   if {$package_map($package) == "bc"} {
 318     puts -nonewline "-fjni "
 319   }
 320   # Unless bc is disabled with --disable-libgcj-bc, $(LIBGCJ_BC_FLAGS) is:
 321   #   -findirect-dispatch -fno-indirect-classes
 322   puts "\$(LIBGCJ_BC_FLAGS) -c -o $loname @$tname"
 323   puts "\t@rm -f $tname"
 324   puts ""
 325
 326   # We skip these because they are built into their own libraries and
 327   # are handled specially in Makefile.am.
 328   if {$loname != "gnu-java-awt-peer-qt.lo" && $loname != "gnu-java-awt-peer-x.lo"} {
 329     lappend bc_objects $loname
 330   }
 331 }
 332
 333 # Emit a rule for a 'package' package.
 334 proc emit_package_rule_to_list {package package_files_list} {
 335   global package_map exclusion_map $package_files_list
 336
 337   if {$package == "."} {
 338     set pkgname ordinary
 339   } else {
 340     set pkgname $package
 341   }
 342   set varname [join [split $pkgname /] _]_source_files
 343   set base $pkgname
 344   set lname $base.list
 345   set dname $base.deps
 346
 347   if {$pkgname == "java/lang"} {
 348     # Object and Class are special cases due to an apparent compiler
 349     # bug.  Process is a special case because we don't build all
 350     # concrete implementations of Process on all platforms.
 351     set omit "| tr ' ' '\\n' | fgrep -v Object.class | fgrep -v Class.class | egrep -v '\(Ecos\|Posix\|Win32\)Process' "
 352   } else {
 353     set omit ""
 354   }
 355
 356   # A rule to make the phony file we are going to compile.
 357   puts "$lname: \$($varname)"
 358   puts "\t@\$(mkinstalldirs) \$(dir \$@)"
 359   puts "\techo \$(srcdir)/classpath/lib/$package/*.class $omit> $lname"
 360   puts ""
 361   puts "-include $dname"
 362   puts ""
 363   puts ""
 364
 365   if {$pkgname != "gnu/gcj/xlib" && $pkgname != "gnu/awt/xlib"
 366       && $pkgname != "gnu/gcj/tools/gcj_dbtool"} {
 367     lappend  $package_files_list $lname
 368   }
 369 }
 370
 371 proc emit_package_rule {package} {
 372   global package_files
 373   emit_package_rule_to_list $package package_files
 374 }
 375
 376 proc emit_interpreter_rule {package} {
 377   global interpreter_package_files
 378   emit_package_rule_to_list $package interpreter_package_files
 379 }
 380
 381 # Emit a rule to build a package full of 'ordinary' files, that is,
 382 # one .o for each .java.
 383 proc emit_ordinary_rule {package} {
 384   global name_map package_files
 385
 386   foreach file $name_map($package) {
 387     # Strip off the '.java'.
 388     set root [file rootname $file]
 389
 390     # Look for all included .class files.  Assumes that we don't have
 391     # multiple top-level classes in a .java file.
 392     set lname $root.list
 393     set dname $root.deps
 394
 395     puts "$lname: classpath/$file"
 396     puts "\t@\$(mkinstalldirs) \$(dir \$@)"
 397     puts "\techo \$(srcdir)/classpath/lib/${root}*.class> $lname"
 398     puts ""
 399     puts "-include $dname"
 400     puts ""
 401     puts ""
 402
 403     lappend package_files $lname
 404   }
 405 }
 406
 407 # Emit a package-like rule for a platform-specific Process
 408 # implementation.
 409 proc emit_process_package_rule {platform} {
 410   set base "java/process-$platform"
 411   set lname $base.list
 412   set dname $base.deps
 413
 414   puts "$lname: java/lang/${platform}Process.java"
 415   puts "\t@\$(mkinstalldirs) \$(dir \$@)"
 416   puts "\techo \$(srcdir)/classpath/lib/java/lang/${platform}Process*.class > $lname"
 417   puts ""
 418   puts "-include $dname"
 419   puts ""
 420   puts ""
 421 }
 422
 423 # Emit a source file variable for a package, and corresponding header
 424 # file variable, if needed.
 425 proc emit_source_var {package} {
 426   global package_map name_map dir_map header_vars interpreter_header_vars
 427
 428   if {$package == "."} {
 429     set pkgname ordinary
 430   } else {
 431     set pkgname $package
 432   }
 433   set uname [join [split $pkgname /] _]
 434   set varname ${uname}_source_files
 435   puts -nonewline "$varname ="
 436
 437   makearray dirs
 438   foreach base [lsort $name_map($package)] {
 439     # Terminate previous line.
 440     puts " \\"
 441     # Having files start with './' is ugly and confuses the automake
 442     # "dirstamp" code; see automake PR 461.
 443     set ndir $dir_map($base)/
 444     if {$ndir == "./"} {
 445       set ndir ""
 446     }
 447     puts -nonewline "${ndir}${base}"
 448     set dirs($dir_map($base)) 1
 449   }
 450   puts ""
 451   puts ""
 452
 453   if {$package_map($package) != "bc"} {
 454     # Ugly code to build up the appropriate patsubst.
 455     set result "\$(patsubst %.java,%.h,\$($varname))"
 456     # We use -decreasing so that classpath/external will be stripped
 457     # before classpath.
 458     foreach dir [lsort -decreasing [array names dirs]] {
 459       if {$dir != "."} {
 460         set result "\$(patsubst $dir/%,%,$result)"
 461       }
 462     }
 463
 464     if {$package == "." || $package == "java/lang"} {
 465       # Ugly hack.
 466       set result "\$(filter-out java/lang/Object.h java/lang/Class.h,$result)"
 467     }
 468
 469     puts "${uname}_header_files = $result"
 470     puts ""
 471     if {$pkgname != "gnu/gcj/xlib" && $pkgname != "gnu/awt/xlib"} {
 472         if {$package_map($package) == "interpreter"} {
 473           lappend interpreter_header_vars "${uname}_header_files"
 474         } else {
 475           lappend header_vars "${uname}_header_files"
 476         }
 477     }
 478   }
 479 }
 480
 481 # Pretty-print a Makefile variable.
 482 proc pp_var {name valueList {pre ""} {post ""}} {
 483   puts ""
 484   puts -nonewline "$name ="
 485   foreach val $valueList {
 486     puts " \\"
 487     puts -nonewline "  ${pre}${val}${post}"
 488   }
 489   puts ""
 490 }
 491
 492 global argv
 493 if {[llength $argv] > 0 && [lindex $argv 0] == "-verbose"} {
 494   set is_verbose 1
 495 }
 496
 497 # Read the proper .omit files.
 498 read_omit_file standard.omit.in
 499 read_omit_file classpath/lib/standard.omit.in
 500
 501 # Scan classpath first.
 502 scan_packages classpath
 503 scan_packages classpath/external/sax
 504 scan_packages classpath/external/w3c_dom
 505 scan_packages classpath/external/relaxngDatatype
 506 scan_packages classpath/external/jsr166
 507 # Resource files.
 508 scan_packages classpath/resource
 509 # Now scan our own files; this will correctly override decisions made
 510 # when scanning classpath.
 511 scan_packages .
 512 # Files created by the build.
 513 classify_source_file classpath gnu/java/locale/LocaleData.java
 514 classify_source_file classpath gnu/java/security/Configuration.java
 515
 516 puts "## This file was automatically generated by scripts/makemake.tcl"
 517 puts "## Do not edit!"
 518 puts ""
 519
 520 foreach package [lsort [array names package_map]] {
 521   if {$package_map($package) == "ignore"} {
 522     continue
 523   }
 524   if {! [info exists name_map($package)]} {
 525     continue
 526   }
 527
 528   emit_source_var $package
 529
 530   if {$package_map($package) == "bc"} {
 531     emit_bc_rule $package
 532   } elseif {$package_map($package) == "bcheaders"} {
 533     emit_bc_rule $package
 534   } elseif {$package_map($package) == "ordinary"} {
 535     emit_ordinary_rule $package
 536   } elseif {$package_map($package) == "package"} {
 537     emit_package_rule $package
 538   } elseif {$package_map($package) == "interpreter"} {
 539     emit_interpreter_rule $package
 540   } else {
 541     error "unrecognized type: $package_map($package)"
 542   }
 543 }
 544
 545 emit_process_package_rule Ecos
 546 emit_process_package_rule Win32
 547 emit_process_package_rule Posix
 548
 549 puts "if INTERPRETER"
 550 pp_var interpreter_packages_source_files $interpreter_package_files
 551 pp_var interpreter_header_files $interpreter_header_vars "\$(" ")"
 552 puts ""
 553 puts "else"
 554 puts ""
 555 puts "interpreter_packages_source_files="
 556 puts ""
 557 puts "interpreter_header_files="
 558 puts ""
 559 puts "endif"
 560
 561 lappend package_files {$(interpreter_packages_source_files)}
 562 lappend header_vars interpreter_header_files
 563
 564 pp_var all_packages_source_files $package_files
 565 pp_var ordinary_header_files $header_vars "\$(" ")"
 566 pp_var bc_objects $bc_objects
 567 pp_var property_files $properties_files