OSDN Git Service

* configure, Makefile.in: Rebuilt.
[pf3gnuchains/gcc-fork.git] / libjava / configure.ac
1 dnl # Process this with autoconf to create configure
2 AC_PREREQ(2.59)
3 # Still use "libjava" here to placate dejagnu.
4 AC_INIT([libjava], [version-unused],, [libjava])
5
6 AC_CONFIG_SRCDIR(java/lang/System.java)
7
8 GCC_TOPLEV_SUBDIRS
9
10 # We use these options to decide which functions to include.
11 AC_ARG_WITH(target-subdir,
12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
13                  [configure in a subdirectory]))
14
15 # We may get other options which we don't document:
16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
17
18 # Find the rest of the source tree framework.
19 AM_ENABLE_MULTILIB(, ..)
20
21 AC_CANONICAL_SYSTEM
22 _GCC_TOPLEV_NONCANONICAL_BUILD
23 _GCC_TOPLEV_NONCANONICAL_TARGET
24
25 AC_SUBST(target_noncanonical)
26
27 # This works around the fact that libtool configuration may change LD
28 # for this particular configuration, but some shells, instead of
29 # keeping the changes in LD private, export them just because LD is
30 # exported.
31 ORIGINAL_LD_FOR_MULTILIBS=$LD
32
33 AC_PROG_LN_S
34
35 # This works around an automake problem.
36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
37 AC_SUBST(mkinstalldirs)
38
39 AC_ARG_WITH(cross-host,
40   AS_HELP_STRING([--with-cross-host=HOST],
41                  [configure with a cross compiler from HOST]))
42
43 AC_ARG_WITH(newlib,
44   AS_HELP_STRING([--with-newlib],
45                  [configure with newlib]))
46
47 AC_ARG_ENABLE(version-specific-runtime-libs,
48   AS_HELP_STRING([--enable-version-specific-runtime-libs],    
49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
50     [case "$enableval" in
51       yes) version_specific_libs=yes ;;
52       no)  version_specific_libs=no ;;
53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
54      esac],
55     [version_specific_libs=no]
56 )
57
58 AC_ARG_ENABLE(plugin,
59   AS_HELP_STRING([--enable-plugin],
60                  [build gcjwebplugin web browser plugin]),
61     [case "$enableval" in
62       yes) plugin_enabled=yes ;;
63       no)  plugin_enabled=no ;;
64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
65      esac],
66     [plugin_enabled=no]
67 )
68
69 AC_ARG_ENABLE(gconf-peer,
70   AS_HELP_STRING([--enable-gconf-peer],
71                  [compile GConf native peers for util.preferences]),
72     [case "$enableval" in
73       yes) gconf_enabled=yes ;;
74       no)  gconf_enabled=no ;;
75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
76      esac],
77     [gconf_enabled=no]
78 )
79
80 AC_ARG_ENABLE(java-maintainer-mode,
81         AS_HELP_STRING([--enable-java-maintainer-mode],
82         [allow rebuilding of .class and .h files]))
83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
84
85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
86 GCC_NO_EXECUTABLES
87
88 # (1) We use an abnormal CXX (without library references), so we
89 # must cache it under a different name.
90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
91 # the non-multilib-adjusted value will be used in multilibs.
92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
93 # (4) As another side effect, automake doesn't automatically include them
94 # in Makefile.in.
95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
97 # used in later tests.  This may not be necessary in libjava; I don't know.
98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
100 save_CXXFLAGS="$CXXFLAGS"
101 CXXFLAGS="$CXXFLAGS -fno-builtin"
102 AC_PROG_CC
103 AC_PROG_CXX
104 CXXFLAGS="$save_CXXFLAGS"
105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
106 AC_SUBST(CFLAGS)
107 AC_SUBST(CXXFLAGS)
108 AC_SUBST(LDFLAGS)
109
110 AM_INIT_AUTOMAKE([1.9.0])
111
112 AC_CHECK_TOOL(AS, as)
113 AC_CHECK_TOOL(LD, ld)
114 AC_CHECK_TOOL(AR, ar)
115 AC_CHECK_TOOL(RANLIB, ranlib, :)
116 AC_PROG_AWK
117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
118 AC_PATH_PROG([ZIP], [zip], no)
119 AC_PATH_PROG([UNZIP], [unzip], unzip)
120
121 # We need a jar that supports -@.  This is a GNU extension.
122 if test "$JAR" != no; then
123    rm -f config-test.jar
124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
125    if test -f config-test.jar; then
126      rm -f config-test.jar
127    else
128      JAR=no
129    fi
130 fi
131
132 # Prefer the jar we found, but fall back to our jar script.
133 if test "$JAR" = no; then
134   if test "$ZIP" = no; then
135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
136   else
137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
138     JAR=`pwd`/scripts/jar
139   fi
140 fi
141
142 AC_PROG_INSTALL
143
144 AM_MAINTAINER_MODE
145
146 AC_EXEEXT
147
148 # configure.host sets the following important variables
149 #       libgcj_cflags    - host specific C compiler flags
150 #       libgcj_cxxflags  - host specific C++ compiler flags
151 #       libgcj_javaflags - host specific Java compiler flags
152
153 libgcj_cflags=
154 libgcj_cxxflags=
155 libgcj_javaflags=
156
157 . ${srcdir}/configure.host
158
159 ACX_PROG_LD_GNU_SYMBOLIC
160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
161 if test -z "$libgcj_ld_symbolic"; then
162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
163 fi
164
165 LIBGCJ_CFLAGS="${libgcj_cflags}"
166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
170 AC_SUBST(LIBGCJ_CFLAGS)
171 AC_SUBST(LIBGCJ_CXXFLAGS)
172 AC_SUBST(LIBGCJ_JAVAFLAGS)
173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
175
176 # Only use libltdl for non-newlib builds.
177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
178    AC_LTDL_SHLIBPATH
179 fi
180
181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
182
183 # See if the user has requested runtime debugging.
184 LIBGCJDEBUG="disable"
185 AC_SUBST(LIBGCJDEBUG)
186 AC_ARG_ENABLE(libgcj-debug,
187   AS_HELP_STRING([--enable-libgcj-debug],
188                  [enable runtime debugging code]),
189   [if test "$enable_libgcj_debug" = yes; then
190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
191     LIBGCJDEBUG="enable"
192   fi])
193
194 AC_ARG_WITH([escher],
195          AS_HELP_STRING([--with-escher=ABS.PATH],
196                         [specify path to escher dir or JAR for X peers]))
197 case "$with_escher" in
198 "")
199         use_escher=false
200         ;;
201 "no")
202         use_escher=false
203         ;;
204 "yes")
205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
206         ;;
207 *)
208         use_escher=true
209         ;;
210 esac
211
212 # Determine which AWT peer libraries to build
213 AC_ARG_ENABLE(java-awt,
214   AS_HELP_STRING([--enable-java-awt],
215                  [list of AWT peer implementations to be built]))
216
217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
218 use_xlib_awt=""
219 use_gtk_awt=""
220 use_qt_awt=""
221 use_x_awt=""
222 # The default toolkit to use is the first one specified.
223 TOOLKIT=
224 AC_SUBST(TOOLKIT)
225
226 for peer in $peerlibs ; do
227   case $peer in
228     xlib)
229       if test "$no_x" = yes; then
230         echo "*** xlib peers requested but no X library available" 1>&2
231         exit 1
232       else
233         use_xlib_awt="yes"
234         if test -z "$TOOLKIT"; then
235            TOOLKIT=gnu.awt.xlib.XToolkit
236         fi
237       fi
238       ;;
239     gtk)
240       if test "$no_x" = yes; then
241          echo "*** gtk peers requested but no X library available" 1>&2
242          exit 1
243       else
244          use_gtk_awt=yes
245          if test -z "$TOOLKIT"; then
246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
247          fi
248       fi
249       ;;
250     qt)
251       if test "$no_x" = yes; then
252          # Perhaps we should admit the possibility of embedded Qt.
253          echo "*** Qt peers requested but no X library available" 1>&2
254          exit 1
255       else
256          use_qt_awt=yes
257          if test -z "$TOOLKIT"; then
258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
259          fi
260       fi
261       ;;
262     x)
263       use_x_awt=yes
264       if test -z "$TOOLKIT"; then
265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
266       fi
267       ;;
268     no)
269       use_xlib_awt=
270       use_gtk_awt=
271       use_qt_awt=
272       use_x_awt=
273       break
274       ;;
275     *)
276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
277       exit 1
278   esac
279 done
280
281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
283
284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
285
286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
287
288 # Create standard.omit based on decisions we just made.
289 cp $srcdir/standard.omit.in standard.omit
290 if test "$use_xlib_awt" != yes; then
291    echo gnu/awt/xlib >> standard.omit
292    echo gnu/gcj/xlib >> standard.omit
293 fi
294 if test "$use_x_awt" != yes; then
295    echo gnu/java/awt/peer/x >> standard.omit
296 fi
297
298 if test -z "${with_multisubdir}"; then
299    builddotdot=.
300 else
301    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
302 fi
303
304 NATIVE=yes
305
306 # Which gcj and host gcj (for ecjx) do we use?
307 which_gcj=default
308 host_exeext=${ac_exeext}
309 GCJ_FOR_ECJX=
310 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
311 if test -n "${with_cross_host}"; then
312   # We are being configured with a cross compiler. We can't
313   # use ac_exeext, because that is for the target platform.
314   NATIVE=no
315   cross_host_exeext=
316   GCJ_FOR_ECJX="${with_cross_host}-gcj"
317   case "${with_cross_host}" in
318      *mingw* | *cygwin*)
319          cross_host_exeext=.exe
320      ;;
321   esac
322   host_exeext=${cross_host_exeext}
323   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
324      if test x"$build_noncanonical" = x"$with_cross_host"; then
325         # Ordinary cross (host!=target and host=build)
326         which_gcj=built
327      else
328         # Canadian cross (host!=target and host!=build)
329         which_gcj=cross
330      fi
331   else
332      which_gcj=cross
333   fi
334 else
335   # We are being configured with a native or crossed-native compiler
336   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
337      if test x"$build" = x"$host"; then
338         # True native build (host=target and host=build)
339         which_gcj=built
340      else
341         # Crossed-native build (host=target and host!=build)
342         which_gcj=cross
343      fi
344   else
345      which_gcj=path
346   fi
347 fi
348 case "${which_gcj}" in
349    built)
350       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
351       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
352    ;;
353    cross)
354       if test "x${with_newlib}" = "xyes"; then
355          # FIXME (comment): Why is this needed?
356          GCC_UNWIND_INCLUDE=
357          GCJ="${target_noncanonical}-gcj"
358       else
359          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
360       fi
361       GCJH="$built_gcc_dir/gcjh"
362    ;;
363    path)
364       GCJ="gcj -B`${PWDCMD-pwd}`/"
365       GCJH=gcjh
366    ;;
367 esac
368
369 AC_SUBST(GCJ_FOR_ECJX)
370 AC_SUBST(GCJH)
371 AC_SUBST(host_exeext)
372
373 # Create it, so that compile/link tests don't fail
374 test -f libgcj.spec || touch libgcj.spec
375
376
377
378 # Set up to configure Classpath.
379 # FIXME: no supported way to pass args in autoconf.
380 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
381 # Disable tool wrappers to avoid ltdl.h configure check.
382 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
383 ac_configure_args="$ac_configure_args --disable-load-library"
384 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
385 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
386 dir1=`cd $srcdir && pwd`
387 dir2=`pwd`
388 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
389 ac_configure_args="$ac_configure_args --disable-core-jni"
390 dnl FIXME?
391 ac_configure_args="$ac_configure_args --disable-examples"
392 ac_configure_args="$ac_configure_args --with-glibj=build"
393 if test "$plugin_enabled" != yes; then
394   ac_configure_args="$ac_configure_args --disable-plugin"
395 fi
396 if test "$gconf_enabled" != yes; then
397   ac_configure_args="$ac_configure_args --disable-gconf-peer"
398   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
399 fi
400 if test "$use_gtk_awt" != yes; then
401   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
402 fi
403 if test "$use_qt_awt" != yes; then
404   ac_configure_args="$ac_configure_args --disable-qt-peer"
405 else
406   # We need this as qt is disabled by default in classpath.
407   ac_configure_args="$ac_configure_args --enable-qt-peer"
408 fi
409 if test "$use_x_awt" != yes; then
410   ac_configure_args="$ac_configure_args --without-escher"
411 else
412   # We need this as escher is disabled by default in classpath.
413   if test "$use_escher" != true; then
414     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
415   else
416     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
417   fi
418 fi
419 # -Werror causes unavoidable problems in code using alsa.
420 ac_configure_args="$ac_configure_args --disable-Werror"
421 dnl --with-gcj=$GCJ
422 dnl --with-javah=$GCJH
423 dnl gjdoc?
424 dnl gtk-cairo -- just export here...
425 dnl --enable-regen-headers?
426
427 # Only use libltdl for non-newlib builds.
428 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
429    AC_LIBLTDL_CONVENIENCE
430    AC_LIBTOOL_DLOPEN
431    DIRLTDL=libltdl
432    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
433    # Sigh.  Libtool's macro doesn't do the right thing.
434    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
435    # FIXME: this is a hack.
436    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
437    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
438 fi
439 AC_SUBST(INCLTDL)
440 AC_SUBST(LIBLTDL)
441 AC_SUBST(DIRLTDL)
442 AC_PROG_LIBTOOL
443 AM_PROG_GCJ
444 AM_PROG_CC_C_O
445
446 AC_CONFIG_SUBDIRS(classpath libltdl)
447
448 # The -no-testsuite modules omit the test subdir.
449 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
450
451 # Should the runtime set system properties by examining the 
452 # environment variable GCJ_PROPERTIES?
453 AC_ARG_ENABLE(getenv-properties,
454   AS_HELP_STRING([--disable-getenv-properties],
455                  [don't set system properties from GCJ_PROPERTIES]))
456
457 # Whether GCJ_PROPERTIES is used depends on the target.
458 if test -z "$enable_getenv_properties"; then
459    enable_getenv_properties=${enable_getenv_properties_default-yes}
460 fi
461 if test "$enable_getenv_properties" = no; then
462    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
463      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
464 fi
465
466 # Whether we should use arguments to main()
467 if test -z "$enable_main_args"; then
468    enable_main_args=${enable_main_args_default-yes}
469 fi
470 if test "$enable_main_args" = no; then
471    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
472 fi
473
474
475 # Should we use hashtable-based synchronization?
476 # Currently works only for Linux X86/ia64
477 # Typically faster and more space-efficient
478 AC_ARG_ENABLE(hash-synchronization,
479   AS_HELP_STRING([--enable-hash-synchronization],
480                  [use global hash table for monitor locks]))
481
482 if test -z "$enable_hash_synchronization"; then
483    enable_hash_synchronization=$enable_hash_synchronization_default
484 fi
485
486
487 install_ecj_jar=no
488 ECJ_BUILD_JAR=
489 ECJ_JAR=
490 AC_ARG_WITH(ecj-jar,
491         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
492         [ECJ_JAR=$withval],
493         [if test -f $multi_basedir/ecj.jar; then
494            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
495            ECJ_JAR='$(jardir)/ecj.jar'
496            install_ecj_jar=yes
497          fi])
498 AC_SUBST(ECJ_BUILD_JAR)
499 AC_SUBST(ECJ_JAR)
500 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
501 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
502
503 AC_ARG_WITH(java-home,
504   AS_HELP_STRING([--with-java-home=DIRECTORY],
505                  [value of java.home system property]),
506                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
507 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
508 AC_SUBST(JAVA_HOME)
509
510 # What is the native OS API for MinGW?
511 AC_ARG_WITH(win32-nlsapi,
512   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
513                  [native MinGW libgcj Win32 OS API (default is ansi)]),
514 [case "${withval}" in
515   ansi) with_win32_nlsapi=ansi ;;
516   unicows) with_win32_nlsapi=unicows ;;
517   unicode) with_win32_nlsapi=unicode ;;
518   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
519 esac],[with_win32_nlsapi=ansi])
520
521 case "${with_win32_nlsapi}" in
522   unicows | unicode) 
523     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
524       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
525     ;;
526 esac
527
528 # configure.host sets slow_pthread_self if the synchronization code should 
529 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
530 if test "${slow_pthread_self}" = "yes"; then
531   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
532     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
533 fi
534
535 # Check for gc debugging.  This option is handled both here and in the GC.
536 AC_ARG_ENABLE(gc-debug,
537    AS_HELP_STRING([--enable-gc-debug],
538                   [include full support for pointer backtracing etc.]),
539 [ if test "$enable_gc_debug" = "yes"; then
540     AC_DEFINE(LIBGCJ_GC_DEBUG, 1, 
541               [Define if we want to use debug calls into the garbage collector.])
542   fi])
543
544 # See if the user has the interpreter included.
545 AC_ARG_ENABLE(interpreter,
546   AS_HELP_STRING([--enable-interpreter],
547                  [enable interpreter]),
548   [if test "$enable_interpreter" = yes; then
549     # This can also be set in configure.host.
550     libgcj_interpreter=yes
551   elif test "$enable_interpreter" = no; then
552     libgcj_interpreter=no
553   fi])
554
555 if test "$libgcj_interpreter" = yes; then
556    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
557 fi
558 INTERPRETER="$libgcj_interpreter"
559 AC_SUBST(INTERPRETER)
560
561 AC_MSG_CHECKING([for exception model to use])
562 AC_LANG_PUSH(C++)
563 AC_ARG_ENABLE(sjlj-exceptions,
564   AS_HELP_STRING([--enable-sjlj-exceptions],
565                  [force use of builtin_setjmp for exceptions]),
566 [:],
567 [dnl Botheration.  Now we've got to detect the exception model.
568 dnl Link tests against libgcc.a are problematic since -- at least
569 dnl as of this writing -- we've not been given proper -L bits for
570 dnl single-tree newlib and libgloss.
571 dnl
572 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
573 dnl conftest files before we got a change to grep them first.
574 cat > conftest.$ac_ext << EOF
575 [#]line __oline__ "configure"
576 struct S { ~S(); };
577 void bar();
578 void foo()
579 {
580   S s;
581   bar();
582 }
583 EOF
584 old_CXXFLAGS="$CXXFLAGS"  
585 CXXFLAGS=-S
586 if AC_TRY_EVAL(ac_compile); then
587   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
588     enable_sjlj_exceptions=yes
589   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
590     enable_sjlj_exceptions=no
591   fi
592 fi
593 CXXFLAGS="$old_CXXFLAGS"
594 rm -f conftest*])
595 if test x$enable_sjlj_exceptions = xyes; then
596   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
597         [Define if the compiler is configured for setjmp/longjmp exceptions.])
598   ac_exception_model_name=sjlj
599 elif test x$enable_sjlj_exceptions = xno; then
600   ac_exception_model_name="call frame"
601 else
602   AC_MSG_ERROR([unable to detect exception model])
603 fi
604 AC_LANG_POP(C++)
605 AC_MSG_RESULT($ac_exception_model_name)
606
607 # If we are non using SJLJ exceptions, and this host does not have support 
608 # for unwinding from a signal handler, enable checked dereferences and divides.
609 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
610   CHECKREFSPEC=-fcheck-references
611   DIVIDESPEC=-fuse-divide-subroutine
612   EXCEPTIONSPEC=
613 fi
614
615 # See if the user wants to disable java.net.  This is the mildly
616 # ugly way that we admit that target-side configuration sucks.
617 AC_ARG_ENABLE(java-net,
618   AS_HELP_STRING([--disable-java-net],
619                  [disable java.net]))
620
621 # Whether java.net is built by default can depend on the target.
622 if test -z "$enable_java_net"; then
623    enable_java_net=${enable_java_net_default-yes}
624 fi
625 if test "$enable_java_net" = no; then
626    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
627 fi
628
629 # See if the user wants to configure without libffi.  Some
630 # architectures don't support it, and default values are set in 
631 # configure.host.
632 AC_ARG_WITH(libffi,
633   AS_HELP_STRING([--without-libffi],
634                  [don't use libffi]),
635   [:],
636   [with_libffi=${with_libffi_default-yes}])
637
638 LIBFFI=
639 LIBFFIINCS=
640 if test "$with_libffi" != no; then
641    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
642    LIBFFI=../libffi/libffi_convenience.la
643    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
644 fi
645 AC_SUBST(LIBFFI)
646 AC_SUBST(LIBFFIINCS)
647
648 # See if the user wants to disable JVMPI support.
649 AC_ARG_ENABLE(jvmpi,
650   AS_HELP_STRING([--disable-jvmpi],
651                  [disable JVMPI support]))
652
653 if test "$enable_jvmpi" != no; then
654     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
655 fi
656
657 # If the target is an eCos system, use the appropriate eCos
658 # I/O routines.
659 # FIXME: this should not be a local option but a global target
660 # system; at present there is no eCos target.
661 TARGET_ECOS=${PROCESS-"no"}
662 AC_ARG_WITH(ecos,
663 [  --with-ecos             enable runtime eCos target support],
664 TARGET_ECOS="$with_ecos"
665 )
666
667 case "$TARGET_ECOS" in
668    no) case "$host" in
669       *mingw*)
670             PLATFORM=Win32
671             PLATFORMNET=Win32
672             PLATFORMH=win32.h
673         CHECK_FOR_BROKEN_MINGW_LD
674       ;;
675       *)
676             PLATFORM=Posix
677             PLATFORMNET=Posix
678             PLATFORMH=posix.h
679       ;;
680       esac
681       ;;
682    *)
683       PLATFORM=Ecos
684       PLATFORMNET=NoNet
685       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
686       PLATFORMH=posix.h
687       ;;
688 esac
689 AC_SUBST(PLATFORM)
690 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
691
692 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
693                                       [Define if you have int32_t and uint32_t.]))
694 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
695                                         [Define if you have int32_t and uint32_t.]))
696 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
697                                           [Define if you have u_int32_t]))
698 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
699                                            [Define if you have u_int32_t]))
700
701 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
702 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
703
704 case "$host" in
705   *-darwin*) DARWIN_CRT=true ;;
706   *) DARWIN_CRT=false ;;
707 esac
708 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
709
710 # These may not be defined in a non-ANS conformant embedded system.
711 # FIXME: Should these case a runtime exception in that case?
712 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
713                                   [Define is you have 'mktime' in <time.h>]))
714 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
715                                   [Define is you have 'localtime' in <time.h>]))
716
717 # Create the subdirectory for natFile.cc, or the attempt
718 # to create the link will fail.
719 test -d java || mkdir java
720 test -d java/io || mkdir java/io
721 test -d gnu || mkdir gnu
722 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
723
724 # Likewise for natConcreteProcess.cc.
725 test -d java/lang || mkdir java/lang
726 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
727
728 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
729 test -d java/net || mkdir java/net
730 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
731 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
732
733 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
734 test -d gnu/java || mkdir gnu/java
735 test -d gnu/java/net || mkdir gnu/java/net
736 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
737 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
738
739 # Likewise for natVMPipe.cc and natVMSelector.cc.
740 test -d gnu/java/nio || mkdir gnu/java/nio
741 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
742 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
743
744 # Likewise for natFileChannelImpl.cc
745 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
746 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
747
748 case "${host}" in
749     *mingw*)
750       SYSTEMSPEC="-lgdi32 -lws2_32"
751       if test "${with_win32_nlsapi}" = "unicows"; then
752         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
753       fi
754     ;;
755     *)
756       SYSTEMSPEC=
757     ;;
758 esac
759 AC_SUBST(SYSTEMSPEC)
760
761 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
762 AC_SUBST(LIBGCJTESTSPEC)
763
764 AC_ARG_WITH(system-zlib,
765   AS_HELP_STRING([--with-system-zlib],
766                  [use installed libz]))
767 ZLIBSPEC=
768 AC_SUBST(ZLIBSPEC)
769 ZLIBTESTSPEC=
770 AC_SUBST(ZLIBTESTSPEC)
771
772 AC_PATH_XTRA
773
774 # FIXME: this should be _libs on some hosts.
775 libsubdir=.libs
776
777 # extra LD Flags which are required for targets
778 case "${host}" in
779 *-*-darwin[[0-7]].*)
780     # For now we have to disable it on darwin[8-9] because it slows down
781     # the linking phase. A possible bug in ld?
782     # on Darwin -single_module speeds up loading of the dynamic libraries.
783     extra_ldflags_libjava=-Wl,-single_module
784     ;;
785 esac
786 AC_SUBST(extra_ldflags_libjava)
787
788 # Allow the GC to be disabled.  Can be useful when debugging.
789 AC_MSG_CHECKING([for garbage collector to use])
790 AC_ARG_ENABLE(java-gc,
791   AS_HELP_STRING([--enable-java-gc=TYPE],
792                  [choose garbage collector (default is boehm)]),
793   [GC=$enableval],
794   [GC=boehm])
795 GCLIBS=
796 GCINCS=
797 GCDEPS=
798 GCSPEC=
799 JC1GCSPEC=
800 GCTESTSPEC=
801 case "$GC" in
802  boehm)
803     AC_MSG_RESULT(boehm)
804     GCLIBS=../boehm-gc/libgcjgc_convenience.la
805     JC1GCSPEC='-fuse-boehm-gc'
806     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
807     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
808     GCOBJS=boehm.lo    
809     GCHDR=boehm-gc.h
810     # The POSIX thread support needs to know this.
811     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
812     ;;
813  no)
814     AC_MSG_RESULT(none)
815     GCHDR=no-gc.h
816     ;;
817  *)
818     AC_MSG_ERROR([unrecognized collector "$GC"])
819     ;;
820 esac
821 AC_SUBST(GCLIBS)
822 AC_SUBST(GCINCS)
823 AC_SUBST(GCDEPS)
824 AC_SUBST(GCSPEC)
825 AC_SUBST(JC1GCSPEC)
826 AC_SUBST(GCTESTSPEC)
827 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
828 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
829 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
830
831
832 AC_MSG_CHECKING([for thread model used by GCC])
833 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
834 AC_MSG_RESULT([$THREADS])
835
836 case "$THREADS" in
837  no | none | single)
838     THREADS=none
839     ;;
840  posix | posix95 | pthreads)
841     THREADS=posix
842     case "$host" in
843      *-*-linux*)
844         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
845         ;;
846     esac
847     ;;
848  win32)
849     ;;
850  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
851     AC_MSG_ERROR(thread package $THREADS not yet supported)
852     ;;
853  *)
854     AC_MSG_ERROR($THREADS is an unknown thread package)
855     ;;
856 esac
857
858 THREADCXXFLAGS=
859 THREADLDFLAGS=
860 THREADLIBS=
861 THREADINCS=
862 THREADDEPS=
863 THREADH=
864 THREADSPEC=
865 THREADSTARTFILESPEC=
866 case "$THREADS" in
867  posix)
868     case "$host" in
869      *-*-cygwin*)
870         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
871         ;;
872      *-*-freebsd[[1234]]*)
873         # Before FreeBSD 5, it didn't have -lpthread (or any library which
874         # merely adds pthread_* functions) but it does have a -pthread switch
875         # which is required at link-time to select -lc_r *instead* of -lc.
876         THREADLDFLAGS=-pthread
877         # Don't set THREADSPEC here as might be expected since -pthread is
878         # not processed when found within a spec file, it must come from
879         # the command line.  For now, the user must provide the -pthread
880         # switch to link code compiled with gcj.  In future, consider adding
881         # support for weak references to pthread_* functions ala gthr.h API.
882         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
883         ;;
884      *-*-freebsd*)
885         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
886         # systems which support threads and -lpthread.
887         THREADLDFLAGS=-pthread
888         THREADSPEC=-lpthread
889         ;;
890      alpha*-dec-osf* | hppa*-hp-hpux*)
891         THREADCXXFLAGS=-pthread
892         # boehm-gc needs some functions from librt, so link that too.
893         THREADLIBS='-lpthread -lrt'
894         THREADSPEC='-lpthread -lrt'
895         ;;
896      *)
897         THREADLIBS=-lpthread
898         THREADSPEC=-lpthread
899         ;;
900     esac
901     THREADH=posix-threads.h
902     # MIT pthreads doesn't seem to have the mutexattr functions.
903     # But for now we don't check for it.  We just assume you aren't
904     # using MIT pthreads.
905     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
906
907     # If we're using the Boehm GC, then we happen to know that it
908     # defines _REENTRANT, so we don't bother.  Eww.
909     if test "$GC" != boehm; then
910        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
911     fi
912     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
913     ;;
914
915  win32)
916     THREADH=win32-threads.h
917     THREADCXXFLAGS=-mthreads
918     # We need thread-safe exception handling so _CRT_MT should be set to 1.
919     # But we do not want the executables created to be dependent on
920     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
921     # exception handling contexts.  The following kludge achieves this effect
922     # and causes a dummy __mingwthr_key_dtor() to be linked in from
923     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
924     # A workaround is to explicitly use -mthreads while linking Java programs.
925     # See PR libgcj/28263.
926     #
927     # FIXME: In Java we are able to detect thread death at the end of
928     # Thread.run() so we should be able to clean up the exception handling
929     # contexts ourselves.
930     THREADSTARTFILESPEC='crtmt%O%s'
931     ;;
932
933  none)
934     THREADH=no-threads.h
935     ;;
936 esac
937 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
938 AC_SUBST(THREADLIBS)
939 AC_SUBST(THREADINCS)
940 AC_SUBST(THREADDEPS)
941 AC_SUBST(THREADSPEC)
942 AC_SUBST(THREADSTARTFILESPEC)
943 AC_SUBST(THREADLDFLAGS)
944 AC_SUBST(THREADCXXFLAGS)
945 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
946 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
947 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
948 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
949
950 if test -d sysdep; then true; else mkdir sysdep; fi
951 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
952 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
953 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
954
955 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
956 if test "$use_libgcj_bc" = yes; then
957   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
958 fi
959 AC_SUBST(LIBGCJ_SPEC)
960
961 HASH_SYNC_SPEC=
962 # Hash synchronization is only useful with posix threads right now.
963 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
964    HASH_SYNC_SPEC=-fhash-synchronization
965    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
966 fi
967 AC_SUBST(HASH_SYNC_SPEC)
968
969 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
970
971 # We're in the tree with gcc, and need to include some of its headers.
972 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
973
974 if test "x${with_newlib}" = "xyes"; then
975    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
976    # may not work correctly, because the compiler may not be able to
977    # link executables.
978
979    # We assume newlib.  This lets us hard-code the functions we know
980    # we'll have.
981    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
982    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
983    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
984    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
985    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
986    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
987    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
988    # This is only for POSIX threads.
989    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
990    # We also assume we are using gcc, which provides alloca.
991    AC_DEFINE(HAVE_ALLOCA)
992
993    # Assume we do not have getuid and friends.
994    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
995    PLATFORMNET=NoNet
996 else
997    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
998                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
999                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1000                    nl_langinfo setlocale \
1001                    inet_pton uname inet_ntoa \
1002                    fork execvp pipe sigaction ftruncate mmap \
1003                    getifaddrs])
1004    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1005    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
1006    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1007    AC_CHECK_LIB(dl, dladdr, [
1008        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1009        AC_CHECK_LIB(dld, dladdr, [
1010        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1011
1012    if test x"$cross_compiling" = x"no"; then
1013      AC_CHECK_FILES(/proc/self/exe, [
1014        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1015    else
1016      case $host in
1017      *-linux*)
1018        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1019        ;;
1020      esac
1021    fi
1022
1023    AM_ICONV
1024    AM_LC_MESSAGES
1025    AC_STRUCT_TIMEZONE
1026
1027    AC_CHECK_FUNCS(gethostbyname_r, [
1028      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1029        [Define if you have the 'gethostbyname_r' function.])
1030      # There are two different kinds of gethostbyname_r.
1031      # We look for the one that returns `int'.
1032      # Hopefully this check is robust enough.
1033      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1034        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1035
1036      case " $GCINCS " in
1037      *" -D_REENTRANT "*) ;;
1038      *)
1039         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1040         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1041         [libjava_cv_gethostbyname_r_needs_reentrant],
1042         [ AC_LANG_PUSH(C++)
1043           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1044             [[gethostbyname_r("", 0, 0);]])],
1045             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1046                 CPPFLAGS_SAVE="$CPPFLAGS"
1047                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1048                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1049                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1050                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1051                 CPPFLAGS="$CPPFLAGS_SAVE"
1052           ])
1053           AC_LANG_POP(C++)
1054         ])
1055         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1056           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1057         fi
1058      ;;
1059      esac
1060
1061      AC_CACHE_CHECK([for struct hostent_data],
1062         [libjava_cv_struct_hostent_data], [dnl
1063         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1064 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1065 # define _REENTRANT 1
1066 #endif
1067 #include <netdb.h>]], [[struct hostent_data data;]])],
1068           [libjava_cv_struct_hostent_data=yes],
1069           [libjava_cv_struct_hostent_data=no])])
1070      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1071        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1072          [Define if struct hostent_data is defined in netdb.h])
1073      fi
1074    ])
1075
1076    # FIXME: libjava source code expects to find a prototype for
1077    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1078    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1079    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1080    # linkage check is enough, yet C++ code requires proper prototypes.)
1081    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1082    AC_CHECK_FUNCS(gethostbyaddr_r, [
1083      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1084        [Define if you have the 'gethostbyaddr_r' function.])
1085      # There are two different kinds of gethostbyaddr_r.
1086      # We look for the one that returns `int'.
1087      # Hopefully this check is robust enough.
1088      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1089        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1090          [Define if gethostbyaddr_r returns 'int'.])])])])
1091
1092    AC_CHECK_FUNCS(gethostname, [
1093      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1094        [Define if you have the 'gethostname' function.])
1095      AC_EGREP_HEADER(gethostname, unistd.h, [
1096        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1097          [Define if gethostname is declared in <unistd.h>.])])])
1098
1099    AC_CHECK_FUNCS(usleep, [
1100      AC_EGREP_HEADER(usleep, unistd.h, [
1101        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1102           [Define if usleep is declared in <unistd.h>.])])])
1103
1104    # Look for these functions in the thread library, but only bother
1105    # if using POSIX threads.
1106    if test "$THREADS" = posix; then
1107       save_LIBS="$LIBS"
1108       LIBS="$LIBS $THREADLIBS"
1109       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1110       # E.g., Solaris.
1111       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1112
1113       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1114       # Solaris 7 the name librt is preferred.
1115       AC_CHECK_FUNCS(sched_yield, , [
1116         AC_CHECK_LIB(rt, sched_yield, [
1117           AC_DEFINE(HAVE_SCHED_YIELD)
1118           THREADLIBS="$THREADLIBS -lrt"
1119           THREADSPEC="$THREADSPEC -lrt"], [
1120           AC_CHECK_LIB(posix4, sched_yield, [
1121             AC_DEFINE(HAVE_SCHED_YIELD)
1122             THREADLIBS="$THREADLIBS -lposix4"
1123             THREADSPEC="$THREADSPEC -lposix4"])])])
1124
1125       AC_CHECK_LIB(rt, clock_gettime, [
1126          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1127          case "$THREADSPEC" in
1128            *-lrt*) ;;
1129            *)
1130              THREADSPEC="$THREADSPEC -lrt"
1131              THREADLIBS="$THREADLIBS -lrt"
1132              ;;
1133          esac])
1134
1135       LIBS="$save_LIBS"
1136
1137       # We can save a little space at runtime if the mutex has m_count
1138       # or __m_count.  This is a nice hack for Linux.
1139       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1140           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1141         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1142              [Define if pthread_mutex_t has m_count member.]), [
1143         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1144             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1145           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1146             [Define if pthread_mutex_t has __m_count member.]))])
1147    fi
1148
1149    # We require a way to get the time.
1150    time_found=no
1151    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1152    if test "$time_found" = no; then
1153       AC_MSG_ERROR([no function found to get the time])
1154    fi
1155
1156    AC_CHECK_FUNCS(memmove)
1157
1158    # We require memcpy.
1159    memcpy_found=no
1160    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1161    if test "$memcpy_found" = no; then
1162       AC_MSG_ERROR([memcpy is required])
1163    fi
1164    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1165    AC_CHECK_LIB(dl, dlopen, [
1166        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1167        AC_CHECK_LIB(dld, dlopen, [
1168        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1169
1170    # Some library-finding code we stole from Tcl.
1171    #--------------------------------------------------------------------
1172    #    Check for the existence of the -lsocket and -lnsl libraries.
1173    #    The order here is important, so that they end up in the right
1174    #    order in the command line generated by make.  Here are some
1175    #    special considerations:
1176    #    1. Use "connect" and "accept" to check for -lsocket, and
1177    #       "gethostbyname" to check for -lnsl.
1178    #    2. Use each function name only once:  can't redo a check because
1179    #       autoconf caches the results of the last check and won't redo it.
1180    #    3. Use -lnsl and -lsocket only if they supply procedures that
1181    #       aren't already present in the normal libraries.  This is because
1182    #       IRIX 5.2 has libraries, but they aren't needed and they're
1183    #       bogus:  they goof up name resolution if used.
1184    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1185    #       To get around this problem, check for both libraries together
1186    #       if -lsocket doesn't work by itself.
1187    #--------------------------------------------------------------------
1188
1189    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1190     [gcj_cv_lib_sockets=
1191      gcj_checkBoth=0
1192      unset ac_cv_func_connect
1193      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1194      if test "$gcj_checkSocket" = 1; then
1195          unset ac_cv_func_connect
1196          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1197                       gcj_checkBoth=1)
1198      fi
1199      if test "$gcj_checkBoth" = 1; then
1200          gcj_oldLibs=$LIBS
1201          LIBS="$LIBS -lsocket -lnsl"
1202          unset ac_cv_func_accept
1203          AC_CHECK_FUNC(accept,
1204                        [gcj_checkNsl=0
1205                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1206          unset ac_cv_func_accept
1207          LIBS=$gcj_oldLibs
1208      fi
1209      unset ac_cv_func_gethostbyname
1210      gcj_oldLibs=$LIBS
1211      LIBS="$LIBS $gcj_cv_lib_sockets"
1212      AC_CHECK_FUNC(gethostbyname, ,
1213                    [AC_CHECK_LIB(nsl, main,
1214                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1215      unset ac_cv_func_gethostbyname
1216      LIBS=$gcj_oldLIBS
1217    ])
1218    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1219
1220    if test "$with_system_zlib" = yes; then
1221       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1222    fi
1223
1224    # Test for Gtk stuff, if asked for.
1225    if test "$use_gtk_awt" = yes; then
1226       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1227       AC_SUBST(GTK_CFLAGS)
1228       AC_SUBST(GTK_LIBS)
1229
1230       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1231       AC_SUBST(GLIB_CFLAGS)
1232       AC_SUBST(GLIB_LIBS)
1233
1234       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1235       AC_SUBST(LIBART_CFLAGS)
1236       AC_SUBST(LIBART_LIBS)
1237
1238       # We require the XTest Extension to support java.awt.Robot.
1239       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1240                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1241                    [${X_LIBS}])
1242    fi
1243
1244    # On Solaris, and maybe other architectures, the Boehm collector
1245    # requires -ldl.
1246    if test "$GC" = boehm; then
1247       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1248    fi
1249 fi
1250
1251 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1252 case $build in
1253     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1254     *)         CLASSPATH_SEPARATOR=':' ;;
1255 esac
1256 AC_SUBST(CLASSPATH_SEPARATOR)
1257
1258 # We must search the source tree for java.lang, since we still don't
1259 # have libgcj.jar nor java/lang/*.class
1260 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1261 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1262
1263 # Since some classes depend on this one, we need its source available
1264 # before we can do any GCJ compilation test :-(
1265 if test ! -f gnu/classpath/Configuration.java; then
1266   test -d gnu || mkdir gnu
1267   test -d gnu/classpath || mkdir gnu/classpath
1268   # Note that it is not crucial that all the values here be correct.
1269   sed -e "s,@prefix@,$prefix," \
1270       -e "s,@VERSION@,$VERSION," \
1271       -e "s,@LIBDEBUG@,false," \
1272       -e "s,@INIT_LOAD_LIBRARY@,false," \
1273       -e "s,@@,$LIBGCJDEBUG," \
1274       -e "s,@default_toolkit@,$TOOLKIT," \
1275       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1276       -e "s,@GTK_CAIRO_ENABLED@,false," \
1277         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1278         > gnu/classpath/Configuration.java
1279   # We do not want to redirect the output of the grep below to /dev/null,
1280   # but we add /dev/null to the input list so that grep will print the
1281   # filename of Configuration.java in case it finds any matches.
1282   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1283     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1284   fi
1285 fi
1286
1287 LT_AC_PROG_GCJ
1288
1289 # Now remove it.
1290 rm -f gnu/classpath/Configuration.java
1291
1292 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1293
1294 AC_CHECK_SIZEOF(void *)
1295
1296 AC_C_BIGENDIAN
1297
1298 ZLIBS=
1299 SYS_ZLIBS=
1300 ZINCS=
1301
1302 if test -z "$ZLIBSPEC"; then
1303    # Use zlib from the GCC tree.
1304    ZINCS='-I$(top_srcdir)/../zlib'
1305    ZLIBS=../zlib/libzgcj_convenience.la
1306 else
1307    # System's zlib.
1308    SYS_ZLIBS="$ZLIBSPEC"
1309 fi
1310 AC_SUBST(ZLIBS)
1311 AC_SUBST(SYS_ZLIBS)
1312 AC_SUBST(ZINCS)
1313 AC_SUBST(DIVIDESPEC)
1314 AC_SUBST(CHECKREFSPEC)
1315 AC_SUBST(EXCEPTIONSPEC)
1316 AC_SUBST(BACKTRACESPEC)
1317 AC_SUBST(IEEESPEC)
1318
1319 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1320 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1321 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1322 AC_SUBST(GCC_UNWIND_INCLUDE)
1323
1324 # Process the option "--enable-version-specific-runtime-libs"
1325 # Calculate toolexeclibdir
1326 case ${version_specific_libs} in
1327   yes)
1328     # Need the gcc compiler version to know where to install libraries
1329     # and header files if --enable-version-specific-runtime-libs option
1330     # is selected.
1331     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1332     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1333     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1334     toolexeclibdir=$toolexecmainlibdir
1335     ;;
1336   no)
1337     if test -n "$with_cross_host" &&
1338        test x"$with_cross_host" != x"no"; then
1339       # Install a library built with a cross compiler in tooldir, not libdir.
1340       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1341       toolexecmainlibdir='$(toolexecdir)/lib'
1342     else
1343       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1344       toolexecmainlibdir='$(libdir)'
1345     fi
1346     multi_os_directory=`$CC -print-multi-os-directory`
1347     case $multi_os_directory in
1348       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1349       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1350     esac
1351     ;;
1352 esac
1353 AC_SUBST(toolexecdir)
1354 AC_SUBST(toolexecmainlibdir)
1355 AC_SUBST(toolexeclibdir)
1356
1357 # Determine where the standard .db file and GNU Classpath JNI
1358 # libraries are found.
1359 multi_os_directory=`$CC -print-multi-os-directory`
1360 case $multi_os_directory in
1361   .)
1362    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1363    ;;
1364   *)
1365    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1366    ;;
1367 esac
1368 AC_SUBST(dbexecdir)
1369
1370 # Determine gcj version number.
1371 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1372 GCJVERSION=$gcjversion
1373 AC_SUBST(GCJVERSION)
1374 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1375
1376 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1377 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1378
1379 TL_AC_GXX_INCLUDE_DIR
1380
1381 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1382 # On that system, sys/ioctl.h will not include sys/filio.h unless
1383 # BSD_COMP is defined; just including sys/filio.h is simpler.
1384 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1385 # for now.  If you change this, you also must update natFile.cc.
1386 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1387                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1388                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1389                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1390                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1391 AC_CHECK_HEADERS(inttypes.h, [
1392     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1393     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1394 ])
1395 AC_HEADER_SYS_WAIT
1396
1397 AC_CHECK_TYPE([ssize_t], [int])
1398 AC_CHECK_TYPE([magic_t], [
1399     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1400 #ifdef HAVE_MAGIC_H
1401 #include <magic.h>
1402 #endif])
1403
1404 AC_MSG_CHECKING([for in_addr_t])
1405 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1406 #if STDC_HEADERS
1407 #include <stdlib.h>
1408 #include <stddef.h>
1409 #endif
1410 #if HAVE_NETINET_IN_H
1411 #include <netinet/in.h>
1412 #endif]], [[in_addr_t foo;]])],
1413   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1414      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1415    AC_MSG_RESULT(yes)],
1416   [AC_MSG_RESULT(no)])
1417
1418 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1419 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1420   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1421      [Define if struct ip_mreq is defined in netinet/in.h.])
1422    AC_MSG_RESULT(yes)],
1423   [AC_MSG_RESULT(no)])
1424
1425 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1426 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1427   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1428      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1429    AC_MSG_RESULT(yes)],
1430   [AC_MSG_RESULT(no)])
1431
1432 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1433 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1434   [AC_DEFINE(HAVE_INET6, 1,
1435      [Define if inet6 structures are defined in netinet/in.h.])
1436    AC_MSG_RESULT(yes)],
1437   [AC_MSG_RESULT(no)])
1438
1439 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1440 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1441 #include <sys/types.h>
1442 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1443   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1444    AC_MSG_RESULT(yes)],
1445   [AC_MSG_RESULT(no)])
1446
1447 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1448 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1449   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1450    AC_MSG_RESULT(yes)],
1451   [AC_MSG_RESULT(no)
1452    AC_MSG_CHECKING([for global timezone variable])
1453    dnl FIXME: we don't want a link check here because that won't work
1454    dnl when cross-compiling.  So instead we make an assumption that
1455    dnl the header file will mention timezone if it exists.
1456    dnl Don't find the win32 function timezone
1457    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1458      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1459       AC_MSG_RESULT(yes)],
1460      [AC_MSG_RESULT(no)
1461        AC_MSG_CHECKING([for global _timezone variable])
1462        dnl FIXME: As above, don't want link check
1463        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1464          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1465             [Define if your platform has the global _timezone variable.])
1466           AC_MSG_RESULT(yes)],
1467           [AC_MSG_RESULT(no)])])])
1468
1469 AC_FUNC_ALLOCA
1470
1471 AC_CHECK_PROGS(PERL, perl, false)
1472
1473 SYSDEP_SOURCES=
1474 SIGNAL_HANDLER_AUX=
1475
1476 case "${host}" in
1477  i?86-*-linux*)
1478     SIGNAL_HANDLER=include/i386-signal.h
1479     ;;
1480  sparc*-sun-solaris*)
1481     SIGNAL_HANDLER=include/sparc-signal.h
1482     ;;
1483 # ia64-*)
1484 #    SYSDEP_SOURCES=sysdep/ia64.c
1485 #    test -d sysdep || mkdir sysdep
1486 #    ;;
1487  hppa*-*-linux*)
1488     SIGNAL_HANDLER=include/pa-signal.h
1489     ;;
1490  hppa*-hp-hpux*)
1491     SIGNAL_HANDLER=include/hppa-signal.h
1492     ;;
1493  ia64-*-linux*)
1494     SIGNAL_HANDLER=include/dwarf2-signal.h
1495     ;;
1496  powerpc*-*-linux*)
1497     SIGNAL_HANDLER=include/powerpc-signal.h
1498     ;;
1499  alpha*-*-linux*)
1500     SIGNAL_HANDLER=include/dwarf2-signal.h
1501     ;;
1502  s390*-*-linux*)
1503     SIGNAL_HANDLER=include/s390-signal.h
1504     ;;
1505  x86_64*-*-linux*)
1506     SIGNAL_HANDLER=include/x86_64-signal.h
1507     SIGNAL_HANDLER_AUX=include/i386-signal.h
1508     ;;
1509  sparc*-*-linux*)
1510     SIGNAL_HANDLER=include/dwarf2-signal.h
1511     ;;
1512  sh*-*-linux*)
1513     SIGNAL_HANDLER=include/sh-signal.h
1514     ;;
1515  *mingw*)
1516     SIGNAL_HANDLER=include/win32-signal.h
1517     ;;
1518  mips*-*-linux*)
1519     SIGNAL_HANDLER=include/mips-signal.h
1520     ;;
1521  powerpc*-*-darwin*)
1522     SIGNAL_HANDLER=include/darwin-signal.h
1523     ;;
1524  *)
1525     SIGNAL_HANDLER=include/default-signal.h
1526     ;;
1527 esac
1528
1529 # If we're using sjlj exceptions, forget what we just learned.
1530 if test "$enable_sjlj_exceptions" = yes; then
1531    SIGNAL_HANDLER=include/default-signal.h
1532    SIGNAL_HANDLER_AUX=
1533 fi
1534
1535 AC_SUBST(SYSDEP_SOURCES)
1536
1537 if test -z "$SIGNAL_HANDLER_AUX"; then
1538   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1539 fi
1540
1541 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1542                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1543
1544 if test "${multilib}" = "yes"; then
1545   multilib_arg="--enable-multilib"
1546 else
1547   multilib_arg=
1548 fi
1549
1550 # See if we support thread-local storage.
1551 GCC_CHECK_TLS
1552
1553 # For _Unwind_GetIPInfo.
1554 GCC_CHECK_UNWIND_GETIPINFO
1555
1556 # Check if linker supports static linking on a per library basis
1557 LD_START_STATIC_SPEC=
1558 LD_FINISH_STATIC_SPEC=
1559 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1560   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1561     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1562     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1563   fi
1564 fi
1565 AC_SUBST(LD_START_STATIC_SPEC)
1566 AC_SUBST(LD_FINISH_STATIC_SPEC)
1567
1568 here=`${PWDCMD-pwd}`
1569 AC_SUBST(here)
1570
1571 # We get this from the environment.
1572 AC_SUBST(GCJFLAGS)
1573
1574 AC_CONFIG_FILES([
1575 Makefile
1576 libgcj.pc
1577 libgcj.spec
1578 libgcj-test.spec
1579 gcj/Makefile
1580 include/Makefile
1581 testsuite/Makefile
1582 ])
1583
1584 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1585
1586 AC_CONFIG_COMMANDS([default],
1587 [# Only add multilib support code if we just rebuilt top-level Makefile.
1588 case " $CONFIG_FILES " in
1589  *" Makefile "*)
1590    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1591    ac_file=Makefile . ${multi_basedir}/./libjava/../config-ml.in
1592    ;;
1593 esac
1594 for ac_multi_file in $CONFIG_FILES; do
1595   case $ac_multi_file in
1596   */Makefile)
1597     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1598   esac
1599 done
1600 ],
1601 srcdir=${srcdir}
1602 host=${host}
1603 target=${target}
1604 with_multisubdir=${with_multisubdir}
1605 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1606 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1607 multi_basedir=${multi_basedir}
1608 CC="${CC}"
1609 CXX="${CXX}"
1610 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1611 )
1612
1613 AC_OUTPUT