libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(plugin,
  59   AS_HELP_STRING([--enable-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) plugin_enabled=yes ;;
  63       no)  plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable plugin]);;
  65      esac],
  66     [plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_ENABLE(java-maintainer-mode,
  81         AS_HELP_STRING([--enable-java-maintainer-mode],
  82         [allow rebuilding of .class and .h files]))
  83 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
  99 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 100 save_CXXFLAGS="$CXXFLAGS"
 101 CXXFLAGS="$CXXFLAGS -fno-builtin"
 102 AC_PROG_CC
 103 AC_PROG_CXX
 104 CXXFLAGS="$save_CXXFLAGS"
 105 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 106 AC_SUBST(CFLAGS)
 107 AC_SUBST(CXXFLAGS)
 108 AC_SUBST(LDFLAGS)
 109
 110 AM_INIT_AUTOMAKE([1.9.0])
 111
 112 AC_CHECK_TOOL(AS, as)
 113 AC_CHECK_TOOL(LD, ld)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116 AC_PROG_AWK
 117 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 118 AC_PATH_PROG([ZIP], [zip], no)
 119 AC_PATH_PROG([UNZIP], [unzip], unzip)
 120
 121 # We need a jar that supports -@.  This is a GNU extension.
 122 if test "$JAR" != no; then
 123    rm -f config-test.jar
 124    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 125    if test -f config-test.jar; then
 126      rm -f config-test.jar
 127    else
 128      JAR=no
 129    fi
 130 fi
 131
 132 # Prefer the jar we found, but fall back to our jar script.
 133 if test "$JAR" = no; then
 134   if test "$ZIP" = no; then
 135     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 136   else
 137     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 138     JAR=`pwd`/scripts/jar
 139   fi
 140 fi
 141
 142 AC_PROG_INSTALL
 143
 144 AM_MAINTAINER_MODE
 145
 146 AC_EXEEXT
 147
 148 # configure.host sets the following important variables
 149 #       libgcj_cflags    - host specific C compiler flags
 150 #       libgcj_cxxflags  - host specific C++ compiler flags
 151 #       libgcj_javaflags - host specific Java compiler flags
 152
 153 libgcj_cflags=
 154 libgcj_cxxflags=
 155 libgcj_javaflags=
 156
 157 . ${srcdir}/configure.host
 158
 159 ACX_PROG_LD_GNU_SYMBOLIC
 160 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 161 if test -z "$libgcj_ld_symbolic"; then
 162   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 163 fi
 164
 165 LIBGCJ_CFLAGS="${libgcj_cflags}"
 166 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 167 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 168 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 169 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 170 AC_SUBST(LIBGCJ_CFLAGS)
 171 AC_SUBST(LIBGCJ_CXXFLAGS)
 172 AC_SUBST(LIBGCJ_JAVAFLAGS)
 173 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 174 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 175
 176 # Only use libltdl for non-newlib builds.
 177 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 178    AC_LTDL_SHLIBPATH
 179 fi
 180
 181 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 182
 183 # See if the user has requested runtime debugging.
 184 LIBGCJDEBUG="disable"
 185 AC_SUBST(LIBGCJDEBUG)
 186 AC_ARG_ENABLE(libgcj-debug,
 187   AS_HELP_STRING([--enable-libgcj-debug],
 188                  [enable runtime debugging code]),
 189   [if test "$enable_libgcj_debug" = yes; then
 190     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 191     LIBGCJDEBUG="enable"
 192   fi])
 193
 194 AC_ARG_WITH([escher],
 195          AS_HELP_STRING([--with-escher=ABS.PATH],
 196                         [specify path to escher dir or JAR for X peers]))
 197 case "$with_escher" in
 198 "")
 199         use_escher=false
 200         ;;
 201 "no")
 202         use_escher=false
 203         ;;
 204 "yes")
 205         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 206         ;;
 207 *)
 208         use_escher=true
 209         ;;
 210 esac
 211
 212 # Determine which AWT peer libraries to build
 213 AC_ARG_ENABLE(java-awt,
 214   AS_HELP_STRING([--enable-java-awt],
 215                  [list of AWT peer implementations to be built]))
 216
 217 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 218 use_xlib_awt=""
 219 use_gtk_awt=""
 220 use_qt_awt=""
 221 use_x_awt=""
 222 # The default toolkit to use is the first one specified.
 223 TOOLKIT=
 224 AC_SUBST(TOOLKIT)
 225
 226 for peer in $peerlibs ; do
 227   case $peer in
 228     xlib)
 229       if test "$no_x" = yes; then
 230         echo "*** xlib peers requested but no X library available" 1>&2
 231         exit 1
 232       else
 233         use_xlib_awt="yes"
 234         if test -z "$TOOLKIT"; then
 235            TOOLKIT=gnu.awt.xlib.XToolkit
 236         fi
 237       fi
 238       ;;
 239     gtk)
 240       if test "$no_x" = yes; then
 241          echo "*** gtk peers requested but no X library available" 1>&2
 242          exit 1
 243       else
 244          use_gtk_awt=yes
 245          if test -z "$TOOLKIT"; then
 246             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 247          fi
 248       fi
 249       ;;
 250     qt)
 251       if test "$no_x" = yes; then
 252          # Perhaps we should admit the possibility of embedded Qt.
 253          echo "*** Qt peers requested but no X library available" 1>&2
 254          exit 1
 255       else
 256          use_qt_awt=yes
 257          if test -z "$TOOLKIT"; then
 258             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 259          fi
 260       fi
 261       ;;
 262     x)
 263       use_x_awt=yes
 264       if test -z "$TOOLKIT"; then
 265          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 266       fi
 267       ;;
 268     no)
 269       use_xlib_awt=
 270       use_gtk_awt=
 271       use_qt_awt=
 272       use_x_awt=
 273       break
 274       ;;
 275     *)
 276       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 277       exit 1
 278   esac
 279 done
 280
 281 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 282 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 283
 284 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 285
 286 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 287
 288 # Create standard.omit based on decisions we just made.
 289 cp $srcdir/standard.omit.in standard.omit
 290 if test "$use_xlib_awt" != yes; then
 291    echo gnu/awt/xlib >> standard.omit
 292    echo gnu/gcj/xlib >> standard.omit
 293 fi
 294 if test "$use_x_awt" != yes; then
 295    echo gnu/java/awt/peer/x >> standard.omit
 296 fi
 297
 298 # Tools that need to be compiled against classpath's tools classes
 299 : > vm-tools-packages
 300 for package in gnu/gcj/tools/gc_analyze ; do
 301     echo $package >> standard.omit
 302     echo $package >> vm-tools-packages
 303 done
 304
 305 if test -z "${with_multisubdir}"; then
 306    builddotdot=.
 307 else
 308    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 309 fi
 310
 311 NATIVE=yes
 312
 313 # Which gcj and host gcj (for ecjx) do we use?
 314 which_gcj=default
 315 host_exeext=${ac_exeext}
 316 GCJ_FOR_ECJX=
 317 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 318 if test -n "${with_cross_host}"; then
 319   # We are being configured with a cross compiler. We can't
 320   # use ac_exeext, because that is for the target platform.
 321   NATIVE=no
 322   cross_host_exeext=
 323   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 324   case "${with_cross_host}" in
 325      *mingw* | *cygwin*)
 326          cross_host_exeext=.exe
 327      ;;
 328   esac
 329   host_exeext=${cross_host_exeext}
 330   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 331      if test x"$build_noncanonical" = x"$with_cross_host"; then
 332         # Ordinary cross (host!=target and host=build)
 333         which_gcj=built
 334      else
 335         # Canadian cross (host!=target and host!=build)
 336         which_gcj=cross
 337      fi
 338   else
 339      which_gcj=cross
 340   fi
 341 else
 342   # We are being configured with a native or crossed-native compiler
 343   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 344      if test x"$build" = x"$host"; then
 345         # True native build (host=target and host=build)
 346         which_gcj=built
 347      else
 348         # Crossed-native build (host=target and host!=build)
 349         which_gcj=cross
 350      fi
 351   else
 352      which_gcj=path
 353   fi
 354 fi
 355 case "${which_gcj}" in
 356    built)
 357       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
 358       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 359    ;;
 360    cross)
 361       if test "x${with_newlib}" = "xyes"; then
 362          # FIXME (comment): Why is this needed?
 363          GCC_UNWIND_INCLUDE=
 364          GCJ="${target_noncanonical}-gcj"
 365       else
 366          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
 367       fi
 368       GCJH='$(target_noncanonical)-gcjh'
 369    ;;
 370    path)
 371       GCJ="gcj -B`${PWDCMD-pwd}`/"
 372       GCJH=gcjh
 373    ;;
 374 esac
 375 JAVAC="$GCJ -C"
 376 export JAVAC
 377
 378 AC_SUBST(GCJ_FOR_ECJX)
 379 AC_SUBST(GCJH)
 380 AC_SUBST(host_exeext)
 381
 382 # Create it, so that compile/link tests don't fail
 383 test -f libgcj.spec || touch libgcj.spec
 384
 385
 386
 387 # Set up to configure Classpath.
 388 # FIXME: no supported way to pass args in autoconf.
 389 ac_configure_args="$ac_configure_args --with-fastjar=$JAR"
 390 # Disable tool wrappers to avoid ltdl.h configure check.
 391 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 392 ac_configure_args="$ac_configure_args --disable-load-library"
 393 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 394 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 395 dir1=`cd $srcdir && pwd`
 396 dir2=`pwd`
 397 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 398 ac_configure_args="$ac_configure_args --disable-core-jni"
 399 dnl FIXME?
 400 ac_configure_args="$ac_configure_args --disable-examples"
 401 ac_configure_args="$ac_configure_args --with-glibj=build"
 402 if test "$plugin_enabled" != yes; then
 403   ac_configure_args="$ac_configure_args --disable-plugin"
 404 fi
 405 if test "$gconf_enabled" != yes; then
 406   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 407   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 408 fi
 409 if test "$use_gtk_awt" != yes; then
 410   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 411 fi
 412 if test "$use_qt_awt" != yes; then
 413   ac_configure_args="$ac_configure_args --disable-qt-peer"
 414 else
 415   # We need this as qt is disabled by default in classpath.
 416   ac_configure_args="$ac_configure_args --enable-qt-peer"
 417 fi
 418 if test "$use_x_awt" != yes; then
 419   ac_configure_args="$ac_configure_args --without-escher"
 420 else
 421   # We need this as escher is disabled by default in classpath.
 422   if test "$use_escher" != true; then
 423     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 424   else
 425     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 426   fi
 427 fi
 428 # -Werror causes unavoidable problems in code using alsa.
 429 ac_configure_args="$ac_configure_args --disable-regen-headers"
 430 ac_configure_args="$ac_configure_args --disable-Werror"
 431 dnl --with-gcj=$GCJ
 432 dnl --with-javah=$GCJH
 433 dnl gjdoc?
 434 dnl gtk-cairo -- just export here...
 435 dnl --enable-regen-headers?
 436
 437 # Only use libltdl for non-newlib builds.
 438 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 439    AC_LIBLTDL_CONVENIENCE
 440    AC_LIBTOOL_DLOPEN
 441    DIRLTDL=libltdl
 442    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 443    # Sigh.  Libtool's macro doesn't do the right thing.
 444    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 445    # FIXME: this is a hack.
 446    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 447    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 448 fi
 449 AC_SUBST(INCLTDL)
 450 AC_SUBST(LIBLTDL)
 451 AC_SUBST(DIRLTDL)
 452 AC_PROG_LIBTOOL
 453 AM_PROG_GCJ
 454 AM_PROG_CC_C_O
 455
 456 AC_CONFIG_SUBDIRS(classpath libltdl)
 457
 458 # The -no-testsuite modules omit the test subdir.
 459 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 460
 461 # Should the runtime set system properties by examining the
 462 # environment variable GCJ_PROPERTIES?
 463 AC_ARG_ENABLE(getenv-properties,
 464   AS_HELP_STRING([--disable-getenv-properties],
 465                  [don't set system properties from GCJ_PROPERTIES]))
 466
 467 # Whether GCJ_PROPERTIES is used depends on the target.
 468 if test -z "$enable_getenv_properties"; then
 469    enable_getenv_properties=${enable_getenv_properties_default-yes}
 470 fi
 471 if test "$enable_getenv_properties" = no; then
 472    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 473      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 474 fi
 475
 476 # Whether we should use arguments to main()
 477 if test -z "$enable_main_args"; then
 478    enable_main_args=${enable_main_args_default-yes}
 479 fi
 480 if test "$enable_main_args" = no; then
 481    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 482 fi
 483
 484
 485 # Should we use hashtable-based synchronization?
 486 # Currently works only for Linux X86/ia64
 487 # Typically faster and more space-efficient
 488 AC_ARG_ENABLE(hash-synchronization,
 489   AS_HELP_STRING([--enable-hash-synchronization],
 490                  [use global hash table for monitor locks]))
 491
 492 if test -z "$enable_hash_synchronization"; then
 493    enable_hash_synchronization=$enable_hash_synchronization_default
 494 fi
 495
 496
 497 install_ecj_jar=no
 498 ECJ_BUILD_JAR=
 499 ECJ_JAR=
 500 AC_ARG_WITH(ecj-jar,
 501         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 502         [ECJ_JAR=$withval],
 503         [if test -f $multi_basedir/ecj.jar; then
 504            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 505            ECJ_JAR='$(jardir)/ecj.jar'
 506            install_ecj_jar=yes
 507          fi])
 508 AC_SUBST(ECJ_BUILD_JAR)
 509 AC_SUBST(ECJ_JAR)
 510 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 511 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 512
 513 AC_ARG_WITH(java-home,
 514   AS_HELP_STRING([--with-java-home=DIRECTORY],
 515                  [value of java.home system property]),
 516                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 517 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 518 AC_SUBST(JAVA_HOME)
 519
 520 suppress_libgcj_bc=no
 521 AC_ARG_ENABLE(libgcj-bc,
 522   AS_HELP_STRING([--enable-libgcj-bc],
 523                  [enable(default) or disable BC ABI for portions of libgcj]),
 524   [if test "$enable_libgcj_bc" = "no"; then
 525      suppress_libgcj_bc=yes
 526    fi])
 527 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 528
 529 # What is the native OS API for MinGW?
 530 AC_ARG_WITH(win32-nlsapi,
 531   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 532                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 533 [case "${withval}" in
 534   ansi) with_win32_nlsapi=ansi ;;
 535   unicows) with_win32_nlsapi=unicows ;;
 536   unicode) with_win32_nlsapi=unicode ;;
 537   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 538 esac],[with_win32_nlsapi=ansi])
 539
 540 case "${with_win32_nlsapi}" in
 541   unicows | unicode)
 542     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 543       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 544     ;;
 545 esac
 546
 547 # configure.host sets slow_pthread_self if the synchronization code should
 548 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 549 if test "${slow_pthread_self}" = "yes"; then
 550   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 551     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 552 fi
 553
 554 # Check for gc debugging.  This option is handled both here and in the GC.
 555 AC_ARG_ENABLE(gc-debug,
 556    AS_HELP_STRING([--enable-gc-debug],
 557                   [include full support for pointer backtracing etc.]),
 558 [ if test "$enable_gc_debug" = "yes"; then
 559     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 560               [Define if we want to use debug calls into the garbage collector.])
 561   fi])
 562
 563 # See if the user has the interpreter included.
 564 AC_ARG_ENABLE(interpreter,
 565   AS_HELP_STRING([--enable-interpreter],
 566                  [enable interpreter]),
 567   [if test "$enable_interpreter" = yes; then
 568     # This can also be set in configure.host.
 569     libgcj_interpreter=yes
 570   elif test "$enable_interpreter" = no; then
 571     libgcj_interpreter=no
 572   fi])
 573
 574 if test "$libgcj_interpreter" = yes; then
 575    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 576 fi
 577 INTERPRETER="$libgcj_interpreter"
 578 AC_SUBST(INTERPRETER)
 579 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 580
 581 AC_MSG_CHECKING([for exception model to use])
 582 AC_LANG_PUSH(C++)
 583 AC_ARG_ENABLE(sjlj-exceptions,
 584   AS_HELP_STRING([--enable-sjlj-exceptions],
 585                  [force use of builtin_setjmp for exceptions]),
 586 [:],
 587 [dnl Botheration.  Now we've got to detect the exception model.
 588 dnl Link tests against libgcc.a are problematic since -- at least
 589 dnl as of this writing -- we've not been given proper -L bits for
 590 dnl single-tree newlib and libgloss.
 591 dnl
 592 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 593 dnl conftest files before we got a change to grep them first.
 594 cat > conftest.$ac_ext << EOF
 595 [#]line __oline__ "configure"
 596 struct S { ~S(); };
 597 void bar();
 598 void foo()
 599 {
 600   S s;
 601   bar();
 602 }
 603 EOF
 604 old_CXXFLAGS="$CXXFLAGS"
 605 CXXFLAGS=-S
 606 if AC_TRY_EVAL(ac_compile); then
 607   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 608     enable_sjlj_exceptions=yes
 609   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 610     enable_sjlj_exceptions=no
 611   fi
 612 fi
 613 CXXFLAGS="$old_CXXFLAGS"
 614 rm -f conftest*])
 615 if test x$enable_sjlj_exceptions = xyes; then
 616   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 617         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 618   ac_exception_model_name=sjlj
 619 elif test x$enable_sjlj_exceptions = xno; then
 620   ac_exception_model_name="call frame"
 621 else
 622   AC_MSG_ERROR([unable to detect exception model])
 623 fi
 624 AC_LANG_POP(C++)
 625 AC_MSG_RESULT($ac_exception_model_name)
 626
 627 # If we are non using SJLJ exceptions, and this host does not have support
 628 # for unwinding from a signal handler, enable checked dereferences and divides.
 629 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 630   CHECKREFSPEC=-fcheck-references
 631   DIVIDESPEC=-fuse-divide-subroutine
 632   EXCEPTIONSPEC=
 633 fi
 634
 635 # See if the user wants to disable java.net.  This is the mildly
 636 # ugly way that we admit that target-side configuration sucks.
 637 AC_ARG_ENABLE(java-net,
 638   AS_HELP_STRING([--disable-java-net],
 639                  [disable java.net]))
 640
 641 # Whether java.net is built by default can depend on the target.
 642 if test -z "$enable_java_net"; then
 643    enable_java_net=${enable_java_net_default-yes}
 644 fi
 645 if test "$enable_java_net" = no; then
 646    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 647 fi
 648
 649 # See if the user wants to configure without libffi.  Some
 650 # architectures don't support it, and default values are set in
 651 # configure.host.
 652 AC_ARG_WITH(libffi,
 653   AS_HELP_STRING([--without-libffi],
 654                  [don't use libffi]),
 655   [:],
 656   [with_libffi=${with_libffi_default-yes}])
 657
 658 LIBFFI=
 659 LIBFFIINCS=
 660 if test "$with_libffi" != no; then
 661    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 662    LIBFFI=../libffi/libffi_convenience.la
 663    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 664 fi
 665 AC_SUBST(LIBFFI)
 666 AC_SUBST(LIBFFIINCS)
 667
 668 # See if the user wants to disable JVMPI support.
 669 AC_ARG_ENABLE(jvmpi,
 670   AS_HELP_STRING([--disable-jvmpi],
 671                  [disable JVMPI support]))
 672
 673 if test "$enable_jvmpi" != no; then
 674     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 675 fi
 676
 677 # If the target is an eCos system, use the appropriate eCos
 678 # I/O routines.
 679 # FIXME: this should not be a local option but a global target
 680 # system; at present there is no eCos target.
 681 TARGET_ECOS=${PROCESS-"no"}
 682 AC_ARG_WITH(ecos,
 683 [  --with-ecos             enable runtime eCos target support],
 684 TARGET_ECOS="$with_ecos"
 685 )
 686
 687 case "$TARGET_ECOS" in
 688    no) case "$host" in
 689       *mingw*)
 690             PLATFORM=Win32
 691             PLATFORMNET=Win32
 692             PLATFORMH=win32.h
 693         CHECK_FOR_BROKEN_MINGW_LD
 694       ;;
 695       *)
 696             PLATFORM=Posix
 697             PLATFORMNET=Posix
 698             PLATFORMH=posix.h
 699       ;;
 700       esac
 701       ;;
 702    *)
 703       PLATFORM=Ecos
 704       PLATFORMNET=NoNet
 705       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 706       PLATFORMH=posix.h
 707       ;;
 708 esac
 709 AC_SUBST(PLATFORM)
 710 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 711
 712 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 713                                       [Define if you have int32_t and uint32_t.]))
 714 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 715                                         [Define if you have int32_t and uint32_t.]))
 716 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 717                                           [Define if you have u_int32_t]))
 718 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 719                                            [Define if you have u_int32_t]))
 720
 721 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 722 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 723
 724 case "$host" in
 725   *-darwin*) DARWIN_CRT=true ;;
 726   *) DARWIN_CRT=false ;;
 727 esac
 728 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 729
 730 # This may not be defined in a non-ANS conformant embedded system.
 731 # FIXME: Should these case a runtime exception in that case?
 732 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 733                                   [Define is you have 'localtime' in <time.h>]))
 734
 735 # Create the subdirectory for natFile.cc, or the attempt
 736 # to create the link will fail.
 737 test -d java || mkdir java
 738 test -d java/io || mkdir java/io
 739 test -d gnu || mkdir gnu
 740 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 741
 742 # Likewise for natConcreteProcess.cc.
 743 test -d java/lang || mkdir java/lang
 744 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 745
 746 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 747 test -d java/net || mkdir java/net
 748 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 749 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 750
 751 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 752 test -d gnu/java || mkdir gnu/java
 753 test -d gnu/java/net || mkdir gnu/java/net
 754 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 755 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 756
 757 # Likewise for natVMPipe.cc and natVMSelector.cc.
 758 test -d gnu/java/nio || mkdir gnu/java/nio
 759 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 760 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 761
 762 # Likewise for natFileChannelImpl.cc
 763 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 764 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 765
 766 case "${host}" in
 767     *mingw*)
 768       SYSTEMSPEC="-lgdi32 -lws2_32"
 769       if test "${with_win32_nlsapi}" = "unicows"; then
 770         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 771       fi
 772     ;;
 773     *)
 774       SYSTEMSPEC=
 775     ;;
 776 esac
 777 AC_SUBST(SYSTEMSPEC)
 778
 779 AC_ARG_WITH(system-zlib,
 780   AS_HELP_STRING([--with-system-zlib],
 781                  [use installed libz]))
 782 ZLIBSPEC=
 783 AC_SUBST(ZLIBSPEC)
 784 ZLIBTESTSPEC=
 785 AC_SUBST(ZLIBTESTSPEC)
 786
 787 AC_PATH_XTRA
 788
 789 # FIXME: this should be _libs on some hosts.
 790 libsubdir=.libs
 791
 792 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 793
 794 LIBSTDCXXSPEC=
 795 # extra LD Flags which are required for targets
 796 case "${host}" in
 797 *-*-darwin[[0-7]].*)
 798     # For now we have to disable it on darwin[8-9] because it slows down
 799     # the linking phase. A possible bug in ld?
 800     # on Darwin -single_module speeds up loading of the dynamic libraries.
 801     extra_ldflags_libjava=-Wl,-single_module
 802     ;;
 803 *-*-darwin[[9]]*)
 804     extra_gij_ldflags=-Wl,-allow_stack_execute
 805     ;;
 806 arm*linux*eabi)
 807     # Some of the ARM unwinder code is actually in libstdc++.  We
 808     # could in principle replicate it in libgcj, but it's better to
 809     # have a dependency on libstdc++.
 810     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 811     LIBSTDCXXSPEC=-lstdc++
 812     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 813     ;;
 814 esac
 815 AC_SUBST(extra_ldflags_libjava)
 816 AC_SUBST(extra_gij_ldflags)
 817 AC_SUBST(extra_ldflags)
 818 AC_SUBST(LIBSTDCXXSPEC)
 819
 820 AC_SUBST(LIBGCJTESTSPEC)
 821
 822 # Allow the GC to be disabled.  Can be useful when debugging.
 823 AC_MSG_CHECKING([for garbage collector to use])
 824 AC_ARG_ENABLE(java-gc,
 825   AS_HELP_STRING([--enable-java-gc=TYPE],
 826                  [choose garbage collector (default is boehm)]),
 827   [GC=$enableval],
 828   [GC=boehm])
 829 GCLIBS=
 830 GCINCS=
 831 GCDEPS=
 832 GCSPEC=
 833 JC1GCSPEC=
 834 GCTESTSPEC=
 835 case "$GC" in
 836  boehm)
 837     AC_MSG_RESULT(boehm)
 838     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 839     JC1GCSPEC='-fuse-boehm-gc'
 840     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 841     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 842     GCOBJS=boehm.lo
 843     GCHDR=boehm-gc.h
 844     # The POSIX thread support needs to know this.
 845     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 846     ;;
 847  no)
 848     AC_MSG_RESULT(none)
 849     GCHDR=no-gc.h
 850     ;;
 851  *)
 852     AC_MSG_ERROR([unrecognized collector "$GC"])
 853     ;;
 854 esac
 855 AC_SUBST(GCLIBS)
 856 AC_SUBST(GCINCS)
 857 AC_SUBST(GCDEPS)
 858 AC_SUBST(GCSPEC)
 859 AC_SUBST(JC1GCSPEC)
 860 AC_SUBST(GCTESTSPEC)
 861 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 862 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 863 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 864
 865
 866 AC_MSG_CHECKING([for thread model used by GCC])
 867 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 868 AC_MSG_RESULT([$THREADS])
 869
 870 case "$THREADS" in
 871  no | none | single)
 872     THREADS=none
 873     ;;
 874  posix | posix95 | pthreads)
 875     THREADS=posix
 876     case "$host" in
 877      *-*-linux*)
 878         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 879         ;;
 880     esac
 881     ;;
 882  win32)
 883     ;;
 884  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 885     AC_MSG_ERROR(thread package $THREADS not yet supported)
 886     ;;
 887  *)
 888     AC_MSG_ERROR($THREADS is an unknown thread package)
 889     ;;
 890 esac
 891
 892 THREADCXXFLAGS=
 893 THREADLDFLAGS=
 894 THREADLIBS=
 895 THREADINCS=
 896 THREADDEPS=
 897 THREADH=
 898 THREADSPEC=
 899 THREADSTARTFILESPEC=
 900 case "$THREADS" in
 901  posix)
 902     case "$host" in
 903      *-*-cygwin*)
 904         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 905         ;;
 906      *-*-freebsd[[1234]]*)
 907         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 908         # merely adds pthread_* functions) but it does have a -pthread switch
 909         # which is required at link-time to select -lc_r *instead* of -lc.
 910         THREADLDFLAGS=-pthread
 911         # Don't set THREADSPEC here as might be expected since -pthread is
 912         # not processed when found within a spec file, it must come from
 913         # the command line.  For now, the user must provide the -pthread
 914         # switch to link code compiled with gcj.  In future, consider adding
 915         # support for weak references to pthread_* functions ala gthr.h API.
 916         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
 917         ;;
 918      *-*-freebsd*)
 919         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
 920         # systems which support threads and -lpthread.
 921         THREADLDFLAGS=-pthread
 922         THREADSPEC=-lpthread
 923         ;;
 924      alpha*-dec-osf* | hppa*-hp-hpux*)
 925         THREADCXXFLAGS=-pthread
 926         # boehm-gc needs some functions from librt, so link that too.
 927         THREADLIBS='-lpthread -lrt'
 928         THREADSPEC='-lpthread -lrt'
 929         ;;
 930      *)
 931         THREADLIBS=-lpthread
 932         THREADSPEC=-lpthread
 933         ;;
 934     esac
 935     THREADH=posix-threads.h
 936     # MIT pthreads doesn't seem to have the mutexattr functions.
 937     # But for now we don't check for it.  We just assume you aren't
 938     # using MIT pthreads.
 939     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 940
 941     # If we're using the Boehm GC, then we happen to know that it
 942     # defines _REENTRANT, so we don't bother.  Eww.
 943     if test "$GC" != boehm; then
 944        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 945     fi
 946     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 947     ;;
 948
 949  win32)
 950     THREADH=win32-threads.h
 951     THREADCXXFLAGS=-mthreads
 952     # We need thread-safe exception handling so _CRT_MT should be set to 1.
 953     # But we do not want the executables created to be dependent on
 954     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
 955     # exception handling contexts.  The following kludge achieves this effect
 956     # and causes a dummy __mingwthr_key_dtor() to be linked in from
 957     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
 958     # A workaround is to explicitly use -mthreads while linking Java programs.
 959     # See PR libgcj/28263.
 960     #
 961     # FIXME: In Java we are able to detect thread death at the end of
 962     # Thread.run() so we should be able to clean up the exception handling
 963     # contexts ourselves.
 964     THREADSTARTFILESPEC='crtmt%O%s'
 965     ;;
 966
 967  none)
 968     THREADH=no-threads.h
 969     ;;
 970 esac
 971 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 972 AC_SUBST(THREADLIBS)
 973 AC_SUBST(THREADINCS)
 974 AC_SUBST(THREADDEPS)
 975 AC_SUBST(THREADSPEC)
 976 AC_SUBST(THREADSTARTFILESPEC)
 977 AC_SUBST(THREADLDFLAGS)
 978 AC_SUBST(THREADCXXFLAGS)
 979 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 980 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 981 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 982 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
 983
 984 if test -d sysdep; then true; else mkdir sysdep; fi
 985 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 986 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
 987 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
 988
 989 LIBGCJ_SPEC="%{s-bc-abi:} -lgcj"
 990 if test "$use_libgcj_bc" = yes; then
 991   LIBGCJ_SPEC="%{s-bc-abi:-lgcj_bc;:-lgcj}"
 992 fi
 993 AC_SUBST(LIBGCJ_SPEC)
 994
 995 HASH_SYNC_SPEC=
 996 # Hash synchronization is only useful with posix threads right now.
 997 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 998    HASH_SYNC_SPEC=-fhash-synchronization
 999    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1000 fi
