libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # When building with srcdir == objdir, links to the source files will
  19 # be created in directories within the target_subdir.  We have to
  20 # adjust toplevel_srcdir accordingly, so that configure finds
  21 # install-sh and other auxiliary files that live in the top-level
  22 # source directory.
  23 if test "${srcdir}" = "."; then
  24   if test -z "${with_target_subdir}"; then
  25     toprel=".."
  26   else
  27     if test "${with_target_subdir}" != "."; then
  28       toprel="${with_multisrctop}../.."
  29     else
  30       toprel="${with_multisrctop}.."
  31     fi
  32   fi
  33 else
  34   toprel=".."
  35 fi
  36
  37 libgcj_basedir=$srcdir/$toprel/./libjava
  38 AC_SUBST(libgcj_basedir)
  39
  40 AC_CANONICAL_SYSTEM
  41 _GCC_TOPLEV_NONCANONICAL_BUILD
  42 _GCC_TOPLEV_NONCANONICAL_TARGET
  43
  44 AC_SUBST(target_noncanonical)
  45
  46 # This works around the fact that libtool configuration may change LD
  47 # for this particular configuration, but some shells, instead of
  48 # keeping the changes in LD private, export them just because LD is
  49 # exported.
  50 ORIGINAL_LD_FOR_MULTILIBS=$LD
  51
  52 AC_PROG_LN_S
  53
  54 # This works around an automake problem.
  55 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  56 AC_SUBST(mkinstalldirs)
  57
  58 AC_ARG_WITH(cross-host,
  59   AS_HELP_STRING([--with-cross-host=HOST],
  60                  [configure with a cross compiler from HOST]))
  61
  62 AC_ARG_WITH(newlib,
  63   AS_HELP_STRING([--with-newlib],
  64                  [configure with newlib]))
  65
  66 AC_ARG_ENABLE(version-specific-runtime-libs,
  67   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  68                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  69     [case "$enableval" in
  70       yes) version_specific_libs=yes ;;
  71       no)  version_specific_libs=no ;;
  72       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  73      esac],
  74     [version_specific_libs=no]
  75 )
  76
  77 # Default to --enable-multilib
  78 AC_ARG_ENABLE(multilib,
  79   AS_HELP_STRING([--enable-multilib],
  80                  [build many library versions (default)]),
  81 [case "${enableval}" in
  82   yes) multilib=yes ;;
  83   no)  multilib=no ;;
  84   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  85  esac], [multilib=yes])dnl
  86
  87 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  88 GCC_NO_EXECUTABLES
  89
  90 # (1) We use an abnormal CXX (without library references), so we
  91 # must cache it under a different name.
  92 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  93 # the non-multilib-adjusted value will be used in multilibs.
  94 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  95 # (4) As another side effect, automake doesn't automatically include them
  96 # in Makefile.in.
  97 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  98 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  99 # used in later tests.  This may not be necessary in libjava; I don't know.
 100 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 101 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 102 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 103 save_CXXFLAGS="$CXXFLAGS"
 104 CXXFLAGS="$CXXFLAGS -fno-builtin"
 105 AC_PROG_CC
 106 AC_PROG_CXX
 107 CXXFLAGS="$save_CXXFLAGS"
 108 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 109 AC_SUBST(CFLAGS)
 110 AC_SUBST(CXXFLAGS)
 111 AC_SUBST(LDFLAGS)
 112
 113 AM_INIT_AUTOMAKE([1.9.0])
 114
 115 AC_CHECK_TOOL(AS, as)
 116 AC_CHECK_TOOL(LD, ld)
 117 AC_CHECK_TOOL(AR, ar)
 118 AC_CHECK_TOOL(RANLIB, ranlib, :)
 119 AC_CHECK_PROGS(JAR, [jar fastjar], false)
 120 if test "$JAR" = false; then
 121   AC_MSG_ERROR(jar program not found)
 122 fi
 123
 124 AC_PROG_INSTALL
 125
 126 AM_MAINTAINER_MODE
 127
 128 AC_EXEEXT
 129
 130 # configure.host sets the following important variables
 131 #       libgcj_cflags    - host specific C compiler flags
 132 #       libgcj_cxxflags  - host specific C++ compiler flags
 133 #       libgcj_javaflags - host specific Java compiler flags
 134
 135 libgcj_cflags=
 136 libgcj_cxxflags=
 137 libgcj_javaflags=
 138
 139 . ${srcdir}/configure.host
 140
 141 LIBGCJ_CFLAGS="${libgcj_cflags}"
 142 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 143 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 144 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 145 AC_SUBST(LIBGCJ_CFLAGS)
 146 AC_SUBST(LIBGCJ_CXXFLAGS)
 147 AC_SUBST(LIBGCJ_JAVAFLAGS)
 148 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 149
 150 # Only use libltdl for non-newlib builds.
 151 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 152    AC_LTDL_SHLIBPATH
 153 fi
 154
 155 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 156
 157 # See if the user has requested runtime debugging.
 158 LIBGCJDEBUG="disable"
 159 AC_SUBST(LIBGCJDEBUG)
 160 AC_ARG_ENABLE(libgcj-debug,
 161   AS_HELP_STRING([--enable-libgcj-debug],
 162                  [enable runtime debugging code]),
 163   [if test "$enable_libgcj_debug" = yes; then
 164     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 165     LIBGCJDEBUG="enable"
 166   fi])
 167
 168 # Determine which AWT peer libraries to build
 169 AC_ARG_ENABLE(java-awt,
 170   AS_HELP_STRING([--enable-java-awt],
 171                  [list of AWT peer implementations to be built]))
 172
 173 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 174 use_xlib_awt=""
 175 use_gtk_awt=""
 176 use_qt_awt=""
 177 # The default toolkit to use is the first one specified.
 178 TOOLKIT=
 179 AC_SUBST(TOOLKIT)
 180
 181 for peer in $peerlibs ; do
 182   case $peer in
 183     xlib)
 184       if test "$no_x" = yes; then
 185         echo "*** xlib peers requested but no X library available" 1>&2
 186         exit 1
 187       else
 188         use_xlib_awt="yes"
 189         if test -z "$TOOLKIT"; then
 190            TOOLKIT=gnu.awt.xlib.XToolkit
 191         fi
 192       fi
 193       ;;
 194     gtk)
 195       if test "$no_x" = yes; then
 196          echo "*** gtk peers requested but no X library available" 1>&2
 197          exit 1
 198       else
 199          use_gtk_awt=yes
 200          if test -z "$TOOLKIT"; then
 201             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 202          fi
 203       fi
 204       ;;
 205     qt)
 206       if test "$no_x" = yes; then
 207          # Perhaps we should admit the possibility of embedded Qt.
 208          echo "*** Qt peers requested but no X library available" 1>&2
 209          exit 1
 210       else
 211          use_qt_awt=yes
 212          if test -z "$TOOLKIT"; then
 213             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 214          fi
 215       fi
 216       ;;
 217     no)
 218       use_xlib_awt=
 219       use_gtk_awt=
 220       use_qt_awt=
 221       break
 222       ;;
 223     *)
 224       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 225       exit 1
 226   esac
 227 done
 228
 229 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 230 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 231 AM_CONDITIONAL(QT_AWT, test "$use_qt_awt" = yes)
 232
 233 # Create standard.omit based on decisions we just made.
 234 cp $srcdir/standard.omit.in standard.omit
 235 if test "$use_xlib_awt" != yes; then
 236    echo gnu/awt/xlib >> standard.omit
 237    echo gnu/gcj/xlib >> standard.omit
 238 fi
 239 if test "$use_gtk_awt" != yes; then
 240    echo gnu/java/awt/peer/gtk >> standard.omit
 241 fi
 242 if test "$use_qt_awt" != yes; then
 243    echo gnu/java/awt/peer/qt >> standard.omit
 244 fi
 245
 246 if test -z "${with_multisubdir}"; then
 247    builddotdot=.
 248 else
 249    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 250 fi
 251
 252 NATIVE=yes
 253
 254 # Which gcj do we use?
 255 which_gcj=default
 256 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 257 if test -n "${with_cross_host}"; then
 258   # We are being configured with a cross compiler. We can't
 259   # use ac_exeext, because that is for the target platform.
 260   NATIVE=no
 261   cross_host_exeext=
 262   case "${with_cross_host}" in
 263      *mingw* | *cygwin*)
 264          cross_host_exeext=.exe
 265      ;;
 266   esac
 267   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 268      if test x"$build_noncanonical" = x"$with_cross_host"; then
 269         # Ordinary cross (host!=target and host=build)
 270         which_gcj=built
 271      else
 272         # Canadian cross (host!=target and host!=build)
 273         which_gcj=cross
 274      fi
 275   else
 276      which_gcj=cross
 277   fi
 278 else
 279   # We are being configured with a native or crossed-native compiler
 280   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 281      if test x"$build" = x"$host"; then
 282         # True native build (host=target and host=build)
 283         which_gcj=built
 284      else
 285         # Crossed-native build (host=target and host!=build)
 286         which_gcj=cross
 287      fi
 288   else
 289      which_gcj=path
 290   fi
 291 fi
 292 case "${which_gcj}" in
 293    built)
 294       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 295       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 296    ;;
 297    cross)
 298       if test "x${with_newlib}" = "xyes"; then
 299          # FIXME (comment): Why is this needed?
 300          GCC_UNWIND_INCLUDE=
 301          GCJ="${target_noncanonical}-gcj"
 302       else
 303          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 304       fi
 305       GCJH='$(target_noncanonical)-gcjh'
 306    ;;
 307    path)
 308       GCJ="gcj -B`${PWDCMD-pwd}`/"
 309       GCJH=gcjh
 310    ;;
 311 esac
 312
 313 AC_SUBST(GCJH)
 314
 315 # Create it, so that compile/link tests don't fail
 316 test -f libgcj.spec || touch libgcj.spec
 317
 318
 319
 320 # Set up to configure Classpath.
 321 # FIXME: no supported way to pass args in autoconf.
 322 ac_configure_args="$ac_configure_args --disable-load-library"
 323 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 324 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 325 dir1=`cd $srcdir && pwd`
 326 dir2=`pwd`
 327 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 328 ac_configure_args="$ac_configure_args --disable-core-jni"
 329 dnl FIXME?
 330 ac_configure_args="$ac_configure_args --disable-examples"
 331 ac_configure_args="$ac_configure_args --with-glibj=build"
 332 if test "$use_gtk_awt" != yes; then
 333   ac_configure_args="$ac_configure_args --disable-gtk-peer"
 334 fi
 335 if test "$use_qt_awt" != yes; then
 336   ac_configure_args="$ac_configure_args --disable-qt-peer"
 337 else
 338   # We need this as qt is disabled by default in classpath.
 339   ac_configure_args="$ac_configure_args --enable-qt-peer"
 340 fi
 341 dnl --with-gcj=$GCJ
 342 dnl --with-javah=$GCJH
 343 dnl gjdoc?
 344 dnl gtk-cairo -- just export here...
 345 dnl --enable-regen-headers?
 346
 347 # Only use libltdl for non-newlib builds.
 348 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 349    AC_LIBLTDL_CONVENIENCE
 350    AC_LIBTOOL_DLOPEN
 351    DIRLTDL=libltdl
 352    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 353    # Sigh.  Libtool's macro doesn't do the right thing.
 354    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 355    # FIXME: this is a hack.
 356    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 357    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 358 fi
 359 AC_SUBST(INCLTDL)
 360 AC_SUBST(LIBLTDL)
 361 AC_SUBST(DIRLTDL)
 362 AC_PROG_LIBTOOL
 363 AM_PROG_GCJ
 364 AM_PROG_CC_C_O
 365
 366 AC_CONFIG_SUBDIRS(classpath libltdl)
 367
 368 # The -no-testsuite modules omit the test subdir.
 369 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 370
 371 # Should the runtime set system properties by examining the
 372 # environment variable GCJ_PROPERTIES?
 373 AC_ARG_ENABLE(getenv-properties,
 374   AS_HELP_STRING([--disable-getenv-properties],
 375                  [don't set system properties from GCJ_PROPERTIES]))
 376
 377 # Whether GCJ_PROPERTIES is used depends on the target.
 378 if test -z "$enable_getenv_properties"; then
 379    enable_getenv_properties=${enable_getenv_properties_default-yes}
 380 fi
 381 if test "$enable_getenv_properties" = no; then
 382    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 383      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 384 fi
 385
 386 # Whether we should use arguments to main()
 387 if test -z "$enable_main_args"; then
 388    enable_main_args=${enable_main_args_default-yes}
 389 fi
 390 if test "$enable_main_args" = no; then
 391    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 392 fi
 393
 394
 395 # Should we use hashtable-based synchronization?
 396 # Currently works only for Linux X86/ia64
 397 # Typically faster and more space-efficient
 398 AC_ARG_ENABLE(hash-synchronization,
 399   AS_HELP_STRING([--enable-hash-synchronization],
 400                  [use global hash table for monitor locks]))
 401
 402 if test -z "$enable_hash_synchronization"; then
 403    enable_hash_synchronization=$enable_hash_synchronization_default
 404 fi
 405
 406 AC_ARG_WITH(java-home,
 407   AS_HELP_STRING([--with-java-home=DIRECTORY],
 408                  [value of java.home system property]),
 409                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 410 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 411 AC_SUBST(JAVA_HOME)
 412
 413 # What is the native OS API for MinGW?
 414 AC_ARG_WITH(win32-nlsapi,
 415   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 416                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 417 [case "${withval}" in
 418   ansi) with_win32_nlsapi=ansi ;;
 419   unicows) with_win32_nlsapi=unicows ;;
 420   unicode) with_win32_nlsapi=unicode ;;
 421   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 422 esac],[with_win32_nlsapi=ansi])
 423
 424 case "${with_win32_nlsapi}" in
 425   unicows | unicode)
 426     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 427       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 428     ;;
 429 esac
 430
 431 # configure.host sets slow_pthread_self if the synchronization code should
 432 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 433 if test "${slow_pthread_self}" = "yes"; then
 434   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 435     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 436 fi
 437
 438 # Check for gc debugging.  This option is handled both here and in the GC.
 439 AC_ARG_ENABLE(gc-debug,
 440    AS_HELP_STRING([--enable-gc-debug],
 441                   [include full support for pointer backtracing etc.]),
 442 [ if test "$enable_gc_debug" = "yes"; then
 443     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 444               [Define if we want to use debug calls into the garbage collector.])
 445   fi])
 446
 447 # See if the user has the interpreter included.
 448 AC_ARG_ENABLE(interpreter,
 449   AS_HELP_STRING([--enable-interpreter],
 450                  [enable interpreter]),
 451   [if test "$enable_interpreter" = yes; then
 452     # This can also be set in configure.host.
 453     libgcj_interpreter=yes
 454   elif test "$enable_interpreter" = no; then
 455     libgcj_interpreter=no
 456   fi])
 457
 458 if test "$libgcj_interpreter" = yes; then
 459    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 460 fi
 461 INTERPRETER="$libgcj_interpreter"
 462 AC_SUBST(INTERPRETER)
 463
 464 AC_MSG_CHECKING([for exception model to use])
 465 AC_LANG_PUSH(C++)
 466 AC_ARG_ENABLE(sjlj-exceptions,
 467   AS_HELP_STRING([--enable-sjlj-exceptions],
 468                  [force use of builtin_setjmp for exceptions]),
 469 [:],
 470 [dnl Botheration.  Now we've got to detect the exception model.
 471 dnl Link tests against libgcc.a are problematic since -- at least
 472 dnl as of this writing -- we've not been given proper -L bits for
 473 dnl single-tree newlib and libgloss.
 474 dnl
 475 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 476 dnl conftest files before we got a change to grep them first.
 477 cat > conftest.$ac_ext << EOF
 478 [#]line __oline__ "configure"
 479 struct S { ~S(); };
 480 void bar();
 481 void foo()
 482 {
 483   S s;
 484   bar();
 485 }
 486 EOF
 487 old_CXXFLAGS="$CXXFLAGS"
 488 CXXFLAGS=-S
 489 if AC_TRY_EVAL(ac_compile); then
 490   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 491     enable_sjlj_exceptions=yes
 492   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 493     enable_sjlj_exceptions=no
 494   fi
 495 fi
 496 CXXFLAGS="$old_CXXFLAGS"
 497 rm -f conftest*])
 498 if test x$enable_sjlj_exceptions = xyes; then
 499   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 500         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 501   ac_exception_model_name=sjlj
 502 elif test x$enable_sjlj_exceptions = xno; then
 503   ac_exception_model_name="call frame"
 504 else
 505   AC_MSG_ERROR([unable to detect exception model])
 506 fi
 507 AC_LANG_POP(C++)
 508 AC_MSG_RESULT($ac_exception_model_name)
 509
 510 # If we are non using SJLJ exceptions, and this host does not have support
 511 # for unwinding from a signal handler, enable checked dereferences and divides.
 512 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 513   CHECKREFSPEC=-fcheck-references
 514   DIVIDESPEC=-fuse-divide-subroutine
 515   EXCEPTIONSPEC=
 516 fi
 517
 518 # See if the user wants to disable java.net.  This is the mildly
 519 # ugly way that we admit that target-side configuration sucks.
 520 AC_ARG_ENABLE(java-net,
 521   AS_HELP_STRING([--disable-java-net],
 522                  [disable java.net]))
 523
 524 # Whether java.net is built by default can depend on the target.
 525 if test -z "$enable_java_net"; then
 526    enable_java_net=${enable_java_net_default-yes}
 527 fi
 528 if test "$enable_java_net" = no; then
 529    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 530 fi
 531
 532 # See if the user wants to configure without libffi.  Some
 533 # architectures don't support it, and default values are set in
 534 # configure.host.
 535 AC_ARG_WITH(libffi,
 536   AS_HELP_STRING([--without-libffi],
 537                  [don't use libffi]),
 538   [:],
 539   [with_libffi=${with_libffi_default-yes}])
 540
 541 LIBFFI=
 542 LIBFFIINCS=
 543 if test "$with_libffi" != no; then
 544    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 545    LIBFFI=../libffi/libffi_convenience.la
 546    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 547 fi
 548 AC_SUBST(LIBFFI)
 549 AC_SUBST(LIBFFIINCS)
 550
 551 # See if the user wants to disable JVMPI support.
 552 AC_ARG_ENABLE(jvmpi,
 553   AS_HELP_STRING([--disable-jvmpi],
 554                  [disable JVMPI support]))
 555
 556 if test "$enable_jvmpi" != no; then
 557     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 558 fi
 559
 560 # If the target is an eCos system, use the appropriate eCos
 561 # I/O routines.
 562 # FIXME: this should not be a local option but a global target
 563 # system; at present there is no eCos target.
 564 TARGET_ECOS=${PROCESS-"no"}
 565 AC_ARG_WITH(ecos,
 566 [  --with-ecos             enable runtime eCos target support],
 567 TARGET_ECOS="$with_ecos"
 568 )
 569
 570 PLATFORM_INNER_NAT_HDRS=
 571 case "$TARGET_ECOS" in
 572    no) case "$host" in
 573       *mingw*)
 574             PLATFORM=Win32
 575             PLATFORMNET=Win32
 576             PLATFORMH=win32.h
 577         CHECK_FOR_BROKEN_MINGW_LD
 578       ;;
 579       *)
 580             PLATFORM=Posix
 581             PLATFORMNET=Posix
 582             PLATFORMH=posix.h
 583             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 584       ;;
 585       esac
 586       ;;
 587    *)
 588       PLATFORM=Ecos
 589       PLATFORMNET=NoNet
 590       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 591       PLATFORMH=posix.h
 592       ;;
 593 esac
 594 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 595 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 596
 597 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 598                                       [Define if you have int32_t and uint32_t.]))
 599 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 600                                         [Define if you have int32_t and uint32_t.]))
 601 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 602                                           [Define if you have u_int32_t]))
 603 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 604                                            [Define if you have u_int32_t]))
 605
 606 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 607 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 608
 609 case "$host" in
 610   *-darwin*) DARWIN_CRT=true ;;
 611   *) DARWIN_CRT=false ;;
 612 esac
 613 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 614
 615 # These may not be defined in a non-ANS conformant embedded system.
 616 # FIXME: Should these case a runtime exception in that case?
 617 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 618                                   [Define is you have 'mktime' in <time.h>]))
 619 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 620                                   [Define is you have 'localtime' in <time.h>]))
 621
 622 # Create the subdirectory for natFile.cc, or the attempt
 623 # to create the link will fail.
 624 test -d java || mkdir java
 625 test -d java/io || mkdir java/io
 626 test -d gnu || mkdir gnu
 627 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 628
 629 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 630 test -d java/lang || mkdir java/lang
 631 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 632 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 633
 634 # Likewise for natInetAddress.cc and natVMNetworkInterface.cc.
 635 test -d java/net || mkdir java/net
 636 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 637 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 638
 639 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 640 test -d gnu/java || mkdir gnu/java
 641 test -d gnu/java/net || mkdir gnu/java/net
 642 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 643 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 644
 645 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 646 test -d gnu/java/nio || mkdir gnu/java/nio
 647 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 648 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 649 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 650 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 651
 652 case "${host}" in
 653     *mingw*)
 654       SYSTEMSPEC="-lgdi32 -lws2_32"
 655       if test "${with_win32_nlsapi}" = "unicows"; then
 656         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 657       fi
 658     ;;
 659     *)
 660       SYSTEMSPEC=
 661     ;;
 662 esac
 663 AC_SUBST(SYSTEMSPEC)
 664
 665 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 666 AC_SUBST(LIBGCJTESTSPEC)
 667
 668 AC_ARG_WITH(system-zlib,
 669   AS_HELP_STRING([--with-system-zlib],
 670                  [use installed libz]))
 671 ZLIBSPEC=
 672 AC_SUBST(ZLIBSPEC)
 673 ZLIBTESTSPEC=
 674 AC_SUBST(ZLIBTESTSPEC)
 675
 676 AC_PATH_XTRA
 677
 678 # determine whether to enable the cairo GTK Graphics2D backend
 679 AC_ARG_ENABLE(gtk-cairo,
 680   AS_HELP_STRING([--enable-gtk-cairo],
 681                  [build the cairo Graphics2D implementation on GTK]))
 682 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 683 if test "x${enable_gtk_cairo}" = xyes
 684 then
 685         PKG_CHECK_MODULES(CAIRO, cairo)
 686         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 687 fi
 688 AC_SUBST(CAIRO_LIBS)
 689 AC_SUBST(CAIRO_CFLAGS)
 690 AC_SUBST(PANGOFT2_LIBS)
 691 AC_SUBST(PANGOFT2_CFLAGS)
 692
 693 # FIXME: this should be _libs on some hosts.
 694 libsubdir=.libs
 695
 696 # extra LD Flags which are required for targets
 697 case "${host}" in
 698 *-*-darwin[[0-7]].*)
 699     # For now we have to disable it on darwin[8-9] because it slows down
 700     # the linking phase. A possible bug in ld?
 701     # on Darwin -single_module speeds up loading of the dynamic libraries.
 702     extra_ldflags_libjava=-Wl,-single_module
 703     ;;
 704 esac
 705 AC_SUBST(extra_ldflags_libjava)
 706
 707 # Allow the GC to be disabled.  Can be useful when debugging.
 708 AC_MSG_CHECKING([for garbage collector to use])
 709 AC_ARG_ENABLE(java-gc,
 710   AS_HELP_STRING([--enable-java-gc=TYPE],
 711                  [choose garbage collector (default is boehm)]),
 712   [GC=$enableval],
 713   [GC=boehm])
 714 GCLIBS=
 715 GCINCS=
 716 GCDEPS=
 717 GCSPEC=
 718 JC1GCSPEC=
 719 GCTESTSPEC=
 720 case "$GC" in
 721  boehm)
 722     AC_MSG_RESULT(boehm)
 723     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 724     JC1GCSPEC='-fuse-boehm-gc'
 725     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 726     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 727     GCOBJS=boehm.lo
 728     GCHDR=boehm-gc.h
 729     # The POSIX thread support needs to know this.
 730     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 731     ;;
 732  no)
 733     AC_MSG_RESULT(none)
 734     GCHDR=no-gc.h
 735     ;;
 736  *)
 737     AC_MSG_ERROR([unrecognized collector "$GC"])
 738     ;;
 739 esac
 740 AC_SUBST(GCLIBS)
 741 AC_SUBST(GCINCS)
 742 AC_SUBST(GCDEPS)
 743 AC_SUBST(GCSPEC)
 744 AC_SUBST(JC1GCSPEC)
 745 AC_SUBST(GCTESTSPEC)
 746 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 747 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 748 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 749
 750
 751 AC_MSG_CHECKING([for thread model used by GCC])
 752 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 753 AC_MSG_RESULT([$THREADS])
 754
 755 case "$THREADS" in
 756  no | none | single)
 757     THREADS=none
 758     ;;
 759  posix | posix95 | pthreads)
 760     THREADS=posix
 761     case "$host" in
 762      *-*-linux*)
 763         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 764         ;;
 765     esac
 766     ;;
 767  win32)
 768     ;;
 769  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 770     AC_MSG_ERROR(thread package $THREADS not yet supported)
 771     ;;
 772  *)
 773     AC_MSG_ERROR($THREADS is an unknown thread package)
 774     ;;
 775 esac
 776
 777 THREADCXXFLAGS=
 778 THREADLDFLAGS=
 779 THREADLIBS=
 780 THREADINCS=
 781 THREADDEPS=
 782 THREADH=
 783 THREADSPEC=
 784 case "$THREADS" in
 785  posix)
 786     case "$host" in
 787      *-*-cygwin*)
 788         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 789         ;;
 790      *-*-freebsd[[1234]]*)
 791         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 792         # merely adds pthread_* functions) but it does have a -pthread switch
 793         # which is required at link-time to select -lc_r *instead* of -lc.
 794         THREADLDFLAGS=-pthread
 795         # Don't set THREADSPEC here as might be expected since -pthread is
 796         # not processed when found within a spec file, it must come from
 797         # the command line.  For now, the user must provide the -pthread
 798         # switch to link code compiled with gcj.  In future, consider adding
 799         # support for weak references to pthread_* functions ala gthr.h API.
 800         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 801         ;;
 802      *-*-freebsd*)
 803         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 804         # systems which support threads and -lpthread.
 805         THREADLDFLAGS=-pthread
 806         THREADSPEC=-lpthread
 807         ;;
 808      alpha*-dec-osf*)
 809         THREADCXXFLAGS=-pthread
 810         # boehm-gc needs some functions from librt, so link that too.
 811         THREADLIBS='-lpthread -lrt'
 812         THREADSPEC='-lpthread -lrt'
 813         ;;
 814      *)
 815         THREADLIBS=-lpthread
 816         THREADSPEC=-lpthread
 817         ;;
 818     esac
 819     THREADH=posix-threads.h
 820     # MIT pthreads doesn't seem to have the mutexattr functions.
 821     # But for now we don't check for it.  We just assume you aren't
 822     # using MIT pthreads.
 823     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 824
 825     # If we're using the Boehm GC, then we happen to know that it
 826     # defines _REENTRANT, so we don't bother.  Eww.
 827     if test "$GC" != boehm; then
 828        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 829     fi
 830     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 831     ;;
 832
 833  win32)
 834     THREADH=win32-threads.h
 835     ;;
 836
 837  none)
 838     THREADH=no-threads.h
 839     ;;
 840 esac
 841 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 842 AC_SUBST(THREADLIBS)
 843 AC_SUBST(THREADINCS)
 844 AC_SUBST(THREADDEPS)
 845 AC_SUBST(THREADSPEC)
 846 AC_SUBST(THREADLDFLAGS)
 847 AC_SUBST(THREADCXXFLAGS)
 848 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 849 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 850 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 851
 852 if test -d sysdep; then true; else mkdir sysdep; fi
 853 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 854 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 855 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 856
 857 HASH_SYNC_SPEC=
 858 # Hash synchronization is only useful with posix threads right now.
 859 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 860    HASH_SYNC_SPEC=-fhash-synchronization
 861    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 862 fi
 863 AC_SUBST(HASH_SYNC_SPEC)
 864
 865 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 866
 867 # We're in the tree with gcc, and need to include some of its headers.
 868 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 869
 870 if test "x${with_newlib}" = "xyes"; then
 871    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 872    # may not work correctly, because the compiler may not be able to
 873    # link executables.
 874
 875    # We assume newlib.  This lets us hard-code the functions we know
 876    # we'll have.
 877    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 878    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 879    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 880    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 881    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 882    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 883    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 884    # This is only for POSIX threads.
 885    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 886    # We also assume we are using gcc, which provides alloca.
 887    AC_DEFINE(HAVE_ALLOCA)
 888
 889    # Assume we do not have getuid and friends.
 890    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 891    PLATFORMNET=NoNet
 892 else
 893    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
 894                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
 895                    access stat mkdir rename rmdir unlink realpath utime chmod \
 896                    nl_langinfo setlocale \
 897                    inet_pton uname inet_ntoa \
 898                    fork execvp pipe sigaction ftruncate mmap])
 899    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 900    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 901    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
 902    AC_CHECK_LIB(dl, dladdr, [
 903        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
 904        AC_CHECK_LIB(dld, dladdr, [
 905        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
 906
 907    if test x"$build" = x"$host"; then
 908      AC_CHECK_FILES(/proc/self/exe, [
 909        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 910    else
 911      case $host in
 912      *-linux*)
 913        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 914        ;;
 915      esac
 916    fi
 917
 918    AM_ICONV
 919    AM_LC_MESSAGES
 920    AC_STRUCT_TIMEZONE
 921
 922    AC_CHECK_FUNCS(gethostbyname_r, [
 923      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 924        [Define if you have the 'gethostbyname_r' function.])
 925      # There are two different kinds of gethostbyname_r.
 926      # We look for the one that returns `int'.
 927      # Hopefully this check is robust enough.
 928      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 929        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 930
 931      case " $GCINCS " in
 932      *" -D_REENTRANT "*) ;;
 933      *)
 934         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 935         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 936         [libjava_cv_gethostbyname_r_needs_reentrant],
 937         [ AC_LANG_PUSH(C++)
 938           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 939             [[gethostbyname_r("", 0, 0);]])],
 940             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 941                 CPPFLAGS_SAVE="$CPPFLAGS"
 942                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 943                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 944                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 945                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 946                 CPPFLAGS="$CPPFLAGS_SAVE"
 947           ])
 948           AC_LANG_POP(C++)
 949         ])
 950         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 951           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 952         fi
 953      ;;
 954      esac
 955
 956      AC_CACHE_CHECK([for struct hostent_data],
 957         [libjava_cv_struct_hostent_data], [dnl
 958         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 959 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 960 # define _REENTRANT 1
 961 #endif
 962 #include <netdb.h>]], [[struct hostent_data data;]])],
 963           [libjava_cv_struct_hostent_data=yes],
 964           [libjava_cv_struct_hostent_data=no])])
 965      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 966        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 967          [Define if struct hostent_data is defined in netdb.h])
 968      fi
 969    ])
 970
 971    # FIXME: libjava source code expects to find a prototype for
 972    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 973    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 974    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 975    # linkage check is enough, yet C++ code requires proper prototypes.)
 976    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 977    AC_CHECK_FUNCS(gethostbyaddr_r, [
 978      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 979        [Define if you have the 'gethostbyaddr_r' function.])
 980      # There are two different kinds of gethostbyaddr_r.
 981      # We look for the one that returns `int'.
 982      # Hopefully this check is robust enough.
 983      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 984        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 985          [Define if gethostbyaddr_r returns 'int'.])])])])
 986
 987    AC_CHECK_FUNCS(gethostname, [
 988      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 989        [Define if you have the 'gethostname' function.])
 990      AC_EGREP_HEADER(gethostname, unistd.h, [
 991        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 992          [Define if gethostname is declared in <unistd.h>.])])])
 993
 994    AC_CHECK_FUNCS(usleep, [
 995      AC_EGREP_HEADER(usleep, unistd.h, [
 996        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 997           [Define if usleep is declared in <unistd.h>.])])])
 998
 999    # Look for these functions in the thread library, but only bother
