libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename_force([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209 #       libgcj_sublib_ltflags - host specific Libtool flags
 210 #                          (only used when building sublibs)
 211 # and a number of others; see the list at the start of the file.
 212
 213 libgcj_cflags=
 214 libgcj_cxxflags=
 215 libgcj_javaflags=
 216 libgcj_sublib_ltflags=
 217
 218 . ${srcdir}/configure.host
 219
 220 ACX_PROG_LD_GNU_SYMBOLIC
 221 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 222 if test -z "$libgcj_ld_symbolic"; then
 223   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 224 fi
 225
 226 LIBGCJ_CFLAGS="${libgcj_cflags}"
 227 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 228 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 229 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 230 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 231 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 232 AC_SUBST(LIBGCJ_CFLAGS)
 233 AC_SUBST(LIBGCJ_CXXFLAGS)
 234 AC_SUBST(LIBGCJ_JAVAFLAGS)
 235 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 236 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 237 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 238
 239 # Only use libltdl for non-newlib builds.
 240 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 241    AC_LTDL_SHLIBPATH
 242 fi
 243
 244 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 245
 246 # Possibly build libgcj as many sub-libraries.
 247 AC_ARG_ENABLE(libgcj-sublibs,
 248   AS_HELP_STRING([--enable-libgcj-sublibs],
 249                  [build libgcj as many sub-libraries]))
 250
 251 if test -z "$enable_libgcj_sublibs"; then
 252    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 253 fi
 254 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 255 if test "$enable_libgcj_sublibs" = yes ; then
 256   # In theory we could make do with only one override and simply
 257   # tag "_bc" onto the end of it when we use it to generate the
 258   # spec, but that's an ugly thing to do when there are multiple
 259   # words in the string and you're relying on the ordering to
 260   # append the correct one.
 261   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 262   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 263 fi
 264
 265
 266 # See if the user has requested runtime debugging.
 267 LIBGCJDEBUG="disable"
 268 AC_SUBST(LIBGCJDEBUG)
 269 AC_ARG_ENABLE(libgcj-debug,
 270   AS_HELP_STRING([--enable-libgcj-debug],
 271                  [enable runtime debugging code]),
 272   [if test "$enable_libgcj_debug" = yes; then
 273     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 274     LIBGCJDEBUG="enable"
 275   fi])
 276
 277 AC_ARG_WITH([escher],
 278          AS_HELP_STRING([--with-escher=ABS.PATH],
 279                         [specify path to escher dir or JAR for X peers]))
 280 case "$with_escher" in
 281 "")
 282         use_escher=false
 283         ;;
 284 "no")
 285         use_escher=false
 286         ;;
 287 "yes")
 288         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 289         ;;
 290 *)
 291         use_escher=true
 292         ;;
 293 esac
 294
 295 # Determine which AWT peer libraries to build
 296 AC_ARG_ENABLE(java-awt,
 297   AS_HELP_STRING([--enable-java-awt],
 298                  [list of AWT peer implementations to be built]))
 299
 300 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 301 use_xlib_awt=""
 302 use_gtk_awt=""
 303 use_qt_awt=""
 304 use_x_awt=""
 305 # The default toolkit to use is the first one specified.
 306 TOOLKIT=
 307 AC_SUBST(TOOLKIT)
 308
 309 for peer in $peerlibs ; do
 310   case $peer in
 311     xlib)
 312       if test "$no_x" = yes; then
 313         echo "*** xlib peers requested but no X library available" 1>&2
 314         exit 1
 315       else
 316         use_xlib_awt="yes"
 317         if test -z "$TOOLKIT"; then
 318            TOOLKIT=gnu.awt.xlib.XToolkit
 319         fi
 320       fi
 321       ;;
 322     gtk)
 323       if test "$no_x" = yes; then
 324          echo "*** gtk peers requested but no X library available" 1>&2
 325          exit 1
 326       else
 327          use_gtk_awt=yes
 328          if test -z "$TOOLKIT"; then
 329             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 330          fi
 331       fi
 332       ;;
 333     qt)
 334       if test "$no_x" = yes; then
 335          # Perhaps we should admit the possibility of embedded Qt.
 336          echo "*** Qt peers requested but no X library available" 1>&2
 337          exit 1
 338       else
 339          use_qt_awt=yes
 340          if test -z "$TOOLKIT"; then
 341             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 342          fi
 343       fi
 344       ;;
 345     x)
 346       use_x_awt=yes
 347       if test -z "$TOOLKIT"; then
 348          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 349       fi
 350       ;;
 351     no)
 352       use_xlib_awt=
 353       use_gtk_awt=
 354       use_qt_awt=
 355       use_x_awt=
 356       break
 357       ;;
 358     *)
 359       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 360       exit 1
 361   esac
 362 done
 363
 364 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 365 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 366
 367 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 368
 369 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 370
 371 # Create standard.omit based on decisions we just made.
 372 cp $srcdir/standard.omit.in standard.omit
 373 if test "$use_xlib_awt" != yes; then
 374    echo gnu/awt/xlib >> standard.omit
 375    echo gnu/gcj/xlib >> standard.omit
 376 fi
 377 if test "$use_x_awt" != yes; then
 378    echo gnu/java/awt/peer/x >> standard.omit
 379 fi
 380
 381 # Tools that need to be compiled against classpath's tools classes
 382 : > vm-tools-packages
 383 for package in gnu/gcj/tools/gc_analyze ; do
 384     echo $package >> standard.omit
 385     echo $package >> vm-tools-packages
 386 done
 387
 388 if test -z "${with_multisubdir}"; then
 389    builddotdot=.
 390 else
 391    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 392 fi
 393
 394 NATIVE=yes
 395
 396 # Which gcj and host gcj (for ecjx) do we use?
 397 which_gcj=default
 398 host_exeext=${ac_exeext}
 399 GCJ_FOR_ECJX=
 400 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 401 if test -n "${with_cross_host}"; then
 402   # We are being configured with a cross compiler. We can't
 403   # use ac_exeext, because that is for the target platform.
 404   NATIVE=no
 405   cross_host_exeext=
 406   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 407   case "${with_cross_host}" in
 408      *mingw* | *cygwin*)
 409          cross_host_exeext=.exe
 410      ;;
 411   esac
 412   host_exeext=${cross_host_exeext}
 413   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 414      if test x"$build_noncanonical" = x"$with_cross_host"; then
 415         # Ordinary cross (host!=target and host=build)
 416         which_gcj=built
 417      else
 418         # Canadian cross (host!=target and host!=build)
 419         which_gcj=cross
 420      fi
 421   else
 422      which_gcj=cross
 423   fi
 424 else
 425   # We are being configured with a native or crossed-native compiler
 426   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 427      if test x"$build" = x"$host"; then
 428         # True native build (host=target and host=build)
 429         which_gcj=built
 430      else
 431         # Crossed-native build (host=target and host!=build)
 432         which_gcj=cross
 433      fi
 434   else
 435      which_gcj=path
 436   fi
 437 fi
 438 libgcjdir=`${PWDCMD-pwd}`
 439 case $GCJ in
 440 *" -B"*)
 441   # Just in case there is a comma in the build dir, quote it for the
 442   # sed command below.
 443   case $libgcjdir in
 444   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 445   *) qlibgcjdir=$libgcjdir;;
 446   esac
 447   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 448   ;;
 449 *)
 450   GCJ=$GCJ" -B$libgcjdir/"
 451   ;;
 452 esac
 453 case "${which_gcj}" in
 454    built)
 455       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 456    ;;
 457    cross)
 458       if test "x${with_newlib}" = "xyes"; then
 459          # FIXME (comment): Why is this needed?
 460          GCC_UNWIND_INCLUDE=
 461       fi
 462       GCJH='$(target_noncanonical)-gcjh'
 463    ;;
 464    path)
 465       GCJH=gcjh
 466    ;;
 467 esac
 468 JAVAC="$GCJ -C"
 469 export JAVAC
 470
 471 AC_SUBST(GCJ_FOR_ECJX)
 472 AC_SUBST(GCJH)
 473 AC_SUBST(host_exeext)
 474
 475 # Create it, so that compile/link tests don't fail
 476 test -f libgcj.spec || touch libgcj.spec
 477
 478
 479
 480 # Set up to configure Classpath.
 481 # FIXME: no supported way to pass args in autoconf.
 482 # Disable tool wrappers to avoid ltdl.h configure check.
 483 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 484 ac_configure_args="$ac_configure_args --disable-load-library"
 485 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 486 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 487 dir1=`cd $srcdir && pwd`
 488 dir2=`pwd`
 489 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 490 ac_configure_args="$ac_configure_args --disable-core-jni"
 491 dnl FIXME?
 492 ac_configure_args="$ac_configure_args --disable-examples"
 493 ac_configure_args="$ac_configure_args --with-glibj=build"
 494 if test "$plugin_enabled" != yes; then
 495   ac_configure_args="$ac_configure_args --disable-plugin"
 496 fi
 497 if test "$gconf_enabled" != yes; then
 498   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 499   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 500 fi
 501 if test "$use_gtk_awt" != yes; then
 502   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 503 fi
 504 if test "$use_qt_awt" != yes; then
 505   ac_configure_args="$ac_configure_args --disable-qt-peer"
 506 else
 507   # We need this as qt is disabled by default in classpath.
 508   ac_configure_args="$ac_configure_args --enable-qt-peer"
 509 fi
 510 if test "$use_x_awt" != yes; then
 511   ac_configure_args="$ac_configure_args --without-escher"
 512 else
 513   # We need this as escher is disabled by default in classpath.
 514   if test "$use_escher" != true; then
 515     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 516   else
 517     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 518   fi
 519 fi
 520 if test "x$BUILD_GJDOC" = xno; then
 521   ac_configure_args="$ac_configure_args --disable-gjdoc"
 522 fi
 523 # -Werror causes unavoidable problems in code using alsa.
 524 ac_configure_args="$ac_configure_args --disable-regen-headers"
 525 ac_configure_args="$ac_configure_args --disable-Werror"
 526 dnl --with-gcj=$GCJ
 527 dnl --with-javah=$GCJH
 528 dnl gtk-cairo -- just export here...
 529 dnl --enable-regen-headers?
 530
 531 # Only use libltdl for non-newlib builds.
 532 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 533    AC_LIBLTDL_CONVENIENCE
 534    AC_LIBTOOL_DLOPEN
 535    DIRLTDL=libltdl
 536    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 537    # Sigh.  Libtool's macro doesn't do the right thing.
 538    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 539    # FIXME: this is a hack.
 540    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 541    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 542 fi
 543 AC_SUBST(INCLTDL)
 544 AC_SUBST(LIBLTDL)
 545 AC_SUBST(DIRLTDL)
 546 AC_PROG_LIBTOOL
 547 AM_PROG_GCJ
 548 AM_PROG_CC_C_O
 549
 550 AC_CONFIG_SUBDIRS(classpath libltdl)
 551
 552 # The -no-testsuite modules omit the test subdir.
 553 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 554
 555 # Should the runtime set system properties by examining the
 556 # environment variable GCJ_PROPERTIES?
 557 AC_ARG_ENABLE(getenv-properties,
 558   AS_HELP_STRING([--disable-getenv-properties],
 559                  [don't set system properties from GCJ_PROPERTIES]))
 560
 561 # Whether GCJ_PROPERTIES is used depends on the target.
 562 if test -z "$enable_getenv_properties"; then
 563    enable_getenv_properties=${enable_getenv_properties_default-yes}
 564 fi
 565 if test "$enable_getenv_properties" = no; then
 566    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 567      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 568 fi
 569
 570 # Whether we should use arguments to main()
 571 if test -z "$enable_main_args"; then
 572    enable_main_args=${enable_main_args_default-yes}
 573 fi
 574 if test "$enable_main_args" = no; then
 575    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 576 fi
 577
 578
 579 # Should we use hashtable-based synchronization?
 580 # Currently works only for Linux X86/ia64
 581 # Typically faster and more space-efficient
 582 AC_ARG_ENABLE(hash-synchronization,
 583   AS_HELP_STRING([--enable-hash-synchronization],
 584                  [use global hash table for monitor locks]))
 585
 586 if test -z "$enable_hash_synchronization"; then
 587    enable_hash_synchronization=$enable_hash_synchronization_default
 588 fi
 589
 590
 591 install_ecj_jar=no
 592 ECJ_BUILD_JAR=
 593 ECJ_JAR=
 594 AC_ARG_WITH(ecj-jar,
 595         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 596         [ECJ_JAR=$withval],
 597         [if test -f $multi_basedir/ecj.jar; then
 598            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 599            ECJ_JAR='$(jardir)/ecj.jar'
 600            install_ecj_jar=yes
 601          fi])
 602 AC_SUBST(ECJ_BUILD_JAR)
 603 AC_SUBST(ECJ_JAR)
 604 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 605 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 606
 607 AC_ARG_WITH(java-home,
 608   AS_HELP_STRING([--with-java-home=DIRECTORY],
 609                  [value of java.home system property]),
 610                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 611 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 612 AC_SUBST(JAVA_HOME)
 613
 614 suppress_libgcj_bc=no
 615 AC_ARG_ENABLE(libgcj-bc,
 616   AS_HELP_STRING([--enable-libgcj-bc],
 617                  [enable(default) or disable BC ABI for portions of libgcj]),
 618   [if test "$enable_libgcj_bc" = "no"; then
 619      suppress_libgcj_bc=yes
 620    fi])
 621 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 622
 623 build_libgcj_reduced_reflection=no
 624 AC_ARG_ENABLE(reduced-reflection,
 625   AS_HELP_STRING([--enable-reduced-reflection],
 626                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 627   [if test "$enable_reduced_reflection" = "yes"; then
 628      build_libgcj_reduced_reflection=yes
 629    fi])
 630 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 631
 632 # What is the native OS API for MinGW?
 633 AC_ARG_WITH(win32-nlsapi,
 634   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 635                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 636 [case "${withval}" in
 637   ansi) with_win32_nlsapi=ansi ;;
 638   unicows) with_win32_nlsapi=unicows ;;
 639   unicode) with_win32_nlsapi=unicode ;;
 640   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 641 esac],[with_win32_nlsapi=ansi])
 642
 643 case "${with_win32_nlsapi}" in
 644   unicows | unicode)
 645     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 646       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 647     ;;
 648 esac
 649
 650 # configure.host sets slow_pthread_self if the synchronization code should
 651 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 652 if test "${slow_pthread_self}" = "yes"; then
 653   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 654     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 655 fi
 656
 657 # Check for gc debugging.  This option is handled both here and in the GC.
 658 AC_ARG_ENABLE(gc-debug,
 659    AS_HELP_STRING([--enable-gc-debug],
 660                   [include full support for pointer backtracing etc.]),
 661 [ if test "$enable_gc_debug" = "yes"; then
 662     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 663               [Define if we want to use debug calls into the garbage collector.])
 664   fi])
 665
 666 # See if the user has the interpreter included.
 667 AC_ARG_ENABLE(interpreter,
 668   AS_HELP_STRING([--enable-interpreter],
 669                  [enable interpreter]),
 670   [if test "$enable_interpreter" = yes; then
 671     # This can also be set in configure.host.
 672     libgcj_interpreter=yes
 673   elif test "$enable_interpreter" = no; then
 674     libgcj_interpreter=no
 675   fi])
 676
 677 if test "$libgcj_interpreter" = yes; then
 678    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 679 fi
 680 INTERPRETER="$libgcj_interpreter"
 681 AC_SUBST(INTERPRETER)
 682 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 683
 684 AC_MSG_CHECKING([for exception model to use])
 685 AC_LANG_PUSH(C++)
 686 AC_ARG_ENABLE(sjlj-exceptions,
 687   AS_HELP_STRING([--enable-sjlj-exceptions],
 688                  [force use of builtin_setjmp for exceptions]),
 689 [:],
 690 [dnl Botheration.  Now we've got to detect the exception model.
 691 dnl Link tests against libgcc.a are problematic since -- at least
 692 dnl as of this writing -- we've not been given proper -L bits for
 693 dnl single-tree newlib and libgloss.
 694 dnl
 695 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 696 dnl conftest files before we got a change to grep them first.
 697 cat > conftest.$ac_ext << EOF
 698 [#]line __oline__ "configure"
 699 struct S { ~S(); };
 700 void bar();
 701 void foo()
 702 {
 703   S s;
 704   bar();
 705 }
 706 EOF
 707 old_CXXFLAGS="$CXXFLAGS"
 708 CXXFLAGS=-S
 709 if AC_TRY_EVAL(ac_compile); then
 710   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 711     enable_sjlj_exceptions=yes
 712   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 713     enable_sjlj_exceptions=no
 714   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 715     # ARM EH ABI.
 716     enable_sjlj_exceptions=no
 717   fi
 718 fi
 719 CXXFLAGS="$old_CXXFLAGS"
 720 rm -f conftest*])
 721 if test x$enable_sjlj_exceptions = xyes; then
 722   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 723         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 724   ac_exception_model_name=sjlj
 725 elif test x$enable_sjlj_exceptions = xno; then
 726   ac_exception_model_name="call frame"
 727 else
 728   AC_MSG_ERROR([unable to detect exception model])
 729 fi
 730 AC_LANG_POP(C++)
 731 AC_MSG_RESULT($ac_exception_model_name)
 732
 733 # If we are non using SJLJ exceptions, and this host does not have support
 734 # for unwinding from a signal handler, enable checked dereferences and divides.
 735 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 736   CHECKREFSPEC=-fcheck-references
 737   DIVIDESPEC=-fuse-divide-subroutine
 738   EXCEPTIONSPEC=
 739 fi
 740
 741 # See if the user wants to disable java.net.  This is the mildly
 742 # ugly way that we admit that target-side configuration sucks.
 743 AC_ARG_ENABLE(java-net,
 744   AS_HELP_STRING([--disable-java-net],
 745                  [disable java.net]))
 746
 747 # Whether java.net is built by default can depend on the target.
 748 if test -z "$enable_java_net"; then
 749    enable_java_net=${enable_java_net_default-yes}
 750 fi
 751 if test "$enable_java_net" = no; then
 752    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 753 fi
 754
 755 # See if the user wants to configure without libffi.  Some
 756 # architectures don't support it, and default values are set in
 757 # configure.host.
 758 AC_ARG_WITH(libffi,
 759   AS_HELP_STRING([--without-libffi],
 760                  [don't use libffi]),
 761   [:],
 762   [with_libffi=${with_libffi_default-yes}])
 763
 764 LIBFFI=
 765 LIBFFIINCS=
 766 if test "$with_libffi" != no; then
 767    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 768    LIBFFI=../libffi/libffi_convenience.la
 769    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 770 fi
 771 AC_SUBST(LIBFFI)
 772 AC_SUBST(LIBFFIINCS)
 773
 774 # See if the user wants to disable JVMPI support.
 775 AC_ARG_ENABLE(jvmpi,
 776   AS_HELP_STRING([--disable-jvmpi],
 777                  [disable JVMPI support]))
 778
 779 if test "$enable_jvmpi" != no; then
 780     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 781 fi
 782
 783 # If the target is an eCos system, use the appropriate eCos
 784 # I/O routines.
 785 # FIXME: this should not be a local option but a global target
 786 # system; at present there is no eCos target.
 787 TARGET_ECOS=${PROCESS-"no"}
 788 AC_ARG_WITH(ecos,
 789 [  --with-ecos             enable runtime eCos target support],
 790 TARGET_ECOS="$with_ecos"
 791 )
 792
 793 case "$TARGET_ECOS" in
 794    no) case "$host" in
 795       *mingw*)
 796             PLATFORM=Win32
 797             PLATFORMNET=Win32
 798             PLATFORMH=win32.h
 799         CHECK_FOR_BROKEN_MINGW_LD
 800       ;;
 801       *)
 802             PLATFORM=Posix
 803             PLATFORMNET=Posix
 804             PLATFORMH=posix.h
 805       ;;
 806       esac
 807       ;;
 808    *)
 809       PLATFORM=Ecos
 810       PLATFORMNET=NoNet
 811       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 812       PLATFORMH=posix.h
 813       ;;
 814 esac
 815 AC_SUBST(PLATFORM)
 816 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 817
 818 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 819                                       [Define if you have int32_t and uint32_t.]))
 820 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 821                                         [Define if you have int32_t and uint32_t.]))
 822 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 823                                           [Define if you have u_int32_t]))
 824 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 825                                            [Define if you have u_int32_t]))
 826
 827 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 828 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 829
 830 case "$host" in
 831   *-darwin*) DARWIN_CRT=true ;;
 832   *) DARWIN_CRT=false ;;
 833 esac
 834 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 835
 836 # This may not be defined in a non-ANS conformant embedded system.
 837 # FIXME: Should these case a runtime exception in that case?
 838 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 839                                   [Define is you have 'localtime' in <time.h>]))
 840
 841 # Create the subdirectory for natFile.cc, or the attempt
 842 # to create the link will fail.
 843 test -d java || mkdir java
 844 test -d java/io || mkdir java/io
 845 test -d gnu || mkdir gnu
 846 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 847
 848 # Likewise for natConcreteProcess.cc.
 849 test -d java/lang || mkdir java/lang
 850 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 851
 852 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 853 test -d java/net || mkdir java/net
 854 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 855 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 856
 857 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 858 test -d gnu/java || mkdir gnu/java
 859 test -d gnu/java/net || mkdir gnu/java/net
 860 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 861 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 862
 863 # Likewise for natVMPipe.cc and natVMSelector.cc.
 864 test -d gnu/java/nio || mkdir gnu/java/nio
 865 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 866 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 867
 868 # Likewise for natFileChannelImpl.cc
 869 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 870 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 871
 872 # Likewise for natVMSecureRandom.cc
 873 test -d gnu/java/security || mkdir gnu/java/security
 874 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 875 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 876 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 877
 878 case "${host}" in
 879     *mingw*)
 880       SYSTEMSPEC="-lgdi32 -lws2_32"
 881       if test "${with_win32_nlsapi}" = "unicows"; then
 882         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 883       fi
 884     ;;
 885     *)
 886       SYSTEMSPEC=
 887     ;;
 888 esac
 889 AC_SUBST(SYSTEMSPEC)
 890
 891 AC_ARG_WITH(system-zlib,
 892   AS_HELP_STRING([--with-system-zlib],
 893                  [use installed libz]))
 894 ZLIBSPEC=
 895 AC_SUBST(ZLIBSPEC)
 896 ZLIBTESTSPEC=
 897 AC_SUBST(ZLIBTESTSPEC)
 898
 899 AC_PATH_XTRA
 900
 901 # FIXME: this should be _libs on some hosts.
 902 libsubdir=.libs
 903
 904 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 905
 906 LIBSTDCXXSPEC=
 907 # extra LD Flags which are required for targets
 908 case "${host}" in
 909 *-*-darwin[[0-7]].*)
 910     # For now we have to disable it on darwin[8-9] because it slows down
 911     # the linking phase. A possible bug in ld?
 912     # on Darwin -single_module speeds up loading of the dynamic libraries.
 913     extra_ldflags_libjava=-Wl,-single_module
 914     ;;
 915 *-*-darwin[[912]]*)
 916     extra_gij_ldflags=-Wl,-allow_stack_execute
 917     ;;
 918 arm*linux*eabi)
 919     # Some of the ARM unwinder code is actually in libstdc++.  We
 920     # could in principle replicate it in libgcj, but it's better to
 921     # have a dependency on libstdc++.
 922     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 923     LIBSTDCXXSPEC=-lstdc++
 924     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 925     ;;
 926 *-*-cygwin)
 927     extra_ldflags_libjava=-liconv
 928     ;;
 929 esac
 930 AC_SUBST(extra_ldflags_libjava)
 931 AC_SUBST(extra_gij_ldflags)
 932 AC_SUBST(extra_ldflags)
 933 AC_SUBST(LIBSTDCXXSPEC)
 934
 935 AC_SUBST(LIBGCJTESTSPEC)
 936
 937 # Allow the GC to be disabled.  Can be useful when debugging.
 938 AC_MSG_CHECKING([for garbage collector to use])
 939 AC_ARG_ENABLE(java-gc,
 940   AS_HELP_STRING([--enable-java-gc=TYPE],
 941                  [choose garbage collector (default is boehm)]),
 942   [GC=$enableval],
 943   [GC=boehm])
 944 GCLIBS=
 945 GCINCS=
 946 GCDEPS=
 947 GCSPEC=
 948 JC1GCSPEC=
 949 GCTESTSPEC=
 950 case "$GC" in
 951  boehm)
 952     AC_MSG_RESULT(boehm)
 953     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 954     JC1GCSPEC='-fuse-boehm-gc'
 955     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 956     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 957     GCOBJS=boehm.lo
 958     GCHDR=boehm-gc.h
 959     # The POSIX thread support needs to know this.
 960     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 961     ;;
 962  no)
 963     AC_MSG_RESULT(none)
 964     GCHDR=no-gc.h
 965     ;;
 966  *)
 967     AC_MSG_ERROR([unrecognized collector "$GC"])
 968     ;;
 969 esac
 970 AC_SUBST(GCLIBS)
 971 AC_SUBST(GCINCS)
 972 AC_SUBST(GCDEPS)
 973 AC_SUBST(GCSPEC)
 974 AC_SUBST(JC1GCSPEC)
 975 AC_SUBST(GCTESTSPEC)
 976 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 977 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 978 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 979
 980
 981 AC_MSG_CHECKING([for thread model used by GCC])
 982 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 983 AC_MSG_RESULT([$THREADS])
 984
 985 case "$THREADS" in
 986  no | none | single)
 987     THREADS=none
 988     ;;
 989  aix | posix | posix95 | pthreads)
 990     THREADS=posix
 991     case "$host" in
 992      *-*-linux*)
 993         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 994         ;;
 995     esac
 996     ;;
 997  win32)
 998     ;;
 999  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1000     AC_MSG_ERROR(thread package $THREADS not yet supported)
