libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -n "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67 dnl See if the user has requested runtime debugging.
  68 LIBGCJDEBUG="false"
  69 AC_SUBST(LIBGCJDEBUG)
  70 AC_ARG_ENABLE(libgcj-debug,
  71 [  --enable-libgcj-debug   enable runtime debugging code],
  72   if test "$enable_libgcj_debug" = yes; then
  73     AC_DEFINE(DEBUG)
  74     LIBGCJDEBUG="true"
  75   fi)
  76
  77 dnl See if the user has the interpreter included.
  78 AC_ARG_ENABLE(interpreter,
  79 [  --enable-interpreter    enable interpreter],
  80   if test "$enable_interpreter" = yes; then
  81     # This can also be set in configure.host.
  82     libgcj_interpreter=yes
  83   elif test "$enable_interpreter" = no; then
  84     libgcj_interpreter=no
  85   fi)
  86
  87 if test "$libgcj_interpreter" = yes; then
  88    AC_DEFINE(INTERPRETER)
  89 fi
  90
  91 AC_MSG_CHECKING([for exception model to use])
  92 AC_LANG_SAVE
  93 AC_LANG_CPLUSPLUS
  94 AC_ARG_ENABLE(sjlj-exceptions,
  95 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
  96 [:],
  97 [dnl Botheration.  Now we've got to detect the exception model.
  98 dnl Link tests against libgcc.a are problematic since -- at least
  99 dnl as of this writing -- we've not been given proper -L bits for
 100 dnl single-tree newlib and libgloss.
 101 dnl
 102 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 103 dnl conftest files before we got a change to grep them first.
 104 cat > conftest.$ac_ext << EOF
 105 [#]line __oline__ "configure"
 106 struct S { ~S(); };
 107 void bar();
 108 void foo()
 109 {
 110   S s;
 111   bar();
 112 }
 113 EOF
 114 old_CXXFLAGS="$CXXFLAGS"
 115 CXXFLAGS=-S
 116 if AC_TRY_EVAL(ac_compile); then
 117   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 118     enable_sjlj_exceptions=yes
 119   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 120     enable_sjlj_exceptions=no
 121   fi
 122 fi
 123 CXXFLAGS="$old_CXXFLAGS"
 124 rm -f conftest*])
 125 if test x$enable_sjlj_exceptions = xyes; then
 126   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 127         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 128   ac_exception_model_name=sjlj
 129 elif test x$enable_sjlj_exceptions = xno; then
 130   ac_exception_model_name="call frame"
 131 else
 132   AC_MSG_ERROR([unable to detect exception model])
 133 fi
 134 AC_LANG_RESTORE
 135 AC_MSG_RESULT($ac_exception_model_name)
 136
 137 AC_MSG_CHECKING([for data_start])
 138 LIBDATASTARTSPEC=
 139 NEEDS_DATA_START=
 140 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 141   [AC_MSG_RESULT(found it)],
 142   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 143    NEEDS_DATA_START=yes
 144    AC_MSG_RESULT(missing)])
 145 AC_SUBST(LIBDATASTARTSPEC)
 146
 147 dnl See if the user wants to disable java.net.  This is the mildly
 148 dnl ugly way that we admit that target-side configuration sucks.
 149 AC_ARG_ENABLE(java-net,
 150 [  --disable-java-net      disable java.net])
 151
 152 dnl Whether java.net is built by default can depend on the target.
 153 if test -n "$enable_java_net"; then
 154    enable_java_net=${enable_java_net_default-yes}
 155 fi
 156 if test "$enable_java_net" = no; then
 157    AC_DEFINE(DISABLE_JAVA_NET)
 158 fi
 159
 160 dnl See if the user wants to disable JVMPI support.
 161 AC_ARG_ENABLE(jvmpi,
 162 [  --disable-jvmpi         disable JVMPI support])
 163
 164 if test "$enable_jvmpi" != no; then
 165     AC_DEFINE(ENABLE_JVMPI)
 166 fi
 167
 168 dnl If the target is an eCos system, use the appropriate eCos
 169 dnl I/O routines.
 170 dnl FIXME: this should not be a local option but a global target
 171 dnl system; at present there is no eCos target.
 172 TARGET_ECOS="no"
 173 AC_ARG_WITH(ecos,
 174 [  --with-ecos             enable runtime eCos target support],
 175 TARGET_ECOS="$with_ecos"
 176 )
 177
 178 case "$TARGET_ECOS" in
 179    no)
 180       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 181       PROCESS=${PROCESS-Posix}
 182       ;;
 183    *)
 184       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 185       PROCESS=Ecos
 186       AC_DEFINE(ECOS)
 187       ;;
 188 esac
 189
 190 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 191 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 192 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 193 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 194
 195
 196 dnl These may not be defined in a non-ANS conformant embedded system.
 197 dnl FIXME: Should these case a runtime exception in that case?
 198 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 199 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 200
 201 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 202 dnl to create the link will fail.
 203 test -d java || mkdir java
 204 test -d java/io || mkdir java/io
 205 test -d gnu || mkdir gnu
 206 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 207
 208 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 209 test -d java/lang || mkdir java/lang
 210 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 211 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 212
 213 SYSTEMSPEC=
 214 AC_SUBST(SYSTEMSPEC)
 215
 216 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 217 AC_SUBST(LIBGCJTESTSPEC)
 218
 219 AC_ARG_WITH(system-zlib,
 220 [  --with-system-zlib      use installed libz])
 221 ZLIBSPEC=
 222 AC_SUBST(ZLIBSPEC)
 223 ZLIBTESTSPEC=
 224 AC_SUBST(ZLIBTESTSPEC)
 225
 226 dnl FIXME: this should be _libs on some hosts.
 227 libsubdir=.libs
 228
 229 dnl Allow the GC to be disabled.  Can be useful when debugging.
 230 AC_MSG_CHECKING([for garbage collector to use])
 231 AC_ARG_ENABLE(java-gc,
 232 changequote(<<,>>)dnl
 233 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 234 changequote([,])
 235   GC=$enableval,
 236   GC=boehm)
 237 GCLIBS=
 238 GCINCS=
 239 GCDEPS=
 240 GCOBJS=
 241 GCSPEC=
 242 JC1GCSPEC=
 243 GCTESTSPEC=
 244 case "$GC" in
 245  boehm)
 246     AC_MSG_RESULT(boehm)
 247     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 248     # We include the path to the boehm-gc build directory.
 249     # See Makefile.am to understand why.
 250     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 251     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 252     GCSPEC='-lgcjgc'
 253     JC1GCSPEC='-fuse-boehm-gc'
 254     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 255     dnl We also want to pick up some cpp flags required when including
 256     dnl boehm-config.h.  Yuck.
 257     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 258     GCOBJS=boehm.lo
 259     GCHDR=boehm-gc.h
 260     dnl The POSIX thread support needs to know this.
 261     AC_DEFINE(HAVE_BOEHM_GC)
 262     ;;
 263  no)
 264     AC_MSG_RESULT(none)
 265     GCOBJS=nogc.lo
 266     GCHDR=no-gc.h
 267     ;;
 268  *)
 269     AC_MSG_ERROR(unrecognized collector \"$GC\")
 270     ;;
 271 esac
 272 AC_SUBST(GCLIBS)
 273 AC_SUBST(GCINCS)
 274 AC_SUBST(GCDEPS)
 275 AC_SUBST(GCOBJS)
 276 AC_SUBST(GCSPEC)
 277 AC_SUBST(JC1GCSPEC)
 278 AC_SUBST(GCTESTSPEC)
 279 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 280
 281
 282 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 283 dnl In particular both packages must make the same decision about which
 284 dnl thread package to use.
 285 AC_MSG_CHECKING([for threads package to use])
 286 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 287   THREADS=$enableval,
 288   dnl FIXME: figure out native threads to use here.
 289   THREADS=no)
 290
 291 if test "$THREADS" = yes; then
 292    case "$host" in
 293     *-*-vxworks*)
 294        THREADS=vxworks
 295        ;;
 296     *-*-linux*)
 297        # FIXME: this isn't correct in all cases.
 298        THREADS=posix
 299        ;;
 300     *-*-win*)
 301        THREADS=win32
 302        ;;
 303     *-*-irix*)
 304        # FIXME: for now, choose POSIX, because we implement that.
 305        # Later, choose irix threads.
 306        THREADS=posix
 307        ;;
 308     *-*-solaris*)
 309        # FIXME: for now, choose POSIX, because we implement that.
 310        # Later, choose solaris threads.
 311        THREADS=posix
 312        ;;
 313     *)
 314        # For now.
 315        THREADS=none
 316        ;;
 317    esac
 318 fi
 319
 320 case "$THREADS" in
 321  no | none | single)
 322     THREADS=none
 323     ;;
 324  posix | pthreads)
 325     THREADS=posix
 326     case "$host" in
 327      *-*-linux*)
 328         AC_DEFINE(LINUX_THREADS)
 329         ;;
 330     esac
 331     ;;
 332  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 333     AC_MSG_ERROR(thread package $THREADS not yet supported)
 334     ;;
 335  *)
 336     AC_MSG_ERROR($THREADS is an unknown thread package)
 337     ;;
 338 esac
 339 AC_MSG_RESULT($THREADS)
 340
 341 THREADLIBS=
 342 THREADINCS=
 343 THREADDEPS=
 344 THREADOBJS=
 345 THREADH=
 346 THREADSPEC=
 347 case "$THREADS" in
 348  posix)
 349     THREADLIBS=-lpthread
 350     THREADSPEC=-lpthread
 351     THREADOBJS=posix-threads.lo
 352     THREADH=posix-threads.h
 353     # MIT pthreads doesn't seem to have the mutexattr functions.
 354     # But for now we don't check for it.  We just assume you aren't
 355     # using MIT pthreads.
 356     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 357
 358     # If we're using the Boehm GC, then we happen to know that it
 359     # defines _REENTRANT, so we don't bother.  Eww.
 360     if test "$GC" != boehm; then
 361        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 362     fi
 363     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 364     ;;
 365
 366  none)
 367     THREADOBJS=no-threads.lo
 368     THREADH=no-threads.h
 369     ;;
 370 esac
 371 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 372 AC_SUBST(THREADLIBS)
 373 AC_SUBST(THREADINCS)
 374 AC_SUBST(THREADDEPS)
 375 AC_SUBST(THREADOBJS)
 376 AC_SUBST(THREADSPEC)
 377
 378 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 379
 380 CANADIAN=no
 381 NULL_TARGET=no
 382 NATIVE=yes
 383
 384 # We're in the tree with gcc, and need to include some of its headers.
 385 GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../gcc'
 386
 387 if test -n "${with_cross_host}"; then
 388    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 389    # may not work correctly, because the compiler may not be able to
 390    # link executables.
 391
 392    # We assume newlib.  This lets us hard-code the functions we know
 393    # we'll have.
 394    AC_DEFINE(HAVE_MEMMOVE)
 395    AC_DEFINE(HAVE_MEMCPY)
 396    AC_DEFINE(HAVE_STRERROR)
 397    AC_DEFINE(HAVE_GMTIME_R)
 398    AC_DEFINE(HAVE_LOCALTIME_R)
 399    dnl This is only for POSIX threads.
 400    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 401    dnl We also assume we are using gcc, which provides alloca.
 402    AC_DEFINE(HAVE_ALLOCA)
 403
 404    dnl Assume we do not have getuid and friends.
 405    AC_DEFINE(NO_GETUID)
 406
 407    ZLIBSPEC=-lzgcj
 408    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 409
 410    # If Canadian cross, then don't pick up tools from the build
 411    # directory.
 412    if test "$build" != "$with_cross_host"; then
 413       CANADIAN=yes
 414       GCC_UNWIND_INCLUDE=
 415       GCJ="${target_alias}-gcj"
 416    else
 417       GCJ=
 418    fi
 419    NATIVE=no
 420 else
 421    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 422    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 423    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 424    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 425    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 426    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 427    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 428    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 429    AC_CHECK_LIB(dl, dladdr, [
 430      AC_DEFINE(HAVE_DLADDR)])
 431    AC_CHECK_FILES(/proc/self/exe, [
 432      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 433
 434    AC_CHECK_FUNCS(gethostbyname_r, [
 435      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 436      # There are two different kinds of gethostbyname_r.
 437      # We look for the one that returns `int'.
 438      # Hopefully this check is robust enough.
 439      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 440        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 441
 442      case " $GCINCS " in
 443      *" -D_REENTRANT "*) ;;
 444      *)
 445         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 446         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 447         [libjava_cv_gethostbyname_r_needs_reentrant],
 448         [ AC_LANG_SAVE
 449           AC_LANG_CPLUSPLUS
 450           AC_TRY_COMPILE([#include <netdb.h>],
 451             [gethostbyname_r("", 0, 0);],
 452             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 453                 CPPFLAGS_SAVE="$CPPFLAGS"
 454                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 455                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 456                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 457                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 458                 CPPFLAGS="$CPPFLAGS_SAVE"
 459           ])
 460           AC_LANG_RESTORE
 461         ])
 462         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 463           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 464         fi
 465      ;;
 466      esac
 467
 468      AC_CACHE_CHECK([for struct hostent_data],
 469         [libjava_cv_struct_hostent_data], [dnl
 470         AC_TRY_COMPILE([
 471 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 472 # define _REENTRANT 1
 473 #endif
 474 #include <netdb.h>], [struct hostent_data data;],
 475           [libjava_cv_struct_hostent_data=yes],
 476           [libjava_cv_struct_hostent_data=no])])
 477      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 478        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 479          [Define if struct hostent_data is defined in netdb.h])
 480      fi
 481    ])
 482
 483    AC_CHECK_FUNCS(gethostbyaddr_r, [
 484      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 485      # There are two different kinds of gethostbyaddr_r.
 486      # We look for the one that returns `int'.
 487      # Hopefully this check is robust enough.
 488      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 489        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 490
 491    AC_CHECK_FUNCS(gethostname, [
 492      AC_DEFINE(HAVE_GETHOSTNAME)
 493      AC_EGREP_HEADER(gethostname, unistd.h, [
 494        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 495
 496    # Look for these functions in the thread library, but only bother
 497    # if using POSIX threads.
 498    if test "$THREADS" = posix; then
 499       save_LIBS="$LIBS"
 500       LIBS="$LIBS $THREADLIBS"
 501       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 502       # E.g., Solaris.
 503       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 504
 505       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 506       # Solaris 7 the name librt is preferred.
 507       AC_CHECK_FUNCS(sched_yield, , [
 508         AC_CHECK_LIB(rt, sched_yield, [
 509           AC_DEFINE(HAVE_SCHED_YIELD)
 510           THREADLIBS="$THREADLIBS -lrt"
 511           THREADSPEC="$THREADSPEC -lrt"], [
 512           AC_CHECK_LIB(posix4, sched_yield, [
 513             AC_DEFINE(HAVE_SCHED_YIELD)
 514             THREADLIBS="$THREADLIBS -lposix4"
 515             THREADSPEC="$THREADSPEC -lposix4"])])])
 516       LIBS="$save_LIBS"
 517
 518       # We can save a little space at runtime if the mutex has m_count
 519       # or __m_count.  This is a nice hack for Linux.
 520       AC_TRY_COMPILE([#include <pthread.h>], [
 521           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 522         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 523         AC_TRY_COMPILE([#include <pthread.h>], [
 524             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 525           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 526    fi
 527
 528    # We require a way to get the time.
 529    time_found=no
 530    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 531    if test "$time_found" = no; then
 532       AC_MSG_ERROR([no function found to get the time])
 533    fi
 534
 535    AC_CHECK_FUNCS(memmove)
 536
 537    # We require memcpy.
 538    memcpy_found=no
 539    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 540    if test "$memcpy_found" = no; then
 541       AC_MSG_ERROR([memcpy is required])
 542    fi
 543
 544    # Some library-finding code we stole from Tcl.
 545    #--------------------------------------------------------------------
 546    #    Check for the existence of the -lsocket and -lnsl libraries.
 547    #    The order here is important, so that they end up in the right
 548    #    order in the command line generated by make.  Here are some
 549    #    special considerations:
 550    #    1. Use "connect" and "accept" to check for -lsocket, and
 551    #       "gethostbyname" to check for -lnsl.
 552    #    2. Use each function name only once:  can't redo a check because
 553    #       autoconf caches the results of the last check and won't redo it.
 554    #    3. Use -lnsl and -lsocket only if they supply procedures that
 555    #       aren't already present in the normal libraries.  This is because
 556    #       IRIX 5.2 has libraries, but they aren't needed and they're
 557    #       bogus:  they goof up name resolution if used.
 558    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 559    #       To get around this problem, check for both libraries together
 560    #       if -lsocket doesn't work by itself.
 561    #--------------------------------------------------------------------
 562
 563    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 564     [gcj_cv_lib_sockets=
 565      gcj_checkBoth=0
 566      unset ac_cv_func_connect
 567      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 568      if test "$gcj_checkSocket" = 1; then
 569          unset ac_cv_func_connect
 570          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 571                       gcj_checkBoth=1)
 572      fi
 573      if test "$gcj_checkBoth" = 1; then
 574          gcj_oldLibs=$LIBS
 575          LIBS="$LIBS -lsocket -lnsl"
 576          unset ac_cv_func_accept
 577          AC_CHECK_FUNC(accept,
 578                        [gcj_checkNsl=0
 579                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 580          unset ac_cv_func_accept
 581          LIBS=$gcj_oldLibs
 582      fi
 583      unset ac_cv_func_gethostbyname
 584      gcj_oldLibs=$LIBS
 585      LIBS="$LIBS $gcj_cv_lib_sockets"
 586      AC_CHECK_FUNC(gethostbyname, ,
 587                    [AC_CHECK_LIB(nsl, main,
 588                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 589      unset ac_cv_func_gethostbyname
 590      LIBS=$gcj_oldLIBS
 591    ])
 592    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 593
 594    if test "$with_system_zlib" = yes; then
 595       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 596    else
 597       ZLIBSPEC=-lzgcj
 598       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 599    fi
 600
 601    # On Solaris, and maybe other architectures, the Boehm collector
 602    # requires -ldl.
 603    if test "$GC" = boehm; then
 604       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 605    fi
 606
 607    if test -z "${with_multisubdir}"; then
 608       builddotdot=.
 609    else
 610 changequote(<<,>>)
 611       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 612 changequote([,])
 613    fi
 614    if test -x "${builddotdot}/../../gcc/gcj"; then
 615       dir="`cd ${builddotdot}/../../gcc && pwd`"
 616       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 617    else
 618       CANADIAN=yes
 619       NULL_TARGET=yes
 620       GCJ="gcj -B`pwd`/"
 621    fi
 622 fi
 623
 624 # Create it, so that compile/link tests don't fail
 625 test -f libgcj.spec || touch libgcj.spec
 626
 627 # We must search the source tree for java.lang, since we still don't
 628 # have libgcj.jar nor java/lang/*.class
 629 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 630 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 631
 632 # Since some classes depend on this one, we need its source available
 633 # before we can do any GCJ compilation test :-(
 634 if test ! -f gnu/classpath/Configuration.java; then
 635   test -d gnu || mkdir gnu
 636   test -d gnu/classpath || mkdir gnu/classpath
 637   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 638         < $srcdir/gnu/classpath/Configuration.java.in \
 639         > gnu/classpath/Configuration.java
 640   # We do not want to redirect the output of the grep below to /dev/null,
 641   # but we add /dev/null to the input list so that grep will print the
 642   # filename of Configuration.java in case it finds any matches.
 643   if grep @ gnu/classpath/Configuration.java /dev/null; then
 644     AC_MSG_ERROR([configure.in is missing the substitutions above])
 645   fi
 646 fi
 647
 648 LT_AC_PROG_GCJ
 649
 650 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 651
 652 dnl FIXME: cross compilation
 653 AC_CHECK_SIZEOF(void *)
 654
 655 ZLIBS=
 656 ZDEPS=
 657 ZINCS=
 658 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 659    # We include the path to the zlib build directory.
 660    # See Makefile.am to understand why.
 661    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 662    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 663    ZINCS='-I$(top_srcdir)/../zlib'
 664 else
 665    ZLIBS="$ZLIBSPEC"
 666 fi
 667 AC_SUBST(ZLIBS)
 668 AC_SUBST(ZDEPS)
 669 AC_SUBST(ZINCS)
 670 AC_SUBST(DIVIDESPEC)
 671
 672 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 673 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 674 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 675 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 676 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 677 AC_SUBST(GCC_UNWIND_INCLUDE)
 678
 679 # Determine gcj version number.
 680 changequote(<<,>>)
 681 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 682 changequote([,])
 683 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 684 AC_SUBST(GCJVERSION)
 685
 686 AC_SUBST(AM_RUNTESTFLAGS)
 687
 688 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 689 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 690 save_CFLAGS="$CFLAGS"
 691 CFLAGS="-x c++ -O2 -ffloat-store"
 692 AC_TRY_COMPILE([#include <math.h>], ,
 693   [AC_MSG_RESULT(no)],
 694   [AC_DEFINE(__NO_MATH_INLINES)
 695    AC_MSG_RESULT(yes)])
 696 CFLAGS="$save_CFLAGS"
 697
 698 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 699 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 700 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 701 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 702 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 703 dnl for now.  If you change this, you also must update natFile.cc.
 704 AC_CHECK_HEADERS(dirent.h)
 705
 706 AC_CHECK_TYPE([ssize_t], [int])
 707
 708 AC_MSG_CHECKING([for in_addr_t])
 709 AC_TRY_COMPILE([#include <sys/types.h>
 710 #if STDC_HEADERS
 711 #include <stdlib.h>
 712 #include <stddef.h>
 713 #endif
 714 #if HAVE_NETINET_IN_H
 715 #include <netinet/in.h>
 716 #endif], [in_addr_t foo;],
 717   [AC_DEFINE([HAVE_IN_ADDR_T])
 718    AC_MSG_RESULT(yes)],
 719   [AC_MSG_RESULT(no)])
 720
 721 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 722 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 723   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 724    AC_MSG_RESULT(yes)],
 725   [AC_MSG_RESULT(no)])
 726
 727 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 728 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 729   [AC_DEFINE(HAVE_INET6)
 730    AC_MSG_RESULT(yes)],
 731   [AC_MSG_RESULT(no)])
 732
 733 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 734 AC_TRY_COMPILE([#include <sys/types.h>
 735 #include <sys/socket.h>], [socklen_t x = 5;],
 736   [AC_DEFINE(HAVE_SOCKLEN_T)
 737    AC_MSG_RESULT(yes)],
 738   [AC_MSG_RESULT(no)])
 739
 740 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 741 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 742   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 743    AC_MSG_RESULT(yes)],
 744   [AC_MSG_RESULT(no)
 745    AC_MSG_CHECKING([for global timezone variable])
 746    dnl FIXME: we don't want a link check here because that won't work
 747    dnl when cross-compiling.  So instead we make an assumption that
 748    dnl the header file will mention timezone if it exists.
 749    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 750      [AC_DEFINE(HAVE_TIMEZONE)
 751       AC_MSG_RESULT(yes)],
 752      [AC_MSG_RESULT(no)])])
 753
 754 AC_FUNC_ALLOCA
 755
 756 AC_CHECK_PROGS(PERL, perl, false)
 757
 758 SYSDEP_SOURCES=
 759
 760 case "${host}" in
 761  i?86-*-linux*)
 762     SIGNAL_HANDLER=include/i386-signal.h
 763     ;;
 764  sparc-sun-solaris*)
 765     SIGNAL_HANDLER=include/sparc-signal.h
 766     ;;
 767  ia64-*)
 768     SYSDEP_SOURCES=sysdep/ia64.c
 769     test -d sysdep || mkdir sysdep
 770     ;;
 771  *)
 772     SIGNAL_HANDLER=include/default-signal.h
 773     ;;
 774 esac
 775
 776 # If we're using sjlj exceptions, forget what we just learned.
 777 if test "$libgcj_sjlj" = yes; then
 778    SIGNAL_HANDLER=include/default-signal.h
 779 fi
 780
 781 AC_SUBST(SYSDEP_SOURCES)
 782
 783 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 784
 785 if test "${multilib}" = "yes"; then
 786   multilib_arg="--enable-multilib"
 787 else
 788   multilib_arg=
 789 fi
 790
 791 AC_PATH_XTRA
 792
 793 dnl Determine which AWT peer libraries to build
 794 AC_ARG_ENABLE(java-awt,
 795 [  --enable-java-awt       list of AWT peer implementations to be built])
 796
 797 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 798 use_xlib_awt=""
 799 use_gtk_awt=""
 800
 801 for peer in $peerlibs ; do
 802   case $peer in
 803     xlib)
 804       if [test "$no_x" = yes]; then
 805         echo "*** xlib peers requested but no X library available" 1>&2
 806         exit 1
 807       else
 808         use_xlib_awt="yes"
 809       fi
 810       ;;
 811     gtk)
 812       # Nothing, yet...
 813       ;;
 814     *)
 815       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 816       exit 1
 817   esac
 818 done
 819
 820 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 821 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 822
 823
 824 here=`pwd`
 825 AC_SUBST(here)
 826
 827 # We get this from the environment.
 828 AC_SUBST(GCJFLAGS)
 829
 830 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 831 [if test -n "$CONFIG_FILES"; then
 832   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 833 fi
 834
 835 # Make subdirectories and `.d' files.  Look in both srcdir and
 836 # builddir for the .java files.
 837 h=`pwd`
 838 : > deps.mk
 839 ( (cd $srcdir && find . -name '*.java' -print) ;
 840   find . -name '*.java' -print) | \
 841    fgrep -v testsuite | \
 842    sed -e 's/\.java/.d/' | \
 843    while read f; do
 844       echo "include $f" >> deps.mk
 845       test -f $f || {
 846 changequote(<<,>>)
 847          d=`echo $f | sed -e 's,/[^/]*$,,'`
 848 changequote([,])
 849          $srcdir/../mkinstalldirs $d
 850          echo > $f
 851       }
 852    done
 853 ],
 854 srcdir=${srcdir}
 855 host=${host}
 856 target=${target}
 857 with_multisubdir=${with_multisubdir}
 858 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 859 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 860 libgcj_basedir=${libgcj_basedir}
 861 CC="${CC}"
 862 CXX="${CXX}"
 863 )