1000    # if using POSIX threads.
1001    if test "$THREADS" = posix; then
1002       save_LIBS="$LIBS"
1003       LIBS="$LIBS $THREADLIBS"
1004       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1005       # E.g., Solaris.
1006       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1007
1008       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1009       # Solaris 7 the name librt is preferred.
1010       AC_CHECK_FUNCS(sched_yield, , [
1011         AC_CHECK_LIB(rt, sched_yield, [
1012           AC_DEFINE(HAVE_SCHED_YIELD)
1013           THREADLIBS="$THREADLIBS -lrt"
1014           THREADSPEC="$THREADSPEC -lrt"], [
1015           AC_CHECK_LIB(posix4, sched_yield, [
1016             AC_DEFINE(HAVE_SCHED_YIELD)
1017             THREADLIBS="$THREADLIBS -lposix4"
1018             THREADSPEC="$THREADSPEC -lposix4"])])])
1019
1020       AC_CHECK_LIB(rt, clock_gettime, [
1021          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1022          case "$THREADSPEC" in
1023            *-lrt*) ;;
1024            *)
1025              THREADSPEC="$THREADSPEC -lrt"
1026              THREADLIBS="$THREADLIBS -lrt"
1027              ;;
1028          esac])
1029
1030       LIBS="$save_LIBS"
1031
1032       # We can save a little space at runtime if the mutex has m_count
1033       # or __m_count.  This is a nice hack for Linux.
1034       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1035           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1036         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1037              [Define if pthread_mutex_t has m_count member.]), [
1038         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1039             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1040           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1041             [Define if pthread_mutex_t has __m_count member.]))])
1042    fi
1043
1044    # We require a way to get the time.
1045    time_found=no
1046    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1047    if test "$time_found" = no; then
1048       AC_MSG_ERROR([no function found to get the time])
1049    fi
1050
1051    AC_CHECK_FUNCS(memmove)
1052
1053    # We require memcpy.
1054    memcpy_found=no
1055    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1056    if test "$memcpy_found" = no; then
1057       AC_MSG_ERROR([memcpy is required])
1058    fi
1059    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1060    AC_CHECK_LIB(dl, dlopen, [
1061        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1062        AC_CHECK_LIB(dld, dlopen, [
1063        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1064
1065    # Some library-finding code we stole from Tcl.
1066    #--------------------------------------------------------------------
1067    #    Check for the existence of the -lsocket and -lnsl libraries.
1068    #    The order here is important, so that they end up in the right
1069    #    order in the command line generated by make.  Here are some
1070    #    special considerations:
1071    #    1. Use "connect" and "accept" to check for -lsocket, and
1072    #       "gethostbyname" to check for -lnsl.
1073    #    2. Use each function name only once:  can't redo a check because
1074    #       autoconf caches the results of the last check and won't redo it.
1075    #    3. Use -lnsl and -lsocket only if they supply procedures that
1076    #       aren't already present in the normal libraries.  This is because
1077    #       IRIX 5.2 has libraries, but they aren't needed and they're
1078    #       bogus:  they goof up name resolution if used.
1079    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1080    #       To get around this problem, check for both libraries together
1081    #       if -lsocket doesn't work by itself.
1082    #--------------------------------------------------------------------
1083
1084    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1085     [gcj_cv_lib_sockets=
1086      gcj_checkBoth=0
1087      unset ac_cv_func_connect
1088      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1089      if test "$gcj_checkSocket" = 1; then
1090          unset ac_cv_func_connect
1091          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1092                       gcj_checkBoth=1)
1093      fi
1094      if test "$gcj_checkBoth" = 1; then
1095          gcj_oldLibs=$LIBS
1096          LIBS="$LIBS -lsocket -lnsl"
1097          unset ac_cv_func_accept
1098          AC_CHECK_FUNC(accept,
1099                        [gcj_checkNsl=0
1100                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1101          unset ac_cv_func_accept
1102          LIBS=$gcj_oldLibs
1103      fi
1104      unset ac_cv_func_gethostbyname
1105      gcj_oldLibs=$LIBS
1106      LIBS="$LIBS $gcj_cv_lib_sockets"
1107      AC_CHECK_FUNC(gethostbyname, ,
1108                    [AC_CHECK_LIB(nsl, main,
1109                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1110      unset ac_cv_func_gethostbyname
1111      LIBS=$gcj_oldLIBS
1112    ])
1113    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1114
1115    if test "$with_system_zlib" = yes; then
1116       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1117    fi
1118
1119    # Test for Gtk stuff, if asked for.
1120    if test "$use_gtk_awt" = yes; then
1121       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1122       AC_SUBST(GTK_CFLAGS)
1123       AC_SUBST(GTK_LIBS)
1124
1125       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1126       AC_SUBST(GLIB_CFLAGS)
1127       AC_SUBST(GLIB_LIBS)
1128
1129       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1130       AC_SUBST(LIBART_CFLAGS)
1131       AC_SUBST(LIBART_LIBS)
1132
1133       # We require the XTest Extension to support java.awt.Robot.
1134       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1135                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1136                    [${X_LIBS}])
1137    fi
1138
1139    # On Solaris, and maybe other architectures, the Boehm collector
1140    # requires -ldl.
1141    if test "$GC" = boehm; then
1142       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1143    fi
1144 fi
1145
1146 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1147 case $build in
1148     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1149     *)         CLASSPATH_SEPARATOR=':' ;;
1150 esac
1151 AC_SUBST(CLASSPATH_SEPARATOR)
1152
1153 # We must search the source tree for java.lang, since we still don't
1154 # have libgcj.jar nor java/lang/*.class
1155 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1156 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1157
1158 # Since some classes depend on this one, we need its source available
1159 # before we can do any GCJ compilation test :-(
1160 if test ! -f gnu/classpath/Configuration.java; then
1161   test -d gnu || mkdir gnu
1162   test -d gnu/classpath || mkdir gnu/classpath
1163   # Note that it is not crucial that all the values here be correct.
1164   sed -e "s,@prefix@,$prefix," \
1165       -e "s,@VERSION@,$VERSION," \
1166       -e "s,@LIBDEBUG@,false," \
1167       -e "s,@INIT_LOAD_LIBRARY@,false," \
1168       -e "s,@@,$LIBGCJDEBUG," \
1169       -e "s,@default_toolkit@,$TOOLKIT," \
1170       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1171       -e "s,@GTK_CAIRO_ENABLED@,false," \
1172         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1173         > gnu/classpath/Configuration.java
1174   # We do not want to redirect the output of the grep below to /dev/null,
1175   # but we add /dev/null to the input list so that grep will print the
1176   # filename of Configuration.java in case it finds any matches.
1177   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1178     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1179   fi
1180 fi
1181
1182 LT_AC_PROG_GCJ
1183
1184 # Now remove it.
1185 rm -f gnu/classpath/Configuration.java
1186
1187 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1188
1189 AC_CHECK_SIZEOF(void *)
1190
1191 AC_C_BIGENDIAN
1192
1193 ZLIBS=
1194 SYS_ZLIBS=
1195 ZINCS=
1196
1197 if test -z "$ZLIBSPEC"; then
1198    # Use zlib from the GCC tree.
1199    ZINCS='-I$(top_srcdir)/../zlib'
1200    ZLIBS=../zlib/libzgcj_convenience.la
1201 else
1202    # System's zlib.
1203    SYS_ZLIBS="$ZLIBSPEC"
1204 fi
1205 AC_SUBST(ZLIBS)
1206 AC_SUBST(SYS_ZLIBS)
1207 AC_SUBST(ZINCS)
1208 AC_SUBST(DIVIDESPEC)
1209 AC_SUBST(CHECKREFSPEC)
1210 AC_SUBST(EXCEPTIONSPEC)
1211 AC_SUBST(BACKTRACESPEC)
1212 AC_SUBST(IEEESPEC)
1213
1214 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1215 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1216 AC_SUBST(GCC_UNWIND_INCLUDE)
1217
1218 # Process the option "--enable-version-specific-runtime-libs"
1219 # Calculate toolexeclibdir
1220 case ${version_specific_libs} in
1221   yes)
1222     # Need the gcc compiler version to know where to install libraries
1223     # and header files if --enable-version-specific-runtime-libs option
1224     # is selected.
1225     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1226     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1227     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1228     toolexeclibdir=$toolexecmainlibdir
1229     ;;
1230   no)
1231     if test -n "$with_cross_host" &&
1232        test x"$with_cross_host" != x"no"; then
1233       # Install a library built with a cross compiler in tooldir, not libdir.
1234       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1235       toolexecmainlibdir='$(toolexecdir)/lib'
1236     else
1237       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1238       toolexecmainlibdir='$(libdir)'
1239     fi
1240     multi_os_directory=`$CC -print-multi-os-directory`
1241     case $multi_os_directory in
1242       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1243       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1244     esac
1245     ;;
1246 esac
1247 AC_SUBST(toolexecdir)
1248 AC_SUBST(toolexecmainlibdir)
1249 AC_SUBST(toolexeclibdir)
1250
1251 # Determine where the standard .db file is found.
1252 multi_os_directory=`$CC -print-multi-os-directory`
1253 case $multi_os_directory in
1254   .) dbexecdir='$(libdir)/gcj-$(gcc_version)' ;; # Avoid /.
1255   *) dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)' ;;
1256 esac
1257 AC_SUBST(dbexecdir)
1258
1259 # Determine gcj version number.
1260 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1261 GCJVERSION=$gcjversion
1262 AC_SUBST(GCJVERSION)
1263 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1264
1265 AC_DEFINE(JV_VERSION, "1.4.2", [Compatibility version string])
1266 AC_DEFINE(JV_API_VERSION, "1.4", [API compatibility version string])
1267
1268 TL_AC_GXX_INCLUDE_DIR
1269
1270 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1271 # On that system, sys/ioctl.h will not include sys/filio.h unless
1272 # BSD_COMP is defined; just including sys/filio.h is simpler.
1273 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1274 # for now.  If you change this, you also must update natFile.cc.
1275 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1276                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1277                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1278                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1279                   dirent.h])
1280 AC_CHECK_HEADERS(inttypes.h, [
1281     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1282     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1283 ])
1284 AC_HEADER_SYS_WAIT
1285
1286 AC_CHECK_TYPE([ssize_t], [int])
1287
1288 AC_MSG_CHECKING([for in_addr_t])
1289 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1290 #if STDC_HEADERS
1291 #include <stdlib.h>
1292 #include <stddef.h>
1293 #endif
1294 #if HAVE_NETINET_IN_H
1295 #include <netinet/in.h>
1296 #endif]], [[in_addr_t foo;]])],
1297   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1298      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1299    AC_MSG_RESULT(yes)],
1300   [AC_MSG_RESULT(no)])
1301
1302 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1303 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1304   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1305      [Define if struct ip_mreq is defined in netinet/in.h.])
1306    AC_MSG_RESULT(yes)],
1307   [AC_MSG_RESULT(no)])
1308
1309 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1310 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1311   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1312      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1313    AC_MSG_RESULT(yes)],
1314   [AC_MSG_RESULT(no)])
1315
1316 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1317 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1318   [AC_DEFINE(HAVE_INET6, 1,
1319      [Define if inet6 structures are defined in netinet/in.h.])
1320    AC_MSG_RESULT(yes)],
1321   [AC_MSG_RESULT(no)])
1322
1323 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1324 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1325 #include <sys/types.h>
1326 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1327   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1328    AC_MSG_RESULT(yes)],
1329   [AC_MSG_RESULT(no)])
1330
1331 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1332 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1333   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1334    AC_MSG_RESULT(yes)],
1335   [AC_MSG_RESULT(no)
1336    AC_MSG_CHECKING([for global timezone variable])
1337    dnl FIXME: we don't want a link check here because that won't work
1338    dnl when cross-compiling.  So instead we make an assumption that
1339    dnl the header file will mention timezone if it exists.
1340    dnl Don't find the win32 function timezone
1341    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1342      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1343       AC_MSG_RESULT(yes)],
1344      [AC_MSG_RESULT(no)
1345        AC_MSG_CHECKING([for global _timezone variable])
1346        dnl FIXME: As above, don't want link check
1347        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1348          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1349             [Define if your platform has the global _timezone variable.])
1350           AC_MSG_RESULT(yes)],
1351           [AC_MSG_RESULT(no)])])])
1352
1353 AC_FUNC_ALLOCA
1354
1355 AC_CHECK_PROGS(PERL, perl, false)
1356
1357 SYSDEP_SOURCES=
1358 SIGNAL_HANDLER_AUX=
1359
1360 case "${host}" in
1361  i?86-*-linux*)
1362     SIGNAL_HANDLER=include/i386-signal.h
1363     ;;
1364  sparc*-sun-solaris*)
1365     SIGNAL_HANDLER=include/sparc-signal.h
1366     ;;
1367 # ia64-*)
1368 #    SYSDEP_SOURCES=sysdep/ia64.c
1369 #    test -d sysdep || mkdir sysdep
1370 #    ;;
1371  hppa*-*-linux*)
1372     SIGNAL_HANDLER=include/pa-signal.h
1373     ;;
1374  ia64-*-linux*)
1375     SIGNAL_HANDLER=include/dwarf2-signal.h
1376     ;;
1377  powerpc*-*-linux*)
1378     SIGNAL_HANDLER=include/powerpc-signal.h
1379     ;;
1380  alpha*-*-linux*)
1381     SIGNAL_HANDLER=include/dwarf2-signal.h
1382     ;;
1383  s390*-*-linux*)
1384     SIGNAL_HANDLER=include/s390-signal.h
1385     ;;
1386  x86_64*-*-linux*)
1387     SIGNAL_HANDLER=include/x86_64-signal.h
1388     SIGNAL_HANDLER_AUX=include/i386-signal.h
1389     ;;
1390  sparc*-*-linux*)
1391     SIGNAL_HANDLER=include/dwarf2-signal.h
1392     ;;
1393  sh*-*-linux*)
1394     SIGNAL_HANDLER=include/sh-signal.h
1395     ;;
1396  *mingw*)
1397     SIGNAL_HANDLER=include/win32-signal.h
1398     ;;
1399  mips*-*-linux*)
1400     SIGNAL_HANDLER=include/mips-signal.h
1401     ;;
1402  *-*-darwin*)
1403     SIGNAL_HANDLER=include/darwin-signal.h
1404     ;;
1405  *)
1406     SIGNAL_HANDLER=include/default-signal.h
1407     ;;
1408 esac
1409
1410 # If we're using sjlj exceptions, forget what we just learned.
1411 if test "$enable_sjlj_exceptions" = yes; then
1412    SIGNAL_HANDLER=include/default-signal.h
1413    SIGNAL_HANDLER_AUX=
1414 fi
1415
1416 AC_SUBST(SYSDEP_SOURCES)
1417
1418 if test -z "$SIGNAL_HANDLER_AUX"; then
1419   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1420 fi
1421
1422 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1423                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1424
1425 if test "${multilib}" = "yes"; then
1426   multilib_arg="--enable-multilib"
1427 else
1428   multilib_arg=
1429 fi
1430
1431 # See if we support thread-local storage.
1432 GCC_CHECK_TLS
1433
1434 # Check if linker supports static linking on a per library basis
1435 LD_START_STATIC_SPEC=
1436 LD_FINISH_STATIC_SPEC=
1437 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1438   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1439     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1440     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1441   fi
1442 fi
1443 AC_SUBST(LD_START_STATIC_SPEC)
1444 AC_SUBST(LD_FINISH_STATIC_SPEC)
1445
1446 here=`${PWDCMD-pwd}`
1447 AC_SUBST(here)
1448
1449 # We get this from the environment.
1450 AC_SUBST(GCJFLAGS)
1451
1452 AC_CONFIG_FILES([
1453 Makefile
1454 libgcj.pc
1455 libgcj.spec
1456 libgcj-test.spec
1457 gcj/Makefile
1458 include/Makefile
1459 testsuite/Makefile
1460 ])
1461
1462 AC_CONFIG_COMMANDS([default],
1463 [# Only add multilib support code if we just rebuilt top-level Makefile.
1464 case " $CONFIG_FILES " in
1465  *" Makefile "*)
1466    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1467    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1468    ;;
1469 esac
1470 for ac_multi_file in $CONFIG_FILES; do
1471   case $ac_multi_file in
1472   */Makefile)
1473     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1474   esac
1475 done
1476 ],
1477 srcdir=${srcdir}
1478 host=${host}
1479 target=${target}
1480 with_multisubdir=${with_multisubdir}
1481 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1482 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1483 libgcj_basedir=${libgcj_basedir}
1484 CC="${CC}"
1485 CXX="${CXX}"
1486 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1487 )
1488
1489 AC_OUTPUT