OSDN Git Service

a62805c1fab166ce038eaf891af2b171ecc3e216
[pf3gnuchains/gcc-fork.git] / libjava / configure.ac
1 dnl # Process this with autoconf to create configure
2 AC_PREREQ(2.59)
3 # Still use "libjava" here to placate dejagnu.
4 AC_INIT([libjava], [version-unused],, [libjava])
5
6 AC_CONFIG_SRCDIR(java/lang/System.java)
7
8 GCC_TOPLEV_SUBDIRS
9
10 # We use these options to decide which functions to include.
11 AC_ARG_WITH(target-subdir,
12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
13                  [configure in a subdirectory]))
14
15 # We may get other options which we don't document:
16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
17
18 # Find the rest of the source tree framework.
19 AM_ENABLE_MULTILIB(, ..)
20
21 AC_CANONICAL_SYSTEM
22 _GCC_TOPLEV_NONCANONICAL_BUILD
23 _GCC_TOPLEV_NONCANONICAL_TARGET
24
25 AC_SUBST(target_noncanonical)
26
27 # This works around the fact that libtool configuration may change LD
28 # for this particular configuration, but some shells, instead of
29 # keeping the changes in LD private, export them just because LD is
30 # exported.
31 ORIGINAL_LD_FOR_MULTILIBS=$LD
32
33 AC_PROG_LN_S
34
35 # This works around an automake problem.
36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
37 AC_SUBST(mkinstalldirs)
38
39 AC_ARG_WITH(cross-host,
40   AS_HELP_STRING([--with-cross-host=HOST],
41                  [configure with a cross compiler from HOST]))
42
43 AC_ARG_WITH(newlib,
44   AS_HELP_STRING([--with-newlib],
45                  [configure with newlib]))
46
47 AC_ARG_ENABLE(version-specific-runtime-libs,
48   AS_HELP_STRING([--enable-version-specific-runtime-libs],    
49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
50     [case "$enableval" in
51       yes) version_specific_libs=yes ;;
52       no)  version_specific_libs=no ;;
53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
54      esac],
55     [version_specific_libs=no]
56 )
57
58 AC_ARG_ENABLE(plugin,
59   AS_HELP_STRING([--enable-plugin],
60                  [build gcjwebplugin web browser plugin]),
61     [case "$enableval" in
62       yes) plugin_enabled=yes ;;
63       no)  plugin_enabled=no ;;
64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
65      esac],
66     [plugin_enabled=no]
67 )
68
69 AC_ARG_ENABLE(gconf-peer,
70   AS_HELP_STRING([--enable-gconf-peer],
71                  [compile GConf native peers for util.preferences]),
72     [case "$enableval" in
73       yes) gconf_enabled=yes ;;
74       no)  gconf_enabled=no ;;
75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
76      esac],
77     [gconf_enabled=no]
78 )
79
80 AC_ARG_ENABLE(java-maintainer-mode,
81         AS_HELP_STRING([--enable-java-maintainer-mode],
82         [allow rebuilding of .class and .h files]))
83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
84
85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
86 GCC_NO_EXECUTABLES
87
88 # (1) We use an abnormal CXX (without library references), so we
89 # must cache it under a different name.
90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
91 # the non-multilib-adjusted value will be used in multilibs.
92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
93 # (4) As another side effect, automake doesn't automatically include them
94 # in Makefile.in.
95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
97 # used in later tests.  This may not be necessary in libjava; I don't know.
98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
100 save_CXXFLAGS="$CXXFLAGS"
101 CXXFLAGS="$CXXFLAGS -fno-builtin"
102 AC_PROG_CC
103 AC_PROG_CXX
104 CXXFLAGS="$save_CXXFLAGS"
105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
106 AC_SUBST(CFLAGS)
107 AC_SUBST(CXXFLAGS)
108 AC_SUBST(LDFLAGS)
109
110 AM_INIT_AUTOMAKE([1.9.0])
111
112 AC_CHECK_TOOL(AS, as)
113 AC_CHECK_TOOL(LD, ld)
114 AC_CHECK_TOOL(AR, ar)
115 AC_CHECK_TOOL(RANLIB, ranlib, :)
116 AC_PROG_AWK
117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
118 AC_PATH_PROG([ZIP], [zip], no)
119 AC_PATH_PROG([UNZIP], [unzip], unzip)
120 # Prefer the jar we found, but fall back to our jar script.
121 if test "$JAR" = no; then
122   if test "$ZIP" = no; then
123     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
124   else
125     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
126     JAR=`pwd`/scripts/jar
127   fi
128 fi
129
130 AC_PROG_INSTALL
131
132 AM_MAINTAINER_MODE
133
134 AC_EXEEXT
135
136 # configure.host sets the following important variables
137 #       libgcj_cflags    - host specific C compiler flags
138 #       libgcj_cxxflags  - host specific C++ compiler flags
139 #       libgcj_javaflags - host specific Java compiler flags
140
141 libgcj_cflags=
142 libgcj_cxxflags=
143 libgcj_javaflags=
144
145 . ${srcdir}/configure.host
146
147 ACX_PROG_LD_GNU_SYMBOLIC
148 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
149 if test -z "$libgcj_ld_symbolic"; then
150   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
151 fi
152
153 LIBGCJ_CFLAGS="${libgcj_cflags}"
154 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
155 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
156 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
157 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
158 AC_SUBST(LIBGCJ_CFLAGS)
159 AC_SUBST(LIBGCJ_CXXFLAGS)
160 AC_SUBST(LIBGCJ_JAVAFLAGS)
161 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
162 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
163
164 # Only use libltdl for non-newlib builds.
165 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
166    AC_LTDL_SHLIBPATH
167 fi
168
169 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
170
171 # See if the user has requested runtime debugging.
172 LIBGCJDEBUG="disable"
173 AC_SUBST(LIBGCJDEBUG)
174 AC_ARG_ENABLE(libgcj-debug,
175   AS_HELP_STRING([--enable-libgcj-debug],
176                  [enable runtime debugging code]),
177   [if test "$enable_libgcj_debug" = yes; then
178     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
179     LIBGCJDEBUG="enable"
180   fi])
181
182 AC_ARG_WITH([escher],
183          AS_HELP_STRING([--with-escher=ABS.PATH],
184                         [specify path to escher dir or JAR for X peers]))
185 case "$with_escher" in
186 "")
187         use_escher=false
188         ;;
189 "no")
190         use_escher=false
191         ;;
192 "yes")
193         AC_MSG_ERROR([Please supply an absolute path to Escher library])
194         ;;
195 *)
196         use_escher=true
197         ;;
198 esac
199
200 # Determine which AWT peer libraries to build
201 AC_ARG_ENABLE(java-awt,
202   AS_HELP_STRING([--enable-java-awt],
203                  [list of AWT peer implementations to be built]))
204
205 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
206 use_xlib_awt=""
207 use_gtk_awt=""
208 use_qt_awt=""
209 use_x_awt=""
210 # The default toolkit to use is the first one specified.
211 TOOLKIT=
212 AC_SUBST(TOOLKIT)
213
214 for peer in $peerlibs ; do
215   case $peer in
216     xlib)
217       if test "$no_x" = yes; then
218         echo "*** xlib peers requested but no X library available" 1>&2
219         exit 1
220       else
221         use_xlib_awt="yes"
222         if test -z "$TOOLKIT"; then
223            TOOLKIT=gnu.awt.xlib.XToolkit
224         fi
225       fi
226       ;;
227     gtk)
228       if test "$no_x" = yes; then
229          echo "*** gtk peers requested but no X library available" 1>&2
230          exit 1
231       else
232          use_gtk_awt=yes
233          if test -z "$TOOLKIT"; then
234             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
235          fi
236       fi
237       ;;
238     qt)
239       if test "$no_x" = yes; then
240          # Perhaps we should admit the possibility of embedded Qt.
241          echo "*** Qt peers requested but no X library available" 1>&2
242          exit 1
243       else
244          use_qt_awt=yes
245          if test -z "$TOOLKIT"; then
246             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
247          fi
248       fi
249       ;;
250     x)
251       use_x_awt=yes
252       if test -z "$TOOLKIT"; then
253          TOOLKIT=gnu.java.awt.peer.x.XToolkit
254       fi
255       ;;
256     no)
257       use_xlib_awt=
258       use_gtk_awt=
259       use_qt_awt=
260       use_x_awt=
261       break
262       ;;
263     *)
264       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
265       exit 1
266   esac
267 done
268
269 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
270 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
271
272 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
273
274 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
275
276 # Create standard.omit based on decisions we just made.
277 cp $srcdir/standard.omit.in standard.omit
278 if test "$use_xlib_awt" != yes; then
279    echo gnu/awt/xlib >> standard.omit
280    echo gnu/gcj/xlib >> standard.omit
281 fi
282 if test "$use_x_awt" != yes; then
283    echo gnu/java/awt/peer/x >> standard.omit
284 fi
285
286 if test -z "${with_multisubdir}"; then
287    builddotdot=.
288 else
289    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
290 fi
291
292 NATIVE=yes
293
294 # Which gcj and host gcj (for ecjx) do we use?
295 which_gcj=default
296 host_exeext=${ac_exeext}
297 GCJ_FOR_ECJX=
298 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
299 if test -n "${with_cross_host}"; then
300   # We are being configured with a cross compiler. We can't
301   # use ac_exeext, because that is for the target platform.
302   NATIVE=no
303   cross_host_exeext=
304   GCJ_FOR_ECJX="${with_cross_host}-gcj"
305   case "${with_cross_host}" in
306      *mingw* | *cygwin*)
307          cross_host_exeext=.exe
308      ;;
309   esac
310   host_exeext=${cross_host_exeext}
311   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
312      if test x"$build_noncanonical" = x"$with_cross_host"; then
313         # Ordinary cross (host!=target and host=build)
314         which_gcj=built
315      else
316         # Canadian cross (host!=target and host!=build)
317         which_gcj=cross
318      fi
319   else
320      which_gcj=cross
321   fi
322 else
323   # We are being configured with a native or crossed-native compiler
324   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
325      if test x"$build" = x"$host"; then
326         # True native build (host=target and host=build)
327         which_gcj=built
328      else
329         # Crossed-native build (host=target and host!=build)
330         which_gcj=cross
331      fi
332   else
333      which_gcj=path
334   fi
335 fi
336 case "${which_gcj}" in
337    built)
338       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
339       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
340    ;;
341    cross)
342       if test "x${with_newlib}" = "xyes"; then
343          # FIXME (comment): Why is this needed?
344          GCC_UNWIND_INCLUDE=
345          GCJ="${target_noncanonical}-gcj"
346       else
347          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
348       fi
349       GCJH="$built_gcc_dir/gcjh"
350    ;;
351    path)
352       GCJ="gcj -B`${PWDCMD-pwd}`/"
353       GCJH=gcjh
354    ;;
355 esac
356
357 AC_SUBST(GCJ_FOR_ECJX)
358 AC_SUBST(GCJH)
359 AC_SUBST(host_exeext)
360
361 # Create it, so that compile/link tests don't fail
362 test -f libgcj.spec || touch libgcj.spec
363
364
365
366 # Set up to configure Classpath.
367 # FIXME: no supported way to pass args in autoconf.
368 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
369 # Disable tool wrappers to avoid ltdl.h configure check.
370 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
371 ac_configure_args="$ac_configure_args --disable-load-library"
372 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
373 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
374 dir1=`cd $srcdir && pwd`
375 dir2=`pwd`
376 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
377 ac_configure_args="$ac_configure_args --disable-core-jni"
378 dnl FIXME?
379 ac_configure_args="$ac_configure_args --disable-examples"
380 ac_configure_args="$ac_configure_args --with-glibj=build"
381 if test "$plugin_enabled" != yes; then
382   ac_configure_args="$ac_configure_args --disable-plugin"
383 fi
384 if test "$gconf_enabled" != yes; then
385   ac_configure_args="$ac_configure_args --disable-gconf-peer"
386   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
387 fi
388 if test "$use_gtk_awt" != yes; then
389   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
390 fi
391 if test "$use_qt_awt" != yes; then
392   ac_configure_args="$ac_configure_args --disable-qt-peer"
393 else
394   # We need this as qt is disabled by default in classpath.
395   ac_configure_args="$ac_configure_args --enable-qt-peer"
396 fi
397 if test "$use_x_awt" != yes; then
398   ac_configure_args="$ac_configure_args --without-escher"
399 else
400   # We need this as escher is disabled by default in classpath.
401   if test "$use_escher" != true; then
402     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
403   else
404     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
405   fi
406 fi
407 # -Werror causes unavoidable problems in code using alsa.
408 ac_configure_args="$ac_configure_args --disable-Werror"
409 dnl --with-gcj=$GCJ
410 dnl --with-javah=$GCJH
411 dnl gjdoc?
412 dnl gtk-cairo -- just export here...
413 dnl --enable-regen-headers?
414
415 # Only use libltdl for non-newlib builds.
416 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
417    AC_LIBLTDL_CONVENIENCE
418    AC_LIBTOOL_DLOPEN
419    DIRLTDL=libltdl
420    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
421    # Sigh.  Libtool's macro doesn't do the right thing.
422    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
423    # FIXME: this is a hack.
424    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
425    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
426 fi
427 AC_SUBST(INCLTDL)
428 AC_SUBST(LIBLTDL)
429 AC_SUBST(DIRLTDL)
430 AC_PROG_LIBTOOL
431 AM_PROG_GCJ
432 AM_PROG_CC_C_O
433
434 AC_CONFIG_SUBDIRS(classpath libltdl)
435
436 # The -no-testsuite modules omit the test subdir.
437 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
438
439 # Should the runtime set system properties by examining the 
440 # environment variable GCJ_PROPERTIES?
441 AC_ARG_ENABLE(getenv-properties,
442   AS_HELP_STRING([--disable-getenv-properties],
443                  [don't set system properties from GCJ_PROPERTIES]))
444
445 # Whether GCJ_PROPERTIES is used depends on the target.
446 if test -z "$enable_getenv_properties"; then
447    enable_getenv_properties=${enable_getenv_properties_default-yes}
448 fi
449 if test "$enable_getenv_properties" = no; then
450    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
451      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
452 fi
453
454 # Whether we should use arguments to main()
455 if test -z "$enable_main_args"; then
456    enable_main_args=${enable_main_args_default-yes}
457 fi
458 if test "$enable_main_args" = no; then
459    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
460 fi
461
462
463 # Should we use hashtable-based synchronization?
464 # Currently works only for Linux X86/ia64
465 # Typically faster and more space-efficient
466 AC_ARG_ENABLE(hash-synchronization,
467   AS_HELP_STRING([--enable-hash-synchronization],
468                  [use global hash table for monitor locks]))
469
470 if test -z "$enable_hash_synchronization"; then
471    enable_hash_synchronization=$enable_hash_synchronization_default
472 fi
473
474
475 install_ecj_jar=no
476 ECJ_BUILD_JAR=
477 ECJ_JAR=
478 AC_ARG_WITH(ecj-jar,
479         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
480         [ECJ_JAR=$withval],
481         [if test -f $multi_basedir/ecj.jar; then
482            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
483            ECJ_JAR='$(jardir)/ecj.jar'
484            install_ecj_jar=yes
485          fi])
486 AC_SUBST(ECJ_BUILD_JAR)
487 AC_SUBST(ECJ_JAR)
488 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
489 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
490
491 AC_ARG_WITH(java-home,
492   AS_HELP_STRING([--with-java-home=DIRECTORY],
493                  [value of java.home system property]),
494                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
495 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
496 AC_SUBST(JAVA_HOME)
497
498 # What is the native OS API for MinGW?
499 AC_ARG_WITH(win32-nlsapi,
500   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
501                  [native MinGW libgcj Win32 OS API (default is ansi)]),
502 [case "${withval}" in
503   ansi) with_win32_nlsapi=ansi ;;
504   unicows) with_win32_nlsapi=unicows ;;
505   unicode) with_win32_nlsapi=unicode ;;
506   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
507 esac],[with_win32_nlsapi=ansi])
508
509 case "${with_win32_nlsapi}" in
510   unicows | unicode) 
511     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
512       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
513     ;;
514 esac
515
516 # configure.host sets slow_pthread_self if the synchronization code should 
517 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
518 if test "${slow_pthread_self}" = "yes"; then
519   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
520     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
521 fi
522
523 # Check for gc debugging.  This option is handled both here and in the GC.
524 AC_ARG_ENABLE(gc-debug,
525    AS_HELP_STRING([--enable-gc-debug],
526                   [include full support for pointer backtracing etc.]),
527 [ if test "$enable_gc_debug" = "yes"; then
528     AC_DEFINE(LIBGCJ_GC_DEBUG, 1, 
529               [Define if we want to use debug calls into the garbage collector.])
530   fi])
531
532 # See if the user has the interpreter included.
533 AC_ARG_ENABLE(interpreter,
534   AS_HELP_STRING([--enable-interpreter],
535                  [enable interpreter]),
536   [if test "$enable_interpreter" = yes; then
537     # This can also be set in configure.host.
538     libgcj_interpreter=yes
539   elif test "$enable_interpreter" = no; then
540     libgcj_interpreter=no
541   fi])
542
543 if test "$libgcj_interpreter" = yes; then
544    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
545 fi
546 INTERPRETER="$libgcj_interpreter"
547 AC_SUBST(INTERPRETER)
548
549 AC_MSG_CHECKING([for exception model to use])
550 AC_LANG_PUSH(C++)
551 AC_ARG_ENABLE(sjlj-exceptions,
552   AS_HELP_STRING([--enable-sjlj-exceptions],
553                  [force use of builtin_setjmp for exceptions]),
554 [:],
555 [dnl Botheration.  Now we've got to detect the exception model.
556 dnl Link tests against libgcc.a are problematic since -- at least
557 dnl as of this writing -- we've not been given proper -L bits for
558 dnl single-tree newlib and libgloss.
559 dnl
560 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
561 dnl conftest files before we got a change to grep them first.
562 cat > conftest.$ac_ext << EOF
563 [#]line __oline__ "configure"
564 struct S { ~S(); };
565 void bar();
566 void foo()
567 {
568   S s;
569   bar();
570 }
571 EOF
572 old_CXXFLAGS="$CXXFLAGS"  
573 CXXFLAGS=-S
574 if AC_TRY_EVAL(ac_compile); then
575   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
576     enable_sjlj_exceptions=yes
577   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
578     enable_sjlj_exceptions=no
579   fi
580 fi
581 CXXFLAGS="$old_CXXFLAGS"
582 rm -f conftest*])
583 if test x$enable_sjlj_exceptions = xyes; then
584   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
585         [Define if the compiler is configured for setjmp/longjmp exceptions.])
586   ac_exception_model_name=sjlj
587 elif test x$enable_sjlj_exceptions = xno; then
588   ac_exception_model_name="call frame"
589 else
590   AC_MSG_ERROR([unable to detect exception model])
591 fi
592 AC_LANG_POP(C++)
593 AC_MSG_RESULT($ac_exception_model_name)
594
595 # If we are non using SJLJ exceptions, and this host does not have support 
596 # for unwinding from a signal handler, enable checked dereferences and divides.
597 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
598   CHECKREFSPEC=-fcheck-references
599   DIVIDESPEC=-fuse-divide-subroutine
600   EXCEPTIONSPEC=
601 fi
602
603 # See if the user wants to disable java.net.  This is the mildly
604 # ugly way that we admit that target-side configuration sucks.
605 AC_ARG_ENABLE(java-net,
606   AS_HELP_STRING([--disable-java-net],
607                  [disable java.net]))
608
609 # Whether java.net is built by default can depend on the target.
610 if test -z "$enable_java_net"; then
611    enable_java_net=${enable_java_net_default-yes}
612 fi
613 if test "$enable_java_net" = no; then
614    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
615 fi
616
617 # See if the user wants to configure without libffi.  Some
618 # architectures don't support it, and default values are set in 
619 # configure.host.
620 AC_ARG_WITH(libffi,
621   AS_HELP_STRING([--without-libffi],
622                  [don't use libffi]),
623   [:],
624   [with_libffi=${with_libffi_default-yes}])
625
626 LIBFFI=
627 LIBFFIINCS=
628 if test "$with_libffi" != no; then
629    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
630    LIBFFI=../libffi/libffi_convenience.la
631    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
632 fi
633 AC_SUBST(LIBFFI)
634 AC_SUBST(LIBFFIINCS)
635
636 # See if the user wants to disable JVMPI support.
637 AC_ARG_ENABLE(jvmpi,
638   AS_HELP_STRING([--disable-jvmpi],
639                  [disable JVMPI support]))
640
641 if test "$enable_jvmpi" != no; then
642     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
643 fi
644
645 # If the target is an eCos system, use the appropriate eCos
646 # I/O routines.
647 # FIXME: this should not be a local option but a global target
648 # system; at present there is no eCos target.
649 TARGET_ECOS=${PROCESS-"no"}
650 AC_ARG_WITH(ecos,
651 [  --with-ecos             enable runtime eCos target support],
652 TARGET_ECOS="$with_ecos"
653 )
654
655 case "$TARGET_ECOS" in
656    no) case "$host" in
657       *mingw*)
658             PLATFORM=Win32
659             PLATFORMNET=Win32
660             PLATFORMH=win32.h
661         CHECK_FOR_BROKEN_MINGW_LD
662       ;;
663       *)
664             PLATFORM=Posix
665             PLATFORMNET=Posix
666             PLATFORMH=posix.h
667       ;;
668       esac
669       ;;
670    *)
671       PLATFORM=Ecos
672       PLATFORMNET=NoNet
673       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
674       PLATFORMH=posix.h
675       ;;
676 esac
677 AC_SUBST(PLATFORM)
678 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
679
680 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
681                                       [Define if you have int32_t and uint32_t.]))
682 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
683                                         [Define if you have int32_t and uint32_t.]))
684 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
685                                           [Define if you have u_int32_t]))
686 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
687                                            [Define if you have u_int32_t]))
688
689 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
690 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
691
692 case "$host" in
693   *-darwin*) DARWIN_CRT=true ;;
694   *) DARWIN_CRT=false ;;
695 esac
696 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
697
698 # These may not be defined in a non-ANS conformant embedded system.
699 # FIXME: Should these case a runtime exception in that case?
700 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
701                                   [Define is you have 'mktime' in <time.h>]))
702 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
703                                   [Define is you have 'localtime' in <time.h>]))
704
705 # Create the subdirectory for natFile.cc, or the attempt
706 # to create the link will fail.
707 test -d java || mkdir java
708 test -d java/io || mkdir java/io
709 test -d gnu || mkdir gnu
710 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
711
712 # Likewise for natConcreteProcess.cc.
713 test -d java/lang || mkdir java/lang
714 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
715
716 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
717 test -d java/net || mkdir java/net
718 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
719 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
720
721 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
722 test -d gnu/java || mkdir gnu/java
723 test -d gnu/java/net || mkdir gnu/java/net
724 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
725 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
726
727 # Likewise for natVMPipe.cc and natVMSelector.cc.
728 test -d gnu/java/nio || mkdir gnu/java/nio
729 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
730 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
731
732 # Likewise for natFileChannelImpl.cc
733 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
734 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
735
736 case "${host}" in
737     *mingw*)
738       SYSTEMSPEC="-lgdi32 -lws2_32"
739       if test "${with_win32_nlsapi}" = "unicows"; then
740         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
741       fi
742     ;;
743     *)
744       SYSTEMSPEC=
745     ;;
746 esac
747 AC_SUBST(SYSTEMSPEC)
748
749 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
750 AC_SUBST(LIBGCJTESTSPEC)
751
752 AC_ARG_WITH(system-zlib,
753   AS_HELP_STRING([--with-system-zlib],
754                  [use installed libz]))
755 ZLIBSPEC=
756 AC_SUBST(ZLIBSPEC)
757 ZLIBTESTSPEC=
758 AC_SUBST(ZLIBTESTSPEC)
759
760 AC_PATH_XTRA
761
762 # FIXME: this should be _libs on some hosts.
763 libsubdir=.libs
764
765 # extra LD Flags which are required for targets
766 case "${host}" in
767 *-*-darwin[[0-7]].*)
768     # For now we have to disable it on darwin[8-9] because it slows down
769     # the linking phase. A possible bug in ld?
770     # on Darwin -single_module speeds up loading of the dynamic libraries.
771     extra_ldflags_libjava=-Wl,-single_module
772     ;;
773 esac
774 AC_SUBST(extra_ldflags_libjava)
775
776 # Allow the GC to be disabled.  Can be useful when debugging.
777 AC_MSG_CHECKING([for garbage collector to use])
778 AC_ARG_ENABLE(java-gc,
779   AS_HELP_STRING([--enable-java-gc=TYPE],
780                  [choose garbage collector (default is boehm)]),
781   [GC=$enableval],
782   [GC=boehm])
783 GCLIBS=
784 GCINCS=
785 GCDEPS=
786 GCSPEC=
787 JC1GCSPEC=
788 GCTESTSPEC=
789 case "$GC" in
790  boehm)
791     AC_MSG_RESULT(boehm)
792     GCLIBS=../boehm-gc/libgcjgc_convenience.la
793     JC1GCSPEC='-fuse-boehm-gc'
794     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
795     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
796     GCOBJS=boehm.lo    
797     GCHDR=boehm-gc.h
798     # The POSIX thread support needs to know this.
799     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
800     ;;
801  no)
802     AC_MSG_RESULT(none)
803     GCHDR=no-gc.h
804     ;;
805  *)
806     AC_MSG_ERROR([unrecognized collector "$GC"])
807     ;;
808 esac
809 AC_SUBST(GCLIBS)
810 AC_SUBST(GCINCS)
811 AC_SUBST(GCDEPS)
812 AC_SUBST(GCSPEC)
813 AC_SUBST(JC1GCSPEC)
814 AC_SUBST(GCTESTSPEC)
815 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
816 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
817 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
818
819
820 AC_MSG_CHECKING([for thread model used by GCC])
821 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
822 AC_MSG_RESULT([$THREADS])
823
824 case "$THREADS" in
825  no | none | single)
826     THREADS=none
827     ;;
828  posix | posix95 | pthreads)
829     THREADS=posix
830     case "$host" in
831      *-*-linux*)
832         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
833         ;;
834     esac
835     ;;
836  win32)
837     ;;
838  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
839     AC_MSG_ERROR(thread package $THREADS not yet supported)
840     ;;
841  *)
842     AC_MSG_ERROR($THREADS is an unknown thread package)
843     ;;
844 esac
845
846 THREADCXXFLAGS=
847 THREADLDFLAGS=
848 THREADLIBS=
849 THREADINCS=
850 THREADDEPS=
851 THREADH=
852 THREADSPEC=
853 THREADSTARTFILESPEC=
854 case "$THREADS" in
855  posix)
856     case "$host" in
857      *-*-cygwin*)
858         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
859         ;;
860      *-*-freebsd[[1234]]*)
861         # Before FreeBSD 5, it didn't have -lpthread (or any library which
862         # merely adds pthread_* functions) but it does have a -pthread switch
863         # which is required at link-time to select -lc_r *instead* of -lc.
864         THREADLDFLAGS=-pthread
865         # Don't set THREADSPEC here as might be expected since -pthread is
866         # not processed when found within a spec file, it must come from
867         # the command line.  For now, the user must provide the -pthread
868         # switch to link code compiled with gcj.  In future, consider adding
869         # support for weak references to pthread_* functions ala gthr.h API.
870         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
871         ;;
872      *-*-freebsd*)
873         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
874         # systems which support threads and -lpthread.
875         THREADLDFLAGS=-pthread
876         THREADSPEC=-lpthread
877         ;;
878      alpha*-dec-osf* | hppa*-hp-hpux*)
879         THREADCXXFLAGS=-pthread
880         # boehm-gc needs some functions from librt, so link that too.
881         THREADLIBS='-lpthread -lrt'
882         THREADSPEC='-lpthread -lrt'
883         ;;
884      *)
885         THREADLIBS=-lpthread
886         THREADSPEC=-lpthread
887         ;;
888     esac
889     THREADH=posix-threads.h
890     # MIT pthreads doesn't seem to have the mutexattr functions.
891     # But for now we don't check for it.  We just assume you aren't
892     # using MIT pthreads.
893     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
894
895     # If we're using the Boehm GC, then we happen to know that it
896     # defines _REENTRANT, so we don't bother.  Eww.
897     if test "$GC" != boehm; then
898        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
899     fi
900     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
901     ;;
902
903  win32)
904     THREADH=win32-threads.h
905     THREADCXXFLAGS=-mthreads
906     # We need thread-safe exception handling so _CRT_MT should be set to 1.
907     # But we do not want the executables created to be dependent on
908     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
909     # exception handling contexts.  The following kludge achieves this effect
910     # and causes a dummy __mingwthr_key_dtor() to be linked in from
911     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
912     # A workaround is to explicitly use -mthreads while linking Java programs.
913     # See PR libgcj/28263.
914     #
915     # FIXME: In Java we are able to detect thread death at the end of
916     # Thread.run() so we should be able to clean up the exception handling
917     # contexts ourselves.
918     THREADSTARTFILESPEC='crtmt%O%s'
919     ;;
920
921  none)
922     THREADH=no-threads.h
923     ;;
924 esac
925 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
926 AC_SUBST(THREADLIBS)
927 AC_SUBST(THREADINCS)
928 AC_SUBST(THREADDEPS)
929 AC_SUBST(THREADSPEC)
930 AC_SUBST(THREADSTARTFILESPEC)
931 AC_SUBST(THREADLDFLAGS)
932 AC_SUBST(THREADCXXFLAGS)
933 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
934 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
935 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
936 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
937
938 if test -d sysdep; then true; else mkdir sysdep; fi
939 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
940 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
941 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
942
943 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
944 if test "$use_libgcj_bc" = yes; then
945   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
946 fi
947 AC_SUBST(LIBGCJ_SPEC)
948
949 HASH_SYNC_SPEC=
950 # Hash synchronization is only useful with posix threads right now.
951 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
952    HASH_SYNC_SPEC=-fhash-synchronization
953    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
954 fi
955 AC_SUBST(HASH_SYNC_SPEC)
956
957 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
958
959 # We're in the tree with gcc, and need to include some of its headers.
960 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
961
962 if test "x${with_newlib}" = "xyes"; then
963    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
964    # may not work correctly, because the compiler may not be able to
965    # link executables.
966
967    # We assume newlib.  This lets us hard-code the functions we know
968    # we'll have.
969    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
970    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
971    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
972    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
973    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
974    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
975    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
976    # This is only for POSIX threads.
977    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
978    # We also assume we are using gcc, which provides alloca.
979    AC_DEFINE(HAVE_ALLOCA)
980
981    # Assume we do not have getuid and friends.
982    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
983    PLATFORMNET=NoNet
984 else
985    AC_CHECK_FUNCS([strerror ioctl select fstat open fsync sleep opendir \
986                    gmtime_r localtime_r readdir_r getpwuid_r getcwd \
987                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
988                    nl_langinfo setlocale \
989                    inet_pton uname inet_ntoa \
990                    fork execvp pipe sigaction ftruncate mmap \
991                    getifaddrs])
992    AC_CHECK_FUNCS(inet_aton inet_addr, break)
993    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
994    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
995    AC_CHECK_LIB(dl, dladdr, [
996        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
997        AC_CHECK_LIB(dld, dladdr, [
998        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
999
1000    if test x"$cross_compiling" = x"no"; then
1001      AC_CHECK_FILES(/proc/self/exe, [
1002        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1003    else
1004      case $host in
1005      *-linux*)
1006        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1007        ;;
1008      esac
1009    fi
1010
1011    AM_ICONV
1012    AM_LC_MESSAGES
1013    AC_STRUCT_TIMEZONE
1014
1015    AC_CHECK_FUNCS(gethostbyname_r, [
1016      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1017        [Define if you have the 'gethostbyname_r' function.])
1018      # There are two different kinds of gethostbyname_r.
1019      # We look for the one that returns `int'.
1020      # Hopefully this check is robust enough.
1021      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1022        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1023
1024      case " $GCINCS " in
1025      *" -D_REENTRANT "*) ;;
1026      *)
1027         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1028         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1029         [libjava_cv_gethostbyname_r_needs_reentrant],
1030         [ AC_LANG_PUSH(C++)
1031           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1032             [[gethostbyname_r("", 0, 0);]])],
1033             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1034                 CPPFLAGS_SAVE="$CPPFLAGS"
1035                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1036                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1037                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1038                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1039                 CPPFLAGS="$CPPFLAGS_SAVE"
1040           ])
1041           AC_LANG_POP(C++)
1042         ])
1043         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1044           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1045         fi
1046      ;;
1047      esac
1048
1049      AC_CACHE_CHECK([for struct hostent_data],
1050         [libjava_cv_struct_hostent_data], [dnl
1051         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1052 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1053 # define _REENTRANT 1
1054 #endif
1055 #include <netdb.h>]], [[struct hostent_data data;]])],
1056           [libjava_cv_struct_hostent_data=yes],
1057           [libjava_cv_struct_hostent_data=no])])
1058      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1059        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1060          [Define if struct hostent_data is defined in netdb.h])
1061      fi
1062    ])
1063
1064    # FIXME: libjava source code expects to find a prototype for
1065    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1066    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1067    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1068    # linkage check is enough, yet C++ code requires proper prototypes.)
1069    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1070    AC_CHECK_FUNCS(gethostbyaddr_r, [
1071      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1072        [Define if you have the 'gethostbyaddr_r' function.])
1073      # There are two different kinds of gethostbyaddr_r.
1074      # We look for the one that returns `int'.
1075      # Hopefully this check is robust enough.
1076      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1077        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1078          [Define if gethostbyaddr_r returns 'int'.])])])])
1079
1080    AC_CHECK_FUNCS(gethostname, [
1081      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1082        [Define if you have the 'gethostname' function.])
1083      AC_EGREP_HEADER(gethostname, unistd.h, [
1084        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1085          [Define if gethostname is declared in <unistd.h>.])])])
1086
1087    AC_CHECK_FUNCS(usleep, [
1088      AC_EGREP_HEADER(usleep, unistd.h, [
1089        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1090           [Define if usleep is declared in <unistd.h>.])])])
1091
1092    # Look for these functions in the thread library, but only bother
1093    # if using POSIX threads.
1094    if test "$THREADS" = posix; then
1095       save_LIBS="$LIBS"
1096       LIBS="$LIBS $THREADLIBS"
1097       # Some POSIX thread systems don't have pthread_mutexattr_settype.
1098       # E.g., Solaris.
1099       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
1100
1101       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1102       # Solaris 7 the name librt is preferred.
1103       AC_CHECK_FUNCS(sched_yield, , [
1104         AC_CHECK_LIB(rt, sched_yield, [
1105           AC_DEFINE(HAVE_SCHED_YIELD)
1106           THREADLIBS="$THREADLIBS -lrt"
1107           THREADSPEC="$THREADSPEC -lrt"], [
1108           AC_CHECK_LIB(posix4, sched_yield, [
1109             AC_DEFINE(HAVE_SCHED_YIELD)
1110             THREADLIBS="$THREADLIBS -lposix4"
1111             THREADSPEC="$THREADSPEC -lposix4"])])])
1112
1113       AC_CHECK_LIB(rt, clock_gettime, [
1114          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1115          case "$THREADSPEC" in
1116            *-lrt*) ;;
1117            *)
1118              THREADSPEC="$THREADSPEC -lrt"
1119              THREADLIBS="$THREADLIBS -lrt"
1120              ;;
1121          esac])
1122
1123       LIBS="$save_LIBS"
1124
1125       # We can save a little space at runtime if the mutex has m_count
1126       # or __m_count.  This is a nice hack for Linux.
1127       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1128           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1129         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1130              [Define if pthread_mutex_t has m_count member.]), [
1131         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1132             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1133           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1134             [Define if pthread_mutex_t has __m_count member.]))])
1135    fi
1136
1137    # We require a way to get the time.
1138    time_found=no
1139    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1140    if test "$time_found" = no; then
1141       AC_MSG_ERROR([no function found to get the time])
1142    fi
1143
1144    AC_CHECK_FUNCS(memmove)
1145
1146    # We require memcpy.
1147    memcpy_found=no
1148    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1149    if test "$memcpy_found" = no; then
1150       AC_MSG_ERROR([memcpy is required])
1151    fi
1152    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1153    AC_CHECK_LIB(dl, dlopen, [
1154        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1155        AC_CHECK_LIB(dld, dlopen, [
1156        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1157
1158    # Some library-finding code we stole from Tcl.
1159    #--------------------------------------------------------------------
1160    #    Check for the existence of the -lsocket and -lnsl libraries.
1161    #    The order here is important, so that they end up in the right
1162    #    order in the command line generated by make.  Here are some
1163    #    special considerations:
1164    #    1. Use "connect" and "accept" to check for -lsocket, and
1165    #       "gethostbyname" to check for -lnsl.
1166    #    2. Use each function name only once:  can't redo a check because
1167    #       autoconf caches the results of the last check and won't redo it.
1168    #    3. Use -lnsl and -lsocket only if they supply procedures that
1169    #       aren't already present in the normal libraries.  This is because
1170    #       IRIX 5.2 has libraries, but they aren't needed and they're
1171    #       bogus:  they goof up name resolution if used.
1172    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1173    #       To get around this problem, check for both libraries together
1174    #       if -lsocket doesn't work by itself.
1175    #--------------------------------------------------------------------
1176
1177    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1178     [gcj_cv_lib_sockets=
1179      gcj_checkBoth=0
1180      unset ac_cv_func_connect
1181      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1182      if test "$gcj_checkSocket" = 1; then
1183          unset ac_cv_func_connect
1184          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1185                       gcj_checkBoth=1)
1186      fi
1187      if test "$gcj_checkBoth" = 1; then
1188          gcj_oldLibs=$LIBS
1189          LIBS="$LIBS -lsocket -lnsl"
1190          unset ac_cv_func_accept
1191          AC_CHECK_FUNC(accept,
1192                        [gcj_checkNsl=0
1193                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1194          unset ac_cv_func_accept
1195          LIBS=$gcj_oldLibs
1196      fi
1197      unset ac_cv_func_gethostbyname
1198      gcj_oldLibs=$LIBS
1199      LIBS="$LIBS $gcj_cv_lib_sockets"
1200      AC_CHECK_FUNC(gethostbyname, ,
1201                    [AC_CHECK_LIB(nsl, main,
1202                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1203      unset ac_cv_func_gethostbyname
1204      LIBS=$gcj_oldLIBS
1205    ])
1206    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1207
1208    if test "$with_system_zlib" = yes; then
1209       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1210    fi
1211
1212    # Test for Gtk stuff, if asked for.
1213    if test "$use_gtk_awt" = yes; then
1214       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1215       AC_SUBST(GTK_CFLAGS)
1216       AC_SUBST(GTK_LIBS)
1217
1218       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1219       AC_SUBST(GLIB_CFLAGS)
1220       AC_SUBST(GLIB_LIBS)
1221
1222       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1223       AC_SUBST(LIBART_CFLAGS)
1224       AC_SUBST(LIBART_LIBS)
1225
1226       # We require the XTest Extension to support java.awt.Robot.
1227       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1228                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1229                    [${X_LIBS}])
1230    fi
1231
1232    # On Solaris, and maybe other architectures, the Boehm collector
1233    # requires -ldl.
1234    if test "$GC" = boehm; then
1235       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1236    fi
1237 fi
1238
1239 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1240 case $build in
1241     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1242     *)         CLASSPATH_SEPARATOR=':' ;;
1243 esac
1244 AC_SUBST(CLASSPATH_SEPARATOR)
1245
1246 # We must search the source tree for java.lang, since we still don't
1247 # have libgcj.jar nor java/lang/*.class
1248 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1249 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1250
1251 # Since some classes depend on this one, we need its source available
1252 # before we can do any GCJ compilation test :-(
1253 if test ! -f gnu/classpath/Configuration.java; then
1254   test -d gnu || mkdir gnu
1255   test -d gnu/classpath || mkdir gnu/classpath
1256   # Note that it is not crucial that all the values here be correct.
1257   sed -e "s,@prefix@,$prefix," \
1258       -e "s,@VERSION@,$VERSION," \
1259       -e "s,@LIBDEBUG@,false," \
1260       -e "s,@INIT_LOAD_LIBRARY@,false," \
1261       -e "s,@@,$LIBGCJDEBUG," \
1262       -e "s,@default_toolkit@,$TOOLKIT," \
1263       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1264       -e "s,@GTK_CAIRO_ENABLED@,false," \
1265         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1266         > gnu/classpath/Configuration.java
1267   # We do not want to redirect the output of the grep below to /dev/null,
1268   # but we add /dev/null to the input list so that grep will print the
1269   # filename of Configuration.java in case it finds any matches.
1270   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1271     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1272   fi
1273 fi
1274
1275 LT_AC_PROG_GCJ
1276
1277 # Now remove it.
1278 rm -f gnu/classpath/Configuration.java
1279
1280 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1281
1282 AC_CHECK_SIZEOF(void *)
1283
1284 AC_C_BIGENDIAN
1285
1286 ZLIBS=
1287 SYS_ZLIBS=
1288 ZINCS=
1289
1290 if test -z "$ZLIBSPEC"; then
1291    # Use zlib from the GCC tree.
1292    ZINCS='-I$(top_srcdir)/../zlib'
1293    ZLIBS=../zlib/libzgcj_convenience.la
1294 else
1295    # System's zlib.
1296    SYS_ZLIBS="$ZLIBSPEC"
1297 fi
1298 AC_SUBST(ZLIBS)
1299 AC_SUBST(SYS_ZLIBS)
1300 AC_SUBST(ZINCS)
1301 AC_SUBST(DIVIDESPEC)
1302 AC_SUBST(CHECKREFSPEC)
1303 AC_SUBST(EXCEPTIONSPEC)
1304 AC_SUBST(BACKTRACESPEC)
1305 AC_SUBST(IEEESPEC)
1306
1307 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1308 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1309 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1310 AC_SUBST(GCC_UNWIND_INCLUDE)
1311
1312 # Process the option "--enable-version-specific-runtime-libs"
1313 # Calculate toolexeclibdir
1314 case ${version_specific_libs} in
1315   yes)
1316     # Need the gcc compiler version to know where to install libraries
1317     # and header files if --enable-version-specific-runtime-libs option
1318     # is selected.
1319     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1320     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1321     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1322     toolexeclibdir=$toolexecmainlibdir
1323     ;;
1324   no)
1325     if test -n "$with_cross_host" &&
1326        test x"$with_cross_host" != x"no"; then
1327       # Install a library built with a cross compiler in tooldir, not libdir.
1328       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1329       toolexecmainlibdir='$(toolexecdir)/lib'
1330     else
1331       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1332       toolexecmainlibdir='$(libdir)'
1333     fi
1334     multi_os_directory=`$CC -print-multi-os-directory`
1335     case $multi_os_directory in
1336       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1337       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1338     esac
1339     ;;
1340 esac
1341 AC_SUBST(toolexecdir)
1342 AC_SUBST(toolexecmainlibdir)
1343 AC_SUBST(toolexeclibdir)
1344
1345 # Determine where the standard .db file and GNU Classpath JNI
1346 # libraries are found.
1347 multi_os_directory=`$CC -print-multi-os-directory`
1348 case $multi_os_directory in
1349   .)
1350    dbexecdir='$(libdir)/gcj-$(gcc_version)' # Avoid /.
1351    ;;
1352   *)
1353    dbexecdir='$(libdir)/'$multi_os_directory'/gcj-$(gcc_version)'
1354    ;;
1355 esac
1356 AC_SUBST(dbexecdir)
1357
1358 # Determine gcj version number.
1359 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1360 GCJVERSION=$gcjversion
1361 AC_SUBST(GCJVERSION)
1362 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1363
1364 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1365 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1366
1367 TL_AC_GXX_INCLUDE_DIR
1368
1369 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1370 # On that system, sys/ioctl.h will not include sys/filio.h unless
1371 # BSD_COMP is defined; just including sys/filio.h is simpler.
1372 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1373 # for now.  If you change this, you also must update natFile.cc.
1374 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1375                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1376                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1377                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1378                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1379 AC_CHECK_HEADERS(inttypes.h, [
1380     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1381     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1382 ])
1383 AC_HEADER_SYS_WAIT
1384
1385 AC_CHECK_TYPE([ssize_t], [int])
1386
1387 AC_MSG_CHECKING([for in_addr_t])
1388 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1389 #if STDC_HEADERS
1390 #include <stdlib.h>
1391 #include <stddef.h>
1392 #endif
1393 #if HAVE_NETINET_IN_H
1394 #include <netinet/in.h>
1395 #endif]], [[in_addr_t foo;]])],
1396   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1397      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1398    AC_MSG_RESULT(yes)],
1399   [AC_MSG_RESULT(no)])
1400
1401 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1402 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1403   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1404      [Define if struct ip_mreq is defined in netinet/in.h.])
1405    AC_MSG_RESULT(yes)],
1406   [AC_MSG_RESULT(no)])
1407
1408 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1409 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1410   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1411      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1412    AC_MSG_RESULT(yes)],
1413   [AC_MSG_RESULT(no)])
1414
1415 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1416 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1417   [AC_DEFINE(HAVE_INET6, 1,
1418      [Define if inet6 structures are defined in netinet/in.h.])
1419    AC_MSG_RESULT(yes)],
1420   [AC_MSG_RESULT(no)])
1421
1422 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1423 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1424 #include <sys/types.h>
1425 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1426   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1427    AC_MSG_RESULT(yes)],
1428   [AC_MSG_RESULT(no)])
1429
1430 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1431 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1432   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1433    AC_MSG_RESULT(yes)],
1434   [AC_MSG_RESULT(no)
1435    AC_MSG_CHECKING([for global timezone variable])
1436    dnl FIXME: we don't want a link check here because that won't work
1437    dnl when cross-compiling.  So instead we make an assumption that
1438    dnl the header file will mention timezone if it exists.
1439    dnl Don't find the win32 function timezone
1440    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1441      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1442       AC_MSG_RESULT(yes)],
1443      [AC_MSG_RESULT(no)
1444        AC_MSG_CHECKING([for global _timezone variable])
1445        dnl FIXME: As above, don't want link check
1446        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1447          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1448             [Define if your platform has the global _timezone variable.])
1449           AC_MSG_RESULT(yes)],
1450           [AC_MSG_RESULT(no)])])])
1451
1452 AC_FUNC_ALLOCA
1453
1454 AC_CHECK_PROGS(PERL, perl, false)
1455
1456 SYSDEP_SOURCES=
1457 SIGNAL_HANDLER_AUX=
1458
1459 case "${host}" in
1460  i?86-*-linux*)
1461     SIGNAL_HANDLER=include/i386-signal.h
1462     ;;
1463  sparc*-sun-solaris*)
1464     SIGNAL_HANDLER=include/sparc-signal.h
1465     ;;
1466 # ia64-*)
1467 #    SYSDEP_SOURCES=sysdep/ia64.c
1468 #    test -d sysdep || mkdir sysdep
1469 #    ;;
1470  hppa*-*-linux*)
1471     SIGNAL_HANDLER=include/pa-signal.h
1472     ;;
1473  hppa*-hp-hpux*)
1474     SIGNAL_HANDLER=include/hppa-signal.h
1475     ;;
1476  ia64-*-linux*)
1477     SIGNAL_HANDLER=include/dwarf2-signal.h
1478     ;;
1479  powerpc*-*-linux*)
1480     SIGNAL_HANDLER=include/powerpc-signal.h
1481     ;;
1482  alpha*-*-linux*)
1483     SIGNAL_HANDLER=include/dwarf2-signal.h
1484     ;;
1485  s390*-*-linux*)
1486     SIGNAL_HANDLER=include/s390-signal.h
1487     ;;
1488  x86_64*-*-linux*)
1489     SIGNAL_HANDLER=include/x86_64-signal.h
1490     SIGNAL_HANDLER_AUX=include/i386-signal.h
1491     ;;
1492  sparc*-*-linux*)
1493     SIGNAL_HANDLER=include/dwarf2-signal.h
1494     ;;
1495  sh*-*-linux*)
1496     SIGNAL_HANDLER=include/sh-signal.h
1497     ;;
1498  *mingw*)
1499     SIGNAL_HANDLER=include/win32-signal.h
1500     ;;
1501  mips*-*-linux*)
1502     SIGNAL_HANDLER=include/mips-signal.h
1503     ;;
1504  powerpc*-*-darwin*)
1505     SIGNAL_HANDLER=include/darwin-signal.h
1506     ;;
1507  *)
1508     SIGNAL_HANDLER=include/default-signal.h
1509     ;;
1510 esac
1511
1512 # If we're using sjlj exceptions, forget what we just learned.
1513 if test "$enable_sjlj_exceptions" = yes; then
1514    SIGNAL_HANDLER=include/default-signal.h
1515    SIGNAL_HANDLER_AUX=
1516 fi
1517
1518 AC_SUBST(SYSDEP_SOURCES)
1519
1520 if test -z "$SIGNAL_HANDLER_AUX"; then
1521   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1522 fi
1523
1524 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1525                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1526
1527 if test "${multilib}" = "yes"; then
1528   multilib_arg="--enable-multilib"
1529 else
1530   multilib_arg=
1531 fi
1532
1533 # See if we support thread-local storage.
1534 GCC_CHECK_TLS
1535
1536 # For _Unwind_GetIPInfo.
1537 GCC_CHECK_UNWIND_GETIPINFO
1538
1539 # Check if linker supports static linking on a per library basis
1540 LD_START_STATIC_SPEC=
1541 LD_FINISH_STATIC_SPEC=
1542 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1543   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1544     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1545     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1546   fi
1547 fi
1548 AC_SUBST(LD_START_STATIC_SPEC)
1549 AC_SUBST(LD_FINISH_STATIC_SPEC)
1550
1551 here=`${PWDCMD-pwd}`
1552 AC_SUBST(here)
1553
1554 # We get this from the environment.
1555 AC_SUBST(GCJFLAGS)
1556
1557 AC_CONFIG_FILES([
1558 Makefile
1559 libgcj.pc
1560 libgcj.spec
1561 libgcj-test.spec
1562 gcj/Makefile
1563 include/Makefile
1564 testsuite/Makefile
1565 ])
1566
1567 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1568
1569 AC_CONFIG_COMMANDS([default],
1570 [# Only add multilib support code if we just rebuilt top-level Makefile.
1571 case " $CONFIG_FILES " in
1572  *" Makefile "*)
1573    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1574    ac_file=Makefile . ${multi_basedir}/./libjava/../config-ml.in
1575    ;;
1576 esac
1577 for ac_multi_file in $CONFIG_FILES; do
1578   case $ac_multi_file in
1579   */Makefile)
1580     grep "^MULTI[[^ ]]* =" Makefile >> "$ac_multi_file" ;;
1581   esac
1582 done
1583 ],
1584 srcdir=${srcdir}
1585 host=${host}
1586 target=${target}
1587 with_multisubdir=${with_multisubdir}
1588 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1589 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1590 multi_basedir=${multi_basedir}
1591 CC="${CC}"
1592 CXX="${CXX}"
1593 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1594 )
1595
1596 AC_OUTPUT