libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120
 121 # We need a jar that supports -@.  This is a GNU extension.
 122 if test "$JAR" != no; then
 123    rm -f config-test.jar
 124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 125    if test -f config-test.jar; then
 126      rm -f config-test.jar
 127    else
 128      JAR=no
 129    fi
 130 fi
 131
 132 # Prefer the jar we found, but fall back to our jar script.
 133 if test "$JAR" = no; then
 134   if test "$ZIP" = no; then
 135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 136   else
 137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 138     JAR=`pwd`/scripts/jar
 139   fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 AM_MAINTAINER_MODE
 145
 146 AC_EXEEXT
 147
 148 # configure.host sets the following important variables
 149 #       libgcj_cflags    - host specific C compiler flags
 150 #       libgcj_cxxflags  - host specific C++ compiler flags
 151 #       libgcj_javaflags - host specific Java compiler flags
 152
 153 libgcj_cflags=
 154 libgcj_cxxflags=
 155 libgcj_javaflags=
 156
 157 . ${srcdir}/configure.host
 158
 159 ACX_PROG_LD_GNU_SYMBOLIC
 160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 161 if test -z "$libgcj_ld_symbolic"; then
 162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 163 fi
 164
 165 LIBGCJ_CFLAGS="${libgcj_cflags}"
 166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 170 AC_SUBST(LIBGCJ_CFLAGS)
 171 AC_SUBST(LIBGCJ_CXXFLAGS)
 172 AC_SUBST(LIBGCJ_JAVAFLAGS)
 173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 175
 176 # Only use libltdl for non-newlib builds.
 177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 178    AC_LTDL_SHLIBPATH
 179 fi
 180
 181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 182
 183 # See if the user has requested runtime debugging.
 184 LIBGCJDEBUG="disable"
 185 AC_SUBST(LIBGCJDEBUG)
 186 AC_ARG_ENABLE(libgcj-debug,
 187   AS_HELP_STRING([--enable-libgcj-debug],
 188                  [enable runtime debugging code]),
 189   [if test "$enable_libgcj_debug" = yes; then
 190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 191     LIBGCJDEBUG="enable"
 192   fi])
 193
 194 AC_ARG_WITH([escher],
 195          AS_HELP_STRING([--with-escher=ABS.PATH],
 196                         [specify path to escher dir or JAR for X peers]))
 197 case "$with_escher" in
 198 "")
 199         use_escher=false
 200         ;;
 201 "no")
 202         use_escher=false
 203         ;;
 204 "yes")
 205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 206         ;;
 207 *)
 208         use_escher=true
 209         ;;
 210 esac
 211
 212 # Determine which AWT peer libraries to build
 213 AC_ARG_ENABLE(java-awt,
 214   AS_HELP_STRING([--enable-java-awt],
 215                  [list of AWT peer implementations to be built]))
 216
 217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 218 use_xlib_awt=""
 219 use_gtk_awt=""
 220 use_qt_awt=""
 221 use_x_awt=""
 222 # The default toolkit to use is the first one specified.
 223 TOOLKIT=
 224 AC_SUBST(TOOLKIT)
 225
 226 for peer in $peerlibs ; do
 227   case $peer in
 228     xlib)
 229       if test "$no_x" = yes; then
 230         echo "*** xlib peers requested but no X library available" 1>&2
 231         exit 1
 232       else
 233         use_xlib_awt="yes"
 234         if test -z "$TOOLKIT"; then
 235            TOOLKIT=gnu.awt.xlib.XToolkit
 236         fi
 237       fi
 238       ;;
 239     gtk)
 240       if test "$no_x" = yes; then
 241          echo "*** gtk peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_gtk_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 247          fi
 248       fi
 249       ;;
 250     qt)
 251       if test "$no_x" = yes; then
 252          # Perhaps we should admit the possibility of embedded Qt.
 253          echo "*** Qt peers requested but no X library available" 1>&2
 254          exit 1
 255       else
 256          use_qt_awt=yes
 257          if test -z "$TOOLKIT"; then
 258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 259          fi
 260       fi
 261       ;;
 262     x)
 263       use_x_awt=yes
 264       if test -z "$TOOLKIT"; then
 265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 266       fi
 267       ;;
 268     no)
 269       use_xlib_awt=
 270       use_gtk_awt=
 271       use_qt_awt=
 272       use_x_awt=
 273       break
 274       ;;
 275     *)
 276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 277       exit 1
 278   esac
 279 done
 280
 281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 283
 284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 285
 286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 287
 288 # Create standard.omit based on decisions we just made.
 289 cp $srcdir/standard.omit.in standard.omit
 290 if test "$use_xlib_awt" != yes; then
 291    echo gnu/awt/xlib >> standard.omit
 292    echo gnu/gcj/xlib >> standard.omit
 293 fi
 294 if test "$use_x_awt" != yes; then
 295    echo gnu/java/awt/peer/x >> standard.omit
 296 fi
 297
 298 # Tools that need to be compiled against classpath's tools classes
 299 : > vm-tools-packages
 300 for package in gnu/gcj/tools/gc_analyze ; do
 301     echo $package >> standard.omit
 302     echo $package >> vm-tools-packages
 303 done
 304
 305 if test -z "${with_multisubdir}"; then
 306    builddotdot=.
 307 else
 308    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 309 fi
 310
 311 NATIVE=yes
 312
 313 # Which gcj and host gcj (for ecjx) do we use?
 314 which_gcj=default
 315 host_exeext=${ac_exeext}
 316 GCJ_FOR_ECJX=
 317 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 318 if test -n "${with_cross_host}"; then
 319   # We are being configured with a cross compiler. We can't
 320   # use ac_exeext, because that is for the target platform.
 321   NATIVE=no
 322   cross_host_exeext=
 323   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 324   case "${with_cross_host}" in
 325      *mingw* | *cygwin*)
 326          cross_host_exeext=.exe
 327      ;;
 328   esac
 329   host_exeext=${cross_host_exeext}
 330   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 331      if test x"$build_noncanonical" = x"$with_cross_host"; then
 332         # Ordinary cross (host!=target and host=build)
 333         which_gcj=built
 334      else
 335         # Canadian cross (host!=target and host!=build)
 336         which_gcj=cross
 337      fi
 338   else
 339      which_gcj=cross
 340   fi
 341 else
 342   # We are being configured with a native or crossed-native compiler
 343   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 344      if test x"$build" = x"$host"; then
 345         # True native build (host=target and host=build)
 346         which_gcj=built
 347      else
 348         # Crossed-native build (host=target and host!=build)
 349         which_gcj=cross
 350      fi
 351   else
 352      which_gcj=path
 353   fi
 354 fi
 355 case "${which_gcj}" in
 356    built)
 357       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 358       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 359    ;;
 360    cross)
 361       if test "x${with_newlib}" = "xyes"; then
 362          # FIXME (comment): Why is this needed?
 363          GCC_UNWIND_INCLUDE=
 364          GCJ="${target_noncanonical}-gcj"
 365       else
 366          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 367       fi
 368       GCJH='$(target_noncanonical)-gcjh'
 369    ;;
 370    path)
 371       GCJ="gcj -B`${PWDCMD-pwd}`/"
 372       GCJH=gcjh
 373    ;;
 374 esac
 375
 376 AC_SUBST(GCJ_FOR_ECJX)
 377 AC_SUBST(GCJH)
 378 AC_SUBST(host_exeext)
 379
 380 # Create it, so that compile/link tests don't fail
 381 test -f libgcj.spec || touch libgcj.spec
 382
 383
 384
 385 # Set up to configure Classpath.
 386 # FIXME: no supported way to pass args in autoconf.
 387 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 388 # Disable tool wrappers to avoid ltdl.h configure check.
 389 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 390 ac_configure_args="$ac_configure_args --disable-load-library"
 391 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 392 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 393 dir1=`cd $srcdir && pwd`
 394 dir2=`pwd`
 395 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 396 ac_configure_args="$ac_configure_args --disable-core-jni"
 397 dnl FIXME?
 398 ac_configure_args="$ac_configure_args --disable-examples"
 399 ac_configure_args="$ac_configure_args --with-glibj=build"
 400 if test "$plugin_enabled" != yes; then
 401   ac_configure_args="$ac_configure_args --disable-plugin"
 402 fi
 403 if test "$gconf_enabled" != yes; then
 404   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 405   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 406 fi
 407 if test "$use_gtk_awt" != yes; then
 408   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 409 fi
 410 if test "$use_qt_awt" != yes; then
 411   ac_configure_args="$ac_configure_args --disable-qt-peer"
 412 else
 413   # We need this as qt is disabled by default in classpath.
 414   ac_configure_args="$ac_configure_args --enable-qt-peer"
 415 fi
 416 if test "$use_x_awt" != yes; then
 417   ac_configure_args="$ac_configure_args --without-escher"
 418 else
 419   # We need this as escher is disabled by default in classpath.
 420   if test "$use_escher" != true; then
 421     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 422   else
 423     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 424   fi
 425 fi
 426 # -Werror causes unavoidable problems in code using alsa.
 427 ac_configure_args="$ac_configure_args --disable-Werror"
 428 dnl --with-gcj=$GCJ
 429 dnl --with-javah=$GCJH
 430 dnl gjdoc?
 431 dnl gtk-cairo -- just export here...
 432 dnl --enable-regen-headers?
 433
 434 # Only use libltdl for non-newlib builds.
 435 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 436    AC_LIBLTDL_CONVENIENCE
 437    AC_LIBTOOL_DLOPEN
 438    DIRLTDL=libltdl
 439    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 440    # Sigh.  Libtool's macro doesn't do the right thing.
 441    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 442    # FIXME: this is a hack.
 443    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 444    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 445 fi
 446 AC_SUBST(INCLTDL)
 447 AC_SUBST(LIBLTDL)
 448 AC_SUBST(DIRLTDL)
 449 AC_PROG_LIBTOOL
 450 AM_PROG_GCJ
 451 AM_PROG_CC_C_O
 452
 453 AC_CONFIG_SUBDIRS(classpath libltdl)
 454
 455 # The -no-testsuite modules omit the test subdir.
 456 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 457
 458 # Should the runtime set system properties by examining the
 459 # environment variable GCJ_PROPERTIES?
 460 AC_ARG_ENABLE(getenv-properties,
 461   AS_HELP_STRING([--disable-getenv-properties],
 462                  [don't set system properties from GCJ_PROPERTIES]))
 463
 464 # Whether GCJ_PROPERTIES is used depends on the target.
 465 if test -z "$enable_getenv_properties"; then
 466    enable_getenv_properties=${enable_getenv_properties_default-yes}
 467 fi
 468 if test "$enable_getenv_properties" = no; then
 469    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 470      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 471 fi
 472
 473 # Whether we should use arguments to main()
 474 if test -z "$enable_main_args"; then
 475    enable_main_args=${enable_main_args_default-yes}
 476 fi
 477 if test "$enable_main_args" = no; then
 478    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 479 fi
 480
 481
 482 # Should we use hashtable-based synchronization?
 483 # Currently works only for Linux X86/ia64
 484 # Typically faster and more space-efficient
 485 AC_ARG_ENABLE(hash-synchronization,
 486   AS_HELP_STRING([--enable-hash-synchronization],
 487                  [use global hash table for monitor locks]))
 488
 489 if test -z "$enable_hash_synchronization"; then
 490    enable_hash_synchronization=$enable_hash_synchronization_default
 491 fi
 492
 493
 494 install_ecj_jar=no
 495 ECJ_BUILD_JAR=
 496 ECJ_JAR=
 497 AC_ARG_WITH(ecj-jar,
 498         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 499         [ECJ_JAR=$withval],
 500         [if test -f $multi_basedir/ecj.jar; then
 501            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 502            ECJ_JAR='$(jardir)/ecj.jar'
 503            install_ecj_jar=yes
 504          fi])
 505 AC_SUBST(ECJ_BUILD_JAR)
 506 AC_SUBST(ECJ_JAR)
 507 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 508 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 509
 510 AC_ARG_WITH(java-home,
 511   AS_HELP_STRING([--with-java-home=DIRECTORY],
 512                  [value of java.home system property]),
 513                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 514 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 515 AC_SUBST(JAVA_HOME)
 516
 517 # What is the native OS API for MinGW?
 518 AC_ARG_WITH(win32-nlsapi,
 519   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 520                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 521 [case "${withval}" in
 522   ansi) with_win32_nlsapi=ansi ;;
 523   unicows) with_win32_nlsapi=unicows ;;
 524   unicode) with_win32_nlsapi=unicode ;;
 525   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 526 esac],[with_win32_nlsapi=ansi])
 527
 528 case "${with_win32_nlsapi}" in
 529   unicows | unicode)
 530     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 531       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 532     ;;
 533 esac
 534
 535 # configure.host sets slow_pthread_self if the synchronization code should
 536 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 537 if test "${slow_pthread_self}" = "yes"; then
 538   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 539     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 540 fi
 541
 542 # Check for gc debugging.  This option is handled both here and in the GC.
 543 AC_ARG_ENABLE(gc-debug,
 544    AS_HELP_STRING([--enable-gc-debug],
 545                   [include full support for pointer backtracing etc.]),
 546 [ if test "$enable_gc_debug" = "yes"; then
 547     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 548               [Define if we want to use debug calls into the garbage collector.])
 549   fi])
 550
 551 # See if the user has the interpreter included.
 552 AC_ARG_ENABLE(interpreter,
 553   AS_HELP_STRING([--enable-interpreter],
 554                  [enable interpreter]),
 555   [if test "$enable_interpreter" = yes; then
 556     # This can also be set in configure.host.
 557     libgcj_interpreter=yes
 558   elif test "$enable_interpreter" = no; then
 559     libgcj_interpreter=no
 560   fi])
 561
 562 if test "$libgcj_interpreter" = yes; then
 563    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 564 fi
 565 INTERPRETER="$libgcj_interpreter"
 566 AC_SUBST(INTERPRETER)
 567
 568 AC_MSG_CHECKING([for exception model to use])
 569 AC_LANG_PUSH(C++)
 570 AC_ARG_ENABLE(sjlj-exceptions,
 571   AS_HELP_STRING([--enable-sjlj-exceptions],
 572                  [force use of builtin_setjmp for exceptions]),
 573 [:],
 574 [dnl Botheration.  Now we've got to detect the exception model.
 575 dnl Link tests against libgcc.a are problematic since -- at least
 576 dnl as of this writing -- we've not been given proper -L bits for
 577 dnl single-tree newlib and libgloss.
 578 dnl
 579 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 580 dnl conftest files before we got a change to grep them first.
 581 cat > conftest.$ac_ext << EOF
 582 [#]line __oline__ "configure"
 583 struct S { ~S(); };
 584 void bar();
 585 void foo()
 586 {
 587   S s;
 588   bar();
 589 }
 590 EOF
 591 old_CXXFLAGS="$CXXFLAGS"
 592 CXXFLAGS=-S
 593 if AC_TRY_EVAL(ac_compile); then
 594   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 595     enable_sjlj_exceptions=yes
 596   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 597     enable_sjlj_exceptions=no
 598   fi
 599 fi
 600 CXXFLAGS="$old_CXXFLAGS"
 601 rm -f conftest*])
 602 if test x$enable_sjlj_exceptions = xyes; then
 603   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 604         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 605   ac_exception_model_name=sjlj
 606 elif test x$enable_sjlj_exceptions = xno; then
 607   ac_exception_model_name="call frame"
 608 else
 609   AC_MSG_ERROR([unable to detect exception model])
 610 fi
 611 AC_LANG_POP(C++)
 612 AC_MSG_RESULT($ac_exception_model_name)
 613
 614 # If we are non using SJLJ exceptions, and this host does not have support
 615 # for unwinding from a signal handler, enable checked dereferences and divides.
 616 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 617   CHECKREFSPEC=-fcheck-references
 618   DIVIDESPEC=-fuse-divide-subroutine
 619   EXCEPTIONSPEC=
 620 fi
 621
 622 # See if the user wants to disable java.net.  This is the mildly
 623 # ugly way that we admit that target-side configuration sucks.
 624 AC_ARG_ENABLE(java-net,
 625   AS_HELP_STRING([--disable-java-net],
 626                  [disable java.net]))
 627
 628 # Whether java.net is built by default can depend on the target.
 629 if test -z "$enable_java_net"; then
 630    enable_java_net=${enable_java_net_default-yes}
 631 fi
 632 if test "$enable_java_net" = no; then
 633    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 634 fi
 635
 636 # See if the user wants to configure without libffi.  Some
 637 # architectures don't support it, and default values are set in
 638 # configure.host.
 639 AC_ARG_WITH(libffi,
 640   AS_HELP_STRING([--without-libffi],
 641                  [don't use libffi]),
 642   [:],
 643   [with_libffi=${with_libffi_default-yes}])
 644
 645 LIBFFI=
 646 LIBFFIINCS=
 647 if test "$with_libffi" != no; then
 648    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 649    LIBFFI=../libffi/libffi_convenience.la
 650    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 651 fi
 652 AC_SUBST(LIBFFI)
 653 AC_SUBST(LIBFFIINCS)
 654
 655 # See if the user wants to disable JVMPI support.
 656 AC_ARG_ENABLE(jvmpi,
 657   AS_HELP_STRING([--disable-jvmpi],
 658                  [disable JVMPI support]))
 659
 660 if test "$enable_jvmpi" != no; then
 661     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 662 fi
 663
 664 # If the target is an eCos system, use the appropriate eCos
 665 # I/O routines.
 666 # FIXME: this should not be a local option but a global target
 667 # system; at present there is no eCos target.
 668 TARGET_ECOS=${PROCESS-"no"}
 669 AC_ARG_WITH(ecos,
 670 [  --with-ecos             enable runtime eCos target support],
 671 TARGET_ECOS="$with_ecos"
 672 )
 673
 674 case "$TARGET_ECOS" in
 675    no) case "$host" in
 676       *mingw*)
 677             PLATFORM=Win32
 678             PLATFORMNET=Win32
 679             PLATFORMH=win32.h
 680         CHECK_FOR_BROKEN_MINGW_LD
 681       ;;
 682       *)
 683             PLATFORM=Posix
 684             PLATFORMNET=Posix
 685             PLATFORMH=posix.h
 686       ;;
 687       esac
 688       ;;
 689    *)
 690       PLATFORM=Ecos
 691       PLATFORMNET=NoNet
 692       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 693       PLATFORMH=posix.h
 694       ;;
 695 esac
 696 AC_SUBST(PLATFORM)
 697 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 698
 699 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 700                                       [Define if you have int32_t and uint32_t.]))
 701 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 702                                         [Define if you have int32_t and uint32_t.]))
 703 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 704                                           [Define if you have u_int32_t]))
 705 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 706                                            [Define if you have u_int32_t]))
 707
 708 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 709 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 710
 711 case "$host" in
 712   *-darwin*) DARWIN_CRT=true ;;
 713   *) DARWIN_CRT=false ;;
 714 esac
 715 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 716
 717 # These may not be defined in a non-ANS conformant embedded system.
 718 # FIXME: Should these case a runtime exception in that case?
 719 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 720                                   [Define is you have 'mktime' in <time.h>]))
 721 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 722                                   [Define is you have 'localtime' in <time.h>]))
 723
 724 # Create the subdirectory for natFile.cc, or the attempt
 725 # to create the link will fail.
 726 test -d java || mkdir java
 727 test -d java/io || mkdir java/io
 728 test -d gnu || mkdir gnu
 729 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 730
 731 # Likewise for natConcreteProcess.cc.
 732 test -d java/lang || mkdir java/lang
 733 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 734
 735 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 736 test -d java/net || mkdir java/net
 737 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 738 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 739
 740 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 741 test -d gnu/java || mkdir gnu/java
 742 test -d gnu/java/net || mkdir gnu/java/net
 743 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 744 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 745
 746 # Likewise for natVMPipe.cc and natVMSelector.cc.
 747 test -d gnu/java/nio || mkdir gnu/java/nio
 748 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 749 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 750
 751 # Likewise for natFileChannelImpl.cc
 752 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 753 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 754
 755 case "${host}" in
 756     *mingw*)
 757       SYSTEMSPEC="-lgdi32 -lws2_32"
 758       if test "${with_win32_nlsapi}" = "unicows"; then
 759         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 760       fi
 761     ;;
 762     *)
 763       SYSTEMSPEC=
 764     ;;
 765 esac
 766 AC_SUBST(SYSTEMSPEC)
 767
 768 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 769 AC_SUBST(LIBGCJTESTSPEC)
 770
 771 AC_ARG_WITH(system-zlib,
 772   AS_HELP_STRING([--with-system-zlib],
 773                  [use installed libz]))
 774 ZLIBSPEC=
 775 AC_SUBST(ZLIBSPEC)
 776 ZLIBTESTSPEC=
 777 AC_SUBST(ZLIBTESTSPEC)
 778
 779 AC_PATH_XTRA
 780
 781 # FIXME: this should be _libs on some hosts.
 782 libsubdir=.libs
 783
 784 # extra LD Flags which are required for targets
 785 case "${host}" in
 786 *-*-darwin[[0-7]].*)
 787     # For now we have to disable it on darwin[8-9] because it slows down
 788     # the linking phase. A possible bug in ld?
 789     # on Darwin -single_module speeds up loading of the dynamic libraries.
 790     extra_ldflags_libjava=-Wl,-single_module
 791     ;;
 792 esac
 793 AC_SUBST(extra_ldflags_libjava)
 794
 795 # Allow the GC to be disabled.  Can be useful when debugging.
 796 AC_MSG_CHECKING([for garbage collector to use])
 797 AC_ARG_ENABLE(java-gc,
 798   AS_HELP_STRING([--enable-java-gc=TYPE],
 799                  [choose garbage collector (default is boehm)]),
 800   [GC=$enableval],
 801   [GC=boehm])
 802 GCLIBS=
 803 GCINCS=
 804 GCDEPS=
 805 GCSPEC=
 806 JC1GCSPEC=
 807 GCTESTSPEC=
 808 case "$GC" in
 809  boehm)
 810     AC_MSG_RESULT(boehm)
 811     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 812     JC1GCSPEC='-fuse-boehm-gc'
 813     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 814     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 815     GCOBJS=boehm.lo
 816     GCHDR=boehm-gc.h
 817     # The POSIX thread support needs to know this.
 818     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 819     ;;
 820  no)
 821     AC_MSG_RESULT(none)
 822     GCHDR=no-gc.h
 823     ;;
 824  *)
 825     AC_MSG_ERROR([unrecognized collector "$GC"])
 826     ;;
 827 esac
 828 AC_SUBST(GCLIBS)
 829 AC_SUBST(GCINCS)
 830 AC_SUBST(GCDEPS)
 831 AC_SUBST(GCSPEC)
 832 AC_SUBST(JC1GCSPEC)
 833 AC_SUBST(GCTESTSPEC)
 834 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 835 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 836 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 837
 838
 839 AC_MSG_CHECKING([for thread model used by GCC])
 840 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 841 AC_MSG_RESULT([$THREADS])
 842
 843 case "$THREADS" in
 844  no | none | single)
 845     THREADS=none
 846     ;;
 847  posix | posix95 | pthreads)
 848     THREADS=posix
 849     case "$host" in
 850      *-*-linux*)
 851         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 852         ;;
 853     esac
 854     ;;
 855  win32)
 856     ;;
 857  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 858     AC_MSG_ERROR(thread package $THREADS not yet supported)
 859     ;;
 860  *)
 861     AC_MSG_ERROR($THREADS is an unknown thread package)
 862     ;;
 863 esac
 864
 865 THREADCXXFLAGS=
 866 THREADLDFLAGS=
 867 THREADLIBS=
 868 THREADINCS=
 869 THREADDEPS=
 870 THREADH=
 871 THREADSPEC=
 872 THREADSTARTFILESPEC=
 873 case "$THREADS" in
 874  posix)
 875     case "$host" in
 876      *-*-cygwin*)
 877         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 878         ;;
 879      *-*-freebsd[[1234]]*)
 880         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 881         # merely adds pthread_* functions) but it does have a -pthread switch
 882         # which is required at link-time to select -lc_r *instead* of -lc.
 883         THREADLDFLAGS=-pthread
 884         # Don't set THREADSPEC here as might be expected since -pthread is
 885         # not processed when found within a spec file, it must come from
 886         # the command line.  For now, the user must provide the -pthread
 887         # switch to link code compiled with gcj.  In future, consider adding
 888         # support for weak references to pthread_* functions ala gthr.h API.
 889         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 890         ;;
 891      *-*-freebsd*)
 892         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 893         # systems which support threads and -lpthread.
 894         THREADLDFLAGS=-pthread
 895         THREADSPEC=-lpthread
 896         ;;
 897      alpha*-dec-osf* | hppa*-hp-hpux*)
 898         THREADCXXFLAGS=-pthread
 899         # boehm-gc needs some functions from librt, so link that too.
 900         THREADLIBS='-lpthread -lrt'
 901         THREADSPEC='-lpthread -lrt'
 902         ;;
 903      *)
 904         THREADLIBS=-lpthread
 905         THREADSPEC=-lpthread
 906         ;;
 907     esac
 908     THREADH=posix-threads.h
 909     # MIT pthreads doesn't seem to have the mutexattr functions.
 910     # But for now we don't check for it.  We just assume you aren't
 911     # using MIT pthreads.
 912     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 913
 914     # If we're using the Boehm GC, then we happen to know that it
 915     # defines _REENTRANT, so we don't bother.  Eww.
 916     if test "$GC" != boehm; then
 917        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 918     fi
 919     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 920     ;;
 921
 922  win32)
 923     THREADH=win32-threads.h
 924     THREADCXXFLAGS=-mthreads
 925     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 926     # But we do not want the executables created to be dependent on
 927     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 928     # exception handling contexts.  The following kludge achieves this effect
 929     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 930     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 931     # A workaround is to explicitly use -mthreads while linking Java programs.
 932     # See PR libgcj/28263.
 933     #
 934     # FIXME: In Java we are able to detect thread death at the end of
 935     # Thread.run() so we should be able to clean up the exception handling
 936     # contexts ourselves.
 937     THREADSTARTFILESPEC='crtmt%O%s'
 938     ;;
 939
 940  none)
 941     THREADH=no-threads.h
 942     ;;
 943 esac
 944 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 945 AC_SUBST(THREADLIBS)
 946 AC_SUBST(THREADINCS)
 947 AC_SUBST(THREADDEPS)
 948 AC_SUBST(THREADSPEC)
 949 AC_SUBST(THREADSTARTFILESPEC)
 950 AC_SUBST(THREADLDFLAGS)
 951 AC_SUBST(THREADCXXFLAGS)
 952 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 953 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 954 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 955 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 956
 957 if test -d sysdep; then true; else mkdir sysdep; fi
 958 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 959 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 960 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 961
 962 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 963 if test "$use_libgcj_bc" = yes; then
 964   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 965 fi
 966 AC_SUBST(LIBGCJ_SPEC)
 967
 968 HASH_SYNC_SPEC=
 969 # Hash synchronization is only useful with posix threads right now.
 970 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 971    HASH_SYNC_SPEC=-fhash-synchronization
 972    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 973 fi
 974 AC_SUBST(HASH_SYNC_SPEC)
 975
 976 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 977
 978 # We're in the tree with gcc, and need to include some of its headers.
 979 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
 980
 981 if test "x${with_newlib}" = "xyes"; then
 982    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 983    # may not work correctly, because the compiler may not be able to
 984    # link executables.
 985
 986    # We assume newlib.  This lets us hard-code the functions we know
 987    # we'll have.
 988    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 989    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 990    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 991    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 992    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 993    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 994    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 995    # This is only for POSIX threads.
 996    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 997    # We also assume we are using gcc, which provides alloca.
 998    AC_DEFINE(HAVE_ALLOCA)
 999
