libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # For libstdc++-v3, -fno-builtin must be present here so that a
 146 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 147 # used in later tests.  This may not be necessary in libjava; I don't know.
 148 save_CXXFLAGS="$CXXFLAGS"
 149 CXXFLAGS="$CXXFLAGS -fno-builtin"
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 CXXFLAGS="$save_CXXFLAGS"
 153
 154 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 155
 156 AC_CHECK_TOOL(AS, as)
 157 AC_CHECK_TOOL(LD, ld)
 158 AC_CHECK_TOOL(AR, ar)
 159 AC_CHECK_TOOL(RANLIB, ranlib, :)
 160 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 161 AC_PROG_AWK
 162 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 163 AC_PATH_PROG([ZIP], [zip], no)
 164 AC_PATH_PROG([UNZIP], [unzip], unzip)
 165
 166 # We need a jar that supports -@.  This is a GNU extension.
 167 if test "$JAR" != no; then
 168    rm -f config-test.jar
 169    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar >/dev/null 2>&1
 170    if test -f config-test.jar; then
 171      rm -f config-test.jar
 172    else
 173      JAR=no
 174    fi
 175 fi
 176
 177 # Prefer the jar we found, but fall back to our jar script.
 178 if test "$JAR" = no; then
 179   if test "$ZIP" = no; then
 180     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 181   else
 182     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 183     JAR=`pwd`/scripts/jar
 184   fi
 185 fi
 186
 187 AC_PROG_INSTALL
 188
 189 AM_MAINTAINER_MODE
 190
 191 AC_EXEEXT
 192
 193 # configure.host sets the following important variables
 194 #       libgcj_cflags    - host specific C compiler flags
 195 #       libgcj_cxxflags  - host specific C++ compiler flags
 196 #       libgcj_javaflags - host specific Java compiler flags
 197 #       libgcj_sublib_ltflags - host specific Libtool flags
 198 #       libgcj_sublib_core_extra_deps - host specific extra
 199 #                          dependencies for core sublib
 200 #       (these last two only used when building sublibs)
 201 # and a number of others; see the list at the start of the file.
 202
 203 libgcj_cflags=
 204 libgcj_cxxflags=
 205 libgcj_javaflags=
 206 libgcj_sublib_ltflags=
 207 libgcj_sublib_core_extra_deps=
 208
 209 . ${srcdir}/configure.host
 210
 211 ACX_PROG_LD_GNU_SYMBOLIC
 212 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 213 if test -z "$libgcj_ld_symbolic"; then
 214   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 215 fi
 216
 217 # for windows native targets enforce export of all symbols for shared libgcj.
 218 libgcj_ld_export_all=
 219 case "$host" in
 220       *mingw*)
 221         libgcj_ld_export_all=-Wl,--export-all-symbols
 222         ;;
 223       *)
 224         ;;
 225 esac
 226
 227 LIBGCJ_CFLAGS="${libgcj_cflags}"
 228 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 229 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 230 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 231 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 232 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 233 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 234 LIBGCJ_LD_EXPORT_ALL="${libgcj_ld_export_all}"
 235 AC_SUBST(LIBGCJ_CFLAGS)
 236 AC_SUBST(LIBGCJ_CXXFLAGS)
 237 AC_SUBST(LIBGCJ_JAVAFLAGS)
 238 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 239 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 240 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 241 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 242 AC_SUBST(LIBGCJ_LD_EXPORT_ALL)
 243
 244 # Only use libltdl for non-newlib builds.
 245 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 246    AC_LTDL_SHLIBPATH
 247 fi
 248
 249 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 250
 251 # Possibly build libgcj as many sub-libraries.
 252 AC_ARG_ENABLE(libgcj-sublibs,
 253   AS_HELP_STRING([--enable-libgcj-sublibs],
 254                  [build libgcj as many sub-libraries]))
 255
 256 if test -z "$enable_libgcj_sublibs"; then
 257    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 258 fi
 259 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 260 if test "$enable_libgcj_sublibs" = yes ; then
 261   # In theory we could make do with only one override and simply
 262   # tag "_bc" onto the end of it when we use it to generate the
 263   # spec, but that's an ugly thing to do when there are multiple
 264   # words in the string and you're relying on the ordering to
 265   # append the correct one.
 266   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 267   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 268 fi
 269
 270
 271 # See if the user has requested runtime debugging.
 272 LIBGCJDEBUG="disable"
 273 AC_SUBST(LIBGCJDEBUG)
 274 AC_ARG_ENABLE(libgcj-debug,
 275   AS_HELP_STRING([--enable-libgcj-debug],
 276                  [enable runtime debugging code]),
 277   [if test "$enable_libgcj_debug" = yes; then
 278     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 279     LIBGCJDEBUG="enable"
 280   fi])
 281
 282 AC_ARG_WITH([escher],
 283          AS_HELP_STRING([--with-escher=ABS.PATH],
 284                         [specify path to escher dir or JAR for X peers]))
 285 case "$with_escher" in
 286 "")
 287         use_escher=false
 288         ;;
 289 "no")
 290         use_escher=false
 291         ;;
 292 "yes")
 293         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 294         ;;
 295 *)
 296         use_escher=true
 297         ;;
 298 esac
 299
 300 # Determine which AWT peer libraries to build
 301 AC_ARG_ENABLE(java-awt,
 302   AS_HELP_STRING([--enable-java-awt],
 303                  [list of AWT peer implementations to be built]))
 304
 305 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 306 use_xlib_awt=""
 307 use_gtk_awt=""
 308 use_qt_awt=""
 309 use_x_awt=""
 310 # The default toolkit to use is the first one specified.
 311 TOOLKIT=
 312 AC_SUBST(TOOLKIT)
 313
 314 for peer in $peerlibs ; do
 315   case $peer in
 316     xlib)
 317       if test "$no_x" = yes; then
 318         echo "*** xlib peers requested but no X library available" 1>&2
 319         exit 1
 320       else
 321         use_xlib_awt="yes"
 322         if test -z "$TOOLKIT"; then
 323            TOOLKIT=gnu.awt.xlib.XToolkit
 324         fi
 325       fi
 326       ;;
 327     gtk)
 328       if test "$no_x" = yes; then
 329          echo "*** gtk peers requested but no X library available" 1>&2
 330          exit 1
 331       else
 332          use_gtk_awt=yes
 333          if test -z "$TOOLKIT"; then
 334             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 335          fi
 336       fi
 337       ;;
 338     qt)
 339       if test "$no_x" = yes; then
 340          # Perhaps we should admit the possibility of embedded Qt.
 341          echo "*** Qt peers requested but no X library available" 1>&2
 342          exit 1
 343       else
 344          use_qt_awt=yes
 345          if test -z "$TOOLKIT"; then
 346             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 347          fi
 348       fi
 349       ;;
 350     x)
 351       use_x_awt=yes
 352       if test -z "$TOOLKIT"; then
 353          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 354       fi
 355       ;;
 356     no)
 357       use_xlib_awt=
 358       use_gtk_awt=
 359       use_qt_awt=
 360       use_x_awt=
 361       break
 362       ;;
 363     *)
 364       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 365       exit 1
 366   esac
 367 done
 368
 369 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 370 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 371
 372 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 373
 374 expanded_prefix=$prefix
 375 if test "X$prefix" = XNONE; then
 376   expanded_prefix=${ac_default_prefix}
 377 fi
 378
 379 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 380
 381 # Create standard.omit based on decisions we just made.
 382 cp $srcdir/standard.omit.in standard.omit
 383 if test "$use_xlib_awt" != yes; then
 384    echo gnu/awt/xlib >> standard.omit
 385    echo gnu/gcj/xlib >> standard.omit
 386 fi
 387 if test "$use_x_awt" != yes; then
 388    echo gnu/java/awt/peer/x >> standard.omit
 389 fi
 390
 391 # Tools that need to be compiled against classpath's tools classes
 392 : > vm-tools-packages
 393 for package in gnu/gcj/tools/gc_analyze ; do
 394     echo $package >> standard.omit
 395     echo $package >> vm-tools-packages
 396 done
 397
 398 if test -z "${with_multisubdir}"; then
 399    builddotdot=.
 400 else
 401    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 402 fi
 403
 404 NATIVE=yes
 405
 406 # Which gcj and host gcj (for ecjx) do we use?
 407 which_gcj=default
 408 host_exeext=${ac_exeext}
 409 GCJ_FOR_ECJX='$(GCJ)'
 410 GCC_FOR_ECJX='$(CXX)'
 411 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 412 if test -n "${with_cross_host}"; then
 413   # We are being configured with a cross compiler. We can't
 414   # use ac_exeext, because that is for the target platform.
 415   NATIVE=no
 416   cross_host_exeext=
 417   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 418   GCC_FOR_ECJX="${with_cross_host}-gcc"
 419   case "${with_cross_host}" in
 420      *mingw* | *cygwin*)
 421          cross_host_exeext=.exe
 422      ;;
 423   esac
 424   host_exeext=${cross_host_exeext}
 425   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 426      if test x"$build_noncanonical" = x"$with_cross_host"; then
 427         # Ordinary cross (host!=target and host=build)
 428         which_gcj=built
 429      else
 430         # Canadian cross (host!=target and host!=build)
 431         which_gcj=cross
 432      fi
 433   else
 434      which_gcj=cross
 435   fi
 436 else
 437   # We are being configured with a native or crossed-native compiler
 438   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 439      if test x"$build" = x"$host"; then
 440         # True native build (host=target and host=build)
 441         which_gcj=built
 442      else
 443         # Crossed-native build (host=target and host!=build)
 444         which_gcj=cross
 445      fi
 446   else
 447      which_gcj=path
 448   fi
 449 fi
 450 libgcjdir=`${PWDCMD-pwd}`
 451 case $GCJ in
 452 *" -B"*)
 453   # Just in case there is a comma in the build dir, quote it for the
 454   # sed command below.
 455   case $libgcjdir in
 456   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 457   *) qlibgcjdir=$libgcjdir;;
 458   esac
 459   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 460   ;;
 461 *)
 462   GCJ=$GCJ" -B$libgcjdir/"
 463   ;;
 464 esac
 465 case "${which_gcj}" in
 466    built)
 467       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 468    ;;
 469    cross)
 470       if test "x${with_newlib}" = "xyes"; then
 471          # FIXME (comment): Why is this needed?
 472          GCC_UNWIND_INCLUDE=
 473       fi
 474       GCJH='$(target_noncanonical)-gcjh'
 475    ;;
 476    path)
 477       GCJH=gcjh
 478    ;;
 479 esac
 480 JAVAC="$GCJ -C"
 481 export JAVAC
 482
 483 AC_SUBST(GCJ_FOR_ECJX)
 484 AC_SUBST(GCC_FOR_ECJX)
 485 AC_SUBST(GCJH)
 486 AC_SUBST(host_exeext)
 487
 488 # Create it, so that compile/link tests don't fail
 489 test -f libgcj.spec || touch libgcj.spec
 490
 491
 492
 493 # Set up to configure Classpath.
 494 # FIXME: no supported way to pass args in autoconf.
 495 # Disable tool wrappers to avoid ltdl.h configure check.
 496 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 497 ac_configure_args="$ac_configure_args --disable-load-library"
 498 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 499 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 500 dir1=`cd $srcdir && pwd`
 501 dir2=`pwd`
 502 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 503 ac_configure_args="$ac_configure_args --disable-core-jni"
 504 dnl FIXME?
 505 ac_configure_args="$ac_configure_args --disable-examples"
 506 ac_configure_args="$ac_configure_args --with-glibj=build"
 507 if test "$browser_plugin_enabled" != yes; then
 508   ac_configure_args="$ac_configure_args --disable-plugin"
 509 else
 510   ac_configure_args="$ac_configure_args --enable-plugin"
 511 fi
 512 if test "$gconf_enabled" != yes; then
 513   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 514   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 515 fi
 516 if test "$use_gtk_awt" != yes; then
 517   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 518 fi
 519 if test "$use_qt_awt" != yes; then
 520   ac_configure_args="$ac_configure_args --disable-qt-peer"
 521 else
 522   # We need this as qt is disabled by default in classpath.
 523   ac_configure_args="$ac_configure_args --enable-qt-peer"
 524 fi
 525 if test "$use_x_awt" != yes; then
 526   ac_configure_args="$ac_configure_args --without-escher"
 527 else
 528   # We need this as escher is disabled by default in classpath.
 529   if test "$use_escher" != true; then
 530     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 531   else
 532     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 533   fi
 534 fi
 535 if test "x$BUILD_GJDOC" = xno; then
 536   ac_configure_args="$ac_configure_args --disable-gjdoc"
 537 fi
 538 # -Werror causes unavoidable problems in code using alsa.
 539 ac_configure_args="$ac_configure_args --disable-regen-headers"
 540 ac_configure_args="$ac_configure_args --disable-Werror"
 541 dnl --with-gcj=$GCJ
 542 dnl --with-javah=$GCJH
 543 dnl gtk-cairo -- just export here...
 544 dnl --enable-regen-headers?
 545
 546 # Only use libltdl for non-newlib builds.
 547 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 548    AC_LIBLTDL_CONVENIENCE
 549    AC_LIBTOOL_DLOPEN
 550    DIRLTDL=libltdl
 551    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 552    # Sigh.  Libtool's macro doesn't do the right thing.
 553    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 554    # FIXME: this is a hack.
 555    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 556    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 557 fi
 558 AC_SUBST(INCLTDL)
 559 AC_SUBST(LIBLTDL)
 560 AC_SUBST(DIRLTDL)
 561 AC_PROG_LIBTOOL
 562 ACX_LT_HOST_FLAGS
 563 AM_PROG_GCJ
 564 AM_PROG_CC_C_O
 565
 566 AC_CONFIG_SUBDIRS(classpath libltdl)
 567
 568 # The -no-testsuite modules omit the test subdir.
 569 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 570
 571 # Should the runtime set system properties by examining the
 572 # environment variable GCJ_PROPERTIES?
 573 AC_ARG_ENABLE(getenv-properties,
 574   AS_HELP_STRING([--disable-getenv-properties],
 575                  [don't set system properties from GCJ_PROPERTIES]))
 576
 577 # Whether GCJ_PROPERTIES is used depends on the target.
 578 if test -z "$enable_getenv_properties"; then
 579    enable_getenv_properties=${enable_getenv_properties_default-yes}
 580 fi
 581 if test "$enable_getenv_properties" = no; then
 582    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 583      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 584 fi
 585
 586 # Whether we should use arguments to main()
 587 if test -z "$enable_main_args"; then
 588    enable_main_args=${enable_main_args_default-yes}
 589 fi
 590 if test "$enable_main_args" = no; then
 591    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 592 fi
 593
 594
 595 # Should we use hashtable-based synchronization?
 596 # Currently works only for Linux X86/ia64
 597 # Typically faster and more space-efficient
 598 AC_ARG_ENABLE(hash-synchronization,
 599   AS_HELP_STRING([--enable-hash-synchronization],
 600                  [use global hash table for monitor locks]))
 601
 602 if test -z "$enable_hash_synchronization"; then
 603    enable_hash_synchronization=$enable_hash_synchronization_default
 604 fi
 605
 606
 607 install_ecj_jar=no
 608 ECJ_BUILD_JAR=
 609 ECJ_JAR=
 610 AC_ARG_WITH(ecj-jar,
 611         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 612         [ECJ_JAR=$withval],
 613         [if test -f $multi_basedir/ecj.jar; then
 614            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 615            ECJ_JAR='$(jardir)/ecj.jar'
 616            install_ecj_jar=yes
 617          fi])
 618 AC_SUBST(ECJ_BUILD_JAR)
 619 AC_SUBST(ECJ_JAR)
 620 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 621 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 622
 623 AC_ARG_WITH(java-home,
 624   AS_HELP_STRING([--with-java-home=DIRECTORY],
 625                  [value of java.home system property]),
 626                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 627 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 628 AC_SUBST(JAVA_HOME)
 629
 630 suppress_libgcj_bc=no
 631 AC_ARG_ENABLE(libgcj-bc,
 632   AS_HELP_STRING([--enable-libgcj-bc],
 633                  [enable(default) or disable BC ABI for portions of libgcj]),
 634   [if test "$enable_libgcj_bc" = "no"; then
 635      suppress_libgcj_bc=yes
 636    fi])
 637 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 638
 639 build_libgcj_reduced_reflection=no
 640 AC_ARG_ENABLE(reduced-reflection,
 641   AS_HELP_STRING([--enable-reduced-reflection],
 642                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 643   [if test "$enable_reduced_reflection" = "yes"; then
 644      build_libgcj_reduced_reflection=yes
 645    fi])
 646 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 647
 648 # What is the native OS API for MinGW?
 649 AC_ARG_WITH(win32-nlsapi,
 650   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 651                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 652 [case "${withval}" in
 653   ansi) with_win32_nlsapi=ansi ;;
 654   unicows) with_win32_nlsapi=unicows ;;
 655   unicode) with_win32_nlsapi=unicode ;;
 656   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 657 esac],[with_win32_nlsapi=ansi])
 658
 659 case "${with_win32_nlsapi}" in
 660   unicows | unicode)
 661     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 662       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 663     ;;
 664 esac
 665
 666 # configure.host sets slow_pthread_self if the synchronization code should
 667 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 668 if test "${slow_pthread_self}" = "yes"; then
 669   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 670     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 671 fi
 672
 673 # Check for gc debugging.  This option is handled both here and in the GC.
 674 AC_ARG_ENABLE(gc-debug,
 675    AS_HELP_STRING([--enable-gc-debug],
 676                   [include full support for pointer backtracing etc.]),
 677 [ if test "$enable_gc_debug" = "yes"; then
 678     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 679               [Define if we want to use debug calls into the garbage collector.])
 680   fi])
 681
 682 # See if the user has the interpreter included.
 683 AC_ARG_ENABLE(interpreter,
 684   AS_HELP_STRING([--enable-interpreter],
 685                  [enable interpreter]),
 686   [if test "$enable_interpreter" = yes; then
 687     # This can also be set in configure.host.
 688     libgcj_interpreter=yes
 689   elif test "$enable_interpreter" = no; then
 690     libgcj_interpreter=no
 691   fi])
 692
 693 if test "$libgcj_interpreter" = yes; then
 694    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 695 fi
 696 INTERPRETER="$libgcj_interpreter"
 697 AC_SUBST(INTERPRETER)
 698 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 699
 700 AC_MSG_CHECKING([for exception model to use])
 701 AC_LANG_PUSH(C++)
 702 AC_ARG_ENABLE(sjlj-exceptions,
 703   AS_HELP_STRING([--enable-sjlj-exceptions],
 704                  [force use of builtin_setjmp for exceptions]),
 705 [:],
 706 [dnl Botheration.  Now we've got to detect the exception model.
 707 dnl Link tests against libgcc.a are problematic since -- at least
 708 dnl as of this writing -- we've not been given proper -L bits for
 709 dnl single-tree newlib and libgloss.
 710 dnl
 711 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 712 dnl conftest files before we got a change to grep them first.
 713 cat > conftest.$ac_ext << EOF
 714 [#]line __oline__ "configure"
 715 struct S { ~S(); };
 716 void bar();
 717 void foo()
 718 {
 719   S s;
 720   bar();
 721 }
 722 EOF
 723 old_CXXFLAGS="$CXXFLAGS"
 724 CXXFLAGS=-S
 725 if AC_TRY_EVAL(ac_compile); then
 726   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 727     enable_sjlj_exceptions=yes
 728   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 729     enable_sjlj_exceptions=no
 730   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 731     # ARM EH ABI.
 732     enable_sjlj_exceptions=no
 733   fi
 734 fi
 735 CXXFLAGS="$old_CXXFLAGS"
 736 rm -f conftest*])
 737 if test x$enable_sjlj_exceptions = xyes; then
 738   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 739         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 740   ac_exception_model_name=sjlj
 741 elif test x$enable_sjlj_exceptions = xno; then
 742   ac_exception_model_name="call frame"
 743 else
 744   AC_MSG_ERROR([unable to detect exception model])
 745 fi
 746 AC_LANG_POP(C++)
 747 AC_MSG_RESULT($ac_exception_model_name)
 748
 749 # If we are non using SJLJ exceptions, and this host does not have support
 750 # for unwinding from a signal handler, enable checked dereferences and divides.
 751 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 752   CHECKREFSPEC=-fcheck-references
 753   DIVIDESPEC=-fuse-divide-subroutine
 754   EXCEPTIONSPEC=
 755 fi
 756
 757 # See if the user wants to disable java.net.  This is the mildly
 758 # ugly way that we admit that target-side configuration sucks.
 759 AC_ARG_ENABLE(java-net,
 760   AS_HELP_STRING([--disable-java-net],
 761                  [disable java.net]))
 762
 763 # Whether java.net is built by default can depend on the target.
 764 if test -z "$enable_java_net"; then
 765    enable_java_net=${enable_java_net_default-yes}
 766 fi
 767 if test "$enable_java_net" = no; then
 768    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 769 fi
 770
 771 # See if the user wants to configure without libffi.  Some
 772 # architectures don't support it, and default values are set in
 773 # configure.host.
 774 AC_ARG_WITH(libffi,
 775   AS_HELP_STRING([--without-libffi],
 776                  [don't use libffi]),
 777   [:],
 778   [with_libffi=${with_libffi_default-yes}])
 779
 780 LIBFFI=
 781 LIBFFIINCS=
 782 if test "$with_libffi" != no; then
 783    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 784    LIBFFI=../libffi/libffi_convenience.la
 785    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 786 fi
 787 AC_SUBST(LIBFFI)
 788 AC_SUBST(LIBFFIINCS)
 789
 790 # See if the user wants to disable JVMPI support.
 791 AC_ARG_ENABLE(jvmpi,
 792   AS_HELP_STRING([--disable-jvmpi],
 793                  [disable JVMPI support]))
 794
 795 if test "$enable_jvmpi" != no; then
 796     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 797 fi
 798
 799 # If the target is an eCos system, use the appropriate eCos
 800 # I/O routines.
 801 # FIXME: this should not be a local option but a global target
 802 # system; at present there is no eCos target.
 803 TARGET_ECOS=${PROCESS-"no"}
 804 AC_ARG_WITH(ecos,
 805 [  --with-ecos             enable runtime eCos target support],
 806 TARGET_ECOS="$with_ecos"
 807 )
 808
 809 case "$TARGET_ECOS" in
 810    no) case "$host" in
 811       *mingw*)
 812             PLATFORM=Win32
 813             PLATFORMNET=Win32
 814             PLATFORMH=win32.h
 815         CHECK_FOR_BROKEN_MINGW_LD
 816       ;;
 817       *)
 818             PLATFORM=Posix
 819             PLATFORMNET=Posix
 820             PLATFORMH=posix.h
 821       ;;
 822       esac
 823       ;;
 824    *)
 825       PLATFORM=Ecos
 826       PLATFORMNET=NoNet
 827       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 828       PLATFORMH=posix.h
 829       ;;
 830 esac
 831 AC_SUBST(PLATFORM)
 832 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 833
 834 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 835                                       [Define if you have int32_t and uint32_t.]))
 836 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 837                                         [Define if you have int32_t and uint32_t.]))
 838 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 839                                           [Define if you have u_int32_t]))
 840 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 841                                            [Define if you have u_int32_t]))
 842
 843 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 844 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 845
 846 case "$host" in
 847   *-darwin*) DARWIN_CRT=true ;;
 848   *) DARWIN_CRT=false ;;
 849 esac
 850 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 851
 852 # This may not be defined in a non-ANS conformant embedded system.
 853 # FIXME: Should these case a runtime exception in that case?
 854 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 855                                   [Define is you have 'localtime' in <time.h>]))
 856
 857 # Create the subdirectory for natFile.cc, or the attempt
 858 # to create the link will fail.
 859 test -d java || mkdir java
 860 test -d java/io || mkdir java/io
 861 test -d gnu || mkdir gnu
 862 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 863
 864 # Likewise for natConcreteProcess.cc.
 865 test -d java/lang || mkdir java/lang
 866 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 867
 868 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 869 test -d java/net || mkdir java/net
 870 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 871 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 872
 873 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 874 test -d gnu/java || mkdir gnu/java
 875 test -d gnu/java/net || mkdir gnu/java/net
 876 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 877 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 878
 879 # Likewise for natVMPipe.cc and natVMSelector.cc.
 880 test -d gnu/java/nio || mkdir gnu/java/nio
 881 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 882 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 883
 884 # Likewise for natFileChannelImpl.cc
 885 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 886 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 887
 888 # Likewise for natVMSecureRandom.cc
 889 test -d gnu/java/security || mkdir gnu/java/security
 890 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 891 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 892 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 893
 894 case "${host}" in
 895     *mingw*)
 896       SYSTEMSPEC="-lgdi32 -lws2_32"
 897       if test "${with_win32_nlsapi}" = "unicows"; then
 898         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 899       fi
 900     ;;
 901     *-*-darwin[[912]]*)
 902       SYSTEMSPEC="%{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 903     ;;
 904     *)
 905       SYSTEMSPEC=
 906     ;;
 907 esac
 908 AC_SUBST(SYSTEMSPEC)
 909
 910 AC_ARG_WITH(system-zlib,
 911   AS_HELP_STRING([--with-system-zlib],
 912                  [use installed libz]))
 913 ZLIBSPEC=
 914 AC_SUBST(ZLIBSPEC)
 915 ZLIBTESTSPEC=
 916 AC_SUBST(ZLIBTESTSPEC)
 917
 918 AC_PATH_XTRA
 919
 920 # FIXME: this should be _libs on some hosts.
 921 libsubdir=.libs
 922
 923 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 924
 925 LIBSTDCXXSPEC=
 926 # extra LD Flags which are required for targets
 927 case "${host}" in
 928 *-*-darwin[[0-7]].*)
 929     # For now we have to disable it on darwin[8-9] because it slows down
 930     # the linking phase. A possible bug in ld?
 931     # on Darwin -single_module speeds up loading of the dynamic libraries.
 932     extra_ldflags_libjava=-Wl,-single_module
 933     ;;
 934 arm*linux*eabi)
 935     # Some of the ARM unwinder code is actually in libstdc++.  We
 936     # could in principle replicate it in libgcj, but it's better to
 937     # have a dependency on libstdc++.
 938     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 939     LIBSTDCXXSPEC=-lstdc++
 940     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 941     ;;
 942 *-*-cygwin)
 943     extra_ldflags_libjava=-liconv
 944     ;;
 945 *-*-mingw*)
 946     extra_ldflags_libjava=-lws2_32
 947     ;;
 948 esac
 949
 950 LIBMATHSPEC=
 951 # extra LD Flags which are required for targets
 952 case "${host}" in
 953 *-*-darwin*)
 954      ;;
 955 *)
 956      LIBMATHSPEC=-lm
 957      ;;
 958 esac
 959
 960 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 961 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 962   [saved_ldflags="$LDFLAGS"
 963    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 964    # The IRIX 6 ld doesn't recognize --no-merge-exidx-entries, but only
 965    # warns about unknown options, which breaks the testsuite.  So enable
 966    # AC_LANG_WERROR, but there's currently (autoconf 2.64) no way to turn
 967    # it off again.  As a workaround, save and restore werror flag like
 968    # AC_PATH_XTRA.
 969    ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag=$ac_[]_AC_LANG_ABBREV[]_werror_flag
 970    AC_LANG_WERROR
 971    AC_LINK_IFELSE([int main(void){ return 0;} ],
 972                       [eval "libgcj_cv_exidx=yes"],
 973                       [eval "libgcj_cv_exidx=no"])
 974    ac_[]_AC_LANG_ABBREV[]_werror_flag=$ac_xsave_[]_AC_LANG_ABBREV[]_werror_flag
 975    LDFLAGS="${saved_ldflags}"]
 976 )
 977 if test "${libgcj_cv_exidx}" = "yes"; then
 978   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 979   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 980 fi
 981
 982 AC_SUBST(extra_ldflags_libjava)
 983 AC_SUBST(extra_ldflags)
 984 AC_SUBST(LIBSTDCXXSPEC)
 985 AC_SUBST(LIBMATHSPEC)
 986
 987 AC_SUBST(LIBGCJTESTSPEC)
 988
 989 # Allow the GC to be disabled.  Can be useful when debugging.
 990 AC_MSG_CHECKING([for garbage collector to use])
 991 AC_ARG_ENABLE(java-gc,
 992   AS_HELP_STRING([--enable-java-gc=TYPE],
 993                  [choose garbage collector (default is boehm)]),
 994   [GC=$enableval],
 995   [GC=boehm])
 996 GCLIBS=
 997 GCINCS=
 998 GCDEPS=
 999 GCSPEC=