1001 AC_SUBST(HASH_SYNC_SPEC)
1002
1003 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1004
1005 # We're in the tree with gcc, and need to include some of its headers.
1006 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1007
1008 if test "x${with_newlib}" = "xyes"; then
1009    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1010    # may not work correctly, because the compiler may not be able to
1011    # link executables.
1012
1013    # We assume newlib.  This lets us hard-code the functions we know
1014    # we'll have.
1015    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1016    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1017    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1018    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1019    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1020    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1021    # This is only for POSIX threads.
1022    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1023
1024    # Assume we do not have getuid and friends.
1025    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1026    PLATFORMNET=NoNet
1027 else
1028    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1029                    localtime_r getpwuid_r getcwd \
1030                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1031                    nl_langinfo setlocale \
1032                    inet_pton uname inet_ntoa \
1033                    getrlimit sigaction ftruncate mmap \
1034                    getifaddrs])
1035    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1036    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1037    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1038    AC_CHECK_LIB(dl, dladdr, [
1039        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1040        AC_CHECK_LIB(dld, dladdr, [
1041        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1042
1043    if test x"$cross_compiling" = x"no"; then
1044      AC_CHECK_FILES(/proc/self/exe, [
1045        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1046      AC_CHECK_FILES(/proc/self/maps, [
1047        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1048          [Define if you have /proc/self/maps])])
1049    else
1050      case $host in
1051      *-linux*)
1052        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1053        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1054        ;;
1055      esac
1056    fi
1057
1058    AM_ICONV
1059    AM_LC_MESSAGES
1060    AC_STRUCT_TIMEZONE
1061
1062    AC_CHECK_FUNCS(gethostbyname_r, [
1063      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1064        [Define if you have the 'gethostbyname_r' function.])
1065      # There are two different kinds of gethostbyname_r.
1066      # We look for the one that returns `int'.
1067      # Hopefully this check is robust enough.
1068      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1069        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1070
1071      case " $GCINCS " in
1072      *" -D_REENTRANT "*) ;;
1073      *)
1074         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1075         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1076         [libjava_cv_gethostbyname_r_needs_reentrant],
1077         [ AC_LANG_PUSH(C++)
1078           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1079             [[gethostbyname_r("", 0, 0);]])],
1080             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1081                 CPPFLAGS_SAVE="$CPPFLAGS"
1082                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1083                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1084                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1085                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1086                 CPPFLAGS="$CPPFLAGS_SAVE"
1087           ])
1088           AC_LANG_POP(C++)
1089         ])
1090         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1091           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1092         fi
1093      ;;
1094      esac
1095
1096      AC_CACHE_CHECK([for struct hostent_data],
1097         [libjava_cv_struct_hostent_data], [dnl
1098         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1099 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1100 # define _REENTRANT 1
1101 #endif
1102 #include <netdb.h>]], [[struct hostent_data data;]])],
1103           [libjava_cv_struct_hostent_data=yes],
1104           [libjava_cv_struct_hostent_data=no])])
1105      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1106        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1107          [Define if struct hostent_data is defined in netdb.h])
1108      fi
1109    ])
1110
1111    # FIXME: libjava source code expects to find a prototype for
1112    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1113    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1114    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1115    # linkage check is enough, yet C++ code requires proper prototypes.)
1116    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1117    AC_CHECK_FUNCS(gethostbyaddr_r, [
1118      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1119        [Define if you have the 'gethostbyaddr_r' function.])
1120      # There are two different kinds of gethostbyaddr_r.
1121      # We look for the one that returns `int'.
1122      # Hopefully this check is robust enough.
1123      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1124        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1125          [Define if gethostbyaddr_r returns 'int'.])])])])
1126
1127    AC_CHECK_FUNCS(gethostname, [
1128      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1129        [Define if you have the 'gethostname' function.])
1130      AC_EGREP_HEADER(gethostname, unistd.h, [
1131        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1132          [Define if gethostname is declared in <unistd.h>.])])])
1133
1134    AC_CHECK_FUNCS(usleep, [
1135      AC_EGREP_HEADER(usleep, unistd.h, [
1136        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1137           [Define if usleep is declared in <unistd.h>.])])])
1138
1139    # Look for these functions in the thread library, but only bother
1140    # if using POSIX threads.
1141    if test "$THREADS" = posix; then
1142       save_LIBS="$LIBS"
1143       LIBS="$LIBS $THREADLIBS"
1144
1145       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1146       # Solaris 7 the name librt is preferred.
1147       AC_CHECK_FUNCS(sched_yield, , [
1148         AC_CHECK_LIB(rt, sched_yield, [
1149           AC_DEFINE(HAVE_SCHED_YIELD)
1150           THREADLIBS="$THREADLIBS -lrt"
1151           THREADSPEC="$THREADSPEC -lrt"], [
1152           AC_CHECK_LIB(posix4, sched_yield, [
1153             AC_DEFINE(HAVE_SCHED_YIELD)
1154             THREADLIBS="$THREADLIBS -lposix4"
1155             THREADSPEC="$THREADSPEC -lposix4"])])])
1156
1157       AC_CHECK_LIB(rt, clock_gettime, [
1158          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1159          case "$THREADSPEC" in
1160            *-lrt*) ;;
1161            *)
1162              THREADSPEC="$THREADSPEC -lrt"
1163              THREADLIBS="$THREADLIBS -lrt"
1164              ;;
1165          esac])
1166
1167       LIBS="$save_LIBS"
1168
1169       # We can save a little space at runtime if the mutex has m_count
1170       # or __m_count.  This is a nice hack for Linux.
1171       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1172           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1173         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1174              [Define if pthread_mutex_t has m_count member.]), [
1175         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1176             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1177           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1178             [Define if pthread_mutex_t has __m_count member.]))])
1179    fi
1180
1181    # We require a way to get the time.
1182    time_found=no
1183    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1184    if test "$time_found" = no; then
1185       AC_MSG_ERROR([no function found to get the time])
1186    fi
1187
1188    AC_CHECK_FUNCS(memmove)
1189
1190    # We require memcpy.
1191    memcpy_found=no
1192    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1193    if test "$memcpy_found" = no; then
1194       AC_MSG_ERROR([memcpy is required])
1195    fi
1196    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1197    AC_CHECK_LIB(dl, dlopen, [
1198        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1199        AC_CHECK_LIB(dld, dlopen, [
1200        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1201
1202    # Some library-finding code we stole from Tcl.
1203    #--------------------------------------------------------------------
1204    #    Check for the existence of the -lsocket and -lnsl libraries.
1205    #    The order here is important, so that they end up in the right
1206    #    order in the command line generated by make.  Here are some
1207    #    special considerations:
1208    #    1. Use "connect" and "accept" to check for -lsocket, and
1209    #       "gethostbyname" to check for -lnsl.
1210    #    2. Use each function name only once:  can't redo a check because
1211    #       autoconf caches the results of the last check and won't redo it.
1212    #    3. Use -lnsl and -lsocket only if they supply procedures that
1213    #       aren't already present in the normal libraries.  This is because
1214    #       IRIX 5.2 has libraries, but they aren't needed and they're
1215    #       bogus:  they goof up name resolution if used.
1216    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1217    #       To get around this problem, check for both libraries together
1218    #       if -lsocket doesn't work by itself.
1219    #--------------------------------------------------------------------
1220
1221    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1222     [gcj_cv_lib_sockets=
1223      gcj_checkBoth=0
1224      unset ac_cv_func_connect
1225      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1226      if test "$gcj_checkSocket" = 1; then
1227          unset ac_cv_func_connect
1228          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1229                       gcj_checkBoth=1)
1230      fi
1231      if test "$gcj_checkBoth" = 1; then
1232          gcj_oldLibs=$LIBS
1233          LIBS="$LIBS -lsocket -lnsl"
1234          unset ac_cv_func_accept
1235          AC_CHECK_FUNC(accept,
1236                        [gcj_checkNsl=0
1237                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1238          unset ac_cv_func_accept
1239          LIBS=$gcj_oldLibs
1240      fi
1241      unset ac_cv_func_gethostbyname
1242      gcj_oldLibs=$LIBS
1243      LIBS="$LIBS $gcj_cv_lib_sockets"
1244      AC_CHECK_FUNC(gethostbyname, ,
1245                    [AC_CHECK_LIB(nsl, main,
1246                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1247      unset ac_cv_func_gethostbyname
1248      LIBS=$gcj_oldLIBS
1249    ])
1250    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1251
1252    if test "$with_system_zlib" = yes; then
1253       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1254    fi
1255
1256    # Test for Gtk stuff, if asked for.
1257    if test "$use_gtk_awt" = yes; then
1258       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1259       AC_SUBST(GTK_CFLAGS)
1260       AC_SUBST(GTK_LIBS)
1261
1262       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1263       AC_SUBST(GLIB_CFLAGS)
1264       AC_SUBST(GLIB_LIBS)
1265
1266       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1267       AC_SUBST(LIBART_CFLAGS)
1268       AC_SUBST(LIBART_LIBS)
1269
1270       # We require the XTest Extension to support java.awt.Robot.
1271       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1272                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1273                    [${X_LIBS}])
1274    fi
1275
1276    # On Solaris, and maybe other architectures, the Boehm collector
1277    # requires -ldl.
1278    if test "$GC" = boehm; then
1279       case "${host}" in
1280           mips-sgi-irix6*)
1281             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1282             # libgcj.spec is used, so override here
1283             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1284           ;;
1285           *)
1286             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1287           ;;
1288       esac
1289    fi
1290 fi
1291
1292 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1293 case $build in
1294     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1295     *)         CLASSPATH_SEPARATOR=':' ;;
1296 esac
1297 AC_SUBST(CLASSPATH_SEPARATOR)
1298
1299 # We must search the source tree for java.lang, since we still don't
1300 # have libgcj.jar nor java/lang/*.class
1301 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1302 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1303
1304 # Since some classes depend on this one, we need its source available
1305 # before we can do any GCJ compilation test :-(
1306 if test ! -f gnu/classpath/Configuration.java; then
1307   test -d gnu || mkdir gnu
1308   test -d gnu/classpath || mkdir gnu/classpath
1309   # Note that it is not crucial that all the values here be correct.
1310   sed -e "s,@prefix@,$prefix," \
1311       -e "s,@VERSION@,$VERSION," \
1312       -e "s,@LIBDEBUG@,false," \
1313       -e "s,@INIT_LOAD_LIBRARY@,false," \
1314       -e "s,@@,$LIBGCJDEBUG," \
1315       -e "s,@default_toolkit@,$TOOLKIT," \
1316       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1317       -e "s,@GTK_CAIRO_ENABLED@,false," \
1318       -e "s,@ECJ_JAR@,," \
1319         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1320         > gnu/classpath/Configuration.java
1321   # We do not want to redirect the output of the grep below to /dev/null,
1322   # but we add /dev/null to the input list so that grep will print the
1323   # filename of Configuration.java in case it finds any matches.
1324   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1325     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1326   fi
1327 fi
1328
1329 LT_AC_PROG_GCJ
1330
1331 # Now remove it.
1332 rm -f gnu/classpath/Configuration.java
1333
1334 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1335
1336 AC_CHECK_SIZEOF(void *)
1337
1338 AC_C_BIGENDIAN
1339
1340 ZLIBS=
1341 SYS_ZLIBS=
1342 ZINCS=
1343
1344 if test -z "$ZLIBSPEC"; then
1345    # Use zlib from the GCC tree.
1346    ZINCS='-I$(top_srcdir)/../zlib'
1347    ZLIBS=../zlib/libzgcj_convenience.la
1348 else
1349    # System's zlib.
1350    SYS_ZLIBS="$ZLIBSPEC"
1351 fi
1352 AC_SUBST(ZLIBS)
1353 AC_SUBST(SYS_ZLIBS)
1354 AC_SUBST(ZINCS)
1355 AC_SUBST(DIVIDESPEC)
1356 AC_SUBST(CHECKREFSPEC)
1357 AC_SUBST(EXCEPTIONSPEC)
1358 AC_SUBST(BACKTRACESPEC)
1359 AC_SUBST(IEEESPEC)
1360
1361 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1362 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1363 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1364 AC_SUBST(GCC_UNWIND_INCLUDE)
1365
1366 # Process the option "--enable-version-specific-runtime-libs"
1367 # Calculate toolexeclibdir
1368 case ${version_specific_libs} in
1369   yes)
1370     # Need the gcc compiler version to know where to install libraries
1371     # and header files if --enable-version-specific-runtime-libs option
1372     # is selected.
1373     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1374     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1375     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1376     toolexeclibdir=$toolexecmainlibdir
1377     ;;
1378   no)
1379     if test -n "$with_cross_host" &&
1380        test x"$with_cross_host" != x"no"; then
1381       # Install a library built with a cross compiler in tooldir, not libdir.
1382       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1383       toolexecmainlibdir='$(toolexecdir)/lib'
1384     else
1385       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1386       toolexecmainlibdir='$(libdir)'
1387     fi
1388     multi_os_directory=`$CC -print-multi-os-directory`
1389     case $multi_os_directory in
1390       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1391       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1392     esac
1393     ;;
1394 esac
1395 AC_SUBST(toolexecdir)
1396 AC_SUBST(toolexecmainlibdir)
1397 AC_SUBST(toolexeclibdir)
1398
1399 # Determine gcj and libgcj version number.
1400 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1401 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1402 GCJVERSION=$gcjversion
1403 AC_SUBST(GCJVERSION)
1404 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1405
1406 # Determine where the standard .db file and GNU Classpath JNI
1407 # libraries are found.
1408 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1409 multi_os_directory=`$CC -print-multi-os-directory`
1410 case $multi_os_directory in
1411   .)
1412    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1413    ;;
1414   *)
1415    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1416    ;;
1417 esac
1418 AC_SUBST(dbexecdir)
1419 AC_SUBST(gcjsubdir)
1420
1421 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1422 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1423
1424 TL_AC_GXX_INCLUDE_DIR
1425
1426 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1427 # On that system, sys/ioctl.h will not include sys/filio.h unless
1428 # BSD_COMP is defined; just including sys/filio.h is simpler.
1429 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1430 # for now.  If you change this, you also must update natFile.cc.
1431 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1432                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1433                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1434                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1435                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1436 AC_CHECK_HEADERS(inttypes.h, [
1437     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1438     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1439 ])
1440
1441 AC_CHECK_TYPE([ssize_t], [int])
1442 AC_CHECK_TYPE([magic_t], [
1443     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1444 #ifdef HAVE_MAGIC_H
1445 #include <magic.h>
1446 #endif])
1447
1448 AC_MSG_CHECKING([for in_addr_t])
1449 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1450 #if STDC_HEADERS
1451 #include <stdlib.h>
1452 #include <stddef.h>
1453 #endif
1454 #if HAVE_NETINET_IN_H
1455 #include <netinet/in.h>
1456 #endif]], [[in_addr_t foo;]])],
1457   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1458      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1459    AC_MSG_RESULT(yes)],
1460   [AC_MSG_RESULT(no)])
1461
1462 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1463 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1464   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1465      [Define if struct ip_mreq is defined in netinet/in.h.])
1466    AC_MSG_RESULT(yes)],
1467   [AC_MSG_RESULT(no)])
1468
1469 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1470 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1471   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1472      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1473    AC_MSG_RESULT(yes)],
1474   [AC_MSG_RESULT(no)])
1475
1476 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1477 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1478   [AC_DEFINE(HAVE_INET6, 1,
1479      [Define if inet6 structures are defined in netinet/in.h.])
1480    AC_MSG_RESULT(yes)],
1481   [AC_MSG_RESULT(no)])
1482
1483 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1484 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1485 #include <sys/types.h>
1486 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1487   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1488    AC_MSG_RESULT(yes)],
1489   [AC_MSG_RESULT(no)])
1490
1491 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1492 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1493   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1494    AC_MSG_RESULT(yes)],
1495   [AC_MSG_RESULT(no)
1496    AC_MSG_CHECKING([for global timezone variable])
1497    dnl FIXME: we don't want a link check here because that won't work
1498    dnl when cross-compiling.  So instead we make an assumption that
1499    dnl the header file will mention timezone if it exists.
1500    dnl Don't find the win32 function timezone
1501    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1502      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1503       AC_MSG_RESULT(yes)],
1504      [AC_MSG_RESULT(no)
1505        AC_MSG_CHECKING([for global _timezone variable])
1506        dnl FIXME: As above, don't want link check
1507        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1508          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1509             [Define if your platform has the global _timezone variable.])
1510           AC_MSG_RESULT(yes)],
1511           [AC_MSG_RESULT(no)])])])
1512
1513 AC_CHECK_PROGS(PERL, perl, false)
1514
1515 SYSDEP_SOURCES=
1516 SIGNAL_HANDLER_AUX=
1517
1518 case "${host}" in
1519  i?86-*-linux*)
1520     SIGNAL_HANDLER=include/i386-signal.h
1521     ;;
1522  sparc*-sun-solaris*)
1523     SIGNAL_HANDLER=include/sparc-signal.h
1524     ;;
1525 # ia64-*)
1526 #    SYSDEP_SOURCES=sysdep/ia64.c
1527 #    test -d sysdep || mkdir sysdep
1528 #    ;;
1529  hppa*-*-linux*)
1530     SIGNAL_HANDLER=include/pa-signal.h
1531     ;;
1532  hppa*-hp-hpux*)
1533     SIGNAL_HANDLER=include/hppa-signal.h
1534     ;;
1535  ia64-*-linux*)
1536     SIGNAL_HANDLER=include/dwarf2-signal.h
1537     ;;
1538  powerpc*-*-linux*)
1539     SIGNAL_HANDLER=include/powerpc-signal.h
1540     ;;
1541  alpha*-*-linux*)
1542     SIGNAL_HANDLER=include/dwarf2-signal.h
1543     ;;
1544  s390*-*-linux*)
1545     SIGNAL_HANDLER=include/s390-signal.h
1546     ;;
1547  x86_64*-*-linux*)
1548     SIGNAL_HANDLER=include/x86_64-signal.h
1549     SIGNAL_HANDLER_AUX=include/i386-signal.h
1550     ;;
1551  sparc*-*-linux*)
1552     SIGNAL_HANDLER=include/dwarf2-signal.h
1553     ;;
1554  sh*-*-linux*)
1555     SIGNAL_HANDLER=include/sh-signal.h
1556     ;;
1557  *mingw*)
1558     SIGNAL_HANDLER=include/win32-signal.h
1559     ;;
1560  mips*-*-linux*)
1561     SIGNAL_HANDLER=include/mips-signal.h
1562     ;;
1563  m68*-*-linux*)
1564     SIGNAL_HANDLER=include/dwarf2-signal.h
1565     ;;
1566  powerpc*-*-darwin* | i?86-*-darwin9* | x86_64-*-darwin9*)
1567     SIGNAL_HANDLER=include/darwin-signal.h
1568     ;;
1569  *)
1570     SIGNAL_HANDLER=include/default-signal.h
1571     ;;
1572 esac
1573
1574 # If we're using sjlj exceptions, forget what we just learned.
1575 if test "$enable_sjlj_exceptions" = yes; then
1576    SIGNAL_HANDLER=include/default-signal.h
1577    SIGNAL_HANDLER_AUX=
1578 fi
1579
1580 AC_SUBST(SYSDEP_SOURCES)
1581
1582 if test -z "$SIGNAL_HANDLER_AUX"; then
1583   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1584 fi
1585
1586 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1587                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1588
1589 if test "${multilib}" = "yes"; then
1590   multilib_arg="--enable-multilib"
1591 else
1592   multilib_arg=
1593 fi
1594
1595 # See if we support thread-local storage.
1596 GCC_CHECK_TLS
1597
1598 # For _Unwind_GetIPInfo.
1599 GCC_CHECK_UNWIND_GETIPINFO
1600
1601 # See if linker supports anonymous version scripts.
1602 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1603   [libjava_cv_anon_version_script],
1604   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1605    libjava_cv_anon_version_script=no
1606    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1607    echo '{ global: globalsymb*; local: *; };' > conftest.map
1608    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1609                [libjava_cv_anon_version_script=yes], [])
1610    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1611   ])
1612 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1613
1614 # Check if linker supports static linking on a per library basis
1615 LD_START_STATIC_SPEC=
1616 LD_FINISH_STATIC_SPEC=
1617 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1618   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1619     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1620     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1621   fi
1622 fi
1623 AC_SUBST(LD_START_STATIC_SPEC)
1624 AC_SUBST(LD_FINISH_STATIC_SPEC)
1625
1626 here=`${PWDCMD-pwd}`
1627 AC_SUBST(here)
1628
1629 # We get this from the environment.
1630 AC_SUBST(GCJFLAGS)
1631
1632 AC_ARG_WITH([python-dir],
1633             AS_HELP_STRING([--with-python-dir],
1634                            [the location to install Python modules. This path should NOT include the prefix.]),
1635             [with_python_dir=$withval], [with_python_dir=""])
1636
1637 if test "x${with_python_dir}" = "x"
1638 then
1639   # Needed for installing Python modules during make install.
1640   python_mod_dir="\${prefix}/share/python"
1641   # Needed for substituting into aot-compile*
1642   python_mod_dir_expanded="${prefix}/share/python"
1643 else
1644   python_mod_dir="\${prefix}${with_python_dir}"
1645   python_mod_dir_expanded="${prefix}${with_python_dir}"
1646 fi
1647 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1648 AC_SUBST(python_mod_dir)
1649 AC_SUBST(python_mod_dir_expanded)
1650
1651 # needed for aot-compile-rpm
1652 MAKE=`which make`
1653 AC_SUBST(MAKE)
1654
1655 AC_ARG_ENABLE([aot-compile-rpm],
1656   [AS_HELP_STRING([--enable-aot-compile-rpm],
1657                  [enable installation of aot-compile-rpm [default=no]])],
1658   [case "${enableval}" in
1659     yes) AOT_RPM_ENABLED=yes ;;
1660     no)  AOT_RPM_ENABLED=no ;;
1661     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1662   esac],
1663   [AOT_RPM_ENABLED=no]
1664 )
1665 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" == xyes)
1666
1667 AC_ARG_ENABLE([java-home],
1668   [AS_HELP_STRING([--enable-java-home],
1669                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1670   [case "${enableval}" in
1671     yes) JAVA_HOME_ENABLED=yes ;;
1672     no)  JAVA_HOME_ENABLED=no ;;
1673     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1674   esac],
1675   [JAVA_HOME_ENABLED=no]
1676 )
1677 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" == xyes)
1678
1679 # Only do these checks if java-home above is enabled.
1680 if test "x${JAVA_HOME_ENABLED}" == xyes
1681 then
1682
1683   AC_ARG_WITH([gcc-suffix],
1684               AS_HELP_STRING([--with-gcc-suffix],
1685                              [the GCC tool suffix (defaults to empty string)]),
1686               [gcc_suffix=$withval], [gcc_suffix=""])
1687   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1688   AC_SUBST(gcc_suffix)
1689
1690   AC_ARG_WITH([arch-directory],
1691               AS_HELP_STRING([--with-arch-directory],
1692                              [the arch directory under jre/lib (defaults to auto-detect)]),
1693               [host_cpu=$withval], [host_cpu=""])
1694
1695   AC_ARG_WITH([os-directory],
1696               AS_HELP_STRING([--with-os-directory],
1697                              [the os directory under include (defaults to auto-detect)]),
1698               [host_os=$withval], [host_os=""])
1699
1700   AC_ARG_WITH([origin-name],
1701               AS_HELP_STRING([--with-origin-name],
1702                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1703               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1704   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1705
1706   AC_ARG_WITH([arch-suffix],
1707               AS_HELP_STRING([--with-arch-suffix],
1708                              [the arch directory suffix (default is the empty string]),
1709               [arch_suffix=$withval], [arch_suffix=""])
1710   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1711
1712   AC_ARG_WITH([jvm-root-dir],
1713               AS_HELP_STRING([--with-jvm-root-dir],
1714                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1715               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1716   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1717
1718   AC_ARG_WITH([jvm-jar-dir],
1719               AS_HELP_STRING([--with-jvm-jar-dir],
1720                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1721               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1722   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1723
1724   JAVA_VERSION=1.5.0
1725   BUILD_VERSION=0
1726   AC_SUBST(JAVA_VERSION)
1727   AC_SUBST(BUILD_VERSION)
1728   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1729
1730   jre_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}/jre
1731   sdk_dir=java-${JAVA_VERSION}-${origin_name}-${JAVA_VERSION}.${BUILD_VERSION}${arch_suffix}
1732   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1733   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1734
1735   JVM_ROOT_DIR=${jvm_root_dir}
1736   AC_SUBST(JVM_ROOT_DIR)
1737   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1738
1739   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1740   AC_SUBST(JVM_JAR_ROOT_DIR)
1741   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1742
1743   JVM_JAR_DIR=${jvm_jar_dir}/${sdk_dir}
1744   AC_SUBST(JVM_JAR_DIR)
1745   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1746
1747   JRE_DIR=${jre_dir}
1748   AC_SUBST(JRE_DIR)
1749
1750   SDK_DIR=${sdk_dir}
1751   AC_SUBST(SDK_DIR)
1752
1753   JRE_LNK=${jre_lnk}
1754   AC_SUBST(JRE_LNK)
1755
1756   SDK_LNK=${sdk_lnk}
1757   AC_SUBST(SDK_LNK)
1758
1759   SDK_BIN_DIR=${jvm_root_dir}/${sdk_dir}/bin
1760   AC_SUBST(SDK_BIN_DIR)
1761   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1762
1763   SDK_LIB_DIR=${jvm_root_dir}/${sdk_dir}/lib
1764   AC_SUBST(SDK_LIB_DIR)
1765   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1766
1767   SDK_INCLUDE_DIR=${jvm_root_dir}/${sdk_dir}/include
1768   AC_SUBST(SDK_INCLUDE_DIR)
1769   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1770
1771   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1772   AC_SUBST(JRE_BIN_DIR)
1773   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1774
1775   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1776   AC_SUBST(JRE_LIB_DIR)
1777   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1778
1779   # Find gcj prefix using gcj found in PATH.
1780   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1781
1782   # Where do the gcj binaries live?
1783   # For jhbuild based builds, they all live in a sibling of bin called
1784   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1785   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1786   AC_SUBST(GCJ_BIN_DIR)
1787   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1788
1789   echo host is ${host}
1790   if test "x${host_cpu}" = "x"
1791   then
1792     case ${host} in
1793       *-mingw* | *-cygwin*)
1794         host_cpu=x86;;
1795       i486-* | i586-* | i686-*)
1796         host_cpu=i386;;
1797       *)
1798         host_cpu=${host_cpu};;
1799     esac
1800   fi
1801   AC_MSG_RESULT(arch directory: ${host_cpu})
1802   CPU=${host_cpu}
1803   AC_SUBST(CPU)
1804
1805   if test "x${host_os}" = "x"
1806   then
1807     case ${host} in
1808       *-mingw* | *-cygwin*)
1809         host_os=win32;;
1810       *-linux*)
1811         host_os=linux;;
1812       *)
1813         host_os=${host_os};;
1814     esac
1815   fi
1816   echo os directory: ${host_os}
1817   OS=${host_os}
1818   AC_SUBST(OS)
1819
1820   # make an expanded $libdir, for substituting into
1821   # scripts (and other non-Makefile things).
1822   LIBDIR=$libdir
1823   if test "x${exec_prefix}" = "xNONE"
1824   then
1825       lib_exec_prefix=$prefix
1826   else
1827       lib_exec_prefix=$exec_prefix
1828   fi
1829   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1830   AC_SUBST(LIBDIR)
1831 fi
1832
1833 AC_CONFIG_FILES([
1834 Makefile
1835 libgcj.pc
1836 libgcj.spec
1837 libgcj-test.spec
1838 gcj/Makefile
1839 include/Makefile
1840 testsuite/Makefile
1841 contrib/aotcompile.py
1842 contrib/aot-compile
1843 contrib/aot-compile-rpm
1844 contrib/rebuild-gcj-db
1845 ])
1846
1847 if test ${multilib} = yes; then
1848   multilib_arg="--enable-multilib"
1849 else
1850   multilib_arg=
1851 fi
1852
1853 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1854 AC_OUTPUT