1000    # Assume we do not have getuid and friends.
1001    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1002    PLATFORMNET=NoNet
1003 else
1004    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
1005                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
1006                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1007                    nl_langinfo setlocale \
1008                    inet_pton uname inet_ntoa \
1009                    fork execvp getrlimit pipe sigaction ftruncate mmap \
1010                    getifaddrs])
1011    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1012    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h sys/resource.h)
1013    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1014    AC_CHECK_LIB(dl, dladdr, [
1015        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1016        AC_CHECK_LIB(dld, dladdr, [
1017        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1018
1019    if test x"$cross_compiling" = x"no"; then
1020      AC_CHECK_FILES(/proc/self/exe, [
1021        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1022      AC_CHECK_FILES(/proc/self/maps, [
1023        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1024          [Define if you have /proc/self/maps])])
1025    else
1026      case $host in
1027      *-linux*)
1028        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1029        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1030        ;;
1031      esac
1032    fi
1033
1034    AM_ICONV
1035    AM_LC_MESSAGES
1036    AC_STRUCT_TIMEZONE
1037
1038    AC_CHECK_FUNCS(gethostbyname_r, [
1039      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1040        [Define if you have the 'gethostbyname_r' function.])
1041      # There are two different kinds of gethostbyname_r.
1042      # We look for the one that returns `int'.
1043      # Hopefully this check is robust enough.
1044      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1045        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1046
1047      case " $GCINCS " in
1048      *" -D_REENTRANT "*) ;;
1049      *)
1050         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1051         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1052         [libjava_cv_gethostbyname_r_needs_reentrant],
1053         [ AC_LANG_PUSH(C++)
1054           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1055             [[gethostbyname_r("", 0, 0);]])],
1056             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1057                 CPPFLAGS_SAVE="$CPPFLAGS"
1058                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1059                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1060                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1061                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1062                 CPPFLAGS="$CPPFLAGS_SAVE"
1063           ])
1064           AC_LANG_POP(C++)
1065         ])
1066         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1067           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1068         fi
1069      ;;
1070      esac
1071
1072      AC_CACHE_CHECK([for struct hostent_data],
1073         [libjava_cv_struct_hostent_data], [dnl
1074         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1075 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1076 # define _REENTRANT 1
1077 #endif
1078 #include <netdb.h>]], [[struct hostent_data data;]])],
1079           [libjava_cv_struct_hostent_data=yes],
1080           [libjava_cv_struct_hostent_data=no])])
1081      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1082        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1083          [Define if struct hostent_data is defined in netdb.h])
1084      fi
1085    ])
1086
1087    # FIXME: libjava source code expects to find a prototype for
1088    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1089    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1090    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1091    # linkage check is enough, yet C++ code requires proper prototypes.)
1092    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1093    AC_CHECK_FUNCS(gethostbyaddr_r, [
1094      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1095        [Define if you have the 'gethostbyaddr_r' function.])
1096      # There are two different kinds of gethostbyaddr_r.
1097      # We look for the one that returns `int'.
1098      # Hopefully this check is robust enough.
1099      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1100        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1101          [Define if gethostbyaddr_r returns 'int'.])])])])
1102
1103    AC_CHECK_FUNCS(gethostname, [
1104      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1105        [Define if you have the 'gethostname' function.])
1106      AC_EGREP_HEADER(gethostname, unistd.h, [
1107        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1108          [Define if gethostname is declared in <unistd.h>.])])])
1109
1110    AC_CHECK_FUNCS(usleep, [
1111      AC_EGREP_HEADER(usleep, unistd.h, [
1112        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1113           [Define if usleep is declared in <unistd.h>.])])])
1114
1115    # Look for these functions in the thread library, but only bother
1116    # if using POSIX threads.
1117    if test "$THREADS" = posix; then
1118       save_LIBS="$LIBS"
1119       LIBS="$LIBS $THREADLIBS"
1120       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1121       # E.g., Solaris.
1122       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1123
1124       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1125       # Solaris 7 the name librt is preferred.
1126       AC_CHECK_FUNCS(sched_yield, , [
1127         AC_CHECK_LIB(rt, sched_yield, [
1128           AC_DEFINE(HAVE_SCHED_YIELD)
1129           THREADLIBS="$THREADLIBS -lrt"
1130           THREADSPEC="$THREADSPEC -lrt"], [
1131           AC_CHECK_LIB(posix4, sched_yield, [
1132             AC_DEFINE(HAVE_SCHED_YIELD)
1133             THREADLIBS="$THREADLIBS -lposix4"
1134             THREADSPEC="$THREADSPEC -lposix4"])])])
1135
1136       AC_CHECK_LIB(rt, clock_gettime, [
1137          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1138          case "$THREADSPEC" in
1139            *-lrt*) ;;
1140            *)
1141              THREADSPEC="$THREADSPEC -lrt"
1142              THREADLIBS="$THREADLIBS -lrt"
1143              ;;
1144          esac])
1145
1146       LIBS="$save_LIBS"
1147
1148       # We can save a little space at runtime if the mutex has m_count
1149       # or __m_count.  This is a nice hack for Linux.
1150       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1151           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1152         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1153              [Define if pthread_mutex_t has m_count member.]), [
1154         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1155             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1156           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1157             [Define if pthread_mutex_t has __m_count member.]))])
1158    fi
1159
1160    # We require a way to get the time.
1161    time_found=no
1162    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1163    if test "$time_found" = no; then
1164       AC_MSG_ERROR([no function found to get the time])
1165    fi
1166
1167    AC_CHECK_FUNCS(memmove)
1168
1169    # We require memcpy.
1170    memcpy_found=no
1171    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1172    if test "$memcpy_found" = no; then
1173       AC_MSG_ERROR([memcpy is required])
1174    fi
1175    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1176    AC_CHECK_LIB(dl, dlopen, [
1177        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1178        AC_CHECK_LIB(dld, dlopen, [
1179        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1180
1181    # Some library-finding code we stole from Tcl.
1182    #--------------------------------------------------------------------
1183    #    Check for the existence of the -lsocket and -lnsl libraries.
1184    #    The order here is important, so that they end up in the right
1185    #    order in the command line generated by make.  Here are some
1186    #    special considerations:
1187    #    1. Use "connect" and "accept" to check for -lsocket, and
1188    #       "gethostbyname" to check for -lnsl.
1189    #    2. Use each function name only once:  can't redo a check because
1190    #       autoconf caches the results of the last check and won't redo it.
1191    #    3. Use -lnsl and -lsocket only if they supply procedures that
1192    #       aren't already present in the normal libraries.  This is because
1193    #       IRIX 5.2 has libraries, but they aren't needed and they're
1194    #       bogus:  they goof up name resolution if used.
1195    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1196    #       To get around this problem, check for both libraries together
1197    #       if -lsocket doesn't work by itself.
1198    #--------------------------------------------------------------------
1199
1200    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1201     [gcj_cv_lib_sockets=
1202      gcj_checkBoth=0
1203      unset ac_cv_func_connect
1204      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1205      if test "$gcj_checkSocket" = 1; then
1206          unset ac_cv_func_connect
1207          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1208                       gcj_checkBoth=1)
1209      fi
1210      if test "$gcj_checkBoth" = 1; then
1211          gcj_oldLibs=$LIBS
1212          LIBS="$LIBS -lsocket -lnsl"
1213          unset ac_cv_func_accept
1214          AC_CHECK_FUNC(accept,
1215                        [gcj_checkNsl=0
1216                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1217          unset ac_cv_func_accept
1218          LIBS=$gcj_oldLibs
1219      fi
1220      unset ac_cv_func_gethostbyname
1221      gcj_oldLibs=$LIBS
1222      LIBS="$LIBS $gcj_cv_lib_sockets"
1223      AC_CHECK_FUNC(gethostbyname, ,
1224                    [AC_CHECK_LIB(nsl, main,
1225                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1226      unset ac_cv_func_gethostbyname
1227      LIBS=$gcj_oldLIBS
1228    ])
1229    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1230
1231    if test "$with_system_zlib" = yes; then
1232       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1233    fi
1234
1235    # Test for Gtk stuff, if asked for.
1236    if test "$use_gtk_awt" = yes; then
1237       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1238       AC_SUBST(GTK_CFLAGS)
1239       AC_SUBST(GTK_LIBS)
1240
1241       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1242       AC_SUBST(GLIB_CFLAGS)
1243       AC_SUBST(GLIB_LIBS)
1244
1245       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1246       AC_SUBST(LIBART_CFLAGS)
1247       AC_SUBST(LIBART_LIBS)
1248
1249       # We require the XTest Extension to support java.awt.Robot.
1250       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1251                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1252                    [${X_LIBS}])
1253    fi
1254
1255    # On Solaris, and maybe other architectures, the Boehm collector
1256    # requires -ldl.
1257    if test "$GC" = boehm; then
1258       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1259    fi
1260 fi
1261
1262 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1263 case $build in
1264     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1265     *)         CLASSPATH_SEPARATOR=':' ;;
1266 esac
1267 AC_SUBST(CLASSPATH_SEPARATOR)
1268
1269 # We must search the source tree for java.lang, since we still don't
1270 # have libgcj.jar nor java/lang/*.class
1271 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1272 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1273
1274 # Since some classes depend on this one, we need its source available
1275 # before we can do any GCJ compilation test :-(
1276 if test ! -f gnu/classpath/Configuration.java; then
1277   test -d gnu || mkdir gnu
1278   test -d gnu/classpath || mkdir gnu/classpath
1279   # Note that it is not crucial that all the values here be correct.
1280   sed -e "s,@prefix@,$prefix," \
1281       -e "s,@VERSION@,$VERSION," \
1282       -e "s,@LIBDEBUG@,false," \
1283       -e "s,@INIT_LOAD_LIBRARY@,false," \
1284       -e "s,@@,$LIBGCJDEBUG," \
1285       -e "s,@default_toolkit@,$TOOLKIT," \
1286       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1287       -e "s,@GTK_CAIRO_ENABLED@,false," \
1288       -e "s,@ECJ_JAR@,," \
1289         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1290         > gnu/classpath/Configuration.java
1291   # We do not want to redirect the output of the grep below to /dev/null,
1292   # but we add /dev/null to the input list so that grep will print the
1293   # filename of Configuration.java in case it finds any matches.
1294   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1295     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1296   fi
1297 fi
1298
1299 LT_AC_PROG_GCJ
1300
1301 # Now remove it.
1302 rm -f gnu/classpath/Configuration.java
1303
1304 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1305
1306 AC_CHECK_SIZEOF(void *)
1307
1308 AC_C_BIGENDIAN
1309
1310 ZLIBS=
1311 SYS_ZLIBS=
1312 ZINCS=
1313
1314 if test -z "$ZLIBSPEC"; then
1315    # Use zlib from the GCC tree.
1316    ZINCS='-I$(top_srcdir)/../zlib'
1317    ZLIBS=../zlib/libzgcj_convenience.la
1318 else
1319    # System's zlib.
1320    SYS_ZLIBS="$ZLIBSPEC"
1321 fi
1322 AC_SUBST(ZLIBS)
1323 AC_SUBST(SYS_ZLIBS)
1324 AC_SUBST(ZINCS)
1325 AC_SUBST(DIVIDESPEC)
1326 AC_SUBST(CHECKREFSPEC)
1327 AC_SUBST(EXCEPTIONSPEC)
1328 AC_SUBST(BACKTRACESPEC)
1329 AC_SUBST(IEEESPEC)
1330
1331 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1332 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1333 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1334 AC_SUBST(GCC_UNWIND_INCLUDE)
1335
1336 # Process the option "--enable-version-specific-runtime-libs"
1337 # Calculate toolexeclibdir
1338 case ${version_specific_libs} in
1339   yes)
1340     # Need the gcc compiler version to know where to install libraries
1341     # and header files if --enable-version-specific-runtime-libs option
1342     # is selected.
1343     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1344     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1345     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1346     toolexeclibdir=$toolexecmainlibdir
1347     ;;
1348   no)
1349     if test -n "$with_cross_host" &&
1350        test x"$with_cross_host" != x"no"; then
1351       # Install a library built with a cross compiler in tooldir, not libdir.
1352       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1353       toolexecmainlibdir='$(toolexecdir)/lib'
1354     else
1355       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1356       toolexecmainlibdir='$(libdir)'
1357     fi
1358     multi_os_directory=`$CC -print-multi-os-directory`
1359     case $multi_os_directory in
1360       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1361       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1362     esac
1363     ;;
1364 esac
1365 AC_SUBST(toolexecdir)
1366 AC_SUBST(toolexecmainlibdir)
1367 AC_SUBST(toolexeclibdir)
1368
1369 # Determine where the standard .db file and GNU Classpath JNI
1370 # libraries are found.
1371 multi_os_directory=`$CC -print-multi-os-directory`
1372 case $multi_os_directory in
1373   .)
1374    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1375    ;;
1376   *)
1377    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1378    ;;
1379 esac
1380 AC_SUBST(dbexecdir)
1381
1382 # Determine gcj version number.
1383 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1384 GCJVERSION=$gcjversion
1385 AC_SUBST(GCJVERSION)
1386 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1387
1388 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1389 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1390
1391 TL_AC_GXX_INCLUDE_DIR
1392
1393 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1394 # On that system, sys/ioctl.h will not include sys/filio.h unless
1395 # BSD_COMP is defined; just including sys/filio.h is simpler.
1396 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1397 # for now.  If you change this, you also must update natFile.cc.
1398 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1399                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1400                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1401                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1402                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1403 AC_CHECK_HEADERS(inttypes.h, [
1404     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1405     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1406 ])
1407 AC_HEADER_SYS_WAIT
1408
1409 AC_CHECK_TYPE([ssize_t], [int])
1410 AC_CHECK_TYPE([magic_t], [
1411     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1412 #ifdef HAVE_MAGIC_H
1413 #include <magic.h>
1414 #endif])
1415
1416 AC_MSG_CHECKING([for in_addr_t])
1417 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1418 #if STDC_HEADERS
1419 #include <stdlib.h>
1420 #include <stddef.h>
1421 #endif
1422 #if HAVE_NETINET_IN_H
1423 #include <netinet/in.h>
1424 #endif]], [[in_addr_t foo;]])],
1425   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1426      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1427    AC_MSG_RESULT(yes)],
1428   [AC_MSG_RESULT(no)])
1429
1430 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1431 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1432   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1433      [Define if struct ip_mreq is defined in netinet/in.h.])
1434    AC_MSG_RESULT(yes)],
1435   [AC_MSG_RESULT(no)])
1436
1437 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1438 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1439   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1440      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1441    AC_MSG_RESULT(yes)],
1442   [AC_MSG_RESULT(no)])
1443
1444 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1445 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1446   [AC_DEFINE(HAVE_INET6, 1,
1447      [Define if inet6 structures are defined in netinet/in.h.])
1448    AC_MSG_RESULT(yes)],
1449   [AC_MSG_RESULT(no)])
1450
1451 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1452 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1453 #include <sys/types.h>
1454 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1455   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1456    AC_MSG_RESULT(yes)],
1457   [AC_MSG_RESULT(no)])
1458
1459 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1460 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1461   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1462    AC_MSG_RESULT(yes)],
1463   [AC_MSG_RESULT(no)
1464    AC_MSG_CHECKING([for global timezone variable])
1465    dnl FIXME: we don't want a link check here because that won't work
1466    dnl when cross-compiling.  So instead we make an assumption that
1467    dnl the header file will mention timezone if it exists.
1468    dnl Don't find the win32 function timezone
1469    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1470      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1471       AC_MSG_RESULT(yes)],
1472      [AC_MSG_RESULT(no)
1473        AC_MSG_CHECKING([for global _timezone variable])
1474        dnl FIXME: As above, don't want link check
1475        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1476          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1477             [Define if your platform has the global _timezone variable.])
1478           AC_MSG_RESULT(yes)],
1479           [AC_MSG_RESULT(no)])])])
1480
1481 AC_FUNC_ALLOCA
1482
1483 AC_CHECK_PROGS(PERL, perl, false)
1484
1485 SYSDEP_SOURCES=
1486 SIGNAL_HANDLER_AUX=
1487
1488 case "${host}" in
1489  i?86-*-linux*)
1490     SIGNAL_HANDLER=include/i386-signal.h
1491     ;;
1492  sparc*-sun-solaris*)
1493     SIGNAL_HANDLER=include/sparc-signal.h
1494     ;;
1495 # ia64-*)
1496 #    SYSDEP_SOURCES=sysdep/ia64.c
1497 #    test -d sysdep || mkdir sysdep
1498 #    ;;
1499  hppa*-*-linux*)
1500     SIGNAL_HANDLER=include/pa-signal.h
1501     ;;
1502  hppa*-hp-hpux*)
1503     SIGNAL_HANDLER=include/hppa-signal.h
1504     ;;
1505  ia64-*-linux*)
1506     SIGNAL_HANDLER=include/dwarf2-signal.h
1507     ;;
1508  powerpc*-*-linux*)
1509     SIGNAL_HANDLER=include/powerpc-signal.h
1510     ;;
1511  alpha*-*-linux*)
1512     SIGNAL_HANDLER=include/dwarf2-signal.h
1513     ;;
1514  s390*-*-linux*)
1515     SIGNAL_HANDLER=include/s390-signal.h
1516     ;;
1517  x86_64*-*-linux*)
1518     SIGNAL_HANDLER=include/x86_64-signal.h
1519     SIGNAL_HANDLER_AUX=include/i386-signal.h
1520     ;;
1521  sparc*-*-linux*)
1522     SIGNAL_HANDLER=include/dwarf2-signal.h
1523     ;;
1524  sh*-*-linux*)
1525     SIGNAL_HANDLER=include/sh-signal.h
1526     ;;
1527  *mingw*)
1528     SIGNAL_HANDLER=include/win32-signal.h
1529     ;;
1530  mips*-*-linux*)
1531     SIGNAL_HANDLER=include/mips-signal.h
1532     ;;
1533  powerpc*-*-darwin*)
1534     SIGNAL_HANDLER=include/darwin-signal.h
1535     ;;
1536  *)
1537     SIGNAL_HANDLER=include/default-signal.h
1538     ;;
1539 esac
1540
1541 # If we're using sjlj exceptions, forget what we just learned.
1542 if test "$enable_sjlj_exceptions" = yes; then
1543    SIGNAL_HANDLER=include/default-signal.h
1544    SIGNAL_HANDLER_AUX=
1545 fi
1546
1547 AC_SUBST(SYSDEP_SOURCES)
1548
1549 if test -z "$SIGNAL_HANDLER_AUX"; then
1550   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1551 fi
1552
1553 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1554                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1555
1556 if test "${multilib}" = "yes"; then
1557   multilib_arg="--enable-multilib"
1558 else
1559   multilib_arg=
1560 fi
1561
1562 # See if we support thread-local storage.
1563 GCC_CHECK_TLS
1564
1565 # For _Unwind_GetIPInfo.
1566 GCC_CHECK_UNWIND_GETIPINFO
1567
1568 # See if linker supports anonymous version scripts.
1569 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1570   [libjava_cv_anon_version_script],
1571   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1572    libjava_cv_anon_version_script=no
1573    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1574    echo '{ global: globalsymb*; local: *; };' > conftest.map
1575    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1576                [libjava_cv_anon_version_script=yes], [])
1577    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1578   ])
1579 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1580
1581 # Check if linker supports static linking on a per library basis
1582 LD_START_STATIC_SPEC=
1583 LD_FINISH_STATIC_SPEC=
1584 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1585   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1586     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1587     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1588   fi
1589 fi
1590 AC_SUBST(LD_START_STATIC_SPEC)
1591 AC_SUBST(LD_FINISH_STATIC_SPEC)
1592
1593 here=`${PWDCMD-pwd}`
1594 AC_SUBST(here)
1595
1596 # We get this from the environment.
1597 AC_SUBST(GCJFLAGS)
1598
1599 AC_CONFIG_FILES([
1600 Makefile
1601 libgcj.pc
1602 libgcj.spec
1603 libgcj-test.spec
1604 gcj/Makefile
1605 include/Makefile
1606 testsuite/Makefile
1607 ])
1608
1609 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1610
1611 AC_CONFIG_COMMANDS([default],
1612 [# Only add multilib support code if we just rebuilt top-level Makefile.
1613 case " $CONFIG_FILES " in
1614  *" Makefile "*)
1615    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1616    ac_file=Makefile . ${multi_basedir}/./libjava/../config-ml.in
1617    ;;
1618 esac
1619 for ac_multi_file in $CONFIG_FILES; do
1620   case $ac_multi_file in
1621   */Makefile)
1622     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1623   esac
1624 done
1625 ],
1626 srcdir=${srcdir}
1627 host=${host}
1628 target=${target}
1629 with_multisubdir=${with_multisubdir}
1630 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1631 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1632 multi_basedir=${multi_basedir}
1633 CC="${CC}"
1634 CXX="${CXX}"
1635 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1636 )
1637
1638 AC_OUTPUT