1000 JC1GCSPEC=
1001 GCTESTSPEC=
1002 case "$GC" in
1003  boehm)
1004     AC_MSG_RESULT(boehm)
1005     GCLIBS=../boehm-gc/libgcjgc_convenience.la
1006     JC1GCSPEC='-fuse-boehm-gc'
1007     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
1008     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
1009     GCOBJS=boehm.lo
1010     GCHDR=boehm-gc.h
1011     # The POSIX thread support needs to know this.
1012     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
1013     ;;
1014  no)
1015     AC_MSG_RESULT(none)
1016     GCHDR=no-gc.h
1017     ;;
1018  *)
1019     AC_MSG_ERROR([unrecognized collector "$GC"])
1020     ;;
1021 esac
1022 AC_SUBST(GCLIBS)
1023 AC_SUBST(GCINCS)
1024 AC_SUBST(GCDEPS)
1025 AC_SUBST(GCSPEC)
1026 AC_SUBST(JC1GCSPEC)
1027 AC_SUBST(GCTESTSPEC)
1028 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
1029 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1030 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1031
1032
1033 AC_MSG_CHECKING([for thread model used by GCC])
1034 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1035 AC_MSG_RESULT([$THREADS])
1036
1037 case "$THREADS" in
1038  no | none | single)
1039     THREADS=none
1040     ;;
1041  aix | posix | posix95 | pthreads)
1042     THREADS=posix
1043     case "$host" in
1044      *-*-linux*)
1045         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1046         ;;
1047     esac
1048     ;;
1049  win32)
1050     ;;
1051  decosf1 | irix | mach | os2 | dce | vxworks)
1052     AC_MSG_ERROR(thread package $THREADS not yet supported)
1053     ;;
1054  *)
1055     AC_MSG_ERROR($THREADS is an unknown thread package)
1056     ;;
1057 esac
1058
1059 THREADCXXFLAGS=
1060 THREADLDFLAGS=
1061 THREADLIBS=
1062 THREADINCS=
1063 THREADDEPS=
1064 THREADH=
1065 THREADSPEC=
1066 THREADSTARTFILESPEC=
1067 case "$THREADS" in
1068  posix)
1069     case "$host" in
1070      *-*-cygwin*)
1071         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1072         ;;
1073      *-*-freebsd[[1234]]*)
1074         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1075         # merely adds pthread_* functions) but it does have a -pthread switch
1076         # which is required at link-time to select -lc_r *instead* of -lc.
1077         THREADLDFLAGS=-pthread
1078         # Don't set THREADSPEC here as might be expected since -pthread is
1079         # not processed when found within a spec file, it must come from
1080         # the command line.  For now, the user must provide the -pthread
1081         # switch to link code compiled with gcj.  In future, consider adding
1082         # support for weak references to pthread_* functions ala gthr.h API.
1083         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1084         ;;
1085      *-*-freebsd*)
1086         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1087         # systems which support threads and -lpthread.
1088         THREADLDFLAGS=-pthread
1089         THREADSPEC=-lpthread
1090         ;;
1091      alpha*-dec-osf* | hppa*-hp-hpux*)
1092         THREADCXXFLAGS=-pthread
1093         # boehm-gc needs some functions from librt, so link that too.
1094         THREADLIBS='-lpthread -lrt'
1095         THREADSPEC='-lpthread -lrt'
1096         ;;
1097      *-*-solaris2.8)
1098         # Always use alternate thread library on Solaris 8.  Need libthread
1099         # for TLS support.
1100         # Need -Wl,-R to get it through libtool ...
1101         THREADLIBS='-L/usr/lib/lwp$(MULTISUBDIR) -Wl,-R -Wl,/usr/lib/lwp$(MULTISUBDIR) -lpthread -lthread'
1102         # ... while ld only accepts -R.
1103         THREADSPEC='-L/usr/lib/lwp%{m64:/64} -R/usr/lib/lwp%{m64:/64} -lpthread -lthread'
1104         ;;
1105      *-*-solaris2.9)
1106         # As on Solaris 8, need libthread for TLS support.
1107         THREADLIBS='-lpthread -lthread'
1108         THREADSPEC='-lpthread -lthread'
1109         ;;
1110      *-*-darwin*)
1111         # Don't set THREADLIBS or THREADSPEC as Darwin already
1112         # provides pthread via libSystem.
1113         ;;
1114      *)
1115         THREADLIBS=-lpthread
1116         THREADSPEC=-lpthread
1117         ;;
1118     esac
1119     THREADH=posix-threads.h
1120     # MIT pthreads doesn't seem to have the mutexattr functions.
1121     # But for now we don't check for it.  We just assume you aren't
1122     # using MIT pthreads.
1123     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1124
1125     # If we're using the Boehm GC, then we happen to know that it
1126     # defines _REENTRANT, so we don't bother.  Eww.
1127     if test "$GC" != boehm; then
1128        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1129     fi
1130     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1131     ;;
1132
1133  win32)
1134     THREADH=win32-threads.h
1135     THREADCXXFLAGS=-mthreads
1136     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1137     # But we do not want the executables created to be dependent on
1138     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1139     # exception handling contexts.  The following kludge achieves this effect
1140     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1141     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1142     # A workaround is to explicitly use -mthreads while linking Java programs.
1143     # See PR libgcj/28263.
1144     #
1145     # FIXME: In Java we are able to detect thread death at the end of
1146     # Thread.run() so we should be able to clean up the exception handling
1147     # contexts ourselves.
1148     THREADSTARTFILESPEC='crtmt%O%s'
1149     ;;
1150
1151  none)
1152     THREADH=no-threads.h
1153     ;;
1154 esac
1155 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1156 AC_SUBST(THREADLIBS)
1157 AC_SUBST(THREADINCS)
1158 AC_SUBST(THREADDEPS)
1159 AC_SUBST(THREADSPEC)
1160 AC_SUBST(THREADSTARTFILESPEC)
1161 AC_SUBST(THREADLDFLAGS)
1162 AC_SUBST(THREADCXXFLAGS)
1163 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1164 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1165 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1166 if test "$enable_shared" != yes; then
1167   use_libgcj_bc=no
1168 fi
1169 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1170
1171 if test -d sysdep; then true; else mkdir sysdep; fi
1172 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1173 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1174 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1175
1176 LIBGCJ_SPEC_LGCJ=-lgcj
1177 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1178 if test x"$libgcj_spec_lgcj_override" != x ; then
1179   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1180 fi
1181 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1182   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1183 fi
1184 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1185 if test "$use_libgcj_bc" = yes; then
1186   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1187   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1188 fi
1189 AC_SUBST(LIBGCJ_SPEC)
1190 AC_SUBST(LIBGCJ_BC_SPEC)
1191
1192 HASH_SYNC_SPEC=
1193 # Hash synchronization is only useful with posix threads right now.
1194 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1195    HASH_SYNC_SPEC=-fhash-synchronization
1196    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1197 fi
1198 AC_SUBST(HASH_SYNC_SPEC)
1199
1200 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1201
1202 # We're in the tree with gcc, and need to include some of its headers.
1203 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1204
1205 if test "x${with_newlib}" = "xyes"; then
1206    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1207    # may not work correctly, because the compiler may not be able to
1208    # link executables.
1209
1210    # We assume newlib.  This lets us hard-code the functions we know
1211    # we'll have.
1212    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1213    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1214    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1215    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1216    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1217    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1218    # This is only for POSIX threads.
1219    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1220
1221    # Assume we do not have getuid and friends.
1222    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1223    PLATFORMNET=NoNet
1224 else
1225    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1226                    localtime_r getpwuid_r getcwd \
1227                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1228                    nl_langinfo setlocale \
1229                    inet_pton uname inet_ntoa \
1230                    getrlimit sigaction ftruncate mmap \
1231                    getifaddrs])
1232    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1233    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1234    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1235    AC_CHECK_LIB(dl, dladdr, [
1236        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1237        AC_CHECK_LIB(dld, dladdr, [
1238        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1239
1240    if test x"$cross_compiling" = x"no"; then
1241      AC_CHECK_FILES(/proc/self/exe, [
1242        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1243      AC_CHECK_FILES(/proc/self/maps, [
1244        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1245          [Define if you have /proc/self/maps])])
1246    else
1247      case $host in
1248      *-linux*)
1249        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1250        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1251        ;;
1252      esac
1253    fi
1254
1255    AM_ICONV
1256    AM_LC_MESSAGES
1257    AC_STRUCT_TIMEZONE
1258    LDLIBICONV=`echo " $LIBICONV " | sed "s/${acl_cv_wl--Wl,}/ /g; s/,/ /g"`
1259    AC_SUBST([LDLIBICONV])
1260
1261    AC_CHECK_FUNCS(gethostbyname_r, [
1262      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1263        [Define if you have the 'gethostbyname_r' function.])
1264      # There are two different kinds of gethostbyname_r.
1265      # We look for the one that returns `int'.
1266      # Hopefully this check is robust enough.
1267      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1268        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1269
1270      case " $GCINCS " in
1271      *" -D_REENTRANT "*) ;;
1272      *)
1273         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1274         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1275         [libjava_cv_gethostbyname_r_needs_reentrant],
1276         [ AC_LANG_PUSH(C++)
1277           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1278             [[gethostbyname_r("", 0, 0);]])],
1279             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1280                 CPPFLAGS_SAVE="$CPPFLAGS"
1281                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1282                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1283                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1284                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1285                 CPPFLAGS="$CPPFLAGS_SAVE"
1286           ])
1287           AC_LANG_POP(C++)
1288         ])
1289         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1290           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1291         fi
1292      ;;
1293      esac
1294
1295      AC_CACHE_CHECK([for struct hostent_data],
1296         [libjava_cv_struct_hostent_data], [dnl
1297         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1298 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1299 # define _REENTRANT 1
1300 #endif
1301 #include <netdb.h>]], [[struct hostent_data data;]])],
1302           [libjava_cv_struct_hostent_data=yes],
1303           [libjava_cv_struct_hostent_data=no])])
1304      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1305        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1306          [Define if struct hostent_data is defined in netdb.h])
1307      fi
1308    ])
1309
1310    # FIXME: libjava source code expects to find a prototype for
1311    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1312    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1313    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1314    # linkage check is enough, yet C++ code requires proper prototypes.)
1315    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1316    AC_CHECK_FUNCS(gethostbyaddr_r, [
1317      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1318        [Define if you have the 'gethostbyaddr_r' function.])
1319      # There are two different kinds of gethostbyaddr_r.
1320      # We look for the one that returns `int'.
1321      # Hopefully this check is robust enough.
1322      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1323        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1324          [Define if gethostbyaddr_r returns 'int'.])])])])
1325
1326    AC_CHECK_FUNCS(gethostname, [
1327      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1328        [Define if you have the 'gethostname' function.])
1329      AC_EGREP_HEADER(gethostname, unistd.h, [
1330        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1331          [Define if gethostname is declared in <unistd.h>.])])])
1332
1333    AC_CHECK_FUNCS(usleep, [
1334      AC_EGREP_HEADER(usleep, unistd.h, [
1335        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1336           [Define if usleep is declared in <unistd.h>.])])])
1337
1338    # Look for these functions in the thread library, but only bother
1339    # if using POSIX threads.
1340    if test "$THREADS" = posix; then
1341       save_LIBS="$LIBS"
1342       LIBS="$LIBS $THREADLIBS"
1343
1344       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1345       # Solaris 7 the name librt is preferred.
1346       AC_CHECK_FUNCS(sched_yield, , [
1347         AC_CHECK_LIB(rt, sched_yield, [
1348           AC_DEFINE(HAVE_SCHED_YIELD)
1349           THREADLIBS="$THREADLIBS -lrt"
1350           THREADSPEC="$THREADSPEC -lrt"], [
1351           AC_CHECK_LIB(posix4, sched_yield, [
1352             AC_DEFINE(HAVE_SCHED_YIELD)
1353             THREADLIBS="$THREADLIBS -lposix4"
1354             THREADSPEC="$THREADSPEC -lposix4"])])])
1355
1356       AC_CHECK_LIB(rt, clock_gettime, [
1357          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1358          case "$THREADSPEC" in
1359            *-lrt*) ;;
1360            *)
1361              THREADSPEC="$THREADSPEC -lrt"
1362              THREADLIBS="$THREADLIBS -lrt"
1363              ;;
1364          esac])
1365
1366       LIBS="$save_LIBS"
1367
1368       # We can save a little space at runtime if the mutex has m_count
1369       # or __m_count.  This is a nice hack for Linux.
1370       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1371           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1372         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1373              [Define if pthread_mutex_t has m_count member.]), [
1374         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1375             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1376           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1377             [Define if pthread_mutex_t has __m_count member.]))])
1378    fi
1379
1380    # We require a way to get the time.
1381    time_found=no
1382    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1383    if test "$time_found" = no; then
1384       AC_MSG_ERROR([no function found to get the time])
1385    fi
1386
1387    AC_CHECK_FUNCS(memmove)
1388
1389    # We require memcpy.
1390    memcpy_found=no
1391    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1392    if test "$memcpy_found" = no; then
1393       AC_MSG_ERROR([memcpy is required])
1394    fi
1395    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1396    AC_CHECK_LIB(dl, dlopen, [
1397        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1398        AC_CHECK_LIB(dld, dlopen, [
1399        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1400
1401    # Some library-finding code we stole from Tcl.
1402    #--------------------------------------------------------------------
1403    #    Check for the existence of the -lsocket and -lnsl libraries.
1404    #    The order here is important, so that they end up in the right
1405    #    order in the command line generated by make.  Here are some
1406    #    special considerations:
1407    #    1. Use "connect" and "accept" to check for -lsocket, and
1408    #       "gethostbyname" to check for -lnsl.
1409    #    2. Use each function name only once:  can't redo a check because
1410    #       autoconf caches the results of the last check and won't redo it.
1411    #    3. Use -lnsl and -lsocket only if they supply procedures that
1412    #       aren't already present in the normal libraries.  This is because
1413    #       IRIX 5.2 has libraries, but they aren't needed and they're
1414    #       bogus:  they goof up name resolution if used.
1415    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1416    #       To get around this problem, check for both libraries together
1417    #       if -lsocket doesn't work by itself.
1418    #--------------------------------------------------------------------
1419
1420    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1421     [gcj_cv_lib_sockets=
1422      gcj_checkBoth=0
1423      unset ac_cv_func_connect
1424      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1425      if test "$gcj_checkSocket" = 1; then
1426          unset ac_cv_func_connect
1427          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1428                       gcj_checkBoth=1)
1429      fi
1430      if test "$gcj_checkBoth" = 1; then
1431          gcj_oldLibs=$LIBS
1432          LIBS="$LIBS -lsocket -lnsl"
1433          unset ac_cv_func_accept
1434          AC_CHECK_FUNC(accept,
1435                        [gcj_checkNsl=0
1436                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1437          unset ac_cv_func_accept
1438          LIBS=$gcj_oldLibs
1439      fi
1440      unset ac_cv_func_gethostbyname
1441      gcj_oldLibs=$LIBS
1442      LIBS="$LIBS $gcj_cv_lib_sockets"
1443      AC_CHECK_FUNC(gethostbyname, ,
1444                    [AC_CHECK_LIB(nsl, main,
1445                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1446      unset ac_cv_func_gethostbyname
1447      LIBS=$gcj_oldLIBS
1448    ])
1449    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1450
1451    if test "$with_system_zlib" = yes; then
1452       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1453    fi
1454
1455    # Test for Gtk stuff, if asked for.
1456    if test "$use_gtk_awt" = yes; then
1457       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1458       AC_SUBST(GTK_CFLAGS)
1459       AC_SUBST(GTK_LIBS)
1460
1461       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1462       AC_SUBST(GLIB_CFLAGS)
1463       AC_SUBST(GLIB_LIBS)
1464
1465       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1466       AC_SUBST(LIBART_CFLAGS)
1467       AC_SUBST(LIBART_LIBS)
1468
1469       # We require the XTest Extension to support java.awt.Robot.
1470       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1471                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1472                    [${X_LIBS}])
1473    fi
1474
1475    # On Solaris, and maybe other architectures, the Boehm collector
1476    # requires -ldl.
1477    if test "$GC" = boehm; then
1478       case "${host}" in
1479           mips-sgi-irix6*)
1480             # While IRIX 6 has libdl for the O32 and N32 ABIs, the N64 one is
1481             # missing.  It's unnecessary anyway since dlopen lives in libc.
1482             ;;
1483           *-*-darwin*)
1484             ;;
1485           *)
1486             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1487             ;;
1488       esac
1489    fi
1490 fi
1491
1492 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1493 case $build in
1494     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1495     *)         CLASSPATH_SEPARATOR=':' ;;
1496 esac
1497 AC_SUBST(CLASSPATH_SEPARATOR)
1498
1499 # We must search the source tree for java.lang, since we still don't
1500 # have libgcj.jar nor java/lang/*.class
1501 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1502 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1503
1504 # Since some classes depend on this one, we need its source available
1505 # before we can do any GCJ compilation test :-(
1506 if test ! -f gnu/classpath/Configuration.java; then
1507   test -d gnu || mkdir gnu
1508   test -d gnu/classpath || mkdir gnu/classpath
1509   # Note that it is not crucial that all the values here be correct.
1510   sed -e "s,@prefix@,$expanded_prefix," \
1511       -e "s,@VERSION@,$VERSION," \
1512       -e "s,@LIBDEBUG@,false," \
1513       -e "s,@INIT_LOAD_LIBRARY@,false," \
1514       -e "s,@@,$LIBGCJDEBUG," \
1515       -e "s,@default_toolkit@,$TOOLKIT," \
1516       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1517       -e "s,@GTK_CAIRO_ENABLED@,false," \
1518       -e "s,@ECJ_JAR@,," \
1519       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1520         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1521         > gnu/classpath/Configuration.java
1522   # We do not want to redirect the output of the grep below to /dev/null,
1523   # but we add /dev/null to the input list so that grep will print the
1524   # filename of Configuration.java in case it finds any matches.
1525   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1526     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1527   fi
1528 fi
1529
1530 LT_AC_PROG_GCJ
1531
1532 # Now remove it.
1533 rm -f gnu/classpath/Configuration.java
1534
1535 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1536
1537 AC_CHECK_SIZEOF(void *)
1538
1539 AC_C_BIGENDIAN
1540
1541 ZLIBS=
1542 SYS_ZLIBS=
1543 ZINCS=
1544
1545 if test -z "$ZLIBSPEC"; then
1546    # Use zlib from the GCC tree.
1547    ZINCS='-I$(top_srcdir)/../zlib'
1548    ZLIBS=../zlib/libzgcj_convenience.la
1549 else
1550    # System's zlib.
1551    SYS_ZLIBS="$ZLIBSPEC"
1552 fi
1553 AC_SUBST(ZLIBS)
1554 AC_SUBST(SYS_ZLIBS)
1555 AC_SUBST(ZINCS)
1556 AC_SUBST(DIVIDESPEC)
1557 AC_SUBST(CHECKREFSPEC)
1558 AC_SUBST(EXCEPTIONSPEC)
1559 AC_SUBST(BACKTRACESPEC)
1560 AC_SUBST(IEEESPEC)
1561 AC_SUBST(ATOMICSPEC)
1562
1563 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1564 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1565 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1566 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1567 AC_SUBST(GCC_UNWIND_INCLUDE)
1568
1569 # Process the option "--enable-version-specific-runtime-libs"
1570 # Calculate toolexeclibdir
1571 case ${version_specific_libs} in
1572   yes)
1573     # Need the gcc compiler version to know where to install libraries
1574     # and header files if --enable-version-specific-runtime-libs option
1575     # is selected.
1576     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1577     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1578     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1579     toolexeclibdir=$toolexecmainlibdir
1580     ;;
1581   no)
1582     if test -n "$with_cross_host" &&
1583        test x"$with_cross_host" != x"no"; then
1584       # Install a library built with a cross compiler in tooldir, not libdir.
1585       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1586       toolexecmainlibdir='$(toolexecdir)/lib'
1587     else
1588       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1589       toolexecmainlibdir='$(libdir)'
1590     fi
1591     multi_os_directory=`$CC -print-multi-os-directory`
1592     case $multi_os_directory in
1593       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1594       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1595     esac
1596     ;;
1597 esac
1598 AC_SUBST(toolexecdir)
1599 AC_SUBST(toolexecmainlibdir)
1600 AC_SUBST(toolexeclibdir)
1601
1602 # Determine gcj and libgcj version number.
1603 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1604 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1605 GCJVERSION=$gcjversion
1606 AC_SUBST(GCJVERSION)
1607 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1608
1609 # Determine where the standard .db file and GNU Classpath JNI
1610 # libraries are found.
1611 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1612 multi_os_directory=`$CC -print-multi-os-directory`
1613 case $multi_os_directory in
1614   .)
1615    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1616    ;;
1617   *)
1618    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1619    ;;
1620 esac
1621 AC_SUBST(dbexecdir)
1622 AC_SUBST(gcjsubdir)
1623
1624 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1625 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1626
1627 TL_AC_GXX_INCLUDE_DIR
1628
1629 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1630 # On that system, sys/ioctl.h will not include sys/filio.h unless
1631 # BSD_COMP is defined; just including sys/filio.h is simpler.
1632 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1633 # for now.  If you change this, you also must update natFile.cc.
1634 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1635                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1636                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1637                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1638                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1639
1640 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1641 AC_CHECK_HEADERS(net/if.h, [], [], [
1642 #ifdef HAVE_SYS_SOCKET_H
1643 #include <sys/socket.h>
1644 #endif
1645 ])
1646
1647 AC_CHECK_HEADERS(inttypes.h, [
1648     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1649     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1650 ])
1651
1652 AC_CHECK_TYPE([ssize_t], [int])
1653 AC_CHECK_TYPE([magic_t], [
1654     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1655 #ifdef HAVE_MAGIC_H
1656 #include <magic.h>
1657 #endif])
1658
1659 AC_MSG_CHECKING([for in_addr_t])
1660 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1661 #if STDC_HEADERS
1662 #include <stdlib.h>
1663 #include <stddef.h>
1664 #endif
1665 #if HAVE_NETINET_IN_H
1666 #include <netinet/in.h>
1667 #endif]], [[in_addr_t foo;]])],
1668   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1669      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1670    AC_MSG_RESULT(yes)],
1671   [AC_MSG_RESULT(no)])
1672
1673 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1674 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1675   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1676      [Define if struct ip_mreq is defined in netinet/in.h.])
1677    AC_MSG_RESULT(yes)],
1678   [AC_MSG_RESULT(no)])
1679
1680 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1681 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1682   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1683      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1684    AC_MSG_RESULT(yes)],
1685   [AC_MSG_RESULT(no)])
1686
1687 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1688 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1689   [AC_DEFINE(HAVE_INET6, 1,
1690      [Define if inet6 structures are defined in netinet/in.h.])
1691    AC_MSG_RESULT(yes)],
1692   [AC_MSG_RESULT(no)])
1693
1694 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1695 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1696 #include <sys/types.h>
1697 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1698   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1699    AC_MSG_RESULT(yes)],
1700   [AC_MSG_RESULT(no)])
1701
1702 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1703 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1704   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1705    AC_MSG_RESULT(yes)],
1706   [AC_MSG_RESULT(no)
1707    AC_MSG_CHECKING([for global timezone variable])
1708    dnl FIXME: we don't want a link check here because that won't work
1709    dnl when cross-compiling.  So instead we make an assumption that
1710    dnl the header file will mention timezone if it exists.
1711    dnl Don't find the win32 function timezone
1712    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1713      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1714       AC_MSG_RESULT(yes)],
1715      [AC_MSG_RESULT(no)
1716        AC_MSG_CHECKING([for global _timezone variable])
1717        dnl FIXME: As above, don't want link check
1718        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1719          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1720             [Define if your platform has the global _timezone variable.])
1721           AC_MSG_RESULT(yes)],
1722           [AC_MSG_RESULT(no)])])])
1723
1724 AC_CHECK_PROGS(PERL, perl, false)
1725
1726 SYSDEP_SOURCES=
1727 SIGNAL_HANDLER_AUX=
1728
1729 case "${host}" in
1730  i?86-*-linux*)
1731     SIGNAL_HANDLER=include/i386-signal.h
1732     ;;
1733  *-*-solaris2*)
1734     SIGNAL_HANDLER=include/solaris-signal.h
1735     ;;
1736 # ia64-*)
1737 #    SYSDEP_SOURCES=sysdep/ia64.c
1738 #    test -d sysdep || mkdir sysdep
1739 #    ;;
1740  hppa*-*-linux*)
1741     SIGNAL_HANDLER=include/pa-signal.h
1742     ;;
1743  hppa*-hp-hpux*)
1744     SIGNAL_HANDLER=include/hppa-signal.h
1745     ;;
1746  ia64-*-linux*)
1747     SIGNAL_HANDLER=include/dwarf2-signal.h
1748     ;;
1749  powerpc*-*-linux*)
1750     SIGNAL_HANDLER=include/powerpc-signal.h
1751     ;;
1752  alpha*-*-linux*)
1753     SIGNAL_HANDLER=include/dwarf2-signal.h
1754     ;;
1755  s390*-*-linux*)
1756     SIGNAL_HANDLER=include/s390-signal.h
1757     ;;
1758  x86_64*-*-linux*)
1759     SIGNAL_HANDLER=include/x86_64-signal.h
1760     SIGNAL_HANDLER_AUX=include/i386-signal.h
1761     ;;
1762  sparc*-*-linux*)
1763     SIGNAL_HANDLER=include/dwarf2-signal.h
1764     ;;
1765  sh*-*-linux*)
1766     SIGNAL_HANDLER=include/sh-signal.h
1767     ;;
1768  *mingw*)
1769     SIGNAL_HANDLER=include/win32-signal.h
1770     ;;
1771  mips*-*-linux*)
1772     SIGNAL_HANDLER=include/mips-signal.h
1773     ;;
1774  m68*-*-linux*)
1775     SIGNAL_HANDLER=include/dwarf2-signal.h
1776     ;;
1777  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1778     SIGNAL_HANDLER=include/darwin-signal.h
1779     ;;
1780  powerpc*-*-aix*)
1781     SIGNAL_HANDLER=include/aix-signal.h
1782     ;;
1783  *)
1784     SIGNAL_HANDLER=include/default-signal.h
1785     ;;
1786 esac
1787
1788 # If we're using sjlj exceptions, forget what we just learned.
1789 if test "$enable_sjlj_exceptions" = yes; then
1790    SIGNAL_HANDLER=include/default-signal.h
1791    SIGNAL_HANDLER_AUX=
1792 fi
1793
1794 AC_SUBST(SYSDEP_SOURCES)
1795
1796 if test -z "$SIGNAL_HANDLER_AUX"; then
1797   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1798 fi
1799
1800 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1801                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1802
1803 if test "${multilib}" = "yes"; then
1804   multilib_arg="--enable-multilib"
1805 else
1806   multilib_arg=
1807 fi
1808
1809 # See if we support thread-local storage.
1810 GCC_CHECK_TLS
1811
1812 # For _Unwind_GetIPInfo.
1813 GCC_CHECK_UNWIND_GETIPINFO
1814
1815 # See if linker supports anonymous version scripts.
1816 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1817   [libjava_cv_anon_version_script],
1818   [AC_ARG_ENABLE(symvers,
1819      AS_HELP_STRING([--disable-symvers],
1820                     [disable symbol versioning for libjava]),
1821        [case "$enableval" in
1822          yes) libjava_cv_anon_version_script=yes ;;
1823          no)  libjava_cv_anon_version_script=no ;;
1824          *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]);;
1825         esac],
1826        [libjava_cv_anon_version_script=yes]
1827    )
1828    if test x$libjava_cv_anon_version_script = xyes; then
1829      save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1830      CFLAGS="$CFLAGS -fPIC";
1831      LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1832      echo '{ global: globalsymb*; local: *; };' > conftest.map
1833      AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1834                  [libjava_cv_anon_version_script=gnu],
1835                  [libjava_cv_anon_version_script=no])
1836      if test x$libjava_cv_anon_version_script = xno; then
1837        case "$target_os" in
1838          solaris2*)
1839            LDFLAGS="$save_LDFLAGS"
1840            LDFLAGS="$LDFLAGS -shared -Wl,-M,conftest.map"
1841            # Sun ld doesn't understand wildcards here.
1842            echo '{ global: globalsymbol; local: *; };' > conftest.map
1843            AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1844                        [libjava_cv_anon_version_script=sun], [])
1845            ;;
1846        esac
1847      fi
1848      CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1849    fi
1850   ])
1851 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" != no)
1852 AM_CONDITIONAL(ANONVERSCRIPT_GNU, test "$libjava_cv_anon_version_script" = gnu)
1853 AM_CONDITIONAL(ANONVERSCRIPT_SUN, test "$libjava_cv_anon_version_script" = sun)
1854
1855 # Check if linker supports static linking on a per library basis
1856 LD_START_STATIC_SPEC=
1857 LD_FINISH_STATIC_SPEC=
1858 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1859   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1860     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1861     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1862   fi
1863 fi
1864 AC_SUBST(LD_START_STATIC_SPEC)
1865 AC_SUBST(LD_FINISH_STATIC_SPEC)
1866
1867 here=`${PWDCMD-pwd}`
1868 AC_SUBST(here)
1869
1870 # We get this from the environment.
1871 AC_SUBST(GCJFLAGS)
1872
1873 default_python_dir="/share/gcc-`cat ${srcdir}/../gcc/BASE-VER`/python/libjava"
1874 AC_ARG_WITH([python-dir],
1875             AS_HELP_STRING([--with-python-dir],
1876                            [the location to install Python modules. This path should NOT include the prefix.]),
1877             [with_python_dir=$withval], [with_python_dir="${default_python_dir}"])
1878
1879 # Needed for installing Python modules during make install.
1880 python_mod_dir="\${prefix}${with_python_dir}"
1881
1882 # Needed for substituting into aot-compile*
1883 python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1884
1885 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1886 AC_SUBST(python_mod_dir)
1887 AC_SUBST(python_mod_dir_expanded)
1888
1889 # needed for aot-compile-rpm
1890 MAKE=`which make`
1891 AC_SUBST(MAKE)
1892
1893 AC_ARG_ENABLE([aot-compile-rpm],
1894   [AS_HELP_STRING([--enable-aot-compile-rpm],
1895                  [enable installation of aot-compile-rpm [default=no]])],
1896   [case "${enableval}" in
1897     yes) AOT_RPM_ENABLED=yes ;;
1898     no)  AOT_RPM_ENABLED=no ;;
1899     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1900   esac],
1901   [AOT_RPM_ENABLED=no]
1902 )
1903 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1904
1905 AC_ARG_ENABLE([java-home],
1906   [AS_HELP_STRING([--enable-java-home],
1907                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1908   [case "${enableval}" in
1909     yes) JAVA_HOME_ENABLED=yes ;;
1910     no)  JAVA_HOME_ENABLED=no ;;
1911     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1912   esac],
1913   [JAVA_HOME_ENABLED=no]
1914 )
1915 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1916
1917 # Only do these checks if java-home above is enabled.
1918 if test "x${JAVA_HOME_ENABLED}" = xyes
1919 then
1920
1921   AC_ARG_WITH([gcc-suffix],
1922               AS_HELP_STRING([--with-gcc-suffix],
1923                              [the GCC tool suffix (defaults to empty string)]),
1924               [gcc_suffix=$withval], [gcc_suffix=""])
1925   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1926   AC_SUBST(gcc_suffix)
1927
1928   AC_ARG_WITH([arch-directory],
1929               AS_HELP_STRING([--with-arch-directory],
1930                              [the arch directory under jre/lib (defaults to auto-detect)]),
1931               [host_cpu=$withval], [host_cpu=""])
1932
1933   AC_ARG_WITH([os-directory],
1934               AS_HELP_STRING([--with-os-directory],
1935                              [the os directory under include (defaults to auto-detect)]),
1936               [host_os=$withval], [host_os=""])
1937
1938   AC_ARG_WITH([origin-name],
1939               AS_HELP_STRING([--with-origin-name],
1940                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1941               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1942   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1943
1944   AC_ARG_WITH([arch-suffix],
1945               AS_HELP_STRING([--with-arch-suffix],
1946                              [the arch directory suffix (default is the empty string]),
1947               [arch_suffix=$withval], [arch_suffix=""])
1948   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1949
1950   AC_ARG_WITH([jvm-root-dir],
1951               AS_HELP_STRING([--with-jvm-root-dir],
1952                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1953               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1954   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1955
1956   AC_ARG_WITH([jvm-jar-dir],
1957               AS_HELP_STRING([--with-jvm-jar-dir],
1958                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1959               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1960   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1961
1962   JAVA_VERSION=1.5.0
1963   BUILD_VERSION=0
1964   AC_SUBST(JAVA_VERSION)
1965   AC_SUBST(BUILD_VERSION)
1966   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1967
1968   jre_dir=jre
1969   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1970   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1971
1972   JVM_ROOT_DIR=${jvm_root_dir}
1973   AC_SUBST(JVM_ROOT_DIR)
1974   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1975
1976   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1977   AC_SUBST(JVM_JAR_ROOT_DIR)
1978   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1979
1980   JVM_JAR_DIR=${jvm_jar_dir}
1981   AC_SUBST(JVM_JAR_DIR)
1982   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1983
1984   JRE_DIR=${jre_dir}
1985   AC_SUBST(JRE_DIR)
1986
1987   JRE_LNK=${jre_lnk}
1988   AC_SUBST(JRE_LNK)
1989
1990   SDK_LNK=${sdk_lnk}
1991   AC_SUBST(SDK_LNK)
1992
1993   SDK_BIN_DIR=${jvm_root_dir}/bin
1994   AC_SUBST(SDK_BIN_DIR)
1995   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1996
1997   SDK_LIB_DIR=${jvm_root_dir}/lib
1998   AC_SUBST(SDK_LIB_DIR)
1999   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
2000
2001   SDK_INCLUDE_DIR=${jvm_root_dir}/include
2002   AC_SUBST(SDK_INCLUDE_DIR)
2003   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
2004
2005   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
2006   AC_SUBST(JRE_BIN_DIR)
2007   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
2008
2009   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
2010   AC_SUBST(JRE_LIB_DIR)
2011   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
2012
2013   # Find gcj prefix using gcj found in PATH.
2014   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
2015
2016   # Where do the gcj binaries live?
2017   # For jhbuild based builds, they all live in a sibling of bin called
2018   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
2019   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
2020   AC_SUBST(GCJ_BIN_DIR)
2021   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
2022
2023   AC_MSG_RESULT(host is ${host})
2024   if test "x${host_cpu}" = "x"
2025   then
2026     case ${host} in
2027       *-mingw* | *-cygwin*)
2028         host_cpu=x86;;
2029       i486-* | i586-* | i686-*)
2030         host_cpu=i386;;
2031       x86_64-*)
2032         host_cpu=amd64;;
2033       *)
2034         host_cpu=${host_cpu};;
2035     esac
2036   fi
2037   AC_MSG_RESULT(arch directory: ${host_cpu})
2038   CPU=${host_cpu}
2039   AC_SUBST(CPU)
2040
2041   if test "x${host_os}" = "x"
2042   then
2043     case ${host} in
2044       *-mingw* | *-cygwin*)
2045         host_os=win32;;
2046       *-linux*)
2047         host_os=linux;;
2048       *)
2049         host_os=${host_os};;
2050     esac
2051   fi
2052   echo os directory: ${host_os}
2053   OS=${host_os}
2054   AC_SUBST(OS)
2055
2056   # make an expanded $libdir, for substituting into
2057   # scripts (and other non-Makefile things).
2058   LIBDIR=$libdir
2059   if test "x${exec_prefix}" = "xNONE"
2060   then
2061       lib_exec_prefix=$expanded_prefix
2062   else
2063       lib_exec_prefix=$exec_prefix
2064   fi
2065   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
2066   AC_SUBST(LIBDIR)
2067 fi
2068
2069 AC_CONFIG_FILES([
2070 Makefile
2071 libgcj.pc
2072 libgcj.spec
2073 libgcj-test.spec
2074 gcj/Makefile
2075 include/Makefile
2076 testsuite/Makefile
2077 contrib/aotcompile.py
2078 contrib/aot-compile
2079 contrib/aot-compile-rpm
2080 contrib/generate-cacerts.pl
2081 contrib/rebuild-gcj-db
2082 ])
2083
2084 if test ${multilib} = yes; then
2085   multilib_arg="--enable-multilib"
2086 else
2087   multilib_arg=
2088 fi
2089
2090 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2091 AC_OUTPUT