1001     ;;
1002  *)
1003     AC_MSG_ERROR($THREADS is an unknown thread package)
1004     ;;
1005 esac
1006
1007 THREADCXXFLAGS=
1008 THREADLDFLAGS=
1009 THREADLIBS=
1010 THREADINCS=
1011 THREADDEPS=
1012 THREADH=
1013 THREADSPEC=
1014 THREADSTARTFILESPEC=
1015 case "$THREADS" in
1016  posix)
1017     case "$host" in
1018      *-*-cygwin*)
1019         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1020         ;;
1021      *-*-freebsd[[1234]]*)
1022         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1023         # merely adds pthread_* functions) but it does have a -pthread switch
1024         # which is required at link-time to select -lc_r *instead* of -lc.
1025         THREADLDFLAGS=-pthread
1026         # Don't set THREADSPEC here as might be expected since -pthread is
1027         # not processed when found within a spec file, it must come from
1028         # the command line.  For now, the user must provide the -pthread
1029         # switch to link code compiled with gcj.  In future, consider adding
1030         # support for weak references to pthread_* functions ala gthr.h API.
1031         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1032         ;;
1033      *-*-freebsd*)
1034         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1035         # systems which support threads and -lpthread.
1036         THREADLDFLAGS=-pthread
1037         THREADSPEC=-lpthread
1038         ;;
1039      alpha*-dec-osf* | hppa*-hp-hpux*)
1040         THREADCXXFLAGS=-pthread
1041         # boehm-gc needs some functions from librt, so link that too.
1042         THREADLIBS='-lpthread -lrt'
1043         THREADSPEC='-lpthread -lrt'
1044         ;;
1045      *)
1046         THREADLIBS=-lpthread
1047         THREADSPEC=-lpthread
1048         ;;
1049     esac
1050     THREADH=posix-threads.h
1051     # MIT pthreads doesn't seem to have the mutexattr functions.
1052     # But for now we don't check for it.  We just assume you aren't
1053     # using MIT pthreads.
1054     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1055
1056     # If we're using the Boehm GC, then we happen to know that it
1057     # defines _REENTRANT, so we don't bother.  Eww.
1058     if test "$GC" != boehm; then
1059        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1060     fi
1061     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1062     ;;
1063
1064  win32)
1065     THREADH=win32-threads.h
1066     THREADCXXFLAGS=-mthreads
1067     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1068     # But we do not want the executables created to be dependent on
1069     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1070     # exception handling contexts.  The following kludge achieves this effect
1071     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1072     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1073     # A workaround is to explicitly use -mthreads while linking Java programs.
1074     # See PR libgcj/28263.
1075     #
1076     # FIXME: In Java we are able to detect thread death at the end of
1077     # Thread.run() so we should be able to clean up the exception handling
1078     # contexts ourselves.
1079     THREADSTARTFILESPEC='crtmt%O%s'
1080     ;;
1081
1082  none)
1083     THREADH=no-threads.h
1084     ;;
1085 esac
1086 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1087 AC_SUBST(THREADLIBS)
1088 AC_SUBST(THREADINCS)
1089 AC_SUBST(THREADDEPS)
1090 AC_SUBST(THREADSPEC)
1091 AC_SUBST(THREADSTARTFILESPEC)
1092 AC_SUBST(THREADLDFLAGS)
1093 AC_SUBST(THREADCXXFLAGS)
1094 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1095 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1096 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1097 if test "$enable_shared" != yes; then
1098   use_libgcj_bc=no
1099 fi
1100 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1101
1102 if test -d sysdep; then true; else mkdir sysdep; fi
1103 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1104 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1105 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1106
1107 LIBGCJ_SPEC_LGCJ=-lgcj
1108 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1109 if test x"$libgcj_spec_lgcj_override" != x ; then
1110   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1111 fi
1112 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1113   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1114 fi
1115 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1116 if test "$use_libgcj_bc" = yes; then
1117   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1118   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1119 fi
1120 AC_SUBST(LIBGCJ_SPEC)
1121 AC_SUBST(LIBGCJ_BC_SPEC)
1122
1123 HASH_SYNC_SPEC=
1124 # Hash synchronization is only useful with posix threads right now.
1125 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1126    HASH_SYNC_SPEC=-fhash-synchronization
1127    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1128 fi
1129 AC_SUBST(HASH_SYNC_SPEC)
1130
1131 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1132
1133 # We're in the tree with gcc, and need to include some of its headers.
1134 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1135
1136 if test "x${with_newlib}" = "xyes"; then
1137    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1138    # may not work correctly, because the compiler may not be able to
1139    # link executables.
1140
1141    # We assume newlib.  This lets us hard-code the functions we know
1142    # we'll have.
1143    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1144    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1145    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1146    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1147    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1148    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1149    # This is only for POSIX threads.
1150    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1151
1152    # Assume we do not have getuid and friends.
1153    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1154    PLATFORMNET=NoNet
1155 else
1156    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1157                    localtime_r getpwuid_r getcwd \
1158                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1159                    nl_langinfo setlocale \
1160                    inet_pton uname inet_ntoa \
1161                    getrlimit sigaction ftruncate mmap \
1162                    getifaddrs])
1163    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1164    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1165    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1166    AC_CHECK_LIB(dl, dladdr, [
1167        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1168        AC_CHECK_LIB(dld, dladdr, [
1169        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1170
1171    if test x"$cross_compiling" = x"no"; then
1172      AC_CHECK_FILES(/proc/self/exe, [
1173        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1174      AC_CHECK_FILES(/proc/self/maps, [
1175        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1176          [Define if you have /proc/self/maps])])
1177    else
1178      case $host in
1179      *-linux*)
1180        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1181        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1182        ;;
1183      esac
1184    fi
1185
1186    AM_ICONV
1187    AM_LC_MESSAGES
1188    AC_STRUCT_TIMEZONE
1189
1190    AC_CHECK_FUNCS(gethostbyname_r, [
1191      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1192        [Define if you have the 'gethostbyname_r' function.])
1193      # There are two different kinds of gethostbyname_r.
1194      # We look for the one that returns `int'.
1195      # Hopefully this check is robust enough.
1196      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1197        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1198
1199      case " $GCINCS " in
1200      *" -D_REENTRANT "*) ;;
1201      *)
1202         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1203         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1204         [libjava_cv_gethostbyname_r_needs_reentrant],
1205         [ AC_LANG_PUSH(C++)
1206           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1207             [[gethostbyname_r("", 0, 0);]])],
1208             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1209                 CPPFLAGS_SAVE="$CPPFLAGS"
1210                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1211                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1212                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1213                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1214                 CPPFLAGS="$CPPFLAGS_SAVE"
1215           ])
1216           AC_LANG_POP(C++)
1217         ])
1218         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1219           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1220         fi
1221      ;;
1222      esac
1223
1224      AC_CACHE_CHECK([for struct hostent_data],
1225         [libjava_cv_struct_hostent_data], [dnl
1226         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1227 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1228 # define _REENTRANT 1
1229 #endif
1230 #include <netdb.h>]], [[struct hostent_data data;]])],
1231           [libjava_cv_struct_hostent_data=yes],
1232           [libjava_cv_struct_hostent_data=no])])
1233      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1234        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1235          [Define if struct hostent_data is defined in netdb.h])
1236      fi
1237    ])
1238
1239    # FIXME: libjava source code expects to find a prototype for
1240    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1241    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1242    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1243    # linkage check is enough, yet C++ code requires proper prototypes.)
1244    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1245    AC_CHECK_FUNCS(gethostbyaddr_r, [
1246      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1247        [Define if you have the 'gethostbyaddr_r' function.])
1248      # There are two different kinds of gethostbyaddr_r.
1249      # We look for the one that returns `int'.
1250      # Hopefully this check is robust enough.
1251      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1252        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1253          [Define if gethostbyaddr_r returns 'int'.])])])])
1254
1255    AC_CHECK_FUNCS(gethostname, [
1256      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1257        [Define if you have the 'gethostname' function.])
1258      AC_EGREP_HEADER(gethostname, unistd.h, [
1259        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1260          [Define if gethostname is declared in <unistd.h>.])])])
1261
1262    AC_CHECK_FUNCS(usleep, [
1263      AC_EGREP_HEADER(usleep, unistd.h, [
1264        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1265           [Define if usleep is declared in <unistd.h>.])])])
1266
1267    # Look for these functions in the thread library, but only bother
1268    # if using POSIX threads.
1269    if test "$THREADS" = posix; then
1270       save_LIBS="$LIBS"
1271       LIBS="$LIBS $THREADLIBS"
1272
1273       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1274       # Solaris 7 the name librt is preferred.
1275       AC_CHECK_FUNCS(sched_yield, , [
1276         AC_CHECK_LIB(rt, sched_yield, [
1277           AC_DEFINE(HAVE_SCHED_YIELD)
1278           THREADLIBS="$THREADLIBS -lrt"
1279           THREADSPEC="$THREADSPEC -lrt"], [
1280           AC_CHECK_LIB(posix4, sched_yield, [
1281             AC_DEFINE(HAVE_SCHED_YIELD)
1282             THREADLIBS="$THREADLIBS -lposix4"
1283             THREADSPEC="$THREADSPEC -lposix4"])])])
1284
1285       AC_CHECK_LIB(rt, clock_gettime, [
1286          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1287          case "$THREADSPEC" in
1288            *-lrt*) ;;
1289            *)
1290              THREADSPEC="$THREADSPEC -lrt"
1291              THREADLIBS="$THREADLIBS -lrt"
1292              ;;
1293          esac])
1294
1295       LIBS="$save_LIBS"
1296
1297       # We can save a little space at runtime if the mutex has m_count
1298       # or __m_count.  This is a nice hack for Linux.
1299       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1300           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1301         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1302              [Define if pthread_mutex_t has m_count member.]), [
1303         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1304             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1305           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1306             [Define if pthread_mutex_t has __m_count member.]))])
1307    fi
1308
1309    # We require a way to get the time.
1310    time_found=no
1311    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1312    if test "$time_found" = no; then
1313       AC_MSG_ERROR([no function found to get the time])
1314    fi
1315
1316    AC_CHECK_FUNCS(memmove)
1317
1318    # We require memcpy.
1319    memcpy_found=no
1320    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1321    if test "$memcpy_found" = no; then
1322       AC_MSG_ERROR([memcpy is required])
1323    fi
1324    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1325    AC_CHECK_LIB(dl, dlopen, [
1326        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1327        AC_CHECK_LIB(dld, dlopen, [
1328        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1329
1330    # Some library-finding code we stole from Tcl.
1331    #--------------------------------------------------------------------
1332    #    Check for the existence of the -lsocket and -lnsl libraries.
1333    #    The order here is important, so that they end up in the right
1334    #    order in the command line generated by make.  Here are some
1335    #    special considerations:
1336    #    1. Use "connect" and "accept" to check for -lsocket, and
1337    #       "gethostbyname" to check for -lnsl.
1338    #    2. Use each function name only once:  can't redo a check because
1339    #       autoconf caches the results of the last check and won't redo it.
1340    #    3. Use -lnsl and -lsocket only if they supply procedures that
1341    #       aren't already present in the normal libraries.  This is because
1342    #       IRIX 5.2 has libraries, but they aren't needed and they're
1343    #       bogus:  they goof up name resolution if used.
1344    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1345    #       To get around this problem, check for both libraries together
1346    #       if -lsocket doesn't work by itself.
1347    #--------------------------------------------------------------------
1348
1349    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1350     [gcj_cv_lib_sockets=
1351      gcj_checkBoth=0
1352      unset ac_cv_func_connect
1353      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1354      if test "$gcj_checkSocket" = 1; then
1355          unset ac_cv_func_connect
1356          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1357                       gcj_checkBoth=1)
1358      fi
1359      if test "$gcj_checkBoth" = 1; then
1360          gcj_oldLibs=$LIBS
1361          LIBS="$LIBS -lsocket -lnsl"
1362          unset ac_cv_func_accept
1363          AC_CHECK_FUNC(accept,
1364                        [gcj_checkNsl=0
1365                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1366          unset ac_cv_func_accept
1367          LIBS=$gcj_oldLibs
1368      fi
1369      unset ac_cv_func_gethostbyname
1370      gcj_oldLibs=$LIBS
1371      LIBS="$LIBS $gcj_cv_lib_sockets"
1372      AC_CHECK_FUNC(gethostbyname, ,
1373                    [AC_CHECK_LIB(nsl, main,
1374                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1375      unset ac_cv_func_gethostbyname
1376      LIBS=$gcj_oldLIBS
1377    ])
1378    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1379
1380    if test "$with_system_zlib" = yes; then
1381       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1382    fi
1383
1384    # Test for Gtk stuff, if asked for.
1385    if test "$use_gtk_awt" = yes; then
1386       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1387       AC_SUBST(GTK_CFLAGS)
1388       AC_SUBST(GTK_LIBS)
1389
1390       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1391       AC_SUBST(GLIB_CFLAGS)
1392       AC_SUBST(GLIB_LIBS)
1393
1394       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1395       AC_SUBST(LIBART_CFLAGS)
1396       AC_SUBST(LIBART_LIBS)
1397
1398       # We require the XTest Extension to support java.awt.Robot.
1399       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1400                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1401                    [${X_LIBS}])
1402    fi
1403
1404    # On Solaris, and maybe other architectures, the Boehm collector
1405    # requires -ldl.
1406    if test "$GC" = boehm; then
1407       case "${host}" in
1408           mips-sgi-irix6*)
1409             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1410             # libgcj.spec is used, so override here
1411             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1412           ;;
1413           *)
1414             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1415           ;;
1416       esac
1417    fi
1418 fi
1419
1420 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1421 case $build in
1422     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1423     *)         CLASSPATH_SEPARATOR=':' ;;
1424 esac
1425 AC_SUBST(CLASSPATH_SEPARATOR)
1426
1427 # We must search the source tree for java.lang, since we still don't
1428 # have libgcj.jar nor java/lang/*.class
1429 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1430 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1431
1432 # Since some classes depend on this one, we need its source available
1433 # before we can do any GCJ compilation test :-(
1434 if test ! -f gnu/classpath/Configuration.java; then
1435   test -d gnu || mkdir gnu
1436   test -d gnu/classpath || mkdir gnu/classpath
1437   # Note that it is not crucial that all the values here be correct.
1438   sed -e "s,@prefix@,$prefix," \
1439       -e "s,@VERSION@,$VERSION," \
1440       -e "s,@LIBDEBUG@,false," \
1441       -e "s,@INIT_LOAD_LIBRARY@,false," \
1442       -e "s,@@,$LIBGCJDEBUG," \
1443       -e "s,@default_toolkit@,$TOOLKIT," \
1444       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1445       -e "s,@GTK_CAIRO_ENABLED@,false," \
1446       -e "s,@ECJ_JAR@,," \
1447       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1448         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1449         > gnu/classpath/Configuration.java
1450   # We do not want to redirect the output of the grep below to /dev/null,
1451   # but we add /dev/null to the input list so that grep will print the
1452   # filename of Configuration.java in case it finds any matches.
1453   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1454     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1455   fi
1456 fi
1457
1458 LT_AC_PROG_GCJ
1459
1460 # Now remove it.
1461 rm -f gnu/classpath/Configuration.java
1462
1463 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1464
1465 AC_CHECK_SIZEOF(void *)
1466
1467 AC_C_BIGENDIAN
1468
1469 ZLIBS=
1470 SYS_ZLIBS=
1471 ZINCS=
1472
1473 if test -z "$ZLIBSPEC"; then
1474    # Use zlib from the GCC tree.
1475    ZINCS='-I$(top_srcdir)/../zlib'
1476    ZLIBS=../zlib/libzgcj_convenience.la
1477 else
1478    # System's zlib.
1479    SYS_ZLIBS="$ZLIBSPEC"
1480 fi
1481 AC_SUBST(ZLIBS)
1482 AC_SUBST(SYS_ZLIBS)
1483 AC_SUBST(ZINCS)
1484 AC_SUBST(DIVIDESPEC)
1485 AC_SUBST(CHECKREFSPEC)
1486 AC_SUBST(EXCEPTIONSPEC)
1487 AC_SUBST(BACKTRACESPEC)
1488 AC_SUBST(IEEESPEC)
1489 AC_SUBST(ATOMICSPEC)
1490
1491 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1492 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1493 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1494 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1495 AC_SUBST(GCC_UNWIND_INCLUDE)
1496
1497 # Process the option "--enable-version-specific-runtime-libs"
1498 # Calculate toolexeclibdir
1499 case ${version_specific_libs} in
1500   yes)
1501     # Need the gcc compiler version to know where to install libraries
1502     # and header files if --enable-version-specific-runtime-libs option
1503     # is selected.
1504     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1505     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1506     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1507     toolexeclibdir=$toolexecmainlibdir
1508     ;;
1509   no)
1510     if test -n "$with_cross_host" &&
1511        test x"$with_cross_host" != x"no"; then
1512       # Install a library built with a cross compiler in tooldir, not libdir.
1513       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1514       toolexecmainlibdir='$(toolexecdir)/lib'
1515     else
1516       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1517       toolexecmainlibdir='$(libdir)'
1518     fi
1519     multi_os_directory=`$CC -print-multi-os-directory`
1520     case $multi_os_directory in
1521       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1522       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1523     esac
1524     ;;
1525 esac
1526 AC_SUBST(toolexecdir)
1527 AC_SUBST(toolexecmainlibdir)
1528 AC_SUBST(toolexeclibdir)
1529
1530 # Determine gcj and libgcj version number.
1531 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1532 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1533 GCJVERSION=$gcjversion
1534 AC_SUBST(GCJVERSION)
1535 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1536
1537 # Determine where the standard .db file and GNU Classpath JNI
1538 # libraries are found.
1539 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1540 multi_os_directory=`$CC -print-multi-os-directory`
1541 case $multi_os_directory in
1542   .)
1543    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1544    ;;
1545   *)
1546    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1547    ;;
1548 esac
1549 AC_SUBST(dbexecdir)
1550 AC_SUBST(gcjsubdir)
1551
1552 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1553 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1554
1555 TL_AC_GXX_INCLUDE_DIR
1556
1557 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1558 # On that system, sys/ioctl.h will not include sys/filio.h unless
1559 # BSD_COMP is defined; just including sys/filio.h is simpler.
1560 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1561 # for now.  If you change this, you also must update natFile.cc.
1562 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1563                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1564                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1565                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1566                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1567 AC_CHECK_HEADERS(inttypes.h, [
1568     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1569     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1570 ])
1571
1572 AC_CHECK_TYPE([ssize_t], [int])
1573 AC_CHECK_TYPE([magic_t], [
1574     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1575 #ifdef HAVE_MAGIC_H
1576 #include <magic.h>
1577 #endif])
1578
1579 AC_MSG_CHECKING([for in_addr_t])
1580 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1581 #if STDC_HEADERS
1582 #include <stdlib.h>
1583 #include <stddef.h>
1584 #endif
1585 #if HAVE_NETINET_IN_H
1586 #include <netinet/in.h>
1587 #endif]], [[in_addr_t foo;]])],
1588   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1589      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1590    AC_MSG_RESULT(yes)],
1591   [AC_MSG_RESULT(no)])
1592
1593 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1594 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1595   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1596      [Define if struct ip_mreq is defined in netinet/in.h.])
1597    AC_MSG_RESULT(yes)],
1598   [AC_MSG_RESULT(no)])
1599
1600 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1601 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1602   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1603      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1604    AC_MSG_RESULT(yes)],
1605   [AC_MSG_RESULT(no)])
1606
1607 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1608 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1609   [AC_DEFINE(HAVE_INET6, 1,
1610      [Define if inet6 structures are defined in netinet/in.h.])
1611    AC_MSG_RESULT(yes)],
1612   [AC_MSG_RESULT(no)])
1613
1614 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1615 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1616 #include <sys/types.h>
1617 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1618   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1619    AC_MSG_RESULT(yes)],
1620   [AC_MSG_RESULT(no)])
1621
1622 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1623 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1624   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1625    AC_MSG_RESULT(yes)],
1626   [AC_MSG_RESULT(no)
1627    AC_MSG_CHECKING([for global timezone variable])
1628    dnl FIXME: we don't want a link check here because that won't work
1629    dnl when cross-compiling.  So instead we make an assumption that
1630    dnl the header file will mention timezone if it exists.
1631    dnl Don't find the win32 function timezone
1632    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1633      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1634       AC_MSG_RESULT(yes)],
1635      [AC_MSG_RESULT(no)
1636        AC_MSG_CHECKING([for global _timezone variable])
1637        dnl FIXME: As above, don't want link check
1638        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1639          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1640             [Define if your platform has the global _timezone variable.])
1641           AC_MSG_RESULT(yes)],
1642           [AC_MSG_RESULT(no)])])])
1643
1644 AC_CHECK_PROGS(PERL, perl, false)
1645
1646 SYSDEP_SOURCES=
1647 SIGNAL_HANDLER_AUX=
1648
1649 case "${host}" in
1650  i?86-*-linux*)
1651     SIGNAL_HANDLER=include/i386-signal.h
1652     ;;
1653  sparc*-sun-solaris*)
1654     SIGNAL_HANDLER=include/sparc-signal.h
1655     ;;
1656 # ia64-*)
1657 #    SYSDEP_SOURCES=sysdep/ia64.c
1658 #    test -d sysdep || mkdir sysdep
1659 #    ;;
1660  hppa*-*-linux*)
1661     SIGNAL_HANDLER=include/pa-signal.h
1662     ;;
1663  hppa*-hp-hpux*)
1664     SIGNAL_HANDLER=include/hppa-signal.h
1665     ;;
1666  ia64-*-linux*)
1667     SIGNAL_HANDLER=include/dwarf2-signal.h
1668     ;;
1669  powerpc*-*-linux*)
1670     SIGNAL_HANDLER=include/powerpc-signal.h
1671     ;;
1672  alpha*-*-linux*)
1673     SIGNAL_HANDLER=include/dwarf2-signal.h
1674     ;;
1675  s390*-*-linux*)
1676     SIGNAL_HANDLER=include/s390-signal.h
1677     ;;
1678  x86_64*-*-linux*)
1679     SIGNAL_HANDLER=include/x86_64-signal.h
1680     SIGNAL_HANDLER_AUX=include/i386-signal.h
1681     ;;
1682  sparc*-*-linux*)
1683     SIGNAL_HANDLER=include/dwarf2-signal.h
1684     ;;
1685  sh*-*-linux*)
1686     SIGNAL_HANDLER=include/sh-signal.h
1687     ;;
1688  *mingw*)
1689     SIGNAL_HANDLER=include/win32-signal.h
1690     ;;
1691  mips*-*-linux*)
1692     SIGNAL_HANDLER=include/mips-signal.h
1693     ;;
1694  m68*-*-linux*)
1695     SIGNAL_HANDLER=include/dwarf2-signal.h
1696     ;;
1697  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1698     SIGNAL_HANDLER=include/darwin-signal.h
1699     ;;
1700  powerpc*-*-aix*)
1701     SIGNAL_HANDLER=include/aix-signal.h
1702     ;;
1703  *)
1704     SIGNAL_HANDLER=include/default-signal.h
1705     ;;
1706 esac
1707
1708 # If we're using sjlj exceptions, forget what we just learned.
1709 if test "$enable_sjlj_exceptions" = yes; then
1710    SIGNAL_HANDLER=include/default-signal.h
1711    SIGNAL_HANDLER_AUX=
1712 fi
1713
1714 AC_SUBST(SYSDEP_SOURCES)
1715
1716 if test -z "$SIGNAL_HANDLER_AUX"; then
1717   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1718 fi
1719
1720 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1721                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1722
1723 if test "${multilib}" = "yes"; then
1724   multilib_arg="--enable-multilib"
1725 else
1726   multilib_arg=
1727 fi
1728
1729 # See if we support thread-local storage.
1730 GCC_CHECK_TLS
1731
1732 # For _Unwind_GetIPInfo.
1733 GCC_CHECK_UNWIND_GETIPINFO
1734
1735 # See if linker supports anonymous version scripts.
1736 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1737   [libjava_cv_anon_version_script],
1738   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1739    libjava_cv_anon_version_script=no
1740    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1741    echo '{ global: globalsymb*; local: *; };' > conftest.map
1742    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1743                [libjava_cv_anon_version_script=yes], [])
1744    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1745   ])
1746 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1747
1748 # Check if linker supports static linking on a per library basis
1749 LD_START_STATIC_SPEC=
1750 LD_FINISH_STATIC_SPEC=
1751 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1752   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1753     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1754     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1755   fi
1756 fi
1757 AC_SUBST(LD_START_STATIC_SPEC)
1758 AC_SUBST(LD_FINISH_STATIC_SPEC)
1759
1760 here=`${PWDCMD-pwd}`
1761 AC_SUBST(here)
1762
1763 # We get this from the environment.
1764 AC_SUBST(GCJFLAGS)
1765
1766 AC_ARG_WITH([python-dir],
1767             AS_HELP_STRING([--with-python-dir],
1768                            [the location to install Python modules. This path should NOT include the prefix.]),
1769             [with_python_dir=$withval], [with_python_dir=""])
1770
1771 if test "x${with_python_dir}" = "x"
1772 then
1773   # Needed for installing Python modules during make install.
1774   python_mod_dir="\${prefix}/share/python"
1775   # Needed for substituting into aot-compile*
1776   python_mod_dir_expanded="${prefix}/share/python"
1777 else
1778   python_mod_dir="\${prefix}${with_python_dir}"
1779   python_mod_dir_expanded="${prefix}${with_python_dir}"
1780 fi
1781 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1782 AC_SUBST(python_mod_dir)
1783 AC_SUBST(python_mod_dir_expanded)
1784
1785 # needed for aot-compile-rpm
1786 MAKE=`which make`
1787 AC_SUBST(MAKE)
1788
1789 AC_ARG_ENABLE([aot-compile-rpm],
1790   [AS_HELP_STRING([--enable-aot-compile-rpm],
1791                  [enable installation of aot-compile-rpm [default=no]])],
1792   [case "${enableval}" in
1793     yes) AOT_RPM_ENABLED=yes ;;
1794     no)  AOT_RPM_ENABLED=no ;;
1795     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1796   esac],
1797   [AOT_RPM_ENABLED=no]
1798 )
1799 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1800
1801 AC_ARG_ENABLE([java-home],
1802   [AS_HELP_STRING([--enable-java-home],
1803                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1804   [case "${enableval}" in
1805     yes) JAVA_HOME_ENABLED=yes ;;
1806     no)  JAVA_HOME_ENABLED=no ;;
1807     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1808   esac],
1809   [JAVA_HOME_ENABLED=no]
1810 )
1811 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1812
1813 # Only do these checks if java-home above is enabled.
1814 if test "x${JAVA_HOME_ENABLED}" = xyes
1815 then
1816
1817   AC_ARG_WITH([gcc-suffix],
1818               AS_HELP_STRING([--with-gcc-suffix],
1819                              [the GCC tool suffix (defaults to empty string)]),
1820               [gcc_suffix=$withval], [gcc_suffix=""])
1821   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1822   AC_SUBST(gcc_suffix)
1823
1824   AC_ARG_WITH([arch-directory],
1825               AS_HELP_STRING([--with-arch-directory],
1826                              [the arch directory under jre/lib (defaults to auto-detect)]),
1827               [host_cpu=$withval], [host_cpu=""])
1828
1829   AC_ARG_WITH([os-directory],
1830               AS_HELP_STRING([--with-os-directory],
1831                              [the os directory under include (defaults to auto-detect)]),
1832               [host_os=$withval], [host_os=""])
1833
1834   AC_ARG_WITH([origin-name],
1835               AS_HELP_STRING([--with-origin-name],
1836                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1837               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1838   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1839
1840   AC_ARG_WITH([arch-suffix],
1841               AS_HELP_STRING([--with-arch-suffix],
1842                              [the arch directory suffix (default is the empty string]),
1843               [arch_suffix=$withval], [arch_suffix=""])
1844   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1845
1846   AC_ARG_WITH([jvm-root-dir],
1847               AS_HELP_STRING([--with-jvm-root-dir],
1848                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1849               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1850   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1851
1852   AC_ARG_WITH([jvm-jar-dir],
1853               AS_HELP_STRING([--with-jvm-jar-dir],
1854                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1855               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1856   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1857
1858   JAVA_VERSION=1.5.0
1859   BUILD_VERSION=0
1860   AC_SUBST(JAVA_VERSION)
1861   AC_SUBST(BUILD_VERSION)
1862   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1863
1864   jre_dir=jre
1865   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1866   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1867
1868   JVM_ROOT_DIR=${jvm_root_dir}
1869   AC_SUBST(JVM_ROOT_DIR)
1870   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1871
1872   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1873   AC_SUBST(JVM_JAR_ROOT_DIR)
1874   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1875
1876   JVM_JAR_DIR=${jvm_jar_dir}
1877   AC_SUBST(JVM_JAR_DIR)
1878   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1879
1880   JRE_DIR=${jre_dir}
1881   AC_SUBST(JRE_DIR)
1882
1883   JRE_LNK=${jre_lnk}
1884   AC_SUBST(JRE_LNK)
1885
1886   SDK_LNK=${sdk_lnk}
1887   AC_SUBST(SDK_LNK)
1888
1889   SDK_BIN_DIR=${jvm_root_dir}/bin
1890   AC_SUBST(SDK_BIN_DIR)
1891   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1892
1893   SDK_LIB_DIR=${jvm_root_dir}/lib
1894   AC_SUBST(SDK_LIB_DIR)
1895   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1896
1897   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1898   AC_SUBST(SDK_INCLUDE_DIR)
1899   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1900
1901   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1902   AC_SUBST(JRE_BIN_DIR)
1903   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1904
1905   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1906   AC_SUBST(JRE_LIB_DIR)
1907   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1908
1909   # Find gcj prefix using gcj found in PATH.
1910   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1911
1912   # Where do the gcj binaries live?
1913   # For jhbuild based builds, they all live in a sibling of bin called
1914   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1915   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1916   AC_SUBST(GCJ_BIN_DIR)
1917   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1918
1919   AC_MSG_RESULT(host is ${host})
1920   if test "x${host_cpu}" = "x"
1921   then
1922     case ${host} in
1923       *-mingw* | *-cygwin*)
1924         host_cpu=x86;;
1925       i486-* | i586-* | i686-*)
1926         host_cpu=i386;;
1927       x86_64-*)
1928         host_cpu=amd64;;
1929       *)
1930         host_cpu=${host_cpu};;
1931     esac
1932   fi
1933   AC_MSG_RESULT(arch directory: ${host_cpu})
1934   CPU=${host_cpu}
1935   AC_SUBST(CPU)
1936
1937   if test "x${host_os}" = "x"
1938   then
1939     case ${host} in
1940       *-mingw* | *-cygwin*)
1941         host_os=win32;;
1942       *-linux*)
1943         host_os=linux;;
1944       *)
1945         host_os=${host_os};;
1946     esac
1947   fi
1948   echo os directory: ${host_os}
1949   OS=${host_os}
1950   AC_SUBST(OS)
1951
1952   # make an expanded $libdir, for substituting into
1953   # scripts (and other non-Makefile things).
1954   LIBDIR=$libdir
1955   if test "x${exec_prefix}" = "xNONE"
1956   then
1957       lib_exec_prefix=$prefix
1958   else
1959       lib_exec_prefix=$exec_prefix
1960   fi
1961   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1962   AC_SUBST(LIBDIR)
1963 fi
1964
1965 AC_CONFIG_FILES([
1966 Makefile
1967 libgcj.pc
1968 libgcj.spec
1969 libgcj-test.spec
1970 gcj/Makefile
1971 include/Makefile
1972 testsuite/Makefile
1973 contrib/aotcompile.py
1974 contrib/aot-compile
1975 contrib/aot-compile-rpm
1976 contrib/generate-cacerts.pl
1977 contrib/rebuild-gcj-db
1978 ])
1979
1980 if test ${multilib} = yes; then
1981   multilib_arg="--enable-multilib"
1982 else
1983   multilib_arg=
1984 fi
1985
1986 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1987 AC_OUTPUT